actor msx_Blood:Blood replaces Blood{
	+NOINTERACTION
	+NOTELEPORT
	states{
	spray:
	spawn:
		TNT1 A 0 NoDelay A_Jump(256,1,2)
		TNT1 A 0 A_SpawnItemEx("msx_BloodSplat1",0,0,0,0,0,0,0,SXF_TRANSFERTRANSLATION)
		stop
		TNT1 A 0 A_SpawnItemEx("msx_BloodSplat2",0,0,0,0,0,0,0,SXF_TRANSFERTRANSLATION)
		stop}}
actor  msx_Blood2:Bloodsplatter replaces Bloodsplatter{
	+NOINTERACTION
	+NOTELEPORT
	states{
	spawn:
		TNT1 A 0 NoDelay A_Jump(256,1,2)
		TNT1 A 0 A_SpawnItemEx("msx_BloodSplat1",0,0,0,0,0,0,0,SXF_TRANSFERTRANSLATION)
		stop
		TNT1 A 0 A_SpawnItemEx("msx_BloodSplat2",0,0,0,0,0,0,0,SXF_TRANSFERTRANSLATION)
		stop}}
actor msx_BloodSplat1{
	mass 0
	radius	1
	height	1
	renderstyle normal
	+NOBLOCKMAP
	+FLOORCLIP
	+NOTELEPORT
	-NOGRAVITY
	states{
	Spawn:
		TNT1 AAAAAA 0 NoDelay A_SpawnItemEx("blood_spray",0,0,0,random(-2,2),random(-2,2),random(-1,2),random(1,360),SXF_TRANSFERTRANSLATION|128)
		TNT1 BBB 0 A_SpawnItemEx("flying_blood",0,0,0,random(-3,3),random(-3,3),random(3,6),random(1,360),SXF_TRANSFERTRANSLATION|128)
		TNT1 A 0 A_SpawnItemEx("blood_cloud",0,0,0,frandom(-0.6,0.6),frandom(-0.6,0.6),frandom(-0.5,0.5),random(1,360),SXF_TRANSFERTRANSLATION)
		BLDI A 5 A_PlaySound("blood/impact",CHAN_AUTO)
		BLDI BC 5 			
		stop}}
actor msx_BloodSplat2:Bloodsplatter replaces Bloodsplatter{
	Mass 0
	Radius	1
	Height	1
	Scale 0.20
	alpha 0.75
	gravity 0
	renderstyle normal
	+NOBLOCKMAP
	+FLOORCLIP
	+NOTELEPORT
	states{
	Spawn:
		SPRY A 1 NoDelay A_PlaySound("blood/impact",CHAN_AUTO)
		TNT1 AAAAAA 0 A_SpawnItemEx("blood_spray",0,0,0,random(-2,2),random(-2,2),random(-1,2),random(1,360),SXF_TRANSFERTRANSLATION|128)
		TNT1 AAAA 0 A_SpawnItemEx("flying_blood",0,0,0,random(-3,3),random(-3,3),random(3,6),random(1,360),SXF_TRANSFERTRANSLATION|128)
		TNT1 A 0 A_SpawnItemEx("blood_cloud2",0,0,0,frandom(-0.6,0.6),frandom(-0.6,0.6),frandom(-0.5,0.5),random(1,360),SXF_TRANSFERTRANSLATION)		
		SPRY BCDEFG 1
		stop}}
actor blood_spray{
	mass 1
	radius 1
	height 1
	scale 0.55
	+FORCEXYBILLBOARD
	+NOINTERACTION
	states{
	spawn:
		BLDS ABCDEF 2
	spawnloop:
		BLDS F 2 A_FadeOut(0.1)
		stop}}
