ACTOR Rocket2
{
	Radius 10
	Height 8
	Speed 45
	Damage 20
	Decal "Scorch"
	Projectile
	Gravity 1.0
	SeeSound "none"
	//DeathSound "weapons/launcher/hit"
	Obituary "$OB_MPROCKET"
	+FORCEXYBILLBOARD
	States
	{
	Spawn:
		MSLE A 1 Bright
		Loop
	Death:
		TNT1 A 0 A_Explode
		TNT1 A 0 A_PlaySound("barrel/explode", CHAN_AUTO, 1, 0, 0.6)
		TNT1 A 0 Radius_Quake(2, 8, 0, 7, 0)
		FLXP ABCDEFGH 1 Bright
		TNT1 A 0 A_PlaySound("rocket/distexp",6,0.75,0,ATTN_NONE)
		FLXP IJKLMNOPQRSTUVWXYZ 1 Bright
		Stop
	}
}


Actor Grenade2 : Grenade 
{
	Decal "Scorch"
	BounceSound "weapons/grenade/bounce"
	//DeathSound "weapons/grenade/hit"
	-GRENADETRAIL
	-ROCKETTRAIL
	+CANBOUNCEWATER
	States
	{
	Death:
		TNT1 A 0 A_Explode
		TNT1 A 0 A_PlaySound("weapons/grenade/hit", CHAN_AUTO, 1, 0, 0.8)
		TNT1 A 0 A_ChangeFlag("NOGRAVITY", 1)
		TNT1 A 0 Radius_Quake(1, 6, 0, 7, 0)
		HELX ABCD 2 Bright
		TNT1 A 0 A_PlaySound("rocket/distexp",6,0.45,0,ATTN_NONE)
		HELX EFG 2 Bright
		HELX HIJ 3
		Stop
	}
}

ACTOR Plasma : PlasmaBall
{
	Scale 0.8
	Speed 40
	Damage 8
	Projectile
	RenderStyle Add
	Alpha 0.75
	SeeSound "none"
	DeathSound "weapons/plasmad/explode"
	Decal PlasmaScorch
	-NOTELEPORT
	+RANDOMIZE
	States
	{
	Spawn:
		PLZS AB 6 Bright
		Loop
	Death:
		TNT1 A 0 A_CustomMissile("PlasmaSmoke", 1, 0, random (0, 360), 2, random (0, 160))
		PLZE ABCDE 4 Bright
		Stop
	}
}

ACTOR BulletArmorSpark
{
	Health 4
	radius 3
	height 6
	speed .1
	RenderStyle ADD
	Alpha		1
	Scale 0.4
	Mass		0
	+missile
	+doombounce
	+FLOORCLIP
	+DONTSPLASH
	+NOTELEPORT
	States
	{
	Spawn:
		PUFF A 1 BRIGHT A_Fadeout(0.05)
		Loop
	}
}

ACTOR PlayerBubble : BulletArmorSpark
{
	+FORCEXYBILLBOARD
	States
	{
		Spawn:
		BUBL AAAABBBB 1
		Stop
	}
}
