ACTOR MSfiXd_DegninOre:Inventory replaces DegninOre{
	Inventory.MaxAmount 100
	Inventory.PickupMessage "Degnin Ore (explosive & energy weapons break forcefields)"
	States{
	Spawn:
		XPRK A -1
		Stop}}
// Lightamp Upgrade (Doom & Raven) //
ACTOR LightampUpgrade:CustomInventory{
	Inventory.PickupMessage "'Scouter' Light Amplification Visor"
	Inventory.PickupSound "inventory/lightamp/pickup"
	Inventory.MaxAmount 5
	Inventory.Amount 1
	Inventory.InterHubAmount 5
	Inventory.UseSound ""
	+INVENTORY.UNDROPPABLE
	States{
	Spawn:
		LAMP A 35
		LAMP BCDEFEDCBA 1 BRIGHT
		Loop
	Use:
		TNT1 A 0 A_JumpIfInventory("PowerLiteamp",1,"Nope")
		TNT1 A 0 {A_PlaySound("inventory/lightamp/on",CHAN_AUTO);
			A_GiveInventory("LightampActive");}
		Fail
	Nope:
		TNT1 A 0 
		Fail}}
ACTOR LightampActive:PowerupGiver{
	+INVENTORY.AUTOACTIVATE
	+INVENTORY.ALWAYSPICKUP
	Inventory.MaxAmount 0
	Powerup.Type "LiteAmp"}
ACTOR PowerLiteAmp:PowerLightAmp{
	+INVENTORY.HUBPOWER 
	+INVENTORY.PERSISTENTPOWER 
	Powerup.Duration -90
	Powerup.Color "40 40 FF",0.02}
// Hazard Screen (Doom & Strife) //
ACTOR HazardScreen:CustomInventory{
	Inventory.Amount 1
	Inventory.MaxAmount 5
	Inventory.PickupSound "weapons/ar_clipin2"
	Inventory.UseSound ""
	Inventory.PickupMessage "Hazard Screen"
	States{
	Spawn:
		HZSD A -1 BRIGHT
		Stop
	Use:
		TNT1 A 0 A_JumpIfInventory("HazardScreenGiver",1,"Nope")
		TNT1 A 0 A_JumpIfInventory("PowerEnviroSuit",1,"Nope")
		TNT1 A 0 {A_PlaySound("inventory/hazardscreen/on",CHAN_AUTO);
			A_GiveInventory("HazardScreenGiver");
			ACS_NamedExecute("pmsx_PowerUpFlash",0,5,0,0);}
		Stop
	Nope:
		TNT1 A 0 {A_Print("\cn- Hazard Screen active -");
			A_PlaySound("weapons/cr_noammo",CHAN_AUTO,0.5);}
		Fail}}
ACTOR HazardScreenGiver:PowerupGiver{
	+INVENTORY.AUTOACTIVATE
	Powerup.Type "EnviroSuit"}
ACTOR PowerEnviroSuit:PowerIronFeet{
	+INVENTORY.HUBPOWER 
	+INVENTORY.PERSISTENTPOWER 
	Powerup.Duration -90 
	Powerup.Color "00 FF 00",0.1
	Inventory.Icon ""}
// Jetpack (Raven) //
// I made a jetpack! And I didn't have to yank code from anybody else's to make 
// it!
ACTOR Jetpack:Inventory{
	Inventory.Amount 100
	Inventory.MaxAmount 100
	Inventory.InterHubAmount 0
	Inventory.PickupMessage "'Firefly' XLR7 Personal Jetpack"
	Inventory.PickupSound "jetpack/pickup"
	States{
	Spawn:
		JETP A -1
		Stop}}
// If twenty-one seems like an odd number,it's because there are ~2100 tics in 
// sixty seconds. Divide that by 100 (the maximum fuel the Jetpack can hold,and
// you get twenty-one. This is the number of tics that should pass before one 
// unit of Jetpack fuel is depleted,resulting in sixty seconds total flight 
// time.
ACTOR JetFuelCounter:Inventory{Inventory.Amount 1 Inventory.MaxAmount 21} 
ACTOR PowerJetpack:PowerFlight{
	Powerup.Duration 0x7FFFFFFF
	Powerup.Color "00 00 00",0.0}
// MSX's Powerups //
actor shieldauto:ArmorBonus{
	Inventory.PickupSound ""
	Inventory.UseSound ""
	+COUNTITEM
	+INVENTORY.ALWAYSPICKUP
	Armor.Savepercent 100.00
	Armor.Saveamount 5
	Armor.maxfullabsorb 0
	Armor.MaxSaveamount 200}
actor fullshield:BasicArmorPickup{
	Armor.saveamount 200
	Armor.savepercent 100.00
	Armor.maxfullabsorb 0}
actor overshield:BasicArmorPickup{
	Armor.saveamount 600
	Armor.savepercent 100.00
	Armor.maxfullabsorb 0}
actor shieldbooster:CustomInventory{
	scale 0.33
	Inventory.Amount 1
	Inventory.Maxamount 10
	Inventory.PickupMessage "Shield Booster Unit"
	inventory.pickupsound "items/armorpickup"
	-INVENTORY.INVBAR
    +COUNTITEM
	States{
	Spawn:
		SBST ABCDEDCB 2 bright
		loop
	Use:
		TNT1 A 0 {A_PlaySound("items/armorup",CHAN_AUTO);
			A_Giveinventory("fullshield",1);
			A_TakeInventory("PlayerShieldDamage",999);}
		fail}}