actor blood_spray_Y:blood_spray{translation "176:191=[255,215,0]:[78,66,0]","32:47=[255,215,0]:[78,66,0]"}
actor blood_cloud{
	scale 0.6
	alpha 0.5
	renderstyle normal
	+FORCEXYBILLBOARD
	+NOINTERACTION
	states{
	spawn:
		TNT1 A 0 NoDelay A_Jump(256,1,2,3,4)
		BLCL A 0 A_Jump(256,4)
		BLCL B 0 A_Jump(256,3)
		BLCL C 0 A_Jump(256,2)
		BLCL D 0
		"####" "#" 5
		"####" "#" 2 A_FadeOut(0.1,1)
		Wait}}
actor blood_cloud2:blood_cloud{scale 0.68}
actor flying_blood{
	mass 0
	radius 1
	height 1
	scale 0.40
	alpha 0.75
	gravity 0.75
	+MISSILE
	+NOTELEPORT
	+FORCEXYBILLBOARD
	states{
	spawn:
		BTRL ABCD 1 NoDelay A_SpawnItemEx("blood_trails",0,0,0,0,0,0,0,SXF_TRANSFERTRANSLATION)
		loop
	death:
		TNT1 A 0 A_SpawnItemEx("floor_blood",0,0,0,0,0,0,0,SXF_TRANSFERTRANSLATION)
		stop}}
actor blood_trails{
	mass 0
	radius 1
	height 1
	scale 0.40
	alpha 0.75
	+NOINTERACTION
	+NOTELEPORT
	+FORCEXYBILLBOARD
	states{
	spawn:
	 	TNT1 A 0 A_Jump(256,"trail1","trail2","trail3","trail4")
	trail1:
		BTRL ABAB 1 
		stop
	trail2:
		BTRL CDCD 1 
		stop
	trail3:
		BTRL BCBC 1 
		stop
	trail4:
		BTRL ADAD 1 
		stop}}
actor floor_blood{
	mass 0
	radius 2
	height 2
	scale 0.40
	alpha 0.8
	-NOBLOCKMAP
	+NOTELEPORT
	+FORCEXYBILLBOARD
	states{
	spawn:
		TNT1 A 0 NoDelay A_PlaySound("blood/drip")
		TNT1 A 0 A_Jump(256,1,2,3,4)
		BSPT A 0 A_Jump(256,4)
		BSPT B 0 A_Jump(256,3)
		BSPT C 0 A_Jump(256,2)
		BSPT D 0
	  	"####" "#" 35 A_FadeOut(0.1)
		Wait}}
////////////////////////////////////////GORN
actor gore_spawner{
	states{
	spawn:
		TNT1 A 0
		TNT1 A 0 A_PlaySound("gore/explode")
		TNT1 AAA 0 A_SpawnItemEx("gore_bloodmist",random(-2,2),random(-2,2),8,frandom(-0.4,0.4),frandom(-0.4,0.4),0,random(1,360),SXF_TRANSFERTRANSLATION)
		TNT1 AAAAAAA 0 A_CustomMissile("gore_fleshbit",25,0,random(0,180),2,random(20,120))
		TNT1 AAAAAAA 0 A_CustomMissile("gore_fleshbit",25,0,random(181,360),2,random(20,120))
		TNT1 AAAA 0 A_CustomMissile("gib_spawner",25,0,random(0,180),2,random(20,120))
		TNT1 AAAA 0 A_CustomMissile("gib_spawner",25,0,random(181,360),2,random(20,120))
		stop}}
actor gore_bloodmist{
	mass 0
	radius 1
	height 1
	scale 0.6
	alpha 0.5
	+FORCEXYBILLBOARD
	+NOINTERACTION
	var int user_hold;
	var float user_fadeamt;
	states{
	spawn:
		TNT1 A 0 NoDelay {A_SetUserVar(user_hold,35);
			A_SetUserVarFloat(user_fadeamt,0.01);}
		TNT1 A 0 A_Jump(256,1,2,3,4,5)
		GRMI A 0 A_Jump(256,5)
		GRMI B 0 A_Jump(256,4)
		GRMI C 0 A_Jump(256,3)
		GRMI D 0 A_Jump(256,2)
		GRMI E 0
		"####" "#" 1 A_SetTics(user_hold)
		"####" "#" 2 A_FadeOut(0.01)
		Wait}} 
