
actor msxArachnotron : Arachnotron replaces Arachnotron {

	Health 270
	Radius 64
	Height 64
	Mass 600
	Speed 12
	PainChance 148
	MONSTER
	+FLOORCLIP
	+DONTHARMCLASS
    +DONTHARMSPECIES
	SeeSound "baby/sight"
	PainSound "baby/pain"
	DeathSound "baby/death"
	ActiveSound "baby/active"
	Obituary "%o was railed by an Arachnotron."
	Decal RedRailScorch
	
	States{
		Spawn:
			RSPI AB 10 A_Look
			Loop
		See:
			RSPI A 20
			RSPI A 2 A_BabyMetal
			RSPI ABBCC 2 A_Chase
			RSPI D 2 A_BabyMetal
			RSPI DEEFF 2 A_Chase
			Goto See+1
		Missile:
			TNT1 A 0 A_Jump(24,"SuperShot")
			RSPI G 3 bright A_FaceTarget
			TNT1 A 0 A_PlaySound("enemy/archnormfire")
			RSPI H 2 bright	A_CustomMissile ("arach_PlasmaBall", 21, 2, random(-2,2), 0, 0)	
			RSPI H 1 A_SpidRefire
			goto Missile
			
		SuperShot:	
			RSPI GGGGG 2 bright A_FaceTarget
			TNT1 A 0 A_PlaySound("enemy/archsuperfire", CHAN_VOICE)
			RSPI H 5 bright	A_CustomMissile ("arach_PlasmaSuperBall", 21, 2, 0, 0, 0)	
			RSPI H 1 A_SpidRefire
			goto see
			
		Pain:
			RSPI I 3
			RSPI I 3 A_Pain
			Goto See+1
		Death:
			RSPI J 20 A_Scream
			RSPI K 7 A_Fall
			RSPI LMNO 7
			RSPI P -1
			Stop
		Raise:
			RSPI P 5
			RSPI ONMLKJ 5
			Goto See+1
	}
}


actor arach_PlasmaBall {
	radius 3
	height 3
	speed 32
	renderstyle add
	scale 0.5
	Damage (random(14,18))
	PROJECTILE
	SeeSound " "
	DeathSound "plasma/smallhit"
	+FORCEXYBILLBOARD
	states{
		spawn:
			TNT1 A 0
			TGBL A 1 bright A_SpawnItemEx("arach_PlasmaBallTrail",0,0,0, 0,0,0) 
			loop
		death:
			TNT1 AA 0 A_SpawnItemEx("arach_PBallBoomFire",0,0,0, 0,frandom(-0.4,0.4),frandom(0.8,1.4)) 
			AGFX GHIJK 2 bright
			stop
	}
}


actor arach_PlasmaBallTrail {
	scale 0.11
	alpha 1.0
	renderstyle add
	+NOINTERACTION
	+FORCEXYBILLBOARD
	+NOTELEPORT
	states{
		spawn:
			RMNS ABCDEFGHIJKLMNOPQ 1 bright A_FadeOut(0.02)
			stop
	}
}

actor arach_PBallBoomFire {
	scale 0.6
	alpha 1.0
	renderstyle add
	+NOINTERACTION
	+FORCEXYBILLBOARD
	+NOTELEPORT
	states{
		spawn:
			PFRE ABCDEFGHIJKL 1 bright A_FadeOut(0.08)
			stop
	}
}

actor arach_PlasmaSuperBall : fastprojectile{
	radius 3
	height 3
	speed 62
	renderstyle add
	scale 0.45
	alpha 1.0
	Damage (random(28,34))
	PROJECTILE
	SeeSound "enemy/archsuperfire"
	DeathSound "plasma/bighit"
	+FORCEXYBILLBOARD
	MissileType "arach_PSuperTrailSpawner"
	MissileHeight 8
	states{
		spawn:
			TNT1 A 0
			NPSB ABCDEFGHIJKL 1 bright 
			loop
		death:
			TNT1 A 0 A_Explode(40, 124, 0)
			TNT1 A 0 A_Quake (2, 10, 0, 158)
			TNT1 AAAA 0 A_SpawnItemEx("arach_PSuperBoomFire",0,0,0, 0,frandom(-1.8,1.8),frandom(-1.4,2.2)) 
			TNT1 AAAAAA 0 A_SpawnItemEx("arach_PSuperBoomFire2",0,0,0, frandom(-2.6,2.6),frandom(-3.6,3.6),frandom(-3.6,3.6)) 
			AGFX GHIJK 2 bright
			stop
	}
}

actor arach_PSuperTrailSpawner {
	+NOINTERACTION
	states{
		spawn:
			TNT1 A 0
			TNT1 A 0 A_SpawnItemEx("arach_PSuperTrail",0,0,0, 0,0,0) 
			TNT1 A 0 A_SpawnItemEx("arach_PSuperTrailFire",0,0,0, 0,frandom(-0.8,0.8),frandom(-0.8,0.8)) 
			stop
	}
}

actor arach_PSuperTrail {
	scale 0.4
	alpha 1.0
	renderstyle add
	+NOINTERACTION
	+FORCEXYBILLBOARD
	+NOTELEPORT
	states{
		spawn:
			TNT1 A 0
			TGBL A 1 bright A_FadeOut(0.08)
			stop
	}
}


actor arach_PSuperTrailFire {
	scale 0.3
	alpha 1.0
	renderstyle add
	+NOINTERACTION
	+FORCEXYBILLBOARD
	+NOTELEPORT
	states{
		spawn:
			PLSR ABCDEFGHIJKLMNO 1 bright A_FadeOut(0.06)
			stop
	}
}

//
actor arach_PSuperBoomFire { 
	scale 0.7
	alpha 1.0
	renderstyle add
	+NOINTERACTION
	+FORCEXYBILLBOARD
	+NOTELEPORT
	states{
		spawn:
			PFRE ABCDEFGHIJKL 1 bright A_FadeOut(0.02)
			stop
	}
}

actor arach_PSuperBoomFire2 : arach_PSuperTrailFire {
	scale 1.2
}