actor healthstim:CustomInventory{
	inventory.amount 1
	inventory.maxamount 15
	inventory.pickupsound "items/hstim_up"
	inventory.pickupmessage "Health Stim"
	scale 0.28
	-INVENTORY.INVBAR
	+COUNTITEM
	states{
  	Spawn:
		HSTI A -1
		loop
	Use:
		TNT1 A 0 {A_PlaySound("items/stimshot",CHAN_VOICE);
			A_GiveInventory("lifeup",1);}
		fail}}
ACTOR HealthStim_MasochistSpawner:RandomSpawner{
	DropItem "HealthStim" 32 1
	DropItem "Pistol_Ammo" 64 2
	DropItem "ARifle_Ammo" 32 2
	DropItem "AutoShot_Ammo" 32 2
	DropItem "GrenadeAmmo" 32 1}
actor healthpack:CustomInventory{
	scale 0.28
	Inventory.PickupMessage "Health Pack"
	inventory.pickupsound "items/hpack_up"
	+COUNTITEM
	States{
	Spawn:
		MPAK A -1
		stop
	Pickup:
		TNT1 A 0 A_JumpIfInventory("healthstim",15,"PickupFail")
		TNT1 A 0 A_JumpIfInventory("healthstim",14,"PickupDropOne")
		TNT1 A 0 A_GiveInventory("healthstim",2)
		stop
	PickupDropOne:
		TNT1 A 0 {A_GiveInventory("healthstim",1);
			A_SpawnItemEx("HealthStim");}
		stop
	PickupFail:
		TNT1 A 0
		fail}}
actor lifeup:Health{
	+COUNTITEM
	+INVENTORY.ALWAYSPICKUP
	Inventory.Amount 80
	Inventory.MaxAmount 200}
actor overshieldsphere:custominventory{
	+FLOATBOB
	+COUNTITEM
	+INVENTORY.ALWAYSPICKUP
	inventory.pickupsound "powerup/overshield"
	inventory.pickupmessage "OverShield Sphere!"
	states {
	spawn:
		OSHD ABCDCBA 2 bright
		loop
	pickup:
		TNT1 A 0 {A_GiveInventory("overshield");
			A_SetBlend("99 58 0",0.8,15);
			A_TakeInventory("PlayerShieldDamage",999);}
		stop}}
actor defensesphere:custominventory{
	scale 0.9
	+FLOATBOB
	+COUNTITEM
	+INVENTORY.AUTOACTIVATE
	+INVENTORY.ALWAYSPICKUP
	+INVENTORY.BIGPOWERUP
	inventory.pickupsound "powerup/defense"
	inventory.pickupmessage "Defense Sphere!"
	states{
	spawn:
		DEFS ABCDE 4 bright
		loop
	pickup:
		TNT1 A 0 {A_GiveInventory("defense_powerup");
			ACS_NamedExecute("pmsx_PowerUpFlash",0,4,0,0);}
		stop}}
actor defense_powerup:PowerupGiver{
	Inventory.MaxAmount 0
	Powerup.Type DefenseAura
	powerup.duration -60
	+AUTOACTIVATE}
actor defense_powerupinf:defense_powerup{powerup.duration 0x7FFFFFFF}
actor PowerDefenseAura:PowerProtection{damagefactor "normal",0.5}
actor immunesphere:custominventory{
	+FLOATBOB
	+COUNTITEM
	+INVENTORY.AUTOACTIVATE
	+INVENTORY.ALWAYSPICKUP
	+INVENTORY.BIGPOWERUP
	inventory.pickupsound "powerup/inmune" 
	inventory.pickupmessage "Immunity Sphere!"
	states{
	spawn:
		INVS ABCDCB 4 Bright
		loop
	pickup:
		TNT1 A 0 {A_GiveInventory("invul_powerup");
			ACS_NamedExecute("pmsx_PowerUpFlash",0,1,0,0);}
		stop}}
actor invul_powerup:PowerupGiver{
	+INVENTORY.AUTOACTIVATE
	+INVENTORY.ALWAYSPICKUP
	Inventory.MaxAmount 0
	Powerup.Type "Invulnerable"}
actor ultrasphere:CustomInventory{
	+FLOATBOB
	+COUNTITEM
	+INVENTORY.ALWAYSPICKUP
	Inventory.PickupMessage "Ultra Sphere!!"
	Inventory.PickupSound "powerup/ultra"
	States{
	Spawn:
		ULSP ABCDCB 4 bright
		Loop
	Pickup:
		TNT1 A 0 {A_GiveInventory("overshield",1);
			A_GiveInventory("ultralifeup",1);
			A_GiveInventory("PlayerStamina",100);
			A_TakeInventory("PlayerShieldDamage",999);
			ACS_NamedExecute("pmsx_PowerUpFlash",0,2,0,0);}
		Stop}}
actor ultralifeup:health{Inventory.Amount 400 Inventory.MaxAmount 400}
actor pdafullmap:CustomInventory{
	+COUNTITEM
	+INVENTORY.ALWAYSPICKUP
	Inventory.PickupSound "powerup/allmap"
	Inventory.PickupMessage "Area Map PDA"
	states{
	spawn:
		AMPD A -1 bright
		stop
	pickup:
		TNT1 A 0 {ACS_NamedExecute("pmsx_PowerUpFlash",0,3,0,0);
			A_GiveInventory("Allmap");}
		stop}}
actor msxBackpack:BackpackItem{
	scale 0.75
	Inventory.PickupMessage "Ammunition Backpack"
	inventory.pickupsound "items/ammopack"
	states{
	spawn:
		BPK2 A -1
		stop}}