actor gore_bloodmistY:gore_bloodmist{
	scale 0.65
	states{
	spawn:
		TNT1 A 0 NoDelay {A_SetUserVar(user_hold,35);
			A_SetUserVarFloat(user_fadeamt,0.01);}
		TNT1 A 0 A_Jump(256,1,2,3,4,5)
		GRMY A 0 A_Jump(256,5)
		GRMY B 0 A_Jump(256,4)
		GRMY C 0 A_Jump(256,3)
		GRMY D 0 A_Jump(256,2)
		GRMY E 0
		"####" "#" 0
		Goto Super::Spawn+6}}
actor gore_bloodmist_small:gore_bloodmist{
	scale 0.18
	alpha 0.4
	states{
	spawn:
		TNT1 A 0 NoDelay {A_SetUserVar(user_hold,15);
			A_SetUserVarFloat(user_fadeamt,0.02);}
		Goto Super::Spawn+1}}
actor gore_bloodmistY_small:gore_bloodmistY{
	scale 0.18
	alpha 0.4
	states{
	spawn:
		TNT1 A 0 NoDelay {A_SetUserVar(user_hold,15);
			A_SetUserVarFloat(user_fadeamt,0.02);}
		Goto Super::Spawn+1}}
actor gore_fleshbit{
	mass 1
	speed 7
	radius 2
	height 2
	scale 0.6
	gravity 0.5
	+MISSILE
	+FLOORCLIP
	+NOTELEPORT
	+FORCEXYBILLBOARD
	states{
	spawn:
		FBLD ABCD 1 NoDelay A_SpawnItemEx("blood_spray",0,0,0,random(-2,2),random(-2,2),random(-2,2),random(0,360),SXF_TRANSFERTRANSLATION)
		loop
	death:
		TNT1 A 0 A_SpawnItemEx("gore_floorblood",0,0,0,0,0,0,0,SXF_TRANSFERTRANSLATION)
		stop}}
actor gore_fleshbitY:gore_fleshbit{translation "176:191=[255,215,0]:[78,66,0]","32:47=[255,215,0]:[78,66,0]"}
actor gore_floorblood:floor_blood{scale 0.9}
actor gib_spawner{
	speed 4
	states{
	spawn:
		TNT1 A 0 NoDelay A_SpawnItemEx("Gib1",0,0,0,random(-3,3),random(-3,3),random(6,9),random(1,360),SXF_TRANSFERTRANSLATION|128)
		stop}}
actor gib_spawnerY:gib_spawner{translation "176:191=[255,215,0]:[78,66,0]","32:47=[255,215,0]:[78,66,0]" }
actor Gib1{
	radius 4
	height 4
	mass 1
	scale 0.8
	gravity 0.7
	+MISSILE
	+FLOORCLIP
	+NOTELEPORT
	states{
	spawn:
		TNT1 A 0 NoDelay A_Jump(256,1,2,3,4,5,6,7,8)
		GIB1 A 0 A_Jump(256,8)
		GIB2 A 0 A_Jump(256,7)
		GIB3 A 0 A_Jump(256,6)
		GIB4 A 0 A_Jump(256,5)
		GIB5 A 0 A_Jump(256,4)
		GIB6 A 0 A_Jump(256,3)
		GIB7 A 0 A_Jump(256,2)
		GIB8 A 0
		"####" "#" 1 A_SpawnItemEx("blood_spray",0,0,0,random(-2,2),random(-2,2),random(-2,2),random(0,360),SXF_TRANSFERTRANSLATION)
		loop
	death:
		"####" "#" 0 A_Gravity
		"####" "#" -1
		stop}}
actor gib_bloodtrail{
	mass 1
	radius 1
	height 1
	+FORCEXYBILLBOARD
	+NOINTERACTION
	scale 1
	states{
	spawn:
		BTRL ABCDABCD 1 A_SpawnItemEx("blood_spray",0,0,0,random(-2,2),random(-2,2),random(-2,2),random(0,360),SXF_TRANSFERTRANSLATION)
		stop}}