*temp blockthis false
*temp rotation 0
*temp hadessituation "default"
*set touching false
*if (hermes_mutualconfess)
	*set hermes_romance true
*if (hekate_mutualconfess)
	*set hekate_romance true

Several days later, you awake to what can only be described as a disturbance. Not a physical one, or at least not the kind that's directly outside your door, obvious and tangible. 

Rather, it's a disturbance in your sense of how the world around you [i]is[/i]. What the Underworld is [i]like[/i]. 

There are few things you imagine could affect such a fundamental thing, but one of them is likely the presence of a powerful deity who does not usually occupy this place. 

And, once you're looking for something like that, you recognize the feel of your mother's magic immediately. 
*page_break
You are not, therefore, surprised at all when there's a knock at your door. You can tell it's Daeira rather than Demeter, which makes sense—your mother probably wouldn't be able to find you unless someone told her where to look. 

"${name}. You've probably noticed by now, but—may I come in?"

Stepping aside to admit them, you expel a breath. 

*if (humorous > serious)
	"That was quicker than I thought she'd be, honestly," you remark lightly. "I suppose Hermes must have been back to Olympus recently." 
*if not (humorous > serious)
	"I wasn't expecting her so soon," you admit, eyes narrowing in thought. "Did Hermes go back to Olympus recently?"

"Yesterday evening," Daeria replies, shaking their head. "She bade him stay and guide her down this morning. We've had little time to prepare. Fortunately, we'd rather expected that would be the case as soon as she received the news."

*if (demeterstatus = "cutoff")
	They pause, brow crinkling. 
	
	*if (cold > warm)
		"Just say it, Daeira," you urge, shaking your head. "There is no need to coddle me."
		
		"Of course not," they agree promptly. 
	*if not (cold > warm)
		"You can tell me," you urge, offering a wry half-smile. "You have to anyway, right?"
		
		"I suppose so," they agree, dipping their chin. 
	"So… yes. As you likely expected, she is asking to see you."
*if ((demeterstatus != "cutoff") and (demeterstatus != "open"))
	They pause, taking in a breath and studying you for a moment. 
	
	*if (cold > warm)
		"You can say it," you inform them flatly, shaking your head. "It's not exactly a surprise."
		
		"As you say," they agree, pressing their lips together. 
	*if not (cold > warm)
		"It's all right," you urge, offering a wry half-smile. "You can tell me." 
		
		"As you say," they murmur, pressing their lips together.
	"It's… yes. As you seem to have expected, she is asking to see you first."
*if (demeterstatus = "open")
	They clear their throat. "As you may have expected, she is asking to see you first." 

That is indeed exactly what you anticipated would be her first order of business upon arrival. She is likely to want to hear whatever you know from your own mouth, rather than with any intermediaries in the way. 

And, well, to see you, regardless. 

*fake_choice
	*if (demeterstatus != "open") 
		#"Please inform my mother that I have no wish to see her. She is permitted here for other business, and I will have nothing to do with her stay." 
			"Please inform my mother that I have no wish to see her. She is permitted here for other business, and I will have nothing to do with her stay." You don't know any way to be clearer about things than that. 
			
			*if (demeterstatus = "cutoff")
				You have severed your ties to her, and you intend for the parting to be either permanent or at least of a substantial duration. A few months lacking her interference in your life is not nearly enough to begin to repair all the damage she's done to it. 
			*if (demeterstatus = "letters")
				You put a boundary down the last time you saw one another: until you were ready for something else, your only communication would be through letters. You aren't ready to change the placement of that boundary, regardless of the circumstances. A few months just isn't going to cut it.
			*if (demeterstatus = "thinking")
				You put a boundary down last time you saw one another: you were now in control of how much contact the two of you have, and you needed time to figure out just how much contact that would be. A few months is not enough time for you to have firmed your opinion about what to do going forward, and you are not yet ready to see her in person. 
			
			Daeira nods immediately. "I will convey your answer," they reply. "And, do not worry. In the unlikely event she tries to press the point, the others are prepared to handle it. If you don't want to see her, we'll make sure it doesn't happen." 
			
			That is, admittedly, reassuring. You think Demeter has learned her lesson about 'pressing the point,' so to speak. And there is no reason for her to be as desperate in her concern for your safety as she was back then. So there's no reason to anticipate her forcing her presence on you. 
			
			But it is still nice to know that if she [i]tried[/i], she wouldn't succeed.
			*goto iasionsolo
	#"Please tell her to give me a few minutes to make myself ready, and I'll join her presently."
		"Please tell her to give me a few minutes to make myself ready, and I'll join her presently." You only just woke, and you certainly aren't going to go running down the hall in your present state just to see her. But you [i]will[/i] see her. 

		*if (demeterstatus = "open")
			It hasn't been that long, really, since you did last. Just a few months. But still, a few months can [i]feel[/i] like an age, particularly when you don't yet have actual ages to your name. It will be good to see her in person, again, even if the occasion of her visit to the Underworld is rather graver than you would have liked.
		*if (demeterstatus = "thinking")
			You put a boundary down the last time you did: you were now in control of how much contact the two of you have, and you needed time to figure out just how much contact that would be. You're not entirely sure that a few months is enough to make a final or permanent decision, but these are extenuating circumstances, ones that concern you both, and you aren't going to force her to confront them on her own. 
		*if (demeterstatus = "letters")
			You put a boundary down the last time you saw one another: until you were ready for something else, your only communication would be through letters. You aren't entirely sure that a few months is enough to change your mind, but these are extenuating circumstances, ones that concern you both, and you aren't going to force her to confront them on her own. 
		*if (demeterstatus = "cutoff")
			You have severed your ties to her, and you intended for the parting to be either permanent or at least of a substantial duration. A few months lacking her interference in your life is not nearly enough to begin to repair all the damage she's done to it. And yet you recognize that these are extenuating circumstances. She is not here because she is attempting to make you change your mind or go against your wishes. She's here because of an unforeseen circumstance that involves you both, and you won't make her confront it on her own.
		*goto demeterfirst
	#"I... suppose you can tell her that I'll be there soon." 
		"I... suppose you can tell her that I'll be there soon." You're not exactly thrilled that things have worked out this way, and you're certainly not going to go running down the hall in your present state just to see her. But you [i]will[/i] see her. 

		*if (demeterstatus = "open")
			It hasn't been that long, really, since you did last. Just a few months. And you were certainly planning to see her again. Just… not quite yet. You're still settling into your life here, and to cross the wires like this because of an urgent situation rather than a considered decision makes things more awkward than they would otherwise be. 

			Still, you can handle it. You'll need to.
		*if (demeterstatus = "thinking")
			You put a boundary down the last time you did: you were now in control of how much contact the two of you have, and you needed time to figure out just how much contact that would be. You're not entirely sure that a few months is enough to make a final or permanent decision, but these are extenuating circumstances, ones that concern you both, and you aren't going to force her to confront them on her own. 

			But you don't have to be happy about it, either. 
		*if (demeterstatus = "letters")
			You put a boundary down the last time you saw one another: until you were ready for something else, your only communication would be through letters. You aren't entirely sure that a few months is enough to change your mind, but these are extenuating circumstances, ones that concern you both, and you aren't going to force her to confront them on her own. 

			But you don't have to be happy about it, either.
		*if (demeterstatus = "cutoff")
			You have severed your ties to her, and you intended for the parting to be either permanent or at least of a substantial duration. A few months lacking her interference in your life is not nearly enough to begin to repair all the damage she's done to it. And yet you recognize that these are extenuating circumstances. She is not here because she is attempting to make you change your mind or go against your wishes. She's here because of an unforeseen circumstance that involves you both, and you won't make her confront it on her own.

			But you don't have to be happy about it, either.
		*goto demeterfirst

*label demeterfirst
*page_break
*set demeter_sequel_1 true
For now, Daeira informs you, your mother is waiting in one of the several different general reception rooms the keep has, a place where there will be comfortable furniture and likely some form of refreshment and… not much else. The room itself isn't really meant for any purpose other than meeting people and talking in, so unsurprisingly none of them are all that striking, compared to personal chambers or even the common room. 

Still, the guest waiting for you this time is plenty [i]striking[/i] on her own.

Daeira turns a sharp left, stopping at the first door down the new hallway, knocking politely a couple of times. "Lady Demeter, my ${lord} ${name} is here." The formality is almost exaggerated, from someone who routinely calls you comfortably by your first name, but you know why they're doing this. 

They're familiar enough with Olympus to understand that there, a nymph like themself would almost never use the name of a deity. Even your mother's own assistant, Antheia, refers to her as 'Lady Demeter.'

You don't know if your mother would think them [i]rude[/i] for calling you by name alone, but they probably don't want to risk offending her. 

"Of course. Please come in." You detect no strain or anxiety in your mother's voice, but you wouldn't. Not if she could help it. 
*page_break
Daeira steps aside, allowing you to enter, then dips their chin. "Please summon me if you need anything," they say quietly, and then they disappear. 

Your mother looks… exactly as you remember her, of course. She's never once changed, not in all the time you've been alive. She does not display the youth some deities prefer, but she isn't touched more than the slightest bit by age, either. Her appearance has always been immaculate, from the tidy piling of her curls atop her head to the perfect placement of the fibula at her shoulder, which allows the rest of her garments to drape just so, an emerald-green cloak resting lightly over her back and partially concealing the pearl-white garment beneath, its golden meander less geometric and more organic in shape, modeled after spiraling vines and grain stalks. The polished golden laurels nestled in her curls sit easily. 

And yet, when she stands, it's with a sharpness you're unused to seeing from her, the first sign that she is not as relaxed here as she appears to be. 

She looks, you have to admit, very out of place, nearly glowing against the muted backdrop of the Underworld, as if she contains her own light, her own colors, neither of which will be convinced to blend with their surroundings even slightly. Like someone cut out a piece of Olympus itself, and transplanted her here.

*if (demeterstatus = "open")
	"${name}," she murmurs, her tone warm and your name swiftly followed by a smile. 
	
	*if (touch2 = "allowed")
		She sweeps forward, winding her arms around you in a full embrace, fingers gently brushing the nape of your neck and the other hand resting at the middle of your back. 
		
		You return the hug, but she doesn't keep you too long, her grip loosening and allowing her to step back to arms' length. 
	*if (touch2 != "allowed")
		She sweeps forward, stopping about arms' length away from you and studying you intently, eyes moving from your face to your limbs to your feet and back again, as if by making such an examination she might discern your health. 
		
		Of course, she might, if she's also using her magic. She [i]is[/i] a life deity, after all, one with a great command of her abilities. 
*if (demeterstatus = "thinking")
	"${name}," she murmurs, her tone warm, but perhaps a touch of reserve in it as well. She smiles, almost hesitantly, and steps forward, stopping about arms' length away from you and studying you intently, eyes moving from your face to your limbs to your feet and back again, as if by making such an examination she might discern your health. 
		
	Of course, she might, if she's also using her magic. She [i]is[/i] a life deity, after all, one with a great command of her abilities. 
*if (demeterstatus = "letters")
	"${name}," she murmurs, her tone reserved, but not without a touch of warmth, as well. She smiles, almost hesitantly, and steps forward, stopping about arms' length away from you and studying you intently, eyes moving from your face to your limbs to your feet and back again, as if by making such an examination she might discern your health. 
		
	Of course, she might, if she's also using her magic. She [i]is[/i] a life deity, after all, one with a great command of her abilities. 
*if (demeterstatus = "cutoff")
	"${name}," she murmurs, her tone cautious. She smiles, almost hesitantly, and steps forward, stopping about twice arms' length away from you and studying you intently, eyes moving from your face to your limbs to your feet and back again, as if by making such an examination she might discern your health. 
		
	Of course, she might, if she's also using her magic. She [i]is[/i] a life deity, after all, one with a great command of her abilities. 

"I am glad to see you are well."

*fake_choice
	*if ((demeterstatus = "open") and (touch2 = "allowed"))
		#I pull her gently back into the hug. "I'm glad to see you too, mother."
			You pull her gently back into the hug. "I'm glad to see you too, mother." This time, you let the embrace last a little longer, and the lingering sense of tentativeness to her touch dissipates. You feel her pull in a deep breath, then release it gently, a tiny shake at the edges of it, and she presses her brow to your shoulder. 
			
			"I have missed you," she whispers, drawing back more slowly this time. Briefly, her hands gently bracket your face, and then she drops them away.
	*if not ((demeterstatus = "open") and (touch2 = "allowed"))
		#I close the distance and gently pull her into a hug. "I'm glad to see you, too, mother." 
			You close the distance and gently pull her into a hug. "I'm glad to see you, too, mother." 
			
			At first, there's a sense of tentativeness to her reciprocation, a hesitance, as if she's unsure whether this is really permitted. You suppose, given the circumstances, that makes sense, but you let the embrace last a little longer, and gradually, her hesitation dissipates. You feel her pull in a deep breath, then release it gently, a tiny shake at the edges of it, and she presses her brow to your shoulder. 
			
			"I have missed you," she whispers, drawing back more slowly this time. Briefly, her hands gently bracket your face, and then she drops them away.
	#I nod slowly. "Troubling circumstances aside, I am. I hope that you are, as well?"
		You nod slowly. "Troubling circumstances aside, I am. I hope that you are, as well?"
		
		Her lips press together, brow knitting for just a moment, but then it smooths out and she inclines her head graciously. "I am… as well as can be expected, I think. Things on Olympus rarely change." There's a certain tightness to her tone, but you get the impression it's the truth all the same. 
		
		A pause. "But… I've missed you."
		
		*if (demeterstatus = "open")
			She offers a tentative smile. "I say so just because the answer to your question felt incomplete without mentioning it. So please don't take me to be scolding you."
			
			You hadn't, but the reassurance is welcome nonetheless. 
		*if (demeterstatus != "open")
			She clears her throat. "I don't say that to get any specific response from you. I just… it was true, and the answer to your question felt incomplete without mentioning it. That is all." 
			
			Considering the circumstances, you can understand that much.
	#I incline my head deferentially. "Welcome to the Underworld, Lady Demeter. I hope your journey here was not too difficult."
		You incline your head deferentially. "Welcome to the Underworld, Lady Demeter. I hope your journey here was not too difficult." The formality of your tone alone is obvious, never mind the slightly-stilted diction you choose. 
		
		*if (demeterstatus = "open")
			It seems to catch your mother genuinely off-guard. "I… you needn't call me so, ${name}. I'm not sure what would prompt you to, but—I am, as I have been since the day of your birth, your mother before anything else, to you." 
			
			Her brow crinkles, as though something else is on her mind, but she shakes her head, apparently deciding to move past it without definitive answer for now. 
		*if (demeterstatus != "open")
			Your mother winces. "I… you needn't call me so, ${name}. I understand that my presence here is contrary to your wishes, and I do apologize for that. But the circumstances are… I wouldn't have come here if the circumstances weren't extraordinary. You understand that, right?"
			
			Her brow crinkles, as though something else is on her mind, but she shakes her head, apparently deciding to move past it without definitive answer for now. 
	#I offer a smile. "Hello, mother. It's been a while, hasn't it?"
		You offer a smile. "Hello, mother. It's been a while, hasn't it?" 
		
		It's nothing elaborate, as greetings go, but then, you don't see the need for that. It hasn't been [i]that[/i] long since you last had one another's company. 
		*if (demeterstatus = "open")
			And you'd always planned to have it again in due time. This is only a little sooner than expected. 
			
			Demeter returns the smile, her own easy and genuine. "It feels at once like too long and barely any time at all. I suppose both can be true at the same time." 
		*if (demeterstatus != "open")
			You hadn't planned to see her again any time soon, but you don't see the need to point [i]that[/i] out, either. She's not here as an intentional violation of your boundaries, but because of circumstances beyond the control of either of you. 
			
			Demeter returns the smile, only a touch awkwardly. "It has. I had… supposed it would be a while longer. I hope you will forgive me for being glad that it was not."			
	*if (demeterstatus != "open")
		#I feel my lips thinning into a line. "Allow me to be clear. You were not invited here, and I certainly did not want to see you at this point. I understand what the circumstances demand, but my boundaries remain as they were, outside of this one incident."
			You feel your lips thinning into a line. "Allow me to be clear. You were not invited here, and I certainly did not want to see you at this point. I understand what the circumstances demand, but my boundaries remain as they were, outside of this one incident."
			
			No part of you [i]wants[/i] to be doing this. If you have to, then so be it. But you need to make it clear exactly what's happening here. This isn't forgiveness. It isn't your boundaries changing. It is a necessary exception for an extraordinary circumstance. 
			
			Demeter visibly winces, if only for a moment before she composes herself once more. "I… understand," she replies. "And I will try to keep that in mind. Nevertheless, I hope you will not resent me for being pleased to see you. That much, I'm afraid I cannot help." 
			
			Her brow crinkles, as though something else is on her mind, but she shakes her head, apparently deciding to move past it without definitive answer for now. 
*page_break
Expelling a breath, she looks around the room, as if trying to find something to remark upon, but while intended primarily to be inoffensive, it's tasteful, and that leaves about nothing further to say. Instead, her eyes temporarily fix out the window, before returning to you. 

"This is my first time in the Underworld," she says, confirming something you already knew. "I can't—how can you tolerate it? The [i]emptiness[/i]." She shivers, and the reaction seems genuine. It's not just something she's putting on to insult the realm. 

You can even sort of understand it. As a life deity yourself, the Underworld [i]did[/i] feel strangely void when you first arrived. Sometimes it still does. Your mother of all people is even more accustomed to the hum of life around her than you are. 

*if (result = "underworld")
	"I just can't imagine enduring this feeling all the time."
*if ((result = "underworldmostly") or (result = "underworldmostlyouch"))
	"I just can't imagine enduring this feeling for most of the year."
*if ((result = "split") or (result = "evensplit"))
	"I just can't imagine enduring this feeling for half a year, every year."

*fake_choice
	#"You get used to it. The Underworld has its own flow of things, and when you start to pick up on that, it doesn't feel empty anymore."
		"You get used to it. The Underworld has its own flow of things, and when you start to pick up on that, it doesn't feel empty anymore." You had to learn to sense that 'flow,' as it were, and certainly having Erebus in your head probably makes some difference in your ability, but you think that even without it now you would not find the Underworld too disorienting or empty. 
		
		And there's something nice, about the subtle pulse of it all. 
		
		Demeter tilts her head, eyes narrowing slightly, then nods. "I see. Well, it seems logical that it would be different, for those accustomed to it. I suppose now I wonder what it will feel like to return to Olympus once matters here are concluded." 
		
		"It was a bit jarring, as I remember it." You huff softly through your nose. Perhaps, considering the manner of your return, 'jarring' could be considered an understatement, but certainly the other circumstances contributed, not just the basic difference between the worlds. 
		
		Demeter flinches, just a bit, and her expression becomes contrite.
	#"I actually like it. Sometimes, I felt overwhelmed by all the life on Olympus. Here it feels... quiet."
		"I actually like it. Sometimes, I felt overwhelmed by all the life on Olympus. Here it feels... quiet." You don't think you've ever explicitly [i]said that[/i] to your mother, but now seems as much the right time as any would be. Sometimes, Olympus was just… too much. You have to wonder if that feeling is completely foreign to the gods who live there, or if maybe some of them would actually understand. 
		
		"Overwhelmed…" Demeter tilts her head, eyes narrowing slightly. "I… suppose I can understand how that might be the case. I think most learn early how to prioritize their attention, but especially when one is young, perhaps it would be… difficult." 
		
		"Or if they aren't very good at that," you point out gently. "Some people just aren't. Sometimes I just perceive everything all at once and can't shut much of it out. Or that's how it feels, anyway." 
		
		Her brows crinkle. "I see. That… [i]would[/i] make a 'quieter' location preferable, at times, I'm sure." 
		
		You aren't certain she completely understands, but it's clear that she's making an effort to.
	#"Every realm is different. This one suits what it is, and the relative absence of life has never bothered me."
		"Every realm is different. This one suits what it is, and the relative absence of life has never bothered me." You don't [i]need[/i] the constant low-level stimulation of feeling life around you. It can be nice, sometimes, but 'nice' and 'necessary' are very different. There are plenty of other things about the Underworld you actively enjoy, so the balance of things means you quite like it here, for the most part. 
		
		Demeter tilts her head, eyes narrowing slightly. "Truly? Even given your domain, this does not put you ill-at-ease?" She sounds a little skeptical, but the question is not a trap. 
		
		"Truly," you reply, lifting your shoulders in a subtle shrug. "My domain isn't all I am, and I don't think it affects me all that deeply, to be honest." 
		
		She nods slowly. "I suppose… that makes sense. You have not built your entire life around it, the way I have. Perhaps I am mistaking which is really the cause of my unease here." 
		
		You aren't certain she completely understands, but it's clear that she's making an effort to.
	#"There are actually people here working on cultivating more life. They're doing reasonably well; this is already much improved on how it was when I first came here."
		"There are actually people here working on cultivating more life. They're doing reasonably well; this is already much improved on how it was when I first came here." Ascalaphus and the others are always working at it, you know, and while the Giant attack did result in some setbacks for the orchard, overall they're doing well. 
		
		*if (job = "gardener")
			You, of course, have something to do with that, and they're always quick to give you most of the credit, but much of the hard work involved is theirs. 
		*if not (job = "gardener")
			You don't see or involve yourself with too much of it, but the elderly satyr has claimed that your mere presence in the realm is a serious aid to their activities. 
		
		"Truly?" Demeter seems intrigued by the information; not exactly the reaction you expected her to have. "I had heard some plants managed to grow down here, but I wasn't aware there was an active effort at cultivation."
		
		*if (job = "gardener")
			You nod. "I'm actually helping. The other three really have most of the technical expertise, but I have abilities that suit, so together we're making progress, yes." 
			
			"Hmm." Demeter clears her throat. "That is… I am pleased to hear that. It seems a most worthy endeavor."
		*if not (job = "gardener")
			You nod. "I don't know that much about it, but I guess it's easier to do because I'm living here, or something like that." 
			
			Demeter looks thoughtful for a moment. "…Perhaps that makes sense."
		
		Shaking her head a bit, she refocuses the conversation. 
	#"It really bothered me at first, too. I needed there to be more... [i]noise[/i], almost. But I've learned to sense more, and that's helped."
		"It really bothered me at first, too. I needed there to be more... [i]noise[/i], almost. But I've learned to sense more, and that's helped." The emptiness had almost [i]itched[/i], but that was before you learned to feel all the ways the Underworld wasn't [i]empty[/i] at all. 
		
		Demeter tilts her head, eyes narrowing slightly. "Truly? Even given your domain, this does not put you ill-at-ease any longer?" She sounds a little skeptical, but the question is not a trap. 
		
		"Truly," you reply, lifting your shoulders in a subtle shrug. "My domain isn't all I am, and I don't think it affects me all that deeply, to be honest. More to the point, I think it's different, being a resident here instead of a guest. There's… more to it, so it's not uncomfortable anymore." 
		
		She nods slowly. "I suppose… that makes sense. You have not built your entire life around it, the way I have. Perhaps I am mistaking which is really the cause of my unease here." 
		
		You aren't certain she completely understands, but it's clear that she's making an effort to.
	#"Fortunately, you don't have to imagine that. It was the choice I made, and I am content with it. That's all."
		"Fortunately, you don't have to imagine that. It was the choice I made, and I am content with it. That's all." She doesn't need to understand you. Only to accept that your experience is not identical to hers. You also rather wish she would get to the point instead of trying to make conversation, but Demeter goes at Demeter's pace, always. 
		
		The only time you've seen her do anything else was during the farcical 'trial' after your return to Olympus, and at that point it was clear that [i]everyone[/i] had to move in step with Zeus, whether they wanted to or not. 
		
		Her lips crimp as she presses them together, but she nods slowly. "I suppose… you are right."
*page_break
Demeter expels the quiet remnants of a breath. "Broader location notwithstanding," she begins, wearing the smallest of frowns, "this may be something of a long conversation. I don't suppose you can think of anywhere more comfortable we might have it?"

*fake_choice
	*if not (tag_nogarden)
		#"Let's go to my garden."
			*set talk "garden"
			"Let's go to my garden." It's private enough for present purposes, and you have a feeling your mother might be academically interested in the logistics of maintaining such a space in the Underworld. 
			
			Sure enough, her brows tick upwards, just for a moment, which you've long learned means she's curious. Opening the door, you head out towards it. 
			
			"How long have you had it?" she asks. 
			
			"It was offered to me shortly after I arrived," you explain. "Or, well, the courtyard it's in was. There weren't any plants involved at the time." 
			
			The two of you pass through the arch into your garden, and your mother examines her surroundings with keen interest. 
			*if ((gardenstate = "great") or (gardenstate = "good"))
				"It has come out impressively well, considering the environs," she says, crouching to examine some of the plants, shifting a patch of ground cover aside to have a proper look at the roots, heedless of the dirt at her hem. 
			*if ((gardenstate = "fair") or (gardenstate = "poor"))
				"You are struggling with the environs, no doubt," she says, crouching to examine some of the plants, shifting a patch of ground cover aside to have a proper look at the roots, heedless of the dirt at her hem. "But it is interesting that anything is growing at all." 
			
			Adjusting them again so they're properly housed in the soil, she stands, turning a circle. 
			*if (((garden1 = "veggies") or (garden2 = "veggies")) or (garden3 = "veggies"))
				Her eyes fall upon your vegetable patch, and her lips turn up into a smile. "I see you're using coplanting techniques. I think they suit such an environment. Any advantage you can get, no?"
				
				You dip your chin slightly. "I thought that, given the relatively low soil nutrition, coplanting and compost were going to be my best chances at making it work." 
				
				"Very wise." 
				*goto endgardencomment
			*elseif (((garden1 = "herbs") or (garden2 = "herbs")) or (garden3 = "herbs"))
				Her eyes fall upon your herb patch, and her lips turn up into a smile. "Herbs aren't a bad choice. They can get by with much less than some other plants. They suit such an environment. Any advantage you can get, no?"
				
				You dip your chin slightly. "I thought that, given the relatively low soil nutrition, plant choice and compost were going to be my best chances at making it work." 
				
				"Very wise." 
				*goto endgardencomment
			*else
				Her eyes seem to seek something in particular, but you don't think she finds it. "No vegetables or herbs?" she asks. 
				
				You sort of understand why; her gardens are [i]mostly[/i] plants of that kind, and those are the ones you first learned to grow. 
				
				"I decided I wanted plants that were a little different," you reply. "A little more ornamental, for one." 
				
				"It does look pretty," she concedes. "Well laid-out."
				*goto endgardencomment
			
			*label endgardencomment
			She moves to take a seat on one of the scattered benches within the space, and you take up the spot next to her. 
	#"You can come to my chambers. They're this way."
		*set talk "room"
		"You can come to my chambers. They're this way." It's certainly private, and perhaps she'll feel a little more at ease in a space that is yours, rather than belonging to anyone else here, with whom she is far less familiar, to say the least. 
		
		"That would be much better. Thank you." 
		
		You head out towards them, Demeter falling into step beside you. "I have been appointed a place in the guest wing," she observes. "Yours is… not in the same direction."
		
		"No," you reply, shaking your head. "It was, until after I returned. Then it was moved from that wing to the main residence area."
		
		You reach your door and open it, gesturing for your mother to precede you inside. 
		
		*if (roomcolor = "dark")
			"It's rather dark in here," she observes, and you light the nearby torches with a flick of your hand. It's still not [i]bright[/i], but seeing is easy enough, like this.
		*if (roomcolor != "dark")
			"It's rather a brighter shade in here than outside," she remarks, and you light the nearby torches with a flick of your hand, further lightening the chamber. 
		
		Demeter takes the opportunity to look around, eyes falling on your collection of belongings and accumulated gifts without comment for a while. In fact it isn't until you've both settled yourself on the opposite couches across the low table that she says anything else at all.
		
		*if (room = "plants")
			"The plants are a lovely touch," she says, smiling slightly. "I suppose it's a great deal easier for them to survive in a place your presence pervades." 
			
			"It seems that way," you agree. "I don't have to do anything for them outside the norm, in any case."
		*if (room = "art")
			"You've amassed quite the tidy art collection," she observes, examining a tapestry for a moment. "I didn't know you liked it so much. Perhaps—" she pauses, shaking her head. "I'm getting rather ahead of myself, I think."
		*if (room = "plain")
			"You haven't… personalized it much," she observes. "If there's anything else you would like me to send you from Olympus, please let me know." She pauses, shaking her head. "But perhaps I am getting rather ahead of the conversation."
		*if (room = "simple")
			"It's rather unfussy, isn't it?" she observes, humming to herself. "There's nothing wrong with that, of course, but if you'd like me to send you anything from Olympus, please let me know." She pauses, shaking her head. "But perhaps I am getting rather ahead of the conversation."
		*if (room = "cozy")
			"This is rather comfortable, isn't it?" She hums softly, a faint smile pulling at her mouth. "It reminds me, of a cottage I used to have. But that's not what we're here to talk about, I suppose." 
		
		Taking a breath, Demeter releases it again. 
	#"I suppose we could use the common room. No one will be there at this time of day."
		*set talk "commonroom"
		"I suppose we could use the common room. No one will be there at this time of day." It's too early for anyone to be using it for the usual purposes of relaxation; despite the fact that most of them seldom sleep, the Underworld's residents tend to take whatever leisure time they get in what for you is the evening. Or at least, not in the morning. 
		
		"I suppose that will do, if you say so." Demeter sounds a little skeptical, but she falls into step beside you as you head out towards it nevertheless. "This is… a place where you socialize?"
		
		"I guess that's mostly what it's for. Everyone who isn't doing something else with dinner tends to eat it there around the same time, and people are in and out to do other things as well." But there's no need to explain all that when she can see it for herself; you come to a stop outside the door and gesture her through before you. 
		
		Demeter pauses several steps in, taking in her surroundings with a slightly-crinkled brow. It's reasonably tidy, at the moment. The place is never a mess. But it's not the exacting kind of orderly she prefers, either, and you know she doesn't fail to notice the slightly-haphazard placement of instruments, or the fact that one of the bookshelves is only about twenty-five percent books, the rest half-finished wire wrapping projects or loose sheet music or the odd child's toy or whatever else someone forgot last time they left. 
		
		Still, she doesn't comment, simply settling onto one of the fastidiously clean couches currently pulled out in front of the low table. You take the one across from her. 
		
		Taking a breath, Demeter releases it again.
	#"I have an office. We shouldn't be disturbed there."
		*set talk "office"
		"I have an office. We shouldn't be disturbed there."
		*if (job = "none")
			You don't really use it for anything, but it's not as though anything gets dusty around here, and you suppose this is as good an occasion as any to finally put it to a purpose. 
		*if ((job != "minister") and (job != "none"))
			Your particular job means you're not really in it that often, but nothing seems to collect dust inside the Keep in any event, and your regular absence means there will be minimal paperwork in need of moving for present purposes.
		*if (job = "minister")
			You work out of it rather often, and there are certainly some stacks of paperwork you'll need to move off the desk, but that's no great problem. 
		
		"Your office?" Your mother lifts a brow slightly, but falls into step beside you. 
		*if (job = "none")
			"I wasn't aware you had a job here." 
			
			"I don't," you reply, shaking your head. "But I have an office in case I want to use it for anything." You suppose everyone wanted you to feel included. Or perhaps it was just a matter of course; even Pyri has an office, though they're never in theirs, either. 
		*if ((job != "none") and (job != "minister"))
			"From what I understand, you don't have the sort of job here that requires an office?"
			
			"I don't, necessarily," you reply. "But my job comes with paperwork, and there are times where having a place to do that by myself is helpful, so I was given one." You aren't sure whether the others anticipated this or simply gave you one as a matter of course; even Pyri has an office, though they're never in it. 
		*if (job = "minister")
			"So this is… usually used for your ministerial duties?" 
			
			"Yes," you reply simply. "I conduct most of my work out of it, when I'm not out in the Underworld more broadly." You're not sure if anticipation of this need was why you were given one, or whether it was simply a matter of course; even Pyri has an office, though they're never in it. 
		
		You open the door, gesturing your mother inside ahead of you. It's a relatively simple place, with shelves for filing and a large desk, one chair behind and two in front. You move to the one behind, moving a few things before taking a seat, and she settles with only a little bit of apparent awkwardness behind the one on the left in front. 
		
		"I confess I am seldom on this side of one," she muses, brushing down her pristine peplos. She draws a breath, then releases it again.
	#"Actually, there's a courtyard that's for my use only, so let's go there."
		*set talk "courtyard"
		"Actually, there's a courtyard that's for my use only, so let's go there." You can call the door from just about anywhere now, so attuned have you become to the 'household' magic of the Keep itself. It's still a little strange that something as fundamental as space can be manipulated in such ways, but considering teleportation is almost [i]mundane[/i] here, you've managed to accept that this is just the way of things. 
		
		"Courtyard?" Demeter lifts a brow, leaning just a touch backwards when you call the door to the nearest empty wall and push it open. 
		
		"Courtyard," you confirm, stepping through and remaining in place until she's done the same, so as to dismiss the door behind her. 
		
		You watch her take it in, all the different features and details, running her fingers lightly over the carvings on a particular bench before she takes a seat upon it. "How did you come to be in possession of this?"
		
		"It was a gift," you reply, sitting on the edge of the quietly-burbling fountain across from her. "From the others." 
		
		"…I see." She appears to let that soak in for a moment, then draws a breath, releasing it slowly. 
*page_break
"I heard about Iasion's presence here yesterday evening," she says slowly, running her hands over the fabric at her thighs as if to brush away dirt that is not there. "I was… surprised. Of course, all mortals will eventually…" her words hitch, then trail off, and she looks away for a moment. 

"Well, they are mortal. In any event, I…" Another moment of hesitation.

*if not ((sequel_demeterletter = "inform") or (sequel_demeterletter = "invite"))
	"I was additionally surprised to hear this from 
	*if (sequel_demeterletter = "iasion")
		Iasion himself, via Hermes, of course.
	*if (sequel_demeterletter = "hermes")
		Hermes. 
	I had rather thought… that you would be the first to inform me of something like this."
	
	*fake_choice
		*if (demeterstatus = "cutoff")
			#"We aren't communicating. I had no intention to change that. You got the news either way."
				"We aren't communicating. I had no intention to change that. You got the news either way." You will be firm about this as many times as you need to for her to understand. 
				
				Demeter's lips part, as though she aims to respond, but for a long moment, nothing comes out. In the end, she shakes her head. "I would have thought that circumstances this significant would be something of an exception," she says, a bit awkwardly. "After all, you're here now. Would a letter have been any more difficult than this?"
				
				"It doesn't matter what's difficult or not. I have chosen to be here. I chose not to write. Those are my decisions to make. You don't have to approve of them, but you don't have the right to make them for me." 
				
				"I—of course not," she says slowly. "I didn't mean to imply that I did. Only that… such news would have been a little easier to hear from you than anyone else." 
				
				But you don't yield, and she doesn't push further. 
		*if (demeterstatus != "cutoff")
			#"To be honest... I wasn't sure how to tell you. I didn't know whether you'd even care, actually."
				"To be honest... I wasn't sure how to tell you. I didn't know whether you'd even care, actually." You have heard his name, before. But you know that it is something very seldom talked about. There was one conversation, long ago in your youth, where your mother explained to you that your father was a human man, who lived in a different world and could not see you, but you were never able to figure out what her [i]feelings[/i] about all of it were.
				
				Demeter seems briefly taken aback, but then her expression eases into something more reflective. "I… see. Perhaps that makes sense. I have tried to be very careful, with information regarding him, lest I put him in danger." 
				
				She's quiet for a moment more.
		*if (sequel_demeterletter = "iasion")
			#"I considered it, but it seemed like his decision to make, and something you should hear from him, if he wanted to let you know."
				"I considered it, but it seemed like his decision to make, and something you should hear from him, if he wanted to let you know." You don't know anything, really, about what their relationship was like, and even less about what it would be like [i]now[/i]. Inadvertently revealing Iasion's business to someone else, even your mother, could have been overstepping, for all you know. 
				
				On her end, you know it was something seldom discussed. There was one conversation, long ago in your youth, where your mother explained to you that your father was a human man, who lived in a different world and could not see you, but you were never able to figure out what her [i]feelings[/i] about all of it were.
				
				Demeter seems briefly taken aback, but then her expression eases into something more reflective. "I… see. Perhaps that makes sense. You've hardly been given the chance to understand why things are as they are, and I suppose he could have changed a great deal. Mortals do, so very quickly." 
				
				She's quiet for a moment more. 
		#"Does it matter who told you? You know, now."
			"Does it matter who told you? You know, now." To your mind, there's no need to give this more weight than it deserves. There are other, much more pressing matters at hand than whether you bothered to put ink to paper or let someone else take care of things. 
			
			"It… does, somewhat," Demeter replies slowly. "It's just… such news would have been a little easier to hear from you than anyone else." 
			
			You suppose you can see her point, to an extent, but you doubt the way it [i]was[/i] conveyed to her was all that harsh. You're not sure you would have been any gentler with it. 
			
			"I'll keep that in mind," you reply, though you don't know if it will ever again be relevant. 
			
			She nods, but she's quiet for a moment more. 
		#"I'm sorry. It's all been so much for me to figure out how to handle; I just didn't know what to do."
			"I'm sorry. It's all been so much for me to figure out how to handle; I just didn't know what to do." The last thing you wanted to do was make her feel bad, but how were you meant to put something like that to paper in any way that might be even remotely gentle? Might take some of the force out of the blow, if indeed it was a blow at all? There's just so much context you don't have, and it left you unsure what to say or how to say it. 
			
			Demeter's expression softens. "Of course," she murmurs. "My intention isn't to scold you, ${name}. I'm sorry if I've given you something else to worry about. No doubt it all came as quite the… shock." 
			
			She's quiet for a moment more. 
	*page_break
"I suppose the obvious thing to ask is… have you met him? Your father?" Her brow crinkles slightly as she meets your eyes, and something in her eyes is almost [i]pained[/i], as if the sheer volume of the questions that must be behind that one are almost too much for her to contain comfortably. 

*fake_choice
	*if (met_iasion)
		#"So... he [i]is[/i] my father? He thought so, and seemed to be genuine, but I wasn't certain."
			"So... he [i]is[/i] my father? He thought so, and seemed to be genuine, but I wasn't certain." 
			
			Demeter takes in a soft breath, then nods. "He is," she replies quietly. "I know there are other men named Iasion, but the truth is… some part of me felt it, when he died. Even before anyone let me know, I just thought… something was wrong." 
			
			She shakes her head, and huffs. "And then the day after, Hera suddenly wanted to visit. The best diviner on Olympus comes to my home, and for once there are no arguments? I didn't know what had caused it, but I knew it must be something of great import to me, and there are only three real possibilities, for that. Two, since I knew Hestia was fine."
			
			The look she gives you is significant. 
	*if (met_iasion)
		#"I did, not too long ago. He asked for me, actually, when he heard a child of yours lived here."
			"I did, not too long ago. He asked for me, actually, when he heard a child of yours lived here."
			
			Demeter takes in a soft breath, and then nods. "That would make sense. He was always very clever. He must have known I was hiding something when we stopped meeting." Taking hold of a curl, she tucks it carefully into the rest, her lips turning down into a frown. 
			
			"I know there are other men named Iasion, but the truth is… some part of me felt it, when he died. Even before anyone let me know, I just thought… something was wrong. Something important, and there are only three real possibilities, for that. Two, since I knew Hestia was fine."
			
			The look she gives you is significant. 
	*if (met_iasion)
		#"I have, though... I'm not sure how good an idea it was. He may forget it soon anyway."
			"I have, though... I'm not sure how good an idea it was. He may forget it soon anyway."
			
			"Forget? Ah, because of the Lethe." Demeter takes in a soft breath, then shakes her head. "I have difficulty believing someone like Iasion has not distinguished himself enough to avoid that fate, at least for a time. But I can understand why you would worry, without knowing him as I do." 
			
			Taking hold of a curl, she tucks it carefully into the rest, her lips turning down into a frown. 
			
			"The truth is… some part of me felt it, when he died. Even before anyone let me know, I just thought… something was wrong. Something important, and there are only three real possibilities, for that. Two, since I knew Hestia was fine."
			
			The look she gives you is significant. 
	*if (met_iasion)
		#"Yes. It was... something I felt I had to do. I'm still not sure I wanted to."
			"Yes. It was... something I felt I had to do. I'm still not sure I wanted to."
			
			Demeter takes in a soft breath. "I worry that is my fault," she murmurs. "I spoke of him so little, and never made my feelings clear. What are you to think of a man who is never present? Who cannot live with you, or even speak with you over distance? I wish things had been some other way—he is a man worth knowing, your father, and I find that true of relatively few people." 
			
			Taking hold of a curl, she tucks it carefully into the rest, her lips turning down into a frown. 
			
			"The truth is… some part of me felt it, when he died. Even before anyone let me know, I just thought… something was wrong. Something important, and there are only three real possibilities, for that. Two, since I knew Hestia was fine."
			
			The look she gives you is significant. 
	*if not (met_iasion)
		#"No, I—I couldn't bear the thought of meeting him just to be forgotten."
			"No, I—I couldn't bear the thought of meeting him just to be forgotten."
			
			"Forgotten? Ah, because of the Lethe." Demeter takes in a soft breath, then shakes her head. "I have difficulty believing someone like Iasion has not distinguished himself enough to avoid that fate, at least for a time. But I can understand why you would worry, without knowing him as I do." 
			
			Taking hold of a curl, she tucks it carefully into the rest, her lips turning down into a frown. 
			
			"The truth is… some part of me felt it, when he died. Even before anyone let me know, I just thought… something was wrong. Something important, and there are only three real possibilities, for that. Two, since I knew Hestia was fine."
			
			The look she gives you is significant. 
	*if ((met_iasion= false) and (iasion_changedmind))
		#"I haven't, yet. When I first heard he was looking for me, I wasn't sure I could bear meeting him just to be forgotten. But, I've decided more recently that I want to try."
			"I haven't, yet. When I first heard he was looking for me, I wasn't sure I could bear meeting him just to be forgotten. But, I've decided more recently that I want to try."
			
			"Forgotten? Ah, because of the Lethe." Demeter takes in a soft breath, then shakes her head. "I have difficulty believing someone like Iasion has not distinguished himself enough to avoid that fate, at least for a time. But I can understand why you would worry, without knowing him as I do. Still… I am glad you have changed your mind—he is a man worth knowing, your father, and I find that true of relatively few people." 
			
			Taking hold of a curl, she tucks it carefully into the rest, her lips turning down into a frown. 
			
			"The truth is… some part of me felt it, when he died. Even before anyone let me know, I just thought… something was wrong. Something important, and there are only three real possibilities, for that. Two, since I knew Hestia was fine."
			
			The look she gives you is significant. 
	*if not (met_iasion)
		#"I haven't. I'm still trying to decide whether I should."
			"I haven't. I'm still trying to decide whether I should." 
			
			Demeter takes in a soft breath. "I worry that is my fault," she murmurs. "I spoke of him so little, and never made my feelings clear. What are you to think of someone who is never present? Who cannot live with you, or even speak with you over distance? I wish things had been some other way—he is a man worth knowing, your father, and I find that true of relatively few people." 
			
			Taking hold of a curl, she tucks it carefully into the rest, her lips turning down into a frown. 
			
			"The truth is… some part of me felt it, when he died. Even before anyone let me know, I just thought… something was wrong. Something important, and there are only three real possibilities, for that. Two, since I knew Hestia was fine."
			
			The look she gives you is significant. 
	*if not (met_iasion)
		#"So he really is my father? I wasn't sure, and that made me reluctant."
			"So he really is my father? I wasn't sure, and that made me reluctant."
			
			Demeter takes in a soft breath, then nods. "He is," she replies quietly. "I know there are other men named Iasion, but the truth is… some part of me felt it, when he died. Even before anyone let me know, I just thought… something was wrong." 
			
			She shakes her head, and huffs. "And then the day after, Hera suddenly wanted to visit. The best diviner on Olympus comes to my home, and for once there are no arguments? I didn't know what had caused it, but I knew it must be something of great import to me, and there are only three real possibilities, for that. Two, since I knew Hestia was fine."
			
			The look she gives you is significant. 
*page_break
*if (talk = "garden")
	Your mother's eyes fall on the pond at the center of your garden, and her brow knits, but it's clear to you that she's really looking at something much farther away than the water, and probably 'far' in more than one sense.
*if (talk = "room")
	Your mother's eyes fall on the low table between you, and her brow knits, but it's clear to you that she's really looking at something much farther away than the wood, and probably 'far' in more than one sense.
*if (talk = "commonroom")
	Your mother's eyes fall on the slightly-scuffed low table between you, and her brow knits, but it's clear to you that she's really looking at something much farther away than the wood, and probably 'far' in more than one sense.
*if (talk = "office")
	Your mother's eyes fall on the edge of the desk between you, and her brow knits, but it's clear to you that she's really looking at something much farther away than the wood, and probably 'far' in more than one sense.
*if (talk = "courtyard")
	Your mother's eyes fall on the mosaic tiles between you, and her brow knits, but it's clear to you that she's really looking at something much farther away than the stone, and probably 'far' in more than one sense.

"In the interest of… honesty, I should say that, once events were brought to me, I found myself… unsure what to do, for several hours. Perhaps still." Her lips purse, and she lifts her eyes again, turning them to your face. 

"For me, the time since I last saw Iasion is… significant, but not very substantial, really. And yet for him, I know it has been much of a lifetime." Her hands clasp in her lap, knuckles paling slightly, and you think perhaps this is the most [i]visibly[/i] unsettled you've ever seen her. 

"As a fraction of my life, the time I've spent with him is… nearly nothing. And yet… the memories have a weight and a power that nothing so small is entitled to. Perhaps that is partly because of you, and yet I do not think your presence explains all of it." 

*label demetermenu03
*fake_choice
	*disable_reuse #"Have I ever reminded you of him?"
		"Have I ever reminded you of him?" You can't help but be curious, now that you know more. They say people inherit things from their parents beyond just aspects of their appearance, but you wonder if perhaps it's different, since you weren't also raised by him. 
		
		How much of him is in you, and did she ever think of him when she saw you?
		
		*if (humorous > serious)
			"Oh yes," she replies, a tiny huff escaping her nose. "In your sense of humor especially. Perhaps I found it most striking because it is the part of both of you that is most different from me. There's a lightness about you both,
			*if (serious > 2)
				but also in each of you, it is tempered by the knowledge of when to take things seriously."
			*if (serious <= 2)
				though I admit, I think perhaps in Iasion it is a bit more… tempered. By a sense of when to take things seriously." She raises an eyebrow, and you grin back at her. 
			*goto likehimend
		*elseif (selfless > selfcaring)
			"Most certainly," she replies with a nod. "You're both rather alike in your concern for others over yourselves. And if you're about to deny that you have such a quality, know that this, too, is a similarity you share." She smiles faintly. 
			
			*if (selfcaring > 0)
				"If anything, he's worse than you, and I do mean that as a criticism. I don't think I've ever seen him properly look after himself; not if there is anyone around him that needs anything at all." 
			*if (selfcaring = 0)
				"You're both terrible, and I do mean that as a criticism. I don't think I've ever seen either of you properly look after yourselves; not if there is anyone around you that needs anything at all."
			*goto likehimend
		*elseif (confident > unsure)
			"You do, sometimes," she replies with a nod. "There's something about your confidence that reminds me of him. Something about the way you handle the situations put before you, with an… ease. A self-possession, perhaps."
			
			*if (unsure > 0)
				She shakes her head. "It's not recklessness, fortunately, and so I think it has been of great benefit to your both."
			*if (unsure = 0)
				She shakes her head. "With you, I wonder if it isn't recklessness, sometimes, but I suppose things like that tend to get tempered a bit with age. Iasion was a bit more reckless than I would have liked, too." 
			*goto likehimend
		*elseif (forthright > reserved)
			"You do, sometimes," she replies with a nod. "There's a certain… directness to the both of you. A frankness, I suppose. One I find myself often avoiding for the sake of being politic." 
			
			*if (reserved > 0)
				She tilts her head. "Of course, you have your moments of reserve as well, as does he or anyone else, but I think you are more like one another than either of you is like me, in this respect."
			*if (reserved = 0)
				She tilts her head. "Of course, I doubt Iasion says everything on his mind all the time. He has since become a king, after all, and they seldom have such luxury, but when I knew him, he was nearly as blunt as you."
			*goto likehimend
		*elseif (warm > cold)
			Demeter presses her lips together. "I think so," she says after a moment. "There's a… a natural warmth to the both of you. An instinctive attachment to those around you, perhaps, that leads to genuine concern for them and investment in their well-being. I fear I am rather… detached, by comparison. Perhaps even cold."
			*goto likehimend
		*else
			Demeter presses her lips together. "In all sincerity? Very seldom. I have found that much more often, you remind me of myself. For better and for worse." Her expression becomes a little bit rueful, but in the end, she manages a small smile. 
			
			"That's not to say that there are never moments. But I suppose the parent you had was me, so it should not be surprising that I am also the one you turned out to be more similar to."
			*goto likehimend
		
		*label likehimend
		*line_break
		*line_break
		You didn't have a particular answer you were expecting, but something about the one you get is still surprising. Maybe it's just the insight she has? You're not sure you entirely expected to agree with Demeter about what you're like. 
		
		But then, maybe what she said was obvious. It's just a topic the two of you haven't broached often before. 
		*goto demetermenu03
	*disable_reuse #"Did you love him?"
		"Did you love him?" 
		
		It is, perhaps, a frank question, 
		*if (forthright > reserved)
			but you're not especially known for avoiding frankness. That applies just as much to conversations with your mother as with anyone else. Or at least, you tell yourself it should.
		*if not (forthright > reserved)
			and you're not precisely comfortable with those all the time. But it's hard to be indirect about something like this without risking getting an answer to the wrong query entirely, and you want to know the truth about [i]this[/i] one.
		
		Demeter doesn't seem overly surprised by it, her brow knitting as she looks down, for a moment, at her hands, before returning her gaze to you. 
		
		"I did," she replies. "It was… difficult to be sure, at first. To pry love apart from passion and identify each properly. For a while, I thought perhaps I was simply infatuated. But I did love him. I still do."
		
		It's hard, somehow, to imagine your mother either passionately in love [i]or[/i] struggling to identify her own emotions. It all seems much too messy for the person you know her to be. And yet, looking at her expression now, still the faintest bit creased in concern but for once something like [i]earnest[/i], you believe her.
		*goto demetermenu03
	*disable_reuse #"Did you expect that you'd have a child, when you were together?"
		"Did you expect that you'd have a child, when you were together?"
		
		It's hard to imagine your mother being caught off-guard by such a thing, but equally-difficult to suppose she intended to do so, with someone she then had no contact with and rarely spoke of to anyone. 
		
		She considers this question for a moment, head tilted. "Well… yes and no," she replies slowly, as if assembling the explanation even as it emerges. "At first, no, I did not anticipate that turn of events." She smiles slightly. "I was usually careful to place certain barriers, so that such a thing would not occur. "But… once, I was so caught up in things that I forgot." 
		
		She pauses, the tip of one thumb moving over the length of the other where her hands are clasped in her lap. "On the other hand, I knew as soon as it had happened. And… I made the decision to allow it. I can't say I'd ever thought of myself as the type of person who desired children, but I knew then that I wanted [i]that[/i] one. You." 
		
		Demeter offers you a wry smile. "I have never regretted that choice."
		*goto demetermenu03
	*disable_reuse #"Why haven't you seen him, since?"
		"Why haven't you seen him, since?" 
		
		She sighs, her head shaking just barely enough for you to catch the movement. "There were a lot of reasons," she confides. "Some of them more reasonable than others. The most important one was simple enough. If his identity became widely-known among the gods, if they were able to find him, his life might be in danger." 
		
		Her expression momentarily contorts in disgust. "At the time, Zeus was… pursuing me, to put it one way. I was not interested, and he took exception to that. But there is only so much he can do to another deity, particularly one with substantial power and influence, as I have. I could not risk his wrath falling upon Iasion." 
		
		Zeus. Somehow it doesn't even surprise you that he has a role to play in this story. 
		
		"Is that why he torments you?" 
		
		She presses her lips together. "It is certainly part of the reason. And, I'm sure, a part of the reason he used you to do so."
		*goto demetermenu03
	#"I see." 
		"I see." That is enough clarity on the matter for you, for now. You're surprised she's being so open about the matter, when she has previously refused to say almost anything about it, but you suppose this would be the time to do so. 
		
		There aren't many chances left. At least, not within a time frame that could reasonably affect things with Iasion himself. 
*page_break
"I am…" Demeter hesitates, shifting in her seat. "You will think this ridiculous, but now that I'm here, I actually think I'm a little afraid to meet him." Her voice is thin, thready, and a tiny bit incredulous. 

She shakes her head. "Imagine, me. Everything I have, everything I am. And still, at the mercy of what a mortal man thinks of me, after all this time. It's absurd."

*fake_choice
	#"I'm fairly sure love is like that, sometimes."
		"I'm fairly sure love is like that, sometimes." You clear your throat. It's not the matter with which you have the [i]most[/i] experience, and so it feels a little presumptive to say as much, but then again, there are all kinds of love, and the ones you [i]do[/i] know can be a bit… ridiculous, sometimes. In some ways. 
		
		"I suppose it is," she replies, wincing a little. "I certainly know my love for you has driven me to irrational ends, before. I like to think this isn't [i]quite[/i] the same, but… do let me know if I seem to be veering in an… unpalatable direction." 
		
		You suppose that if you notice such a thing, it won't be difficult to point it out. The last thing anyone needs is a similar incident to [i]that[/i], well-intentioned as it was. 
	#"I admit... it's definitely strange, to hear something like that from you."
		"I admit... it's definitely strange, to hear something like that from you." You've never thought of your mother as the type to take other people's opinions into such great account. She couldn't be, to continue opposing Zeus the way she does, even as unpopular as it makes her in some circles. 
		
		"Is it?" She winces slightly. "Actually I would have thought you were beginning to understand that irrational behavior in cases where close affinity is involved is… more a part of me than I would like." 
		
		When she puts it [i]that[/i] way, you suppose you can see it. 
	*if (tag_humansdislike)
		#"It does seem a bit... beneath you somehow. But I suppose he's not [i]entirely[/i] human."
			"It does seem a bit... beneath you somehow. But I suppose he's not [i]entirely[/i] human." Still, even thinking about a powerful goddess caring for the opinion of a single mortal is a little foreign. Particularly when that goddess is your mother, of all people, who has never once seemed to care what [i]anyone[/i] thinks of her. 
			
			Not even Zeus, with whom others spend a great deal of time currying favor.
			
			She winces a little. "That's not what I meant," she replies, brushing down the fabric over her legs again. "Humans are no worse or better than the gods. Just less powerful, and much more briefly-lived. Nevertheless, I suppose I take your point. It is strange of me. But then, I suppose I become strange in cases where close affinity is involved. More than I would like." 
			
			When she puts it [i]that[/i] way, you suppose you can see it.  Even if you don't understand why she feels 'close affinity' for someone so nearly human.
	#"See him or don't. It's none of my business." 
		"See him or don't. It's none of my business." You shake your head. She's talking to you as though you are going to be closely involved in the whole process, or have a stake in the outcome, but you don't. This is a matter that concerns her, and that's all. 
		
		Demeter's lips purse, but she nods nevertheless. "I suppose that is the only decision to be made about any of this ahead of time, yes."
*page_break
*if (talk = "garden")
	She looks around the garden once more, as if taking it in, and then stands, a certain stiffness to her spine that could as easily be nerves as resolution.
*if (talk = "room")
	She looks around your room once more, as if taking it in, and then stands, a certain stiffness to her spine that could as easily be nerves as resolution.
*if (talk = "commonroom")
	She looks around the common room once more, as if taking it in, and then stands, a certain stiffness to her spine that could as easily be nerves as resolution.
*if (talk = "office")
	She looks around the office once more, as if taking it in, and then stands, a certain stiffness to her spine that could as easily be nerves as resolution.
*if (talk = "courtyard")
	She looks around the courtyard once more, as if taking it in, and then stands, a certain stiffness to her spine that could as easily be nerves as resolution.

Than, she expels a quiet breath through her nose, meeting your eyes as you stand, too. 
*if (demeterstatus = "cutoff")
	"As much as it pains me that I cannot spend more time with you," she says carefully, seemingly well aware that such a comment might not please you, "I understand that I am welcome in the Underworld on a very provisional basis. I must not lose any more time doing things other than what I am meant to be doing, lest I cause offense… and so it is now time for me to meet Iasion."
*if ((demeterstatus = "letters") or (demeterstatus = "thinking"))
	"As much as it pains me that I cannot spend more time with you," she says carefully, seemingly well aware that such a comment might not please you, "I understand that I am welcome in the Underworld on a very provisional basis. And so I must hope that at some point in the future, there might be a less… urgent reason for me to be here. For now… it is time for me to meet Iasion."
*if (demeterstatus = "open")
	"As much as it pains me that I cannot spend more time with you," she says, offering a small smile, "I understand that this time, I am welcome in the Underworld on a very provisional basis. Perhaps, next time, there will be more notice, and I will not need to attend to urgent matters. For now… it is time for me to meet Iasion." 

You can see her throat shift subtly as she swallows, and for a moment, she closes her eyes. When she opens them again, any hint of nervousness has disappeared, and she looks as you have always seen her: proud, confident, collected. 

Still, when she turns to you, something in her expression softens. "Would you accompany me? I confess I am not sure if I will lose my nerve, otherwise."

*fake_choice
	#"If you think it will help, then I'll go with you."
		"If you think it will help, then I'll go with you." You can sort of understand feeling anxious about something like this, even if you've never been in the same position. 
		
		*if (demeterstatus != "open")
			Maybe you're not feeling as generous toward your mother as you might be were things better between you, but that doesn't mean you're going to turn her down in a circumstance like this. There is something genuine between them—you can tell that much. And, for both of their sakes, you want this part to go well.
		*if (demeterstatus = "open")
			There's no reason for you to refuse in the first place. Something genuine lies between them—you can tell that much. For both of their sakes, you want this part to go well.
		*goto iasiondemeter
	*if (met_iasion)
		#"Of course. I've been wanting to meet him again, anyway."
			"Of course. I've been wanting to meet him again, anyway." One meeting, you think, just isn't enough. It's the beginning of something, but certainly not an end. Whether your father ends up on the Isles or not… you want to know him better. 
			
			*if (demeterstatus != "open")
				And maybe you're not feeling as generous toward your mother as you might be were things better between you, but that doesn't mean you're going to turn her down in a circumstance like this, either. There is something genuine between them—you can tell that much. For both of their sakes, you want this part to go well.
			*if (demeterstatus = "open")
				And there's no reason for you to refuse her in the first place. Something genuine lies between them—you can tell that much. For both of their sakes, you want this part to go well.
			*goto iasiondemeter
	*if not (met_iasion)	
		#"I think you're giving me the courage to do this at least as much as I'm giving it to you, so yes."
			"I think you're giving me the courage to do this at least as much as I'm giving it to you, so yes." It's not clear to you how well you'd do at getting yourself to see him without your mother present. You want to meet him, at least, want to take that first step. Admittedly, it will be much easier with her beside you. 
			
			*if (demeterstatus != "open")
				And maybe you're not feeling as generous toward your mother as you might be were things better between you, but that doesn't mean you're going to turn her down in a circumstance like this, either. There seems to be something genuine between them—for both of their sakes, you want this part to go well.
			*if (demeterstatus = "open")
				And there's no reason for you to refuse her in the first place. Something genuine seems to lie between them—for both of their sakes, you want this part to go well.
			*goto iasiondemeter
	#"I really don't think you need me for that, but I'll accompany you nonetheless."
		"I really don't think you need me for that, but I'll accompany you nonetheless." You can't imagine that your mother would [i]actually[/i] lose her nerve in this situation, because you can't really imagine that happening in general. One thing she has always been is strong-willed, maybe more so than anyone else you've ever met. 
		
		Still, if she wants you to go, you'll go. 
		
		*if (demeterstatus != "open")
			Maybe you're not feeling as generous toward her as you might be were things better between you, but that doesn't mean you're going to turn her down in a circumstance like this, either. There seems to be something genuine between them—for both of their sakes, you want this part to go well.
		*if (demeterstatus = "open")
			There's no reason for you to refuse her in the first place. Something genuine seems to lie between them—for both of their sakes, you want this part to go well.
		*goto iasiondemeter
	#"I won't. Your time with him is your affair. I will see him on my own, later."
		"I won't. Your time with him is your affair. I will see him on my own, later." You have every intention of visiting Iasion
		*if (met_iasion)
			again,
		*if not (met_iasion)
			this time, 
		but you won't do it with Demeter. This is something they should sort out themselves, if there's anything to be sorted out. 
		
		*if (demeterstatus != "open")
			Just because you came to see her this time does not mean you intend to do the rest with her. You wanted information and confirmation, and now you have it. Your boundaries are still your boundaries, and she can act like it even while she's here. 
		*if (demeterstatus = "open")
			That kind of thing isn't something you should stand in the middle of, even if you are their child. You're an adult, after all, with your own inclinations towards each of them, and that would only further complicate matters. 
			
		Demeter's expression shutters, and when she nods, the motion is visibly not smooth. Still, as far as loss of composure goes, it's only that—only a little bump in things. 
		
		"Perhaps you have a point," she says softly, the words coming out half on a sigh. "In that case, I suppose I had best get to it." 
		
		She makes her exit, and you have little doubt she will be able to navigate as she needs to. If nothing else, others will help her get there. As for you—you'd best give it a few hours before making your own visit. Until then, perhaps you can find something to keep yourself distracted. 
		*goto iasionsolo
	*if ((met_iasion = false) and (iasion_changedmind = false))
		#"No. I don't desire to meet with him, least of all at the same time as you are reuniting."
			*set iasionstatus "cutoff"
			"No. I don't desire to meet with him, least of all at the same time as you are reuniting." You didn't want to in the first place, and nothing that's happened has changed your mind about this. Your mortal father is not someone you can bring yourself to want to interact with. Not at this stage. Perhaps things would have been different, if he weren't dead or you were still a child, but you find that, for you, the context is decisive. 
			
			There will be no meetings. Not between the two of you. 
			*if (demeterstatus != "open")
				And [i]certainly[/i] not between the three of you.
			*if (demeterstatus = "open")
				And certainly not at the same time as your mother is working out… whatever exactly it is that she needs to work out with him.
			
			Demeter's expression shutters, and when she nods, the motion is visibly not smooth. Still, as far as loss of composure goes, it's only that—only a little bump in things. 
		
			"I think… that is a shame," she says softly, the words coming out half on a sigh. "But I suppose it is not my place to force the issue. And so I had best be on my way."

			She makes her exit, and you have little doubt she will be able to navigate as she needs to. If nothing else, others will help her get there. As for you—hopefully your part in all of this is over, at the very least for the rest of today. You ought to find yourself something else to do.
			*goto ro_scenehub
		
*label iasionsolo
*page_break
*set iasion_sequel_2 true
*set iasion2 "solo"
*if (demeter_sequel_1)
	You make sure to give Demeter plenty of time to visit before you do the same. For multiple reasons, you think this might be for the best. From the others, you hear that she spends an awfully long period doing so—most of the day, in fact. 
	
	In light of this, you wait until the next to make your own appearance at the strange facsimile of a war camp where your father's spirit dwells. Dozens of other spirits move about, some drilling with weapons, others clustered around in groups socially, but it certainly yet has that atmosphere, and you wonder how long it will take everyone within to come to terms with the fact that they are dead. That there are no more enemies to fight. 
	
	Shaking your head, you head further in. 
	*if (met_iasion)
		You remember which tent is his, and it isn't difficult to find.
	*if not (met_iasion)
		You've not been within the camp before, but Hermes described his tent to you, and it's easy enough to find, being the largest in this particular cluster of them. 
	*goto scenebegins
*elseif (met_iasion)
	Though you've elected to visit Iasion again yourself, you opt to give Demeter plenty of time to do so first. For multiple reasons, you think this might be for the best. From the others, you hear that she spends an awfully long period doing so—most of the day, in fact. 
	
	In light of this, you wait until the next to make your own appearance at the strange facsimile of a war camp where your father's spirit dwells. Dozens of other spirits move about, some drilling with weapons, others clustered around in groups socially, but it certainly yet has that atmosphere, and you wonder how long it will take everyone within to come to terms with the fact that they are dead. That there are no more enemies to fight. 
	
	Shaking your head, you head further in. You remember which tent is his, and it isn't difficult to find.
	*goto scenebegins
*elseif (iasion_changedmind)
	Though you've elected to meet Iasion yourself, now, you opt to give Demeter plenty of time to visit him herself, first. For multiple reasons, you think this might be for the best. From the others, you hear that she spends an awfully long period doing so—most of the day, in fact. 
	
	In light of this, you wait until the next to make your own appearance at the strange facsimile of a war camp where your father's spirit dwells. Dozens of other spirits move about, some drilling with weapons, others clustered around in groups socially, but it certainly yet has that atmosphere, and you wonder how long it will take everyone within to come to terms with the fact that they are dead. That there are no more enemies to fight. It's as it was described to you by the others, but there's something uncanny about it, almost.
	
	Shaking your head, you head further in. You've not been within the camp before, obviously, but Hermes described Iasion's tent to you, and it's easy enough to find, being the largest of the lot in this particular cluster of them. 
	*goto scenebegins
*else
	You suppose the question of whether or not you want to see Iasion has been somewhat reopened by current developments. Though you have no intention of speaking with her about it, Demeter's presence certainly confirms that the man is your father. And yet you still feel that in some ways it wouldn't suit you to visit him, or develop any sort of relationship. 
	
	*fake_choice
		#And the new information changes nothing. I am simply not interested in speaking with him.
			*set iasionstatus "cutoff"
			There is no good reason you can think of to do such a thing. And at this point, you say that with all the information out that you can imagine being relevant, so there is no need to consider the question further. 
			*goto ro_scenehub
		#I can't help but be a little less firm in my refusal, now. I'll try visiting him once, just to see how it goes.
			You can't help but be a little less firm in your refusal, now. You've decided to try visiting him once, just to see how it goes.
			
			Of course, you make sure to give Demeter plenty of time to do so before you put in an appearance yourself. For multiple reasons, you think this might be for the best. From the others, you hear that she spends an awfully long period doing so—most of the day, in fact. 
	
			In light of this, you wait until the next to make your own appearance at the strange facsimile of a war camp where your father's spirit dwells. Dozens of other spirits move about, some drilling with weapons, others clustered around in groups socially, but it certainly yet has that atmosphere, and you wonder how long it will take everyone within to come to terms with the fact that they are dead. That there are no more enemies to fight. 

			Shaking your head, you head further in. 
			
			You've not been within the camp before, of course, but Hermes described the correct tent to you, and it's easy enough to find, being the largest of the lot in this particular cluster of them. 
			*goto scenebegins
*label scenebegins
*page_break
As it turns out, the man you're looking for is just emerging from the tent as you approach, face creased in thought. 

*if not (met_iasion)
	He's of middling height for a human, you think, perhaps a fraction taller than Hermes, and his posture, upright and steady, tells you he carries himself with a certain dignity. 
	*if (skintone = "light brown")
		The tone of his skin is a little deeper than yours, marked here and there with scars of lighter or darker hue.
	*if (skintone = "pale")
		The tone of his skin is almost as pale as yours, save a little touch of the sun, and marked here and there with white or pink scars.
	*if (skintone = "tan")
		The tone of his skin is a little more darkly-tanned than yours, most likely due to the sun, and marked here and there with white and pink scars. 
	*if (skintone = "tawny")
		The tone of his skin is tawny like yours, made just a little darker, perhaps, by the sun, and marked here and there with scars of lighter or deeper hue. 
	*if (skintone = "medium brown")
		The tone of his skin is similar to yours, perhaps a shade darker, and marked here and there with scars of lighter or deeper hue.
	*if (skintone = "dark brown")
		His skin is an even deeper brown than your own, by a shade or two, and marked here and there with scars of a lighter or darker hue. 
	*if (((hairtexture = "smooth") or (hairtexture = "coarse")) or (hairtexture = "wavy"))
		*set iasionhair "wavy"
		$!{haircolor} hair has gone nearly half-grey, and he wears it to the nape of his neck, where it sits, wavy and a bit disheveled, as though it's been pushed down by the plumed helmet tucked under one arm.  
	*if (hairtexture = "curly")
		*set iasionhair "curly"
		$!{haircolor} hair has gone nearly half-grey, and he wears it to the nape of his neck, where it sits, curly and a bit disheveled, as though it's been pushed down by the plumed helmet tucked under one arm.  
	*if ((hairtexture = "coily") or (hairtexture = "dense"))
		*set iasionhair "longrows"
		$!{haircolor} hair has gone nearly half-grey, and he wears it in neat, tight rows of braids against his scalp, the long ends of each gathered into a tail at his nape to trail down his back, perhaps in part to sit easier beneath the helmet tucked under one arm.
	
	His attention fixes on you immediately,  like he knows exactly where to put it. 
	*if (eyecolor = "green")
		"Your eyes," he murmurs, so softly you can't be sure if he meant you to hear. "They're just like…" 

		He closes his lips abruptly, but you know what he has to be referring to. You've been told often enough that the green color of your eyes is the exact same shade as your mother's. 
	*if (eyecolor != "green")
		"Your eyes," he murmurs, so softly you can't be sure if he meant you to hear. 

		He closes his lips abruptly, but being within a few feet of him, you have a guess about what he must be referring to. His eyes are the same shade of ${eyecolor} as your own, you're confident of that much.

	He shakes his head slightly. "I-I'm sorry. I'm saying useless things and getting rather ahead of myself."

	*fake_choice
		#@{convotoggle [☆]|} "Iasion, I presume?"
			*set humorous +1
			*set confident +1
			"Iasion, I presume?" You can't help a trickle of amusement entering your voice; something about his obvious fluster provokes it. Maybe it's the fact that the reaction is so…
			
			You aren't even sure what the right word is, but it means you can put your own reservations aside, just for the moment, and make light of the rather odd situation the both of you are in. 
			
			This, in turn, pulls a smile from him. "I'd ask how you guessed, but considering what just happened, I'm not sure I want to know. Don't know what I'd do if I had a reputation for being a scattered fool already."
		#"I don't think it's likely 'ahead' of much. You must know who I am."
			*set serious +1
			*set confident +1
			"I don't think it's likely 'ahead' of much. You must know who I am." By this point, it's surely obvious, regardless of resemblance or anything so unreliable as that. Demeter's already spoken to him, and you know at least a few of the others have met him as well. 
			
			"Well." He clears his throat, then smiles. It's an awkward expression, a tad sheepish, but genuine as far as you can tell. "It's coming on a bit strong, isn't it? To say something like that as soon as I lay eyes on you. Maybe even rude." 
			
			He inclines his head. "In that vein, please forgive me. I'd like to do this properly. Or at least, as close to it as I can manage."
		#"I—you—uh."
			*set unsure +1
			"I—you—uh."
			
			Certainly not what you'd [i]planned[/i] to say in this moment, though you can't remember just now if you'd planned anything in particular. Something about him standing right here, in the… well not [i]exactly[/i] 'the flesh' in the usual sense, but certainly close enough—
			
			"Yeah," he says, a small smile quirking his lips. "Me too, honestly." A huff of something close to laughter escapes his nose, and the color of his eyes seems suddenly much warmer.
		#I swallow thickly, nerves sticking my tongue to the roof of my mouth.
			*set unsure +1
			You swallow thickly, nerves sticking your tongue to the roof of your mouth. You can't remember just now what you'd planned to say here, or even if you'd planned to say anything in particular. Something about him standing right here, in the… well not [i]exactly[/i] 'the flesh' in the usual sense, but certainly close enough—
			
			"Yeah," he says, a small smile quirking his lips. "Me too, honestly." A huff of something close to laughter escapes his nose, and the color of his eyes seems suddenly much warmer.
	*page_break
	He gestures to the tent. Part of you wonders where the objects in the camp even came from; the dead don't typically bring anything with them to the Underworld save the payment for the ferry, in this part of the realm. Then again, you wouldn't be entirely surprised if the items were provided [i]for[/i] the spirits, because it's clear this is how these people are comfortable, for now. 

	Iasion pulls aside the tent flap, admitting you first.
	
	He files in himself after, closing the flap behind him and gesturing to where a moderately-sized table with several chairs is set up near the middle. "Please, have a seat."

	You get settled in one of the chairs, casting your glance around the plain room. It is more of a 'room' than you'd expected at the word 'tent,' but then this is quite a bit larger than you thought, too. 
	*if (tag_learned)
		There's an easy explanation for that, of course: this is a military commander's tent, designed for holding meetings and the like as well as the commander's living quarters in the field. It means Iasion is someone with relatively high status, whether he got that through a coincidence of his birth or through success in his military career, or both. 
	*if ((tag_learned = false) and (tag_unlearned = false))
		You believe you've heard of constructions like this, though—a large tent near a battlefield would probably belong to a commander or leader of some sort, so you can imagine the table might be for strategy meetings. It's just a guess, though, and you don't draw any solid conclusions from it. 
	*if (tag_unlearned)
		Then again, it's not like you know much about tents in general, or armies, or anything like that. For all you know, this is just what the Underworld was able to get for the people here, and doesn't correspond to anything about their previous lives at all.

	Iasion takes the seat across from you, hemming softly and placing his hands on the tabletop. 

	"I would like to apologize," he says, tone low-pitched and quiet. "For how… abrupt all this is. Even now, I have to keep reminding myself that this isn't how I would have wanted it to be. That I am dead, our time is limited, and everything has to be… compressed." His lips thin, paling a few shades as he purses them. 

	"In an ideal world, it would all be much more leisurely a process. I would ask you as many things about yourself as I could think of, and answer anything you could think to ask, and simply be glad of the fact that you were interested enough to do so. Now, though… I wonder if perhaps there are things you will simply want to know, that I will need to talk about all at once, while there is still time."

	He smiles, but there's an edge of bitterness to it.

	"I'm still trying to come to terms with my death, in truth. So I hope you will understand that this is not how I would have done this, had I the choice."

	*fake_choice
		#"I understand. The circumstances aren't ideal, but we'll adapt."
			"I understand. The circumstances aren't ideal, but we'll adapt." 

			You can hardly blame him for the fact that things will inevitably feel rushed and truncated. He surely wouldn't have been expecting to meet you [i]after he died[/i], and it's not his fault that process works the way it does. 

			"Thank you," he replies, managing half a smile. "You know, in spite of all that, I'm looking forward to this. I'll never be able to satisfy my desire for answers, I suppose, but if you have such a thing, I hope I can at least make sure you know everything you want to."
		#"You speak as though you've had a plan for a while, but I got the impression you didn't know I existed."
			"You speak as though you've had a plan for a while, but I got the impression you didn't know I existed." 

			It's strange, and you're not sure how to interpret it. Maybe he [i]did[/i] know about you, and planned to meet you one day? It would have been difficult in any case; perhaps he was simply hoping that one day, Demeter would allow it. 

			"You existed," he replies, almost too softly. "To me, you existed. I didn't [i]know[/i] it, and I didn't let myself make too many guesses about you, but… in my wildest hopes, you always existed." He clears his throat, looking down at his hands for a moment. "I always wanted to be—well, it doesn't matter. Suffice to say that for me, this meeting is a miracle. If I had to die to see it, well… everyone dies." He manages half a smile, genuine in spite of the touch of wryness.
		#"It's not how I would have done things, either, but here we are."
			"It's not how I would have done things, either, but here we are." 

			You don't [i]blame[/i] him for the fact that things will eventually feel rushed and truncated. He surely wouldn't have been expecting to meet you [i]after he died[/i], and it's not his fault that things turned out this way. But it [i]is[/i] what you're dealing with, and the sooner you both start dealing with it, the sooner you'll get the answers you're after. 

			"So it is," he replies, managing half a smile. "You know, in spite of all that, I'm looking forward to this. I'll never be able to satisfy my desire for answers, I suppose, but if you have such a thing, I hope I can at least make sure you know everything you want to. I'll try not to get distracted."
		#"With respect, don't get ahead of yourself. I haven't decided if there is any 'this' in the first place."
			"With respect, don't get ahead of yourself. I haven't decided if there is any 'this' in the first place." 

			It's true that you know he's your father, at this stage. But that alone doesn't entitle him to any relationship with you. Nor are you sure just yet whether that's something you want. You'll have to feel each other out quite a bit before you can answer a question like that.

			"That's reasonable," he replies, managing a slightly-awkward half-smile. "I'll do my best to give you any information you want and answer your questions, but in the end your decision what to do about that is your own. I have my hopes for what you'll choose, of course. No point pretending otherwise."
	*page_break
	Expelling a breath, Iasion sits back in his chair, studying you for a few seconds. His gaze is frank, but there is nothing critical or even especially assessing in it, as far as you can tell; rather, a small, slightly-baffled smile pulls at the corners of his mouth. 
	
	"Well, as you're probably aware, I'm—we're related. I'm your father. Demeter was here yesterday; I'd sort of… supposed I must be, but she confirmed that I was. So at least I suppose we don't have to wonder, when it comes to that part of things." 
	
	He clears his throat. "She said… you didn't know much. About how all of that came about, or about me, so if you'd like to hear the story, I'd be happy to tell it to you."
	
	*fake_choice
		#"I definitely would; I've always wanted to know about you."
			*set warm +1
			"I definitely would; I've always wanted to know about you." You're sure a little excitement is seeping into your voice, but you let it. Why wouldn't you? This is your [i]father[/i], someone who has always been a blank space in your knowledge of yourself. In your understanding of who and what you are. And you finally have the chance to talk to him, and begin to fill in that space. 
			
			Excitement is understandable, surely. 
			
			Iasion seems to have a little of it himself as he grins back at you, eyes crinkling. 
			
			*label iasionexplains2
			"To begin with, I suppose I should tell you: while I consider myself human in every way that really matters, my mother was one of the Pleiades, the nymph companions of Lady Artemis. My father was Corythus, King of Samothrace, a position that I now occupy. Or, well, did, I suppose."

			Technically, you're fairly sure this makes [i]him[/i] a demigod as well, or something akin to one. 

			"I mention this mostly to explain why I was even [i]at[/i] the place and time where I met Demeter," he admits with a rueful smile. "The marriage of Cadmus and Harmonia; she's my half-sister, you see." He shakes his head, expression slightly baffled. 

			He shakes his head. "Anyway, forgive me, I was meant to be telling of the event itself. I was invited to the wedding ceremony and attended, as did many of the gods, including Demeter. I would say… Harmonia's power was strong over the atmosphere, to put it one way. It was a rather unprecedented and unrepeated opportunity for humans and deities to simply… exist in the same place, under the banner of the same celebration, and it removed what I imagine must have been quite a number of barriers."
			*page_break
			Iasion's lips turn up into a wry smile. "When I saw your mother, I didn't recognize her for who she was. How could I? I just knew she was someone I needed to talk to. And so, like an arrogant fool, I did. And for reasons I can hardly fathom… she spoke to me in turn. If I try to understand it, I have to guess I bemused her at first. Probably because she couldn't imagine where someone so unimportant got the gall to address her without at least twice as much bowing and flattery."

			He rubs absently at the side of his neck with his fingertips, tracing along the line of an old, thin scar. "I certainly won't claim it was love at first sight, but it was… there was something. At least for me. A sense of connection. The desire to know more of her. And perhaps a bit too much ambrosia wine in the both of us." He lowers his hand, smiling softly. 

			"That was the first time we met, but it wasn't the last. Over the months afterwards, I… well, I did just about anything I could to meet her again, and for reasons I still don't fathom, she allowed it. I knew who she really was, by then, but I was much too infatuated to let any sense of what my place was in the world stop me. She was a person, and so was I, and that was the only part that seemed to matter." 

			The hand finds the surface of the table, and blunt fingertips tap gently, almost inaudibly, against it. "For the last… little while, it felt different. Like she was trying to keep something from me. And then I never saw her again."
			
			You suppose, then, that that would have been the time in which she'd discovered her pregnancy. 
			
			"You never knew about me," you say, drawing the conclusion in a deliberate, careful tone. 
			
			Iasion smiles, the slant of it a bit awkward, and nods. "Not… with any real certainty, no. I wondered. I [i]hoped[/i]. But I didn't know." 
		#"I suppose it couldn't hurt."
			*set cold +1
			"I suppose it couldn't hurt." You're not going to allow yourself to become invested in all of this just yet. But answers are not a bad thing, and indeed much of the reason you're here to begin with. You may as well allow him to provide them for you. 
			
			He smiles back at you, eyes crinkling. There isn't a hint of tentativeness about him, really, in spite of your obvious detachment. You have to wonder about that, a little. 
			*goto iasionexplains2
		#"I don't particularly need to know how you met or anything, but please do tell me a bit about yourself."
			*set warm +1
			"I don't particularly need to know how you met or anything, but please do tell me a bit about yourself." You're sure a little excitement is seeping into your voice, but you let it. Why wouldn't you? This is your [i]father[/i], someone who has always been a blank space in your knowledge of yourself. In your understanding of who and what you are. And you finally have the chance to talk to him, and begin to fill in that space. 
			
			Excitement is understandable, surely. 
			
			Iasion seems to have a little of it himself as he grins back at you, eyes crinkling. 
			
			*label iasionexplainshimself
			"Fair enough. I'm not sure how much of a story it is, anyway. We met at a wedding, and carried on for a bit. That's what it is, if I'm not waxing a bit too lyrical on the subject. Anyway, when it comes to me… I'm not quite sure what to say. While I consider myself human in every way that really matters, my mother was one of the Pleiades, the nymph companions of Lady Artemis. My father was Corythus, King of Samothrace, a position that I now occupy. Or, well, did, I suppose."

			Technically, you're fairly sure this makes [i]him[/i] a demigod as well, or something akin to one. 
			
			He clasps his hands on the table. "I can't say I ever thought myself particularly suited for the role of king, but maybe I managed to grow into it. Samothrace isn't such a large area, anyway, and the people all tend to know what they're doing just fine without me telling them. I know how to do the things kings are supposed to know: how to delegate, how to fight, how to sail and parley with one's allies and enemies… how to pay one's debts. Which is how we ended up at war, I suppose."
			
			"This war?" you ask, gesturing slightly to encompass the tent and those moving about outside of it. 
			
			"Yes. The only war I ever had to participate in. I won't call that fortunate, but it's better than it could have been. I hope now that I have died, Samothrace will be considered relieved of its debts and have no such obligations again."
			
			Clearly, Iasion is familiar with the burdens of responsibility. It's hard to imagine being compelled to go to war on behalf of another. You're not certain how you would have handled that situation. It's clearly not something he enjoyed, but he doesn't seem to resent it, either. 
		#"Let's stick to the basics, for now. Who are you?"
			*set cold +1
			"Let's stick to the basics, for now. Who are you?" You're not going to allow yourself to become invested in all of this just yet. But answers are not a bad thing, and indeed much of the reason you're here to begin with. You may as well allow him to provide them for you, even if the ones you're interested in don't have much to do with your mother, right now.
			
			He smiles back at you, eyes crinkling. There isn't a hint of tentativeness about him, really, in spite of your obvious detachment. You have to wonder about that, a little. 
			*goto iasionexplainshimself
	*page_break
	"I also want… to apologize," Iasion continues, running a hand back over his hair. "I can't imagine what it must be like to wake up one morning to all of this, and on a time limit, no less. I want you to know that I don't—I don't expect anything in particular from you. To be honest, I'm just…"

	He swallows, the cartilage in his throat bobbing, and coughs softly. His fingers curl against the surface of the table, nail beds paling. "I'm just… delighted. To know that you're not just someone I imagined might one day exist. That you're [i]real[/i], and alive, and well." 

	Iasion's eyes drop to the table, then slowly drag back up to you. "I hope your life has been everything you could ever want. I hope it always will be. That's…. really the main thing."

	*fake_choice
		#The irony and unfairness of it all forms a lump in my throat. "I... thank you."
			*set warm +1
			The irony and unfairness of it all forms a lump in your throat. "I... thank you."

			You can feel tears threatening, but you're fighting them, not so much for your own sake as for his. Wouldn't it just give him something to worry about, if he saw you cry over this? After everything, in [i]this[/i] situation, you don't want to make him concerned like that. 

			It's so—

			He meets your eyes, and you can tell his aren't quite dry, either. "I'm sorry," he murmurs. "I wish it could have been some other way. But… this is the situation we have."
			
			There's a chance, of course, that it isn't as bad as all that. That he ends up on the Isles, and can keep his memories for a while longer. But even then—even then, you will eventually lose him to the cycle of rebirth. And it will be so much sooner than you're expecting, you just know it. 
		#I can at least offer a smile, even if this is not the joyful occasion I might have wanted it to be. "It's been... there's been ups and downs, but I'm happy."
			*set warm +1
			You can at least offer a smile, even if this is not the joyful occasion you might have wanted it to be. "It's been... there's been ups and downs, but I'm happy." 

			That's the truth, but it's also meant to give him as much reassurance as you can, while you can. Your life hasn't been perfect, by any means, but you're satisfied with where it is and where it's going. And if he wishes for your happiness, he need not worry too much. 

			The situation strikes you as deeply unfair, but what can you do about that? There's no one here who can fix that, and so you simply have to cope with it as best you can.

			Iasion meets your eyes, and you can tell his aren't quite dry. "I want very much to lament the situation we're in," he admits quietly. "But instead I am going to be grateful that this meeting happened at all, because it could very easily never have taken place."

			There's a chance, of course, that it isn't as bad as all that. That he ends up on the Isles, and can keep his memories for a while longer. But even then—even then, you will eventually lose him to the cycle of rebirth. And it will be so much sooner than you're expecting, you just know it. 
		#I'm still reeling a little, not sure how to properly respond, but I manage a tight 'thank you,' at least.
			You're still reeling a little, not sure how to properly respond, but you manage a tight 'thank you,' at least.

			It's all… quite a lot. Of information, of ways in which you need to reconfigure your understanding of things. Filling in the largest blank in your understanding of your own life, your own origin, is naturally a significant undertaking, but even this much is leaving the parts you still [i]don't[/i] know to stand out in stark contrast. 

			Why did your mother stop speaking to him? Why weren't you allowed to know him? It seems he would have been willing to know [i]you[/i], but is that perhaps a more recent development than he has indicated?

			There are too many questions for you to even know where to begin, and the squeeze of the time limitation is [i]also[/i] looming large.

			Iasion meets your eyes, and you can tell his aren't quite dry. "I want very much to lament the situation we're in," he admits quietly. "But instead I am going to be grateful that this meeting happened at all, because it could very easily never have taken place."

			He doesn't press it, though, doesn't leave an expectant silence in which you might reciprocate the sentiment. Perhaps he knows you can't right now. Perhaps he senses that you're overwhelmed. You can only hope so, because it would be difficult to explain.

			There's a chance, of course, that it isn't as bad as all that. That he ends up on the Isles, and can keep his memories for a while longer. But even then—even then, you will eventually lose him to the cycle of rebirth. And it's hard to know just how to feel about that.
		#I can't help but feel that's a tad presumptive of him, but I'll let it slide. He's not being overbearing with this, and I appreciate that. "Thank you. If it helps to know, I'm doing rather well."
			*set cold +1
			You can't help but feel that's a tad presumptive of him, but you'll let it slide. He's not being overbearing with this, and you appreciate that. "Thank you. If it helps to know, I'm doing rather well."

			At the moment, your emotions remain firmly under your control. There is still a fair bit of thinking you'll need to do about these matters, of course. Filling in the largest blank in your understanding of your own life, your own origin, is naturally a significant undertaking, but even this much is leaving the parts you still [i]don't[/i] know to stand out in stark contrast. 

			Why did your mother stop speaking to him? Why weren't you allowed to know him? It seems he would have been willing to know [i]you[/i], but is that perhaps a more recent development than he has indicated?

			The short time span in which you may be able to get hints as to the answers is daunting, in its way, but you will handle it in your own way and with your own priorities. 

			Iasion meets your eyes, and you can tell his aren't quite dry. "I want very much to lament the situation we're in," he admits quietly. "But instead I am going to be grateful that this meeting happened at all, because it could very easily never have taken place."

			He doesn't press it, though, doesn't leave an expectant silence in which you might reciprocate the sentiment. Perhaps he knows that you wouldn't necessarily be able to. You can't claim to feel exactly the way he does about it, but you [i]do[/i] think perhaps you're glad this happened, even if the circumstances are less than ideal.

			There's a chance, of course, that it isn't as bad as all that. That he ends up on the Isles, and can keep his memories for a while longer. But ultimately, you aren't sure how much about this that would change, given that the cycle of rebirth marches on even so.
		#I do understand that he's holding back his emotions, which is good because I'd rather not confront those. We're still essentially strangers, but I can manage politeness. "I appreciate the sentiment."
			*set cold  +1
			You do understand that he's holding back his emotions, which is good because you'd rather not confront those. We're still essentially strangers, but you can manage politeness. "I appreciate the sentiment."

			It's not as though you can suddenly claim to feel a bond with this man. Or any sort of attachment. Perhaps, with time, something like that might have been possible. But time is something you do not necessarily have, and so the best choice is to remain at a courteous distance. 

			Even if somehow you think Iasion is not as capable of that as you are.

			Iasion meets your eyes, and you can tell his aren't quite dry. "I want very much to lament the situation we're in," he admits quietly. "But instead I am going to be grateful that this meeting happened at all, because it could very easily never have taken place."

			He doesn't press it, though, doesn't leave an expectant silence in which you might reciprocate the sentiment. Perhaps he knows that you wouldn't necessarily be able to. You can't claim to feel exactly the way he does about it, but you [i]do[/i] think perhaps you're glad this happened, even if the circumstances are less than ideal. It's… something. More answers than you had, at the very least.
			
			There's a chance, of course, that circumstances improve. That he ends up on the Isles, and can keep his memories for a while longer. But ultimately, you aren't sure how much about this that would change, given that the cycle of rebirth marches on even so.
	*page_break
	Releasing a long, slow breath, Iasion seems almost to resign himself to something, his hands relaxing on the tabletop and his expression clearing, then becoming something almost wry for a moment before he shakes his head. 
*if (met_iasion)
	It takes him no time at all to spot you, and he startles, just a little bit, before breaking into a smile. 
	
	"Sorry, ${name}. I think I'm always going to be surprised to see you for a while. It's good to feel that way again." 
	
	*fake_choice
		#"I think I know what you mean."
			*set serious +1
			"I think I know what you mean." You lift your hand to your chest, pressing down through your clothes. You can't feel your heartbeat, exactly, but you know it's accelerated a little with your own… perhaps [i]surprise[/i] isn't quite it. But still, seeing Iasion does give you some kind of adrenaline response, and it's not unpleasant. 
			
			His smile broadens into something almost a grin, and he nods, touching his hand to the same place on himself. 
			
			"Anyway, let's head inside. I have a guess as to what might have brought you by today."
		#@{convotoggle [☆]|} "Well, as long as I don't give you a heart condition."
			*set humorous +1
			"Well, as long as I don't give you a heart condition," you reply lightly, smiling back at him. Really, it isn't so bad to see him, either. You wouldn't say you're [i]surprised[/i] in any sense, but it does feel like your mood is a little lifted, and you're not going to turn your nose up at something like that. 
			
			His expression broadens into a grin. "Would it matter? It's not like it'd kill me," he points out, just as light. 
			
			Once the resultant mirth has subsided a little, he gestures backwards. "Anyway, let's head inside. I have a guess as to what might have brought you by, today."
		#"I suppose it's a bit of an unusual situation, so fair enough."
			"I suppose it's a bit of an unusual situation, so fair enough." You can't say you feel anything similar, but you aren't going to begrudge him his responses. You aren't sure what you'd be feeling or thinking in a situation like his, but you don't have to relate to understand at least a little. 
			
			"Well, I appreciate the graciousness," he says, just a hint of humor in it. "But anyway, let's head inside. I have a guess as to what might have brought you by, today."
	*page_break
	The tent is, unsurprisingly, exactly as it was before. All of Iasion's 'belongings,' and there are quite few, are very neatly-placed, and the entire interior has a sense of transience and depersonalization. Whatever the other men think, to whatever degree they've accepted their deaths or haven't, it is clear that your father is well aware of just how temporary his current situation is. 
	
	*fake_choice
		#It's almost a shame. I wish I'd gotten to see what his home looked like.
			It's almost a shame. You wish you'd gotten to see what his home looked like. You're not sure if, as a king, he'd have had the ability to furnish it however he wanted, or if he'd stick to some kind of convention, but either way would have been interesting. Told you something about him. 
			
			This hardly gives a hint, so you suppose any insights into who Iasion is will have to come from the man himself, one way or another.
		*if (iasiontalk != "none")
			#I'm a little nervous. Last time, I wasn't alone here, so this feels different.
				You're a little nervous. Last time, you weren't here alone, so this feels different. You're not [i]afraid[/i], exactly; you know there's no reason to be that. But the prickle of anxiety is definitely there under your skin. 
				
				*if (dontstim)
					It's not something that manifests much, though. Maybe your expression is a bit strained, but if Iasion notices, he doesn't comment on it. 
					
					That alone is enough for you to begin to relax, just a little bit. 
				*if ((dontstim = false) and (stimt != "unknown"))
					*fake_choice
						*if (stimt != "suppress")
							#It's enough for me to begin to fidget, in the same way I often do when feeling anxious.
								It's enough for you to begin to 
								*if (stimt = "tap")
									tap your fingers against your leg, in the same way you often do when feeling anxious. The slightly-frenetic rhythm of it is grounding, and it's not something you even [i]decide[/i] to do—it just happens, in almost the same way breathing just happens. 
								*if (stimt = "rock")
									rock back and forth a bit on your heels, in the same way you often do when feeling anxious. It would probably be more comfortable if you were already sitting, but for now, this will do. The motion is grounding, and it's not something you even [i]decide[/i] to do—it just happens, in almost the same way breathing just happens. 
								*if (stimt = "lip")
									chew your lip, in the same way you often do when feeling anxious. The dull sensation of it is grounding, and it's not something you even [i]decide[/i] to do—it just happens, in almost the same way breathing just happens. 
								*if (stimt = "hands")
									wring and flap your hands, in the same way you often do when feeling anxious. The rhythm of it is grounding, and it's not something you even [i]decide[/i] to do—it just happens, in almost the same way breathing just happens. 
								*if (stimt = "hair")
									tug at your hair, in the same way you often do when feeling anxious. The sensation of it is grounding, and it's not something you even [i]decide[/i] to do—it just happens, in almost the same way breathing just happens. 
								
								Iasion, catching sight of you from the corner of his eye, turns from where he's moving chairs to, of all things, grin broadly at you. "My father used to do that," he says, tone soft. "He hid it from his subjects, but in front of his family, you could always tell when he was annoyed or worried about something. Or enjoying himself, for that matter."
						*if (stimt = "suppress")
							#The desire is there, to fidget, but as usual, I manage to suppress it.
								The desire is there, to fidget, but as usual, you manage to suppress it. You're not sure how Iasion would react to such an overt display of your emotions, never mind your discomfort with expressing things in such a way. 
								
								You're not sure exactly what your face is doing, or if Iasion picks up on your nervousness otherwise, but if he does, he doesn't comment on it. 
							
								That alone is enough for you to begin to relax, just a little bit. 
						#I don't tend to show my anxiety with fidgeting; that's usually triggered by different emotions and moods. 
							Though some of your emotions are sometimes obvious, given your very physical reactions to them, perhaps fortunately, anxiety isn't one that brings out such a reaction in you. You're not sure exactly what your face is doing, or if Iasion picks up on your nervousness, but if he does, he doesn't comment on it. 
							
							That alone is enough for you to begin to relax, just a little bit. 
				*if ((dontstim = false) and (stimt = "unknown"))
					*gosub_scene stimb
					*if ((dontstim = false) and (stimt != "suppress"))
						Iasion, catching sight of you from the corner of his eye, turns from where he's moving chairs to, of all things, grin broadly at you. "My father used to do that," he says, tone soft. "He hid it from his subjects, but in front of his family, you could always tell when he was annoyed or worried about something. Or enjoying himself, for that matter."
					*if ((dontstim) or (stimt = "suppress"))
						Your anxiety isn't something that manifests much, though. Maybe your expression is a bit strained, but if Iasion notices, he doesn't comment on it. 
					
						That alone is enough for you to begin to relax, just a little bit. 
		#It shows his practicality, I suppose. 
			It shows his practicality, you suppose. Even with the paucity of items to his name here in the Underworld, he could have been much more haphazard. Honestly, he probably could have demanded more supplies and received them. As far as you know, there's no rule that the souls waiting here have to get only the bare minimum in lodgings and comforts. 
			
			So you have to assume his own lack is something to do with his personality. If he knows he won't be here long, then the fact that he hasn't opted for more creature comforts shows a certain… respectable pragmatism, you suppose.
		#It's hard to even imagine living in a tent of all things. Even if this is a nice one, it's so... boring.
			It's hard to even imagine living in a tent of all things. Even if this is a nice one, it's so… boring. Honestly, he probably could have demanded more supplies and received them. As far as you know, there's no rule that the souls waiting here have to get only the bare minimum in lodgings and comforts. 
			
			The fact that he apparently hasn't is… well, you would not have made the same choice, to put it one way.
	*page_break
	Getting the table arranged so that it's just two chairs across from one another, Iasion gestures to one, taking the other himself. Releasing a long, slow breath, he seems almost to resign himself to something, his hands relaxing on the tabletop and his expression clearing, then becoming something almost wry for a moment before he shakes his head. 
*page_break
"So… I saw Demeter yesterday." His tone doesn't suggest that this should be news to you. Rather, it's given a tinge of disbelief, or maybe something akin to being dazed. Meeting your eyes for a brief moment, he offers half an awkward smile. 

"It was… I'm not even sure what the right word is for it. Strange, maybe. As many years as it's been, she's—well, I won't say she's the same. She isn't. But she [i]looks[/i] nearly the same. And I definitely don't." He gestures at himself, brow ticking upwards.

*fake_choice
	#"You make it sound almost uncomfortable."
		*set serious +1
		"You make it sound almost uncomfortable." You sit back a little in your chair, studying him across the table. He puts it a bit lightly, but not so much so that the underlying sentiment there is impossible for you to detect. 
		*if (tag_unintuitive)
			You wonder if he always projects his feelings so clearly—if [i]you[/i] can pick up on this much, surely anyone can. But there must have been times he needed to be more circumspect, right? As a king?
		
		Iasion huffs, mostly through his nose. "Well… it was, a little bit. I'm not sure if you've ever tried reuniting with someone after this big a chunk of your life but… well, no. Maybe it would be different. At least part of it is feeling a little like an old man when the person in front of you [i]looks[/i] like she's seen a decade at the most." 
		
		"She looks older to you?" That's actually a little surprising. 
		
		He nods. "It's different for immortals, right? I've always been told the appearance of age is sort of… psychological. Which is sort of its own set of questions, you know? I have to wonder what she's been going through, when I've been running the damned island." 
		
		Iasion shakes his head. 
	#"Really? She's different? She always seems exactly the same to me."
		*set serious +1
		"Really? She's different? She always seems exactly the same to me." Theoretically, of course, people change. But the gods, in your experience, take so long to do it you're not even sure how much they're capable of it, after the initial period of maturing and all that. Something your mother was long past by the time you were born. 
		
		"Well… it's definitely not like talking to an entirely new person," he replies, rubbing at the hair on his chin. "But… yes. There are definitely differences. That's jarring in some ways, but it's almost not jarring [i]enough[/i] in others, you know? At least part of the strangeness of it all is feeling a little like an old man when the person in front of you [i]looks[/i] like she's seen a decade at the most." 
		
		"She looks older to you?" That's actually a little surprising. 
		
		He nods. "It's different for immortals, right? I've always been told the appearance of age is sort of… psychological. Which is sort of its own set of questions, you know? I have to wonder what she's been going through, when I've been running the damned island." 
		
		Iasion shakes his head. 
	#@{convotoggle [☆]|} "Don't be too down on yourself. I think you look distinguished."
		*set humorous +1
		"Don't be too down on yourself. I think you look distinguished." You offer a smile and an arch of the brow, and Iasion laughs. 
		
		"Where did you learn to flatter people? Certainly not from your mother; I had to wonder if she even recognized me for a second there." He shakes his head; perhaps not entirely serious about [i]that[/i], either. 
		
		"Certainly, part of the strangeness of it all is feeling a little like an old man when the person in front of you [i]looks[/i] like she's seen a decade at the most." 
		
		"She looks older to you?" That's actually a little surprising. 
		
		He nods. "It's different for immortals, right? I've always been told the appearance of age is sort of… psychological. Which is sort of its own set of questions, you know? I have to wonder what she's been going through, when I've been running the damned island." 
		
		Iasion shakes his head. 
	#@{convotoggle [☆]|} "Yeah, I'm betting that was as awkward as awkward gets."
		*set humorous +1
		"Yeah, I'm betting that was as awkward as awkward gets." You can't help but snort softly through your nose, offering a wry smile. You're not sure exactly what would have happened between them, but you can only imagine it getting pretty strange, pretty fast. 
		
		"I don't know," he says. "I think maybe I've managed to find myself in one or two more awkward situations before. But maybe not in quite a while." Shaking his head, he expels a breath. "At least part of the strangeness of it all is feeling a little like an old man when the person in front of you [i]looks[/i] like she's seen a decade at the most." 
		
		"She looks older to you?" That's actually a little surprising. 
		
		He nods. "It's different for immortals, right? I've always been told the appearance of age is sort of… psychological. Which is sort of its own set of questions, you know? I have to wonder what she's been going through, when I've been running the damned island." 
		
		Iasion shakes his head. 
*page_break
Running a finger down the bridge of his nose, he studies you across the table for a few moments. "It's awkward between you two, too, it seems. 
*if (iasion_knowsawkward)
	Well—you basically [i]told[/i] me that, last time. 
*if not (iasion_knowsawkward)
	At least, that's one interpretation of the fact that you aren't together right now. 
Is it okay if I ask you more about that?" 

*fake_choice
	*if (demeterstatus = "open")
		#"Honestly, we're fine. It's just that I didn't want to get stuck in the middle of anything that went wrong between you two."
			"Honestly, we're fine. It's just that I didn't want to get stuck in the middle of anything that went wrong between you two." 
			
			The words clearly come as a surprise to Iasion, but the short bark of laughter suggests that the sentiment isn't received negatively, at least. "That's…" he coughs, a smile pulling at his mouth. "I'm not sure exactly what to make of it when my ${son} is convinced that my reunion with ${his} mother could have collateral damage." 
			
			The residual chuckles trail off, and he offers a grin across the table. "I'm not sure which one of us you think is the disaster waiting to happen, but I suppose I can't fault you for being cautious." 
	*if ((demeterstatus = "open") and (refusediasion = false))
		#"It's not that things are awkward between us. But I'd already had a chance to talk to you alone, and it felt like she should have one, too, before anything else."
			"It's not that things are awkward between us. But I'd already had a chance to talk to you alone, and it felt like she should have one, too, before anything else." 
			
			"Ah." Iasion nods, eyes narrowing fractionally. "Sensible, I suppose. I don't think either of us would have at all minded your presence. Perhaps it would have been preferable, if only because I'd like to see as much of you as I can." He offers a smile across the table. 
			
			"But still, thank you for thinking of us. It was very kind."
	*if ((demeterstatus  = "open") and (refusediasion))
		#"It's not that things are awkward between us. But it would have been a lot, for you to see her again [i]and[/i] meet me in the same event. I didn't want to put that much pressure on you at once."
			"It's not that things are awkward between us. But it would have been a lot, for you to see her again [i]and[/i] meet me in the same event. I didn't want to put that much pressure on you at once."
			
			"Ah." Iasion nods, eyes narrowing fractionally. "Sensible, I suppose. I'm not sure how, exactly, I would have reacted to that, but maybe it's better that we don't know, because I might have been a bit of a mess. You do remember me from a few minutes ago, after all." 
			
			He offers a smile across the table. "Even so, I should put out there that for all the strangeness, it's an [i]overjoyed[/i] mess that I would have been. Don't ever doubt that I'd like to see as much of you as I can. And do ignore me if that seems overbearing."
	*if (demeterstatus != "open")
		#"Things are a bit... strained, yes, but we did things this way mostly because I wanted to let you two meet without any interference from me." 
			"Things are a bit... strained, yes, but we did things this way mostly because I wanted to let you two meet without any interference from me." 
			
			"Ah." Iasion nods, eyes narrowing fractionally. "Sensible, I suppose. I don't think either of us would have at all minded your presence. Perhaps it would have been preferable, if only because I'd like to see as much of you as I can." He offers a smile across the table. 
			
			"But still, thank you for thinking of us. It was very kind. Even if things aren't easy between the two of you."
	*if (demeterstatus != "open")
		#"If you think meeting her was already uncomfortable, it would have been doubly so if I were there as well. I decided not to put any of us through that."
			"If you think meeting her was already uncomfortable, it would have been doubly so if I were there as well. I decided not to put any of us through that."
			
			Iasion's brows ascend his forehead. "I hadn't realized the situation was quite [i]that[/i] bad," he admits. "Perhaps Demeter was downplaying things a bit." His mouth turns down a little. "I'm not sure exactly what happened, but I won't ask you to explain the whole thing right now."
			
			He offers a very small smile across the table. "Just know that, if you prefer things that way, I can keep any relationship I get to have with you apart from my relationship with her. Anything you tell me in confidence will remain that way."
	*if (demeterstatus != "open")
		#"I would prefer not to talk about my relationship with her." 
			"I would prefer not to talk about my relationship with her." 
			
			Iasion's brows ascend his forehead. "I hadn't realized the situation was quite like that," he admits. "Perhaps Demeter was downplaying things a bit." His mouth turns down a little. "But I won't ask for details, since it's not a topic you want to get into."
			
			He offers a very small smile across the table. "Just know that, if you prefer things that way, I can keep any relationship I get to have with you apart from my relationship with her. Anything you tell me in confidence will remain that way."
*page_break
*if (demeterstatus = "open")
	"In any event…" he trails off for a moment, eyes shifting to the upper corner of the tent and hands clasping together on the tabletop. "I was hoping I might ask you for some advice, actually. With regard to her." 
*if (demeterstatus != "open")
	"In any event…" he trails off for a moment, eyes shifting to the upper corner of the tent and hands clasping together on the tabletop. "I had thought to ask you for some advice, concerning our situation, but I understand that you might not be interested in offering it. So we can move on instead, if you prefer."
	
	*fake_choice
		#"No, it's all right. You can ask."
			*set warm +1
			"No, it's all right. You can ask." The friction there isn't enough for you to feel too uncomfortable giving your insights, insofar as you might have any. The very thought that you might be in a position to offer your father insight about your mother feels a little [i]odd[/i], but it's not as though it's unreasonable, given the situation. 
			
			"Ah. That's… much appreciated." Iasion relaxes fractionally. 
		#"I don't mind if you ask, but I can't promise anything insightful."
			*set cold +1
			"I don't mind if you ask, but I can't promise anything insightful." The friction there isn't enough for you to feel too uncomfortable giving your insights, insofar as you might have any. The very thought that you might be in a position to offer your father insight about your mother feels a little [i]odd[/i], but it's not as though it's unreasonable, given the situation. 
			
			"Ah. That's… much appreciated." Iasion relaxes fractionally. 
		#"Thank you. It's not that I don't want to help you. I'm just... really not comfortable discussing her right now."
			*set warm +1
			"Thank you. It's not that I don't want to help you. I'm just... really not comfortable discussing her right now." You've been grateful that his mention so far has been relatively brief, and asking an obvious question that you'd anticipated. Anything else is… you're just not prepared to handle that, yet. 
			
			"Of course." Iasion's expression softens. "I'll admit, all the questions I'm [i]really[/i] burning to ask are about you, anyway."
			*goto andnowaboutyou
		#"Let's talk about anything besides my mother."
			*set cold +1
			"Let's talk about anything besides my mother." You've been relieved that his mention of her so far has been relatively brief, and asking an obvious question that you'd anticipated. Anything else would be beyond the pale at this point. 
			
			"Of course." Iasion's expression softens. "I'll admit, all the questions I'm [i]really[/i] burning to ask are about you, anyway."
			*goto andnowaboutyou
*line_break
*line_break
He pushes out a breath, fingers dragging gently along the surface of the table as he leans back. "It's… hard to put into words exactly how I feel about all of this. I know I want to mend things, but that grows much more difficult when I can't even find the right words to describe what needs mending in the first place." Gently, squared fingertips tap on the wood, producing just the subtlest of sounds. 

"I think—" He pauses, rolling his lips together and then relaxing them again. "I think I feel a little betrayed, in all sincerity. I'm aware that Demeter left to protect me, but I would have preferred to be consulted about that, and… perhaps I'm most upset that she never told me about you. We were in a [i]form[/i] of communication, at times, and there was never a hint of it." 

"A form of communication?" 

He nods. "Prayer, I guess you could call it. I built her a temple on Samothrace and everything. I was that desperate to hear anything from her. Though… I suppose I'd have done it, anyway. And our harvests were always good. I can't complain at all, in that sense. Which… sort of just makes the rest of it feel worse."

*fake_choice
	#"I'm sure she was trying to do what was best. You have the right to be upset, but I think you should talk to her about this. As calmly and kindly as possible." 
		*set iasion_reconcile true
		"I'm sure she was trying to do what was best. You have the right to be upset, but I think you should talk to her about this. As calmly and kindly as possible." 
		
		*if (demeterstatus = "open")
			You have some experience with your mother making decisions on your behalf, but then in [i]most[/i] of those cases, you were a child. And in the major one where you weren't, well… you've decided to look at it as charitably as you can. She was distressed, and concerned, and for all she knew your life could be on the line. 
			
			Most of those descriptors probably apply to Iasion's situation, as well, and you think it wouldn't hurt if he went into things with an attitude of reconciliation, rather than one of looking for some kind of restitution for what she's done. 
		*if ((demeterstatus != "open") and (demeterstatus != "cutoff"))
			You have some experience with your mother making decisions on your behalf, but then in [i]most[/i] of those cases, you were a child. And in the major one where you weren't, well… admittedly your response hasn't been [i]quite[/i] as forgiving as you're suggesting here. 
			
			But what is between you and your mother is complicated by a lot of years of living together and trying to communicate and things just… not going well. There's a chance their situation could turn out similarly, but you hope not. 
		*if (demeterstatus = "cutoff")
			You have some experience with your mother making decisions on your behalf, but then in [i]most[/i] of those cases, you were a child. And in the major one where you weren't, well… admittedly your response hasn't been nearly as forgiving as you're suggesting here. 
			
			But what is between you and your mother is complicated by a lot of factors. Even if you don't want her involved in your life right now, you don't want her to be [i]unhappy[/i], either, and Iasion's words suggest that there's still a chance for the two of them, at least, to work things out.
			
			All you can do is give him what you think the best advice is for his chances of success. 
			
		"Oh, I know she was trying to do what was best," he replies, smiling crookedly. "That was never at issue. It's just… I thought we were partners, in some larger sense. That if a problem arose, we'd figure out how to handle it [i]together[/i]. Still… you're probably right. It's not like I want to be upset with her, anyway."
	#"She's definitely the one in the wrong here. I've been on the other end of her unilateral decisions to protect me, too. I don't think it's impossible to reconcile, but you need to be firm."
		*set iasion_reconcile true
		"She's definitely the one in the wrong here. I've been on the other end of her unilateral decisions to protect me, too. I don't think it's impossible to reconcile, but you need to be firm."
		
		*if (demeterstatus = "open")
			Your experience with those kinds of actions on Demeter's part is admittedly mostly from when you were a child, but there was certainly a major one where you weren't, and quite recently. You've decided to look at all of them charitably, but not by losing your sense of who was in the wrong, by any means. 
			
			Many of the same mitigating circumstances—her concern, her distress, her impression that your life was on the line—could probably be applied equally-well to his situation, at the time. So perhaps he could get somewhere taking a similar view on it. 
		*if ((demeterstatus != "open") and (demeterstatus != "cutoff"))
			Your experience with those kinds of actions on Demeter's part is admittedly mostly from when you were a child, but there was certainly a major one where you weren't, and quite recently. You've wound up needing space from her because of all that, but 'space' doesn't seem like the right recommendation in a case like this, of all things.
			
			So, you give him the best advice you can. Perhaps their situation turns out similarly to yours. But, you can hope that it will be better, in part because he very much seems to want it to be. 
		*if (demeterstatus = "cutoff")
			Your experience with those kinds of actions on Demeter's part is admittedly mostly from when you were a child, but there was certainly a major one where you weren't, and quite recently. You've wound up cutting contact with her in part because of that, but that hardly seems like the advice to offer here. After all, 'cut contact' is basically where they're [i]starting[/i] from. 
			
			So, you give him the best advice you can. Perhaps their situation turns out similarly to yours. But, you can hope that it will be better, in part because he very much seems to want it to be. 
			
		"Firm, huh?" he asks, smiling crookedly. "That might be a bit of a challenge, with someone so bull-headed. But I guess it can't hurt to remind her that I'm pretty stubborn, too, when it comes down to it. Anyway, it's not like I [i]want[/i] to be angry with her, so I'll keep that in mind."
	#"Well... you [i]were[/i] betrayed. I don't know that I'd find it easy to forgive that, and I'm not sure I can encourage you to try."
		"Well... you [i]were[/i] betrayed. I don't know that I'd find it easy to forgive that, and I'm not sure I can encourage you to try."
		
		*if (demeterstatus = "open")
			You have some experience with your mother making decisions on your behalf, but then in [i]most[/i] of those cases, you were a child. And in the major one where you weren't, well… you've decided to look at it as charitably as you can. She was distressed, and concerned, and for all she knew your life could be on the line. 
			
			Maybe some of those factors applied to his situation as well, but Iasion was also [i]right there[/i]. She could have just discussed it with him, face to face, quite easily, and she hadn't. It wasn't as though he'd been in a realm generally considered beyond her reach. 
			
			Given that, it's hard to imagine being able to just overcome the feeling he's experiencing. 
		*if ((demeterstatus != "open") and (demeterstatus != "cutoff"))
			You have some experience with your mother making decisions on your behalf, but then in [i]most[/i] of those cases, you were a child. And in the major one where you weren't, well… admittedly your response hasn't been [i]quite[/i] forgiving, either. 
			
			Maybe some of the factors she'd been dealing with in your case applied to his situation as well, but Iasion was also [i]right there[/i]. She could have just discussed it with him, face to face, quite easily, and she hadn't. It wasn't as though he'd been in a realm generally considered beyond her reach. 
			
			Given that, it's hard to imagine being able to just overcome the feeling he's experiencing. You certainly can't just overcome your own.
		*if (demeterstatus = "cutoff")
			You have some experience with your mother making decisions on your behalf, but then in [i]most[/i] of those cases, you were a child. And in the major one where you weren't, well… admittedly your response hasn't been forgiving, either. 
			
			Maybe some of the factors she'd been dealing with in your case applied to his situation as well, but Iasion was also [i]right there[/i]. She could have just discussed it with him, face to face, quite easily, and she hadn't. It wasn't as though he'd been in a realm generally considered beyond her reach. 
			
			Given that, it's hard to imagine being able to just overcome the feeling he's experiencing. You certainly can't just overcome your own.
		
		"Well, I appreciate the honesty," he admits, giving you a lopsided smile. "Some part of me could almost forgive her for anything, but… maybe I need to think a little harder about that. It's not easy to just accept being excluded from matters as important as [i]you[/i]."
	#"I'm not sure why you're bothering, here. She's always like that, and it's never going to change. If you can't accept it, you should just... stay estranged." 
		"I'm not sure why you're bothering, here. She's always like that, and it's never going to change. If you can't accept it, you should just... stay estranged." 
		
		*if (demeterstatus = "open")
			You have some experience with your mother making decisions on your behalf, but then in [i]most[/i] of those cases, you were a child. And in the major one where you weren't, well… you've decided to look at it as charitably as you can. She was distressed, and concerned, and for all she knew your life could be on the line. 
			
			Maybe some of those factors applied to his situation as well, but Iasion was also [i]right there[/i]. She could have just discussed it with him, face to face, quite easily, and she hadn't. It wasn't as though he'd been in a realm generally considered beyond her reach. 
			
			Given that, it's hard to imagine being able to just overcome the feeling he's experiencing. 
		*if ((demeterstatus != "open") and (demeterstatus != "cutoff"))
			You have some experience with your mother making decisions on your behalf, but then in [i]most[/i] of those cases, you were a child. And in the major one where you weren't, well… admittedly your response hasn't been [i]quite[/i] forgiving, either. 
			
			Maybe some of the factors she'd been dealing with in your case applied to his situation as well, but Iasion was also [i]right there[/i]. She could have just discussed it with him, face to face, quite easily, and she hadn't. It wasn't as though he'd been in a realm generally considered beyond her reach. 
			
			Given that, it's hard to imagine being able to just overcome the feeling he's experiencing. You certainly can't just overcome your own.
		*if (demeterstatus = "cutoff")
			You have some experience with your mother making decisions on your behalf, but then in [i]most[/i] of those cases, you were a child. And in the major one where you weren't, well… admittedly your response hasn't been forgiving, either. 
			
			Maybe some of the factors she'd been dealing with in your case applied to his situation as well, but Iasion was also [i]right there[/i]. She could have just discussed it with him, face to face, quite easily, and she hadn't. It wasn't as though he'd been in a realm generally considered beyond her reach. 
			
			Given that, it's hard to imagine being able to just overcome the feeling he's experiencing. You certainly can't just overcome your own.
		
		"Maybe she won't," he admits softly, mouth falling into a frown. "Some part of me could almost forgive her for anything, but… maybe I need to think a little harder about that. It's not easy to just accept being excluded from matters as important as [i]you[/i]."
	#"I don't think I have any advice to give you. How to deal with something like this is a really personal decision."
		*set iasion_reconcile true
		"I don't think I have any advice to give you. How to deal with something like this is a really personal decision."
		
		*if (demeterstatus = "open")
			You have some experience with your mother making decisions on your behalf, but then in [i]most[/i] of those cases, you were a child. And in the major one where you weren't, well… you've decided to look at it as charitably as you can. She was distressed, and concerned, and for all she knew your life could be on the line. 
			
			Maybe some of those factors applied to his situation as well, but Iasion was also [i]right there[/i]. She could have just discussed it with him, face to face, quite easily, and she hadn't. It wasn't as though he'd been in a realm generally considered beyond her reach. 
			
			You don't know how he should respond to that. It seems like something he has to weigh up against his emotions for her, among other things, and the likelihood of any of it even making a difference to begin with, given the potential time constraints. 
			
			There's no advice that could possibly account for all of those deeply personal things.
		*if ((demeterstatus != "open") and (demeterstatus != "cutoff"))
			You have some experience with your mother making decisions on your behalf, but then in [i]most[/i] of those cases, you were a child. And in the major one where you weren't, well… admittedly your response hasn't been [i]quite[/i] forgiving. 
			
			Maybe some of the factors she'd been dealing with in your case applied to his situation as well, but Iasion was also [i]right there[/i]. She could have just discussed it with him, face to face, quite easily, and she hadn't. It wasn't as though he'd been in a realm generally considered beyond her reach.  
			
			You don't know how he should respond to that. It seems like something he has to weigh up against his emotions for her, among other things, and the likelihood of any of it even making a difference to begin with, given the potential time constraints. 
			
			There's no advice that could possibly account for all of those deeply personal things. They aren't the same as your equally-personal considerations, even, so talking about what you've done is no good, either. 
		*if (demeterstatus = "cutoff")
			You have some experience with your mother making decisions on your behalf, but then in [i]most[/i] of those cases, you were a child. And in the major one where you weren't, well… admittedly your response hasn't been exactly forgiving. 
			
			Maybe some of the factors she'd been dealing with in your case applied to his situation as well, but Iasion was also [i]right there[/i]. She could have just discussed it with him, face to face, quite easily, and she hadn't. It wasn't as though he'd been in a realm generally considered beyond her reach. 
			
			You don't know how he should respond to that. It seems like something he has to weigh up against his emotions for her, among other things, and the likelihood of any of it even making a difference to begin with, given the potential time constraints. 
			
			There's no advice that could possibly account for all of those deeply personal things. They aren't the same as your equally-personal considerations, even, so talking about what you've done is no good, either. 
		
		"I suppose you make a fair point," he admits, giving you a soft, lopsided grin. "It means I have a lot of thinking to do, but I don't think I was ever going to get away from that. Thanks for listening, anyway."
*label andnowaboutyou
*page_break
Iasion visibly relaxes, something about his expression easing, giving his smile a sense of openness and sincerity. You didn't necessarily think him lacking in either of those things before, but perhaps this is simply the result of his getting the rest of all that off his chest. 

"I'd like to know more about you, if you don't mind sharing," he admits, "but first, let's maybe get out of here? I'm not sure I want to have this whole conversation in a tent, after all. Do you mind if we walk along the river instead?"

*if (forthright > reserved)
	"We can do that." 
*if not (forthright > reserved)
	You shake your head. 
The setting isn't all that material to you, especially considering you're sure he'll take care to keep matters private either way. 

"Excellent," Iasion stands, exhaling in a large gust. "I'm just more comfortable moving, a lot of the time. Sitting still reminds me of all those interminable meetings I had to sit through. Important, but very, very hard on my focus. And occasionally my rear end." His grin widens for just a moment, and then he lifts the tent flap, following you out. 
*page_break
Things are mostly quiet while you get yourselves out of the camp and a ways beyond it, along the shore of the Styx. Greyish reeds of all sorts droop along the banks, pushing up stubbornly amidst the silt of the sloping ground, many outright sitting in the slow-moving water.

When you're well and truly away from the other spirits and settled into an easy amble, Iasion picks up the thread of the conversation. 

"So… I admit I had a list of things I wanted to ask you. Naturally, I've subsequently forgotten everything on it." He lifts his shoulders in a helpless shrug. "So I suppose… would you mind telling me what it was like, growing up? On Olympus, in general, whatever you prefer to talk about."

*fake_choice
	#It's nice to be asked, honestly, and I don't feel any need to keep anything back in my explanation.
		*set warm +1
		*set forthright +1
		It's nice to be asked, honestly, and you don't feel any need to keep anything back in your explanation. You've given versions of it a few times, by this point, to others in the Underworld, but Iasion makes it a proper conversation, asking all kinds of questions that you're only too happy to answer. 
		
		It meanders a little bit, but everything comes out, with time: 
		*label fullexplanation
		*if (opinion_olympus = "like")
			the way you'd always liked Olympus,
			*if (chose = "olympusmostly")
				and in fact would be living there still, if not for extenuating circumstances.
			*if ((result = "underworldmostlyouch") and (chose != "olympusmostly"))
				and had wound up living there part time, if perhaps a little less of a part than you might have liked.
			*if ((result = "threemonths") and (chose != "olympusmostly"))
				and had wound up living there for three months of the year, an arrangement which has yet to go into effect but that you think will be good for you.
			*if (result = "underworld")
				but had ended up liking the Underworld so much more as you found yourself with the freedom to explore an alternative way of life. And how you now live full time here, with no desire at all to go back.
			*if (result = "underworldmostly")
				but had ended up preferring the Underworld, especially as you found yourself with the freedom to explore an alternative way of life. And how you now live here for all but a little bit of each year, an arrangement which has yet to go into effect but that you think will be good for you.
			*if ((result = "split") or (result = "evensplit"))
				but had also wound up liking the Underworld, especially as you found yourself with the freedom to explore an alternative way of life. And how you now live here for part of each year and there for the other part,  an arrangement which has yet to go into effect but that you think will be good for you.
		*if (opinion_olympus = "dislike")
			the way you'd never been particularly fond of Olympus, really, 
			*if (chose = "olympusmostly")
				but had wound up missing it while you were in the Underworld, and choosing to live there, only to be overturned by extenuating circumstances. 
			*if ((result = "underworldmostlyouch") and (chose != "olympusmostly"))
				and had wound up choosing to live in the Underworld most of the time, albeit a 'most' more strictly-enforced than you would have liked. 
			*if ((result = "threemonths") and (chose != "olympusmostly"))
				but there was enough about it that you still cared for that you've wound up living there three months of the year, an arrangement which has yet to go into effect but that you think will be good for you.
			*if (result = "underworld")
				and that the Underworld had been in every way a better alternative, especially as you found yourself with the freedom to explore a different way of life. And now you live here full-time, with no desire at all to go back.
			*if (result = "underworldmostly")
				and that the Underworld had been in every way a better alternative, especially as you found yourself with the freedom to explore a different way of life. And now you live here for all but a little while each year, an arrangement which has yet to go into effect but that you think will be good for you.
			*if ((result = "split") or (result = "evensplit"))
				but even the Underworld hadn't appealed to you so much more that you'd abandoned it altogether. There were still things about it that you liked, enough for you to choose to divide your time roughly evenly between the two, an arrangement which has yet to go into effect but that you think will be good for you.
		*if (opinion_olympus = "likehome")
			the way you'd always liked Olympus, thought of it as your home, 
			*if (chose = "olympusmostly")
				and in fact would be living there still, if not for extenuating circumstances.
			*if ((result = "underworldmostlyouch") and (chose != "olympusmostly"))
				and, though the sense of home had come to feel less complete, you had wound up living there part time, if perhaps a little less of a part than you might have liked.
			*if ((result = "threemonths") and (chose != "olympusmostly"))
				and, though the sense of home had come to feel less complete, you had wound up living there for three months of the year, an arrangement which has yet to go into effect but that you think will be good for you.
			*if (result = "underworld")
				but had ended up liking the Underworld so much more as you found yourself with the freedom to explore an alternative way of life. And how you now live full time here, with no desire at all to go back, that sense of home entirely replaced.
			*if (result = "underworldmostly")
				but had ended up preferring the Underworld, especially as you found yourself with the freedom to explore an alternative way of life. And how you now live here for all but a little bit of each year, an arrangement which has yet to go into effect but that you think will be good for you. The sense of home is certainly something that has shifted, and mostly settled here instead.
			*if ((result = "split") or (result = "evensplit"))
				but had also wound up liking the Underworld, especially as you found yourself with the freedom to explore an alternative way of life. And how you now live here for part of each year and there for the other part,  an arrangement which has yet to go into effect but that you think will be good for you. You have two homes, now, and both of them are beloved.
		*if (opinion_olympus = "dislikehome")
			the way you'd never been particularly fond of Olympus, really, but had thought of it as your home.
			*if (chose = "olympusmostly")
				The way you had wound up missing it while you were in the Underworld, and choosing to live there, only to be overturned by extenuating circumstances. 
			*if ((result = "underworldmostlyouch") and (chose != "olympusmostly"))
				The way you had wound up choosing to live in the Underworld most of the time, albeit a 'most' more strictly-enforced than you would have liked. Because now, you know what a home really feels like.
			*if ((result = "threemonths") and (chose != "olympusmostly"))
				The way there was enough about it that you still cared for that you've wound up living there three months of the year, an arrangement which has yet to go into effect but that you think will be good for you. 
			*if (result = "underworld")
				The way the Underworld had been in every sense a better alternative, especially as you found yourself with the freedom to explore a different way of life. And now you live here full-time, with no desire at all to go back. Because now, you know what a home really feels like. 
			*if (result = "underworldmostly")
				The way the Underworld had been in every sense a better alternative, especially as you found yourself with the freedom to explore a different way of life. And now you live here for all but a little while each year, an arrangement which has yet to go into effect but that you think will be good for you. 
			*if ((result = "split") or (result = "evensplit"))
				The way even the Underworld hadn't appealed to you so much more that you'd abandoned it altogether. There were still things about it that you liked, enough for you to choose to divide your time roughly evenly between the two, an arrangement which has yet to go into effect but that you think will be good for you.
			
			And then your childhood itself, growing up there, 
			*if (opinion_childhood = "wantfreedom")
				and how you'd always chafed at the restrictions set in place for you. You know they were intended to keep you safe, but it wasn't [i]safe[/i] you most needed to be. 
				
				It was [i]free[/i].
			*if (opinion_childhood = "understand")
				and how you'd always been restricted by the need for your own safety, in an environment where your mother could only guarantee it under close watch. How you'd always understood it, but wondered if maybe there wasn't a whole world of experiences you were missing out on, nonetheless. 
			
			Iasion listens to all of it, adding the occasional anecdote about Samothrace or his own upbringing. Yours and his have almost nothing in common, save perhaps high parental expectations, but the differences are as interesting as the similarity. 
	#I give a reasonably complete explanation, organizing the important points in my mind and laying them out deliberately. If he wants to know, I'll tell him.
		*set cold +1
		*set forthright +1
		You give a reasonably complete explanation, organizing the important points in your mind and laying them out deliberately. If he wants to know, you'll tell him.
		
		Perhaps because of this internal sense of organization, the conversation is almost systematic, each topic being thoroughly explored before moving on to the next:
		*goto fullexplanation
	#I'm not comfortable talking about absolutely everything, but I'll happily give him the basic idea, at least. It feels good that he wants to know.
		*set warm +1
		*set reserved +1
		You're not comfortable talking about absolutely everything, but you'll happily give him the basic idea, at least. It feels good that he wants to know. You've given versions of this explanation a few times before, o the others in the Underworld, but Iasion makes it a proper conversation, asking all kinds of questions, some of which you're quite happy to answer, and others which you sidestep with no protest from him. 
		
		It meanders a little bit, but everything you want to say comes out, with time:
		*label partialexplanation
		*if (opinion_olympus = "like")
			the way you'd always liked Olympus,
			*if (chose = "olympusmostly")
				and in fact would be living there still, if not for extenuating circumstances.
			*if ((result = "underworldmostlyouch") and (chose != "olympusmostly"))
				and had wound up living there part time, if perhaps a little less of a part than you might have liked.
			*if ((result = "threemonths") and (chose != "olympusmostly"))
				and had wound up living there for three months of the year, an arrangement which has yet to go into effect but that you think will be good for you.
			*if (result = "underworld")
				but had ended up liking the Underworld so much more as you found yourself with the freedom to explore an alternative way of life. And how you now live full time here, with no desire at all to go back.
			*if (result = "underworldmostly")
				but had ended up preferring the Underworld, especially as you found yourself with the freedom to explore an alternative way of life. And how you now live here for all but a little bit of each year, an arrangement which has yet to go into effect but that you think will be good for you.
			*if ((result = "split") or (result = "evensplit"))
				but had also wound up liking the Underworld, especially as you found yourself with the freedom to explore an alternative way of life. And how you now live here for part of each year and there for the other part,  an arrangement which has yet to go into effect but that you think will be good for you.
		*if (opinion_olympus = "dislike")
			the way you'd never been particularly fond of Olympus, really, 
			*if (chose = "olympusmostly")
				but had wound up missing it while you were in the Underworld, and choosing to live there, only to be overturned by extenuating circumstances. 
			*if ((result = "underworldmostlyouch") and (chose != "olympusmostly"))
				and had wound up choosing to live in the Underworld most of the time, albeit a 'most' more strictly-enforced than you would have liked. 
			*if ((result = "threemonths") and (chose != "olympusmostly"))
				but there was enough about it that you still cared for that you've wound up living there three months of the year, an arrangement which has yet to go into effect but that you think will be good for you.
			*if (result = "underworld")
				and that the Underworld had been in every way a better alternative, especially as you found yourself with the freedom to explore a different way of life. And now you live here full-time, with no desire at all to go back.
			*if (result = "underworldmostly")
				and that the Underworld had been in every way a better alternative, especially as you found yourself with the freedom to explore a different way of life. And now you live here for all but a little while each year, an arrangement which has yet to go into effect but that you think will be good for you.
			*if ((result = "split") or (result = "evensplit"))
				but even the Underworld hadn't appealed to you so much more that you'd abandoned it altogether. There were still things about it that you liked, enough for you to choose to divide your time roughly evenly between the two, an arrangement which has yet to go into effect but that you think will be good for you.
		*if (opinion_olympus = "likehome")
			the way you'd always liked Olympus, thought of it as your home, 
			*if (chose = "olympusmostly")
				and in fact would be living there still, if not for extenuating circumstances.
			*if ((result = "underworldmostlyouch") and (chose != "olympusmostly"))
				and, though the sense of home had come to feel less complete, you had wound up living there part time, if perhaps a little less of a part than you might have liked.
			*if ((result = "threemonths") and (chose != "olympusmostly"))
				and, though the sense of home had come to feel less complete, you had wound up living there for three months of the year, an arrangement which has yet to go into effect but that you think will be good for you.
			*if (result = "underworld")
				but had ended up liking the Underworld so much more as you found yourself with the freedom to explore an alternative way of life. And how you now live full time here, with no desire at all to go back, that sense of home entirely replaced.
			*if (result = "underworldmostly")
				but had ended up preferring the Underworld, especially as you found yourself with the freedom to explore an alternative way of life. And how you now live here for all but a little bit of each year, an arrangement which has yet to go into effect but that you think will be good for you. The sense of home is certainly something that has shifted, and mostly settled here instead.
			*if ((result = "split") or (result = "evensplit"))
				but had also wound up liking the Underworld, especially as you found yourself with the freedom to explore an alternative way of life. And how you now live here for part of each year and there for the other part,  an arrangement which has yet to go into effect but that you think will be good for you. You have two homes, now, and both of them are beloved.
		*if (opinion_olympus = "dislikehome")
			the way you'd never been particularly fond of Olympus, really, but had thought of it as your home.
			*if (chose = "olympusmostly")
				The way you had wound up missing it while you were in the Underworld, and choosing to live there, only to be overturned by extenuating circumstances. 
			*if ((result = "underworldmostlyouch") and (chose != "olympusmostly"))
				The way you had wound up choosing to live in the Underworld most of the time, albeit a 'most' more strictly-enforced than you would have liked. Because now, you know what a home really feels like.
			*if ((result = "threemonths") and (chose != "olympusmostly"))
				The way there was enough about it that you still cared for that you've wound up living there three months of the year, an arrangement which has yet to go into effect but that you think will be good for you. 
			*if (result = "underworld")
				The way the Underworld had been in every sense a better alternative, especially as you found yourself with the freedom to explore a different way of life. And now you live here full-time, with no desire at all to go back. Because now, you know what a home really feels like. 
			*if (result = "underworldmostly")
				The way the Underworld had been in every sense a better alternative, especially as you found yourself with the freedom to explore a different way of life. And now you live here for all but a little while each year, an arrangement which has yet to go into effect but that you think will be good for you. 
			*if ((result = "split") or (result = "evensplit"))
				The way even the Underworld hadn't appealed to you so much more that you'd abandoned it altogether. There were still things about it that you liked, enough for you to choose to divide your time roughly evenly between the two, an arrangement which has yet to go into effect but that you think will be good for you.
			
			You keep your opinion of your upbringing to yourself, for the most part, simply talking about it in factual terms: what you did, rather than what you didn't or couldn't do, things like that. 
			
			Iasion listens to all of it, adding the occasional anecdote about Samothrace or his own upbringing. Yours and his almost nothing in common, save perhaps high parental expectations, but the differences are as interesting as the similarity. 
	#There are certain things I will definitely be omitting, but a clear, organized explanation of the basic contours is certainly within my abilities to give, if he wants it. 
		*set cold +1
		*set reserved +1
		There are certain things you will definitely be omitting, but a clear, organized explanation of the basic contours is certainly within your abilities to give, if he wants it. 
		
		Perhaps because of this internal sense of organization, the conversation is almost systematic, each topic being thoroughly explored before moving on to the next:
		*goto partialexplanation
*page_break
"So, you wound up here because of the whole marriage thing," he muses, when you come to the end of your explanation. "That makes sense, with what Demeter told me. That must have been… some experience. I managed to avoid an arranged marriage, thankfully; the island didn't really need a whole lot more than what it had, and by the time my parents would have been looking at that kind of thing for me, they were already gone. Being a king has some benefits, I suppose."

His nose crinkles with distaste. "I can't imagine His Majesty had… particularly good intentions, with it. You hear all the time about the Underworld, and how awful it is. I can't speak to the typical experience, obviously, but I think I can see how this part might wear on someone, at least." 

*if (((birthannounced = "male") and (tag_trans = false)) and (tag_nonbinary = false))
	He pauses, hesitating. "And, well… I've never heard of an alliance marriage between two men, before. But then, I guess the gods have less concern about dynasties than humans do."

*fake_choice
	#@{convotoggle [☆]|} "Oh, his intentions were terrible all the way down, no doubt. Unfortunately for him, it backfired spectacularly."
		*set humorous +1
		*set confident +1
		"Oh, his intentions were terrible all the way down, no doubt. Unfortunately for him, it backfired spectacularly." It still baffles you, sometimes, how mistaken he has to have been about almost everyone involved, not to have realized things would turn out as they did. 
		
		"I have to suppose it did, if you wound up here on a more permanent basis," Iasion replies with a hint of humor. 
		*if (result != "underworld")
			"Even if it's not all the time, it's still a lot of it." 
		
		You nod. "It ended up suiting me, I suppose. But more than just the place, I think he completely misunderstood the people, in some combination." 
		
		"I have to suppose you most of all." Your father offers you a hint of a smile. "Just based on what you told me, I think if I were looking to make things difficult for you, I wouldn't choose putting you into an unusual environment. Not that I've thought too much about it, mind."
		
		"I'd certainly [i]hope[/i] you haven't."
	#@{convotoggle [☆]|} "Well... I don't think he was looking to make any part of it typical, or even comfortable. Which... sort of came back to bite him, I think."
		*set humorous +1
		*set unsure +1
		"Well... I don't think he was looking to make any part of it typical, or even comfortable. Which... sort of came back to bite him, I think." On the surface, you can sort of understand the reasoning, but it's a little funny, too, just how badly it worked out with respect to his original aim. 
		
		Iasion chuckles. "I'll say. You wound up here on a more permanent basis." He shakes his head. 
		*if (result != "underworld")
			"Even if it's not full-time, it's time enough that he looks pretty foolish for thinking it was some kind of punishment." 
		
		You nod. "I suppose… it ended up suiting me. The place, but also the people. It's not surprising to me that he misunderstood everyone involved; before you spend any time here, I think that's easy to do." 
		
		"Seems like he misunderstood you most of all, though." Your father offers you a hint of a smile. "Just based on what you told me, I think if I were looking to make things difficult for you, I wouldn't choose putting you into an unusual environment. Not that I've thought too much about it, mind."
		
		"Well, I admit I'm glad to hear the last part."
	#"I don't doubt for a moment that his real goal was to make [i]Demeter[/i] as frustrated and concerned as possible. The rest of us were just collateral damage."
		*set serious +1
		*set confident +1
		"I don't doubt for a moment that his real goal was to make [i]Demeter[/i] as frustrated and concerned as possible. The rest of us were just collateral damage." things make much more sense if you think of them that way. While you don't think Zeus fully understands anyone here by any stretch of the imagination, he likely has [i]some[/i] sense of how his brother runs things. Meaning that, if he'd genuinely cared for making [i]you[/i] miserable, it was a terrible plan.
		
		Your mother, on the other hand, would have little to go on but rumor and reputation, and her ability to speak to you directly was taken from her. No matter what you conveyed by letter, she would find a way to worry. So if his plan was to hurt [i]her[/i], he'd succeeded spectacularly. 
		
		He might act the arrogant buffoon at times, but there is cunning there. 
		
		"I suppose that makes sense," Iasion replies somberly. "When I knew her, he was certainly the biggest thorn in her side. I remember feeling quite powerless to do anything about it—it's probably good that I wasn't quite stupid enough to take him to task for it. I wouldn't be much good to anyone charred, I suppose."
		
		"It is… certainly preferable that you aren't, yes."
	#"It's... I'm sure there were a lot of things at play in the decision. But no, the intentions weren't what anyone would call 'good.'"
		*set serious +1
		*set unsure +1
		"It's... I'm sure there were a lot of things at play in the decision. But no, the intentions weren't what anyone would call 'good.'" You have to suppose that the main point, of course, was to distress your mother, and in that sense, it went off without a hitch. The rest, if perhaps your own frustration or Hades's could be counted as a secondary goal… less so. 
		
		But then, that's part of the reason you can guess it was secondary. Zeus might act the arrogant buffoon at times, but there is cunning there. 
		
		"It's a little difficult to get my head around divine politics," Iasion admits, somberly. "There are fewer players, they're all individuals, and most of them carry eons of history with them. It's… a different beast to the human kind, to be sure." 
		
		*if (job = "minister")
			"Well, not always," you reply. "I'm sort of involved myself, now. It's definitely not easy, and everything moves [i]very slowly[/i] to me, but I'm not that old and I don't find myself completely out of my depth too often." 
			
			Maybe a bit, at the trial. But you think [i]everyone[/i] was a bit out of their depth, there.
		*if (job != "minister")
			"I wouldn't really be able to compare them," you point out. "I don't have that much experience with either." 
			
			There had been the trial, of course, but you'd been completely out of your depth, there. Then again, it sort of seemed like everyone had. 
	*if (((birthannounced = "male") and (tag_trans = false)) and (tag_nonbinary = false))
		#"I'm sure the last part was intended to make me more uncomfortable. Little did he know I have no objections to being married to another man, per se. There was plenty else to object to, of course."
			"I'm sure the last part was intended to make me more uncomfortable. Little did he know I have no objections to being married to another man, per se. There was plenty else to object to, of course." You aren't sure if he'd taken a guess he was wrong about or simply counted on the unconventional nature of such an arrangement to throw you off. Perhaps it was hardly a factor. In any case, it didn't make matters any more difficult or awkward than they were already going to be. 
			
			Iasion takes your hint and smiles. "Can't say it would have bothered me, per se, either," she says with a shrug. "No more than any other marriage would have. Which is the small downside to falling irrevocably in love with someone in the part of your life where you're being told to be 'responsible' about that sort of thing." 
			
			You can't help but smile a little at that. "You got out of it just by being king, or…?"
			
			He chuckles. "Mostly. It turns out that if your nation is small and content enough, no one can really [i]make[/i] the king do much of anything. Even if I did have to concede in a lot of other ways because of it." He shakes his head. "Honestly, the human version of politics is hard enough. It's hard to get my head around the divine kind. There are fewer players, they're all individuals, and most of them carry eons of history with them. It's… a different beast, to be sure." 
		
			*if (job = "minister")
				"Well, not always," you reply. "I'm sort of involved myself, now. It's definitely not easy, and everything moves [i]very slowly[/i] to me, but I'm not that old and I don't find myself completely out of my depth too often." 

				Maybe a bit, at the trial. But you think [i]everyone[/i] was a bit out of their depth, there.
			*if (job != "minister")
				"I wouldn't really be able to compare them," you point out. "I don't have that much experience with either." 

				There had been the trial, of course, but you'd been completely out of your depth, there. Then again, it sort of seemed like everyone had. 	
	*if (((birthannounced = "male") and (tag_trans = false)) and (tag_nonbinary = false))
		#"He probably intended to make things as inconvenient as possible. And it's true that I'm incompatible with other men, but it really didn't work as he'd wanted." 
			"He probably intended to make things as inconvenient as possible. And it's true that I'm incompatible with other men, but it really didn't work as he'd wanted." After all, the marriage itself had ended up being a nonissue. Right out of the gate, you knew that Hades thought it as much of a sham as you did, for at least most of the same reasons. 
			
			You have no idea if he's attracted to other men or not, but you know for certain that he'd never be interested in pursuing someone who wasn't also interested in him, and that was an easy thing to rely on. 
			
			Iasion smiles. "I sort of figured, given that you ended up liking it here. It was just the sort of move you don't see in human politics. I had to work my way out of a fair bit of pressure to marry, but it was always a woman that was at issue. Life certainly would have been a lot [i]easier[/i] if I hadn't fallen irrevocably in love with someone in the part of my life where everyone thought I needed to be 'responsible' about that kind of thing."
			
			You can't help but smile a little at that. "You got out of it just by being king, or…?"
			
			He chuckles. "Mostly. It turns out that if your nation is small and content enough, no one can really [i]make[/i] the king do much of anything. Even if I did have to concede in a lot of other ways because of it." He shakes his head. "Honestly, the mortal sort of politics is hard enough. It's hard to get my head around the divine kind. There are fewer players, they're all individuals, and most of them carry eons of history with them. It's… a different beast, to be sure." 
		
			*if (job = "minister")
				"Well, not always," you reply. "I'm sort of involved myself, now. It's definitely not easy, and everything moves [i]very slowly[/i] to me, but I'm not that old and I don't find myself completely out of my depth too often." 

				Maybe a bit, at the trial. But you think [i]everyone[/i] was a bit out of their depth, there.
			*if (job != "minister")
				"I wouldn't really be able to compare them," you point out. "I don't have that much experience with either." 

				There had been the trial, of course, but you'd been completely out of your depth, there. Then again, it sort of seemed like everyone had.
*page_break
He tilts his head at you for a moment, quiet for the next several meters. 

"You know, it… you're incredible, you know? You've been through some things most other people would find it hard to imagine. Not the arranged marriage itself, exactly—those are common enough. But being a demi${god} on Olympus, then suddenly being told you live somewhere else, with a basket of strangers, and I can only imagine that it's tremendous whiplash, as environments go. Even if you turned out enjoying it, it takes a lot of resilience just to get [i]used[/i] to a new place like that. Especially when none of your own choices are involved."

He shakes his head. "Then to navigate a hearing with Zeus himself… I definitely don't think I could do that part with any semblance of skill."

*fake_choice
	#"What about you? Would you say more about how you got here?"
		"What about you? Would you say more about how you got here?" You know the broad contours of it by this stage, of course, but he hasn't spoken much about the war involved, or even particularly about how life was on Samothrace. You find that you want to know as much about him as he now knows about you. Perhaps even more. 
		
		Iasion hums, low in the back of his throat, folding his arms over his chest as he walks. "I could," he replies with a nod, "but I suppose I'm not sure what's… it's hard to find a simple, anecdotal way to describe a war. The systematic, logical type of explanation misses something important, but if we get into all the feelings I have about it, we won't be done with this conversation for another year, at least." 
		
		A breath puffs out through his nose. "It's an old war, by now. In a lot of ways. A lot of it came down to sitting around waiting for things to happen. That's the heart of it: interminable [i]waiting[/i], between short bursts of seeing and doing things that rip you apart. And sometimes being literally ripped apart, by the other side's weapons. That's almost the easiest bit, if I'm really honest. I don't have nightmares about getting stabbed." 
		
		You nod slightly, just showing that you're listening. 
		
		"Anyway, it… I don't think I want to say much more about it than that. Maybe some other day. In either case, it's how I ended up here. How most of these people did. I can understand why it might take them a while to learn to let it go. I can't. Not yet."
		
		You press your lips together. Perhaps that makes the part you've come to officially convey a little less likely to matter, but you should probably say it anyway, at some point. 
	#"I'm not sure that there's anything too incredible about it. I just got through things day by day."
		*set serious +1
		"I'm not sure that there's anything too incredible about it. I just got through things day by day." When it comes right down to it, to your mind, it's sort of what he said: lots of people deal with arranged marriages of one stripe or another, and for you, that was really the main inconvenience of it all. One that turned out not to be all that inconvenient in the first place. 
		
		His lips quirk. "I suppose that's a fair way of looking at it. As long as the day to day of it was manageable, almost any situation could be. And it seems like you've fit in well down here, so I suppose it's less extreme than it sounds, on the surface." 
		
		That was, somehow, a rather quicker understanding of the reality than you'd expected. 
		
		"You're… not going to argue that it must have been terrible?" 
		
		Iasion snorts. "Why would I? I don't know anything about it. If you say it wasn't, it's easy to believe you."
		
		Perhaps that fact about him will make the next bit of things easier to understand, as well. You've come here in part to convey something a little more official, after all, and this seems as good a time as any to do that. 
	#"It was hardly a great trial, really. There were certainly difficult parts, but those came more from ongoing problems in the Underworld than my situation itself."
		*set serious +1
		"It was hardly a great trial, really. There were certainly difficult parts, but those came more from ongoing problems in the Underworld than my situation itself." The Giant attack, Lethe's sickness… well, Kronos, really, was at the heart of most of the problems you encountered. Other things, like Orpheus's unexpected visit weren't really what you'd call [i]problems[/i], even if the were rather large departures from the ordinary flow of things. 
		
		The situation itself is basically just what he said: lots of people deal with arranged marriages of one stripe or another, and for you, that was really the main inconvenience of it all. One that turned out not to be all that inconvenient in the first place. 
		
		"I can imagine those were… challenging," Iasion says, a touch of wryness in his tone. "Not that I can imagine exactly what they [i]were[/i]. I know so little about anything here, but it already seems much more structured than I imagined it, somehow. More… civilized, if that makes sense?" 
		
		"I think so." At least, you can see where he might have thought it would be more chaotic here. That's supposedly built into the realm, though you've only ever seen small manifestations of that.
		
		Thinking about this subject, though, has reminded you of another. You've come here in part to convey something a little more official, after all, and this seems as good a time as any to do that. 
	#@{convotoggle [☆]|} "Ah yes, the great struggle I went through, meeting nice people and exploring my hobbies. A terrible trial."
		*set humorous +1
		"Ah yes, the great struggle I went through, meeting nice people and exploring my hobbies. A terrible trial." You can't help but laugh a little at your own joke. Really, though, he makes it sound like something much more challenging than it was, which you suppose is understandable from the outside. 
		
		But really, it's sort of what he said: lots of people deal with arranged marriages of one stripe or another, and for you, that was really the main inconvenience of it all. One that turned out not to be all that inconvenient in the first place. 
		
		And on top of it, you came out of the whole thing with friends and a place to live, and things that have meaning to you that you can spend your time on. It's hard to see the downsides when you remember all you've gained from it. 
		
		Iasion chuckles, too, shaking his head. "Fair point, I suppose. Those were… a little less obvious on the surface. it seems like you've fit in well down here, so I suppose the Underworld must be less extreme than it sounds." 
		
		That was, somehow, a rather quicker understanding of the reality than you'd expected. 
		
		"You're… not going to argue that it must have been terrible? I confess I was expecting you to argue it must have been terrible." 
		
		Iasion snorts. "Why would I? I don't know anything about it. If you say it wasn't, it's easy to believe you."
		
		Perhaps that fact about him will make the next bit of things easier to understand, as well. You've come here in part to convey something a little more official, after all, and this seems as good a time as any to do that. 
	#@{convotoggle [☆]|} "And you haven't even heard about the Giant attack yet."
		*set humorous +1
		"And you haven't even heard about the Giant attack yet." You can't help but laugh a little at your own joke. But really, if he thinks that the parts he knows about were anything [i]difficult[/i], you have to wonder how he'll think of something like [i]that[/i]. 
		
		"You mean the one where you ended up unconscious at the end?" he asks, one side of his mouth curling up. "I might have come across some mention of that, actually. Though I don't know the exact details of what happened or how." 
		
		"You could have pretended like you hadn't. I thought that was a great comedic setup I gave you, just there." 
		
		"It was. But I have to admit the comedy potential was not the first thought on my mind, when it comes to that incident." One of his brows ticks up, and he huffs softly. "Perhaps it should have been; you're clearly quite fine in spite of it." 
		
		"You know, it's a little refreshing that you don't insist I must have constantly suffered here. I'm not sure that's something most people would easily believe." 
		
		Iasion snorts. "Why would I? I don't know anything about it. If you say you didn't, it's easy to believe you."
		
		Perhaps that fact about him will make the next bit of things easier to understand, as well. You've come here in part to convey something a little more official, after all, and this seems as good a time as any to do that.		
*page_break
You clear your throat. "Actually, I had another reason for coming here, besides catching up." You glance towards him, watching as he nods once, a bit more slowly than usual.

"I won't say I knew that, but I had wondered," he replies, folding his arms behind his back. "Something fairly serious, then?"

You nod as well. "It's somewhat complicated, and also vague, but we decided it would be worth it to tell you anyway. I… assume you know who Kronos is?" 

Iasion blinks; whatever direction he'd been expecting the conversation to go in, this is not it. "I've heard of him, yes. The father of Zeus, Poseidon, and Hades, and formerly king of the Titans? Well, I assume he's probably still their king, but they're collectively much less of an entity now, yes?" 

"Right. He… currently lives here. For some reason, Zeus has put him in charge of the Blesséd Isles. He was responsible for a lot of the problems that happened when I first came here, and for some reason, he seems interested in those of you that just arrived from above." 

That's about as well as you can summarize what you've been told; since no one has any idea of his motive or potential plan, it's not as though you can tell him to be wary of anything in particular. 

Iasion takes this in for a few moments, looking out at the river with a contemplative expression. "And you think his interest might not be benign." 

*if (humorous > serious)
	"I'm not sure if his interest is [i]ever[/i] benign," you say with a chuckle. It might be a serious matter, but sometimes a joke is just as good at conveying what's true.
*if not (humorous > serious)
	"It seems unlikely, given the other things he's been responsible for." You may not be able to say anything with complete certainty, but in some ways, Kronos's past behavior speaks for itself.

"I see. I'm not sure exactly how much I can prepare for something I don't really know about, but I'll keep my eyes open, nonetheless. It might have something to do with how many of these men are going to end up on the Isles. Some of them are the bravest, most pious and honorable people I know, after all."

*fake_choice
	#"Do you think... there might be a chance you end up there, after judgement?"
		"Do you think... there might be a chance you end up there, after judgement?" He's mentioned those with him, after all. You don't think it would be any great stretch to suppose that he, as their leader, would share those qualities, and as far as you can tell, courage and honor at least are traits that would give someone a better chance of ending up on the Isles. 
		
		"Me?" The question seems rhetorical; Iasion at least does not seem to be surprised that you've asked it. "I don't know," he admits. "I've done many things in my life that might be questionable. There are times, even, when I have cursed the gods. Times when I have chosen selfishly for my people over our neighbors. Times when I have resented my duty and wished to forsake honor. I hope I have lived well, but I am no judge, to know with any certainty." 
	#I can't ask him about himself, in that regard. It would imply pressure, and that's not something I want to put on him.
		You can't ask him about himself, in that regard. It would imply pressure, and that's not something you want to put on him. You don't [i]think[/i] it would be any great stretch to suppose that he, as their leader, would share those qualities, and as far as you can tell, courage and honor at least are traits that would give someone a better chance of ending up on the Isles. But there's a difference between supposing all of that and asking him to speculate on the next stage of his fate. 
		
		He studies you curiously for a moment, a twitch at the corner of his mouth. "I've done many things in my life that might be questionable," he says conversationally. "There are times, even, when I have cursed the gods. Times when I have chosen selfishly for my people over our neighbors. Times when I have resented my duty and wished to forsake honor. I hope I have lived well, but I am no judge, to know with any certainty." 
		
		A pause. "Just… in case you were wondering."
	#"I've spoken to some others about this, and they seem to think there's a pretty good chance [i]you[/i] might end up on the Isles, after you're judged."
		"I've spoken to some others about this, and they seem to think there's a pretty good chance [i]you[/i] might end up on the Isles, after you're judged." The fact that he's mentioned those with him is only a bit more evidence in favor of that hypothesis. You don't think it would be any great stretch to suppose that he, as their leader, would share those qualities, and as far as you can tell, courage and honor at least are traits that would give someone a better chance of ending up on the Isles. 
		
		"Me?" The question seems rhetorical; Iasion at least does not seem to be surprised that you've asked it. "I don't know," he admits. "I've done many things in my life that might be questionable. There are times, even, when I have cursed the gods. Times when I have chosen selfishly for my people over our neighbors. Times when I have resented my duty and wished to forsake honor. I hope I have lived well, but I am no judge, to know with any certainty." 
*page_break
"In any case," he adds, expression sobering, "I have to admit that while I've never aimed for a blesséd afterlife, I hope for one, now. It might allow me the chance at some sort of proper kinship with you… if that's something you would be interested in."

*fake_choice
	#"Of course I would be!"
		*set iasion_wantrelationship true
		"Of course I would be!" You jump on the offer immediately. It's something that had been in the back of your mind, already, but you hadn't been entirely sure how to broach the topic. Since Iasion's done that part himself, you can easily give him an answer. 
		
		The breadth of his smile can only be the same as yours: the kind that makes your cheeks hurt, just a little. "That's… you don't know how glad I am to hear that, ${name}. Or, honestly, maybe you do. I'm not sure if [i]I[/i] quite grasp how glad I am, right now." He laughs, a hint of nerves on the edge of it, but it's nevertheless a delighted sound. 
		
		*if ((touch2 = "averse") or ((touch = "averse") and (touch2 = "unknown")))
			"You, uh. Your mother said you weren't one for touching, so I won't ask for anything along those lines, but… know that this is the kind of thing I would normally be wanting to hug you about. It's a really… shockingly-good feeling, actually. I hope you feel a little bit of that, too." 
			
			*label nothugchoice
			*fake_choice
				#"I do, and thank you."
					"I do, and thank you." Your smile remains, and his softens in response. 
					
					"Good. That's… really good."
				#"I'm not really sure what the urge to hug anyone feels like, but I can agree with the rest."
					"I'm not really sure what the urge to hug anyone feels like, but I can agree with the rest." Your smile remains, and his softens in response. 
					
					"Good. That's… really good."
				#"That's not my favorite metaphor, but the sentiment is appreciated."
					"That's not my favorite metaphor, but the sentiment is appreciated." Your smile becomes something a little different, and his softens in response. 
					
					"That's… fair. I'll need to figure out a better way to describe it, but… thanks."
		*if not ((touch2 = "averse") or ((touch = "averse") and (touch2 = "unknown")))
			Stopping, he spreads his arms out towards you, tilting his head in a querying manner. 

			"No, um. No hard feelings if this feels like a bit much, right now." 

			*label hugchoice
			*fake_choice
				#I step into the embrace readily.
					You step into the embrace readily, and his arms wind around you. They're—perhaps you shouldn't be surprised by how much strength you feel in them. He's not entirely human, after all, and a soldier besides. It's a very [i]secure[/i] hug, and you squeeze back a little as he pats your back firmly before letting go. 
					
					A short thing, but emphatic, and enough that the smile on your face does not dim. 
				#It [i]is[/i] a little strange, but I want to try it anyway.
					It [i]is[/i] a little strange, but you want to try it anyway, so you step into it with only a bit of caution, and his arms wind around you. They're—perhaps you shouldn't be surprised by how much strength you feel in them. He's not entirely human, after all, and a soldier besides. It's a very [i]secure[/i] hug, and you squeeze back a little as he pats your back firmly before letting go. 
					
					A short thing, but emphatic, and enough that the smile on your face does not dim. 
				#"Maybe for right now, but ask again later." 
					"Maybe for right now, but ask again later." You're still very new to each other, after all. Perhaps such physical gestures are something you could work up to, but you're definitely not there yet. 
					
					"No problem," he replies, letting his hands drop back to his sides. If he's disappointed, he hides it well; his grin doesn't even slip. Perhaps he isn't.
	#"I think... I think that would be nice, if we get the chance."
		*set iasion_wantrelationship true
		"I think... I think that would be nice, if we get the chance." It's hard to feel the same way about it as you would if anything were guaranteed, but in spite of your caution, you [i]do[/i] want to say at least this much. You want a relationship with him, and you can admit that you're hoping you get one. 
		
		You offer him a tentative smile, one that he returns with a much broader grin. "That's… you don't know how glad I am to hear that, ${name}. Or, honestly, maybe you do. I'm not sure if [i]I[/i] quite grasp how glad I am, right now." He laughs, a hint of nerves on the edge of it, but it's nevertheless a delighted sound. 
		
		*if ((touch2 = "averse") or ((touch = "averse") and (touch2 = "unknown")))
			"You, uh. Your mother said you weren't one for touching, so I won't ask for anything along those lines, but… know that this is the kind of thing I would normally be wanting to hug you about. It's a really… shockingly-good feeling, actually. I hope you feel a little bit of that, too." 
			*goto nothugchoice
		*if not ((touch2 = "averse") or ((touch = "averse") and (touch2 = "unknown")))
			Stopping, he spreads his arms out towards you, tilting his head in a querying manner. 

			"No, um. No hard feelings if this feels like a bit much, right now." 
			*goto hugchoice
	#"That's not something I can decide until I know whether it's really an option. I hope you understand."
		"That's not something I can decide until I know whether it's really an option. I hope you understand." You shake your head with a twinge of regret. It would be [i]better[/i] if you could give him a proper answer right now, but too many things are up in the air for you to be comfortable with that. There's just no telling what happens in the near future, and you can't commit to anything one way or the other without more information. 
		
		Iasion nods, his expression remaining one of open, pleasant neutrality. You have to imagine the answer is a disappointment, but he doesn't go to the length of indicating as much. 
		
		"I understand," he says quietly. "I think I'm used to a lot of things in life being unreliable, but it's different for someone in your position. So… wait it out if that's what you need. I'm always here if you just want to talk, and I won't assume it means anything if you do." 
		
		Something tight in your chest eases, just a little.
	#"Let's not jump all the way to that conclusion. We can talk more, for now, but I'm not committing to treating you like my father."
		"Let's not jump all the way to that conclusion. We can talk more, for now, but I'm not committing to treating you like my father." There's the uncertainty of his fate to consider, of course, but it's not [i]just[/i] that. You're still basically strangers to one another, even if talking has helped ease the sense of that a bit. 
		
		Whether you'll end up wanting a closer relationship with him or not isn't something that can be decided with so little interaction, though. 
		
		Iasion nods, his expression remaining one of open, pleasant neutrality. You have to imagine the answer is a disappointment, but he doesn't go to the length of indicating as much. 
		
		"I understand," he says quietly. "We're definitely not starting on the same footing, to put it one way. I'm always here if you just want to talk, and I won't assume it means anything if you do." 
		
		You feel yourself relax fractionally. 
*page_break
The two of you walk for a while longer, sometimes talking and sometimes just ambling along, but in time, you both have other things to return to. And so you part ways: he to the riverbank, and you once more to your home.
*set met_iasion true
*goto ro_scenehub

*label iasiondemeter
*page_break
*set iasion_sequel_2 true
*set iasion2 "demeter"
And so, after an hour or so to get something to eat and otherwise prepare, you reunite with your mother and lead her in the direction of Iasion's current residence. 

It's a strange facsimile of a war camp, the place where your father's spirit dwells. Dozens of other spirits move about, some drilling with weapons, others clustered around in groups socially, but it certainly yet has that atmosphere, and you wonder how long it will take everyone within to come to terms with the fact that they are dead. That there are no more enemies to fight. 
	
Shaking your head, you head further in. 
*if (met_iasion)
	You remember which tent is his, and it isn't difficult to find.
*if not (met_iasion)
	You've not been within the camp before, but Hermes described his tent to you, and it's easy enough to find, being the largest in this particular cluster of them. 
	
As it turns out, the man you're looking for is just emerging from the tent as you approach, face creased in thought. 

*if not (met_iasion)
	He's of middling height for a human, you think, perhaps a fraction taller than Hermes, and his posture, upright and steady, tells you he carries himself with a certain dignity. 
	*if (skintone = "light brown")
		The tone of his skin is a little deeper than yours, marked here and there with scars of lighter or darker hue.
	*if (skintone = "pale")
		The tone of his skin is almost as pale as yours, save a little touch of the sun, and marked here and there with white or pink scars.
	*if (skintone = "tan")
		The tone of his skin is a little more darkly-tanned than yours, most likely due to the sun, and marked here and there with white and pink scars. 
	*if (skintone = "tawny")
		The tone of his skin is tawny like yours, made just a little darker, perhaps, by the sun, and marked here and there with scars of lighter or deeper hue. 
	*if (skintone = "medium brown")
		The tone of his skin is similar to yours, perhaps a shade darker, and marked here and there with scars of lighter or deeper hue.
	*if (skintone = "dark brown")
		His skin is an even deeper brown than your own, by a shade or two, and marked here and there with scars of a lighter or darker hue. 
	*if (((hairtexture = "smooth") or (hairtexture = "coarse")) or (hairtexture = "wavy"))
		*set iasionhair "wavy"
		$!{haircolor} hair has gone nearly half-grey, and he wears it to the nape of his neck, where it sits, wavy and a bit disheveled, as though it's been pushed down by the plumed helmet tucked under one arm.  
	*if (hairtexture = "curly")
		*set iasionhair "curly"
		$!{haircolor} hair has gone nearly half-grey, and he wears it to the nape of his neck, where it sits, curly and a bit disheveled, as though it's been pushed down by the plumed helmet tucked under one arm.  
	*if ((hairtexture = "coily") or (hairtexture = "dense"))
		*set iasionhair "longrows"
		$!{haircolor} hair has gone nearly half-grey, and he wears it in neat, tight rows of braids against his scalp, the long ends of each gathered into a tail at his nape to trail down his back, perhaps in part to sit easier beneath the helmet tucked under one arm.
	
	His attention fixes on you immediately,  like he knows exactly where to put it. He stops dead in his tracks, wide eyes flicking from you, to your mother, and you can see his throat work as he swallows. 
	
	"D-Demi? And—" His mouth falls open. 
	
	*fake_choice
		#@{convotoggle [☆]|} "Iasion, I presume?"
			*set humorous +1
			*set confident +1
			"Iasion, I presume?" You can't help a trickle of amusement entering your voice; something about his obvious fluster provokes it. Maybe it's the fact that the reaction is so…
			
			You aren't even sure what the right word is, but it means you can put your own reservations aside, just for the moment, and make light of the rather odd situation the both of you are in. Well, the three of you.
			
			This, in turn, pulls a smile from him. "I'd ask how you guessed, but considering what just happened, I'm not sure I want to know. Don't know what I'd do if I had a reputation for being a scattered fool already."
			
			"I think you could be excused for such a reaction, given the suddenness of present events." Demeter smiles, a slight wobble to it, and Iasion clears his throat. 
			
			"I… I rather hope so, yes."
		#"I take it you can guess who I am."
			*set serious +1
			*set confident +1
			"I take it you can guess who I am." Considering your mother's presence, it's surely obvious, regardless of resemblance or anything so unreliable as that. He already knows you live here, if what the others have said is true, and of course it would be.
			
			"Well." He clears his throat, then smiles. It's an awkward expression, a tad sheepish, but genuine as far as you can tell. "Yes. I had an idea. Just… took me a moment to get my head around it, I think. I—you must think me a daft fool, but it's—" 
			
			"I think you could be excused for such a reaction, given the suddenness of present events." Demeter smiles, a slight wobble to it, and Iasion clears his throat. 
			
			"I… I rather hope so, yes."
		#"I—you—uh."
			*set unsure +1
			"I—you—uh."
			
			Certainly not what you'd [i]planned[/i] to say in this moment, though you can't remember just now if you'd planned anything in particular. Something about him standing right here, in the… well not [i]exactly[/i] 'the flesh' in the usual sense, but certainly close enough—
			
			"Yeah," he says, a small smile quirking his lips. "Me too, honestly." A huff of something close to laughter escapes his nose, and the color of his eyes seems suddenly much warmer.
			
			"I think you could both be excused for such reactions, given the suddenness of present events." Demeter smiles, a slight wobble to it, and Iasion clears his throat. 
			
			"I… I rather hope so, yes."
		#I swallow thickly, nerves sticking my tongue to the roof of my mouth.
			*set unsure +1
			You swallow thickly, nerves sticking your tongue to the roof of your mouth. You can't remember just now what you'd planned to say here, or even if you'd planned to say anything in particular. Something about him standing right here, in the… well not [i]exactly[/i] 'the flesh' in the usual sense, but certainly close enough—
			
			"Yeah," he says, a small smile quirking his lips. "Me too, honestly." A huff of something close to laughter escapes his nose, and the color of his eyes seems suddenly much warmer.
			
			"I think you could both be excused for such reactions, given the suddenness of present events." Demeter smiles, a slight wobble to it, and Iasion clears his throat. 
			
			"I… I rather hope so, yes."
	*page_break
	He gestures to the tent. Part of you wonders distantly where the objects in the camp even came from; the dead don't typically bring anything with them to the Underworld save the payment for the ferry, in this part of the realm. Then again, you wouldn't be entirely surprised if the items were provided [i]for[/i] the spirits, because it's clear this is how these people are comfortable, for now. 

	Iasion pulls aside the tent flap, admitting you and your mother first.
	
	He files in himself after, closing the flap behind him and gesturing to where a moderately-sized table with several chairs is set up near the middle. "Please, uh, have a seat. I'm sorry it isn't anything more suitable."
	
	"…I rather suspect there is ample excuse for that as well." Demeter's tone is stilted, and she hems quietly, taking a seat.

	You get settled in one of the chairs, too, casting your glance around the plain room. It is more of a 'room' than you'd expected at the word 'tent,' but then this is quite a bit larger than you thought, too. 
	*if (tag_learned)
		There's an easy explanation for that, of course: this is a military commander's tent, designed for holding meetings and the like as well as the commander's living quarters in the field. It means Iasion is someone with relatively high status, whether he got that through a coincidence of his birth or through success in his military career, or both. 
	*if ((tag_learned = false) and (tag_unlearned = false))
		You believe you've heard of constructions like this, though—a large tent near a battlefield would probably belong to a commander or leader of some sort, so you can imagine the table might be for strategy meetings. It's just a guess, though, and you don't draw any solid conclusions from it. 
	*if (tag_unlearned)
		Then again, it's not like you know much about tents in general, or armies, or anything like that. For all you know, this is just what the Underworld was able to get for the people here, and doesn't correspond to anything about their previous lives at all.
	*page_break
	Iasion takes the seat across from you, hemming softly and placing his hands on the tabletop. 

	"I would like to apologize," he says, tone low-pitched and quiet. "For how… abrupt all this is. Even now, I have to keep reminding myself that this isn't how I would have wanted it to be. That I am dead, our time is limited, and everything has to be… compressed." His lips thin, paling a few shades as he purses them. 
	
	"I hardly think that is something for you to apologize for," Demeter says, frowning. "It is not you who suddenly appeared on our doorstep. At least, not in any manner you could prevent." She glances once towards you, a small acknowledgment that this is, indeed, your doorstep now, and he did show up on it unexpectedly. 

	"Maybe not, but… I am compressing the time in which… in which any of us can say or do anything about it. In an ideal world, it would all be much more leisurely a process. I would ask you as many things about yourself as I could think of, ${name}, and answer anything you could think to ask, and simply be glad of the fact that you were interested enough to do so." 

	He swallows thickly. "And Demi—I…" He loses the trail of his thoughts completely, and silence sits between the three of you for several long seconds before Iasion shakes his head abruptly.
	
	"Now, though… I just have to hope we can all say or ask everything we need to, while there's still time."

	He smiles, but there's an edge of bitterness to it.

	"I'm still trying to come to terms with my death, in truth. So I hope you will understand that this is not how I would have done this, had I the choice."
	
	He shifts his attention to you in particular, there.

	*fake_choice
		#"I understand. The circumstances aren't ideal, but we'll adapt."
			"I understand. The circumstances aren't ideal, but we'll adapt." 

			You can hardly blame him for the fact that things will inevitably feel rushed and truncated. He surely wouldn't have been expecting to meet you [i]after he died[/i], and it's not his fault that process works the way it does. 

			"Thank you," he replies, managing half a smile. "You know, in spite of all that, I'm looking forward to this. I'll never be able to satisfy my desire for answers, I suppose, but if you have such a thing, I hope we can at least make sure you know everything you want to."
		#"You speak as though you've had a plan for a while, but I got the impression you didn't know I existed."
			"You speak as though you've had a plan for a while, but I got the impression you didn't know I existed." 

			It's strange, and you're not sure how to interpret it. Maybe he [i]did[/i] know about you, and planned to meet you one day? It would have been difficult in any case; perhaps he was simply hoping that one day, Demeter would allow it. 

			"You existed," he replies, almost too softly. "To me, you existed. I didn't [i]know[/i] it, and I didn't let myself make too many guesses about you, but… in my wildest hopes, you always existed." He clears his throat, looking down at his hands for a moment. "I always wanted to be—well, it doesn't matter. Suffice to say that for me, this meeting is a miracle. If I had to die to see it, well… everyone dies." He manages half a smile, genuine in spite of the touch of wryness.
			
			From the corner of your eye, you see Demeter turn her face briefly away from both of you.
		#"It's not how I would have done things, either, but here we are."
			"It's not how I would have done things, either, but here we are." 

			You don't [i]blame[/i] him for the fact that things will eventually feel rushed and truncated. He surely wouldn't have been expecting to meet you [i]after he died[/i], and it's not his fault that things turned out this way. But it [i]is[/i] what you're dealing with, and the sooner you both start dealing with it, the sooner you'll get the answers you're after. 

			"So it is," he replies, managing half a smile. "You know, in spite of all that, I'm looking forward to this. I'll never be able to satisfy my desire for answers, I suppose, but if you have such a thing, I hope we can at least make sure you know everything you want to. I'll try not to get distracted."
		#"With respect, don't get ahead of yourself. I haven't decided if there is any 'this' in the first place."
			"With respect, don't get ahead of yourself. I haven't decided if there is any 'this' in the first place." 

			It's true that you know he's your father, at this stage. But that alone doesn't entitle him to any relationship with you. Nor are you sure just yet whether that's something you want. You'll have to feel each other out quite a bit before you can answer a question like that.
			
			Demeter parts her lips, as if to say something, but Iasion shakes his head, and she presses them back together, both thinning. 

			"That's reasonable," he replies, managing a slightly-awkward half-smile in your direction. "I'll do my best to give you any information you want and answer your questions, but in the end your decision what to do about that is your own. I have my hopes for what you'll choose, of course. No point pretending otherwise."
	*page_break
	Sitting back in his chair, he studies you for a moment, an odd smile pulling at the corner of his mouth, before broadening his attention. You wonder if maybe he isn't a little bit nervous, to look at your mother square-on. 
	
	For her part, she sits as stiffly as you've ever seen, back ramrod straight and hands clasped in her lap. 
	
	"I, so…" he hesitates. "I'm not really sure how much you know. How much you want to know. Even why you're here, really." He laughs, a bit strained in the sound, but the expression on his face is a sincere one. 
	
	Running a hand back over his hair, he pulls in a breath. "I'm Iasion, by the way. Did I ever actually say that? I suppose you must have known, regardless." 
	
	"${name} knows your name," Demeter says, her voice as stiff as her spine. "And who you are to ${him}. I would never have kept that much from ${him2}."
	
	Iasion's face… the best word for it is probably [i]scrunches[/i], like all of his features are pulling in towards each other on a wince. You've seen Pyri do that before, but it looks stranger on him, somehow. 
	
	"Well, Demi… I have to admit, there wasn't any way for me to be sure about that, you know?" The words come after his expression has relaxed, but what's left is much more solemn than it had been before she spoke. 
	
	Demeter clears her throat. "…I suppose I deserve that," she replies, almost too quietly for you to hear. "And… you should know that I said little else. For both your sakes." Her fingers tangle with one another on her lap. 
	
	Iasion nods. "I think I get the idea. So… well, if that's the case, I guess I should just ask you what you want to know." He returns his attention to you, finding a small smile. "We could tell you how we met, for starters? It's sort of how you came about, so if you're interested, I'm happy to fill you in." 
	
	*fake_choice
		#"I definitely am; I've always wanted to know about you."
			*set warm +1
			"I definitely am; I've always wanted to know about you." You're sure a little excitement is seeping into your voice, but you let it. Why wouldn't you? This is your [i]father[/i], someone who has always been a blank space in your knowledge of yourself. In your understanding of who and what you are. And you finally have the chance to talk to him, and begin to fill in that space. 
			
			Excitement is understandable, surely. 
			
			Iasion seems to have a little of it himself as he grins back at you, eyes crinkling. 
			
			*label iasionexplains3
			"To begin with, I suppose I should tell you: while I consider myself human in every way that really matters, my mother was one of the Pleiades, the nymph companions of Lady Artemis. My father was Corythus, King of Samothrace, a position that I now occupy. Or, well, did, I suppose."

			Technically, you're fairly sure this makes [i]him[/i] a demigod as well, or something akin to one. 

			"I mention this mostly to explain why I was even [i]at[/i] the place and time where we met," he admits with a rueful smile. "The marriage of Cadmus and Harmonia; she's my half-sister, you see." He shakes his head, expression slightly baffled. 

			He shakes his head. "Anyway, forgive me, I was meant to be telling of the event itself. I was invited to the wedding ceremony and attended, as did many of the gods, including your mother." His eyes move automatically to her at her mention, and she nods slightly, though you're not sure he was seeking confirmation.
			
			"I would say… Harmonia's power was strong over the atmosphere, to put it one way. It was a rather unprecedented and unrepeated opportunity for humans and deities to simply… exist in the same place, under the banner of the same celebration, and it removed what I imagine must have been quite a number of barriers."
			
			"That and everyone was drunk," Demeter adds, a hint of dryness making it through the otherwise stilted sound of it.
			*page_break
			Iasion's lips turn up into a wry smile. "They were. I certainly was. When I saw your mother, I didn't recognize her for who she was. How could I? I just knew she was someone I needed to talk to. And so, like an arrogant fool, I did. And for reasons I can hardly fathom… she spoke to me in turn." He huffs, lifting a brow at her. 
			
			"If I try to understand it, I have to guess I bemused you, at first. I'm not sure you could imagine where someone so unimportant got the gall to address you without at least twice as much bowing and flattery."
			
			Demeter presses her lips together for a moment. "Part of it is [i]because[/i] there was less bowing and flattery," she admits. "It was different."

			Iasion rubs absently at the side of his neck with his fingertips, tracing along the line of an old, thin scar, and nodding slightly at her, accepting the answer for what it is. "I certainly won't claim it was love at first sight, but it was… there was something. At least for me. A sense of connection. The desire to know more of her. And definitely too much ambrosia wine in me." He lowers his hand, smiling softly. 
			
			And then, surprisingly enough, your mother [i]rolls her eyes[/i]. You don't think you've ever seen her express that particular brand of exasperation, least of all with a set to her mouth that is [i]almost[/i] a smile. "If that's what you want to think, go ahead."

			He grins. "In any case, that was the first time we met, but it wasn't the last. Over the months afterwards, I… well, I did just about anything I could to meet her again, and for reasons I still don't fathom, she allowed it. I knew who she really was, by then, but I was much too infatuated to let any sense of what my place was in the world stop me. She was a person, and so was I, and that was the only part that seemed to matter." 
			
			Demeter's slightly relaxed expression fades, giving you a clue as to the [i]next[/i] part of this.
			*page_break
			Iasion's hand finds the surface of the table, and blunt fingertips tap gently, almost inaudibly, against it. "For the last… little while, it felt different. Like she was trying to keep something from me. And then I never saw her again."
			
			You suppose, then, that that would have been the time in which she'd discovered her pregnancy. 
			
			"You never knew about me," you say, drawing the conclusion in a deliberate, careful tone. 
			
			Iasion smiles, the slant of it a bit awkward, and nods. "Not… with any real certainty, no. I wondered. I [i]hoped[/i]. But I didn't know." 
			
			"And that was my fault," Demeter supplies. "I will admit that it was a choice I made. And one I stand by." 
		#"I suppose it couldn't hurt."
			*set cold +1
			"I suppose it couldn't hurt." You're not going to allow yourself to become invested in all of this just yet. But answers are not a bad thing, and indeed much of the reason you're here to begin with. You may as well allow him to provide them for you. 
			
			He smiles back at you, eyes crinkling. There isn't a hint of tentativeness about him, really, in spite of your obvious detachment. You have to wonder about that, a little. 
			*goto iasionexplains3
		#"I don't particularly need to know how you met or anything, but please do tell me a bit about yourself."
			*set warm +1
			"I don't particularly need to know how you met or anything, but please do tell me a bit about yourself." You're sure a little excitement is seeping into your voice, but you let it. Why wouldn't you? This is your [i]father[/i], someone who has always been a blank space in your knowledge of yourself. In your understanding of who and what you are. And you finally have the chance to talk to him, and begin to fill in that space. 
			
			Excitement is understandable, surely. 
			
			Iasion seems to have a little of it himself as he grins back at you, eyes crinkling. 
			
			*label iasionexplainshimself3
			"Fair enough. I'm not sure how much of a story it is, anyway. We met at a wedding, and carried on for a bit. That's what it is, if I'm not waxing a bit too lyrical on the subject."
			
			He fixes his eyes on her for a moment, expression grim. 
			
			"It was more than that and you know it, Iasion," she replies firmly, forcing his eyes down to his hands. He clears his throat, and looks back up at you.

			"Anyway, when it comes to me… I'm not quite sure what to say. While I consider myself human in every way that really matters, my mother was one of the Pleiades, the nymph companions of Lady Artemis. My father was Corythus, King of Samothrace, a position that I now occupy. Or, well, did, I suppose."

			Technically, you're fairly sure this makes [i]him[/i] a demigod as well, or something akin to one. 
			*page_break
			He clasps his hands on the table. "I can't say I ever thought myself particularly suited for the role of king, but maybe I managed to grow into it. Samothrace isn't such a large area, anyway, and the people all tend to know what they're doing just fine without me telling them. I know how to do the things kings are supposed to know: how to delegate, how to fight, how to sail and parley with one's allies and enemies… how to pay one's debts. Which is how we ended up at war, I suppose."
			
			"This war?" you ask, gesturing slightly to encompass the tent and those moving about outside of it. 
			
			"Yes. The only war I ever had to participate in. I won't call that fortunate, but it's better than it could have been. I hope now that I have died, Samothrace will be considered relieved of its debts and have no such obligations again."
			
			Clearly, Iasion is familiar with the burdens of responsibility. It's hard to imagine being compelled to go to war on behalf of another. You're not certain how you would have handled that situation. It's clearly not something he enjoyed, but he doesn't seem to resent it, either. 
		#"Let's stick to the basics, for now. Who are you?"
			*set cold +1
			"Let's stick to the basics, for now. Who are you?" You're not going to allow yourself to become invested in all of this just yet. But answers are not a bad thing, and indeed much of the reason you're here to begin with. You may as well allow him to provide them for you, even if the ones you're interested in don't have much to do with your mother, right now.
			
			He smiles back at you, eyes crinkling. There isn't a hint of tentativeness about him, really, in spite of your obvious detachment. You have to wonder about that, a little. 
			*goto iasionexplainshimself3
	*page_break
	"I also want… to apologize," Iasion continues, running a hand back over his hair. "To you both, for different reasons. I can't imagine what it must be like to wake up one morning to all of this, and on a time limit, no less. ${name}, I want you to know that I don't—I don't expect anything in particular from you. To be honest, I'm just…"

	He swallows, the cartilage in his throat bobbing, and coughs softly. His fingers curl against the surface of the table, nail beds paling. "I'm just… delighted. To know that you're not just someone I imagined might one day exist. That you're [i]real[/i], and alive, and well." 

	Iasion's eyes drop to the table, then slowly drag back up to you. "I hope your life has been everything you could ever want. I hope it always will be. That's…. really the main thing."

	*fake_choice
		#The irony and unfairness of it all forms a lump in my throat. "I... thank you."
			*set warm +1
			The irony and unfairness of it all forms a lump in your throat. "I... thank you."

			You can feel tears threatening, but you're fighting them, not so much for your own sake as for his. Wouldn't it just give him something to worry about, if he saw you cry over this? After everything, in [i]this[/i] situation, you don't want to make him concerned like that. 

			It's so—

			He meets your eyes, and you can tell his aren't quite dry, either. "I'm sorry," he murmurs. "I wish it could have been some other way. But… this is the situation we have."
			
			Next to you, you can hear the soft intake of Demeter's breath, just a tiny bit unsteady, and you know your mother is thinking something not so different from you.
			
			There's a chance, of course, that it isn't as bad as all that. That he ends up on the Isles, and can keep his memories for a while longer. But even then—even then, you will eventually lose him to the cycle of rebirth. And it will be so much sooner than you're expecting, you just know it. 
		#I can at least offer a smile, even if this is not the joyful occasion I might have wanted it to be. "It's been... there's been ups and downs, but I'm happy."
			*set warm +1
			You can at least offer a smile, even if this is not the joyful occasion you might have wanted it to be. "It's been... there's been ups and downs, but I'm happy." 

			That's the truth, but it's also meant to give him as much reassurance as you can, while you can. Your life hasn't been perfect, by any means, but you're satisfied with where it is and where it's going. And if he wishes for your happiness, he need not worry too much. 

			The situation strikes you as deeply unfair, but what can you do about that? There's no one here who can fix that, and so you simply have to cope with it as best you can.

			Iasion meets your eyes, and you can tell his aren't quite dry. "I want very much to lament the situation we're in," he admits quietly. "But instead I am going to be grateful that this meeting happened at all, because it could very easily never have taken place."
			
			Next to you, you can hear the soft intake of Demeter's breath, just a tiny bit unsteady, and you know then that this is affecting her more than she will want to show.

			There's a chance, of course, that it isn't as bad as all that. That he ends up on the Isles, and can keep his memories for a while longer. But even then—even then, you will eventually lose him to the cycle of rebirth. And it will be so much sooner than you're expecting, you just know it. 
		#I'm still reeling a little, not sure how to properly respond, but I manage a tight 'thank you,' at least.
			You're still reeling a little, not sure how to properly respond, but you manage a tight 'thank you,' at least.

			It's all… quite a lot. Of information, of ways in which you need to reconfigure your understanding of things. Filling in the largest blank in your understanding of your own life, your own origin, is naturally a significant undertaking, but even this much is leaving the parts you still [i]don't[/i] know to stand out in stark contrast. 

			Why did your mother stop speaking to him? Why weren't you allowed to know him? It seems he would have been willing to know [i]you[/i], but is that perhaps a more recent development than he has indicated?

			There are too many questions for you to even know where to begin, and the squeeze of the time limitation is [i]also[/i] looming large.

			Iasion meets your eyes, and you can tell his aren't quite dry. "I want very much to lament the situation we're in," he admits quietly. "But instead I am going to be grateful that this meeting happened at all, because it could very easily never have taken place."

			He doesn't press it, though, doesn't leave an expectant silence in which you might reciprocate the sentiment. Perhaps he knows you can't right now. Perhaps he senses that you're overwhelmed. You can only hope so, because it would be difficult to explain.
			
			Next to you, you can hear the soft intake of Demeter's breath, just a tiny bit unsteady, and you know then that this is affecting her more than she will want to show.

			There's a chance, of course, that it isn't as bad as all that. That he ends up on the Isles, and can keep his memories for a while longer. But even then—even then, you will eventually lose him to the cycle of rebirth. And it's hard to know just how to feel about that.
		#I can't help but feel that's a tad presumptive of him, but I'll let it slide. He's not being overbearing with this, and I appreciate that. "Thank you. If it helps to know, I'm doing rather well."
			*set cold +1
			You can't help but feel that's a tad presumptive of him, but you'll let it slide. He's not being overbearing with this, and you appreciate that. "Thank you. If it helps to know, I'm doing rather well."

			At the moment, your emotions remain firmly under your control. There is still a fair bit of thinking you'll need to do about these matters, of course. Filling in the largest blank in your understanding of your own life, your own origin, is naturally a significant undertaking, but even this much is leaving the parts you still [i]don't[/i] know to stand out in stark contrast. 

			Why did your mother stop speaking to him? Why weren't you allowed to know him? It seems he would have been willing to know [i]you[/i], but is that perhaps a more recent development than he has indicated?

			The short time span in which you may be able to get hints as to the answers is daunting, in its way, but you will handle it in your own way and with your own priorities. 

			Iasion meets your eyes, and you can tell his aren't quite dry. "I want very much to lament the situation we're in," he admits quietly. "But instead I am going to be grateful that this meeting happened at all, because it could very easily never have taken place."

			He doesn't press it, though, doesn't leave an expectant silence in which you might reciprocate the sentiment. Perhaps he knows that you wouldn't necessarily be able to. You can't claim to feel exactly the way he does about it, but you [i]do[/i] think perhaps you're glad this happened, even if the circumstances are less than ideal.
			
			Next to you, you can hear the soft intake of Demeter's breath, just a tiny bit unsteady, and you know then that this is affecting her more than she will want to show.

			There's a chance, of course, that it isn't as bad as all that. That he ends up on the Isles, and can keep his memories for a while longer. But ultimately, you aren't sure how much about this that would change, given that the cycle of rebirth marches on even so.
		#I do understand that he's holding back his emotions, which is good because I'd rather not confront those. We're still essentially strangers, but I can manage politeness. "I appreciate the sentiment."
			*set cold  +1
			You do understand that he's holding back his emotions, which is good because you'd rather not confront those. We're still essentially strangers, but you can manage politeness. "I appreciate the sentiment."

			It's not as though you can suddenly claim to feel a bond with this man. Or any sort of attachment. Perhaps, with time, something like that might have been possible. But time is something you do not necessarily have, and so the best choice is to remain at a courteous distance. 

			Even if somehow you think Iasion is not as capable of that as you are.

			Iasion meets your eyes, and you can tell his aren't quite dry. "I want very much to lament the situation we're in," he admits quietly. "But instead I am going to be grateful that this meeting happened at all, because it could very easily never have taken place."

			He doesn't press it, though, doesn't leave an expectant silence in which you might reciprocate the sentiment. Perhaps he knows that you wouldn't necessarily be able to. You can't claim to feel exactly the way he does about it, but you [i]do[/i] think perhaps you're glad this happened, even if the circumstances are less than ideal. It's… something. More answers than you had, at the very least.
			
			Next to you, you can hear the soft intake of Demeter's breath, just a tiny bit unsteady, and you know then that this is affecting her more than it's affecting you.
			
			There's a chance, of course, that circumstances improve. That he ends up on the Isles, and can keep his memories for a while longer. But ultimately, you aren't sure how much about this that would change, given that the cycle of rebirth marches on even so.
	*page_break
	Releasing a long, slow breath, Iasion seems almost to resign himself to something, his hands relaxing on the tabletop and his expression clearing, then becoming something almost wry for a moment before he shakes his head. 
	
	"And Demi, I…" His voice, relatively steady in spite of his emotion when he'd been addressing you, fails as he turns his eyes to your mother. For a long moment, he just [i]looks[/i] at her, and she looks back.
	
	She's the one to break the eye contact, shifting her eyes briefly down to her hands. "We will… discuss some things later," she says quietly. "I owe you some proper explanations, at the very least."
*if (met_iasion)
	He spots you immediately, and you catch the smile beginning to bloom over his face before his eyes shift to the goddess beside you. 
	
	Iasion blanches, too much of the color draining from his face, leaving it a shade paler and more ashen than it should be. You can see his throat work as he swallows. 
	
	"D-Demi?" His mouth doesn't quite fall open, but you think it might be a near thing. Rather, a muscle in his jaw jumps with how hard he's clenching his back teeth, and his posture seems to you to straighten, to gain a more rigid kind of dignity you hadn't seen him wear last time. 
	
	For her part, Demeter has clasped her hands in front of herself, stiff as a board. "Iasion." 
	
	The silence is heavy. 
	
	*fake_choice
		#@{convotoggle [☆]|} "Well... this got awkward even faster than I expected."
			*set humorous +1
			"Well... this got awkward even faster than I expected." Your chuckle is a bit awkward itself; you're not immune to the mood, so to speak, but you're certainly still the least affected by it. Demeter really wasn't exaggerating, when she'd claimed there were nerves involved here. You're not as sure about him, but she at least has never really been the type to get stunned into anything, least of all silence. 
			
			He's the one who snaps out of it first, though, clearing his throat and shaking his head. "Apologies. I should—you're both welcome here. Please, come in." His tone's unmistakably strained, but he makes the effort to pull aside the tent flap for the both of you, politely gesturing you inside. 
		#@{convotoggle [☆]|} "Hello, father. You remember mother, I'm sure."
			*set humorous +1
			"Hello, father. You remember mother, I'm sure." You grin broadly, not letting the obvious discomfort of the situation get to you, too much. Besides, hopefully you can move things out of their awkward little stasis. Demeter really wasn't exaggerating, when she'd claimed there were nerves involved here. You're not as sure about him, but she at least has never really been the type to get stunned into anything, least of all silence. 
			
			He's the one who snaps out of it first, though, clearing his throat and shaking his head. "Apologies. I should—you're both welcome here. Please, come in." His tone's unmistakably strained, but he makes the effort to pull aside the tent flap for the both of you, politely gesturing you inside. 
		#I clear my throat softly, trying to break it as gently as possible.
			*set serious +1
			You clear your throat softly, trying to break it as gently as possible. You're not sure what else [i]to[/i] do. Demeter really wasn't exaggerating, when she'd claimed there were nerves involved here. You're not as sure about him, but she at least has never really been the type to get stunned into anything, least of all silence. 
			
			He's the one who snaps out of it first, though, clearing his throat and shaking his head. "Apologies. I should—you're both welcome here. Please, come in." His tone's unmistakably strained, but he makes the effort to pull aside the tent flap for the both of you, politely gesturing you inside. 
		#"Should I leave for a bit, maybe?"
			*set serious +1
			"Should I leave for a bit, maybe?" That hadn't been the initial plan at all, but then, you're not sure you'd anticipated quite this amount of discomfort. Demeter really wasn't exaggerating, when she'd claimed there were nerves involved here. You're not as sure about him, but she at least has never really been the type to get stunned into anything, least of all silence. 
			
			He's the one who snaps out of it first, though, clearing his throat and shaking his head. "No, uh, no—of course not. You're both welcome here. Please, come in." His tone's unmistakably strained, but he makes the effort to pull aside the tent flap for the both of you, politely gesturing you inside. 
	*page_break
	The tent is, unsurprisingly, exactly as it was before. All of Iasion's 'belongings,' and there are quite few, are very neatly-placed, and the entire interior has a sense of transience and depersonalization. Whatever the other men think, to whatever degree they've accepted their deaths or haven't, it is clear that your father is well aware of just how temporary his current situation is. 
	
	*fake_choice
		#It's almost a shame. I wish I'd gotten to see what his home looked like.
			It's almost a shame. You wish you'd gotten to see what his home looked like. You're not sure if, as a king, he'd have had the ability to furnish it however he wanted, or if he'd stick to some kind of convention, but either way would have been interesting. Told you something about him. 
			
			This hardly gives a hint, so you suppose any insights into who Iasion is will have to come from the man himself, one way or another.
		*if (iasiontalk != "none")
			#I'm a little nervous. Last time, I wasn't here with just my mother, so this feels different.
				You're a little nervous. Last time, you weren't here with just your mother, so this feels different. You're not [i]afraid[/i], exactly; you know there's no reason to be that. But the prickle of anxiety is definitely there under your skin. 
				
				*if (dontstim)
					It's not something that manifests much, though. Maybe your expression is a bit strained, but if Iasion or Demeter notice, they doesn't comment on it. 
					
					That alone is enough for you to begin to relax, just a little bit. 
				*if ((dontstim = false) and (stimt != "unknown"))
					*fake_choice
						*if (stimt != "suppress")
							#It's enough for me to begin to fidget, in the same way I often do when feeling anxious.
								It's enough for you to begin to 
								*if (stimt = "tap")
									tap your fingers against your leg, in the same way you often do when feeling anxious. The slightly-frenetic rhythm of it is grounding, and it's not something you even [i]decide[/i] to do—it just happens, in almost the same way breathing just happens. 
								*if (stimt = "rock")
									rock back and forth a bit on your heels, in the same way you often do when feeling anxious. It would probably be more comfortable if you were already sitting, but for now, this will do. The motion is grounding, and it's not something you even [i]decide[/i] to do—it just happens, in almost the same way breathing just happens. 
								*if (stimt = "lip")
									chew your lip, in the same way you often do when feeling anxious. The dull sensation of it is grounding, and it's not something you even [i]decide[/i] to do—it just happens, in almost the same way breathing just happens. 
								*if (stimt = "hands")
									wring and flap your hands, in the same way you often do when feeling anxious. The rhythm of it is grounding, and it's not something you even [i]decide[/i] to do—it just happens, in almost the same way breathing just happens. 
								*if (stimt = "hair")
									tug at your hair, in the same way you often do when feeling anxious. The sensation of it is grounding, and it's not something you even [i]decide[/i] to do—it just happens, in almost the same way breathing just happens. 
								
								Iasion, catching sight of you from the corner of his eye, turns from where he's moving chairs to, of all things, grin broadly at you. "My father used to do that," he says, tone soft. "He hid it from his subjects, but in front of his family, you could always tell when he was annoyed or worried about something. Or enjoying himself, for that matter."
								
								Demeter blinks. "Did he? I was never sure if it came from somewhere, or it it was just ${name}." 
								
								He huffs. "Well, either way it's ${name}, but maybe it's one of those things you can inherit. I admit I really don't know." He's still smiling though, the warm expression turned on you, and he shrugs. 
						*if (stimt = "suppress")
							#The desire is there, to fidget, but as usual, I manage to suppress it.
								The desire is there, to fidget, but as usual, you manage to suppress it. You're not sure how Iasion would react to such an overt display of your emotions, never mind your discomfort with expressing things in such a way. Demeter's never really understood it, and while she hasn't discouraged it, it's always been obvious to you that she doesn't understand it, either.
								
								You're not sure exactly what your face is doing, or if either of them pick up on your nervousness otherwise, but if they do, they don't comment on it. 
							
								That alone is enough for you to begin to relax, just a little bit. 
						#I don't tend to show my anxiety with fidgeting; that's usually triggered by different emotions and moods. 
							Though some of your emotions are sometimes obvious, given your very physical reactions to them, perhaps fortunately, anxiety isn't one that brings out such a reaction in you. You're not sure exactly what your face is doing, or if either of them pick up on your nervousness, but if they do, they don't comment on it. 
							
							That alone is enough for you to begin to relax, just a little bit. 
				*if ((dontstim = false) and (stimt = "unknown"))
					*gosub_scene stimb
					*if ((dontstim = false) and (stimt != "suppress"))
						Iasion, catching sight of you from the corner of his eye, turns from where he's moving chairs to, of all things, grin broadly at you. "My father used to do that," he says, tone soft. "He hid it from his subjects, but in front of his family, you could always tell when he was annoyed or worried about something. Or enjoying himself, for that matter."
						
						Demeter blinks. "Did he? I was never sure if it came from somewhere, or it it was just ${name}." 

						He huffs. "Well, either way it's ${name}, but maybe it's one of those things you can inherit. I admit I really don't know." He's still smiling though, the warm expression turned on you, and he shrugs. 
					*if ((dontstim) or (stimt = "suppress"))
						Your anxiety isn't something that manifests much, though. Maybe your expression is a bit strained, but if Iasion or Demeter notice, they don't comment on it. 
					
						That alone is enough for you to begin to relax, just a little bit. 
		#It shows his practicality, I suppose. 
			It shows his practicality, you suppose. Even with the paucity of items to his name here in the Underworld, he could have been much more haphazard. Honestly, he probably could have demanded more supplies and received them. As far as you know, there's no rule that the souls waiting here have to get only the bare minimum in lodgings and comforts. 
			
			So you have to assume his own lack is something to do with his personality. If he knows he won't be here long, then the fact that he hasn't opted for more creature comforts shows a certain… respectable pragmatism, you suppose.
		#It's hard to even imagine living in a tent of all things. Even if this is a nice one, it's so... boring.
			It's hard to even imagine living in a tent of all things. Even if this is a nice one, it's so… boring. Honestly, he probably could have demanded more supplies and received them. As far as you know, there's no rule that the souls waiting here have to get only the bare minimum in lodgings and comforts. 
			
			The fact that he apparently hasn't is… well, you would not have made the same choice, to put it one way.
	*page_break
	Getting the table arranged so that it's just two chairs across from one, Iasion gestures to the pair, taking the other himself. Releasing a long, slow breath, he seems almost to resign himself to something, his hands relaxing on the tabletop and his expression clearing, then becoming something almost wry for a moment before he shakes his head. 

	"Demi, I…" His voice, relatively functional a moment ago, fails again as he turns his eyes to your mother. For a long moment, he just [i]looks[/i] at her, and she looks back.

	She's the one to break the eye contact this time, shifting her eyes briefly down to her hands. "We will… discuss some things later," she says quietly. "I owe you some proper explanations, at the very least."
*page_break
*set met_iasion true
"Right," Iasion says softly. "Later. That's… probably for the best." 

He makes conscious effort to relax, loosening his muscles in a slow succession, and it seems to work. Something about his expression eases up a bit, giving his faint smile a sense of openness and sincerity. You didn't necessarily think him lacking in either of those things before, but he seems to have decided to set whatever is between him and your mother aside, for now.

"As for now, I'd like to know more about you, ${name}, if you don't mind sharing," he admits. "But first, let's maybe get out of here? I'm not sure I want to have this whole conversation in a tent, after all. Do you two mind if we walk along the river instead?"

*if (forthright > reserved)
	"We can do that." 
*if not (forthright > reserved)
	You shake your head. 
The setting isn't all that material to you, especially considering you're sure he'll take care to keep matters private either way. 

Demeter ponders a moment, then dips her chin. "I suppose the setting isn't so important," she replies. 

"Excellent," Iasion stands, exhaling in a large gust. "I'm just more comfortable moving, a lot of the time. Sitting still reminds me of all those interminable meetings I had to sit through. Important, but very, very hard on my focus. And occasionally my rear end." His grin widens for just a moment, and then he lifts the tent flap, following you and your mother out. 
*page_break
Things are mostly quiet while you get yourselves out of the camp and a ways beyond it, along the shore of the Styx. Greyish reeds of all sorts droop along the banks, pushing up stubbornly amidst the silt of the sloping ground, many outright sitting in the slow-moving water. Demeter studies them with a sort of puzzled curiosity, albeit not one that slows her down.

When you're well and truly away from the other spirits and settled into an easy amble, Iasion picks up the thread of the conversation. 

"So… I admit I had a list of things I wanted to ask you. Naturally, I've subsequently forgotten everything on it." He lifts his shoulders in a helpless shrug. "So I suppose… would you mind telling me what it was like, growing up? On Olympus, in general, whatever you prefer to talk about."

*fake_choice
	#It's nice to be asked, honestly, and I don't feel any need to keep anything back in my explanation, even with my mother here.
		*set warm +1
		*set forthright +1
		It's nice to be asked, honestly, and you don't feel any need to keep anything back in your explanation, even with your mother here. You've given versions of it a few times, by this point, to others in the Underworld, but Iasion makes it a proper conversation, asking all kinds of questions that you're only too happy to answer. 
		
		It meanders a little bit, but everything comes out, with time: 
		*label fullexplanation2
		*if (opinion_olympus = "like")
			the way you'd always liked Olympus,
			*if (chose = "olympusmostly")
				and in fact would be living there still, if not for extenuating circumstances.
				
				Your mother frowns deeply at that part, adding that it's her fault, for not better protecting you, but even Iasion, less aware of the situation, doesn't accept that as an full explanation, and the rest comes out with a few more queries. 
			*if ((result = "underworldmostlyouch") and (chose != "olympusmostly"))
				and had wound up living there part time, if perhaps a little less of a part than you might have liked.
				
				Demeter lays the blame for that part squarely with Zeus, and Iasion does not seem surprised. 
			*if ((result = "threemonths") and (chose != "olympusmostly"))
				and had wound up living there for three months of the year, an arrangement which has yet to go into effect but that you think will be good for you.
				
				Demeter listens, but does not offer comment, something you have to admit you're a little surprised by.
			*if (result = "underworld")
				but had ended up liking the Underworld so much more as you found yourself with the freedom to explore an alternative way of life. And how you now live full time here, with no desire at all to go back.
				
				Demeter listens, but does not offer comment, something you have to admit you're a little surprised by.
			*if (result = "underworldmostly")
				but had ended up preferring the Underworld, especially as you found yourself with the freedom to explore an alternative way of life. And how you now live here for all but a little bit of each year, an arrangement which has yet to go into effect but that you think will be good for you.
				
				Demeter listens, but does not offer comment, something you have to admit you're a little surprised by.
			*if ((result = "split") or (result = "evensplit"))
				but had also wound up liking the Underworld, especially as you found yourself with the freedom to explore an alternative way of life. And how you now live here for part of each year and there for the other part, an arrangement which has yet to go into effect but that you think will be good for you.
				
				Demeter listens, but does not offer comment, something you have to admit you're a little surprised by.
		*if (opinion_olympus = "dislike")
			the way you'd never been particularly fond of Olympus, really, 
			*if (chose = "olympusmostly")
				but had wound up missing it while you were in the Underworld, and choosing to live there, only to be overturned by extenuating circumstances. 
				
				Your mother frowns deeply at that part, adding that it's her fault, for not better protecting you, but even Iasion, less aware of the situation, doesn't accept that as an full explanation, and the rest comes out with a few more queries. 
			*if ((result = "underworldmostlyouch") and (chose != "olympusmostly"))
				and had wound up choosing to live in the Underworld most of the time, albeit a 'most' more strictly-enforced than you would have liked. 
				
				Demeter lays the blame for that part squarely with Zeus, and Iasion does not seem surprised. 
			*if ((result = "threemonths") and (chose != "olympusmostly"))
				but there was enough about it that you still cared for that you've wound up living there three months of the year, an arrangement which has yet to go into effect but that you think will be good for you.
				
				Demeter listens, but does not offer comment, something you have to admit you're a little surprised by.
			*if (result = "underworld")
				and that the Underworld had been in every way a better alternative, especially as you found yourself with the freedom to explore a different way of life. And now you live here full-time, with no desire at all to go back.
				
				Demeter listens, but does not offer comment, something you have to admit you're a little surprised by.
			*if (result = "underworldmostly")
				and that the Underworld had been in every way a better alternative, especially as you found yourself with the freedom to explore a different way of life. And now you live here for all but a little while each year, an arrangement which has yet to go into effect but that you think will be good for you.
				
				Demeter listens, but does not offer comment, something you have to admit you're a little surprised by.
			*if ((result = "split") or (result = "evensplit"))
				but even the Underworld hadn't appealed to you so much more that you'd abandoned it altogether. There were still things about it that you liked, enough for you to choose to divide your time roughly evenly between the two, an arrangement which has yet to go into effect but that you think will be good for you.
				
				Demeter listens, but does not offer comment, something you have to admit you're a little surprised by.
		*if (opinion_olympus = "likehome")
			the way you'd always liked Olympus, thought of it as your home, 
			*if (chose = "olympusmostly")
				and in fact would be living there still, if not for extenuating circumstances.
				
				Your mother frowns deeply at that part, adding that it's her fault, for not better protecting you, but even Iasion, less aware of the situation, doesn't accept that as an full explanation, and the rest comes out with a few more queries. 
			*if ((result = "underworldmostlyouch") and (chose != "olympusmostly"))
				and, though the sense of home had come to feel less complete, you had wound up living there part time, if perhaps a little less of a part than you might have liked.
				
				Demeter lays the blame for that part squarely with Zeus, and Iasion does not seem surprised. 
			*if ((result = "threemonths") and (chose != "olympusmostly"))
				and, though the sense of home had come to feel less complete, you had wound up living there for three months of the year, an arrangement which has yet to go into effect but that you think will be good for you.
				
				Demeter listens, but does not offer comment, something you have to admit you're a little surprised by.
			*if (result = "underworld")
				but had ended up liking the Underworld so much more as you found yourself with the freedom to explore an alternative way of life. And how you now live full time here, with no desire at all to go back, that sense of home entirely replaced.
				
				Demeter listens, but does not offer comment, something you have to admit you're a little surprised by.
			*if (result = "underworldmostly")
				but had ended up preferring the Underworld, especially as you found yourself with the freedom to explore an alternative way of life. And how you now live here for all but a little bit of each year, an arrangement which has yet to go into effect but that you think will be good for you. The sense of home is certainly something that has shifted, and mostly settled here instead.
				
				Demeter listens, but does not offer comment, something you have to admit you're a little surprised by.
			*if ((result = "split") or (result = "evensplit"))
				but had also wound up liking the Underworld, especially as you found yourself with the freedom to explore an alternative way of life. And how you now live here for part of each year and there for the other part,  an arrangement which has yet to go into effect but that you think will be good for you. You have two homes, now, and both of them are beloved.
				
				Demeter listens, but does not offer comment, something you have to admit you're a little surprised by.
		*if (opinion_olympus = "dislikehome")
			the way you'd never been particularly fond of Olympus, really, but had thought of it as your home.
			*if (chose = "olympusmostly")
				The way you had wound up missing it while you were in the Underworld, and choosing to live there, only to be overturned by extenuating circumstances. 
				 
				Your mother frowns deeply at that part, adding that it's her fault, for not better protecting you, but even Iasion, less aware of the situation, doesn't accept that as an full explanation, and the rest comes out with a few more queries. 
			*if ((result = "underworldmostlyouch") and (chose != "olympusmostly"))
				The way you had wound up choosing to live in the Underworld most of the time, albeit a 'most' more strictly-enforced than you would have liked. Because now, you know what a home really feels like.
				
				Demeter lays the blame for that part squarely with Zeus, and Iasion does not seem surprised. 
			*if ((result = "threemonths") and (chose != "olympusmostly"))
				The way there was enough about it that you still cared for that you've wound up living there three months of the year, an arrangement which has yet to go into effect but that you think will be good for you. 
				
				Demeter listens, but does not offer comment, something you have to admit you're a little surprised by.
			*if (result = "underworld")
				The way the Underworld had been in every sense a better alternative, especially as you found yourself with the freedom to explore a different way of life. And now you live here full-time, with no desire at all to go back. Because now, you know what a home really feels like. 
				
				Demeter listens, but does not offer comment, something you have to admit you're a little surprised by.
			*if (result = "underworldmostly")
				The way the Underworld had been in every sense a better alternative, especially as you found yourself with the freedom to explore a different way of life. And now you live here for all but a little while each year, an arrangement which has yet to go into effect but that you think will be good for you. 
				
				Demeter listens, but does not offer comment, something you have to admit you're a little surprised by.
			*if ((result = "split") or (result = "evensplit"))
				The way even the Underworld hadn't appealed to you so much more that you'd abandoned it altogether. There were still things about it that you liked, enough for you to choose to divide your time roughly evenly between the two, an arrangement which has yet to go into effect but that you think will be good for you.
				
				Demeter listens, but does not offer comment, something you have to admit you're a little surprised by.
			
			And then the subject shifts to your childhood itself, growing up there, 
			*if (opinion_childhood = "wantfreedom")
				and how you'd always chafed at the restrictions set in place for you. You know they were intended to keep you safe, but it wasn't [i]safe[/i] you most needed to be. 
				
				It was [i]free[/i].
				
				You imagine it must test your mother, in some ways, to hear that, because you're not sure you've ever been nearly as emphatic about what specifically rubbed you the wrong way and why, but if she has the instinct to defend herself, she masters it, only offering the occasional comment to add details to your recollections.
			*if (opinion_childhood = "understand")
				and how you'd always been restricted by the need for your own safety, in an environment where your mother could only guarantee it under close watch. How you'd always understood it, but wondered if maybe there wasn't a whole world of experiences you were missing out on, nonetheless. 
				
				It's hard to know exactly how your mother feels, to hear it put in such terms, even if they're generous to her. Whatever her instincts might be, what she [i]does[/i] is add to your explanations in places, with additional details or nuances.
			
			Iasion listens to all of it, adding the occasional anecdote about Samothrace or his own upbringing. Yours and his have almost nothing in common, save perhaps high parental expectations, but the differences are as interesting as the similarity. 
	#I give a reasonably complete explanation, organizing the important points in my mind and laying them out deliberately. If he wants to know, I'll tell him.
		*set cold +1
		*set forthright +1
		You give a reasonably complete explanation, organizing the important points in your mind and laying them out deliberately. If he wants to know, you'll tell him.
		
		Perhaps because of this internal sense of organization, the conversation is almost systematic, each topic being thoroughly explored before moving on to the next:
		*goto fullexplanation2
	#I'm not comfortable talking about absolutely everything, particularly with Demeter here, but I'll happily give him the basic idea, at least. It feels good that he wants to know.
		*set warm +1
		*set reserved +1
		You're not comfortable talking about absolutely everything, particularly with Demeter here, but you'll happily give him the basic idea, at least. It feels good that he wants to know. You've given versions of this explanation a few times before, o the others in the Underworld, but Iasion makes it a proper conversation, asking all kinds of questions, some of which you're quite happy to answer, and others which you sidestep with no protest from him. 
		
		It meanders a little bit, but everything you want to say comes out, with time:
		*label partialexplanation2
		*if (opinion_olympus = "like")
			the way you'd always liked Olympus,
			*if (chose = "olympusmostly")
				and in fact would be living there still, if not for extenuating circumstances.
				
				Your mother frowns deeply at that part, adding that it's her fault, for not better protecting you, but even Iasion, less aware of the situation, doesn't accept that as an full explanation, and the rest comes out with a few more queries. 
			*if ((result = "underworldmostlyouch") and (chose != "olympusmostly"))
				and had wound up living there part time, if perhaps a little less of a part than you might have liked.
				
				Demeter lays the blame for that part squarely with Zeus, and Iasion does not seem surprised. 
			*if ((result = "threemonths") and (chose != "olympusmostly"))
				and had wound up living there for three months of the year, an arrangement which has yet to go into effect but that you think will be good for you.
				
				Demeter listens, but does not offer comment, something you have to admit you're a little surprised by.
			*if (result = "underworld")
				but had ended up liking the Underworld so much more as you found yourself with the freedom to explore an alternative way of life. And how you now live full time here, with no desire at all to go back.
				
				Demeter listens, but does not offer comment, something you have to admit you're a little surprised by.
			*if (result = "underworldmostly")
				but had ended up preferring the Underworld, especially as you found yourself with the freedom to explore an alternative way of life. And how you now live here for all but a little bit of each year, an arrangement which has yet to go into effect but that you think will be good for you.
				
				Demeter listens, but does not offer comment, something you have to admit you're a little surprised by.
			*if ((result = "split") or (result = "evensplit"))
				but had also wound up liking the Underworld, especially as you found yourself with the freedom to explore an alternative way of life. And how you now live here for part of each year and there for the other part, an arrangement which has yet to go into effect but that you think will be good for you.
				
				Demeter listens, but does not offer comment, something you have to admit you're a little surprised by.
		*if (opinion_olympus = "dislike")
			the way you'd never been particularly fond of Olympus, really, 
			*if (chose = "olympusmostly")
				but had wound up missing it while you were in the Underworld, and choosing to live there, only to be overturned by extenuating circumstances. 
				
				Your mother frowns deeply at that part, adding that it's her fault, for not better protecting you, but even Iasion, less aware of the situation, doesn't accept that as an full explanation, and the rest comes out with a few more queries. 
			*if ((result = "underworldmostlyouch") and (chose != "olympusmostly"))
				and had wound up choosing to live in the Underworld most of the time, albeit a 'most' more strictly-enforced than you would have liked. 
				
				Demeter lays the blame for that part squarely with Zeus, and Iasion does not seem surprised. 
			*if ((result = "threemonths") and (chose != "olympusmostly"))
				but there was enough about it that you still cared for that you've wound up living there three months of the year, an arrangement which has yet to go into effect but that you think will be good for you.
				
				Demeter listens, but does not offer comment, something you have to admit you're a little surprised by.
			*if (result = "underworld")
				and that the Underworld had been in every way a better alternative, especially as you found yourself with the freedom to explore a different way of life. And now you live here full-time, with no desire at all to go back.
				
				Demeter listens, but does not offer comment, something you have to admit you're a little surprised by.
			*if (result = "underworldmostly")
				and that the Underworld had been in every way a better alternative, especially as you found yourself with the freedom to explore a different way of life. And now you live here for all but a little while each year, an arrangement which has yet to go into effect but that you think will be good for you.
				
				Demeter listens, but does not offer comment, something you have to admit you're a little surprised by.
			*if ((result = "split") or (result = "evensplit"))
				but even the Underworld hadn't appealed to you so much more that you'd abandoned it altogether. There were still things about it that you liked, enough for you to choose to divide your time roughly evenly between the two, an arrangement which has yet to go into effect but that you think will be good for you.
				
				Demeter listens, but does not offer comment, something you have to admit you're a little surprised by.
		*if (opinion_olympus = "likehome")
			the way you'd always liked Olympus, thought of it as your home, 
			*if (chose = "olympusmostly")
				and in fact would be living there still, if not for extenuating circumstances.
				
				Your mother frowns deeply at that part, adding that it's her fault, for not better protecting you, but even Iasion, less aware of the situation, doesn't accept that as an full explanation, and the rest comes out with a few more queries. 
			*if ((result = "underworldmostlyouch") and (chose != "olympusmostly"))
				and, though the sense of home had come to feel less complete, you had wound up living there part time, if perhaps a little less of a part than you might have liked.
				
				Demeter lays the blame for that part squarely with Zeus, and Iasion does not seem surprised. 
			*if ((result = "threemonths") and (chose != "olympusmostly"))
				and, though the sense of home had come to feel less complete, you had wound up living there for three months of the year, an arrangement which has yet to go into effect but that you think will be good for you.
				
				Demeter listens, but does not offer comment, something you have to admit you're a little surprised by.
			*if (result = "underworld")
				but had ended up liking the Underworld so much more as you found yourself with the freedom to explore an alternative way of life. And how you now live full time here, with no desire at all to go back, that sense of home entirely replaced.
				
				Demeter listens, but does not offer comment, something you have to admit you're a little surprised by.
			*if (result = "underworldmostly")
				but had ended up preferring the Underworld, especially as you found yourself with the freedom to explore an alternative way of life. And how you now live here for all but a little bit of each year, an arrangement which has yet to go into effect but that you think will be good for you. The sense of home is certainly something that has shifted, and mostly settled here instead.
				
				Demeter listens, but does not offer comment, something you have to admit you're a little surprised by.
			*if ((result = "split") or (result = "evensplit"))
				but had also wound up liking the Underworld, especially as you found yourself with the freedom to explore an alternative way of life. And how you now live here for part of each year and there for the other part, an arrangement which has yet to go into effect but that you think will be good for you. You have two homes, now, and both of them are beloved.
				
				Demeter listens, but does not offer comment, something you have to admit you're a little surprised by.
		*if (opinion_olympus = "dislikehome")
			the way you'd never been particularly fond of Olympus, really, but had thought of it as your home.
			*if (chose = "olympusmostly")
				The way you had wound up missing it while you were in the Underworld, and choosing to live there, only to be overturned by extenuating circumstances. 
				 
				Your mother frowns deeply at that part, adding that it's her fault, for not better protecting you, but even Iasion, less aware of the situation, doesn't accept that as an full explanation, and the rest comes out with a few more queries. 
			*if ((result = "underworldmostlyouch") and (chose != "olympusmostly"))
				The way you had wound up choosing to live in the Underworld most of the time, albeit a 'most' more strictly-enforced than you would have liked. Because now, you know what a home really feels like.
				
				Demeter lays the blame for that part squarely with Zeus, and Iasion does not seem surprised. 
			*if ((result = "threemonths") and (chose != "olympusmostly"))
				The way there was enough about it that you still cared for that you've wound up living there three months of the year, an arrangement which has yet to go into effect but that you think will be good for you. 
				
				Demeter listens, but does not offer comment, something you have to admit you're a little surprised by.
			*if (result = "underworld")
				The way the Underworld had been in every sense a better alternative, especially as you found yourself with the freedom to explore a different way of life. And now you live here full-time, with no desire at all to go back. Because now, you know what a home really feels like. 
				
				Demeter listens, but does not offer comment, something you have to admit you're a little surprised by.
			*if (result = "underworldmostly")
				The way the Underworld had been in every sense a better alternative, especially as you found yourself with the freedom to explore a different way of life. And now you live here for all but a little while each year, an arrangement which has yet to go into effect but that you think will be good for you. 
				
				Demeter listens, but does not offer comment, something you have to admit you're a little surprised by.
			*if ((result = "split") or (result = "evensplit"))
				The way even the Underworld hadn't appealed to you so much more that you'd abandoned it altogether. There were still things about it that you liked, enough for you to choose to divide your time roughly evenly between the two, an arrangement which has yet to go into effect but that you think will be good for you.
				
				Demeter listens, but does not offer comment, something you have to admit you're a little surprised by.
			
			You keep your opinion of your upbringing to yourself, for the most part, simply talking about it in factual terms: what you did, rather than what you didn't or couldn't do, things like that. Your mother adds the occasional detail or bit of nuance to your recollections, especially the hazy ones from childhood.
			
			Iasion listens to all of it, adding the occasional anecdote about Samothrace or his own upbringing. Yours and his almost nothing in common, save perhaps high parental expectations, but the differences are as interesting as the similarity. 
	#There are certain things I will definitely be omitting, but a clear, organized explanation of the basic contours is certainly within my abilities to give, if he wants it. 
		*set cold +1
		*set reserved +1
		There are certain things you will definitely be omitting, but a clear, organized explanation of the basic contours is certainly within your abilities to give, if he wants it. 
		
		Perhaps because of this internal sense of organization, the conversation is almost systematic, each topic being thoroughly explored before moving on to the next:
		*goto partialexplanation2
*page_break
"So, I'm gathering that things could get… tense," he says, once the conversation comes to a natural lull. "On Olympus, I mean. Is Zeus really still…?"

Demeter's lips thin; she studies a cattail with at least twice the attention the pale plant requires. "It's not… all about the same thing, no. Or, well, I suppose it is, in the end, but the thing in question isn't the one you know about. I just—I cannot abide how much of the world is determined by that god's whim."

Iasion's brows knit. "He's more cunning than impulsive, I thought?"

She pushes out a breath, shifting her attention back to the two of you. "Yes. But I'm always tempted to say 'whim' anyway, because beyond retaining his own power and lording it over everyone else for fun, what he wants isn't terribly consistent from century to century."

*if (humorous > serious)
	"A delightful combination for all involved," you add dryly.
*if not (humorous > serious)
	"It's not too hard to see where that combination would cause problems," you add, tone a tad dry. 

Iasion runs a hand back over his hair. "You've both been through a lot," he murmurs softly. "I wish—well. I suppose it doesn't really matter. It's not like there's anything I could have done against the king of the gods but run my mouth and die for it, I suppose." His gaze finds the ground. 

Demeter winces. "Iasi…it. I never would have expected you to—"

"But that's just the problem, isn't it?" he says, the lightness of his tone strained nearly to the breaking point. "You knew I wouldn't have anything useful to offer. You knew I would only be a liability, used to hurt you. And so you shut me out instead. I should be grateful, but all I can think about is how much I've missed you. How much I've [i]missed[/i]." 

*fake_choice
	#"I understand how you feel, but please don't blame mother for it. She's been protecting us, all this time."
		*set iasion_reconcile true
		"I understand how you feel, but please don't blame mother for it. She's been protecting us, all this time." It's not unreasonable, to be upset at what happened. You can't imagine being in Iasion's exact situation.
		
		*if (demeterstatus = "open")
			But you've been in one that's similar enough, and you decided that the thing to do was forgive Demeter for the things she had to do to keep you safe in that world. You don't know exactly what would have happened if she'd failed in her attempt, but you know enough to be grateful she succeeded. 
			
			*if (opinion_childhood = "wantfreedom")
				Even if it chafed at the time. Even if you resented it for a while. 
			*if (opinion_childhood = "understand")
				Even then, you were. You understood why it had to be like that, and you're sure that, deep down, Iasion understands it, too. 
		*if (demeterstatus != "open")
			And your own approach to dealing with Demeter's overprotectiveness towards you hasn't been the [i]most[/i] conciliatory, but your situation is a bit different. In his case, things are… if not straightforward, then at least clearly justified. There was no one else who [i]could[/i] have protected him, had Zeus decided to end his life. He doesn't have the status that even you do. To everyone there, he would have been human. 
			
			A plaything for the gods. 
		
		"I do comprehend that," he says, pressing the words out on a sigh. Some of the tension in his body dissipates. "But I was not a child, and whether I was protected or not is something I should have had a say in. For all I lost… I think I would have chosen the risk." 
		
		"I know you would have," Demeter says quietly. "And I'm sorry. I wish I could say I regret it. Maybe I do. I was just… I thought it would be worth it, if I could see you again someday. If I could bring your ${son} to meet you." 
		
		"…Alive." 
		
		She nods. "If this was to be the end, perhaps you're right about everything. Perhaps we should have just enjoyed the time we had."
	*if (tag_intuitive)
		#@{convotoggle [❋]|} "It's frustrating, isn't it? Not being strong enough to help."
			*set iasion_reconcile true
			"It's frustrating, isn't it? Not being strong enough to help." That, you sense, is where a lot of his difficulty with the situation is really coming from. No doubt it isn't [i]everything[/i]—there's certainly an issue there about Demeter making decisions for him instead of consulting him, but you think the lion's share of his trouble isn't even with her so much as himself. 
			
			"I—" Iasion clears his throat, and his tone lowers to a quiet murmur. "Of course it is. And I know it's because of that that you were protecting me, Demi." Some of the tension in his body dissipates. "But I was not a child, and whether I was protected or not is something I should have had a say in. For all I lost… I think I would have chosen the risk." 
		
			"I know you would have," Demeter says quietly. "And I'm sorry. I wish I could say I regret it. Maybe I do. I was just… I thought it would be worth it, if I could see you again someday. If I could bring your ${son} to meet you." 

			"…Alive." 

			She nods. "If this was to be the end, perhaps you're right about everything. Perhaps we should have just enjoyed the time we had."
	#"You have a right to be angry. Whatever her motives, she deprived you of your choices." 
		"You have a right to be angry. Whatever her motives, she deprived you of your choices." It's not unreasonable, to be upset at what happened. You can't imagine being in Iasion's exact situation.
		
		*if (demeterstatus = "open")
			You've been in one that's a bit similar, of course, but yours is tempered by the fact that you were a child, for most of it. And even if you've wound up taking a conciliatory approach, that's not the only choice you could justifiably have made. He should know that his own is well open to him, and if he decides not to forgive her, he's well within his rights. 
		*if (demeterstatus != "open")
			You've been in one that's pretty similar, though, and you know he has every reason to be upset with her for this. Even if her motives were as pure as could be, making such a big decision without even telling him why, much [i]less[/i] actually consulting him about it, wasn't the right thing to do. If he decides not to forgive her, he's well within his rights. 
			
		"I wasn't a child, Demi," he adds, nodding slightly at you before his attention returns to her. "I know you were protecting me, but whether I was protected or not  is something I should have had a say in. For all I lost… I think I would have chosen the risk." 
		
		"I know you would have," Demeter says quietly. "And I'm sorry. I wish I could say I regret it. Maybe I do. I was just… I thought it would be worth it, if I could see you again someday. If I could bring your ${son} to meet you." 
		
		"…Alive." 
		
		She nods. "If this was to be the end, perhaps you're right about everything. Perhaps we should have just enjoyed the time we had."
		
		Iasion frowns, and the expression seems to stick, but in the end he shakes his head, letting out a long breath. 
		
		"Let's… talk about something else."
	#I'm not going to say anything here; this is something they have to work out themselves.
		*set iasion_reconcile true
		You're not going to say anything here; this is something they have to work out themselves. You do understand roughly how Iasion is feeling—while you've never been in his [i]exact[/i] position, your own was similar enough, not that long ago. 
		
		*if (demeterstatus = "open")
			And even if you've wound up taking a conciliatory approach about all of it, that's not the only choice you could justifiably have made. Whether he wants to forgive or not is a highly personal decision, and you wouldn't dream of trying to make it for him.
		*if (demeterstatus != "open")
			And your own approach to dealing with Demeter's overprotectiveness towards you hasn't been the [i]most[/i] conciliatory, but your situation is a bit different. In his case, things are… if not straightforward, then at least clearly justified. There was no one else who [i]could[/i] have protected him, had Zeus decided to end his life. He doesn't have the status that even you do. To everyone there, he would have been human. 
			
			A plaything for the gods. 
			
			Still, whether he can ultimately forgive the way she chose to do things is a highly personal decision, and you wouldn't dream of trying to make it for him. 
		
		"I needed you to be safe," Demeter says quietly. "I couldn't put you at risk. I [i]couldn't[/i]."
		
		"I do comprehend that," he says, pressing the words out on a sigh. Some of the tension in his body dissipates. "But I was not a child, and whether I was protected or not is something I should have had a say in. For all I lost… I think I would have chosen the risk." 
		
		"I know you would have," Demeter says quietly. "And I'm sorry. I wish I could say I regret it. Maybe I do. I was just… I thought it would be worth it, if I could see you again someday. If I could bring your ${son} to meet you." 
		
		"…Alive." 
		
		She nods. "If this was to be the end, perhaps you're right about everything. Perhaps we should have just enjoyed the time we had."		
*page_break
Awkward silence reigns for a little while as you walk, but the best thing to do seems to be to let it sit for a while. You can tell both of your parents are thinking, and admittedly there are some things you're dwelling on, too.

This proves to work well enough, as when Iasion speaks again, he sounds considerably less tense. 

"You know, ${name}, you've been through some things most other people would find it hard to imagine. Not the arranged marriage itself, exactly—those are common enough. But being a demi${god} on Olympus, then suddenly being told you live somewhere else, with a basket of strangers, and I can only imagine that it's tremendous whiplash, as environments go. Even if you turned out enjoying it, it takes a lot of resilience just to get [i]used[/i] to a new place like that. Especially when none of your own choices are involved."

He shakes his head. "Then to navigate a hearing with Zeus himself… I definitely don't think I could do that part with any semblance of skill."

"I'm not entirely sure anyone could," Demeter murmurs. 

*fake_choice
	#"What about you? Would you say more about how you got here?"
		"What about you? Would you say more about how you got here?" You know the broad contours of it by this stage, of course, but he hasn't spoken much about the war involved, or even particularly about how life was on Samothrace. You find that you want to know as much about him as he now knows about you. Perhaps even more. 
		
		Iasion hums, low in the back of his throat, folding his arms over his chest as he walks. "I could," he replies with a nod, "but I suppose I'm not sure what's… it's hard to find a simple, anecdotal way to describe a war. The systematic, logical type of explanation misses something important, but if we get into all the feelings I have about it, we won't be done with this conversation for another year, at least." 
		
		A breath puffs out through his nose. "It's an old war, by now. In a lot of ways. A lot of it came down to sitting around waiting for things to happen. That's the heart of it: interminable [i]waiting[/i], between short bursts of seeing and doing things that rip you apart. And sometimes being literally ripped apart, by the other side's weapons. That's almost the easiest bit, if I'm really honest. I don't have nightmares about getting stabbed." 
		
		You nod slightly, just showing that you're listening. 
		
		"Anyway, it… I don't think I want to say much more about it than that. Maybe some other day. In either case, it's how I ended up here. How most of these people did. I can understand why it might take them a while to learn to let it go. I can't. Not yet."
		
		You press your lips together. Perhaps that makes the part you've come to officially convey a little less likely to matter, but you should probably say it anyway, at some point. 
	#"I'm not sure that there's anything too incredible about it. I just got through things day by day."
		*set serious +1
		"I'm not sure that there's anything too incredible about it. I just got through things day by day." When it comes right down to it, to your mind, it's sort of what he said: lots of people deal with arranged marriages of one stripe or another, and for you, that was really the main inconvenience of it all. One that turned out not to be all that inconvenient in the first place. 
		
		His lips quirk. "I suppose that's a fair way of looking at it. As long as the day to day of it was manageable, almost any situation could be. And it seems like you've fit in well down here, so I suppose it's less extreme than it sounds, on the surface." 
		
		That was, somehow, a rather quicker understanding of the reality than you'd expected. 
		
		"You're… not going to argue that it must have been terrible?" 
		
		Demeter's jaw tenses.
		
		Iasion snorts. "Why would I? I don't know anything about it. If you say it wasn't, it's easy to believe you."
		
		Perhaps that fact about him will make the next bit of things easier to understand, as well. You've come here in part to convey something a little more official, after all, and this seems as good a time as any to do that. 
	#"It was hardly a great trial, really. There were certainly difficult parts, but those came more from ongoing problems in the Underworld than my situation itself."
		*set serious +1
		"It was hardly a great trial, really. There were certainly difficult parts, but those came more from ongoing problems in the Underworld than my situation itself." The Giant attack, Lethe's sickness… well, Kronos, really, was at the heart of most of the problems you encountered. Other things, like Orpheus's unexpected visit weren't really what you'd call [i]problems[/i], even if the were rather large departures from the ordinary flow of things. 
		
		The situation itself is basically just what he said: lots of people deal with arranged marriages of one stripe or another, and for you, that was really the main inconvenience of it all. One that turned out not to be all that inconvenient in the first place. 
		
		"I can imagine those were… challenging," Iasion says, a touch of wryness in his tone. "Not that I can imagine exactly what they [i]were[/i]. I know so little about anything here, but it already seems much more structured than I imagined it, somehow. More… civilized, if that makes sense?" 
		
		"I think so." At least, you can see where he might have thought it would be more chaotic here. That's supposedly built into the realm, though you've only ever seen small manifestations of that.
		
		Thinking about this subject, though, has reminded you of another. You've come here in part to convey something a little more official, after all, and this seems as good a time as any to do that. 
	#@{convotoggle [☆]|} "Ah yes, the great struggle I went through, meeting nice people and exploring my hobbies. A terrible trial."
		*set humorous +1
		"Ah yes, the great struggle I went through, meeting nice people and exploring my hobbies. A terrible trial." You can't help but laugh a little at your own joke. Really, though, he makes it sound like something much more challenging than it was, which you suppose is understandable from the outside. 
		
		But really, it's sort of what he said: lots of people deal with arranged marriages of one stripe or another, and for you, that was really the main inconvenience of it all. One that turned out not to be all that inconvenient in the first place. 
		
		And on top of it, you came out of the whole thing with friends and a place to live, and things that have meaning to you that you can spend your time on. It's hard to see the downsides when you remember all you've gained from it. 
		
		Iasion chuckles, too, shaking his head. "Fair point, I suppose. Those were… a little less obvious on the surface, it seems like you've fit in well down here, so I suppose the Underworld must be less extreme than it sounds." 
		
		That was, somehow, a rather quicker understanding of the reality than you'd expected. 
		
		"You're… not going to argue that it must have been terrible? I confess I was expecting you to argue it must have been terrible." 
		
		Demeter's jaw tenses. 
		
		Iasion snorts. "Why would I? I don't know anything about it. If you say it wasn't, it's easy to believe you."
		
		Perhaps that fact about him will make the next bit of things easier to understand, as well. You've come here in part to convey something a little more official, after all, and this seems as good a time as any to do that. 
	#@{convotoggle [☆]|} "And you haven't even heard about the Giant attack yet."
		*set humorous +1
		"And you haven't even heard about the Giant attack yet." You can't help but laugh a little at your own joke. But really, if he thinks that the parts he knows about were anything [i]difficult[/i], you have to wonder how he'll think of something like [i]that[/i]. 
		
		"You mean the one where you ended up unconscious at the end?" he asks, one side of his mouth curling up. "I might have come across some mention of that, actually. Though I don't know the exact details of what happened or how." 
		
		"You could have pretended like you hadn't. I thought that was a great comedic setup I gave you, just there." 
		
		"It was. But I have to admit the comedy potential was not the first thought on my mind, when it comes to that incident." One of his brows ticks up, and he huffs softly. "Perhaps it should have been; you're clearly quite fine in spite of it." 
		
		"You know, it's a little refreshing that you don't insist I must have constantly suffered here. I'm not sure that's something most people would easily believe." 
		
		Demeter's jaw tightens.
		
		Iasion snorts. "Why would I? I don't know anything about it. If you say you didn't, it's easy to believe you."
		
		Perhaps that fact about him will make the next bit of things easier to understand, as well. You've come here in part to convey something a little more official, after all, and this seems as good a time as any to do that.		
*page_break
You clear your throat. "Actually, I had another reason for coming here, besides catching up." You glance towards him, watching as he nods once, a bit more slowly than usual.

"I won't say I knew that, but I had wondered," he replies, folding his arms behind his back. "Something fairly serious, then?"

You nod as well. "It's somewhat complicated, and also vague, but we decided it would be worth it to tell you anyway. I… assume you know who Kronos is?" 

Iasion blinks; whatever direction he'd been expecting the conversation to go in, this is not it. "I've heard of him, yes. The father of Zeus, Poseidon, and Hades, and formerly king of the Titans? Well, I assume he's probably still their king, but they're collectively much less of an entity now, yes?" 

"Right. He… currently lives here. For some reason, Zeus has put him in charge of the Blesséd Isles. He was responsible for a lot of the problems that happened when I first came here, and for some reason, he seems interested in those of you that just arrived from above." 

That's about as well as you can summarize what you've been told; since no one has any idea of his motive or potential plan, it's not as though you can tell him to be wary of anything in particular. 

Iasion takes this in for a few moments, looking out at the river with a contemplative expression. "And you think his interest might not be benign." 

*if (humorous > serious)
	"I'm not sure if his interest is [i]ever[/i] benign," you say with a chuckle. It might be a serious matter, but sometimes a joke is just as good at conveying what's true.
*if not (humorous > serious)
	"It seems unlikely, given the other things he's been responsible for." You may not be able to say anything with complete certainty, but in some ways, Kronos's past behavior speaks for itself.

"Kronos never wants anything that isn't to his advantage in some way," Demeter says, her eyes narrowing precipitously. "He was once told by prophesy that his own son would overthrow him—and what he [i]did[/i] in response…" She clicks her tongue. 

"Even Zeus has more care for those around him, and I do not say so lightly."

"I see." Iasion frowns. "I'm not sure exactly how much I can prepare for something I don't really know about, but I'll keep my eyes open, nonetheless. It might have something to do with how many of these men are going to end up on the Isles. Some of them are the bravest, most pious and honorable people I know, after all."

*fake_choice
	#"Do you think... there might be a chance you end up there, after judgement?"
		"Do you think... there might be a chance you end up there, after judgement?" He's mentioned those with him, after all. You don't think it would be any great stretch to suppose that he, as their leader, would share those qualities, and as far as you can tell, courage and honor at least are traits that would give someone a better chance of ending up on the Isles. 
		
		"Me?" The question seems rhetorical; Iasion at least does not seem to be surprised that you've asked it. "I don't know," he admits. "I've done many things in my life that might be questionable. There are times, even, when I have cursed the gods. Times when I have chosen selfishly for my people over our neighbors. Times when I have resented my duty and wished to forsake honor. I hope I have lived well, but I am no judge, to know with any certainty." 
	#I can't ask him about himself, in that regard. It would imply pressure, and that's not something I want to put on him.
		You can't ask him about himself, in that regard. It would imply pressure, and that's not something you want to put on him. You don't [i]think[/i] it would be any great stretch to suppose that he, as their leader, would share those qualities, and as far as you can tell, courage and honor at least are traits that would give someone a better chance of ending up on the Isles. But there's a difference between supposing all of that and asking him to speculate on the next stage of his fate. 
		
		He studies you curiously for a moment, a twitch at the corner of his mouth. "I've done many things in my life that might be questionable," he says conversationally. "There are times, even, when I have cursed the gods. Times when I have chosen selfishly for my people over our neighbors. Times when I have resented my duty and wished to forsake honor. I hope I have lived well, but I am no judge, to know with any certainty." 
		
		A pause. "Just… in case you were wondering."
	#"I've spoken to some others about this, and they seem to think there's a pretty good chance [i]you[/i] might end up on the Isles, after you're judged."
		"I've spoken to some others about this, and they seem to think there's a pretty good chance [i]you[/i] might end up on the Isles, after you're judged." The fact that he's mentioned those with him is only a bit more evidence in favor of that hypothesis. You don't think it would be any great stretch to suppose that he, as their leader, would share those qualities, and as far as you can tell, courage and honor at least are traits that would give someone a better chance of ending up on the Isles. 
		
		"Me?" The question seems rhetorical; Iasion at least does not seem to be surprised that you've asked it. "I don't know," he admits. "I've done many things in my life that might be questionable. There are times, even, when I have cursed the gods. Times when I have chosen selfishly for my people over our neighbors. Times when I have resented my duty and wished to forsake honor. I hope I have lived well, but I am no judge, to know with any certainty." 
*page_break
"In any case," he adds, expression sobering, "I have to admit that while I've never aimed for a blesséd afterlife, I hope for one, now. It might allow me the chance at some sort of proper kinship with you… if that's something you would be interested in."

*fake_choice
	#"Of course I would be!"
		*set iasion_wantrelationship true
		"Of course I would be!" You jump on the offer immediately. It's something that had been in the back of your mind, already, but you hadn't been entirely sure how to broach the topic. Since Iasion's done that part himself, you can easily give him an answer. 
		
		The breadth of his smile can only be the same as yours: the kind that makes your cheeks hurt, just a little. "That's… you don't know how glad I am to hear that, ${name}. Or, honestly, maybe you do. I'm not sure if [i]I[/i] quite grasp how glad I am, right now." He laughs, a hint of nerves on the edge of it, but it's nevertheless a delighted sound. 
		
		*if ((touch2 = "averse") or ((touch = "averse") and (touch2 = "unknown")))
			"You, uh. I heard you weren't one for touching, so I won't ask for anything along those lines, but… know that this is the kind of thing I would normally be wanting to hug you about. It's a really… shockingly-good feeling, actually. I hope you feel a little bit of that, too." 
			
			*label nothugchoice2
			*fake_choice
				#"I do, and thank you."
					"I do, and thank you." Your smile remains, and his softens in response. 
					
					"Good. That's… really good."
				#"I'm not really sure what the urge to hug anyone feels like, but I can agree with the rest."
					"I'm not really sure what the urge to hug anyone feels like, but I can agree with the rest." Your smile remains, and his softens in response. 
					
					"Good. That's… really good."
				#"That's not my favorite metaphor, but the sentiment is appreciated."
					"That's not my favorite metaphor, but the sentiment is appreciated." Your smile becomes something a little different, and his softens in response. 
					
					"That's… fair. I'll need to figure out a better way to describe it, but… thanks."
		*if not ((touch2 = "averse") or ((touch = "averse") and (touch2 = "unknown")))
			Stopping, he spreads his arms out towards you, tilting his head in a querying manner. 

			"No, um. No hard feelings if this feels like a bit much, right now." 

			*label hugchoice2
			*fake_choice
				#I step into the embrace readily.
					You step into the embrace readily, and his arms wind around you. They're—perhaps you shouldn't be surprised by how much strength you feel in them. He's not entirely human, after all, and a soldier besides. It's a very [i]secure[/i] hug, and you squeeze back a little as he pats your back firmly before letting go. 
					
					A short thing, but emphatic, and enough that the smile on your face does not dim. 
				#It [i]is[/i] a little strange, but I want to try it anyway.
					It [i]is[/i] a little strange, but you want to try it anyway, so you step into it with only a bit of caution, and his arms wind around you. They're—perhaps you shouldn't be surprised by how much strength you feel in them. He's not entirely human, after all, and a soldier besides. It's a very [i]secure[/i] hug, and you squeeze back a little as he pats your back firmly before letting go. 
					
					A short thing, but emphatic, and enough that the smile on your face does not dim. 
				#"Maybe for right now, but ask again later." 
					"Maybe for right now, but ask again later." You're still very new to each other, after all. Perhaps such physical gestures are something you could work up to, but you're definitely not there yet. 
					
					"No problem," he replies, letting his hands drop back to his sides. If he's disappointed, he hides it well; his grin doesn't even slip. Perhaps he isn't.
	#"I think... I think that would be nice, if we get the chance."
		*set iasion_wantrelationship true
		"I think... I think that would be nice, if we get the chance." It's hard to feel the same way about it as you would if anything were guaranteed, but in spite of your caution, you [i]do[/i] want to say at least this much. You want a relationship with him, and you can admit that you're hoping you get one. 
		
		You offer him a tentative smile, one that he returns with a much broader grin. "That's… you don't know how glad I am to hear that, ${name}. Or, honestly, maybe you do. I'm not sure if [i]I[/i] quite grasp how glad I am, right now." He laughs, a hint of nerves on the edge of it, but it's nevertheless a delighted sound. 
		
		*if ((touch2 = "averse") or ((touch = "averse") and (touch2 = "unknown")))
			"You, uh. I heard you weren't one for touching, so I won't ask for anything along those lines, but… know that this is the kind of thing I would normally be wanting to hug you about. It's a really… shockingly-good feeling, actually. I hope you feel a little bit of that, too." 
			*goto nothugchoice2
		*if not ((touch2 = "averse") or ((touch = "averse") and (touch2 = "unknown")))
			Stopping, he spreads his arms out towards you, tilting his head in a querying manner. 

			"No, um. No hard feelings if this feels like a bit much, right now." 
			*goto hugchoice2
	#"That's not something I can decide until I know whether it's really an option. I hope you understand."
		"That's not something I can decide until I know whether it's really an option. I hope you understand." You shake your head with a twinge of regret. It would be [i]better[/i] if you could give him a proper answer right now, but too many things are up in the air for you to be comfortable with that. There's just no telling what happens in the near future, and you can't commit to anything one way or the other without more information. 
		
		Iasion nods, his expression remaining one of open, pleasant neutrality. You have to imagine the answer is a disappointment, but he doesn't go to the length of indicating as much. 
		
		"I understand," he says quietly. "I think I'm used to a lot of things in life being unreliable, but it's different for someone in your position. So… wait it out if that's what you need. I'm always here if you just want to talk, and I won't assume it means anything if you do." 
		
		Something tight in your chest eases, just a little.
	#"Let's not jump all the way to that conclusion. We can talk more, for now, but I'm not committing to treating you like my father."
		"Let's not jump all the way to that conclusion. We can talk more, for now, but I'm not committing to treating you like my father." There's the uncertainty of his fate to consider, of course, but it's not [i]just[/i] that. You're still basically strangers to one another, even if talking has helped ease the sense of that a bit. 
		
		Whether you'll end up wanting a closer relationship with him or not isn't something that can be decided with so little interaction, though. 
		
		Iasion nods, his expression remaining one of open, pleasant neutrality. You have to imagine the answer is a disappointment, but he doesn't go to the length of indicating as much. 
		
		"I understand," he says quietly. "We're definitely not starting on the same footing, to put it one way. I'm always here if you just want to talk, and I won't assume it means anything if you do." 
		
		You feel yourself relax fractionally. 
*page_break
"And Demi…" he trails off, turning his attention to your mother. 
*if (iasion_reconcile)
	"Let's… try to figure this out. Can you agree to that?"
	
	Her eyes round subtly, and it takes her a moment to find her voice. "Of course," she says, tone thickened. "It… may not be the easiest thing; I have to return to Olympus soon, but… I'm sure Hermes would be willing to carry some letters."
	
	"Letters." Iasion pauses for a moment, but the turn of his mouth is ever so slightly upwards. "I can't promise eloquence, but I can promise letters." 
*if not (iasion_reconcile)
	"Let's… we've both got some thinking to do, I suppose. Is there any way I can contact you, from here out?"
	
	She pulls in a soft breath through her nose, lips pinching. "Of course. I must return to Olympus, soon, but… I'm sure Hermes would be willing to carry some letters." 
	
	"Letters." Iasion pauses for a moment, the turn of his mouth ever so slightly downwards. "I suppose we can try something like that. Yes. I can't promise eloquence, but… I'll write." 
*page_break
The three of you walk for a while longer, sometimes talking and sometimes just ambling along, but in time, you both have other things to return to. And so you part ways: he to the riverbank, and you and your mother once more to your home, and her guest quarters.
*set met_iasion true
*goto ro_scenehub

*label ro_scenehub
*page_break
*if (route = "hades")
	*goto chap3hades
*if ((route = "hermes") and (poly != "yes"))
	*goto chap3hermes
*if (route = "charon")
	*goto chap3charon
*if (route = "pyri")
	*goto chap3pyri
*if (route = "alekto")
	*goto chap3alekto
*if ((route = "hekate") and (poly != "yes"))
	*goto chap3hekate
*if (poly = "yes")
	*goto chap3poly

*label chap3poly
A few days later, Demeter has returned to Olympus. You're not sure exactly when or if she'll be back, but for now at least, she has obviously seen Iasion and confirmed his identity. What difference it will make in the long run, you can't be sure, but some things are surely worth doing even if they don't change how the world works. 

You wonder, for a moment, what you would do in her position, but the thought is easily enough brushed aside. 

*if (route = "hermes")
	Hermes, sitting next to you in the common room, is in the process of re-stringing one of the harps while you have a snack and something to drink. It seems to be a rather involved process, but you have the feeling that his intent concentration on it does not mean he's lost track of what [i]you're[/i] doing, either. 
*if (route = "hekate")
	Hekate, sitting next to you in the common room, is tinkering with some sort of small device while you have a snack and something to drink. It's made of a series of brass rings of varying sizes, which she'd taken apart to polish and seemingly adjust, given the way she's wiped all the previous etching off each with magic.

It's nice, to get a chance to just exist in the same space for a while. With everything that's happened over the last week and some, you've not really had the chance to let yourself relax as much as you might have liked, nor spend as much time with
*if (route = "hermes")
	him.
*if (route = "hekate")
	her. 

It's as you're coming to the end of your food that there's a small knock on the frame of the door—a slightly ridiculous practice, given the nature of the room, but one that almost everyone observes as a matter of courtesy nonetheless. 

*if (route = "hermes")
	You and Hermes both look up, to find Hekate in the doorway, and she smiles broadly at both of you. "I come bearing gifts," she intones, a bit of humor in the false gravity of it. 
	
	Hermes looks up from his work, raising an eyebrow. "Gifts? Have you done something?" 
	
	"Only you would think a gift is automatically meant to smooth something over, Hermes." Hekate strides in, taking a seat on the couch opposite the two of you, and hands each of you a small, stoppered vial. 
	
	"I was doing some work with alchemy today, and decided to make some scented oils for fun. They're nothing elaborate, but they will make your rooms smell nice, if you so desire. And because I'm me and also didn't know what scents you preferred, ${name}, it's magic and you can choose from between several. Experiment with it later and tell me what you think. Hermes, yours smells like cinnamon and oranges." 
	
	"I'd be upset you only gave me one smell, but I guess you do have good taste." He grins, accepting the vial. "Thanks, Hekate."
	
	*fake_choice
		#"Yes, thank you. This is lovely." 
			*set forthright +1
			"Yes, thank you. This is lovely." You accept your vial with some curiosity, but you can always figure out how it works later. At the moment, lifting the cork tells you it smells the same as Hermes's—citrus and warm spice. 
			
			You replace the stopper carefully, then set it aside so you don't forget to take it back to your room, later. 
			
			"You're welcome, of course," Hekate replies. "I had the supplies to make them, so I thought, 'why not'?"
		#"What are my scent options, exactly?"
			"What are my scent options, exactly?" You accept your vial with some curiosity, wondering how something like that would work. Hekate has a knack for making things complex on the side of creation so that they are simple on the side of [i]use[/i], but that alone doesn't tell you much. 
			
			At the moment, lifting the cork tells you it smells the same as Hermes's—citrus and warm spice. 
			
			"There's several. Actually, in theory you can choose any, as long as you can envision in your mind what it smells like and give the vial a shake. If not, just shake it normally and it'll cycle through a few different flowers, fruits, and types of wood." 
			
			That's quite convenient.
		#"I'm a bit sensitive to strong odors, unfortunately."
			"I'm a bit sensitive to strong odors, unfortunately." You accept the vial anyway, because it's being handed to you, but you can't see yourself using it for anything. 
			
			"Well, they don't have to be strong," Hekate says. "You can adjust that. Just hold the vial between your thumb and forefinger. Tilt it towards the cork for a stronger smell, and away from it for a weaker one. With intent, obviously; purely physically that wouldn't do much."
			
			Maybe that would work for you; you can at least give it a try. If it's still too strong, well, you can appreciate the thought at least. 
		#I nod, thankful for the thought.
			*set reserved +1
			You nod, thankful for the thought. Reaching out, you accept your vial with some curiosity, but you can always figure out how it works later. At the moment, lifting the cork tells you it smells the same as Hermes's—citrus and warm spice. 
			
			You replace the stopper carefully, then set it aside so you don't forget to take it back to your room, later. 
			
			"You're welcome, of course," Hekate replies to the unspoken sentiment. "I had the supplies to make them, so I thought, 'why not'?"
	*page_break
	"Are you free now?" Hermes asks, stowing his vial… somewhere, with a flick of his fingers. Honestly, it just seems to disappear. Maybe he sent it back to his room directly or something. "No more work for the day?"
	
	She dips her chin. "No more for today. My project's giving me some headaches, so I'm taking a break. Letting things ferment in the back of my head for a while. Like cheese. Or wine." 
	
	"Want to join us, then? No idea what we're doing yet, but in a way that makes it easier." 
	
	Hekate smiles. "I'd love to."
	*page_break
*if (route = "hekate")
	You and Hekate both look up, to find Hermes in the doorway, and he grins at both of you. "Oh look, if it isn't two of my favorite people. I brought you something, actually. Was just up in the mortal realm, thought you might like these."
	
	"'These' being?" Hekate lifts an eyebrow as the younger god moves in, taking a seat on the couch across from you. 
	
	He shows you his hands, which each have a fruit in them you've never actually seen in person before. Slightly oblong, the skin mostly red and yellow, with a little bit of green at one end. 
	
	"Mangoes?" you ask. 
	
	Hermes nods. "Yeah! I was out east today helping a soul. Like… farther east than usual. It's where these grow. I thought you might want to try them. You don't eat the skin, I don't think. Just in case you weren't aware." 
	
	"Well, sure. I'll try something new." Hekate accepts one of the fruits, running a finger down the length to separate it, then considering her next move with a head-tilt.
	
	*fake_choice
		#"Mother doesn't grow these. At least, not in the garden I'm familiar with. Thanks for letting me try one."
			*set forthright +1
			"Mother doesn't grow these. At least, not in the garden I'm familiar with. Thanks for letting me try one." You mimic Hekate's action, 
			*if (tag_unmagic)
				albeit clumsily,
			and the fruit splits open for you as well. Avoiding the skin isn't too hard if you make your magical cuts precise, and the tangy flavor of the fruit is unlike anything you've had before. 
			
			"I think this would be good with honey on it," Hekate remarks. "Not that it's bad by itself."
		#"I've just eaten, actually. Maybe later." 
			"I've just eaten, actually. Maybe later." You accept the fruit but don't follow suit with Hekate. You [i]did[/i] just finish your snack, after all.
			
			"Ah, bad timing on my part then. Not that it going bad is really an issue if [i]you[/i] have it." Hermes's smile widens briefly. "I wouldn't mind having a power like that. Keeping things fresh, or however it works." 
			
			"Technically it's preventing the process of decay," Hekate chimes in, after another bite. "Well, sorry. I should have let you explain it." She presses her lips together.
			
			"It's fine," you reply, shaking your head. Certainly, in some contexts you would prefer to do the explaining, but this is such a minor thing, among friends, that you really don't feel the need. 
			
			She gives you a soft smile, shoulders relaxing a bit. 
		#"I appreciate the thought, but no thank you."
			"I appreciate the thought, but no thank you." You shake your head, and Hermes draws back the one he'd offered out to you with a shrug. 
			
			"Suit yourself. I don't mind eating it." And he does, mimicking Hekate's magical slicing procedure and then turning the skin inside out to get at the squares of fruit still clinging to it. 
			
			"I think this would be good with honey on it," Hekate remarks. "Not that it's bad by itself."
		#I nod, accepting the fruit. It was nice of him to think of me.
			*set reserved +1
			You nod, accepting the fruit. It was nice of him to think of you. You mimic Hekate's action, 
			*if (tag_unmagic)
				albeit clumsily,
			and the fruit splits open for you as well. Avoiding the skin isn't too hard if you make your magical cuts precise, and the tangy flavor of the fruit is unlike anything you've had before. 
			
			"I think this would be good with honey on it," Hekate remarks. "Not that it's bad by itself."
	*page_break
	"Anyway, Hermes, are you off again, or would you like to stay a while?" Hekate flicks her wrist, and the skins of your fruits disappear, presumably back to the kitchen for use in the orchard, as fertilizer.
	
	"I don't have anything pressing, no," he replies with half a grin. "What are you two going to get up to?"
	
	You and Hekate exchange a glance, and she shrugs as he sits down across from the both of you. "We hadn't really decided, yet. Perhaps you can help us figure something out."
*page_break
"All right."  Hermes stretches his wings a bit behind him, humming softly. "Well, I guess maybe a game of some sort might be easy. Something we can talk while playing, so nothing too intense. I know how you get with your strategy games." 

He rolls his eyes at her, and she huffs. 

"You just don't like losing." 

"What about you, ${name}? Preferences for games?" Hermes shifts bright, silvery eyes to yours. 

*fake_choice
	#"I don't really care which game we play, honestly. I'm happy to go with whatever you two pick."
		"I don't really care which game we play, honestly. I'm happy to go with whatever you two pick." The activity seems much less important than the company, to you, and you don't know very many games in the first place. 
		
		"All right. We'll take Hermes's suggestion and pick something fairly simple, then. I think there's a  board around here somewhere…" 
		
		Eventually, she finds what she's looking for, and they get a small wooden board set up on the table between you. There are a few pieces of different sizes, and a six-sided die, and some cards, but you're unfamiliar with the setup. 
	*if (knows_petteia)
		#"Makaria and I played a game that I liked. Petteia, I think?"
			"Makaria and I played a game that I liked. Petteia, I think?" You hadn't been familiar, before, and to be honest you still don't know many games at all, but it's the first one you think of. 
			
			"Hm. That's really only meant for two players, but we can try something kind of similar." Hekate smiles, then waves her hand at one of the bookshelves, summoning a board and setting it out on the table. There are a few pieces of different sizes, and a six-sided die, and some cards, but you're unfamiliar with the setup. 
	#"I agree that it should be something simple." 
		"I agree that it should be something simple."  The activity seems much less important than the company, to you, and you don't have the largest repertoire to choose from to begin with. 
		
		*if (stratgamewin)
			"And here I thought you enjoyed a challenge," Hekate says with a chuckle. "After your win at the party, I figured you'd be quite the formidable opponent. Compared to this one, who cheats." 
		*if not (stratgamewin)
			"Alas, no one wants a challenge," Hekate says with a chuckle. "I was looking forward to seeing what happened with you in the mix, unlike this one, who cheats." 
			
		"I find creative solutions to resource discrepancies," Hermes replies immediately. "Games should be like life."
		
		"Whatever you say, Hermes."
	#"I'd prefer something challenging. I think we can manage conversation even if we're doing that."
		"I'd prefer something challenging. I think we can manage conversation even if we're doing that." It would be nice to have something to sink your teeth into. Not [i]literally[/i], given that you've just eaten, but a more engaging activity should make for more interesting conversation anyway, you think.
		
		*if (stratgamewin)
			"Not a surprise, from you," Hekate says with a chuckle. "But count me in. I'm keen to see how you handle a new game, after your win at the party. At least you'll be formidable on your own merit. This one cheats." 
		*if not (stratgamewin)
			"Ah, excellent." Hekate chuckles. "I wasn't sure what to expect from your answer, but I'll be keen to see how things go with you in the mix. At least you'll play on your own merit. This one cheats."
		
		"I find creative solutions to resource discrepancies," Hermes replies immediately. "Games should be like life."
		
		"Whatever you say, Hermes."
*page_break
You get your game set up, everyone moving down onto the floor for better positioning relative to the board. 
*if (route = "hekate")
	Hekate nests herself comfortably on a large cushion,
	*if (((hekate_touch2 = "ask") or (hekate_touch2 = "permission")) or (touchtoggle = "default"))
		considering a moment before patting the spot next to her. It's not so large that you could keep much space between the two of you; you'd be sitting mostly against one another. But that's clearly the point. 
		
		*fake_choice
			#I take the seat without hesitation. 
				*if ((touchtoggle = "default") and (hekate_touch2 != "ask"))
					*set hekate_touch2 "permission"
				You take the seat without hesitation, getting yourself settled on the cushion. The distance is intimate; even just resting, her shoulder and arm are leaned into you with a soft pressure, enough to make her warmth quite evident. 
				
				"Look at you two, getting cozy," Hermes says with a broad grin. "I'm almost jealous of how comfortable you look."
				
				"You can stay over there," Hekate replies, arching a brow. "I don't trust you not to look at cards you shouldn't be seeing." 
				
				He sighs theatrically. "My wily ways come back to bite me once again."
				*set touching true
			#I hesitate just a little, then nod and take the seat. 
				*if ((touchtoggle = "default") and (hekate_touch2 != "ask"))
					*set hekate_touch2 "permission"
				You hesitate just a little, then nod and take the seat. The distance is intimate; even just resting, her shoulder and arm are leaned into you with a soft pressure, enough to make her warmth quite evident. 
				
				It makes you a little nervous, your heart perhaps too fast in your chest for how relaxed it all is otherwise, but you can deal with that. 
				
				"Look at you two, getting cozy," Hermes says with a broad grin. "I'm almost jealous of how comfortable you look."
				
				"You can stay over there," Hekate replies, arching a brow. "I don't trust you not to look at cards you shouldn't be seeing." 
				
				He sighs theatrically. "My wily ways come back to bite me once again."
			#I consider it a moment, then shake my head.
				You consider it a moment, then shake your head. 
				*if (hekate_touch2 = "averse") or (hekate_touch2 = "ask")
					You know she keeps asking about these things for your benefit, in case you decide you can be comfortable with a specific kind of contact, and you appreciate it, but this isn't one you like the idea of. 
				*if (hekate_touch2 = "permission")
					Considering that you're about to play a game, a little more space feels more appropriate. 
				
				Hekate offers no protest, just a wry smile, before conjuring you a similarly large cushion of your own. That, you gladly settle on.
		*page_break
	*if ((hekate_touch2 = "averse") and (touchtoggle != "default"))
		then looks at you contemplatively for a moment before summoning another, laid flush with her own. The distance is comfortably intimate, but crucially [i]not[/i] within touching distance, and you get yourself settled, pleased by the thought. 
	*page_break
*if (route = "hermes")
	Hekate nests herself comfortably on a large cushion, and Hermes seems to consider for a moment before summoning another himself and getting settled onto it. 
	*if (((hermes_touch2 = "permission") or (hermes_touch2 = "ask")) or (touchtoggle = "default"))
		Grinning at you, he pats his thigh, a clear invitation to sit with him in a very close manner. 
		
		*label hermessit
		*fake_choice
			*if (height > 5)
				*disable_reuse #"Aren't I a bit too tall for that to be comfortable?" 
					"Aren't I a bit too tall for that to be comfortable?" You're certainly taller than [i]him[/i],
					*if (height = 5)
						If not by all that much.
					*if (height > 5)
						and by a pretty considerable amount, at that. 
					
					"No?" he replies, with a chuckle. "You'll fit, and that's all that really matters for this. I can just lean around you when I need to see the board. But it's up to you."
					*goto hermessit
			#I take the offer without hesitation. 
				*if ((touchtoggle = "default") and (hermes_touch2 != "ask"))
					*set hermes_touch2 "permission"
				*set touching true
				You take the offer without hesitation, getting yourself seated on his legs. It's a very intimate distance, obviously, and perhaps slightly awkward as a position while you both adjust to make it comfortable, but you manage. 
				
				*if (height < 4)
					You fit easily, at least, and Hermes leans forward a little, pressing his chest to your back and winding his arms around your waist, setting his chin on your shoulder. You can feel his chuckle against the skin of your neck as much as you hear it, and the sensation makes the hairs on the back of your neck stand up. 
				*if (height = 4)
					Being about the same height as him means it's a fraction awkward; with the extra inches provided by his thighs, you're slightly taller, now, but he doesn't seem to have trouble adjusting, propping his chin on your shoulder with only a little difficulty and winding his arms around your middle. You can feel his chuckle against the skin of your neck as much as you hear it, and the sensation makes the hairs on the back of your neck stand up.  
				*if (height > 4)
					You [i]are[/i] taller than him, even just standing next to each other, and this fact is amplified by the extra height you get from sitting [i]on[/i] him, but he doesn't seem to mind. Eventually, you settle somewhat sideways to make it easier, and he hums, leaning his brow against your arm, near your shoulder, and wrapping his arms around your middle. You feel his fingers stroke lightly at your waist as he chuckles, and the sensation makes the hairs on the back of your neck stand up. 
				
				"I have the best ideas," he declares. 
				
				"Oh, you two are flagrant," Hekate replies, but there's nothing but good-natured amusement in her tone. 
				
				"You're just jealous." 
				
				"Of ${name}? Right now, not in the least. Of you?" She pauses, as if thinking about it, then winks at you. "Maybe a little."
			#I hesitate a little, but then take the offer.
				*if ((touchtoggle = "default") and (hermes_touch2 != "ask"))
					*set hermes_touch2 "permission"
				*set touching true
				You hesitate a little, but then take the offer, getting yourself seated on his legs as best you can.  It's a very intimate distance, obviously, and perhaps slightly awkward as a position while you both adjust to make it comfortable, but you manage. 
				
				*if (height < 4)
					You fit easily, at least, and Hermes leans forward a little, pressing his chest to your back and winding his arms around your waist, setting his chin on your shoulder. You can feel his chuckle against the skin of your neck as much as you hear it, and the sensation makes the hairs on the back of your neck stand up. 
				*if (height = 4)
					Being about the same height as him means it's a fraction awkward; with the extra inches provided by his thighs, you're slightly taller, now, but he doesn't seem to have trouble adjusting, propping his chin on your shoulder with only a little difficulty and winding his arms around your middle. You can feel his chuckle against the skin of your neck as much as you hear it, and the sensation makes the hairs on the back of your neck stand up.  
				*if (height > 4)
					You [i]are[/i] taller than him, even just standing next to each other, and this fact is amplified by the extra height you get from sitting [i]on[/i] him, but he doesn't seem to mind. Eventually, you settle somewhat sideways to make it easier, and he hums, leaning his brow against your arm, near your shoulder, and wrapping his arms around your middle. You feel his fingers stroke lightly at your waist as he chuckles, and the sensation makes the hairs on the back of your neck stand up. 
				
				"I have the best ideas," he declares. 
				
				"Oh, you two are flagrant," Hekate replies, but there's nothing but good-natured amusement in her tone. She scans your face a moment, studying you before she nods. 
				
				"You're just jealous." 
				
				"Of ${name}? Right now, not in the least. Of you?" She pauses, as if thinking about it, then winks at you. "Maybe a little."
			#"We should swap places."
				*if ((touchtoggle = "default") and (hermes_touch2 != "ask"))
					*set hermes_touch2 "permission"
				*set touching true
				*set hermeslap true
				"We should swap places." You nudge at his leg, and he gets the idea readily enough, huffing a laugh and moving off the cushion so you can sit down first. 
				
				*if (height < 4)
					"You know, I'm not against this, but it might have been a little easier for everyone to see the other way. I'm not tall, but you're even shorter than me."
					
					He [i]is[/i] taller than you, even just standing next to each other, and this fact is amplified by the extra height he gets from sitting [i]on[/i] you, but he doesn't seem to mind, and you knew that was going to be the case when you asked. Eventually, he settles somewhat sideways to make it easier, and you're able to put your hands around his middle. 
					
					He rests his brow against the side of your head for a moment, and you feel the breath of his soft chuckle over your ear. The sensation makes the hairs on the back of your neck stand up.
				*if (height = 4)
					"Well, I guess if you insist. It's going to be about the same either way, you know." He makes a gesture from the top of his head to your own, indicating your similar heights, but for you that's not really the point. You just want to be the one holding. 
					
					Sitting on your legs, he [i]is[/i] a bit taller than you, by a bit, but it's not too hard to adjust for. Eventually, he settles somewhat sideways to make it easier, and you're able to put your hands around his middle. 
					
					He rests his brow against the side of your head for a moment, and you feel the breath of his soft chuckle over your ear. The sensation makes the hairs on the back of your neck stand up.
				*if (height > 4)
					"Well, if you insist. I suppose it might be a little easier." He settles after you have, fitting easily enough, and you're able to lean forward into a comfortable position, pressing your chest to his back. The wings are a bit awkward, but the manages to spread them such that most of their bulk is out to either side and not in the way. You set your chin on his shoulder for a moment, and the scent of fresh air and warm skin hits you immediately, making the hairs on the back of your neck stand up. 
				
				"I have the best ideas," he declares. 
				
				"Half credit," Hekate replies immediately. "${name} is just as responsible for your current coziness." There's nothing but good-natured amusement in her tone. 
				
				"You're just jealous." 
				
				"Of ${name}? Right now, not in the least. Of you?" She pauses, as if thinking about it, then winks at you. "Maybe a little."
			#I consider it a moment, then shake my head. 
				You consider it a moment, then shake your head. 
				*if (hermes_touch2 = "averse") or (hermes_touch2 = "ask")
					You know he keeps asking about these things for your benefit, in case you decide you can be comfortable with a specific kind of contact, and you appreciate it, but this feels like a bit too much. 
				*if (hekate_touch2 = "permission")
					Considering that you're about to play a game, a little more space feels more appropriate. 
				
				Hermes only shrugs, still wearing a smile, and draws another cushion from who knows where for you to sit on instead. That offer, you can easily accept, and you get settled quickly. 
	*page_break
	*if ((hekate_touch2 = "averse") and (touchtoggle != "default"))
		He considers you for a moment before adding another, laid flush with his own. The distance is comfortably intimate, but crucially [i]not[/i] within touching distance, and you get yourself settled, pleased by the thought. 
	*page_break
With everyone settled, you assemble the game materials you'll be playing with, making sure everyone knows the rules before beginning. 

The initial few rounds pass, the conversation mostly being about the game itself, but after that things relax a little, and the three of you fall into more personal conversation topics. 

*if ((demeter_sequel_1 = false) and (iasion2 = "none"))
	"So… Demeter left," Hermes ventures, silver eyes shifting to you before they glance back at the game board. "Seems like you didn't get much involved with all that, but… it's got to be stressful having it all going on around you, right?" 
	
	The question seems to be just a question; though obviously asking with no small amount of curiosity, he's not condemning the choice, that you can discern. You don't think Hermes would, anyway; he of all people understands complicated situations with one's parents.
	
	*fake_choice
		#"Well, I understand Iasion has no choice, and Demeter has a right to see him. I just don't want to be involved."
			"Well, I understand Iasion has no choice, and Demeter has a right to see him. I just don't want to be involved." He didn't choose to be dead. And he hasn't pressured you for anything. The fact that you don't want to see him has much more to do with you than with him. And considering how important he must have been to Demeter at some point, you can't begrudge her coming to visit him, really. 
			
			You just wish all this could be taking place somewhere a little farther from you. Since it can't, you'll deal with the situation you have. 
			
			"I suppose that's a pragmatic way to look at it," Hekate says with a small nod. "It shouldn't be too difficult to stay out if things you don't want to be dragged into, here. The Underworld's a big place."
		#"It's incredibly stressful, honestly. But all I can do is wait it all out."
			"It's incredibly stressful, honestly. But all I can do is wait it all out." Iasion didn't decide to die, obviously, and he's not pressuring you to do anything. Demeter's presence is inherently a bit more… compelling, in the literal sense of the word, but you can do your best to ignore it and avoid her as well. Hopefully she won't be coming here again, and if she does, she can stay to a part of the Underworld you will not be in. 
			
			It's not [i]quite[/i] enough to give you hives, but you do sometimes feel that if you were perhaps a touch more human, it would. 
			
			"I'm sorry," Hekate says, grimacing. "At least the Underworld's a big place. No getting dragged in any more than this unless you want to be."
		#"Fortunately, he's not in a part of the Underworld I need to visit, and she won't be allowed to come back whenever she likes."
			"Fortunately, he's not in a part of the Underworld I need to visit, and she won't be allowed to come back whenever she likes." Iasion didn't decide to die, obviously, and he's not pressuring you to do anything. Demeter's presence is inherently a bit more… compelling, in the literal sense of the word, but you can do your best to ignore it and avoid her as well. She doesn't just get to drop in whenever she wants, at the very least. 
			
			Hekate grimaces. "Well, no. But she probably will come back at least a couple of times. Hades isn't going to keep her away from Iasion if she actually asks to come here. But, the Underworld is a big place, and you won't have to handle any of that if you don't want to, so… consolation, I hope." 
			
			It is a bit of that. 
		#"It's... difficult. Complicated. But it won't be like this forever."
			"It's... difficult. Complicated. But it won't be like this forever." Your emotions about the whole thing aren't completely straightforward, but you [i]do[/i] have a lot of them to deal with. Iasion didn't decide to die, obviously, and he's not pressuring you to do anything. Demeter's presence is inherently a bit more… compelling, in the literal sense of the word, but you can do your best to ignore it and avoid her as well, for now. 
			
			Whatever happens, the situation can't recur too many times. There's a limit on how much time Iasion has before his soul is judged, and then either he'll be on the Isles, a place you don't ever go and don't have to, or he'll have forgotten everything, and there won't be any reason for your mother to return. 
			
			It's… hardly a [i]good[/i] ending, but at least it means you won't have to keep trying to decide how to handle unexpected and unpleasant situations.
			
			"Well, that's definitely true," Hekate says with a soft huff. 
	*page_break
*if ((demeter_sequel_1) and (iasion2 = "none"))
	"So… Demeter just left," Hermes ventures, silver eyes shifting to you before they glance back at the game board. "I know you saw her, but you didn't see Iasion after that? I sort of thought maybe the chance to learn more about your history would have been interesting, at least."
	
	The question seems to be just a question; though obviously asking with no small amount of curiosity, he's not condemning the choice, that you can discern. You don't think Hermes would, anyway; he of all people understands complicated situations with one's parents.
	
	*fake_choice
		#"I have certain obligations to her as the person who raised me, but none to him. I just don't want her to make a fuss, and now she won't."
			"I have certain obligations to her as the person who raised me, but none to him. I just don't want her to make a fuss, and now she won't." That's what it had been about: obligation. Not preference, and certainly not desire. 
			
			*if (demeterstatus = "open")
				Whether or not you'd welcome contact with her at a different time, all of this was just… a mess you didn't want anything to do with.
			*if (demeterstatus != "open")
				You didn't welcome the contact with her, but it had been necessary to prevent things from becoming an even bigger mess, in your estimation. 
			
			"I guess that's fair," Hermes says with a shrug. "She might've kicked up a fuss if she'd come all this way and you said you didn't want to talk to her." 
			
			Hekate grimaces. "I'm sure she'll be back a few more times, before everything resolves. Don't feel like you have to do that every time, if you really don't want to. Hades can forbid her from setting foot anywhere he doesn't want her to go—and I mean that literally."
			
			Useful to know, though you have to wonder if you'll make use of the information. Obligations hold, after all, even if you don't especially want them to. 
		#"It's a difficult situation, but at least I know she'll always be around. That's what makes most of the difference." 
			"It's a difficult situation, but at least I know she'll always be around. That's what makes most of the difference." You aren't [i]pleased[/i] that there's no room to be developing a relationship with your father, but you [i]do[/i] feel there is none. Your mother isn't going anywhere. She will never forget you, and she has always been a part of your life. 
			
			*if (demeterstatus = "open")
				That is all significant. And it means that, even should your relationship become difficult or troubled in a way it isn't right now, it will be worth the time and effort to fix. Just like it is currently worth time and effort to maintain. 
			*if (demeterstatus != "open")
				That isn't always for the better, but it does mean that even if your relationship is not doing exceptionally well right now, it is worth keeping the door open. Trying to mend things, one little bit at a time. 
				
			You just… can't make yourself invest like that in your father, when you know it will all come to nothing but heartache. 
			
			"Yeah, that… not sure how I'd even begin to handle that," Hermes admits. "But if you need to protect yourself, then that's how it is." 
			
			"And you can always change your mind, if things turn out differently later," Hekate points out. "I guess it will be a while before we know. Probably months at least. But we [i]will[/i] know, eventually. No harm in waiting." 
			
			You doubt you [i]will[/i] change your mind, but the point is fair enough, you suppose. 
		#"Of course I'd see my mother, but I'm honestly just... uncomfortable, with the rest of the situation." 
			"Of course I'd see my mother, but I'm honestly just... uncomfortable, with the rest of the situation." Your father is a stranger to you, one who happens to be related by blood. But that tie doesn't mean you suddenly feel connected to him, and frankly you're much more comfortable with remaining strangers. Your lives have been separate until now, and even though that doesn't seem to be his [i]fault[/i], it is a fact. Sometimes, things just work out that way. 
			
			*if (demeterstatus = "open")
				Your mother, of course, is the furthest thing from a stranger, and as unexpected as her visit was, you have nothing against it. It was nice to see her, in fact, even if the reason for it had more than you would like to do with extenuating circumstances, so to speak. 
				
				Perhaps, in time, she will come to the Underworld of her own volition, in a way that has nothing to do with an emergency. 
			*if (demeterstatus != "open")
				Maybe the first part wasn't obvious, either; you've certainly had your differences with Demeter, and you definitely hadn't planned on seeing her again so soon. But when the situation came up, it just seemed like the obvious thing to do. Perhaps your resolve on the point is not so solid as you thought; if so, that's something important to know about yourself. 
				
				It could mean things are already beginning to heal. 
			
			"Yeah, that… not sure how I'd even begin to handle that," Hermes admits. "But if you prefer things as they are, then that's how it is." 
			
			"No shame in it," Hekate agrees. "I think I know what I'd do, but my experiences are very particular." 
			
			You have no idea what those are, but the tone of her voice leaves little room for doubt.
		#"I always try to act in a way I won't regret, and in this case, I've succeeded." 
			"I always try to act in a way I won't regret, and in this case, I've succeeded."  You know it's a vague sentiment, one that doesn't really explain your actions, but that's what you'd prefer, right now. You think they might be seeking a more detailed answer, but… it's just not in you give something like that, right now. You don't need to justify yourself. 
			
			And they won't force it. 
			
			"Well, that's the main thing," Hekate says with a small shrug. "I'd hate to regret something that had to do with family. Especially something that couldn't be changed afterwards. As long as you're happy with the situation, you've probably done it the right way."
			
			You certainly feel you have.
*if ((demeter_sequel_1 = false) and (iasion2 != "none"))
	"So… Demeter just left," Hermes ventures, silver eyes shifting to you before they glance back at the game board. "She was pretty rattled, I think. But you went to see Iasion without her? How was that?" 
	
	The question seems to be just a question; though obviously asking with no small amount of curiosity, he's not condemning the choice, that you can discern. You don't think Hermes would, anyway; he of all people understands complicated situations with one's parents.
	
	*fake_choice
		#"Well, he talks about her a bit too much for me, but it's not like I don't understand."
			"Well, he talks about her a bit too much for me, but it's not like I don't understand." You hadn't wanted to see her, or get her involved in this, at this particular juncture. And in some sense, you couldn't escape doing so even with your decision to leave her be and see him separately. 
			
			But you can hardly fault him for referring to her. She is half the reason you exist, after all, and it's pretty clear he still cares deeply for her. 
			
			"I think that might happen less as you go," Hekate says, seemingly following a similar line of thought. "She's a point of commonality between the two of you, but if you keep getting to know each other, plenty of those will crop up that have nothing to do with her, I suspect." 
			
			You're certainly hoping for something like that. 
		#"It was great, actually; we had a good talk and learned more about each other."
			"It was great, actually; we had a good talk and learned more about each other." You hadn't wanted to see your mother, or get her involved in this, at this particular juncture. And in some sense, you couldn't escape doing so even with your decision to leave her be and see him separately. 
			
			But you can hardly fault him for thinking about her, or bringing her up. It wasn't constant, and it seemed to you that he was more interested in learning about you than anything else. Which was good, because you were interested in learning about him as well. 
			
			"That's great," Hekate says, giving you the sort of smile that shows teeth—rather rare from her, compared to more subtle types. "I imagined something like that could be overwhelming or awkward; I'm glad to hear that it wasn't so." 
			
			"Well, 'awkward' and 'overwhelming' aren't mutually exclusive of 'good,'" Hermes replies with a chuckle. 
			
			"You know what I meant." 
			
			She directs the words at him, but you certainly understand as well, and the underlying point is correct. Maybe there were parts that were a bit odd, but overall it was wonderful, and those things didn't take away from that. 
		#"It was okay. Things are still a little awkward, but he seems like a good person."
			"It was okay. Things are still a little awkward, but he seems like a good person." You hadn't wanted to see your mother, or get her involved in this, at this particular juncture. And in some sense, you couldn't escape doing so even with your decision to leave her be and see him separately. 
			
			But you can hardly fault him for thinking about her, or bringing her up. It was part of the awkwardness involved, to be sure, but it's nothing you can't understand. It wasn't constant, and it seemed to you as if he was at least as interested in hearing about you as anything to do with her, and that sincerity made things… nice. Even in spite of the hiccups. 
			
			"I'm glad to hear that," Hekate says, offering you a small smile. "It would have been disappointing to learn that he was anything else." 
			
			"Yeah, who knows what we would have done if he were horrible?" Hermes says, and though his eyes are playfully-narrowed, his tone isn't quite as light as you would have expected. 
			
			Hekate clicks her tongue. "Nothing," she replies primly, but there's a small pause before she amends, "without permission. Or excessive due cause."
			
			It's hard to tell how much of that is serious.
		#"I don't know. It's hard to tell if this is all a good idea, but it's what I'm doing, so there it is."
			"I don't know. It's hard to tell if this is all a good idea, but it's what I'm doing, so there it is." You hadn't wanted to see your mother, or get her involved in this, at this particular juncture. And in some sense, you couldn't escape doing so even with your decision to leave her be and see him separately. 
			
			But you can hardly fault him for thinking about her, or bringing her up. It does contribute to your feeling of ambivalence about the whole thing, but it's not [i]just[/i] that, either. Mostly it's the surrounding circumstances, but you don't need to explain that to these two. They already know all about it, and neither shows a lack of understanding in their expressions. 
			
			On the contrary, both of them are giving you sympathetic looks, at the moment. 
			
			"I could… see how that would be the case," Hekate says, her brows crinkling. "Nothing about this is especially tidy or well-timed." 
			
			"Is anything in life ever?" Hermes replies. "Embrace the mess, Sunshine. That's my real advice, so now you have it." 
			
			"Whether you wanted it or not," Hekate adds dryly.
			
			You can tell the words were well-intended, of course, but you're not sure that 'embracing mess' is something you really know how to do. Before the Underworld, your life was as orderly—as [i]tidy[/i], as Hekate put it—as they come. 
			
			That doesn't necessarily make it bad advice, though.
	*page_break
*if ((demeter_sequel_1) and (iasion2 = "solo"))
	"So… Demeter just left," Hermes ventures, silver eyes shifting to you before they glance back at the game board. "I know you saw her, but you didn't go with her to see Iasion? Is everything okay?" 
	
	The question seems to be just a question; though obviously asking with no small amount of curiosity, he's not condemning the choice, that you can discern. You don't think Hermes would, anyway; he of all people understands complicated situations with one's parents.
	
	*fake_choice
		#"Yes, everything's fine. I just wanted them to have a chance to meet without me in the middle."
			"Yes, everything's fine. I just wanted them to have a chance to meet without me in the middle."
			
			*if (demeterstatus = "open")
				And that really is the truth. While things between you and your mother aren't perfect, no parent-child relationship is. Maybe, at some point, all three of you will be able to speak together, but for now, you just felt that there are too many separate things going on here, and a chance for the two of them to talk things through seemed important. 
			*if (demeterstatus != "open")
				And that's… mostly true. Your own current difficulties with your mother certainly contributed to the decision, but you would have made it even without those. Maybe, at some point, all three of you will be able to speak together, but for now, you just felt that there are too many separate things going on here, and a chance for the two of them to talk things through seemed important. 
			
			"Really? I'd have loved to eavesdrop on that conversation. Demeter's always been so mysterious, and strict with what she says about herself. And she's [i]never[/i] talked about Iasion. To anyone but you, I guess. And I assume Hestia." 
			
			Hekate rolls her eyes. "Never mind eavesdropping. I'm sure ${name}'s very presence would have changed the substance of the discussion. As well it should have—I'm sure Iasion wants to know about ${him2} just as much as about Demeter. As he should." 
			
			You're not sure what makes her sound so confident in that, but it had been part of your thought as well. At least, that he might want to know [i]some[/i] things about you, which he very clearly had. 
		#"It's a weird feeling to have two relationships that are awkward in different ways, but it's definitely better than not having them."
			"It's a weird feeling to have two relationships that are awkward in different ways, but it's definitely better than not having them." You shake your head a bit. There's certainly awkwardness in each, and sometimes you find yourself wishing all of this was easier, but all you can do is work with the situation you actually have. 
			
			*if (demeterstatus = "open")
				The friction with your mother is nothing catastrophic, but you felt that mixing that in with whatever was going on between them, and [i]then[/i] the strange process of getting to know your father as an adult… that's just too many things to handle at once. 
			*if (demeterstatus != "open")
				The friction with your mother is difficult enough to navigate on its own, but mixing that in with whatever was going on between them, and [i]then[/i] the strange process of getting to know your father as an adult… that's just too many things to handle at once. Far too many. 
			
			"Tell me about it," Hermes mutters, shaking his head. "Though yours are definitely awkward in different ways than mine." 
			
			"At least you're managing to navigate it," Hekate says, offering you a small smile. "For what it's worth, your strategy seems sound to me. No need to give yourself more stress than you can handle at once." 
			
			You already knew that, of course, but it's a bit reassuring to hear from someone else, too. 
		#"I saw my mother entirely from obligation. Seeing Iasion was a real choice." 
			"I saw my mother entirely from obligation. Seeing Iasion was a real choice." It's an important difference, and one you want to be clear about with the people who matter to you. 
			
			*if (demeterstatus = "open")
				Whether or not you'd welcome contact with her at a different time, all of this was just… a mess you didn't want anything to do with.
			*if (demeterstatus != "open")
				You didn't welcome the contact with her, but it had been necessary to prevent things from becoming an even bigger mess, in your estimation. 
			
			On the contrary, you very much wanted to get to know more about Iasion, and so the natural decision was to keep those two things as separate as possible. Not to mention it gave them a chance to resolve whatever is between them without putting you in the middle of it—a position you [i]truly[/i] do not desire to occupy. 
			
			"Well, then I suppose your strategy is quite sound. No need to put stress on the part of things you think you might enjoy." 
			
			You already knew that, of course, but it's a bit reassuring to hear from someone else, too. 
		#"I don't know. It's hard to tell if this is all a good idea, but it's what I'm doing, so there it is."
			"I don't know. It's hard to tell if this is all a good idea, but it's what I'm doing, so there it is." There's certainly an awkwardness to both relationships, in some sense, but it isn't just that. 
			
			Rather, there are just… too many extenuating circumstances for you to be sure of anything, at the moment. But you don't need to explain those to these two. They already know all about them, and neither shows a lack of understanding in their expressions. 
			
			On the contrary, both of them are giving you sympathetic looks, at the moment. 
			
			"I could… see how that would be the case," Hekate says, her brows crinkling. "Nothing about this is especially tidy or well-timed." 
			
			"Is anything in life ever?" Hermes replies. "Embrace the mess, Sunshine. That's my real advice, so now you have it." 
			
			"Whether you wanted it or not," Hekate adds dryly.
			
			You can tell the words were well-intended, of course, but you're not sure that 'embracing mess' is something you really know how to do. Before the Underworld, your life was as orderly—as [i]tidy[/i], as Hekate put it—as they come. 
			
			That doesn't necessarily make it bad advice, though.
*if ((demeter_sequel_1) and (iasion2 = "demeter"))
	"So… Demeter just left," Hermes ventures, silver eyes shifting to you before they glance back at the game board. "You talked with them both together, huh? How awkward was that? I personally would have enjoyed being a fly on the wall, but I promise I wasn't." He flashes a brief smile, which fades. 
	
	Hekate rolls her eyes. "You would not have," she replies. "The 'fly on the wall' thing is for strangers and people you don't like. You like ${name}, therefore you wouldn't have gone anywhere near that." 
	
	"Can you please stop explaining me? I like to remain mysterious."
	
	*fake_choice
		#"I've felt awkward plenty of times before in life, but that one was certainly up there, on occasion."
			"I've felt awkward plenty of times before in life, but that one was certainly up there, on occasion." It wasn't as bad as it could have been, you're sure. There are plenty of things they [i]didn't[/i] say, times when they might have but refrained, and you suspect that was at least partly for your sake. 
			
			You do appreciate not being dragged into the [i]whole[/i] mess. The part you did get was quite enough. 
			
			Hermes scrunches his nose. "I admit… I wouldn't want to be in the room if it were my [i]own[/i] parents. Well, I would, but not because it would be pleasant or funny. Glad it was only occasional." He huffs. 
			
			Hekate shakes her head. "Let's hope it isn't like that if it ever happens again. Mediating a relationship dispute is definitely not a job for one's child." 
			
			"Well, I did sort of volunteer for that," you point out. "I knew this was a distinct possibility when I went with her to meet him." 
			
			She presses her lips together. "Well, as long as you're not too stressed by it, I suppose."
			
			It's kind of her to worry, but you can handle that amount of strain without a problem. It's not like anyone in the situation was upset with you, or misdirected their frustration your way.
		#"Honestly? Not as much of a disaster as I was expecting. They were pretty civil with each other."
			"Honestly? Not as much of a disaster as I was expecting. They were pretty civil with each other." There are plenty of things they [i]didn't[/i] say, times when they might have but refrained, and you suspect that was at least partly for your sake. But still, what was exchanged managed to be mostly respectful, and while you wouldn't call all of it [i]calm[/i], you'd have been shocked if you could have. 
			
			Hermes scrunches his nose. "I admit… I wouldn't want to be in the room if it were my [i]own[/i] parents. Well, I would, but not because it would be pleasant or funny. Glad it worked out for yours." He huffs. 
			
			Hekate shakes her head. "Let's hope it stays that way. Mediating a relationship dispute is definitely not a job for one's child." 
			
			"Well, I did sort of volunteer for that," you point out. "I knew this was a distinct possibility when I went with her to meet him." 
			
			She presses her lips together. "Well, as long as you're not too stressed by it, I suppose."
			
			It's kind of her to worry, but you can handle that amount of strain without a problem. It's not like anyone in the situation was upset with you, or misdirected their frustration your way.
		#"There were definitely hiccups, but overall I think it went well. I learned more about both of them."
			"There were definitely hiccups, but overall I think it went well. I learned more about both of them." There are plenty of things they [i]didn't[/i] say, times when they might have but refrained, and you suspect that was at least partly for your sake. And you're sure that did deprive you of some insight. But you think that how things went was the most balanced way it could have—between what they needed to say to each other, and what each wanted to exchange with you. 
			
			Hermes scrunches his nose. "I admit… I wouldn't want to be in the room if it were my [i]own[/i] parents. Well, I would, but not because it would be pleasant or funny. Glad it worked out for yours." He huffs. 
			
			Hekate shakes her head. "Let's be glad most people are much more civil in their disagreements than Zeus," she replies. "Though… I do hope you weren't expected to mediate, ${name}. That's hardly a job for the child of the relationship."
			
			"Well, I did sort of volunteer for that," you point out. "I knew it was a distinct possibility when I went with her to meet him." 
			
			She presses her lips together. "Well, as long as you're not too stressed by it, I suppose."
			
			It's kind of her to worry, but you can handle that amount of strain without a problem. It's not like anyone in the situation was upset with you, or misdirected their frustration your way.
		#"I just want to bring my family together. I think maybe it's working."
			"I just want to bring my family together. I think maybe it's working." There are plenty of things they [i]didn't[/i] say, times when they might have but refrained, and you know that whatever those things were will need to get brought to light eventually. But still, it seemed to you like there was concrete progress on all sides, and that can't be a bad thing, to you. 
			
			Hermes scrunches his nose. "I admit… I wouldn't want to be in the room if it were my [i]own[/i] parents. Well, I would, but not because it would be pleasant or funny. Glad it worked out for yours." He huffs. 
			
			Hekate shakes her head. "Let's be glad most people are much more civil in their disagreements than Zeus," she replies. "Though… I do hope you weren't expected to mediate, ${name}. That's hardly a job for the child of the relationship."
			
			"Well, I did sort of volunteer for that," you point out. "I knew it was a distinct possibility when I went with her to meet him. And… I want to, if they need someone to do that." 
			
			She presses her lips together. "Well, as long as you're not too stressed by it, I suppose."
			
			It's kind of her to worry, but you can handle that amount of strain without a problem. It's not like anyone in the situation was upset with you, or misdirected their frustration your way.
	*page_break
A few more turns pass before Hekate fixes her attention on Hermes for a moment. "Any updates on Maia?" she asks quietly. There's a little crease between her brows, which deepens slightly when Hermes shrugs. 

"I don't know," he replies. "It's not like she actually talks to me about anything important. Whenever I visit she's 'fine' and everything's 'fine,' you know?" 

She sighs, nodding slowly. "Yes, I do. But that makes it all the more concerning, really." 

You glance between the two of them, settling on Hermes as well.

*fake_choice
	#"I'm sorry. That sounds really difficult."
		"I'm sorry. That sounds really difficult." You're unsure what the background situation is, but even you know from his tone that clearly, not everything is 'fine' with his mother. 
		
		*if (hermeslap)
			You briefly, gently, tighten your grip around him, and he responds with a light squeeze to one of your arms.
		*if (((touching) and (hermeslap = false)) and (route = "hermes"))
			You lift a hand to squeeze one of the arms around you, and he responds by briefly tightening his grip on you. 
		*if ((touching = false) or (route = "hekate"))
			You feel yourself frown, but when he catches sight of the expression, he smiles a little. 
		"Thanks, Sunshine. But it's not anything you need to worry yourself about. My mother's always been… she's never done especially well, on Olympus. But she refuses to leave, so the most anyone else can really do is just… be there to listen if she actually wants to talk about it, you know?"
		
		"She doesn't have too many people to talk to, right?" Hekate inquires, her voice still betraying obvious concern. 
		
		"Well… not really, no. She has me, and maybe a few of the people who come to help her out now and then, but she's never really been able to enjoy that glittery Olympian social life." His voice turns a little bitter towards the end. 
		
		"Why not?" you ask. Hermes certainly has, in the past, though you wonder, these days, how much he actually enjoyed it and how much was a show he put on.
		
		"Well, no one wants to talk to the king's mistress when the queen's right there, do they?" he replies, his smile pulling too wide for the words. "Go to a couple of parties where only Hestia says hello and you won't want to go to them anymore. Not that there's anything wrong with Hestia. Just, you know." 
		
		You suppose that makes sense. 
	#"I suppose one advantage to having Demeter as a parent is always knowing if something has upset her."
		"I suppose one advantage to having Demeter as a parent is always knowing if something has upset her." You're unsure what the background situation is, but if nothing else it sounds like Hermes's mother might be difficult to read. Or at least difficult to speak honestly with. Although your mother's relative communicativeness has at times [i]not[/i] felt like an advantage, you can see how it would be in a case like this. 
		
		*if (hermeslap)
			You give him a small squeeze with your arms, offering a wry smile. He huffs, and briefly grips your arm in return.
		*if (((touching) and (hermeslap = false)) and (route = "hermes"))
			You lift a hand to squeeze one of the arms around you, and he responds by briefly tightening his grip on you, huffing softly.
		*if ((touching = false) or (route = "hekate"))
			You meet his eyes with a slightly-lopsided smile, and he huffs. 
		"I could see that," he replies with a nod. "You just also get her opinion on basically everything else all the time as well. But, my situation's nothing to worry about. My mother's always been… she's never done especially well, on Olympus. But she refuses to leave, so the most anyone else can really do is just… be there to listen if she actually wants to talk about it, you know?"
		
		"She doesn't have too many people to talk to, right?" Hekate inquires, her voice still betraying obvious concern. 
		
		"Well… not really, no. She has me, and maybe a few of the people who come to help her out now and then, but she's never really been able to enjoy that glittery Olympian social life." His voice turns a little bitter towards the end. 
		
		"Why not?" you ask. Hermes certainly has, in the past, though you wonder, these days, how much he actually enjoyed it and how much was a show he put on.
		
		"Well, no one wants to talk to the king's mistress when the queen's right there, do they?" he replies, his smile pulling too wide for the words. "Go to a couple of parties where only Hestia says hello and you won't want to go to them anymore. Not that there's anything wrong with Hestia. Just, you know." 
		
		You suppose that makes sense. 
	#"I don't really understand her situation. Is there anything you can tell me?"
		"I don't really understand her situation," you say carefully. "Is there anything you can tell me?" You're unsure what the background situation is, but even you know from his tone that clearly, not everything is 'fine' with his mother. 
		
		*if (hermeslap)
			You briefly, gently, tighten your grip around him, and he responds with a light squeeze to one of your arms.
		*if (((touching) and (hermeslap = false)) and (route = "hermes"))
			You lift a hand to squeeze one of the arms around you, and he responds by briefly tightening his grip on you. 
		*if ((touching = false) or (route = "hekate"))
			You feel yourself frown, but when he catches sight of the expression, he smiles a little. 
		"Sure, Sunshine. But it's not anything you need to worry yourself about. My mother's always been… she's never done especially well, on Olympus. But she refuses to leave, so the most anyone else can really do is just… be there to listen if she actually wants to talk about it, you know?"
		
		"She doesn't have too many people to talk to, right?" Hekate inquires, her voice still betraying obvious concern. 
		
		"Well… not really, no. She has me, and maybe a few of the people who come to help her out now and then, but she's never really been able to enjoy that glittery Olympian social life." His voice turns a little bitter towards the end. 
		
		"Why not?" you ask. Hermes certainly has, in the past, though you wonder, these days, how much he actually enjoyed it and how much was a show he put on.
		
		"Well, no one wants to talk to the king's mistress when the queen's right there, do they?" he replies, his smile pulling too wide for the words. "Go to a couple of parties where only Hestia says hello and you won't want to go to them anymore. Not that there's anything wrong with Hestia, just, you know." 
		
		You suppose that makes sense. 
	#"Is her health or well-being a concern in some way?"
		"Is her health or well-being a concern in some way?" You're unsure what the background situation is, but even you know from his tone that clearly, not everything is 'fine' with his mother. 
		
		*if (hermeslap)
			You briefly, gently, tighten your grip around him, and he responds with a light squeeze to one of your arms.
		*if (((touching) and (hermeslap = false)) and (route = "hermes"))
			You lift a hand to squeeze one of the arms around you, and he responds by briefly tightening his grip on you. 
		*if ((touching = false) or (route = "hekate"))
			You feel yourself frown, but when he catches sight of the expression, he smiles a little. 
		"Well, in a way, yes. But it's not anything you need to worry yourself about. My mother's always been… she's never done especially well, on Olympus. But she refuses to leave, so the most anyone else can really do is just… be there to listen if she actually wants to talk about it, you know?"
		
		"She doesn't have too many people to talk to, right?" Hekate inquires, her voice still betraying obvious concern. 
		
		"Well… not really, no. She has me, and maybe a few of the people who come to help her out now and then, but she's never really been able to enjoy that glittery Olympian social life." His voice turns a little bitter towards the end. 
		
		"Why not?" you ask. Hermes certainly has, in the past, though you wonder, these days, how much he actually enjoyed it and how much was a show he put on.
		
		"Well, no one wants to talk to the king's mistress when the queen's right there, do they?" he replies, his smile pulling too wide for the words. "Go to a couple of parties where only Hestia says hello and you won't want to go to them anymore. Not that there's anything wrong with Hestia, just, you know." 
		
		You suppose that makes sense. 
*page_break
Hermes lets out a long, perhaps slightly exaggerated breath. "Anyway, I wish she would talk to me, but I'm not going to force it. So… let's discuss something else?" He looks to Hekate, in clear hope that she will provide that topic, which is fair. She seems to know a little about everything. 

She smiles, a touch wryly, and clears her throat. "Well, since we seem to be on the general topic of parents, allow me to assert that no one's mother is as vague and troubling a communicator as my own."

Hermes manages a real chuckle, at that. "Well, that's true. At least mine's answers don't need charts and interpretations and instruments to figure out. I can be grateful for that much."

*fake_choice
	#"Uh... I don't get it?"
		*set unsure +1
		*set forthright +1
		"Uh... I don't get it?" 
		
		Hekate's already straightening a little by the time you [i]begin[/i] the sentence; by the end, she's nodding, expression contrite. 
		
		"Of course. I do apologize, ${name}; I'd rather forgotten I hadn't told you this part already." 
		*if ((route = "hekate") and (touching))
			She leans a little into where you're touching, giving you a gentle nudge.
		*if not ((route = "hekate") and (touching))
			She offers you half a smile. 
		"My mother is Asteria. She has been many things. A quail. An island. A Titan. Nowadays, she is the portents and divinations in the night sky." 
	#"I think I'm missing some context here. It would be polite of you to provide it." 
		*set confident +1
		*set forthright +1
		"I think I'm missing some context here. It would be polite of you to provide it." 
		
		Hekate's already straightening a little by the time you [i]begin[/i] the sentence; by the end, she's nodding, expression contrite. 
		
		"Of course. I do apologize, ${name}; I'd rather forgotten I hadn't told you this part already." 
		*if ((route = "hekate") and (touching))
			She leans a little into where you're touching, giving you a gentle nudge.
		*if not ((route = "hekate") and (touching))
			She offers you half a smile. 
		"My mother is Asteria. She has been many things. A quail. An island. A Titan. Nowadays, she is the portents and divinations in the night sky." 
	#I raise a brow, expecting that someone will apprise me of the relevant details to understand the joke.
		*set confident +1
		*set reserved +1
		You raise a brow, expecting that someone will apprise you of the relevant details to understand the joke.
		
		Hekate straightens a little, interpreting your expression and nodding.
		
		"It would make sense if I explained. I do apologize, ${name}; I'd rather forgotten you didn't know this already." 
		*if ((route = "hekate") and (touching))
			She leans a little into where you're touching, giving you a gentle nudge.
		*if not ((route = "hekate") and (touching))
			She offers you half a smile. 
		"My mother is Asteria. She has been many things. A quail. An island. A Titan. Nowadays, she is the portents and divinations in the night sky." 
	#I don't really understand why that's funny, but I'm not sure I should say that, either.
		*set unsure +1
		*set reserved +1
		You don't really understand why that's funny, but you're not sure you should say that, either.
		
		But Hekate straightens a little, presumably either interpreting confusion on your face,
		*if (tag_uncharming)
			or more likely just realizing you might be confused, since you doubt it's showing in your expression.
		*if not (tag_uncharming)
			or just realizing you might feel as much, without the same context as the two of them. 
		
		"It would make sense if I explained. I do apologize, ${name}; I'd rather forgotten you didn't know this already." 
		*if ((route = "hekate") and (touching))
			She leans a little into where you're touching, giving you a gentle nudge.
		*if not ((route = "hekate") and (touching))
			She offers you half a smile. 
		"My mother is Asteria. She has been many things. A quail. An island. A Titan. Nowadays, she is the portents and divinations in the night sky." 

*fake_choice
	#"Really? Does that mean you're a Titan, too?"
		"Really? Does that mean you're a Titan, too?" You've never been especially clear on what divides the gods from the Titans. Zeus is the son of two of them, and yet he is the king of the [i]gods[/i]. His parents and many other Titans also lived on Olympus, so it's not that. Perhaps it's merely a generational distinction?
		
		"I am," Hekate admits, a touch wryly. "My parents were Titans, and technically that was the 'side' I was on during the Titanomachy as well. Not that I actually did much fighting, back then."
		
		"Is that why you don't like Olympus very much?"
		
		She pauses at the question, clearly giving it some thought. "Yes, and no," she decides. "I know that's not very helpful, but my feelings about my identity and the war are… quite complicated."
	#"Your mother is the portents in the sky? How does that even work?"
		"Your mother is the portents in the sky? How does that even work?" It still boggles you a little that gods or Titans or whomever can be transformed into such things as landmasses and constellations, but something like that sounds [i]even more[/i] abstract. 
		
		"Well… it's sort of like Erebus," Hekate replies, tilting her head. "Or between Erebus and someone like Lethe or Acheron. Erebus is a domain now stripped from its original bearer and repurposed. Acheron exists as both a person and a river. What my mother is… is a concept. She used to have a body like you or I, and her domains included the stars and prognostication. When her domain was taken from her at the end of the war, her [i]self[/i] went with it, by her choice. She is housed in the sky, like anyone who becomes a constellation, but she isn't limited by space." 
		
		"That's… quite complicated."
		
		"Yeah I still don't totally get it, either," Hermes admits. "I always end up thinking of a woman sitting 'behind' the sky, making sure the stars align properly or shooting a comet through things to warn someone." 
		
		"If it's easier, by all means think of it that way," Hekate replies with a small smile. "It's close enough to the truth."
	#"I thought all the Titans were imprisoned after the Titanomachy." 
		"I thought all the Titans were imprisoned after the Titanomachy." Well, except for Kronos, apparently, and you're not sure why that is, but you assume Zeus made some kind of exception for his father, for whatever reason. 
		
		But the rest of them are meant to be in the lowest depths of Tartarus, lower even than the Giants. 
		
		"Most of them were," Hekate replies. "But a few of them died, and a few chose alternate punishments. My mother was given a small amount of leeway, at Hades's request. Which in turn was at mine." She smiles, but there isn't much good humor in it. 
		
		"So she was allowed to choose an alternate punishment. Like Erebus, she chose to have her domains pulled away from her. Unlike him, 'she' went with them, and her body withered to dust." 
		
		"I'm sorry." You're not sure exactly what the appropriate sentiment is, but her mother had more or less [i]died[/i], at least in some important sense. 
		
		"I appreciate that, ${name}, but it's all right. It was a very long time ago, now."
*page_break
*if (route = "hermes")
	"So!" she clears her throat, clapping her hands together softly and moving a piece on the board. "Parents are a very strange topic to choose when I have a couple of lovers in front of me, and I myself am so invested in their happiness. So tell me—how are things? He's not giving you too much trouble, is he, ${name}?"
	
	"I resent your implications," Hermes complains, though he doesn't sound particularly offended. 
	
	"You [i]resemble[/i] them, you mean."
	
	*label hekateasks
	*fake_choice
		*disable_reuse #"Wait, you know about that?"
			"Wait, you know about that?" You hadn't exactly been shouting your new relationship status from the rooftops or anything. It's been a little while now, but it's still very new, what with everything else going on and the fact that Hermes can't always be here. You'd certainly never announced it to anyone. 
			
			Then again, you hadn't specifically been aiming to keep it a secret, either. 
			*if (hermeslap)
				And you suppose Hermes [i]is[/i] in your lap. It's not impossible that friends would do something like that, but it's certainly a clue that [i]something[/i] about your relationship is different, because you'd never done this before.
			*if ((touching) and (hermeslap = false))
				And you suppose you [i]are[/i] in Hermes's lap. It's not impossible that friends would do something like that, but it's certainly a clue that [i]something[/i] about your relationship is different, because you'd never done this before.
			
			Hekate lifts a brow at you, but it's Hermes who answers. "That's my fault," he admits, clearing his throat. "I… look, I needed to tell people. It was new, and exciting, and terrifying, and I needed, uh… advice." 
			
			"I knew before he told me," Hekate says with a shrug. "You weren't overt at the time, but there were things I could notice. And [i]did[/i] notice. I'm sure basically everyone's figured it out by now, but I don't know about Pyri."
			
			Hermes hems again. "They asked. So I told them."
			*goto hekateasks
		#"Things are going well, I think." 
			*set hermes_pace "good"
			"Things are going well, I think." It [i]is[/i] still early in the process, so to speak, and you aren't sure you want to get into the details in front of anyone. Not even Hekate. But you can say that much with relative ease. 
			
			She studies you for a moment with interest, then her eyes flick to Hermes, and she chuckles. 
			*if not (tag_uncharming)
				"You're both pretty easy to read, so I'll suppose that's answer enough. I'm delighted to hear it, for the record." 
			*if (tag_uncharming)
				"It's work to figure out what you're thinking, ${name}, but I can read Hermes like a book. So I suppose that's answer enough. I'm delighted to hear it, for the record." 
			She offers you both a sincere grin.
		#"Mm, I'm enjoying myself, but I expected Hermes to be a little more forward than he actually is." 
			*set hermes_pace "tooslow"
			"Mm, I'm enjoying myself, but I expected Hermes to be a little more forward than he actually is." It [i]is[/i] still early in the process, so to speak, but you know enough about what he's gotten up to previously to know that that doesn't necessarily have to matter to him, so you kind of wonder what's got him stuck. 
			
			Hekate studies you for a moment with interest, then her eyes flick to Hermes, and she chuckles. 
			*if not (tag_unintuitive)
				"I think I have an idea what might be at issue there," she says, even as Hermes frowns at her. "And I think you could, too, if you considered it long enough. But there's a great shortcut to learning these things—and that's asking about them. Good to hear you're enjoying yourself regardless, though." 
			*if (tag_unintuitive)
				"I think I have an idea what might be at issue there," she says, even as Hermes frowns at her. "But since I'm fairly sure figuring out what people are thinking is not your strong suit, maybe you should just ask him why that is. Good to hear you're enjoying yourself regardless, though."
			She offers you both a sincere grin.
		#"Well, I'm happy, but I worry with everything going on lately, we haven't really had time to spend on the relationship." 
			*set hermes_pace "notime"
			"Well, I'm happy, but I worry with everything going on lately, we haven't really had time to spend on the relationship." It [i]is[/i] still early in the process, of course, but in a way that's why you think it's so vital to spend the time. If only you had it. 
			
			Hekate studies you for a moment with interest, then her eyes flick to Hermes, and she chuckles. "You'd think, being immortal, that we'd have time for everything, but on a day-to-day basis that's not really true, is it? If you want time, you're going to have to make it, I'm afraid. At least for now. Hopefully things calm down for a while now that Demeter's come and gone." 
			
			She offers you both a sincere grin.
	*page_break
	"You probably know this already, but don't feel the need to go at anyone's pace but your own. Fast, slow, however you want it."
	
	"We've only got eternity," Hermes agrees, and you can't help but think he sounds a little bit terrified. 
	
	She gives him a wry look. "Eternity [i]can[/i] work, you know. Despite all the evidence out there to the contrary." 
*if (route = "hekate")
	"Anyway," Hermes stretches his wings out to the side for a moment, resettling them at his back. They're sort of awkwardly-tilted when he sits so close to the floor like this, but he manages to look at ease in any case. "Parents are fine as a topic, I guess, but let's choose something more interesting. Like whatever the two of you have going on." 
	
	He looks between you with a slowly-broadening smile. "How are things going? You can tell me details; I don't mind." 
	
	"Not if we want them to remain relatively private, we can't," Hekate replies dryly. 
	
	"Well [i]do[/i] you want them to be 'relatively private'? Because that's interesting on its own." 
	
	She rolls her eyes, clearly content to leave the actual answer to your discretion.
	
	*label hermesasks
	*fake_choice
		*disable_reuse #"Wait, you know about that?"
			"Wait, you know about that?" You hadn't exactly been shouting your new relationship status from the rooftops or anything. It's been a little while now, but it's still very new, what with everything else going on. You'd certainly never announced it to anyone. 
			
			"Was it meant to be a secret?" He asks with a huff, lifting a brow. 
			
			"No, I just hadn't told anyone yet, so I didn't think anyone would know." You look to Hekate, wondering if perhaps the information had come from her. 
			
			"I mentioned it to a few people," she replies with a small shrug, "but most likely Hermes figured it out long beforehand by observing us. I don't believe we're going to any lengths to be clandestine, are we?"
			
			That's true. It's not as though you do anything blatantly obvious in public areas, but probably your body language alone is enough to clue in someone accustomed to looking for such signs.
			
			"Pretty much everyone knows," Hermes adds, shrugging. "Pyri wasn't sure, but I told them what I thought, so… everyone knows." 
			*goto hermesasks
		#"Things are going well, I think." 
			*set hekate_pace "good"
			"Things are going well, I think." It [i]is[/i] still early in the process, so to speak, and you aren't sure you want to get into the details in front of anyone. Not even Hermes. But you can say that much with relative ease. 
			
			He studies you for a moment with interest, then his eyes move to Hekate, and he sighs. 
			*if not (tag_uncharming)
				"Well, at least I can read one of you, so I'll go ahead and believe it." 
				
				"Were you not planning to do so by default?" Hekate regards him dubiously. 
				
				"No, I probably would have. It's just nice to see some version of the words on someone's face. Tip for the future, Hekate." 
				
				"I'll keep that in mind, if I ever decide to care about your attempts at intuition."
			*if (tag_uncharming)
				"You're both so inscrutable, sometimes. It's hard to know what to think." 
				
				"Are our words insufficient evidence of how we feel?" Hekate regards him dubiously. 
				
				"No, not necessarily. It's just nice to see some version of the words on someone's face. Tip for the future, Hekate." 
				
				"I'll keep that in mind, if I ever decide to care about your attempts at intuition."

			Hermes chuckles, offering you both a sincere grin.
		#"Mm, I'm enjoying myself, but I expected Hekate to be a little more forward than she actually is." 
			*set hekate_pace "tooslow"
			"Mm, I'm enjoying myself, but I expected Hekate to be a little more forward than she actually is." It [i]is[/i] still early in the process, so to speak, but you get the impression Hekate might have done this sort of thing once or twice before. You're not really sure why things are moving in a way that to you feels quite slow. 
			
			"Ah," Hekate herself hums. "Well, that's useful to know." 
			
			"And there you have it," Hermes replies, his grin flaring wide for a moment before it subsides slightly. "Communication. Happy I could facilitate for you." 
		#"Well, I'm happy, but I worry with everything going on lately, we haven't really had time to spend on the relationship." 
			*set hekate_pace "notime"
			"Well, I'm happy, but I worry with everything going on lately, we haven't really had time to spend on the relationship." It [i]is[/i] still early in the process, of course, but in a way that's why you think it's so vital to spend the time. If only you had it. 
			
			"Ah," Hekate hums. "Well, that's useful to know." 
			
			"And there you have it," Hermes replies, his grin flaring wide for a moment before it subsides slightly. "Communication. Happy I could facilitate for you." 
	*page_break
	"I'm sure you've both got a better handle on this sort of thing than I ever would, but don't stop talking to each other. Sunshine, if Hekate gets caught up in a project and you need attention, just tell her. She's bad at keeping track of time." 
	
	"Yes, yes, thank you Hermes," Hekate replies, rolling her eyes a little. "Silly as he's being, he's right, of course. I have been… faulted for my attentiveness, in the past, and not without reason."

You reach forward to take up one of your pieces for your next move, still thinking about what you might want to say in response to that, 
*if (route = "hermes")
	when quick footsteps herald a new appearance in the doorway.
	
	*if (job = "research")
		You recognize the entrant: Dorotheos, a satyr who works in the research division with you. 
	*if (job != "research")
		You don't recognize the entrant, a satyr with grey-black fur and darker hair, one horn broken off at the tip.
	He looks a little awkward to be interrupting, and clears his throat softly. "I apologize, Hekate," he says, dipping himself into half a bow at you and Hermes, "but some of the spirits have reported a burst pipe in the western city. It's… gone in several places, and we're worried about flooding if we don't get it under control. Do you have a few minutes, or…?"
	
	Hekate sighs, but the expression on her face is almost fond. "Of course I have a few minutes, Doro. Let's get it sorted out." Standing, she brushes down her lilac-colored tunic and shoots you a wry smile. 
	
	"We'll have to finish our game some other time." 
	
	*if (selfless > selfcaring)
		"Do you need any help?"
	
		She shakes her head. "Not at all. I should have this under control rather quickly, but then I'll need to figure out what went wrong. Nothing for you two to worry about. Have fun." 
	*if not (selfless > selfcaring)
		"Is everything going to be all right?" 
		
		She nods lightly. "Of course. I should have this under control rather quickly, but then I'll need to figure out what went wrong. Nothing for you two to worry about. Have fun." 
	Lifting a hand, she waggles her fingers in a casual wave before both she and the satyr vanish.
	*page_break
	Her departure leaves you alone with Hermes, who seems to have descended into something of a contemplative mood; he's sort of staring at the game board in front of you without really looking at it. 
	
	You think you might have a guess at what he's thinking [i]about[/i]; the tone of his remark earlier had been something of a surprise. The part about having eternity. 
	
	*fake_choice
		#"You... want to be doing this, right?"
			*set serious +1
			You... want to be doing this, right?" You're not entirely sure how to take the way he'd sounded about it, but as Hekate just got done reminding you, in her way, talking about the things that matter is important, and this [i]certainly[/i] matters. 
			
			"What?" He looks up from the table to you, silver eyes round. "Of course I want to be doing this. What kind of question is that?" 
			
			*if (confident > unsure)
				"Well, you didn't sound entirely pleased a few moments ago. And you didn't respond, when Hekate said eternity can work." 
			*if not (confident > unsure)
				"Well…" You hesitate. Confidence is not your strong suit, and this is significant. You know that means you [i]need[/i] to talk about it, but the necessity makes the task no easier. "You just didn't sound very happy. When you said we had eternity. And… you didn't say anything, after Hekate said that could work." 
			
			"Oh." Hermes pushes a breath out through his nose,
			*if ((touching) and (hermeslap))
				and you feel him shift against you, leaning back a little more into your chest. 
			*if ((touching) and (hermeslap = false))
				and you feel his arms firm around you.
			*if (touching = false)
				and his eyes fall back down to the table before he properly turns to face you.
			
			*label hermestalk3_1
			"I do have some doubts about anything lasting that long," he admits. "Maybe because it's hard to even imagine what that amount of time is [i]like[/i], still. I know I've got some years on you, but it's not like I'm Hekate, where there's already been thousands of them, you know?" 
			
			He clears his throat. "I [i]want[/i] this to work. I just don't know if anything [i]can[/i]."
			
			*fake_choice
				#"I think there are things that can. I think we're one of them."
					"I think there are things that can. I think we're one of them." Sure, there aren't a lot of obvious examples. You know of a few solid partnerships, in the Underworld, but you're not sure how long any of them have been going on, or if you can point to them as examples. 
					
					But you don't need any of that. You know you, and you know Hermes. You didn't agree to this arrangement supposing you'd just stick around until the fun was had and then leave again. You want to be with him. For as long as you can. 
					
					"You really think so, huh?" There's a faint note of skepticism in his voice, but when you shift to look at him properly, his face is… different.
					*if (tag_unintuitive)
						You're not sure what expression that is, but it's not skepticism.
					*if not (tag_unintuitive)
						Hope, maybe. The expression on his face might be hope. 
					
					"I do," you reply, as firmly as you can.
					*if (hermes_backstory = "friends")
						"We've been friends basically all our lives, Hermes. That's never wavered. Why would this?"
					*if (hermes_backstory = "strangers")
						"We somehow made it from strangers to this in the middle of what was the biggest upheaval in my entire life. Next to that, what else could shake us?"
					*if (hermes_backstory = "rivals")
						"We somehow made it from hating each other to this, in the middle of what was the biggest upheaval in my entire life. Next to that, what else could shake us?"
					
					A wry little twist appears at the corner of his mouth. "That much is true enough, I suppose."
					*if (hermes_backstory = "rivals")
						After a beat, he adds, "though just so you know, I never hated you." 
					
					You return the smile with a similar one of your own,
					*if (tag_uncharming)
						as best you can.
					*if not (tag_uncharming)
						finding that it comes naturally. 
					
					You're not naive enough to think that a few words have resolved a doubt like this, but you know they've reached him, nonetheless. For now, that's enough.
				#"No relationship is exactly the same decade after decade. Ours will change. But as long as we keep caring for each other, isn't that completely fine?"
					"No relationship is exactly the same decade after decade. Ours will change. But as long as we keep caring for each other, isn't that completely fine?" You can sort of understand where he's coming from. Expecting that things will always be the same, that the both of you as individuals [i]and[/i] a couple will never change no matter how much time passes, is romantic enough, but it's not in the least realistic. 
					
					Fortunately, you don't need some kind of absurd promise like that. As long as the two of you can promise to weather those changes and try to do right by one another, that's enough. 
					
					"I don't know," he admits. "It sounds… it sounds reasonable, but [i]is[/i] it enough for you?"
					
					"It is," you reply, as firmly as you can.
					*if (hermes_backstory = "friends")
						"Besides, we've been friends basically all our lives, Hermes. That's never wavered. I don't imagine it's going to start doing that for no reason, right?"
					*if (hermes_backstory = "strangers")
						"Besides, we somehow made it from strangers to this in the middle of what was the biggest upheaval in my entire life. Next to that, I doubt much else could shake us."
					*if (hermes_backstory = "rivals")
						"Besides, we somehow made it from hating each other to this, in the middle of what was the biggest upheaval in my entire life. Next to that, I doubt much else could shake us."
					
					A wry little twist appears at the corner of his mouth. "That much is true enough, I suppose."
					*if (hermes_backstory = "rivals")
						After a beat, he adds, "though just so you know, I never hated you." 
					
					You return the smile with a similar one of your own,
					*if (tag_uncharming)
						as best you can.
					*if not (tag_uncharming)
						finding that it comes naturally. 
					
					You're not naive enough to think that a few words have resolved a doubt like this, but you know they've reached him, nonetheless. For now, that's enough.
				#"I'm not asking you to think about eternity, Hermes. I want you [i]now[/i], and if you want [i]me[/i] now, that's enough."
					"I'm not asking you to think about eternity, Hermes. I want you [i]now[/i], and if you want [i]me[/i] now, that's enough." You can sort of understand where he's coming from. Expecting that things will always be the same, that the both of you as individuals [i]and[/i] a couple will never change no matter how much time passes, is romantic enough, but it's not in the least realistic. 
					
					Fortunately, you don't need some kind of absurd promise like that. What you care about is what's true right now, and if it changes later, well… that's something you can figure out later. Not something you need to solve before it's even happened. 
					
					"I don't know," he admits. "It sounds… it sounds okay, but is it really enough for you?"
					
					"It is," you reply, as firmly as you can.
					*if (hermes_backstory = "friends")
						"Besides, we've been friends basically all our lives, Hermes. That's never wavered. I don't imagine it's going to start doing that for no reason, right?"
					*if (hermes_backstory = "strangers")
						"Besides, we somehow made it from strangers to this in the middle of what was the biggest upheaval in my entire life. Next to that, I doubt much else could shake us."
					*if (hermes_backstory = "rivals")
						"Besides, we somehow made it from hating each other to this, in the middle of what was the biggest upheaval in my entire life. Next to that, I doubt much else could shake us."
					
					A wry little twist appears at the corner of his mouth. "That much is true enough, I suppose."
					*if (hermes_backstory = "rivals")
						After a beat, he adds, "though just so you know, I never hated you." 
					
					You return the smile with a similar one of your own,
					*if (tag_uncharming)
						as best you can.
					*if not (tag_uncharming)
						finding that it comes naturally. 
					
					You're not naive enough to think that a few words have resolved a doubt like this, but you know they've reached him, nonetheless. For now, that's enough.
				#"I understand what you mean. But we don't have to dwell on that, do we?"
					"I understand what you mean. But we don't have to dwell on that, do we?" His doubt is reasonable, and if you stare at it straight-on, it's troubling. You completely understand why it's bothering him, because it's starting to bother you a little, too, now that it's on your mind. 
					
					The great uncertainty of it all. 
					
					But that doesn't mean you have to let that doubt paralyze you. That's no way to live, and you certainly couldn't give your best to a relationship if you were just waiting for it to end someday. So… instead you can do your best to focus on what is keeping you together, not whatever hypothetical things might eventually drive you apart. 
					
					"I… suppose not," Hermes admits. "But is that uncertainty really something you can live with?"
					
					"It is," you reply, as firmly as you can.
					*if (hermes_backstory = "friends")
						"Besides, we've been friends basically all our lives, Hermes. That's never wavered. I don't imagine it's going to start doing that for no reason, right?"
					*if (hermes_backstory = "strangers")
						"Besides, we somehow made it from strangers to this in the middle of what was the biggest upheaval in my entire life. Next to that, I doubt much else could shake us."
					*if (hermes_backstory = "rivals")
						"Besides, we somehow made it from hating each other to this, in the middle of what was the biggest upheaval in my entire life. Next to that, I doubt much else could shake us."
					
					A wry little twist appears at the corner of his mouth. "That much is true enough, I suppose."
					*if (hermes_backstory = "rivals")
						After a beat, he adds, "though just so you know, I never hated you." 
					
					You return the smile with a similar one of your own,
					*if (tag_uncharming)
						as best you can.
					*if not (tag_uncharming)
						finding that it comes naturally. 
					
					You're not naive enough to think that a few words have resolved a doubt like this, but you know they've reached him, nonetheless. For now, that's enough.
		#"Is everything okay?"
			"Is everything okay?" You're not entirely sure how to take the way he'd sounded about it, but as Hekate just got done reminding you, in her way, talking about the things that matter is important, and this [i]certainly[/i] matters. 
			
			"What?" He looks up from the table to you, brow knitting. "Have I done something to make it seem like I'm not?"
			
			*if (confident > unsure)
				"Well, you didn't sound entirely pleased a few moments ago. And you didn't respond, when Hekate said eternity can work." 
			*if not (confident > unsure)
				"Well…" You hesitate. Confidence is not your strong suit, and this is significant. You know that means you [i]need[/i] to talk about it, but the necessity makes the task no easier. "You just didn't sound very happy. When you said we had eternity. And… you didn't say anything, after Hekate said that could work." 
			
			"Oh." Hermes pushes a breath out through his nose,
			*if ((touching) and (hermeslap))
				and you feel him shift against you, leaning back a little more into your chest. 
			*if ((touching) and (hermeslap = false))
				and you feel his arms firm around you.
			*if (touching = false)
				and his eyes fall back down to the table before he properly turns to face you.
			*goto hermestalk3_1
		#@{convotoggle [☆]|} "Is this the part where we talk about your problem committing to things?"
			*set humorous +1
			"Is this the part where we talk about your problem committing to things?" You put it lightly, but it's a serious question, in its way. You're not entirely sure how to take the way he'd sounded earlier, but as Hekate basically just reminded you both, talking about the things that matter is important, and this certainly matters.
			
			"Where we talk about my what?" Hermes looks up from the table to you, one brow arching over the other. "Is that how I seem to you?"
			
			*if (confident > unsure)
				"Well, you didn't sound entirely pleased a few moments ago. And you didn't respond, when Hekate said eternity can work." 
			*if not (confident > unsure)
				"Well…" You hesitate. Confidence is not your strong suit, and this is significant. You know that means you [i]need[/i] to talk about it, but the necessity makes the task no easier, and trying to be funny about it didn't help much, either. "You just didn't sound very happy. When you said we had eternity. And… you didn't say anything, after Hekate said that could work." 
			
			"Oh." Hermes pushes a breath out through his nose,
			*if ((touching) and (hermeslap))
				and you feel him shift against you, leaning back a little more into your chest. 
			*if ((touching) and (hermeslap = false))
				and you feel his arms firm around you.
			*if (touching = false)
				and his eyes fall back down to the table before he properly turns to face you.
			*goto hermestalk3_1
		#"Eternity's a pretty daunting concept, isn't it? You don't have to commit to that much."
			"Eternity's a pretty daunting concept, isn't it? You don't have to commit to that much." You offer a small smile, taking your best guess as to why he'd sounded like that and going with it. After all, as Hekate had basically just reminded you, communication is important. You might as well get started. 
			
			"Wait, what?" Hermes looks up from the table to you, his brows knitted. "What do you mean?"
			
			*if (confident > unsure)
				"Well, you didn't sound entirely pleased a few moments ago. And you didn't respond, when Hekate said eternity can work." 
			*if not (confident > unsure)
				"Well…" You hesitate. Confidence is not your strong suit, and this is important. You know that means you [i]need[/i] to talk about it, but the necessity makes the task no easier. "You just didn't sound very happy. When you said we had eternity. And… you didn't say anything, after Hekate said that could work." 
			
			"Oh." Hermes pushes a breath out through his nose,
			*if ((touching) and (hermeslap))
				and you feel him shift against you, leaning back a little more into your chest. 
			*if ((touching) and (hermeslap = false))
				and you feel his arms firm around you.
			*if (touching = false)
				and his eyes fall back down to the table before he properly turns to face you.
			*goto hermestalk3_1
		#"You know... I'm looking forward to forever, however that goes for us."
			You know... I'm looking forward to forever, however that goes for us." You're not entirely sure how to take the way he'd sounded about it, but as Hekate just got done reminding you, in her way, talking about the things that matter is important, and this [i]certainly[/i] matters. 
			
			"What?" He looks up from the table to you, brow knitting. "What makes you bring that up?"
			
			*if (confident > unsure)
				"Well, you didn't sound entirely pleased a few moments ago. And you didn't respond, when Hekate said eternity can work." 
			*if not (confident > unsure)
				"Well…" You hesitate. Confidence is not your strong suit, and this is significant. You know that means you [i]need[/i] to talk about it, but the necessity makes the task no easier. "You just didn't sound very happy. When you said we had eternity. And… you didn't say anything, after Hekate said that could work." 
			
			"Oh." Hermes pushes a breath out through his nose,
			*if ((touching) and (hermeslap))
				and you feel him shift against you, leaning back a little more into your chest. 
			*if ((touching) and (hermeslap = false))
				and you feel his arms firm around you.
			*if (touching = false)
				and his eyes fall back down to the table before he properly turns to face you.
			*goto hermestalk3_1
	*page_break
	*if (hermes_pace = "good")
		"So…" Hermes, obviously having collected himself, gives you a sly, narrow-eyed smile. "Since everything is going [i]well[/i] between us, and all that, and since we're now definitely alone, what would you say to something a little more… intimate?" 
	*if (hermes_pace = "tooslow")
		"So…" Hermes, obviously having collected himself, gives you a sly, narrow-eyed smile. "Since we're on the subject of our relationship, perhaps I should rectify your complaint about our pace. Being that we're alone, now, what would you say to something a little more… intimate?"
	*if (hermes_pace = "notime")
		"So…" Hermes, obviously having collected himself, gives you a sly, narrow-eyed smile. "Since we're on the subject of our relationship, perhaps I should start working on making time. Being that we're alone with nothing else to do right [i]now[/i], what would you say to something a little more… intimate?"
		
	*if (hermeslap)
		He twists a bit in your lap until he's more or less facing you square on, and the way he leans forward, bringing your faces closer, is an obvious suggestion about the kind of intimacy he has in mind.
	*if ((touching) and (hermeslap = false))
		He lifts you slightly, turning you about in his lap until it's a little easier to see his face, and the way he leans forward, bringing your faces closer, is an obvious suggestion about the kind of intimacy he has in mind.
	*if ((touching = false) and (hermes_touch2 != "averse"))
		The way he leans toward you, bringing your faces closer, is an obvious suggestion about the kind of intimacy he has in mind.
	*if ((touching = false) and (hermes_touch2 = "averse"))
		The way he leans just a little bit towards you, bringing your faces closer, is a clear suggestion about the kind of intimacy he has in mind, but the tone of his voice is cautious. As it obviously would be—this is quite a thing to ask of someone who doesn't respond well to casual touching. 
	
	*fake_choice
		#@{convotoggle [♥]|} "I've been waiting for you to ask something like that."
			*set intimate_touch "fine"
			*set overt +1
			"I've been waiting for you to ask something like that." You smile, swaying a little closer to him, in turn. 
			
			*if (hermes_touch2 = "averse")
				You know you've surprised him, saying something like that. 
				
				"I thought… you didn't like touching, though? The ask was sort of a… just in case it was different enough, with this kind." 
				
				"Well, it is," you reply with a shrug. Casual touching for no reason isn't something you like, but intimacy like this is deliberate. Planned, if not necessarily in advance, then at least a few seconds beforehand. You know what you're getting into, and you [i]do[/i] want to be intimate in this way. You can put aside your response to touch long enough to make it work. 
			
			"Well, then." Hermes's smile widens, looking almost silly for just a moment, before his fingers move to tilt your chin so he can brush his lips lightly over yours. 
		#@{convotoggle [♥]|} "I'd... love to."
			*set intimate_touch "fine"
			*set subtle +1
			"I'd… love to." You smile with a hint of sheepishness, swaying a little closer to him, in turn.
			
			*if (hermes_touch2 = "averse")
				You know you've surprised him, saying something like that. 
				
				"I thought… you didn't like touching, though? The ask was sort of a… just in case it was different enough, with this kind." 
				
				"Well, it is," you reply with a shrug. Casual touching for no reason isn't something you like, but intimacy like this is deliberate. Planned, if not necessarily in advance, then at least a few seconds beforehand. You know what you're getting into, and you [i]do[/i] want to be intimate in this way. You can put aside your response to touch long enough to make it work. 
			
			"Well, then." Hermes's smile widens, looking almost silly for just a moment, before his fingers move to tilt your chin so he can brush his lips lightly over yours. 
		#"I really don't like kissing, if I'm being honest."
			*set kissing "dislike"
			"I really don't like kissing, if I'm being honest." You clear your throat, only a little awkwardly, and shrug. You know he'd rather know. You've tried it, once or twice, and it's never been something you enjoyed. Even the idea of it just makes you uncomfortable, if you really think about it for more than a couple of seconds. 
			
			Hernes blinks, apparently a bit surprised, then nods. "Okay. That's a bit of a shame, because I love it. But it's not that important, really." He mirrors your shrug with one of his own, straightening his posture so he's no longer so close to your face. "We can do something else. Cuddling, maybe?"
			
			*label hermes_nokissmenu
			*if (hermes_touch2 = "averse")
				His brows knit. "Ah, but, that seems like you wouldn't enjoy it, either. Too much touching, right? Is there a better idea?"
				
				*fake_choice
					#"I just can't do touching. Not in any form. So this is going to need to be a relationship without any of the physical stuff. Okay?" 
						*set intimate_touch "averse"
						"I just can't do touching. Not in any form. So this is going to need to be a relationship without any of the physical stuff. Okay?" It's… you know most people expect things out of relationships that go beyond the intimacy of deep conversations and trust and going through life together, but those dimensions aren't anything you can provide. 
						
						Hermes frowns, but rather than upset, he looks thoughtful. "Okay," he says, with a small nod. "I knew that was a possibility. I suppose I should have asked about it before now, but I know, and that's the important thing. No touching of any kind." 
						
						His eyes narrow, and his lips quirk upwards. "So then, I'm going to ask a totally separate question. Are you interested in sex at all? Supposing I could think of ways to be intimate like that, and it didn't involve either of us touching the other?"
						
						*label hermesacequestion
						*fake_choice
							#I think I might understand at least some of what he means, and I nod. "Yes, if that would be possible, I'd be interested." 
								You think you might understand at least some of what he means, and you nod. "Yes, if that would be possible, I'd be interested." It's not like you're without desires, and you [i]do[/i] have desire for him. It's just that you [i]also[/i] can't stand being touched in any capacity. 
								
								Fortunately, those two things need not preclude one another completely. 
								
								"All right. Good to know." Hermes replies with a small smile. "I think maybe I'll need some time to think about how to do something like that properly, but for now…" 
								
								The smile turns quite sly. "I hope you'll think of me, when you handle those needs of yours. Now, how about we split up Hekate's pieces and finish the game?"
								
								*label hermes_thinkingofyou
								*fake_choice
									#@{convotoggle [☆]|} "It's extremely rude of you to say something like that and then go back to the game, you know?"
										"It's extremely rude of you to say something like that and then go back to the game, you know?" Nevertheless, you understand why he's doing so, and you don't ultimately object, moving to help him redistribute the resources. 
										
										"Well consider it payback, for making me want to kiss you," he replies, just as lightly. 
										
										You suppose you can accept the petty vengeance. For now.
										*goto chap3end
									#@{convotoggle [♥]|} "I think I will." 
										*set overt +1
										"I think I will." You offer him a languid smile, meeting his flirtation with your own. 
										
										*if (tag_uncharming)
											For a moment, he looks outright shocked at the expression, and then he chuckles. 
											
											"So you [i]can[/i] make bedroom eyes. I'd wondered." His expression doesn't lose the hint of sensuality, though, and the mirth fades lightly a moment later.
											
											"I like that idea quite a lot. I hope you don't mind that I'll be thinking of you, too."
										*if not (tag_uncharming)
											He chuckles. "Good. I like that idea… quite a lot. I hope you don't mind that I'll be thinking of you, too."
										*goto chap3end
									#@{convotoggle [♥]|} "As long as you're thinking of me, too."
										*set overt +1
										"As long as you're thinking of me, too." You offer him a languid smile, meeting his flirtation with your own. 
										
										*if (tag_uncharming)
											For a moment, he looks outright shocked at the expression, and then he chuckles. 
											
											"So you [i]can[/i] make bedroom eyes. I'd wondered." His expression doesn't lose the hint of sensuality, though, and the mirth fades lightly a moment later.
											
											"But… I like that idea quite a lot. And you can rest assured, I will be."
										*if not (tag_uncharming)
											He chuckles. "I like that idea… quite a lot. You can rest assured, I will be."
										*goto chap3end
									#@{convotoggle [♥]|} That is... far too embarrassing to respond to.
										*set subtle +1
										That is… far too embarrassing to respond to. You don't know what your face is doing, except that it's getting very hot, and it seems ridiculous to even try fumbling some kind of response together, so you don't, reaching for a few of Hekate's pieces instead. 
										
										Hermes chuckles, but fortunately he doesn't make any further comment. Perhaps he has some sense of mercy, after all. 
										*goto chap3end
							#You're not totally sure you know what he's talking about, but it sounds like a good idea anyway. "Yes, of course. I'm definitely attracted to you that way, I just..."
								You're not totally sure you know what he's talking about, but it sounds like a good idea anyway. "Yes, of course. I'm definitely attracted to you that way, I just..." 
								
								It's not like you're without desires, and you [i]do[/i] have desire for him. It's just that you [i]also[/i] can't stand being touched in any capacity. 
								
								You'd thought those two things were mutually exclusive, but apparently he doesn't share the view. That's both a relief and kind of surprising to learn. 
								
								He smiles a little. "You just don't want to be touched. It's all right, Sunshine. We'll get it figured out. I have a few ideas already, but I'll need a little time to decide how to do things properly."
								
								The smile turns quite sly. "I hope you'll think of me, when you handle your needs in the interim. Now, how about we split up Hekate's pieces and finish the game?"
								*goto hermes_thinkingofyou
							#The implications don't totally escape me, and I clear my throat softly. "Well... not right away, but eventually, I might be."
								The implications don't totally escape you, and you clear my throat softly. "Well... not right away, but eventually, I might be." It's not like you're without desires, and you [i]do[/i] have desire for him. It's just that you [i]also[/i] can't stand being touched in any capacity. 
								
								Fortunately, those two things need not preclude one another completely. 
								
								"All right. Good to know." Hermes replies with a small smile. "I think maybe I'll need some time to think about how to do something like that properly, anyway, so for now…" 
								
								The smile turns quite sly. "I hope you'll think of me, when you handle those needs of yours. Now, how about we split up Hekate's pieces and finish the game?"
								*goto hermes_thinkingofyou
							#I have no idea what he's talking about, but I can answer the hypothetical. "When we get to that point, maybe. Not right this moment, though." 
								You have no idea what he's talking about, but you can answer the hypothetical. "When we get to that point, maybe. Not right this moment, though." 								It's not like you're without desires, and you [i]do[/i] have desire for him. It's just that you [i]also[/i] can't stand being touched in any capacity. 
								
								You'd thought those two things were mutually exclusive, but apparently he doesn't share the view. That's both a relief and kind of surprising to learn. 
								
								He smiles a little. "It's all right, Sunshine. We'll get it figured out, at our own pace. I have a few ideas, but I'll need a little time to decide how to do things properly, anyway."
								
								The smile turns quite sly. "I hope you'll think of me, when you handle your needs in the interim. Now, how about we split up Hekate's pieces and finish the game?"
								*goto hermes_thinkingofyou
							#"No, I'm honestly not interested in anything sexual at all."
								*set tag_ace true 
								"No, I'm honestly not interested in anything sexual at all." He's right that it [i]is[/i] a separate question, but in your case at least, the answers are the same. Even if he could come up with something like that—and somehow you don't doubt that he could—you wouldn't be interested in the slightest. It's just not the way you are. 
								
								"Got it," Hermes says, smiling wryly. 
								*if (hermes_backstory = "friends")
									"I sort of figured that might be the case. Most people show at least some interest in that kind of thing, but I've never known you to."
								*if (hermes_backstory != "friends")
									"I don't know if I was expecting it, but it's good to know now."
								
								"Is that… going to be a problem for you?" Reputationally alone, you know he enjoys sex and all kinds of things related to it. He's never gone into any detail with you about that kind of thing, so you don't know how much of what you've heard is true, but you suspect at least some of it must be. 
								
								"Of course not," he replies with a small smile. "I don't [i]need[/i] sex. And what needs I do have, I can handle myself." He shrugs, as easy and confident as ever. 
								
								"Anyway, what do you say we redistribute Hekate's pieces and finish the game, for now?" 
								
								You aren't sure how you expected him to handle that information, but you have to admit, it's a relief that it really doesn't seem like a big deal to him at all. 
								
								Nodding, you start to collect the resources from the other side of the table. That's something that could have been a hurdle in your relationship cleared with aplomb, and you can't deny the way it helps you relax. 
								
								That feeling of sweet relief lasts through the rest of the afternoon.
								*goto chap3end
							#"I'm not really interested personally, but if it's something you'd enjoy, I don't mind participating now and then." 
								*set tag_posace true
								"I'm not really interested personally, but if it's something you'd enjoy, I don't mind participating now and then." He's right that it [i]is[/i] a separate question, and in your case, at least, the answers diverge a little. Your aversion to touch is not a total aversion to sexuality. You don't feel any real [i]desire[/i] for that sort of thing, but if he does, you don't mind sharing that experience with him on occasion. 
								
								"Huh." Hermes smiles wryly. 
								*if (hermes_backstory = "friends")
									"I sort of figured that might be the case. Most people show at least some interest in that kind of thing, but I've never known you to."
								*if (hermes_backstory != "friends")
									"I don't know if I was expecting that, but it's good to know now."
								
								He tilts his head at you. "As for the other part, also good to know. I'll think about it some more and let you know. After all, it's not like I [i]need[/i] sex. And what needs I do have, I can handle myself." He shrugs, as easy and confident as ever. 
								
								"Anyway, what do you say we redistribute Hekate's pieces and finish the game, for now?" 
								
								You aren't sure how you expected him to handle that information, but you have to admit, it's a relief that it really doesn't seem like a big deal to him at all. 
								
								Nodding, you start to collect the resources from the other side of the table. That's something that could have been a hurdle in your relationship cleared with aplomb, and you can't deny the way it helps you relax. 
								
								That feeling of sweet relief lasts through the rest of the afternoon.
								*goto chap3end
					#"I do understand that if we want to have any kind of sexual relationship, we'll have to touch sometimes. I just really don't like this kind."
						*set intimate_touch "middling"
						"I do understand that if we want to have any kind of sexual relationship, we'll have to touch sometimes. I just really don't like this kind." 
						
						Hermes frowns, but rather than upset or discouraged, he looks thoughtful. "So… intimacy by touch is fine, as long as it isn't kissing?"
						
						"More or less." You nod to confirm the rephrasing. It's probably not something he's run across before, so you don't mind explaining as much as he needs. 
						
						"So, supposing we were at a point where both of us wanted it, I could touch your body with my hands?" He arcs an eyebrow, the faint hint of a smile quirking at his lips. 
						
						*if (humorous > serious)
							"That's the idea," you reply, huffing softly.
						*if not (humorous > serious)
							"Isn't that what I just said?"
						
						"Okay, just making sure." The small smile becomes a grin. "I can work with that. Not right now, of course, but… soon enough. I do hope you'll think of me when addressing any needs that might come up in the interim. Now, shall we redistribute Hekate's ill-gotten gains and finish the game between ourselves?"
						*goto hermes_thinkingofyou
					#"I don't like being touched casually, and I don't want to be kissed on the mouth, but other kinds of touching or kissing in this context are okay."
						*set intimate_touch "fine"
						*set kissing "notface"
						"I don't like being touched casually, and I don't want to be kissed on the mouth, but other kinds of touching or kissing in this context are okay."
						
						Hermes frowns, but rather than upset or discouraged, he looks thoughtful. "So… intimacy by touch is fine, as long as it isn't kissing on the mouth?"
						
						"Yes, definitely." You nod to confirm the rephrasing. It's probably not something he's run across before, so you don't mind explaining as much as he needs. 
						
						"So, supposing we were at a point where both of us wanted it, I could touch your body with my hands?" He arcs an eyebrow, the faint hint of a smile quirking at his lips. 
						
						*if (humorous > serious)
							"That's the idea," you reply, huffing softly.
						*if not (humorous > serious)
							"Isn't that what I just said?"
						
						"Okay, just making sure." The small smile becomes a grin. "I can work with that. Not right now, of course, but… soon enough. I do hope you'll think of me when addressing any needs that might come up in the interim. Now, shall we redistribute Hekate's ill-gotten gains and finish the game between ourselves?"
						*goto hermes_thinkingofyou
					#"I don't like being touched casually, or any kind of kissing, but other kinds of touching in this context are okay."
						*set intimate_touch "fine"
						"I don't like being touched casually, or any kind of kissing, but other kinds of touching in this context are okay."
						
						Hermes frowns, but rather than upset or discouraged, he looks thoughtful. "So… intimacy by touch is fine, as long as it isn't kissing?"
						
						"Yes, definitely." You nod to confirm the rephrasing. It's probably not something he's run across before, so you don't mind explaining as much as he needs. 
						
						"So, supposing we were at a point where both of us wanted it, I could touch your body with my hands?" He arcs an eyebrow, the faint hint of a smile quirking at his lips. 
						
						*if (humorous > serious)
							"That's the idea," you reply, huffing softly.
						*if not (humorous > serious)
							"Isn't that what I just said?"
						
						"Okay, just making sure." The small smile becomes a grin. "I can work with that. Not right now, of course, but… soon enough. I do hope you'll think of me when addressing any needs that might come up in the interim. Now, shall we redistribute Hekate's ill-gotten gains and finish the game between ourselves?"
						*goto hermes_thinkingofyou
			*if (hermes_touch2 != "averse")
				His brows knit. "Stop me if I'm still heading the wrong way here, obviously."
				
				*fake_choice
					#@{convotoggle [♥]|} "Not at all. I'd love to cuddle."
						"Not at all. I'd love to cuddle." You offer him a small smile, and Hermes returns it, a soft breath of relief escaping him. 
						
						"That's good; I wasn't entirely sure what I was going to do if you didn't want to do that, either. Maybe offer to finish the game." He rolls his eyes, presumably at himself, then stands. 
						
						*label hermesgettingsettled
						*if ((hermeslap) or (touching = false))
							Once he's on his feet, he offers a hand down to you, and as soon you've stood as well, the two of you move over to one of the reclined sofas. 
						*if ((touching) and (hermeslap = false))
							He takes you with him as he does, lifting with no discernible effort and setting you down lightly on your feet.
						
						"You want to do this here?" you ask, lifting a brow slightly. 
						
						Hermes's smile briefly broadens. "Well, why not? It's not like anyone else is around, and the couches are comfortable. Don't get me wrong, you're welcome to invite yourself to my bed any time you want, but if you do that I might get ideas a little less tame than this one." 
						
						*if (hermeslap)
							Taking the cue from earlier, he gestures to the couch. "You first?" 
							
							Nodding, you get yourself settled, using the angled side of the couch to recline on your back, legs stretched out in front of you. When you're in place, Hermes climbs on with you, settling half to your side and half atop you, laying his head in the crook of your shoulder and arm. One wing drags on the floor, but he keeps the other tucked, adjusting so none of his weight is leaning anywhere uncomfortable, and sighs quietly. 
						*if (((touching) and (hermeslap = false)) or (touching = false))
							Considering it a moment, he hums, then moves to settle first, using the angled side of the couch to recline on his back, wings spread out to either side so he's not laying on top of them, legs stretched out in front of him. Then he opens his arms, and you take the cue, climbing on with him. 
							
							With some work, you manage to find a position that's relatively comfortable for both of you—you're partially atop him and partially to his side, head resting in the crook of his shoulder. 
							
							He sighs quietly. 
							*goto hermescuddle
					#"I suppose we could do something like that, sure."
						"I suppose we could do something like that, sure." You can't claim to be [i]overjoyed[/i] by the idea, but it sounds nice enough. You [i]have[/i] put paid to the other idea he had, and it's not as though you want to reject him, either. A bit of proximity could be enjoyable. 
						
						"That's good; I wasn't entirely sure what I was going to do if you didn't want to do that, either. Maybe offer to finish the game." He rolls his eyes, presumably at himself, then stands. 
						*goto hermesgettingsettled
					#@{convotoggle [♥]|} "You can kiss me places that aren't my mouth, just so you know. But cuddling is also fine."
						*set kissing "notface"
						"You can kiss me places that aren't my mouth, just so you know. But cuddling is also fine." You offer him a small smile, and Hermes returns it, a soft breath of relief escaping him. 
						
						"That's good to know; I'll keep it in mind. For now, though, being close is plenty. I wasn't entirely sure what I was going to do if you didn't want to try this, either. Maybe offer to finish the game." He rolls his eyes, presumably at himself, then stands. 
						*goto hermesgettingsettled
					#@{convotoggle [♥]|} "Could we just... hold hands for now?"
						"Could we just... hold hands for now?" You hate to say no yet again, but it's important that you're honest, and that degree of contact just doesn't feel like something you're quite up to, right now. But you still want to be close with him. 
						
						He blinks for a moment, but then nods readily. 
						*if (hermeslap)
							You can sort of understand the confusion, considering that what you've suggested is something of a step backward from the position you're already in, in a way. 
							
							But he doesn't protest, moving off your legs to settle down beside you instead, letting out a quiet breath as his hand finds your own. 
						*if ((touching) and (hermeslap = false))
							You can sort of understand the confusion, considering that what you've suggested is something of a step backward from the position you're already in, in a way. 
							
							But he doesn't protest, loosening his grip on you so you can move off his legs and settle beside him instead. His hand finds yours, and he lets out a quiet breath.
						*if (touching = false)
							It's probably not surprising, given that you'd already declined to sit any closer to him than you are. His hand finds yours, and he lets out a quiet breath. 
						
						"It's a little strange," he admits. "I never thought I'd have the inclination to just sit and hold somebody's hand." His own briefly squeezes yours, warm and soft. If his knifework might have given him calluses at any point, he's staved them off successfully, probably by taking very good care of himself. Then again, you've never known him to 'spar' much, so perhaps it wasn't a concern to begin with. 
						
						His fingertips are slightly roughened, though, where he drags them gently back and forth across your palm. Instrument strings, perhaps.
						*page_break
						"Why not?" you ask quietly, leaning back against the seat of the sofa behind you. 
						
						"I'm not sure," he replies, though then his lips purse. "Well, I'm kind of sure, but it'll probably make me sound like an ass to say it." 
						
						*fake_choice
							#@{convotoggle [☆]|} "And when has that ever stopped you from saying something?"
								*set humorous +1
								"And when has that ever stopped you from saying something?" You fix him with a [i]look[/i], and he snorts. 
								
								"Hey. I could say jerk-sounding things a lot more often than I actually do, you know. I [i]have[/i] a filter. It's just a matter of deciding when to use it." 
								
								His expression sobers. "Just… it's the kind of thing I've always thought was a waste of time. If I had the minutes to spare doing something like that, I could be doing something more interesting. I didn't think very highly of intimacy for its own sake."
							#"Well you don't have to, but I'd like to know."
								*set serious +1
								"Well you don't have to, but I'd like to know." You tilt your head slightly at him. 
								
								He hums, considering for a moment, and shakes his head.  "Just… it's the kind of thing I've always thought was a waste of time. If I had the minutes to spare doing something like that, I could be doing something more interesting. I didn't think very highly of intimacy for its own sake."
							#"Is that a problem?"
								"Is that a problem?" You're not sure if it means he isn't going to say it or not, but you know he's usually fairly honest by default—at least when he's here. 
								
								He hums, considering for a moment, and shakes his head.  "Just… it's the kind of thing I've always thought was a waste of time. If I had the minutes to spare doing something like that, I could be doing something more interesting. I didn't think very highly of intimacy for its own sake."								
						*line_break
						*line_break
						"Do you still think that?"
						
						He clicks his tongue against his teeth. "I don't know yet. Maybe in general. This doesn't feel like one, but maybe that's because we're talking. Or maybe it's because it's a different kind of relationship from the ones I've had before, and that changes things. I'll figure it out eventually." 
						
						His thumb lightly caresses the inside of your wrist, and you take a soft breath, holding it a moment and then releasing. It feels nice, if also a little strange. Like your awareness has narrowed to so few things that everything about them is more apparent to you. The drag of his fingertip, which could in another context be something you easily ignored, seems to take the lion's share of your attention, now. 
						
						But it isn't a focus that comes with any sense of urgency. You don't need to do anything about it. Don't need to act a certain way, or try to think about anything else. You can just… sit here and enjoy it, for a little while. Enjoy talking to Hermes. 
						
						And right now, that feels like everything you want.
						*goto chap3end
		#"I really don't like the idea of kissing, if I'm being honest." 
			*set kissing "dislike"
			"I really don't like the idea of kissing, if I'm being honest." You clear your throat, only a little awkwardly, and shrug. You know he'd rather know. You've never tried it, but you know you don't want to. Even the idea of it just makes you uncomfortable, if you really think about it for more than a couple of seconds. 
			
			Hernes blinks, apparently a bit surprised, then nods. "Okay. That's a bit of a shame, because I love it. But it's not that important, really." He mirrors your shrug with one of his own, straightening his posture so he's no longer so close to your face. "We can do something else. Cuddling, maybe?"
			*goto hermes_nokissmenu
		*if (hermes_touch2 = "averse")
			#"You know I don't like touching. This is no different. We're going to need to have a relationship without any of the physical stuff, okay?" 
				*set kissing "dislike"
				*set intimate_touch "averse"
				"You know I don't like touching. This is no different. We're going to need to have a relationship without any of the physical stuff, okay?"  You suppose it was a fair thing for him to ask about, because, well… casual touch and intimate touch [i]are[/i] different things. You, however, don't think of them all that differently.
				
				It's… you know most people expect things out of relationships that go beyond the intimacy of deep conversations and trust and going through life together, but those dimensions aren't anything you can provide. 
						
				Hermes frowns, but rather than upset, he looks thoughtful. "Okay," he says, with a small nod. "I knew that was a possibility. I suppose I should have asked about it before now, but I know, and that's the important thing. No touching of any kind." 

				His eyes narrow, and his lips quirk upwards. "So then, I'm going to ask a totally separate question. Are you interested in sex at all? Supposing I could think of ways to be intimate like that, and it didn't involve either of us touching the other?"
				*goto hermesacequestion
	*label hermeskissing
	*page_break
	It's a gentle touch, that first one, but not at all tentative. Hermes kisses like someone who knows exactly what he's doing, the little motions sure and deliberate. 
	*if (hermes_firstkiss)
		You've done this much before, but you're a little surprised that, when it ends, he doesn't immediately move away, instead pressing forward for another, this one much firmer, a little less perfectly controlled. 
	*if not (hermes_firstkiss)
		*set hermes_firstkiss true
		Somehow, even though this is the first time it's happened, that quality of assurance doesn't surprise you in the least.
		
		When it ends, he pulls back slightly, just enough to meet your eyes, searching there for… you know not what. 
		
		Whatever it is, he must find it, because he moves in again, and the second kiss is much firmer, a little less perfectly controlled. 
		
	*fake_choice
		#I sink into it, allowing him to guide me. 
			*set passive +1
			You sink into it, allowing him to guide you. Without a doubt, Hermes knows more about kissing than you do, but more than that, he seems to know how this should go. And, as good as it feels, you can't argue that he does, and so you don't try. 

			You press back into the kiss, one hand coming to rest on his shoulder, and you make a small sound of protest when he pulls away to brush his nose along your jaw, before laying a soft, warm kiss there as well. 

			"This okay?" he murmurs, setting another just at the corner of your mouth. 

			"Yes," you manage to murmur. There's a [i]dizzy[/i] feeling that goes with it all, something almost overwhelming, but the little break is enough for you to bring your head above metaphorical water. 
			*page_break
			Then his mouth touches yours again, lightly parted, and his tongue flicks playfully at the seam of your lips, and you're sinking again, slowly, delightfully, like a stone.

			One of his hands slips around your waist, fingers splaying wide over the small of your back, and the other remains near your face, the pad of his thumb running along your cheekbone as he coaxes your lips open, teasing your tongue with his own and encouraging you to do the same. Heat blooms in your gut; a strange tingling spreads out over your back and sides, little electrical sparks that seem to rush out from your spine just to make you shiver. 

			He feels it, and chuckles, the sound lightly muffled by your mouth, and the hand at your face moves to cup the nape of your neck. 

			"That's it, Sunshine. That's [i]good[/i]."

			That tone, slightly roughened but sincere, only adds to the heat in your belly. 
		#I bring my hand up to the back of his neck and shift the angle slightly. I don't mind being steered, but I'd like to have some say in how this goes, too. 
			You bring your hand up to the back of his neck and shift the angle slightly. You don't mind being steered, but you'd like to have some say in how this goes, too. Without a doubt, Hermes knows more about kissing than you do, but that's not so important, in the grand scheme of things. It still takes two, and you want to push as well as pull, as it were. 

			You press back into the kiss, using your hand for a bit of leverage, to angle the both of you a little differently. His mouth tastes very faintly of something citrusy, though you can't put your finger on exactly what it is. 

			Before you can decide, he pulls back a little, lips curled into a faint smile. "This okay?"

			"Was the participation not enough of a clue?" You [i]do[/i] feel a little dizzy, and the line perhaps comes out a touch more breathlessly than you'd intended, but that's fine with you, at the moment. He doesn't sound completely himself either, his voice lower and raspier than you're used to hearing it. 
			*page_break
			"Well, I thought it'd be polite to check anyway. Push me off if that changes." Briefly, his smile becomes a grin, and then he's pressing forward again, mouth parted slightly when it next touches yours. His tongue flicks out, teasing at the seam of your lips. 

			You hum, pulling away to press a kiss to his jaw instead, then another just below his ear, and he makes a noise somewhere between amusement and frustration, slipping one of his arms around your waist, fingers splaying wide over the small of your back. 

			"Sunshine," he half-protests, a hint of laughter on the edges of the word.

			You [i]do[/i] return to his mouth, when you're good and ready. The truth is, you hadn't wanted to be away long, either. When you run your tongue over his lip, he immediately opens to you, teasing your tongue with his own and encouraging you to do the same. Heat blooms in your gut; a strange tingling spreads out over your back and sides, little electrical sparks that seem to rush out from your spine just to make you shiver. 

			He makes a noise that sounds like it wants to be words but doesn't quite get there. But frankly, you don't have time for those, either, right now.
		#I take hold of the front of his tunic, asserting myself firmly in the exchange. 
			*set assertive +1
			You take hold of the front of his tunic, asserting yourself firmly in the exchange. Hermes probably knows more about kissing than you do, but that doesn't matter. What you don't know, you can learn, and what you [i]do[/i] know is that this is how you want things to be. 

			You press back into the kiss, using your grip on the fabric for leverage. His mouth tastes very faintly of something citrusy, though you can't put your finger on exactly what it is. 

			Before you can decide, he pulls back a little, lips curled into a faint smile. "This okay?"

			"Obviously," you reply, pulling him back in unceremoniously. You can feel his shoulders shake with a silent chuckle, but it soon becomes a softly-audible groan, instead, and you smile against his mouth.
			*page_break
			Pulling away, you press a kiss to his jaw instead, then another just below his ear, and he makes a noise somewhere between amusement and frustration, slipping one of his arms around your waist, fingers splaying wide over the small of your back. 

			"Sunshine," he half-protests, a hint of laughter on the edges of the word.

			You [i]do[/i] return to his mouth, when you're good and ready. The truth is, you hadn't wanted to be away long, either. When you run your tongue over his lip, he immediately opens to you, teasing your tongue with his own and encouraging you to do the same. Heat blooms in your gut; a strange tingling spreads out over your back and sides, little electrical sparks that seem to rush out from your spine just to make you shiver. 

			He hums, a noise that sounds like it wants to be words but doesn't quite get there. But frankly, you don't have time for those, either, right now.
	*page_break
	You lose track of time, a bit, one of many details that doesn't feel like it [i]matters[/i], right now. For as long as you can stand it, it's just you, and Hermes, and the heat between you. 

	And that feels exactly right.
	*goto chap3end
	*label hermescuddle
	His hand ends up on your arm, and he strokes gently at your skin, skimming down over your bicep and lingering at the inside of your elbow for a moment before gently taking your hand. It's a bit awkward, the angles of it, but you don't mind that for a short while. 
	
	"It's a little strange," he admits. "I never thought I'd have the inclination to just sit and hold somebody. Or be held." His hand briefly squeezes yours, warm and soft. If his knifework might have given him calluses at any point, he's staved them off successfully, probably by taking very good care of himself. Then again, you've never known him to 'spar' much, so perhaps it wasn't a concern to begin with. 

	His fingertips are slightly roughened, though, where he drags them gently back and forth across your palm. Instrument strings, perhaps.
	*page_break
	"Why not?" you ask quietly, adjusting a little for comfort. He's so close that you can easily smell him—fresh air and something a bit spicy. 

	"I'm not sure," he replies, though then his lips purse. "Well, I'm kind of sure, but it'll probably make me sound like an ass to say it." 

	*fake_choice
		#@{convotoggle [☆]|} "And when has that ever stopped you from saying something?"
			*set humorous +1
			"And when has that ever stopped you from saying something?" You fix him with a [i]look[/i] as best you can in this position, and he snorts. 

			"Hey. I could say rude-sounding things a lot more often than I actually do, you know. I [i]have[/i] a sense of decorum. It's just a matter of deciding when to use it." 

			His expression sobers. "Just… it's the kind of thing I've always thought was a waste of time. If I had the minutes to spare doing something like that, I could be doing something more interesting. I didn't think very highly of intimacy for its own sake."
		#"Well you don't have to, but I'd like to know."
			*set serious +1
			"Well you don't have to, but I'd like to know." You tilt your head slightly at him, at least as well as you can convey that, in this position. 

			He hums, considering for a moment, and shakes his head.  "Just… it's the kind of thing I've always thought was a waste of time. If I had the minutes to spare doing something like that, I could be doing something more interesting. I didn't think very highly of intimacy for its own sake."
		#"Is that a problem?"
			"Is that a problem?" You're not sure if it means he isn't going to say it or not, but you know he's usually fairly honest by default—at least when he's here. 

			He hums, considering for a moment, and shakes his head.  "Just… it's the kind of thing I've always thought was a waste of time. If I had the minutes to spare doing something like that, I could be doing something more interesting. I didn't think very highly of intimacy for its own sake."								
	*line_break
	*line_break
	"Do you still think that?"

	He clicks his tongue against his teeth. "I don't know yet. Maybe in general. This doesn't feel like one, but maybe that's because we're talking. Or maybe it's because it's a different kind of relationship from the ones I've had before, and that changes things. I'll figure it out eventually." 

	His thumb lightly caresses the inside of your wrist, and you take a soft breath, holding it a moment and then releasing. It feels nice, if also a little strange. Like your awareness has narrowed to so few things that everything about them is more apparent to you. The drag of his fingertip, which could in another context be something you easily ignored, seems to take the lion's share of your attention, now, the rest of it mostly consumed by the warmth and smell of him. 

	But it isn't a focus that comes with any sense of urgency. You don't need to do anything about it. Don't need to act a certain way, or try to think about anything else. You can just… sit here and enjoy it, for a little while. Enjoy talking to Hermes. Laying next to him. 

	Right now, that feels like everything you want.
	*goto chap3end
*if (route = "hekate")
	when you're interrupted by the sound of Hermes clicking his tongue against his teeth, then sighing. You look over to his side of the table to find him wearing a wry smile. 
	
	"Sorry, you two," he says. "His Deathliness is asking me for a consult." He points to his head, a shorthand for an Erebus message, and stands. 
	
	"Consult on what?" Hekate asks. "Does he need us as well?"
	
	"Doesn't seem to," Hermes replies, brushing down his tunic. "Might be a mortal realm thing. Or there's another lost spirit I have to go find. You never know around here." Lifting a hand in farewell, he shrugs. "I'll see you around; sorry we couldn't finish the game."
	
	*fake_choice
		#@{convotoggle [☆]|} "Are you sure you're not leaving just because you're losing?"
			*set humorous +1
			"Are you sure you're not leaving just because you're losing?" It's hard to resist the urge to rib him a little, so you don't try. 
			
			He barks a short laugh, eyes narrowing. "We must be looking at very different boards, Sunshine. You should be glad I'm leaving." 
			
			"Get your eyes checked, 'Featherhead,'" Hekate replies, using one of Pyri's sillier nicknames for him. "You were about three turns from being crushed beneath my heel." 
			
			"If you say so." He offers a silly grin. "Anyway, see you both later. Enjoy your alone time!" 
			
			And then he's gone.
		#"It's no problem, Hermes. Work has to come first."
			*set serious +1
			"It's no problem, Hermes. Work has to come first." You offer him a small nod. 
			
			He gives you an amused expression in return. "I don't know that that's [i]always[/i] true, but I suppose it should be sometimes, considering what we're all doing, here." 
			
			"Good luck," Hekate adds, and he snorts softly. 
			
			"I do have that. See you both later. Enjoy your alone time!" 
			
			And then he's gone.
		#"We'll see you later, then?"
			"We'll see you later, then?" You tilt your head to the side. 
			
			"Of course," he replies readily. "Until then, enjoy your alone time!"
			
			And then he's gone.
	*page_break
	This does, in fact, leave you alone with Hekate, for the first time in a little while. She leans forward as if to begin tidying the game board, then seems to think better of it, turning to you instead. "I'd say this was a deliberate gambit on his part, to get us to talk, but unfortunately running about everywhere is entirely normal for him." 
	
	"Get us to talk about what?" 
	
	Her smile becomes slightly lopsided. "The part where I said I've been faulted for my attentiveness, before. He probably thinks I'm falling into those habits, with you.
	*if ((hekate_pace = "tooslow") or (hekate_pace = "notime"))
		And judging from your response to his question, he might be right. If you're unsatisfied with something, I need to put it right."
	*if (hekate_pace = "good")
		And given the vagueness of your response to his question, it's certainly a matter I should check on. If you're unsatisfied with something, I need to put it right."
	
	*fake_choice
		#"I don't think it has anything to do with you prioritizing your work too much, or anything like that."
			"I don't think it has anything to do with you prioritizing your work too much, or anything like that." You shake your head. 
			*if (hekate_pace = "good")
				You really don't think there's a problem in need of fixing here. Maybe it's true that your relationship isn't currently taking up as much of your mutual time as you'd [i]most[/i] prefer, but it doesn't strike you as a serious issue, or even one that's been around very long. Things have just been busy lately. 
			*if (hekate_pace = "tooslow")
				Maybe there's something to be said about the pace at which your relationship is growing, but it doesn't come down to how often you see each other, or that you feel neglected. Hekate's attentive—it's just that sometimes you wish the [i]kind[/i] of attention were different. 
			*if (hekate_pace = "notime")
				Things have just been extremely busy, of late, and a lot of that is on [i]your[/i] end, at least as much as hers. It would be nice to get more time together, but this isn't some longstanding problem born of neglect. It's just a quirk of the circumstances. 
				
			"Okay," she replies slowly, nodding her head once. "That's good to know. Thanks for saying it, but if it ever changes, don't feel like you can't tell me that, too." 
			
			"I won't," you reply. "I promise."
		*if (hekate_pace = "good")
			#"Perhaps I was a bit vague, but that isn't because I have any problems with how things are. I really think they're going well."
				"Perhaps I was a bit vague, but that isn't because I have any problems with how things are. I really think they're going well."
				
				As far as you're concerned, there's no problem in need of fixing, here. Maybe it's true that your relationship isn't currently taking up as much of your mutual time as you'd [i]most[/i] prefer, but it doesn't strike you as a serious issue, or even one that's been around very long. Things have just been busy lately, at least as much for you as for her. 
				
				"Okay," she replies slowly, nodding her head once. "That's fair. I'm not all that keen to go into details with anyone else just yet, either. Maybe in time Hermes will answer all the little burning questions on his mind, but for now I'm more than fine keeping anything but the vague stuff to ourselves. Just as long as you promise to tell me if anything changes." 
				
				"I will," you reply. "I promise."
		#"Well... I suppose it would be nice if we got more time together than we do, but I think that's less about your work and more about how busy things have been lately for both of us." 
			"Well... I suppose it would be nice if we got more time together than we do, but I think that's less about your work and more about how busy things have been lately for both of us." Namely, extremely so, more even for you than for her. It would be nice to get more time together, but this isn't some longstanding problem born of neglect. It's just a quirk of the circumstances. 
			
			"Okay," she replies slowly, nodding her head once. "That's fair. It's been… quite a lot at once, lately, to be sure. But we'll get past it, and I'll do my best to make sure I'm taking enough time away from the library. Just as long as you promise to tell me if anything changes." 
				
			"I will," you reply. "I promise."
		#"Before? Can you explain what you mean?"
			"Before? Can you explain what you mean?" You're more curious about that than you are worried about any sort of neglect on her part. Maybe it's true that your relationship isn't currently taking up as much of your mutual time as you'd [i]most[/i] prefer, but it doesn't strike you as a serious issue, or even one that's been around very long. Things have just been busy lately, at least as much for you as for her. 
			
			"There's not much to explain," she replies, lifting her shoulders a bit. "I've had some previous relationships—no one you've met or anything—and perhaps more often than not, they end because I'm not… especially good at gauging the right amount of time to devote to them. And I often fall specifically on the side of 'not enough.'" 
			
			She grimaces slightly. "Mind you, I [i]am[/i] trying to fix that, even in terms of finding more time for my friendships, but if it ever seems like I'm not around enough, please tell me before it gets to the point that you can't take it anymore." 
			
			That's an easy enough commitment to make. 
			
			"I will," you reply. "I promise."
	*page_break
	*if (hekate_pace = "good")
		"Good." Hekate pauses for a moment, considering you with warm, dark eyes. "If you're satisfied with how things are presently proceeding, however, I have to wonder if perhaps my next suggestion isn't too forward." She chuckles softly.
	*if (hekate_pace = "tooslow")
		"Good." Hekate pauses for a moment, considering you with warm, dark eyes. "Now that I know you do feel things are moving a bit slowly, though, I'm wondering if you might not enjoy my next suggestion." She chuckles softly. 
	*if (hekate_pace = "notime")
		"Good." Hekate pauses for a moment, considering you with warm, dark eyes. "Now that I know you've been feeling my absence, of late, I'm wondering if you might not enjoy my next suggestion." She chuckles softly. 
	
	"I guess that depends on what it is," you reply honestly, and the small smile on her lips tugs wider. 

	"Entirely reasonable. I'll ask: how would you feel about it, if things got a little more…" She leans a little closer, 
	*if (touching)
		pressing herself a bit into your arm.
	*if not (touching)
		closing some of the polite distance between you. 
	"Let's say the word I want is 'intimate.' I'd like to kiss you, you see. More than once at a time, as it were."
	*if (hekate_touch2 = "averse")
		Her tone has a note of caution to it, and she tilts her head inquiringly.
	*if (hekate_touch2 != "averse")
		Her tone is lightly-playful, but the question is obviously genuine.
	
	*fake_choice
		#@{convotoggle [♥]|} "I've been waiting for you to ask me something like that."
			*set intimate_touch "fine"
			*set overt +1
			"I've been waiting for you to ask something like that." You smile, swaying a little closer to her, in turn. 
			
			*if (hekate_touch2 = "averse")
				You know you've surprised her, saying something like that. It's in the care she used, even venturing the question. You think she probably expected you to decline.
				
				"I admit," she confirms, a touch wryly. "I wasn't expecting that answer. I was asking just in case your thinking about that sort of touch was different to the other kinds."
				
				"It is," you reply with a small nod. Casual touching for no reason isn't something you like, but intimacy like this is deliberate. Planned, if not necessarily in advance, then at least a few seconds beforehand. You know what you're getting into, and you [i]do[/i] want to be intimate in this way. You can put aside your response to touch long enough to make it work. 
			
			"I'll trust you to be sure," Hekate replies lightly, locking eyes with you. "And to tell me if that changes." 
			
			She doesn't belabor the point, though, running the pad of one finger lightly along the line of your jaw. The touch is almost featherlight, but still angles your head just enough that when your lips meet, they do so fully.
		#@{convotoggle [♥]|} "I'd... love to."
			*set intimate_touch "fine"
			*set subtle +1
			"I'd… love to." You smile with a hint of sheepishness, swaying a little closer to her, in turn.
			
			*if (hekate_touch2 = "averse")
				You know you've surprised her, saying something like that. It's in the care she used, even venturing the question. You think she probably expected you to decline.
				
				"I admit," she confirms, a touch wryly. "I wasn't expecting that answer. I was asking just in case your thinking about that sort of touch was different to the other kinds."
				
				"It is," you reply with a small nod. Casual touching for no reason isn't something you like, but intimacy like this is deliberate. Planned, if not necessarily in advance, then at least a few seconds beforehand. You know what you're getting into, and you [i]do[/i] want to be intimate in this way. You can put aside your response to touch long enough to make it work. 
			
			"I'll trust you to be sure," Hekate replies lightly, locking eyes with you. "And to tell me if that changes." 
			
			She doesn't belabor the point, though, running the pad of one finger lightly along the line of your jaw. The touch is almost featherlight, but still angles your head just enough that when your lips meet, they do so fully.
		#"I really don't like kissing, if I'm being honest."
			*set kissing "dislike"
			"I really don't like kissing, if I'm being honest." You clear your throat, only a little awkwardly, and shrug. You know she'd rather know. You've tried it, once or twice, and it's never been something you enjoyed. Even the idea of it just makes you uncomfortable, if you really think about it for more than a couple of seconds. 
			
			"Entirely fair," Hekate says, with a soft huff. "It's such a strange thing if you think about it, isn't it? Putting your mouth to someone else's. I used to be rather disgusted by the thought, myself." 
			
			"What changed your mind?"
			
			She lifts her shoulders, casually letting them fall again. "The way it felt. But it seems that hasn't changed your mind, so let's think about alternatives, hm? What about holding each other?"
			
			*label hekate_nokissmenu
			*if (hekate_touch2 = "averse")
				She frowns. "Ah, but, that might be a little too close to other kinds of touching, right? Perhaps a poor suggestion."
				
				There's a pause there, though, a clear opening for you to confirm or deny the hypothesis.
				
				*fake_choice
					#"I just can't do touching. Not in any form. So this is going to need to be a relationship without any of the physical stuff. Okay?" 
						*set intimate_touch "averse"
						"I just can't do touching. Not in any form. So this is going to need to be a relationship without any of the physical stuff. Okay?" In a way, it's a relief to be able to say that. It had never seemed quite the right time to bring it up in conversation before. Different people are okay or not with different amounts and kinds of touch, you know, but you just can't do any of it. 
						
						It's been on your mind for a while, that this might be something of a problem. Most people enter into relationships like this expecting [i]some[/i] kind of physical intimacy, but it's not something you can give. 
						
						If she's not going to be able to cope with that, it would be much better to know now.
						
						Hekate hums, but her expression is thoughtful, you think, and she isn't giving you any sense of disappointment. 
						
						"All right," she says, nodding slowly. "That's clear now, so I'd like to ask you a separate question. "Do you feel any desire for sexual intimacy at all? Or do you desire me in a sexual way? Don't worry about touching for a moment." 
						
						*label hekate_acequestion
						*fake_choice
							#"I do, yes. I just... the not-touching part is more urgent, if that makes sense." 
								"I do, yes. I just... the not-touching part is more urgent, if that makes sense." You're not entirely sure it does, but this is not the easiest subject matter to talk about, considering how little practice you have. 
								
								Hekate, though, seems to be entirely unfazed. "All right. That's simple enough. We just need to explore ways of being together that don't have to involve touching one another." 
								
								"You have some kind of idea?" 
								
								"Ideas," she corrects, with a hint of mischief in her smile. "Nothing for today, but some things that might suit us in the future. For the meantime, how about we embrace Hermes's spirit and steal his belongings so we can finish our game?" 
								
								*label hekate_transitionout
								*fake_choice
									#@{convotoggle [☆]|} "It's a little unfair to leave me hanging like this, you know. But sure; let's do that."
										*set humorous +1
										"It's a little unfair to leave me hanging like this, you know. But sure; let's do that." You offer her a grin for the jest, and she returns it with a subtler smile. 
										
										"Anticipation is one of the keys to exchanges like this, you know. Intimacy is at least as much about the mind as the body, and we especially are going to be counting on the truth of that." 
										
										You don't know that you've ever thought about it in that way, but she seems to know what she's talking about, and there's no reason not to at least try. 
										
										So you reach for the pieces across the table, letting the things she's said percolate at the back of your mind quietly, for now.
										*goto chap3end
									#"If you think that's what's best, then sure." 
										*set serious +1
										"If you think that's what's best, then sure." You offer a small shrug, and she returns it with a subtle smile. 
										
										"Anticipation is one of the keys to exchanges like this, you know. Intimacy is at least as much about the mind as the body, and we especially are going to be counting on the truth of that." 
										
										You don't know that you've ever thought about it in that way, but she seems to know what she's talking about, and there's no reason not to at least try. 
										
										So you reach for the pieces across the table, letting the things she's said percolate at the back of your mind quietly, for now.
										*goto chap3end
									#@{convotoggle [♥]|} "I'll look forward to hearing more about what you just said, but all right." 
										"I'll look forward to hearing more about what you just said, but all right." You arch an eyebrow slightly at her, lips curling, and she returns the expression with a subtle smile of her own. 
										
										"Anticipation is one of the keys to exchanges like this, you know. Intimacy is at least as much about the mind as the body, and we especially are going to be counting on the truth of that." 
										
										You don't know that you've ever thought about it in that way, but she seems to know what she's talking about, and there's no reason not to at least try. 
										
										So you reach for the pieces across the table, letting the things she's said percolate at the back of your mind quietly, for now.
										*goto chap3end
									#I nod slowly, reaching for the pieces across from us.
										You nod slowly, reaching for the pieces across from you. If she thinks that's for the best, you don't have any arguments to the contrary, after all. 
										
										Seeing this, Hekate offers you a subtle smile. 
										
										"Anticipation is one of the keys to exchanges like this, you know. Intimacy is at least as much about the mind as the body, and we especially are going to be counting on the truth of that." 
										
										You don't know that you've ever thought about it in that way, but she seems to know what she's talking about, and there's no reason not to at least try. 
										
										So you begin to divide up Hermes's assets, letting the things she's said percolate at the back of your mind quietly, for now.
										*goto chap3end
							#"I'm not sure. I think so, but the other part complicates my feelings, too. I don't know if I can keep them completely separate." 
								"I'm not sure. I think so, but the other part complicates my feelings, too. I don't know if I can keep them completely separate." It's hard to explain, but you say it as well as you can anyway, hoping that she understands. 
								
								Hekate, as it happens, seems quite unfazed. "Okay. I can see where that would be difficult. But it should be simple enough to figure out. We just need to explore ways of being together that don't have to involve touching one another. If you enjoy it, you'll know one way, and if you don't, we can avoid that sort of thing from there out." 
								
								"You have some kind of idea?" 
								
								"Ideas," she corrects, with a hint of mischief in her smile. "Nothing for today, but some things that might suit us in the future. For the meantime, how about we embrace Hermes's spirit and steal his belongings so we can finish our game?" 
								*goto hekate_transitionout
							#"No. I've never wanted anyone in what I would describe as a sexual way. My feelings for you are real, but not like that."
								*set tag_ace true
								"No. I've never wanted anyone in what I would describe as a sexual way. My feelings for you are real, but not like that." The same sense of awkwardness that had made the first part difficult to say are still there—just amplified. 
								
								But Hekate seems quite unfazed. "All right," she says, with a single simple nod. "That makes things quite uncomplicated, doesn't it?" A hint of a smile curls her lips. 
								
								*if (confident > unsure)
									"Is that going to be any kind of issue?"
								*if not (confident > unsure)
									"Is that… are you okay with that?" 
								You get the sense that she is of a very different mind, when it comes to sexuality. 
								
								"It's not a problem at all," she replies, one eyebrow arcing over the other. "I'm not with you because I desire you, ${name}. I [i]do[/i], but it's comparatively quite an easy feeling to ignore, for me. And trust me when I say I know how to take care of my own needs. so there's nothing to be concerned about, all right?"
								
								A welling feeling of relief spreads from your guts up into your chest, and you let out a soft breath. You're glad to hear it, and when you tell Hekate so, she laughs gently. 
								
								"You know, I had a feeling it was possible," she observes. "But even if it'd surprised me, it's not so uncommon, you know? I've met plenty of people who have no desire for sex." She shakes her head. 
								
								"Anyway, what say you we embrace Hermes's spirit and ruthlessly plunder his resources so we can finish our game?"
								
								"Sure." You start to collect the resources from the other side of the table. That's something that could have been a hurdle in your relationship cleared with aplomb, and you can't deny the way it helps you relax. 
								
								That feeling of sweet ease lasts through the rest of the afternoon.
								*goto chap3end
							#"No, but... I would like to be intimate with you regardless. If that makes sense."
								*set tag_posace true
								"No, but... I would like to be intimate with you regardless. If that makes sense." She's right that it [i]is[/i] a separate question, and in your case, at least, the answers diverge a little. Your aversion to touch is not a total aversion to sexuality. You don't feel any real [i]desire[/i] for that sort of thing, but if she does, you don't mind sharing that experience with her on occasion. 
								
								Hekate considers this for a moment and nods. "All right," she says, tone relaxed. "We'll figure that part out as we go. I'm rather experienced at taking care of myself, so it's not as though I [i]need[/i] anything I don't already have, in that realm. But if you're ever curious or want that type of closeness, let me know." 
								
								Her eyes flick across the table, for a moment, and she turns back to you with a conspiratorial smile. "Now. What say you we embrace Hermes's spirit and ruthlessly plunder his resources so we can finish our game?"
								
								"Sure." You start to collect the resources from the other side of the table. That's something that could have been a hurdle in your relationship cleared with aplomb, and you can't deny the way it helps you relax. 
								
								That feeling of sweet ease lasts through the rest of the afternoon.
								*goto chap3end
					#"I do understand that if we want to have any kind of sexual relationship, we'll have to touch sometimes. I just really don't like this kind."
						*set intimate_touch "middling"
						"I do understand that if we want to have any kind of sexual relationship, we'll have to touch sometimes. I just really don't like this kind."
						
						Hekate considers this for a moment, humming softly. "So, to be clear, you're all right with being touched in a sexual way, as long as it isn't kissing specifically?"
						
						"More or less." There are nuances, but you're sure you can address those when they come up. [i]If[/i] they do. Rather than just trying to list them all, or something like that, it seems best to handle organically.
						
						"Interesting…" There's a playful lilt to her tone, and you blink.
						
						"You have an idea?"
						
						"Ideas," she corrects, with a hint of mischief in her smile. "Nothing for today, but some things that might suit us in the future. For the meantime, how about we embrace Hermes's spirit and steal his belongings so we can finish our game?" 
						*goto hekate_transitionout
					#"I don't like being touched casually, and I don't want to be kissed on the mouth, but other kinds of touching or kissing in this context are okay."
						*set intimate_touch "fine"
						*set kissing "notface"
						"I don't like being touched casually, and I don't want to be kissed on the mouth, but other kinds of touching or kissing in this context are okay."
						
						Hekate considers this for a moment, humming softly. "So, to be clear, you're all right with being touched in a sexual way, as long as it isn't kissing on the mouth specifically?"
						
						"Yes, that's basically it." You don't mind clarifying; you have a feeling this is not a specific combination of preferences she's likely to have run across before. 
						
						"Interesting…" There's a playful lilt to her tone, and you blink.
						
						"You have an idea?"
						
						"Ideas," she corrects, with a hint of mischief in her smile. "Nothing for today, but some things that might suit us in the future. For the meantime, how about we embrace Hermes's spirit and steal his belongings so we can finish our game?" 
						*goto hekate_transitionout
					#"I don't like being touched casually, or any kind of kissing, but other kinds of touching in this context are okay."
						*set intimate_touch "fine"
						"I don't like being touched casually, or any kind of kissing, but other kinds of touching in this context are okay."
						
						Hekate considers this for a moment, humming softly. "So, to be clear, you're all right with being touched in a sexual way, as long as it isn't kissing specifically?"
						
						"Yes, that's basically it." You don't mind clarifying; you have a feeling this is not a specific combination of preferences she's likely to have run across before. 
						
						"Interesting…" There's a playful lilt to her tone, and you blink.
						
						"You have an idea?"
						
						"Ideas," she corrects, with a hint of mischief in her smile. "Nothing for today, but some things that might suit us in the future. For the meantime, how about we embrace Hermes's spirit and steal his belongings so we can finish our game?" 
						*goto hekate_transitionout
			*if (hekate_touch2 != "averse")
				She tilts her head. "Would that be a suitable substitution?"
				
				*fake_choice
					#@{convotoggle [♥]|} "Yes, definitely. I'd love to."
						"Yes, definitely. I'd love to." That sounds much more enjoyable, and you find even the notion itself puts a little grain of warmth in the pit of your stomach. 
						
						"Ah, excellent. My only other suggestion for today at least was to finish our game. Which I wouldn't mind, of course, but this is something altogether preferable to me." 

						*label hekate_gettingsettled
						Standing, Hekate offers a hand down to you, and you slip yours into it, not pulling against her too hard as you find your feet. She leads you over to one of the reclined couches, and hums thoughtfully. 
						
						*if (height > 3)
							"You're taller than me, though I don't think that's necessarily the relevant point, here. Would you prefer to lay down first or second?"
						*if (height <= 3)
							"Our heights aren't too different, though I don't think that's necessarily the relevant point here, anyway. Would you prefer to lay down first or second?"
						
						First would likely mean that she's against you, possibly with her head atop you in some way, while second would be the opposite, you suppose. There's certainly going to be a lot of contact involved, if you're both going to fit on the couch lengthways.
						
						*fake_choice
							#"I'll go first."
								"I'll go first." 
								
								You get yourself settled against the reclined arm, stretching your legs out in along the cushions and making yourself comfortable. With a gesture, you invite Hekate to take a place as well, and she climbs on, maneuvering her long tunic layers and tucking herself into your side. Her temple comes to rest against the front of your shoulder, and she throws an arm over your waist, whether for stability or just to enjoy the contact isn't clear, and probably doesn't much matter. 
								
								You wind your arm around her back, your other loose at your opposite side, and let out a breath.
							#"I'll go second."
								"I'll go second." 
								
								She gets herself settled against the reclined arm, stretching her legs out along the cushions and shifting her tunic's hem about until she's comfortable. Then she invites you on with a small gesture and a smile, and you climb into place, tucking yourself against her side and wrapping an arm around her middle, letting your head rest just inside the front of her shoulder. 
								
								It leaves you looking down at the swell of her chest, mostly, but it's undeniably comfortable, and she winds her arm around your back, letting the one on the opposite side of you rest loosely next to her. 
						*page_break
						*goto hekate_cuddle
					#"I suppose we could do something like that, sure."
						"I suppose we could do something like that, sure." You can't claim to be [i]overjoyed[/i] by the idea, but it sounds nice enough. You [i]have[/i] put paid to the other idea she had, and it's not as though you want to reject her, either. A bit of proximity could be enjoyable. 
						
						"Ah, excellent. My only other suggestion for today at least was to finish our game. Which I wouldn't mind, of course, but this is something altogether preferable to me."						
						*goto hekate_gettingsettled
					#@{convotoggle [♥]|} "You can kiss me places that aren't my mouth, just so you know. But cuddling is also fine."
						*set kissing "notface"
						"You can kiss me places that aren't my mouth, just so you know. But cuddling is also fine." You offer her a small smile, and she returns it with a chuckle. 
						
						"That is something I'll keep in mind. For now, though, I rather think being holding and being held sounds delightful. My only other suggestion for today at least was to finish our game. Which I wouldn't mind, of course, but this is something altogether preferable to me."						
						*goto hekate_gettingsettled
					#@{convotoggle [♥]|} "Could we just... hold hands for now?"
						"Could we just... hold hands for now?" You hate to say no yet again, but it's important that you're honest, and that degree of contact just doesn't feel like something you're quite up to, right now. But you still want to be close with her. 
						
						Hekate considers this for a moment, though you're not exactly sure why, because her answer doesn't come out like something she had to think about. "Of course we can."
						
						*if (touching)
							You're already in close contact, and she only has to shift her hand a little to grasp yours, pressing her palm gently against your own.
						*if not (touching)
							You're not sitting so far apart that she can't reach, and you meet her halfway over that distance. She grasps your hand, pressing her palm gently against your own. 
						
						"You don't have to say 'just,' you know," she offers, her lips tilting slightly upwards again. "I'm not one of those people who thinks of some forms of intimacy as 'more' than others. They're different, to be sure, and some of them can be more than one type, but I don't like the idea that this is 'less than' a kiss." 
						
						*fake_choice
							#"It really is, though, isn't it? Less intimate?"
								"It really is, though, isn't it? Less intimate?" You press your lips together. You do think that there is more intimacy to some acts than others. Saying they're all basically on the same level and differ only by type seems a bit… well. You're not really sure how she could think that. 
								
								"Not to me," she replies with a small shrug. "I think it comes down to how you think about things. It's possible to have sex without any intimacy involved at all. Whereas something as simple as holding hands can be very significant, in the right context. It's not about the act. It's about the way the people involved are approaching it."
								
								You suppose there's some truth to that, at least, but you're not entirely sure if you're convinced just yet. 
								
								Perhaps inferring as much, she chuckles. "Well, in any event, know that [i]I[/i] find this very satisfying, and that I am not disappointed that this is where we wound up. At the very least I think we can agree that the only intimacy worth the name is the kind we both enjoy, no?"
								
								That much, at least, is entirely correct. 
							#"That's a relief to hear. A lot of the things that people think of as 'more,' I'm not really sure about."
								"That's a relief to hear. A lot of the things that people think of as 'more,' I'm not really sure about." Perhaps it's just a lack of familiarity, but you don't particularly need to figure out exactly why that is right now. 
								
								Hekate, after all, doesn't ask. 
								
								"That's more than fine," she replies, giving your hand a comforting squeeze. "Whatever happens, we just do what we're comfortable with, and that'll always be enough." 
								
								Her lips twitch. "In any event, know that I find this very satisfying, and that I am not disappointed that this is where we wound up. At the very least I think we can agree that the only intimacy worth the name is the kind we both enjoy, no?"
								
								That much, at least, is entirely correct. 
							#"There wasn't a deeper meaning to the 'just,' really." 
								"There wasn't a deeper meaning to the 'just,' really." You hadn't been implying that your suggestion was less than any of hers, really. Maybe you can see a sense in which it is, but only one, and probably not even the most important one, presently. 
								
								"Ah, my mistake, then. I'm glad to hear you don't think so." Hekate gives your hand a playful squeeze. 
								
								Her lips twitch. "In any event, know that I find this very satisfying, and that I am not disappointed that this is where we wound up. I'm sure we can agree that the only intimacy worth the name is the kind we both enjoy, no?"
								
								That much is entirely correct. 
							#"What do you mean by more than one type?"
								"What do you mean by more than one type?" You aren't sure you completely grasped what she was saying, given the vagueness of some of her terms. 
								
								"Ah. Nothing too profound or anything. I just meant that certain things could be intimate in more than one way. Like… holding hands could express that I'm your friend, or that I'm romantically involved with you, or both at the same time. It doesn't mean that, when used to express the romantic part, that it's any less so than another form of expression would be. At least, not to me." 
								
								You nod slowly. That makes sense, you suppose. People can do all kinds of things with all kinds of intentions. That doesn't have to affect the meaning of the things [i]you[/i] do. 
								
								Her lips twitch. "In any event, know that I find this very satisfying, and that I am not disappointed that this is where we wound up. I'm sure we can agree that the only intimacy worth the name is the kind we both enjoy, no?"
								
								That much is entirely correct. 
						*page_break
						Her thumb rubs over the back of your hand, tracing the shapes of your knuckles, and Hekate lets out a soft breath, leaning back against the sofa behind both of you. "Either way, this is exactly what I need, right now."
						
						It feels nice, if also a little strange. Like your awareness has narrowed to so few things that everything about them is more apparent to you. The drag of her fingertip, which could in another context be something you easily ignored, seems to take the lion's share of your attention, now. 
						
						But it isn't a focus that comes with any sense of urgency. You don't need to do anything about it. Don't need to act a certain way, or try to think about anything else. You can just… sit here and enjoy it, for a little while. Enjoy talking to Hekate. 
						
						And right now, that feels like everything you want.
						*goto chap3end
		#"I really don't like the idea of kissing, if I'm being honest." 
			*set kissing "dislike"
			"I really don't like the idea of kissing, if I'm being honest." You clear your throat, only a little awkwardly, and shrug. You know she'd rather know. You've never tried it, but you know you don't want to. Even the idea of it just makes you uncomfortable, if you really think about it for more than a couple of seconds. 
			
			"Entirely fair," Hekate says, with a soft huff. "It's such a strange thing if you think about it, isn't it? Putting your mouth to someone else's. I used to be rather disgusted by the thought, myself." 
			
			"What changed your mind?"
			
			She lifts her shoulders, casually letting them fall again. "The way it felt. But you and I are different people, and you seem certain, so let's think about alternatives, hm? What about holding each other?"
			*goto hekate_nokissmenu
		*if (hekate_touch2 = "averse")
			#"You know I don't like touching. This is no different. We're going to need to have a relationship without any of the physical stuff, okay?" 
				*set kissing "dislike"
				*set intimate_touch "averse"
				"You know I don't like touching. This is no different. We're going to need to have a relationship without any of the physical stuff, okay?" You suppose it was a fair thing for her to ask about, because, well… casual touch and intimate touch [i]are[/i] different things. You, however, don't think of them all that differently.
				
				It's been on your mind for a while, that this might be something of a problem. Most people enter into relationships like this expecting [i]some[/i] kind of physical intimacy, but it's not something you can give. 
						
				If she's not going to be able to cope with that, it would be much better to know now.

				Hekate hums, but her expression is thoughtful, you think, and she isn't giving you any sense of disappointment. 

				"All right," she says, nodding slowly. "That's clear now, so I'd like to ask you a separate question. Do you feel any desire for sexual intimacy at all? Or do you desire me in a sexual way? Don't worry about touching for a moment." 
				*goto hekate_acequestion
	*label hekatekissing
	*page_break
	The first sensation that hits you is the [i]warmth[/i] of it, then the softness. Her mouth feels like nothing so much as silk left out in the sun, and you draw in a breath through your nose more sharply than you'd intended. 
	
	*if (hekate_firstkiss)
		You've kissed Hekate before, but there's something a little different about this one. Something a little less cautious on her part, more easily sensual. Slow. 
		
		And then, of course, there's the way it doesn't end at one.
	*if not (hekate_firstkiss)
		You've never kissed her before, so you have no baseline for what it's like. The best way you can describe it is… easy. Not cautious, not reserved, but not pitched or desperate, either. It's sensual. Slow. 
		
		And she doesn't stop at one.
		
	*fake_choice
		#I sink into it, allowing her to guide me. 
			*set passive +1
			You sink into it, allowing her to guide you. Without a doubt, Hekate knows more about kissing than you do, but more than that, she seems to know how this should go. And, as good as it feels, you can't argue that she does, and so you don't try. 

			You press back into the kiss, one hand coming to rest on her shoulder, and you make a small sound of protest when she shifts slightly to catch the corner of your mouth instead. 

			"Still all right?" she murmurs, setting another at the base of your ear. 

			"Yes," you manage, albeit not in a tone of voice that sounds remotely normal. There's a [i]dizzy[/i] feeling that goes with it all, something almost overwhelming, but the little break is enough for you to bring your head above metaphorical water. 
			*page_break
			Then her mouth brushes against the shell of your ear, and the soft touch sends a tingle through the nape of your neck, as much magic as anything else you've ever seen her do.

			You gasp when her teeth pinch lightly at your lobe, and she chuckles, pulling back from the spot to run the pads of her thumbs over your cheekbones, gently caressing your face as your lips meet again. There's nothing urgent about it at all; when her tongue comes to gently brush against the seam of your lips, you find it easy to part them, allowing her in. 
			
			Her fingertips drag lightly over your neck, then your shoulders, then down to where your collarbones are only partly covered by today's tunic.
			
			"Delightful," she whispers against your mouth, and then the contact firms, so neither of you can speak at all. 
		#I bring my hand up to the back of her neck and shift the angle slightly. I don't mind being steered, but I'd like to have some say in how this goes, too. 
			You bring your hand up to the back of her neck and shift the angle slightly. You don't mind being steered, but you'd like to have some say in how this goes, too. Without a doubt, Hekate knows more about kissing than you do, but that's not so important, in the grand scheme of things. It still takes two, and you want to push as well as pull, as it were. 

			You press back into the kiss, using your hand for a bit of leverage, to angle the both of you a little differently. Her mouth tastes very faintly of something spiced, though you can't put your finger on exactly what it is. 

			Before you can decide, she pulls back a little, brow arched playfully. "Still all right?"

			"Was the participation not enough of a clue?" You [i]do[/i] feel a little dizzy, and the line perhaps comes out a touch more breathlessly than you'd intended, but that's fine with you, at the moment. She doesn't sound completely herself either, her voice lower and thinner than you're used to hearing it. 
			*page_break
			"It never hurts to be sure." Her mouth brushes against the shell of your ear, and the soft touch sends a tingle through the nape of your neck, as much magic as anything else you've ever seen her do.

			You gasp when her teeth pinch lightly at your lobe, and she chuckles, pulling back from the spot to run the pads of her thumbs over your cheekbones, gently caressing your face as your lips meet again. There's nothing urgent about it at all; when her tongue comes to gently brush against the seam of your lips, you find it easy to part them, allowing her in, but teasing her tongue with your own. 
			
			Her fingertips drag lightly over your neck, then your shoulders, then down to where your collarbones are only partly covered by today's tunic. Your hand wraps around the nape of her neck, beneath the curtain of her braids, keeping her in the kiss.
			
			"Delightful," she whispers against your mouth, and then the contact firms, so neither of you can speak at all. 
		#I take hold of the front of her tunic, asserting myself firmly in the exchange. 
			*set assertive +1
			You take hold of the front of her tunic, asserting yourself firmly in the exchange. Hekate probably knows more about kissing than you do, but that doesn't matter. What you don't know, you can learn, and what you [i]do[/i] know is that this is how you want things to be. 

			You press back into the kiss, using your grip on the fabric for leverage. Her mouth tastes very faintly of something spiced, though you can't put your finger on exactly what it is. 

			Before you can decide, he pulls back a little, she pulls back a little, brow arched playfully. "Still all right?"

			"Obviously," you reply, pulling her back in unceremoniously. You can feel her smile against your mouth, but there's a soft little noise she makes, too, one that gives you a welling sense of satisfaction.
			*page_break
			She shifts slightly away, and her mouth brushes against the shell of your ear. The soft touch sends a tingle through the nape of your neck, as much magic as anything else you've ever seen her do.

			You hum when her teeth pinch lightly at your lobe, and she chuckles, pulling back from the spot to run the pads of her thumbs over your cheekbones, gently caressing your face as your lips meet again. There's nothing urgent about it at all; when her tongue comes to gently brush against the seam of your lips, you find it easy to part them, taking the lead in the push and pull of lips and tongues. 
			
			Her fingertips drag lightly over your neck, then your shoulders, then down to where your collarbones are only partly covered by today's tunic. Your hand wraps around the nape of her neck, beneath the curtain of her braids, keeping her in the kiss.
			
			"Delightful," she whispers against your mouth, and then the contact firms, so neither of you can speak at all. 
	*page_break
	You lose track of time, a bit, one of many details that doesn't feel like it [i]matters[/i], right now. For as long as you can stand it, it's just you, and Hekate, and the heat between you. 

	And that feels exactly right.
	*goto chap3end
	*label hekate_cuddle
	Once you're properly settled, Hekate releases a deep sigh. "This is good," she murmurs. "Maybe exactly the right thing, right now. Sometimes I think I might actually [i]prefer[/i] this to kissing. Some people say it's 'less intimate' or what have you, but that's nonsense." 
	
	She pauses, and you hum to indicate that you're listening, since she seems to have more to say. 
	
	"Of course, some things can be more than one type of intimate, but I don't really think you can put actions into categories by degree of it, you know?"
	
	*fake_choice
		#"It really is, though, isn't it? Less intimate than kissing?"
			"It really is, though, isn't it? Less intimate than kissing?" You press your lips together. You do think that there is more intimacy to some acts than others. Saying they're all basically on the same level and differ only by type seems a bit… well. You're not really sure how she could think that. 

			"Not to me," she replies with a small shrug. "I think it comes down to how you think about things. It's possible to have sex without any intimacy involved at all. Whereas something as simple as holding hands can be very significant, in the right context. It's not about the act. It's about the way the people involved are approaching it."

			You suppose there's some truth to that, at least, but you're not entirely sure if you're convinced just yet. 

			Perhaps inferring as much, she chuckles. "Well, in any event, know that [i]I[/i] find this very satisfying, and that I am not disappointed that this is where we wound up. At the very least I think we can agree that the only intimacy worth the name is the kind we both enjoy, no?"

			That much, at least, is entirely correct. 
		#"That's a relief to hear. A lot of the things that people think of as 'more,' I'm not really sure about."
			"That's a relief to hear. A lot of the things that people think of as 'more,' I'm not really sure about." Perhaps it's just a lack of familiarity, but you don't particularly need to figure out exactly why that is right now. 

			Hekate, after all, doesn't ask. 

			"That's more than fine," she replies, giving your hand a comforting squeeze. "Whatever happens, we just do what we're comfortable with, and that'll always be enough." 

			Her lips twitch. "In any event, know that I find this very satisfying, and that I am not disappointed that this is where we wound up. At the very least I think we can agree that the only intimacy worth the name is the kind we both enjoy, no?"

			That much, at least, is entirely correct. 
		#"I think I have to agree with you, there." 
			"I think I have to agree with you, there." People can mean all kinds of things with all kinds of actions, and what might be perfunctory for one person, could be intimate but platonic for another, and explicitly romantic or sexual in another context, or whatever. Her way of thinking about it makes perfect sense, to you. 
			
			"Well, good," she replies with a chuckle. "I think that makes us quite likely to be right. In any event, I know that I find this very satisfying, and that I am not disappointed that it's where we wound up. The only intimacy worth the name is the kind we both enjoy, no?"

			That much, too, is entirely correct. 
		#"What do you mean by more than one type?"
			"What do you mean by more than one type?" You aren't sure you completely grasped what she was saying, given the vagueness of some of her terms. 

			"Ah. Nothing too profound or anything. I just meant that certain things could be intimate in more than one way. Like… holding hands could express that I'm your friend, or that I'm romantically involved with you, or both at the same time. It doesn't mean that, when used to express the romantic part, that it's any less so than another form of expression would be. At least, not to me." 

			You nod slowly. That makes sense, you suppose. People can do all kinds of things with all kinds of intentions. That doesn't have to affect the meaning of the things [i]you[/i] do. 

			Her lips twitch. "In any event, know that I find this very satisfying, and that I am not disappointed that this is where we wound up. I'm sure we can agree that the only intimacy worth the name is the kind we both enjoy, no?"

			That much is entirely correct. 
	*page_break
	Her thumb rubs small circles over your tunic, near your waistline, and Hekate lets out a soft breath. You can feel her relax against you. "In any case, this is exactly what I need, right now."

	It feels nice, if also a little strange. Like your awareness has narrowed to so few things that everything about them is more apparent to you. The drag of her fingertip, which could in another context be something you easily ignored, seems to take the lion's share of your attention, now. 

	But it isn't a focus that comes with any sense of urgency. You don't need to do anything about it. Don't need to act a certain way, or try to think about anything else. You can just… sit here and enjoy it, for a little while. Enjoy talking to Hekate. 

	And right now, that feels like everything you want.
	*goto chap3end

*label chap3hermes
A few days later, Demeter has returned to Olympus. You're not sure exactly when or if she'll be back, but for now at least, she has obviously seen Iasion and confirmed his identity. What difference it will make in the long run, you can't be sure, but some things are surely worth doing even if they don't change how the world works. 

You wonder, for a moment, what you would do in her position, but the thought is easily enough brushed aside. 
*page_break
The descent back into the Underworld is always an interesting experience, one that acts upon all your senses. You don't mind it, exactly, that quiet and dark, perhaps because you've had so much time to acclimate to it that it's now what's normal for you. 

By contrast, the mortal realm is a world that buzzes and flashes, bright and almost overwhelming at times, but perhaps you've learned to enjoy that as well. At least, it's always nice to go flying with Hermes, which is exactly what you've spent the afternoon doing. 

You're not sure exactly what possessed him to ask you today in particular, but apparently he had the time, and so did you, and that was all the reason you really needed to accept. Even now, windswept and a little bit exhausted, you can still feel the distinct tingle on your skin that comes with adrenaline, and from the broad grin on Hermes's face, he feels much the same. 

As you cross the threshold, he lets out a short but heavy breath, his shoulders relaxing. "That's a good feeling," he murmurs, stretching his arms over his head, then dropping them to roll his shoulders. "Hungry? I could really go for something to eat." 

*if (reserved > forthright)
	You nod; you could definitely eat as well, after all that. 
*if not (reserved > forthright)
	"Yeah, I could eat, too, after all that."

It's a bit late; you've no doubt missed the regular dinnertime already, so the two of you make your way to the kitchen instead, looking to see what you might be able to find in cupboards or cold storage. You're not sure if Hermes can cook, but it shouldn't be too hard to at least throw together something light. Bread, cheese, fruit, that sort of thing. 
*page_break
The kitchen is darkened, but the crystalline sconces on the wall and overhead light a bit when the two of you step in, revealing a clean room devoid of activity—but there's also a large tray on one of the counters, covered over with what looks like a solid black dome of some sort. Magic, presumably. 

"This must be for us," Hermes somehow concludes, moving over to the spot and tapping the dome lightly with his fingertips. He grins as doing so reveals a small spread of dishes, a few of them with steam still curling from the food inside. 

*fake_choice
	#"How is it still hot? It looks like no one's been here for a while."
		"How is it still hot? It looks like no one's been here for a while." The room certainly shows no sign of recent habitation; everything is clean, dry, and in its place. 
		
		"Magic, of course," Hermes says with a little grin. "His Deathliness can do strange things with time, now and then, so it looks like he put this in stasis so everything would stay fresh." He picks up a small piece of paper from the tray, huffs softly, and passes it to you.
	#"Are you sure this is meant for us?"
		"Are you sure this is meant for us?" It's not obvious that it would be so, after all. It could very easily be for a staff member's meal, or even someone else's late dinner that they actually ordered. 
		
		"Of course it is," Hermes replies with a grin. "Who else would it be for? If someone else had ordered it, it'd have been teleported to them already." He picks up a small piece of paper from the tray, huffs softly, and passes it to you.
	#"Huh. That's convenient."
		"Huh. That's convenient." You have little doubt the servings were meant for the two of you, even if there are no obvious indicators of as much. The kitchen surfaces can teleport food, so if it were for someone else, it would have been moved to them already. 
		
		"Right?" Hermes grins a little. "His Deathliness can do strange things with time, now and then, so it looks like he put this in stasis so everything would stay fresh." He picks up a small piece of paper from the tray, huffs softly, and passes it to you.
	#I peer more closely at the earthenware, checking what's inside.
		You peer more closely at the earthenware, checking what's inside. It's mostly dinner staples, as you'd expect, but there's also some kind of nut-based cake inside, by the loks, and a small bowl of honey to drizzle over it. 
		
		"Convenient, right?" Hermes asks, grinning a little. "His Deathliness can do strange things with time, now and then, so it looks like he put this in stasis so everything would stay fresh." He picks up a small piece of paper from the tray, huffs softly, and passes it to you.
*page_break
[i]Dear ${name} and Hermes,[/i]

[i]Dad and I asked the kitchen to set this aside for you. Except the cake. We made it, so I hope it tastes good to you. You've both had hard things happening lately, and cake is nice when things are hard. It's also nice when they're easy, though, so I'm not sure if that part is really important.[/i]

[i]Anyway, I hope the hard things get easier.[/i]

[i]-Makaria[/i]

*fake_choice
	#"Ah, they didn't have to do something like that."
		*set selfless +1
		"Ah, they didn't have to do something like that." It was kind, of course, but it's still a little odd to you that anyone would put in that kind of effort for something so small—particularly when it isn't their job or anything. 
		
		"Of course they didn't," Hermes says, gripping the tray with both hands and picking it up. "It's just the kind of people they are. Let's go eat in mine, okay?" 
		
		He's already moving off, so you fall in behind him easily enough. You know [i]where[/i] his room is, but you've never been inside for any length of time, before. You get the impression he's not in it much more often than that, either. 
	#"Cake [i]is[/i] nice when things are hard. I'm looking forward to this."
		*set selfcaring +1
		"Cake [i]is[/i] nice when things are hard. I'm looking forward to this." It was kind of them to do, and you can accept the gesture without much fuss. After all, you have the feeling Makaria would have enjoyed the baking, and Hades would have enjoyed doing something with her, so it's not like you've put them out.
		
		"Me too," Hermes says, gripping the tray with both hands and picking it up. "I've had this one before; it's great. Let's go eat in mine, okay?" 
		
		He's already moving off, so you fall in behind him easily enough. You know [i]where[/i] his room is, but you've never been inside for any length of time, before. You get the impression he's not in it much more often than that, either. 
	#"I hope this wasn't an inconvenience for them."
		*set selfless +1
		"I hope this wasn't an inconvenience for them." It was kind, of course, but you do worry about being a burden on the others, and here it seems they sort of… went out of their way. 
		
		"Of course it wasn't," Hermes says, gripping the tray with both hands and picking it up. "It's just the kind of people they are. Let's go eat in mine, okay?" 
		
		He's already moving off, so you fall in behind him easily enough. You know [i]where[/i] his room is, but you've never been inside for any length of time, before. You get the impression he's not in it much more often than that, either. 
	#"This was good of them. It's nice to have friends, isn't it?"
		*set selfcaring +1
		"This was good of them. It's nice to have friends, isn't it?" People to rely on, even for the little things like this. You suppose you could be worried about having put them out instead, but you aren't. After all, you have the feeling Makaria would have enjoyed the baking, and Hades would have enjoyed doing something with her, so it's not like you've put them out.
		
		"It really is," Hermes says, gripping the tray with both hands and picking it up. "I've had this one before; it's great. Let's go eat in mine, okay?" 
		
		He's already moving off, so you fall in behind him easily enough. You know [i]where[/i] his room is, but you've never been inside for any length of time, before. You get the impression he's not in it much more often than that, either.  
*page_break
You wouldn't necessarily call it messy, but he does seem to have accumulated an unusual number of [i]things[/i] compared to most people, at least in this front room. The walls are lined with shelves, which display about twenty percent books or scrolls along the bottom and the rest varying objects, from pieces of art like statuettes or small ceramic works, to hand tools you can't guess the use for, to jars with unusual plants suspended in resin. 

More than anything, though, what's always striking is the sheer number of musical instruments he has, some of them familiar and others presumably from far-flung parts of the mortal realm. It's a joyful sort of clutter, and one where everything still has its own respected place, but clutter nonetheless. 

Almost in contrast with the edges of the room, the center is occupied by an arrangement of couches large enough to host several guests, each draped in pillows and blankets with all kinds of color in the threads. It's almost ostentatious in its comfort, and as you settle on one of the couches, you do have to concede that it manages to [i]be[/i] very comfortable, indeed. 

*fake_choice
	#"You should invite us all in here, more often. I think it might even be cozier than the common room." 
		"You should invite us all in here, more often. I think it might even be cozier than the common room." You offer a smile across to him, as he settles the tray down between you, and he lifts a brow. 
		
		"Well, maybe, but it's also nice to have somewhere to go that's a little [i]less[/i] equally for everyone," he points out with a shrug. "Even I like privacy sometimes." 
		
		"Sure, but I wasn't suggesting you actually make it a common room. It just seems like a bit of  a waste to have a place this comfortable that hardly gets used." You reach forward to begin filling your plate from the smaller dishes. 
		
		Hermes waits for you to finish before he does the same. "I guess that's a fair point. I just don't think it's [i]quite[/i] big enough for everyone. If I were going to throw a party or something, I'd want to invite everybody." 
	#"Can I ask where all your stuff came from?"
		"Can I ask where all your stuff came from?" You offer a smile across to him, as he settles the tray down between you, and he lifts a brow. 
		
		"Well, definitely not all the same place," he points out with a shrug. "So it's a lot of partial answers rather than one big one." 
		
		"But basically all of this is from the mortal realm somewhere, right? I know it's a big place, but that's still a useful answer, in a way." You reach forward to begin filling your plate from the smaller dishes. 
		
		Hermes waits for you to finish before he does the same. "Sure, fair enough. And yes—almost everything in here is from somewhere in the mortal world. Some of them are gifts, or things people left at shrines, but most of them I just went somewhere and paid for because I liked them."
	#"Do you know how to play all these instruments?"
		"Do you know how to play all these instruments?" You lift your brow at him as he settles the tray on the table between you. 
		
		"Most of them," he replies with a shrug. "Definitely not all just yet. But I'm aiming to get there at some point. Trouble is, humans keep inventing new ones." 
		
		"Trouble? That sounds like something you'd love." You reach forward to begin filling your plate from the smaller dishes. 
		
		Hermes waits for you to finish before he does the same, flashing you a smile. "Well… yes. 'Trouble' wasn't [i]precisely[/i] the sentiment I was trying to reach. It [i]is[/i] a good thing. And I do enjoy learning new ones." 
	#"Thanks for inviting me, Hermes."
		"Thanks for inviting me, Hermes." You offer a smile across to him, as he settles the tray down between you, and he lifts a brow. 
		
		"I'm not sure it's anything that particularly deserves thanks, but you're welcome," he replies with a shrug. "It's nice to have someone else in here, in a way. It's not really big enough for everyone, and sometimes I feel like I'd like to keep it a bit more for [i]me[/i], but I think having you here is the right medium." 
		
		"It does sort of look like it's caught between something just for you and something where people would congregate." Something about the shelving display seems like he did it just for himself, whereas the part of the room you now occupy is definitely designed for multiple people. You reach forward to begin filling your plate from the smaller dishes. 
		
		Hermes waits for you to finish before he does the same, flashing you a smile. "I am full of contradictions, Sunshine."
*page_break
As hungry as you are, you're glad you manage to get a few satisfying bites in before Hermes resumes the conversation. You're working your way through a bowl of lentil soup when he sits back a little, tearing a chunk off his bread and using it to spoon up another bite. 

"Stop me if you're tired of talking about this, but I figured I'd ask you how things are going with the folks. Demeter left, so… how are you feeling about it all?"

It's not an unexpected question, obviously. You'd handled all of that essentially on your own, and you have no doubt plenty of people are concerned with how it went. 

*fake_choice
	#"Maybe this is selfish, but I'm really ready for things to be quiet again."
		"Maybe this is selfish, but I'm really ready for things to be quiet again." You can't say you begrudge anyone anything, exactly, but all of this has been quite disturbing to your ordinary routine. That's not [i]unacceptable[/i], but it's been exhausting, and you really need some time to not have to think about things as personally significant—and fraught—as your relationships to your parents. 
		
		The fact that Demeter has left for now is certainly helping with that. 
		
		"I don't think that's—well, maybe some people would call it selfish, but I think some of that is good for you, now and then. If you don't set aside some of your time for yourself, you're not going to get it, you know?"
		
		"I know. Hopefully now that things have slowed down, I'll have more of that." 
	*if not (iasionstatus = "cutoff")
		#"It's confusing, and often difficult, but I'm glad for the chance to build and repair my relationships."
			"It's confusing, and often difficult, but I'm glad for the chance to build and repair my relationships." 
		
			*if (demeterstatus = "open")
				Not that you necessarily think either of them need much repairing, on your side. You need to build one with Iasion, but while you have had the occasional disagreement with your mother, you don't consider that relationship one that needs a fix. 

				Theirs, though, is another matter, you're sure. 
			*if not (demeterstatus = "open")
				And there's certainly a relationship to repair, as well as a relationship to build. Oddly enough, you think your mother's being here was a step in the right direction, even if
				*if (demeter_sequel_1 = false)
					you didn't go to see her. It means you know that she cared enough to show up, and also that she respected your boundaries by not seeking you out against your will. Maybe there's a chance all of this ends well.
				*if (demeter_sequel_1)
					you hadn't explicitly given her permission to visit you. After all, it showed that she cares enough about Iasion to come and visit him, and she didn't seek you out against your will—you went to her. Maybe there's a chance all of this ends well.

			"Glad to hear it. She might be back, just so you know. I don't think His Deathliness is going to keep her out when the person she loves still remembers her. But I guess that's a good thing all around, if this is how you're handling things." 

			"I'll consider it a positive, yes."
	*if not (iasionstatus = "cutoff")
		#"I think I'm enjoying getting to know Iasion, in spite of everything. I'd prefer to do so without Demeter's intervention, though."
			"I think I'm enjoying getting to know Iasion, in spite of everything. I'd prefer to do so without Demeter's intervention, though."
			
			*if (demeterstatus = "open")
				It's not like you don't want your mother around at all, of course; it's just that your relationship with him and yours are different entities, and you don't necessarily want them blending together too much, especially at this fragile, early stage of things. 
			*if not (demeterstatus = "open")
				You'd have preferred not to need to handle your mother or anything to do with her until you were ready—if you're ever ready. But this complicates things. You can hardly expect her not to see your father at all, so you're left trying to navigate the situation as well as you can.
				
			Hermes makes an expression you'd probably call a 'sympathetic grimace,' then huffs. "I don't envy your situation, honestly. Though I may have some idea what it's like." 
			
			"Well, I'll manage somehow. I usually do."
	*if not (demeterstatus = "cutoff")
		#"I don't think I'll be spending much time with Iasion, if I can avoid it, but I suppose mother and I are getting along well enough."
			"I don't think I'll be spending much time with Iasion, if I can avoid it, but I suppose mother and I are getting along well enough."
			
			*if (iasionstatus = "cutoff")
				You'd made the decision not to pursue that relationship in any capacity, given the circumstances and your own emotional needs.
			*if not (iasionstatus = "cutoff")
				You'd made some attempt at getting to know him, but you just don't think it makes sense to go any further than you have. You know what you need to know about him, and… 'he,' the person with memories that are at all relevant to you, may not be around much longer.  
			
			*if (demeterstatus = "open")
				You and your mother have [i]always[/i] gotten along well enough, you suppose, so the news is more or less that there is no news. 
			*if not (demeterstatus = "open")
				As for Demeter, well. That was a bit of a surprise, but you can respect that she didn't seek you out against your will, even if she came here without your explicit permission. That means something, considering what your biggest problems with how she does things have always been. 
			
			"Well, the part about Lady Demeter is good news, I suppose," Hermes replies with a huff. "Well, all of it's good news, if it's what you want to be doing."
			
			"It is. I've had enough time to consider it by now."
	*if not (iasionstatus = "cutoff")
		#"It's exciting, of course! It feels like I'm... I don't know if 'repairing' my family is the right word, but things are developing in a way I'm really pleased with."
			"It's exciting, of course! It feels like I'm... I don't know if 'repairing' my family is the right word, but things are developing in a way I'm really pleased with."
			
			*if (demeterstatus = "open")
				You do need to build a relationship with Iasion, but while you have had the occasional disagreement with your mother, you don't consider that one something that needs a fix. 

				Theirs, though, is another matter, you're sure. 
			*if not (demeterstatus = "open")
				Maybe repair is at least partly appropriate to one of the two relationships you're involved in, whereas 'build' makes more sense for the other. Oddly enough, you think your mother's being here was a step in the right direction, even if
				*if (demeter_sequel_1 = false)
					you didn't go to see her. It means you know that she cared enough to show up, and also that she respected your boundaries by not seeking you out against your will. Maybe there's a chance all of this ends well.
				*if (demeter_sequel_1)
					you hadn't explicitly given her permission to visit you. After all, it showed that she cares enough about Iasion to come and visit him, and she didn't seek you out against your will—you went to her. Maybe there's a chance all of this ends well.

			"Glad to hear it. She might be back, just so you know. I don't think His Deathliness is going to keep her out when the person she loves still remembers her. But I guess that's a good thing all around, if this is how you're handling things." 

			"I'll consider it a positive, yes."
*page_break
"Well, as long as you're taking care of yourself, I've got nothing to complain about," he replies, offering you a small grin.

It occurs to you that Hekate recently mentioned something about his own mother, Maia. You don't know the details of her situation, but apparently she's on Olympus, and seen in public even less often than you were when you were growing up.

*fake_choice
	#"What about your mother? Is anything new in her life?"
		"What about your mother? Is anything new in her life?" 
		
		Hermes shrugs, but the way his lips purse, paling slightly in their color, makes you think he's not so indifferent as the motion would ordinarily suggest. 
		
		"I don't know if I'd say there's anything [i]new[/i], no. But then I guess I wouldn't know that for sure, because she never actually talks to me about anything." 
	#"I... don't know much about Lady Maia's circumstances, now that I think on it."
		"I... don't know much about Lady Maia's circumstances, now that I think on it."
		
		Hermes shrugs, but the way his lips purse, paling slightly in their color, makes you think he's not so indifferent as the motion would ordinarily suggest. 
		
		"Not many people do. Not even me, exactly, because she never actually talks to me about anything."
	#"This might be uncomfortable for me to ask about, but... I've never heard you talk much about your mother, Hermes. Is there a reason for that?"
		"This might be uncomfortable for me to ask about, but... I've never heard you talk much about your mother, Hermes. Is there a reason for that?"
		
		Hermes shrugs, but the way his lips purse, paling slightly in their color, makes you think he's not so indifferent as the motion would ordinarily suggest. 
		
		"I don't know. Because it's not useful to talk about, I guess. She doesn't really talk to [i]me[/i] about anything, so it's not like I've ever had much to share if I wanted to."
*page_break
He blows out a long breath, some of it ruffling the curls sitting on his brow, then shakes his head. "You probably know she's on Olympus, but she hardly ever goes anywhere. Mostly because it's uncomfortable, I can only guess." 

"Uncomfortable? Why?"

There are general reasons someone might be uncomfortable on Olympus, of course, but concerns about how loud or busy it is, for example, wouldn't apply to the [i]whole[/i] thing. Besides, somehow you don't think he's talking about something like that. 

He eats a little more before he answers, brows faintly knit. "Well, it [i]would[/i] be, you know? It's never a great feeling to be the king's 'mistress' in a place where most people respect and love the Queen. People don't talk to her at social events. Well, except Hestia. I'm sure Demeter would, if she didn't have her own problems to handle at those types of things, but she [i]does[/i], so… my mother has one friend in the world, and a lot more enemies."

He shakes his head. "It's hurt her. I know it has. I don't think she's well, but she never talks much about herself."

*fake_choice
	#"I'm sorry, Hermes. That sounds really difficult to handle."
		*set warm +1
		"I'm sorry, Hermes. That sounds really difficult to handle."
		
		He runs a hand back over his hair, most of which promptly bounces back into place. "Well, it's not like I've been the best son, either, I'm sure. Who knows if I've asked enough questions, or the right ones. Or whether I've just always given up too early. It's something I've been trying to work on, but… I guess not very well." 
		
		"I'm not sure something like that comes down to the right number or type of questions."
	#"Do you think she'd do better here?"
		*set forthright +1
		"Do you think she'd do better here?"
		
		He runs a hand back over his hair, most of which promptly bounces back into place. "Yeah," he replies slowly. "She probably would. But I can't possibly broach that topic with her, yet. She'll just ignore me and say that everything on Olympus is fine. I guess I've never gotten her to trust me. Never asked enough questions. Or the right ones. Or maybe I've just always given up too early. It's something I've been trying to work on, but… I guess not very well." 
		
		"I'm not sure something like that comes down to the right number or type of questions."
	#"That's unfortunate—I doubt there's anything you can do if she's not even willing to talk about it."
		*set cold +1
		"That's unfortunate—I doubt there's anything you can do if she's not even willing to talk about it."
		
		He runs a hand back over his hair, most of which promptly bounces back into place. "Yeah," he replies slowly. "But there's got to be some way to get her to want to, right? I guess I've never gotten her to trust me. Never asked enough questions. Or the right ones. Or maybe I've just always given up too early. It's something I've been trying to work on, but… I guess not very well." 
		
		"I'm not sure something like that comes down to the right number or type of questions."
	#I frown sympathetically. It seems like it's really bothering him.
		*set reserved +1
		You frown sympathetically. It seems like it's really bothering him. 
		
		He runs a hand back over his hair, most of which promptly bounces back into place. "Well, it's not like I've been the best son, either, I'm sure. Who knows if I've asked enough questions, or the right ones. Or whether I've just always given up too early. It's something I've been trying to work on, but… I guess not very well." 
		
		"I'm not sure something like that comes down to the right questions," you point out quietly.
*page_break
He expels a breath. "Yeah, I know. But I don't know what it does come down to, either." 

Looking across at you, he studies your face for a moment, then straightens a little. "But… it's because of you, you know. That I'm trying. You took initiative in your life, and your relationship with Demeter. It's different now, than it used to be,
*if (demeterstatus = "open")
	even if the changes are subtle. 
*if (demeterstatus != "open")
	even if it's not in the best place right now. 
I just sort of figured… if Sunshine was doing it, what excuse do I have not to try?" 

He clears his throat, the hand on his head dropping back to his side. "Clearly I'm not doing all that well at it, though. I can't figure out how to get her to… engage with me. Like you've gotten Demeter to do with you. Sort of."

*if (demeterstatus = "cutoff")
	You lift an eyebrow, a bit skeptical. After all, the current defining feature of your relationship with Demeter is that there isn't one. 
	
	"You know what I mean," he grumbles. "She's respecting your boundaries when she wouldn't have, before. That's already much better."

*fake_choice
	#"I think that's just Demeter, though. I haven't done anything special."
		"I think that's just Demeter, though. I haven't done anything special." There are a lot of things you could say about your mother, not all of them always positive, but she doesn't generally have trouble communicating. It's sort of inherent to her job, for one, and she carries it over well enough to her personal life, you suppose. 
		
		At the very least, that's never been an issue between you on her end. If anything, the person who has needed to learn to assert themselves more is [i]you[/i]. And you don't think your specific difficulties with all that have anything in common with… whatever Hermes's mother might be dealing with. 
		
		Hermes pushes a breath out of his nose, "That's… fair, I guess. I was just hoping maybe you had some insight into how to… I don't even know. I say this like getting her to talk to me will solve everything, but I'm not even sure that's true." 
		
		You press your lips together. You don't want to offer him [i]nothing[/i]. "Well… all I can really say is that it might take more than one try. Not just for you, but for her. Just because she isn't talking to you doesn't necessarily mean she doesn't want to. It might just be difficult."
	#"I don't know how to encourage communication except to advise you to do more of it yourself."
		"I don't know how to encourage communication except to advise you to do more of it yourself." You shrug, a bit helplessly. 
		*if (tag_intuitive)
			It's a two-way thing, after all, and you know that Hermes can close himself off to people even while seeming to be perfectly talkative. It's a peculiar skill, but there are lots of ways to mask a person's true thoughts, and 'keeping things light' or 'brushing off the serious questions' are among them.
		*if not (tag_intuitive)
			You can't guess how things must go between them, but communication in its true form involves both people. Hermes can't control what his mother does, but he can control his side of things. 
		
		You don't know enough about Maia to say whether him offering more of himself will draw the same out of her, but it seems like the first thing to try, at least. 
		
		Hermes pushes a soft breath out of his nose. "I… yeah. That's probably something I needed to hear. I'm not sure I do a good enough job at being really honest with her. But it's… I don't want to give her even more burdens by talking about my problems, you know?"
		
		You press your lips together thoughtfully. "Well, you don't necessarily have to start with your problems, if you're worried about that. Talk to her about things you sincerely like, or things that are neutral. But also, I don't think the people who care about you would find knowing about your struggles to be a burden."
	#"I suppose... my only advice would be to be patient, and present when you can."
		"I suppose... my only advice would be to be patient, and present when you can." You frown. It doesn't sound all that certain, as advice goes, but it's not like this is the kind of thing it's easy to be certain about. You don't know Maia, or much about what's caused her situation, or how she really feels. All you can do is look at this from the side of Hermes, whom you [i]do[/i] know, and take your best guess. 
		
		And you know he isn't the most patient of people. You don't know whether him waiting and being around more often will draw anything out of her, but it seems like this first thing to try, at least. 
		
		Hermes pushes a soft breath out of his nose. "I… yeah. That's probably something I needed to hear. It's just really hard to be around someone who won't ever say what she's thinking, or be honest with me. Maybe I get too frustrated, too fast. Maybe I don't see her as often as I should, either."
		
		You press your lips together thoughtfully. "Well, I can't guarantee it'll make a difference, but it might help, at least. Some people just need time."
	#"I don't think I have any insight into a situation like yours. I'm sorry." 
		"I don't think I have any insight into a situation like yours. I'm sorry." You shake your head. You can tell this is important to him, and it would be nice if you could offer something that would help, but you don't have enough information to even begin to guess at it. Moreover, you don't want to irresponsibly offer anything that might have the opposite effect. 
		
		Hermes pushes a soft breath out of his nose. 		Hermes pushes a breath out of his nose, "That's… fair, I guess. I was just hoping maybe you had some insight into how to… I don't even know. I say this like getting her to talk to me will solve everything, but I'm not even sure that's true." 
		
		You press your lips together. "I think the person most likely to have the answer to this problem, if there is one, is you," you point out. "You know her better than I do. Maybe better than anyone else does, given the way you've described her situation."
*page_break
He considers your words for a few long moments, and nods. "I'll keep that in mind. I owe her a better job than I've done being a son so far, but maybe for once I should just think about it for a while, instead of jumping into things headfirst."
*page_break
*if (hermes_confessiondeferred)
	You lapse into silence for a little while, polishing off dinner and moving on to dessert, the cake with nuts in it. You've each been given quite a thick slice, and you're breaking off a chunk to try when Hermes clears his throat softly. 
	
	"Speaking of things I've been trying to do slowly and carefully," he says, his tone a little wry. "I've been trying to… give you time to decide about things, and all that, but it's sort of eating at me by now, you know?"
	
	*if (tag_unintuitive)
		It takes you several seconds of staring blankly at him to recognize what he must be talking about.
	*if not (tag_unintuitive)
		You recognize what he's talking about immediately, of course. 
	
	He'd admitted to romantic interest in you, shortly after your return from the trial on Olympus. You'd demurred at the time, so as to have longer to think about it, and it [i]has[/i] been a couple of months since then. Plenty of time for your daily life to stabilize, and surely enough time in which to think of some kind of answer for him.
	
	You can only suppose the abruptness with which he asked is a symptom of that patience being strained to its edges.
	
	*fake_choice
		#@{convotoggle [♥]|} "Thanks for waiting, Hermes. I'm ready to try a relationship with you."
			*set hermes_romance true
			*set overt  +1
			"Thanks for waiting, Hermes. I'm ready to try a relationship with you." It did take you the extra time to be sure, but now that you're settled and more stable, you recognize that your inclinations are nudging you in this direction. You're not exactly sure how it will go, or how things will end up, but for now, you're inclined to try it and see what happens.
			
			"Perfect." Hermes's eyes light up. "There's other things to figure out, obviously, but I hope you'll forgive me for my entirely predictable reaction to this information." 
			
			"Which is?" you lift an eyebrow, kind of curious as to what he might be about to do.
			*goto hermes_intimatesolo
		#@{convotoggle [♥]|} "I... yes. My answer is yes. I want to be with you, if you still want that, too." 
			*set hermes_romance true
			*set subtle +1
			"I... yes. My answer is yes. I want to be with you, if you still want that, too."  It did take you the extra time to be sure, but now that you're settled and more stable, you recognize that your inclinations are nudging you in this direction. You're not exactly sure how it will go, or how things will end up, but for now, you're inclined to try it and see what happens.
			
			"Perfect." Hermes's eyes light up. "There's other things to figure out, obviously, but I hope you'll forgive me for my entirely predictable reaction to this information." 
			
			"Uh, what's that?" you ask, blinking slowly.
			*goto hermes_intimatesolo
		#"I'm sorry, Hermes. I think we're better off as friends and nothing else."
			*set hermes_justfriends true
			*set hermes_rejected true
			"I'm sorry, Hermes. I think we're better off as friends and nothing else."
			
			"…Ah. Fair enough, then." He shrugs, offering you a wry little smile with a hint of sheepishness to it. "More fool I, for supposing you just needed time to realize you wanted to be with me." 
			
			"I'm—"
			
			He shakes his head. "You don't need to apologize, Sunshine. Not for this. No one can force their feelings, and I wouldn't want you to try."
			*page_break
			Hermes expels a short breath, offering a wry smile. "Anyway, as much as I've appreciated getting you all to myself today, we should probably look towards wrapping things up, huh? You need to sleep, and all that. Should we get these dishes back to the kitchen?"
	
			*if (tag_unintuitive)
				At first, you're not sure what to make of the transition, but after a long moment's pause to think about it, you realize he's probably reached his capacity for talking about personal things for one day. And he's not wrong that you'll need to sleep soon, so you nod, reaching forward to begin collecting some of the plates and bowls. 
			*if not (tag_unintuitive)
				It's obvious that he's probably reached his capacity for talking about personal things for one day, particularly after an answer like that. And he's not wrong that you'll need to sleep soon, so you nod, reaching forward to begin collecting some of the plates and bowls. 

			It's been a good day, minor awkwardness aside, and you don't need it to be anything more than that. 
			*goto chap3end
		#"I know this isn't ideal, but I'm just not ready to decide yet. I'm sorry."
			*set hermes_deferred2 true
			"I know this isn't ideal, but I'm just not ready to decide yet. I'm sorry." You press your lips together. You just don't [i]know[/i]. How are you meant to feel when you want to be with someone? Is it simple attraction, that and some kind of emotional connection? Should those emotions feel distinct from being close friends? 
			
			It's all a jumble in your head, and you just can't bring yourself to say anything decisive until you know more. 
			
			Hermes winces, a tad exaggerated. "Ah, my ego. It's being deflated as we speak. Here I thought you just needed a little time to remember why I'm great." His tone is jocular, entirely unserious, but there's something about his eyes that doesn't quite carry the humor. 
			
			"I'm—"
			
			He shakes his head. "You don't need to apologize, Sunshine. Not for this. No one can force their feelings, and I wouldn't want you to try."
			*page_break
			Hermes expels a short breath, offering a wry smile. "Anyway, as much as I've appreciated getting you all to myself today, we should probably look towards wrapping things up, huh? You need to sleep, and all that. Should we get these dishes back to the kitchen?"
	
			*if (tag_unintuitive)
				At first, you're not sure what to make of the transition, but after a long moment's pause to think about it, you realize he's probably reached his capacity for talking about personal things for one day. And he's not wrong that you'll need to sleep soon, so you nod, reaching forward to begin collecting some of the plates and bowls. 
			*if not (tag_unintuitive)
				It's obvious that he's probably reached his capacity for talking about personal things for one day, particularly after an answer like that. And he's not wrong that you'll need to sleep soon, so you nod, reaching forward to begin collecting some of the plates and bowls. 

			It's been a good day, minor awkwardness aside, and you don't need it to be anything more than that. 
			*goto chap3end
*elseif (hermes_mutualconfess)
	You lapse into silence for a little while, polishing off dinner and moving on to dessert, the cake with nuts in it. You've each been given quite a thick slice, and you're breaking off a chunk to try when Hermes clears his throat softly. 
	
	*label hermes_intimatesolo
	"Let's get a little closer, shall we?" He grins, setting down his half-eaten slice of cake and moving over to your side of the table, sitting down next to you.
	*if (hermes_touch2 = "averse")
		He's figured out how close he can be before you begin to feel uncomfortable with the proximity, and he respects that line even now, leaving the right amount of space without seeming to think about it. 
	*if (hermes_touch2 != "averse")
		He sits quite close, not quite touching you but near enough to it that you can feel a little of the heat from his body. 
	
	"I had a question," he continues, once settled. "Since, you know, we're in the sort of relationship where some people do things of an intimate nature, how would you feel about getting a little more intimate, right now?"
	
	*if ((touching = false) and (hermes_touch2 != "averse"))
		The way he leans toward you, bringing your faces closer, is an obvious suggestion about the kind of intimacy he has in mind.
	*if ((touching = false) and (hermes_touch2 = "averse"))
		The way he leans just a little bit towards you, bringing your faces closer, is a clear suggestion about the kind of intimacy he has in mind, but the tone of his voice is cautious. As it obviously would be—this is quite a thing to ask of someone who doesn't respond well to casual touching. 

	*fake_choice
		#@{convotoggle [♥]|} "I've been waiting for you to ask something like that."
			*set intimate_touch "fine"
			*set overt +1
			"I've been waiting for you to ask something like that." You smile, swaying a little closer to him, in turn. 

			*if (hermes_touch2 = "averse")
				You know you've surprised him, saying something like that. 

				"I thought… you didn't like touching, though? The ask was sort of a… just in case it was different enough, with this kind." 

				"Well, it is," you reply with a shrug. Casual touching for no reason isn't something you like, but intimacy like this is deliberate. Planned, if not necessarily in advance, then at least a few seconds beforehand. You know what you're getting into, and you [i]do[/i] want to be intimate in this way. You can put aside your response to touch long enough to make it work. 

			"Well, then." Hermes's smile widens, looking almost silly for just a moment, before his fingers move to tilt your chin so he can brush his lips lightly over yours. 
			*goto hermeskissing
		#@{convotoggle [♥]|} "I'd... love to."
			*set intimate_touch "fine"
			*set subtle +1
			"I'd… love to." You smile with a hint of sheepishness, swaying a little closer to him, in turn.

			*if (hermes_touch2 = "averse")
				You know you've surprised him, saying something like that. 

				"I thought… you didn't like touching, though? The ask was sort of a… just in case it was different enough, with this kind." 

				"Well, it is," you reply with a shrug. Casual touching for no reason isn't something you like, but intimacy like this is deliberate. Planned, if not necessarily in advance, then at least a few seconds beforehand. You know what you're getting into, and you [i]do[/i] want to be intimate in this way. You can put aside your response to touch long enough to make it work. 

			"Well, then." Hermes's smile widens, looking almost silly for just a moment, before his fingers move to tilt your chin so he can brush his lips lightly over yours. 
			*goto hermeskissing
		*if not (hermes_mutualconfess)
			#"Hold on. I know we're starting that kind of relationship, but this is a bit too sudden for me."
				*set intimate_touch "fine"
				"Hold on. I know we're starting that kind of relationship, but this is a bit too sudden for me." He's right that people [i]do[/i] those sorts of things, and you're not even against the idea in theory, but you still need to process the change in things before you can consider acting in a new way. 
				
				He chuckles, leaning back a little to his original position. 
				*if (hermes_touch2 = "averse")
					"Honestly, perfectly understandable. I thought you weren't going to go for it at [i]all[/i], considering how you feel about being touched in other situations. Is it really different, like this?"
					
					"It is," you reply with a shrug. Casual touching for no reason isn't something you like, but intimacy like this is deliberate. Planned, if not necessarily in advance, then at least a few seconds beforehand. You know what you're getting into, and you [i]do[/i] want to be intimate in this way. You can put aside your response to touch long enough to make it work. 
					
					Just not quite yet. 
				*if not (hermes_touch2 = "averse")
					"Fair enough. I've been wanting to do something like this for a [i]while[/i], but I can wait longer. Easily."
				
				He pauses a moment, extending his hand towards you. "Maybe something like this would be all right, though?" 
				
				It's immediately somehow unexpected that he should offer to hold your hand, but that [i]is[/i] something you can do. 
				*if (hermes_touch2 = "averse")
					It's intimate enough, in this context, that it doesn't feel too offhand or casual, and there's plenty of warning, so you nod. 
				
				Lips twitching, he folds his hand over your own.
				*goto hermes_holdhands
		#"I really don't like kissing, if I'm being honest."
			*set kissing "dislike"
			"I really don't like kissing, if I'm being honest." You clear your throat, only a little awkwardly, and shrug. You know he'd rather know. You've tried it, once or twice, and it's never been something you enjoyed. Even the idea of it just makes you uncomfortable, if you really think about it for more than a couple of seconds. 

			Hermes blinks, apparently a bit surprised, then nods. "Okay. That's a bit of a shame, because I love it. But it's not that important, really." He mirrors your shrug with one of his own, straightening his posture so he's no longer so close to your face. "We can do something else. Cuddling, maybe?"

			*label hermes_nokissmenu2
			*if (hermes_touch2 = "averse")
				His brows knit. "Ah, but, that seems like you wouldn't enjoy it, either. Too much touching, right? Is there a better idea?"

				*fake_choice
					#"I just can't do touching. Not in any form. So this is going to need to be a relationship without any of the physical stuff. Okay?" 
						*set intimate_touch "averse"
						"I just can't do touching. Not in any form. So this is going to need to be a relationship without any of the physical stuff. Okay?" It's… you know most people expect things out of relationships that go beyond the intimacy of deep conversations and trust and going through life together, but those dimensions aren't anything you can provide. 

						Hermes frowns, but rather than upset, he looks thoughtful. "Okay," he says, with a small nod. "I knew that was a possibility. And now I know it's true. No touching of any kind." 

						His eyes narrow, and his lips quirk upwards. "So then, I'm going to ask a totally separate question. Are you interested in sex at all? Supposing I could think of ways to be intimate like that, and it didn't involve either of us touching the other?"

						*label hermesacequestion2
						*fake_choice
							#I think I might understand at least some of what he means, and I nod. "Yes, if that would be possible, I'd be interested." 
								You think you might understand at least some of what he means, and you nod. "Yes, if that would be possible, I'd be interested." It's not like you're without desires, and you [i]do[/i] have desire for him. It's just that you [i]also[/i] can't stand being touched in any capacity. 

								Fortunately, those two things need not preclude one another completely. 

								"All right. Good to know." Hermes replies with a small smile. "I think maybe I'll need some time to think about how to do something like that properly, but for now…" 

								The smile turns quite sly. "I hope you'll think of me, when you handle those needs of yours. Now, how about we get these dishes back to the kitchen?"

								*label hermes_thinkingofyou2
								*fake_choice
									#@{convotoggle [☆]|} "It's extremely rude of you to say something like that and then go back to something so mundane, you know?"
										"It's extremely rude of you to say something like that and then go back to something so mundane, you know?" Nevertheless, you understand why he's doing so, and you don't ultimately object, moving to help him stack plates and bowls. 

										"Well consider it payback, for making me want to kiss you," he replies, just as lightly. 

										You suppose you can accept the petty vengeance. For now.
										*goto chap3end
									#@{convotoggle [♥]|} "I think I will think of you." 
										*set overt +1
										"I think I will think of you." You offer him a languid smile, meeting his flirtation with your own. 

										*if (tag_uncharming)
											For a moment, he looks outright shocked at the expression, and then he chuckles. 

											"So you [i]can[/i] make bedroom eyes. I'd wondered." His expression doesn't lose the hint of sensuality, though, and the mirth fades lightly a moment later.

											"I like that idea quite a lot. I hope you don't mind that I'll be thinking of you, too."
										*if not (tag_uncharming)
											He chuckles. "Good. I like that idea… quite a lot. I hope you don't mind that I'll be thinking of you, too."
										*goto chap3end
									#@{convotoggle [♥]|} "As long as you're thinking of me, too."
										*set overt +1
										"As long as you're thinking of me, too." You offer him a languid smile, meeting his flirtation with your own. 

										*if (tag_uncharming)
											For a moment, he looks outright shocked at the expression, and then he chuckles. 

											"So you [i]can[/i] make bedroom eyes. I'd wondered." His expression doesn't lose the hint of sensuality, though, and the mirth fades lightly a moment later.

											"But… I like that idea quite a lot. And you can rest assured, I will be."
										*if not (tag_uncharming)
											He chuckles. "I like that idea… quite a lot. You can rest assured, I will be."
										*goto chap3end
									#@{convotoggle [♥]|} That is... far too embarrassing to respond to.
										*set subtle +1
										That is… far too embarrassing to respond to. You don't know what your face is doing, except that it's getting very hot, and it seems ridiculous to even try fumbling some kind of response together, so you don't, reaching for a few of the plates instead. 

										Hermes chuckles, but fortunately he doesn't make any further comment. Perhaps he has some sense of mercy, after all. 
										*goto chap3end
							#You're not totally sure you know what he's talking about, but it sounds like a good idea anyway. "Yes, of course. I'm definitely attracted to you that way, I just..."
								You're not totally sure you know what he's talking about, but it sounds like a good idea anyway. "Yes, of course. I'm definitely attracted to you that way, I just..." 

								It's not like you're without desires, and you [i]do[/i] have desire for him. It's just that you [i]also[/i] can't stand being touched in any capacity. 

								You'd thought those two things were mutually exclusive, but apparently he doesn't share the view. That's both a relief and kind of surprising to learn. 

								He smiles a little. "You just don't want to be touched. It's all right, Sunshine. We'll get it figured out. I have a few ideas already, but I'll need a little time to decide how to do things properly."

								The smile turns quite sly. "I hope you'll think of me, when you handle your needs in the interim. Now, how about we get these dishes back to the kitchen?"
								*goto hermes_thinkingofyou2
							#The implications don't totally escape me, and I clear my throat softly. "Well... not right away, but eventually, I might be."
								The implications don't totally escape you, and you clear my throat softly. "Well... not right away, but eventually, I might be." It's not like you're without desires, and you [i]do[/i] have desire for him. It's just that you [i]also[/i] can't stand being touched in any capacity. 

								Fortunately, those two things need not preclude one another completely. 

								"All right. Good to know." Hermes replies with a small smile. "I think maybe I'll need some time to think about how to do something like that properly, anyway, so for now…" 

								The smile turns quite sly. "I hope you'll think of me, when you handle those needs of yours. Now, how about we get these dishes back to the kitchen?"
								*goto hermes_thinkingofyou2
							#I have no idea what he's talking about, but I can answer the hypothetical. "When we get to that point, maybe. Not right this moment, though." 
								You have no idea what he's talking about, but you can answer the hypothetical. "When we get to that point, maybe. Not right this moment, though." 								It's not like you're without desires, and you [i]do[/i] have desire for him. It's just that you [i]also[/i] can't stand being touched in any capacity. 

								You'd thought those two things were mutually exclusive, but apparently he doesn't share the view. That's both a relief and kind of surprising to learn. 

								He smiles a little. "It's all right, Sunshine. We'll get it figured out, at our own pace. I have a few ideas, but I'll need a little time to decide how to do things properly, anyway."

								The smile turns quite sly. "I hope you'll think of me, when you handle your needs in the interim. Now, how about we get these dishes back to the kitchen?"
								*goto hermes_thinkingofyou2
							#"No, I'm honestly not interested in anything sexual at all."
								*set tag_ace true 
								"No, I'm honestly not interested in anything sexual at all." He's right that it [i]is[/i] a separate question, but in your case at least, the answers are the same. Even if he could come up with something like that—and somehow you don't doubt that he could—you wouldn't be interested in the slightest. It's just not the way you are. 

								"Got it," Hermes says, smiling wryly. 
								*if (hermes_backstory = "friends")
									"I sort of figured that might be the case. Most people show at least some interest in that kind of thing, but I've never known you to."
								*if (hermes_backstory != "friends")
									"I don't know if I was expecting it, but it's good to know now."

								"Is that… going to be a problem for you?" Reputationally alone, you know he enjoys sex and all kinds of things related to it. He's never gone into any detail with you about that kind of thing, so you don't know how much of what you've heard is true, but you suspect at least some of it must be. 

								"Of course not," he replies with a small smile. "I don't [i]need[/i] sex. And what needs I do have, I can handle myself." He shrugs, as easy and confident as ever. 

								"Anyway, what do you say we get these dishes back to the kitchen?" 

								You aren't sure how you expected him to handle that information, but you have to admit, it's a relief that it really doesn't seem like a big deal to him at all. 

								Nodding, you start to collect the plates and bowls from the table. That's something that could have been a hurdle in your relationship cleared with aplomb, and you can't deny the way it helps you relax. 

								That feeling of sweet relief lasts until you sleep finds you, a few hours later.
								*goto chap3end
							#"I'm not really interested personally, but if it's something you'd enjoy, I don't mind participating now and then." 
								*set tag_posace true
								"I'm not really interested personally, but if it's something you'd enjoy, I don't mind participating now and then." He's right that it [i]is[/i] a separate question, and in your case, at least, the answers diverge a little. Your aversion to touch is not a total aversion to sexuality. You don't feel any real [i]desire[/i] for that sort of thing, but if he does, you don't mind sharing that experience with him on occasion. 

								"Huh." Hermes smiles wryly. 
								*if (hermes_backstory = "friends")
									"I sort of figured that might be the case. Most people show at least some interest in that kind of thing, but I've never known you to."
								*if (hermes_backstory != "friends")
									"I don't know if I was expecting that, but it's good to know now."

								He tilts his head at you. "As for the other part, also good to know. I'll think about it some more and let you know. After all, it's not like I [i]need[/i] sex. And what needs I do have, I can handle myself." He shrugs, as easy and confident as ever. 

								"Anyway, what do you say we get these dishes back to the kitchen?" 

								You aren't sure how you expected him to handle that information, but you have to admit, it's a relief that it really doesn't seem like a big deal to him at all. 

								Nodding, you start to collect the plates and bowls. That's something that could have been a hurdle in your relationship cleared with aplomb, and you can't deny the way it helps you relax. 

								That feeling of sweet relief lasts until sleep finds you, a few hours later.
								*goto chap3end
					#"I do understand that if we want to have any kind of sexual relationship, we'll have to touch sometimes. I just really don't like this kind."
						*set intimate_touch "middling"
						"I do understand that if we want to have any kind of sexual relationship, we'll have to touch sometimes. I just really don't like this kind." 

						Hermes frowns, but rather than upset or discouraged, he looks thoughtful. "So… intimacy by touch is fine, as long as it isn't kissing?"

						"More or less." You nod to confirm the rephrasing. It's probably not something he's run across before, so you don't mind explaining as much as he needs. 

						"So, supposing we were at a point where both of us wanted it, I could touch your body with my hands?" He arcs an eyebrow, the faint hint of a smile quirking at his lips. 

						*if (humorous > serious)
							"That's the idea," you reply, huffing softly.
						*if not (humorous > serious)
							"Isn't that what I just said?"

						"Okay, just making sure." The small smile becomes a grin. "I can work with that. Not right now, of course, but… soon enough. I do hope you'll think of me when addressing any needs that might come up in the interim. Now, shall we get these dishes back to the kitchen?"
						*goto hermes_thinkingofyou2
					#"I don't like being touched casually, and I don't want to be kissed on the mouth, but other kinds of touching or kissing in this context are okay."
						*set intimate_touch "fine"
						*set kissing "notface"
						"I don't like being touched casually, and I don't want to be kissed on the mouth, but other kinds of touching or kissing in this context are okay."

						Hermes frowns, but rather than upset or discouraged, he looks thoughtful. "So… intimacy by touch is fine, as long as it isn't kissing on the mouth?"

						"Yes, definitely." You nod to confirm the rephrasing. It's probably not something he's run across before, so you don't mind explaining as much as he needs. 

						"So, supposing we were at a point where both of us wanted it, I could touch your body with my hands?" He arcs an eyebrow, the faint hint of a smile quirking at his lips. 

						*if (humorous > serious)
							"That's the idea," you reply, huffing softly.
						*if not (humorous > serious)
							"Isn't that what I just said?"

						"Okay, just making sure." The small smile becomes a grin. "I can work with that. Not right now, of course, but… soon enough. I do hope you'll think of me when addressing any needs that might come up in the interim. Now, shall we get these dishes back to the kitchen?"
						*goto hermes_thinkingofyou2
					#"I don't like being touched casually, or any kind of kissing, but other kinds of touching in this context are okay."
						*set intimate_touch "fine"
						"I don't like being touched casually, or any kind of kissing, but other kinds of touching in this context are okay."

						Hermes frowns, but rather than upset or discouraged, he looks thoughtful. "So… intimacy by touch is fine, as long as it isn't kissing?"

						"Yes, definitely." You nod to confirm the rephrasing. It's probably not something he's run across before, so you don't mind explaining as much as he needs. 

						"So, supposing we were at a point where both of us wanted it, I could touch your body with my hands?" He arcs an eyebrow, the faint hint of a smile quirking at his lips. 

						*if (humorous > serious)
							"That's the idea," you reply, huffing softly.
						*if not (humorous > serious)
							"Isn't that what I just said?"

						"Okay, just making sure." The small smile becomes a grin. "I can work with that. Not right now, of course, but… soon enough. I do hope you'll think of me when addressing any needs that might come up in the interim. Now, shall we get these dishes back to the kitchen?"
						*goto hermes_thinkingofyou2
			*if (hermes_touch2 != "averse")
				His brows knit. "Stop me if I'm still heading the wrong way here, obviously."

				*fake_choice
					#@{convotoggle [♥]|} "Not at all. I'd love to cuddle."
						"Not at all. I'd love to cuddle." You offer him a small smile, and Hermes returns it, a soft breath of relief escaping him. 

						"That's good; I wasn't entirely sure what I was going to do if you didn't want to do that, either. Maybe offer to play a board game, or something." He rolls his eyes, presumably at himself, then shifts, picking his feet up and laying them across your legs with a snicker, reclining himself against the sloped end of the couch. 

						*label hermesgettingsettled2
						"You want to do this here?" you ask, lifting a brow slightly. 

						Hermes's smile briefly broadens. "Well, why not? It's not like anyone else is around, and the couches are comfortable. Don't get me wrong, you're welcome to invite yourself to my bed any time you want, but if you do that I might get ideas a little less tame than this one." 

						Considering a moment, he hums, then spreads his wings out to either side so he's not laying on top of them. Then he opens his arms, and you take the cue, getting out from beneath his legs and climbing on next to him properly. 

						With some work, you manage to find a position that's relatively comfortable for both of you—you're partially atop him and partially to his side, head resting in the crook of his shoulder. 

						He sighs quietly. 
						*goto hermescuddle
					#"I suppose we could do something like that, sure."
						"I suppose we could do something like that, sure." You can't claim to be [i]overjoyed[/i] by the idea, but it sounds nice enough. You [i]have[/i] put paid to the other idea he had, and it's not as though you want to reject him, either. A bit of proximity could be enjoyable. 

						"That's good; I wasn't entirely sure what I was going to do if you didn't want to do that, either. Maybe offer to play a board game or something." He rolls his eyes, presumably at himself, then stands. 
						*goto hermesgettingsettled2
					#@{convotoggle [♥]|} "You can kiss me places that aren't my mouth, just so you know. But cuddling is also fine."
						*set kissing "notface"
						"You can kiss me places that aren't my mouth, just so you know. But cuddling is also fine." You offer him a small smile, and Hermes returns it, a soft breath of relief escaping him. 

						"That's good to know; I'll keep it in mind. For now, though, being close is plenty. I wasn't entirely sure what I was going to do if you didn't want to try this, either. Maybe offer to finish the game." He rolls his eyes, presumably at himself, then shifts, picking his feet up and laying them across your legs with a snicker, reclining himself against the sloped end of the couch. 
						*goto hermesgettingsettled2
					#@{convotoggle [♥]|} "Could we just... hold hands for now?"
						"Could we just... hold hands for now?" You hate to say no yet again, but it's important that you're honest, and that degree of contact just doesn't feel like something you're quite up to, right now. But you still want to be close with him. 

						He blinks for a moment, but then nods readily. 
						
						*label hermes_holdhands
						"It's a little strange," he admits. "I never thought I'd have the inclination to just sit and hold somebody's hand." His own briefly squeezes yours, warm and soft. If his knifework might have given him calluses at any point, he's staved them off successfully, probably by taking very good care of himself. Then again, you've never known him to 'spar' much, so perhaps it wasn't a concern to begin with. 

						His fingertips are slightly roughened, though, where he drags them gently back and forth across your palm. Instrument strings, perhaps.
						*page_break
						"Why not?" you ask quietly, leaning back against the seat of the sofa behind you. 

						"I'm not sure," he replies, though then his lips purse. "Well, I'm kind of sure, but it'll probably make me sound like an ass to say it." 

						*fake_choice
							#@{convotoggle [☆]|} "And when has that ever stopped you from saying something?"
								*set humorous +1
								"And when has that ever stopped you from saying something?" You fix him with a [i]look[/i], and he snorts. 

								"Hey. I could say jerk-sounding things a lot more often than I actually do, you know. I [i]have[/i] a filter. It's just a matter of deciding when to use it." 

								His expression sobers. "Just… it's the kind of thing I've always thought was a waste of time. If I had the minutes to spare doing something like that, I could be doing something more interesting. I didn't think very highly of intimacy for its own sake."
								*goto mandatedtransition1
							#"Well you don't have to, but I'd like to know."
								*set serious +1
								"Well you don't have to, but I'd like to know." You tilt your head slightly at him. 

								He hums, considering for a moment, and shakes his head.  "Just… it's the kind of thing I've always thought was a waste of time. If I had the minutes to spare doing something like that, I could be doing something more interesting. I didn't think very highly of intimacy for its own sake."
								*goto mandatedtransition1
							#"Is that a problem?"
								"Is that a problem?" You're not sure if it means he isn't going to say it or not, but you know he's usually fairly honest by default—at least when he's here. 

								He hums, considering for a moment, and shakes his head.  "Just… it's the kind of thing I've always thought was a waste of time. If I had the minutes to spare doing something like that, I could be doing something more interesting. I didn't think very highly of intimacy for its own sake."								
								*goto mandatedtransition1
						*label mandatedtransition1
						*line_break
						*line_break
						"Do you still think that?"

						He clicks his tongue against his teeth. "I don't know yet. Maybe in general. This doesn't feel like one, but maybe that's because we're talking. Or maybe it's because it's a different kind of relationship from the ones I've had before, and that changes things. I'll figure it out eventually." 

						His thumb lightly caresses the inside of your wrist, and you take a soft breath, holding it a moment and then releasing. It feels nice, if also a little strange. Like your awareness has narrowed to so few things that everything about them is more apparent to you. The drag of his fingertip, which could in another context be something you easily ignored, seems to take the lion's share of your attention, now. 

						But it isn't a focus that comes with any sense of urgency. You don't need to do anything about it. Don't need to act a certain way, or try to think about anything else. You can just… sit here and enjoy it, for a little while. Enjoy talking to Hermes. 

						And right now, that feels like everything you want.
						*goto chap3end
		#"I really don't like the idea of kissing, if I'm being honest." 
			*set kissing "dislike"
			"I really don't like the idea of kissing, if I'm being honest." You clear your throat, only a little awkwardly, and shrug. You know he'd rather know. You've never tried it, but you know you don't want to. Even the idea of it just makes you uncomfortable, if you really think about it for more than a couple of seconds. 

			Hermes blinks, apparently a bit surprised, then nods. "Okay. That's a bit of a shame, because I love it. But it's not that important, really." He mirrors your shrug with one of his own, straightening his posture so he's no longer so close to your face. "We can do something else. Cuddling, maybe?"
			*goto hermes_nokissmenu2
		*if (hermes_touch2 = "averse")
			#"You know I don't like touching. This is no different. We're going to need to have a relationship without any of the physical stuff, okay?" 
				*set kissing "dislike"
				*set intimate_touch "averse"
				"You know I don't like touching. This is no different. We're going to need to have a relationship without any of the physical stuff, okay?"  You suppose it was a fair thing for him to ask about, because, well… casual touch and intimate touch [i]are[/i] different things. You, however, don't think of them all that differently.

				It's… you know most people expect things out of relationships that go beyond the intimacy of deep conversations and trust and going through life together, but those dimensions aren't anything you can provide. 

				Hermes frowns, but rather than upset, he looks thoughtful. "Okay," he says, with a small nod. "I knew that was a possibility. Maybe I should have asked about it before now, but I know, and that's the important thing. No touching of any kind." 

				His eyes narrow, and his lips quirk upwards. "So then, I'm going to ask a totally separate question. Are you interested in sex at all? Supposing I could think of ways to be intimate like that, and it didn't involve either of us touching the other?"
				*goto hermesacequestion2
	*goto chap3end
*elseif (hermes_justfriends)
	You lapse into silence for a little while, polishing off dinner and moving on to dessert, the cake with nuts in it. You've each been given quite a thick slice, and you're breaking off a chunk to try when Hermes clears his throat softly. 
	
	"Thanks, by the way. For listening to all that. I hate whining to people, but it seems like I always end up doing it, anyway." He shakes his head, an expression almost bitter crossing his features for a moment. 
	
	*fake_choice
		#"I don't think what you did was complaining."
			"I don't think what you did was complaining." It's natural to struggle with relationships, sometimes, and it sounds like the one he has with his mother is complicated, to say the least. It's probably a good thing that he spoke to someone about it. 
			
			"Mm… it feels a little like it, but either way I appreciate you listening."
			*goto mandatedtransition2
		#"That's what friends are for, isn't it?"
			"That's what friends are for, isn't it?" You offer a small smile. You [i]are[/i] friends, after all, and it sounds like his relationship with his mother is complicated, to say the least. Talking to you about it is one of the most obvious things to do about that. And frankly, you're glad he told you about it. 
			
			"I guess it is. Appreciate it, Sunshine."
			*goto mandatedtransition2
		#"Everyone has things they struggle with. I'd rather you shared them with me than not."
			"Everyone has things they struggle with. I'd rather you shared them with me than not." At least that way, the burden can be lessened a little bit. Or at least, that's how you've found things tend to go, when you share the things troubling you with others. Hopefully you can do something like that for him as well. 
			
			"Well… then you're welcome, I guess." Hermes's lips twitch. "But in all seriousness, I appreciate it, Sunshine."
			*goto mandatedtransition2
	*label mandatedtransition2
	*page_break
	Hermes expels a short breath, offering a wry smile. "Anyway, as much as I've appreciated getting you all to myself today, we should probably look towards wrapping things up, huh? You need to sleep, and all that. Should we get these dishes back to the kitchen?"
	
	*if (tag_unintuitive)
		At first, you're not sure what to make of the transition, but after a long moment's pause to think about it, you realize he's probably reached his capacity for talking about personal things for one day. And he's not wrong that you'll need to sleep soon, so you nod, reaching forward to begin collecting some of the plates and bowls. 
	*if not (tag_unintuitive)
		It's obvious that he's probably reached his capacity for talking about personal things for one day. And he's not wrong that you'll need to sleep soon, so you nod, reaching forward to begin collecting some of the plates and bowls. 
	
	It's been a good day, and you don't need it to be anything more than that. 
	*goto chap3end
*elseif (npc_init)
	You lapse into silence for a little while, polishing off dinner and moving on to dessert, the cake with nuts in it. You've each been given quite a thick slice, and you're breaking off a chunk to try when Hermes clears his throat softly.
	
	"So, Sunshine, there's something I've been meaning to talk to you about." 
	
	You blink. It's not like him to preface something like that rather than just coming right out with it, so you suppose the matter, whatever it is, must be rather important. 
	
	"What is it?"
	
	He clears his throat. "So, stop me if I'm just being an idiot here, but… is there a chance you might think of me as something other than a friend? Because obviously you're one of mine, but I also think I might have a few… additional feelings for you, if you see what I'm getting at, here."
	
	*label hermesconfess2
	*fake_choice
		*if ((tag_unintuitive) and (blockthis = false))
			*disable_reuse #@{convotoggle [❋]|} "I... don't think I see what you're getting at, sorry. Can you just say whatever it is?"
				"I... don't think I see what you're getting at, sorry. Can you just say whatever it is?" Your brows knit. It's a bit unfortunate, because he seems to be choosing his words carefully, but you just don't… get it. 
				 
				He expels his breath. "I'm asking whether you could see me as a potential romantic partner," he says bluntly, nose crinkling. "Which I probably should have said, but it feels rather confronting to make it that obvious without any idea of the answer." 
				 
				"Ah, sorry." 
				 
				He shakes his head. "No, no, it's fine. More importantly than anything, answer honestly, okay?"
				 
				That's an instruction you can certainly follow.
				*goto hermesconfess2
		#@{convotoggle [♥]|} "I do think of you that way, yes. Or at least, I think it would be nice if we were in that kind of relationship."
			*set hermes_romance true
			"I do think of you that way, yes. Or at least, I think it would be nice if we were in that kind of relationship." In the end, the words come to you easily. Simply, without any hesitation or particular playfulness, either. It just is how you feel, and plain sincerity seems like the best way to convey something of such import. 
			
			Hermes's eyes round a little, for a moment, and then a smile flits across his face. "You do, huh? That's… great, honestly." 
			
			Apparently your way of putting it has drawn something similar out of him, and you feel a gentle warmth bloom in your chest. 
			
			The both of you feel the same way about each other. There's something deeply comforting about that.
			*page_break
			*goto hermes_intimatesolo
		#@{convotoggle [♥]|} "I actually hadn't thought about it much before, but... I think I'd like to give something like that a try."
			*set hermes_romance true
			"I actually hadn't thought about it much before, but... I think I'd like to give something like that a try." In the end, the words come to you easily. Simply, without any hesitation or particular playfulness, either. It just is how you feel, and plain sincerity seems like the best way to convey something of such import. 
			
			It may not have much crossed your mind, before, but hearing the words feels like something [i]clicks[/i] in your head, fitting several things together that hadn't made the most sense until now. Until you could categorize them with this kind of feeling.

			Hermes's eyes round a little, for a moment, and then a smile flits across his face. "You would, huh? That's… great, honestly." 
			
			Apparently your way of putting it has drawn something similar out of him, and you feel a gentle warmth bloom in your chest. 
			
			The both of you feel the same way about each other. There's something deeply comforting about that.
			*page_break
			*goto hermes_intimatesolo
		#@{convotoggle [♥]|} "I've been waiting for you to ask me that for a while now."
			*set hermes_romance true
			*set overt +1
			"I've been waiting for you to ask me that for a while now." You don't mince your words about it, but the little smile you give him is a wry one, accompanied by a slight rolling of your eyes. "It took you long enough to catch up."
			
			Hermes's eyes round a little, for a moment, and then a smile flits across his face, accompanied by a huff of laughter. "Hey, this isn't as easy as falling into bed with someone I hardly know, okay? I had things to think about. You're important to me, believe it or not."
			
			"Oh, I believe it." Your reply is light, but his way of describing it makes something warm bloom in your chest. He was being deliberate because it matters. 
			
			There's something deeply comforting about that.
			*page_break
			*goto hermes_intimatesolo
		#{convotoggle [♥]|} "Yes! I mean... yes. I do think of you like that. I have for... a bit, now."
			*set hermes_romance true
			*set subtle +1
			"Yes! I mean... yes. I do think of you like that. I have for... a bit, now." You wince at your initial answer, quickly amending at a much softer volume. It's not easy for you to talk about things like this; most often your words are awkward, or you blurt them, or whatever else. But you couldn't risk being unclear [i]now[/i] of all times, and what emerged as your answer was honest, even if it wasn't elegant. 
			
			Hermes's eyes round a little, for a moment, and then a smile flits across his face, accompanied by a soft huff. "You do, huh? That's… great, honestly." 
			
			Apparently your way of putting it was amusing, but you feel a gentle warmth bloom in your chest. 
			
			The both of you feel the same way about each other. There's something deeply comforting about that.
			*page_break
			*goto hermes_intimatesolo
		*if (blockthis = false)
			#"I'm sorry, Hermes. You're a good friend, but that's how I think about you. There's no other component to it."
				*set hermes_justfriends true
				*set hermes_rejected true
				"I'm sorry, Hermes. You're a good friend, but that's how I think about you. There's no other component to it."

				"…Ah. Fair enough, then." He shrugs, offering you a wry little smile with a hint of sheepishness to it. "More fool I, for thinking so much about whether I should even say anything." 

				"I'm—"

				He shakes his head. "You don't need to apologize, Sunshine. Not for this. No one can force their feelings, and I wouldn't want you to try."
				*page_break
				Hermes expels a short breath, offering a wry smile. "Anyway, as much as I've appreciated getting you all to myself today, we should probably look towards wrapping things up, huh? You need to sleep, and all that. Should we get these dishes back to the kitchen?"

				*if (tag_unintuitive)
					At first, you're not sure what to make of the transition, but after a long moment's pause to think about it, you realize he's probably reached his capacity for talking about personal things for one day. And he's not wrong that you'll need to sleep soon, so you nod, reaching forward to begin collecting some of the plates and bowls. 
				*if not (tag_unintuitive)
					It's obvious that he's probably reached his capacity for talking about personal things for one day, particularly after an answer like that. And he's not wrong that you'll need to sleep soon, so you nod, reaching forward to begin collecting some of the plates and bowls. 

				It's been a good day, minor awkwardness aside, and you don't need it to be anything more than that. 
				*goto chap3end
		*if (blockthis = false)
			#"I... I won't say I haven't ever considered it, but I'm not ready to make a decision about what I want, just yet. Can you ask me again later?"
				*set hermes_deferred2 true
				"I... I won't say I haven't ever considered it, but I'm not ready to make a decision about what I want, just yet. Can you ask me again later?" There's just too much going on in your life right now for you to feel like you can make a decision about this. At least now you know you need to consider it seriously and come up with an answer for him, instead of speculating about that part. 

				Hermes winces, a tad exaggerated. "Ah, my ego. It's being deflated as we speak. Here I thought you would immediately accept." His tone is jocular, entirely unserious, but there's something about his eyes that doesn't quite carry the humor. 

				"I'm—"

				He shakes his head. "You don't need to apologize, Sunshine. Not for this. No one can force their feelings, and I wouldn't want you to try. Take the time you need to figure things out, and we'll go from there."
				*page_break
				Hermes expels a short breath, offering a wry smile. "Anyway, as much as I've appreciated getting you all to myself today, we should probably look towards wrapping things up, huh? You need to sleep, and all that. Should we get these dishes back to the kitchen?"

				*if (tag_unintuitive)
					At first, you're not sure what to make of the transition, but after a long moment's pause to think about it, you realize he's probably reached his capacity for talking about personal things for one day. And he's not wrong that you'll need to sleep soon, so you nod, reaching forward to begin collecting some of the plates and bowls. 
				*if not (tag_unintuitive)
					It's obvious that he's probably reached his capacity for talking about personal things for one day, particularly after an answer like that. And he's not wrong that you'll need to sleep soon, so you nod, reaching forward to begin collecting some of the plates and bowls. 

				It's been a good day, minor awkwardness aside, and you don't need it to be anything more than that. 
				*goto chap3end
*else
	You lapse into silence for a little while, polishing off dinner and moving on to dessert, the cake with nuts in it. You've each been given quite a thick slice, and you're breaking off a chunk to try when Hermes clears his throat softly.
	
	"Thanks for coming with me, today. Flying's always fun, but I think I like it the most when you're there, too." He grins a little. "You're like a fledgling, learning how to navigate the sky with absolutely no grace." 
	
	*if (humorous > serious)
		"Right. Because I'm sure [i]you[/i] were spectacular from day one."
	*if not (humorous > serious)
		"It is a relatively new skill. I doubt you were that able on your first few outings, either." 
	
	"Oh, but I was," Hermes replies, waggling his eyebrows playfully. "Where I was so clumsy you'd hardly believe was in the water. I still don't enjoy swimming much, but if you want to go sometime, I suppose I could put up with it, for you."
	
	*fake_choice
		#@{convotoggle [♥]|} "It's a date, then."
			*set hermes_romance true
			*set overt +1
			"It's a date, then," you reply with a smile. "I hope you are prepared to be ruthlessly mocked for any ungainliness you display in the water."
			
			"Is it?" he asks, lifting an eyebrow, expression composed. "A date, that is? Because I would like to go on one with you. A real one, if you see what I'm getting at, here."
			*set blockthis true
			*goto hermesconfess2
		#@{convotoggle [♥]|} "For me? Can I... ask you about that?"
			*set hermes_romance true
			*set subtle +1
			"For me? Can I... ask you about that?" You swallow a little bit past the small lump at the back of your throat. It feels like your nerves are live at once, like a mild breeze would knock you over, but you ask anyway. 
			
			"Ask me about what?" he replies, lifting an eyebrow, expression composed. "The fact that I'd be willing to do things I don't especially enjoy for more time with you? I think it's pretty obvious why that would be, if you see what I'm getting at, here."
			*set blockthis true
			*goto hermesconfess2
		#His phrasing is easily misunderstood, but even if he were serious, I think of him as a friend, not a potential romantic partner or anything.
			*set hermes_justfriends true
			His phrasing is easily misunderstood, but even if he were serious, you think of him as a friend, not a potential romantic partner or anything. He's joking in his implications anyway, of course, even if the words are literally true. 
			
			"Perhaps I'll take you up on that, at some point." 
			
			"By all means, Sunshine. Anyway, let's get all this back to the kitchen and you to some much-needed sleep, hm?"
			
			You nod readily, helping him collect the various tableware and stack it neatly on the tray. You [i]are[/i] getting a bit tired, and you're not surprised he noticed. Now's not such a bad time to rest, anyway.
			
			It's been a good day, and you're quite satisfied with it. 
			*goto chap3end
		#I sort of want to ask him what he means by that, but I'm not sure I'm quite ready for the discussion, just yet.
			You sort of want to ask him what he means by that, but you're not sure you're quite ready for the discussion, just yet. It could change an awful lot of things, and not for the better if you aren't certain when you broach the topic. Plus, it's… hard to know how serious he is, in his implications, because Hermes is the sort of person who flirts for fun [i]and[/i] thinks the world of the people he considers his friends. 
			
			You just can't risk it, at this point. 
			
			"Perhaps I'll take you up on that, at some point," you say, mostly to have said something without leaving a too-long silence in the middle. 
			
			"By all means, Sunshine. Anyway, let's get all this back to the kitchen and you to some much-needed sleep, hm?"
			
			You nod readily, helping him collect the various tableware and stack it neatly on the tray. You [i]are[/i] getting a bit tired, and you're not surprised he noticed. Now's not such a bad time to rest, anyway.
			
			It's been a good day, and you don't need it to be anything else 
			*goto chap3end

*label chap3hekate
A few days later, Demeter has returned to Olympus. You're not sure exactly when or if she'll be back, but for now at least, she has obviously seen Iasion and confirmed his identity. What difference it will make in the long run, you can't be sure, but some things are surely worth doing even if they don't change how the world works. 

You wonder, for a moment, what you would do in her position, but the thought is easily enough brushed aside. 
*page_break
The library is presently quite quiet, its only occupants yourself and Hekate. Even then, conversation is intermittent if anything, occasionally punctuated by the quiet sound of someone picking up a bit of food. 

[i]Don't tell Hermes I allowed us snacks in here,[/i] she'd said, giving you a conspiratorial smile as you both settled in for your reading. 

*if (tag_unlearned)
	It's certainly not usually your favorite activity; you've always had a bit of trouble with conventional study. But then, right at this moment it doesn't feel like study. You're just reading about things that interest you, and if some of it slips your mind later, well. It's not like there's going to be any kind of examination about it. 
	
	That fact makes this something you can enjoy, on the rare occasion, and today is one such. 
*if not (tag_unlearned)
	You don't always have as much time as you might like to pursue your interests in this way, with all the other things you get up to, but it's a pleasant sort of dilemma, and makes times like this all the more enjoyable, particularly with present company considered.
	
Hekate herself has a rather large stack of tomes and fat scrolls to either side of her, along with one open book she writes in periodically. Her brows are knit, wrinkled in a way that almost suggests she's troubled by something. You've learned, over time, that she welcomes conversation even when apparently very occupied, and given the amount of time that's passed since you got here, a small break might be in order, anyway.

*fake_choice
	#"What are you reading?"
		*set forthright +1
		"What are you reading?" You tilt your head to get a look at the cover of the book she's got propped on the small wooden stand in front of her, but you can't make out any lettering, so your gaze shifts back to her, instead.
		
		It takes Hekate several long moments to respond. Eventually, she blinks, shaking herself slightly as if recovering from a daze, and offers you a small smile. 
		
		"Human magic," she replies. "It's different from the deific kind, of course, and I've been making something of a study of it's different manifestations, recently." 
	#"That is... quite the number of materials."
		*set reserved +1
		"That is… quite the number of materials." You tilt your head to get a look at the cover of the book she's got propped on the small wooden stand in front of her, but you can't make out any lettering, so your gaze shifts back to her, instead.
		
		It takes Hekate several long moments to respond. Eventually, she blinks, shaking herself slightly as if recovering from a daze, and offers you a small smile. 
		
		"And many of them one of a kind. Magicians' personal journals, lists of alchemical recipes, that sort of thing. I've been making a study of the manifestations of human magic, of late. It's quite different from the deific sort, as you might expect." 
	#"Is something bothering you?"
		*set forthright +1
		"Is something bothering you?" The expression on her face makes you wonder, so you might as well ask. Perhaps she's reading something that doesn't agree with her, or the research is just on a difficult topic. 
		
		It takes Hekate several long moments to respond. Eventually, she blinks, shaking herself slightly as if recovering from a daze, and offers you a small smile. 
		
		"Oh, I'm fine," she replies. "Just trying to puzzle some things out. I'm making a study of human magic, which is quite different from the deific kind, as you might imagine, and the records are certainly more… obscure."
	#I feel a flicker of concern at her expression, but can't quite bring myself to interrupt even so.
		*set reserved +1
		You feel a flicker of concern at her expression, but can't quite bring yourself to interrupt even so. Perhaps she's reading something that doesn't agree with her, or the research is just on a difficult topic. 
		
		A few moments pass, and you return to your reading, shooting her the occasional glance, but it seems unlikely that she notices your particular regard.
		
		Eventually, her posture shifts, and she blinks, shaking herself slightly as if recovering from a daze, then offers you a small smile, flipping another page with decidedly less apparent concentration.
*page_break
She clicks her tongue softly. "Mm, I think I need a bit of a break. I was at this for quite a while even before you got here, and like any other organ, you can only work your brain so hard before it starts to rebel, no?" 

Her chuckle is soft and easy.

"So, shall we recuperate a little? I trust your reading is going well?"

*fake_choice
	#"I think my brain started rebelling an hour ago, honestly."
		"I think my brain started rebelling an hour ago, honestly."
		
		You aren't particularly joking, but she laughs lightly nevertheless, nodding with a knowing expression. "Well, don't feel like you need to push through it. The books will always be here when you're in a less-weary state of mind." 
		
		"I suppose they will."
	#"It is, though I can't say I'm doing anything particularly important."
		"It is, though I can't say I'm doing anything particularly important."
		
		You aren't particularly joking, but she laughs lightly nevertheless, smile lingering even after the sound has tapered off. "Some of my favorite learning has been about the least important things you could imagine, I'm sure," she replies. "Sometimes it almost feels as if there's a reverse correlation between how practical some information is likely to be and how much I enjoy reading about it."
		
		"I don't know if I'd go that far, but I do see your point."
	#"Well enough, I suppose. A bit dry, but that's how it is, sometimes."
		"Well enough, I suppose. A bit dry, but that's how it is, sometimes."
		
		Her smile takes on a touch of wryness. "It most certainly is. I suppose it's hard to blame the writers of most of these—in the majority of cases, I imagine they were trying to be as clear and informational as possible, and that does sometimes clash with any sort of… let's say 'stylistic flourishes.'"
		
		"Sometimes they don't manage 'clear,' either, though."
		
		She snorts softly.
	#"Yes, thank you. I've always enjoyed the chance to spend a few hours lost in a book."
		"Yes, thank you. I've always enjoyed the chance to spend a few hours lost in a book."
		
		Her smile takes on a touch of wryness. "[i]Lost[/i] can certainly be the right metaphor for the experience sometimes, can't it? I fear I am more often lost than aptly-navigated, but I manage." 
		
		"I'd say you manage quite well, considering all the things you've built." 
		
		"Well, thank you. I do appreciate that, though I've hardly done so by myself."
*page_break
Hekate leans back in her chair with a quiet sigh, picking up one of the small snacks on the table—an invention of Empusa's, apparently, oats and honey dipped in a layer of sweetened yogurt. There are more conventional victuals present as well, but Hekate makes a small noise of satisfaction when she tries these, so they might be worth the venture. 

"Stop me if you'd rather not discuss it," she says, tilting her head. "But now that it's sort of… settled down for now, I thought I might ask how things are going with your parents."

It's not an unexpected question, obviously. You'd handled all of that essentially on your own, and you have no doubt plenty of people are concerned with how it went. 

*fake_choice
	#"Maybe this is selfish, but I'm really ready for things to be quiet again."
		"Maybe this is selfish, but I'm really ready for things to be quiet again." You can't say you begrudge anyone anything, exactly, but all of this has been quite disturbing to your ordinary routine. That's not [i]unacceptable[/i], but it's been exhausting, and you really need some time to not have to think about things as personally significant—and fraught—as your relationships to your parents. 
		
		The fact that Demeter has left for now is certainly helping with that. 
		
		"Not selfish at all," Hekate declares, with no sense of uncertainty. "You're entitled to peace of mind, and dealing with family can certainly present its own… challenges."
		
		"Peace of mind would be nice. Perhaps I'll have a little more of it, now, for a while."
		
		At least until the next inevitable development.
	*if not (iasionstatus = "cutoff")
		#"It's confusing, and often difficult, but I'm glad for the chance to build and repair my relationships."
			"It's confusing, and often difficult, but I'm glad for the chance to build and repair my relationships." 
		
			*if (demeterstatus = "open")
				Not that you necessarily think either of them need much repairing, on your side. You need to build one with Iasion, but while you have had the occasional disagreement with your mother, you don't consider that relationship one that needs a fix. 

				Theirs, though, is another matter, you're sure. 
			*if not (demeterstatus = "open")
				And there's certainly a relationship to repair, as well as a relationship to build. Oddly enough, you think your mother's being here was a step in the right direction, even if
				*if (demeter_sequel_1 = false)
					you didn't go to see her. It means you know that she cared enough to show up, and also that she respected your boundaries by not seeking you out against your will. Maybe there's a chance all of this ends well.
				*if (demeter_sequel_1)
					you hadn't explicitly given her permission to visit you. After all, it showed that she cares enough about Iasion to come and visit him, and she didn't seek you out against your will—you went to her. Maybe there's a chance all of this ends well.

			"'Confusing and difficult' describes many things that are worth doing," Hekate observes, her eyes narrowing with a touch of amusement. "But I imagine you will certainly have further chances, if they're what you want. Hades wouldn't turn Demeter away from the Underworld while Iasion still remembers her. As long as she's reasonable about it, of course. Which I suppose may be a good thing, from your perspective."
			
			"I'll consider it a positive, yes."
	*if not (iasionstatus = "cutoff")
		#"I think I'm enjoying getting to know Iasion, in spite of everything. I'd prefer to do so without Demeter's intervention, though."
			"I think I'm enjoying getting to know Iasion, in spite of everything. I'd prefer to do so without Demeter's intervention, though."
			
			*if (demeterstatus = "open")
				It's not like you don't want your mother around at all, of course; it's just that your relationship with him and yours are different entities, and you don't necessarily want them blending together too much, especially at this fragile, early stage of things. 
			*if not (demeterstatus = "open")
				You'd have preferred not to need to handle your mother or anything to do with her until you were ready—if you're ever ready. But this complicates things. You can hardly expect her not to see your father at all, so you're left trying to navigate the situation as well as you can.
				
			Hekate hums. "Not an enviable situation, considering. Just so you know, Hades isn't likely to restrict her access to the Underworld too much while the person she loves is here and still remembers her, but I think you can keep that separate from your own relationship with him, if you like."
			
			"I'll manage somehow, I suppose. I usually do."
	*if not (demeterstatus = "cutoff")
		#"I don't think I'll be spending much time with Iasion, if I can avoid it, but I suppose mother and I are getting along well enough."
			"I don't think I'll be spending much time with Iasion, if I can avoid it, but I suppose mother and I are getting along well enough."
			
			*if (iasionstatus = "cutoff")
				You'd made the decision not to pursue that relationship in any capacity, given the circumstances and your own emotional needs.
			*if not (iasionstatus = "cutoff")
				You'd made some attempt at getting to know him, but you just don't think it makes sense to go any further than you have. You know what you need to know about him, and… 'he,' the person with memories that are at all relevant to you, may not be around much longer.  
			
			*if (demeterstatus = "open")
				You and your mother have [i]always[/i] gotten along well enough, you suppose, so the news is more or less that there is no news. 
			*if not (demeterstatus = "open")
				As for Demeter, well. That was a bit of a surprise, but you can respect that she didn't seek you out against your will, even if she came here without your explicit permission. That means something, considering what your biggest problems with how she does things have always been. 
			
			Hekate hums. "Well, it's not difficult to avoid a particular spirit in a place as massive as the Underworld, so that should be easy enough. Nice to hear you're getting along with at least one parent, though." She lifts a brow, just a fraction of an inch.
			
			"And the harder one to avoid by far," you reply, a touch dryly.
	*if not (iasionstatus = "cutoff")
		#"It's exciting, of course! It feels like I'm... I don't know if 'repairing' my family is the right word, but things are developing in a way I'm really pleased with."
			"It's exciting, of course! It feels like I'm... I don't know if 'repairing' my family is the right word, but things are developing in a way I'm really pleased with."
			
			*if (demeterstatus = "open")
				You do need to build a relationship with Iasion, but while you have had the occasional disagreement with your mother, you don't consider that one something that needs a fix. 

				Theirs, though, is another matter, you're sure. 
			*if not (demeterstatus = "open")
				Maybe repair is at least partly appropriate to one of the two relationships you're involved in, whereas 'build' makes more sense for the other. Oddly enough, you think your mother's being here was a step in the right direction, even if
				*if (demeter_sequel_1 = false)
					you didn't go to see her. It means you know that she cared enough to show up, and also that she respected your boundaries by not seeking you out against your will. Maybe there's a chance all of this ends well.
				*if (demeter_sequel_1)
					you hadn't explicitly given her permission to visit you. After all, it showed that she cares enough about Iasion to come and visit him, and she didn't seek you out against your will—you went to her. Maybe there's a chance all of this ends well.

			"A delightful development, then," Hekate replies, her tone lightened with amusement. But her smile is full, her eyes crinkling a bit at the corners with it. "I imagine you will certainly have further chances to make progress on that. Hades wouldn't turn Demeter away from the Underworld while Iasion still remembers her. As long as she's reasonable about it, of course. Which I suppose may be a good thing, from your perspective."
			
			"Definitely."
*page_break
She's quiet for a while, chewing over another of the snacks with a deliberate slowness, eyes narrowed. "Family can certainly be… complicated," she admits after a moment. "A reductive triviality when I say it aloud like this, really, and yet it's hard to find a better characterization, for me. I cannot say I am close with either of my parents. Perhaps I should even despise them. But I've never quite been able to manage it." 

"Despise them?" The question comes out automatically, if only because it is such a strange thing to hear from her, of all people. You're not sure if Hekate despises [i]anyone[/i].

"They weren't exactly good people," she replies, a knowing tone in her voice as she meets your eyes squarely. "But they were my people, for a very long time. Back then, I daresay I wanted nothing more than their approval."

*fake_choice
	#"...I can definitely understand that. There was a time when what I cared about most was my mother's opinion."
		"...I can definitely understand that. There was a time when what I cared about most was my mother's opinion." It wasn't quite as long ago as you'd like it to be, either. Part of you [i]still[/i] places weight on her approval, even.
		
		"It's not the worst instinct," Hekate replies, with a faint smile. "But it can feel troubling, particularly when that which you esteem so much is ever out of your reach. I fear I was a rather poor example of our kind, and a disappointment to them."
		
		"Your kind?" 
		
		She nods. "A difficult thing to describe. The lines between the various distinctions everyone accepts are not always perfectly clear. I suppose at the time, however, I thought of it like this: we were the people of the Underworld, and everyone else was not. A rather foolish distinction, of course, for at times location says almost as little as vague appellation. But I was not always as wise as I am today."
		
		Her expression briefly morphs into a wry smile. 
	#"Really? You seem so... independent, for lack of a better word."
		"Really? You seem so... independent, for lack of a better word." It's hard to imagine her feeling beholden to what anyone thinks. Even in interacting with the others, you've never noticed her obviously seeking anyone else's approval. She's more likely to give it out, and have her own sought by others. 
		
		"I was young, once," she replies, a hint of humor to it. "And at that time, I wanted little more than to have that esteem. But, alas, I fear I was a rather poor example of our kind, and a disappointment to them."
		
		"Your kind?" 
		
		She nods. "A difficult thing to describe. The lines between the various distinctions everyone accepts are not always perfectly clear. I suppose at the time, however, I thought of it like this: we were the people of the Underworld, and everyone else was not. A rather foolish distinction, of course, for at times location says almost as little as vague appellation. But I was not always as wise as I am today."
		
		Her expression briefly morphs into a wry smile. 
	#"I'm having trouble imagining your parents [i]not[/i] approving of you."
		"I'm having trouble imagining your parents [i]not[/i] approving of you." She's incredibly accomplished, and though perhaps it took her time to accumulate all of her power and knowledge, you have to imagine that the roots of it were always there. 
		
		"I do appreciate the vote of confidence," she says, a touch of humor in it, "but I fear I was a rather poor example of our kind, and a disappointment to them."
		
		"Your kind?" 
		
		She nods. "A difficult thing to describe. The lines between the various distinctions everyone accepts are not always perfectly clear. I suppose at the time, however, I thought of it like this: we were the people of the Underworld, and everyone else was not. A rather foolish distinction, of course, for at times location says almost as little as vague appellation. But I was not always as wise as I am today."
		
		Her expression briefly morphs into a wry smile. 
	#"Your people? In what sense?"
		"Your people? In what sense?" It sounds like she means something a little different than her [i]family[/i], because if she'd intended to imply only that, she would have said it. 
		
		She hums. "A hard one to describe," she replies matter-of-factly. "The lines between the various distinctions everyone accepts are not always perfectly clear. I suppose at the time, however, I thought of it like this: we were the people of the Underworld, and everyone else was not. A rather foolish distinction, of course, for at times location says almost as little as vague appellation. But I was not always as wise as I am today."
		
		Her expression briefly morphs into a wry smile. 
*page_break
"To be precise, however, my parents were Asteria and Perses. Titans, specifically those who at one point called the Underworld their home. Now, of course, he is dead and she is… not quite. These days, I would call her no more or less than the portents in the sky itself." 

There's a tinge of melancholy to her expression when she says that.

*fake_choice
	#"Really? Does that mean you're a Titan, too?"
		"Really? Does that mean you're a Titan, too?" You've never been especially clear on what divides the gods from the Titans. Zeus is the son of two of them, and yet he is the king of the [i]gods[/i]. His parents and many other Titans also lived on Olympus, so it's not that. Perhaps it's merely a generational distinction?
		
		"I am," Hekate admits, a touch wryly. "As I said, it's not easy to precisely define, but my parents were Titans, and technically that was the 'side' I was on during the Titanomachy as well. Not that I actually did much fighting, back then."
		
		"Is that why you don't like Olympus very much?"
		
		She pauses at the question, clearly giving it some thought. "Yes, and no," she decides. "I know that's not very helpful, but my feelings about my identity and the war are… quite complicated."
	#"Your mother is the portents in the sky? How does that even work?"
		"Your mother is the portents in the sky? How does that even work?" It still boggles you a little that gods or Titans or whomever can be transformed into such things as landmasses and constellations, but something like that sounds [i]even more[/i] abstract. 
		
		"Well… it's sort of like Erebus," Hekate replies, tilting her head. "Or between Erebus and someone like Lethe or Acheron. Erebus is a domain now stripped from its original bearer and repurposed. Acheron exists as both a person and a river. What my mother is… is a concept. She used to have a body like you or I, and her domains included the stars and prognostication. When her domain was taken from her at the end of the war, her [i]self[/i] went with it, by her choice. She is housed in the sky, like anyone who becomes a constellation, but she isn't limited by space." 
		
		"That's… quite complicated."
		
		"Yes. If it helps, Hermes thinks of her as a woman sitting 'behind' the sky, if you will. Making sure the stars align properly or arranging them to warn those who can interpret her. If it's easier, by all means think of it that way." She shrugs a little. "It's close enough to the truth."
	#"I thought all the Titans were imprisoned after the Titanomachy." 
		"I thought all the Titans were imprisoned after the Titanomachy." Well, except for Kronos, apparently, and you're not sure why that is, but you assume Zeus made some kind of exception for his father, for whatever reason. 
		
		But the rest of them are meant to be in the lowest depths of Tartarus, lower even than the Giants. 
		
		"Most of them were," Hekate replies. "But a few of them died, and a few chose alternate punishments. My mother was given a small amount of leeway, at Hades's request. Which in turn was at mine." She smiles, but there isn't much good humor in it. 
		
		"So she was allowed to choose an alternate punishment. Like Erebus, she chose to have her domains pulled away from her. Unlike him, 'she' went with them, and her body withered to dust." 
		
		"I'm sorry." You're not sure exactly what the appropriate sentiment is, but her mother had more or less [i]died[/i], at least in some important sense, and apparently her father had in the normal sense. 
		
		"I appreciate that, ${name}, but it's all right. It was a very long time ago, now."
*page_break
Her parents were Titans, and nowadays, they're gone. [i]She[/i] is a Titan, by some definition, and from things she's said, now and before, you know she was in fact alive, here in the Underworld, [i]during[/i] the Titanomachy. It means, among other things, that she's lived here longer than Hades himself. 

It also means that she somehow escaped the Fate of her parents, and their kind. 

*fake_choice
	#"I... have to imagine the war was devastating."
		"I... have to imagine the war was devastating." You're not even sure what you're trying to get at. Of course it was devastating. It was a war. There aren't any non-devastating wars. But really it's just… an invitation for her to say more. She [i]must[/i] have feelings about it all. 
		
		Hekate purses her lips for a moment, idly rubbing her index finger back and forth along the edge of her book's cover. 
		
		"It was," she says slowly, "but not necessarily in the usual way, for me. I didn't end up fighting a single battle. Instead, I suppose my actions ended it much more quickly. And those same actions earned me my place here, so I can't say I regret them. I do miss my parents, at times, but I do not miss what the Underworld used to be, and I do not miss the era when Titans ruled." 
		
		She shakes her head. "You might think Zeus is terrible, and you wouldn't be wrong, but believe it or not I'd much prefer him on the throne of Olympus than Kronos."
		
		"…I can believe that," you reply, mirroring her gesture a bit belatedly. You've seen just one of Kronos's schemes, after all, but it was certainly awful.
		
		You're not sure if Zeus [i]would[/i] poison a goddess's magic or send Giants after people minding their own business. Maybe he would. But he hasn't, yet. 
	#"Now that I think on it, some of the people on Olympus seemed to think... unkindly of you."
		"Now that I think on it, some of the people on Olympus seemed to think... unkindly of you." You're not even sure what you're trying to get at. Many Olympians seemed to think unkindly of [i]everyone[/i] from the Underworld, during their brief visit and before. But maybe some of it [i]was[/i] specifically directed at Hekate. Your instincts are telling you so, in any event. 
		
		Hekate purses her lips for a moment, idly rubbing her index finger back and forth along the edge of her book's cover. 
		
		"Well, they would," she replies. "For many reasons. To most of them, I am still 'a Titan,' to be contrasted with those who threw off the yoke of their parents' names. I still consider [i]myself[/i] one, at least to a degree. In so doing, I am a living reminder of what for those who went through it was the worst, most dangerous time of their lives. Hardly welcome company for tea, really." 
		
		"…I suppose that makes a certain kind of sense." Not one you really find all that rational, but then feelings seldom are. 
		
		"It does," Hekate replies with a small nod. "And in all sincerity, it doesn't bother me. I've nothing to do with them, most of the time, so their opinions are of no consequence."
	#"What was it like? Really like? Almost no one ever talks about it."
		"What was it like? Really like? Almost no one ever talks about it." It might be a bit of an insensitive question, but Hekate has never faulted curiosity, and you think perhaps you will get more of an answer out of her than out of most people. 
		
		She purses her lips for a moment, idly rubbing her index finger back and forth along the edge of her book's cover. 
		
		"It was like every other war," she replies, shaking her head. "And at the same time, like none of them. When gods and their ilk do battle, the entire landscape changes. And we do not, typically, fight in battalions, nor field them. But the devastation is… similar. There was death, ${name}, and for the otherwise-undying, you can imagine how fearsome a thing that was to confront." 
		
		"Did you do battle as well?" 
		
		"In a way, but not until near the very end, and even then only reluctantly and for a short time. I would not say I 'fought in the war' in the same sense I would say that Hades or Zeus did, for instance. Nor even the same sense my parents did."
	#"Are you all right? I don't want to make you think about things that are uncomfortable."
		"Are you all right? I don't want to make you think about things that are uncomfortable." It occurs to you that this might be a sensitive topic, and while she broached it, you are the one who may be pushing it a little further than she intended. 
		
		"On the contrary, ${name}, I believe we must confront uncomfortable things from time to time. As respectful as we all try to be of one another, here, there is nothing to apologize for in asking difficult questions. Especially not when I have given you information that provokes them."
		
		"Then… you probably don't care too much for Olympians, I take it?" Of course, there's another question in here, too. Hades is as much a god of his generation as Zeus is, so shouldn't her dislike extend to him as well? 
		
		Hekate shrugs. "There are traits about the 'typical' example of the Olympian mindset that I do not like," she replies, "as exemplified by Zeus and those who believe as he does. But I don't have any special disdain for them as an entire group, no. In spite of their distaste for me, I do not wish them ill. In a way, they or their forebears played a part in freeing me, so it would hardly seem an appropriate reaction."
*page_break
She sits back with a long sigh, mouth finding its characteristic curl. "All this to say that, perhaps ironically, my family and friends have come to mean much more to me than anything else. I never thought I'd place much value on such a word, once my blood relations were gone, but in point of fact I understand that value more clearly now than I ever did then."

"Do you still consider your parents your family?" 

"Of course I do," she replies, a hint of something like nostalgia crossing her expression. It gives her eyes a softer aspect, like they lose a little of their analytical sharpness, if only for a moment. "Family is not just [i]good[/i] family, to me. If someone else wants to disown theirs, or deny them the word, then that's a fair choice, but it's not one I would ever make. For better and worse, they are my parents. And I their issue. I could neither fully understand nor fully accept myself if I did not acknowledge that." 
*page_break
For a while, you both lapse back into thoughtful silence, though you get the impression that there is perhaps something else Hekate wishes to say. It's hard to pin down why you think so, because she seems perfectly at ease, but it's what you think all the same. 

*if (hekate_confessiondeferred)
	Sure enough, she closes over her book completely and meets your eyes with an ambiguous smile. 
	
	"Speaking of things I would like to acknowledge and accept… I think perhaps it's time I followed up with you. On what we spoke about just after your homecoming. I would like to ask once more after your answer."
	
	*if (tag_unintuitive)
		It takes you several seconds of staring blankly at her to recognize what he must be talking about.
	*if not (tag_unintuitive)
		You recognize what she's talking about immediately, of course. 
	
	She'd admitted to romantic interest in you, shortly after your return from the trial on Olympus. You'd demurred at the time, so as to have longer to think about it, and it [i]has[/i] been a couple of months since then. Plenty of time for your daily life to stabilize, and surely enough time in which to think of some kind of answer for her.
	
	She doesn't seem impatient, exactly, but it is certainly not an unreasonable juncture at which to ask again, even if in some way it [i]feels[/i] quite soon.
	
	*fake_choice
		#@{convotoggle [♥]|} "Thanks for waiting, Hekate. I'm ready to try a relationship with you."
			*set hekate_romance true
			*set overt  +1
			"Thanks for waiting, Hekate. I'm ready to try a relationship with you." It did take you the extra time to be sure, but now that you're settled and more stable, you recognize that your inclinations are nudging you in this direction. You're not exactly sure how it will go, or how things will end up, but for now, you're inclined to try it and see what happens.
			
			Hekate's shoulders ease—you hadn't even realized she was carrying any tension in them, perhaps because you never would have expected it. Her confidence is so complete that you'd have thought she took this to be the obvious answer, only slightly delayed. 
			
			"Delightful," she says, a soft curve gracing her mouth. "Then in that case, there are many other things to talk about, but I hope you will forgive me for putting an obvious question first."
			
			"Such as?"
			*goto hekate_intimatesolo
		#@{convotoggle [♥]|} "I... yes. My answer is yes. I want to be with you, if you still want that, too." 
			*set hekate_romance true
			*set subtle +1
			"I... yes. My answer is yes. I want to be with you, if you still want that, too."  It did take you the extra time to be sure, but now that you're settled and more stable, you recognize that your inclinations are nudging you in this direction. You're not exactly sure how it will go, or how things will end up, but for now, you're inclined to try it and see what happens.
			
			Hekate's shoulders ease—you hadn't even realized she was carrying any tension in them, perhaps because you never would have expected it. Her confidence is so complete that you'd have thought she took this to be the obvious answer, only slightly delayed. 
			
			"Delightful," she says, a soft curve gracing her mouth. "Then in that case, there are many other things to talk about, but I hope you will forgive me for putting an obvious question first."
			
			"Uh, what's that?" you ask, blinking slowly.
			*goto hekate_intimatesolo
		#"I'm sorry, Hekate. I think we're better off as friends and nothing else."
			*set hekate_justfriends true
			*set hekate_rejected true
			"I'm sorry, Hekate. I think we're better off as friends and nothing else."
			
			She nods once, slow and ponderous. "I see. Easily enough done, I suppose."
			
			"I'm—"
			
			"Oh, no, don't misunderstand, ${name}. You've done nothing that needs apologizing for. Your friendship is dear to me, and I am most pleased to be able to keep it, regardless of any little awkward hitch I've put in things."
			*page_break
			Hekate offers a little shrug, something almost diffident in it, if that word could ever be applied to anything about her. "However, I [i]do[/i] admit to feeling slightly awkward right now, so I hope you will be willing to excuse any less than sparkling conversation that results? You're welcome to stay and read with me still, of course." 
	
			*if (tag_unintuitive)
				Honestly, you don't notice anything awkward about her at all, but if she says she's feeling that way, you'll believe her. You [i]also[/i] believe, though, that you're genuinely welcome to stay, and she's still very much your friend, so you do. 
			*if not (tag_unintuitive)
				You can sort of detect that without being told, but you have to give her credit for being able to exhibit small signs of it without making the atmosphere uncomfortable. Perhaps it's because she was so sincere, in saying you really could stay despite it all. So you will.
			
			The both of you return to your reading, and if it's punctuated with slightly fewer questions or scraps of conversation than usual, well… that's all right.

			It's been a good day, minor awkwardness aside, and you don't need it to be anything more than that. 
			*goto chap3end
		#"I know this isn't ideal, but I'm just not ready to decide yet. I'm sorry."
			*set hekate_deferred2 true
			"I know this isn't ideal, but I'm just not ready to decide yet. I'm sorry." You press your lips together. You just don't [i]know[/i]. How are you meant to feel when you want to be with someone? Is it simple attraction, that and some kind of emotional connection? Should those emotions feel distinct from being close friends? 
			
			It's all a jumble in your head, and you just can't bring yourself to say anything decisive until you know more. 
			
			She nods once, slow and ponderous. "I see. Easily enough handled, I suppose."
			
			"I'm—"
			
			"Oh, no, don't misunderstand, ${name}. You've done nothing that needs apologizing for. Your friendship is dear to me, and I am most pleased to be able to keep it, regardless of any little awkward hitch I've put in things. And of course, you are welcome to as much time to decide as you like, though… I would advise that if it takes you too long to be sure, the answer is probably 'no.'" 
			*page_break
			Hekate offers a little shrug, something almost diffident in it, if that word could ever be applied to anything about her. "However, I [i]do[/i] admit to feeling slightly awkward right now, so I hope you will be willing to excuse any less than sparkling conversation that results? You're welcome to stay and read with me still, of course." 
	
			*if (tag_unintuitive)
				Honestly, you don't notice anything awkward about her at all, but if she says she's feeling that way, you'll believe her. You [i]also[/i] believe, though, that you're genuinely welcome to stay, and she's still very much your friend, so you do. 
			*if not (tag_unintuitive)
				You can sort of detect that without being told, but you have to give her credit for being able to exhibit small signs of it without making the atmosphere uncomfortable. Perhaps it's because she was so sincere, in saying you really could stay despite it all. So you will.
			
			The both of you return to your reading, and if it's punctuated with slightly fewer questions or scraps of conversation than usual, well… that's all right.

			It's been a good day, minor awkwardness aside, and you don't need it to be anything more than that. 
			*goto chap3end
*elseif (hekate_mutualconfess)
	Sure enough, she closes over her book completely and meets your eyes with an warm smile. 
	
	"You know… I consider you part of my family, too. And the others, of course. But there's something special about you. There always has been."
	
	*fake_choice
		#"What do you mean?"
			"What do you mean?" You understand that you're special, of course. Just as she's special to you, even among those you consider the closest. But 'always has been' is not a phrase you'd necessarily have associated with her feelings for you. 
			
			"Mm, I wonder." She tilts her head, eyes narrowing. "Anyway, I hope you'll forgive what might come across as a rather uncouth question, in light of my feelings."
			
			"Uncouth?" 
		#@{convotoggle [☆]|} "'Always'? Is this the part where you tell me you fell in love with me at first sight?"
			*set humorous +1
			"'Always'? Is this the part where you tell me you fell in love with me at first sight?" There's a lilt of humor in your words, and her lips twitch at it. 
			
			"Mm, I wonder." She tilts her head, eyes narrowing. "Anyway, I hope you'll forgive what might come across as a rather uncouth question, in light of my feelings."
			
			"And what might that be?" 
		#"I'm not sure 'family' is the word I would use, but there's something special about you, too."
			*set serious +1
			"I'm not sure 'family' is the word I would use, but there's something special about you, too." Because of course there is. The two of you certainly know this about one another already, and you sort of have to wonder why she's bringing it up now. 
			
			"Mm." She tilts her head, eyes narrowing. "I hope you'll forgive what might come across as a rather uncouth question, in light of my feelings."
			
			"I'm sure I could."
		#"Well... that's good, because I feel similarly about you."
			*set serious +1
			Well... that's good, because I feel similarly about you." Because of course you do. The two of you certainly know this about one another already, and you sort of have to wonder why she's bringing it up now. 
			
			"Mm." She tilts her head, eyes narrowing. "I hope you'll forgive what might come across as a rather uncouth question, in light of my feelings."
			
			"I'm sure I could." 
	*page_break
	*label hekate_intimatesolo
	She stands, moving around the table between you to take the chair next to you instead. You're not quite sure why, but there's a hint of mischief in her eyes. "I suppose it's as much a suggestion as a question. About what we might do with some of our time, here. I have to wonder how receptive you might be."

	"I guess that depends on what it is," you reply honestly, and the small smile on her lips tugs wider. 

	"Entirely reasonable. I'll ask, then: how would you feel about it, if things got a little more…" She leans a little closer, 
	*if (touching)
		pressing herself a bit into your arm.
	*if not (touching)
		closing some of the polite distance between you. 
	"Let's say the word I want is 'intimate.' I'd like to kiss you, you see. More than once at a time, as it were."
	*if (hekate_touch2 = "averse")
		Her tone has a note of caution to it, and she tilts her head inquiringly.
	*if (hekate_touch2 != "averse")
		Her tone is lightly-playful, but the question is obviously genuine.

	*fake_choice
		#@{convotoggle [♥]|} "I've been waiting for you to ask something like that."
			*set intimate_touch "fine"
			*set overt +1
			"I've been waiting for you to ask something like that." You smile, swaying a little closer to her, in turn. 
			
			*if (hekate_touch2 = "averse")
				You know you've surprised her, saying something like that. It's in the care she used, even venturing the question. You think she probably expected you to decline.
				
				"I admit," she confirms, a touch wryly. "I wasn't expecting that answer. I was asking just in case your thinking about that sort of touch was different to the other kinds."
				
				"It is," you reply with a small nod. Casual touching for no reason isn't something you like, but intimacy like this is deliberate. Planned, if not necessarily in advance, then at least a few seconds beforehand. You know what you're getting into, and you [i]do[/i] want to be intimate in this way. You can put aside your response to touch long enough to make it work. 
			
			"I'll trust you to be sure," Hekate replies lightly, locking eyes with you. "And to tell me if that changes." 
			
			She doesn't belabor the point, though, running the pad of one finger lightly along the line of your jaw. The touch is almost featherlight, but still angles your head just enough that when your lips meet, they do so fully.
			*goto hekatekissing
		#@{convotoggle [♥]|} "I'd... love to."
			*set intimate_touch "fine"
			*set subtle +1
			"I'd… love to." You smile with a hint of sheepishness, swaying a little closer to her, in turn.
			
			*if (hekate_touch2 = "averse")
				You know you've surprised her, saying something like that. It's in the care she used, even venturing the question. You think she probably expected you to decline.
				
				"I admit," she confirms, a touch wryly. "I wasn't expecting that answer. I was asking just in case your thinking about that sort of touch was different to the other kinds."
				
				"It is," you reply with a small nod. Casual touching for no reason isn't something you like, but intimacy like this is deliberate. Planned, if not necessarily in advance, then at least a few seconds beforehand. You know what you're getting into, and you [i]do[/i] want to be intimate in this way. You can put aside your response to touch long enough to make it work. 
			
			"I'll trust you to be sure," Hekate replies lightly, locking eyes with you. "And to tell me if that changes." 
			
			She doesn't belabor the point, though, running the pad of one finger lightly along the line of your jaw. The touch is almost featherlight, but still angles your head just enough that when your lips meet, they do so fully.
			*goto hekatekissing
		*if not (hekate_mutualconfess)
			#"Hold on. I know we're starting that kind of relationship, but this is a bit too sudden for me."
				*set intimate_touch "fine"
				"Hold on. I know we're starting that kind of relationship, but this is a bit too sudden for me." She's right that people [i]do[/i] those sorts of things, and you're not even against the idea in theory, but you still need to process the change in things before you can consider acting in a new way. 
				
				She huffs gently, leaning back a little to her original position. 
				*if (hekate_touch2 = "averse")
					"I admit, I wasn't expecting that answer. I thought perhaps it was totally out of the question, not just for now. But I thought I'd ask, just in case your thinking about that sort of touch was different to the other kinds."
					
					"It is," you reply with a shrug. Casual touching for no reason isn't something you like, but intimacy like this is deliberate. Planned, if not necessarily in advance, then at least a few seconds beforehand. You know what you're getting into, and you [i]do[/i] want to be intimate in this way. You can put aside your response to touch long enough to make it work. 
					
					Just not quite yet. 
				*if not (hekate_touch2 = "averse")
					"That's all right. I'm more than happy to wait until you feel ready." Her expression is warm, even a little uncharacteristically open, for her. 
				
				She pauses a moment, then holds her hand towards you. "Would you perhaps mind indulging me in something more like this, then?"
				
				It's immediately somehow unexpected that she should offer to hold your hand, but that [i]is[/i] something you can do. 
				*if (hekate_touch2 = "averse")
					It's intimate enough, in this context, that it doesn't feel too offhand or casual, and there's plenty of warning, so you nod. 
				
				Eyes narrowing, she folds her hand over your own.
				*goto hekate_holdhands
		#"I really don't like kissing, if I'm being honest."
			*set kissing "dislike"
			"I really don't like kissing, if I'm being honest." You clear your throat, only a little awkwardly, and shrug. You know she'd rather know. You've tried it, once or twice, and it's never been something you enjoyed. Even the idea of it just makes you uncomfortable, if you really think about it for more than a couple of seconds. 
			
			"Entirely fair," Hekate says, with a soft huff. "It's such a strange thing if you think about it, isn't it? Putting your mouth to someone else's. I used to be rather disgusted by the thought, myself." 
			
			"What changed your mind?"
			
			She lifts her shoulders, casually letting them fall again. "The way it felt. But it seems that hasn't changed your mind, so let's think about alternatives, hm? What about holding each other?"
			
			*label hekate_nokissmenu2
			*if (hekate_touch2 = "averse")
				She frowns. "Ah, but, that might be a little too close to other kinds of touching, right? Perhaps a poor suggestion."
				
				There's a pause there, though, a clear opening for you to confirm or deny the hypothesis.
				
				*fake_choice
					#"I just can't do touching. Not in any form. So this is going to need to be a relationship without any of the physical stuff. Okay?" 
						*set intimate_touch "averse"
						"I just can't do touching. Not in any form. So this is going to need to be a relationship without any of the physical stuff. Okay?" In a way, it's a relief to be able to say that. It had never seemed quite the right time to bring it up in conversation before. Different people are okay or not with different amounts and kinds of touch, you know, but you just can't do any of it. 
						
						It's been on your mind for a while, that this might be something of a problem. Most people enter into relationships like this expecting [i]some[/i] kind of physical intimacy, but it's not something you can give. 
						
						If she's not going to be able to cope with that, it would be much better to know now.
						
						Hekate hums, but her expression is thoughtful, you think, and she isn't giving you any sense of disappointment. 
						
						"All right," she says, nodding slowly. "That's clear now, so I'd like to ask you a separate question. "Do you feel any desire for sexual intimacy at all? Or do you desire me in a sexual way? Don't worry about touching for a moment." 
						
						*label hekate_acequestion2
						*fake_choice
							#"I do, yes. I just... the not-touching part is more urgent, if that makes sense." 
								"I do, yes. I just... the not-touching part is more urgent, if that makes sense." You're not entirely sure it does, but this is not the easiest subject matter to talk about, considering how little practice you have. 
								
								Hekate, though, seems to be entirely unfazed. "All right. That's simple enough. We just need to explore ways of being together that don't have to involve touching one another." 
								
								"You have some kind of idea?" 
								
								"Ideas," she corrects, with a hint of mischief in her smile. "Nothing for today, but some things that might suit us in the future. For the meantime, shall we get back to our research?" 
								
								She makes the offer, but she doesn't get up to return to her place, instead pulling her materials over to her new seat with the crook of a finger.
								
								*label hekate_transitionout2
								*fake_choice
									#@{convotoggle [☆]|} "It's a little unfair to leave me hanging like this, you know. But sure; let's do that."
										*set humorous +1
										"It's a little unfair to leave me hanging like this, you know. But sure; let's do that." You offer her a grin for the jest, and she returns it with a subtler smile. 
										
										"Anticipation is one of the keys to exchanges like this, you know. Intimacy is at least as much about the mind as the body, and we especially are going to be counting on the truth of that." 
										
										You don't know that you've ever thought about it in that way, but she seems to know what she's talking about, and there's no reason not to at least try. 
										
										So you reach for for your book, letting the things she's said percolate at the back of your mind quietly, for now.
										*goto chap3end
									#"If you think that's what's best, then sure." 
										*set serious +1
										"If you think that's what's best, then sure." You offer a small shrug, and she returns it with a subtle smile. 
										
										"Anticipation is one of the keys to exchanges like this, you know. Intimacy is at least as much about the mind as the body, and we especially are going to be counting on the truth of that." 
										
										You don't know that you've ever thought about it in that way, but she seems to know what she's talking about, and there's no reason not to at least try. 
										
										So you reach for your book, letting the things she's said percolate at the back of your mind quietly, for now.
										*goto chap3end
									#@{convotoggle [♥]|} "I'll look forward to hearing more about what you just said, but all right." 
										"I'll look forward to hearing more about what you just said, but all right." You arch an eyebrow slightly at her, lips curling, and she returns the expression with a subtle smile of her own. 
										
										"Anticipation is one of the keys to exchanges like this, you know. Intimacy is at least as much about the mind as the body, and we especially are going to be counting on the truth of that." 
										
										You don't know that you've ever thought about it in that way, but she seems to know what she's talking about, and there's no reason not to at least try. 
										
										So you reach for your book, letting the things she's said percolate at the back of your mind quietly, for now.
										*goto chap3end
									#I nod slowly, reaching for my book again.
										You nod slowly, reaching for your book again. If she thinks that's for the best, you don't have any arguments to the contrary, after all. 
										
										Seeing this, Hekate offers you a subtle smile. 
										
										"Anticipation is one of the keys to exchanges like this, you know. Intimacy is at least as much about the mind as the body, and we especially are going to be counting on the truth of that." 
										
										You don't know that you've ever thought about it in that way, but she seems to know what she's talking about, and there's no reason not to at least try. 
										
										So you return to your previous page, letting the things she's said percolate at the back of your mind quietly, for now.
										*goto chap3end
							#"I'm not sure. I think so, but the other part complicates my feelings, too. I don't know if I can keep them completely separate." 
								"I'm not sure. I think so, but the other part complicates my feelings, too. I don't know if I can keep them completely separate." It's hard to explain, but you say it as well as you can anyway, hoping that she understands. 
								
								Hekate, as it happens, seems quite unfazed. "Okay. I can see where that would be difficult. But it should be simple enough to figure out. We just need to explore ways of being together that don't have to involve touching one another. If you enjoy it, you'll know one way, and if you don't, we can avoid that sort of thing from there out." 
								
								"You have some kind of idea?" 
								
								"Ideas," she corrects, with a hint of mischief in her smile. "Nothing for today, but some things that might suit us in the future. For the meantime, shall we get back to our research?" 
								
								She makes the offer, but she doesn't get up to return to her place, instead pulling her materials over to her new seat with the crook of a finger.
								*goto hekate_transitionout
							#"No. I've never wanted anyone in what I would describe as a sexual way. My feelings for you are real, but not like that."
								*set tag_ace true
								"No. I've never wanted anyone in what I would describe as a sexual way. My feelings for you are real, but not like that." The same sense of awkwardness that had made the first part difficult to say are still there—just amplified. 
								
								But Hekate seems quite unfazed. "All right," she says, with a single simple nod. "That makes things quite uncomplicated, doesn't it?" A hint of a smile curls her lips. 
								
								*if (confident > unsure)
									"Is that going to be any kind of issue?"
								*if not (confident > unsure)
									"Is that… are you okay with that?" 
								You get the sense that she is of a very different mind, when it comes to sexuality. 
								
								"It's not a problem at all," she replies, one eyebrow arcing over the other. "I'm not with you because I desire you, ${name}. I [i]do[/i], but it's comparatively quite an easy feeling to ignore, for me. And trust me when I say I know how to take care of my own needs. so there's nothing to be concerned about, all right?"
								
								A welling feeling of relief spreads from your guts up into your chest, and you let out a soft breath. You're glad to hear it, and when you tell Hekate so, she laughs gently. 
								
								"You know, I had a feeling it was possible," she observes. "But even if it'd surprised me, it's not so uncommon, you know? I've met plenty of people who have no desire for sex." She shakes her head. 
								
								"Anyway, what say you we get back to our research?" She makes the offer, but she doesn't get up to return to her place, instead pulling her materials over to her new seat with the crook of a finger.
								
								"Sure." You pick your book up again, as well. That's something that could have been a hurdle in your relationship cleared with aplomb, and you can't deny the way it helps you relax. 
								
								That feeling of sweet ease lasts through the rest of the afternoon.
								*goto chap3end
							#"No, but... I would like to be intimate with you regardless. If that makes sense."
								*set tag_posace true
								"No, but... I would like to be intimate with you regardless. If that makes sense." She's right that it [i]is[/i] a separate question, and in your case, at least, the answers diverge a little. Your aversion to touch is not a total aversion to sexuality. You don't feel any real [i]desire[/i] for that sort of thing, but if she does, you don't mind sharing that experience with her on occasion. 
								
								Hekate considers this for a moment and nods. "All right," she says, tone relaxed. "We'll figure that part out as we go. I'm rather experienced at taking care of myself, so it's not as though I [i]need[/i] anything I don't already have, in that realm. But if you're ever curious or want that type of closeness, let me know." 
								
								Her eyes flick across the table, for a moment, and she turns back to you with a conspiratorial smile. "Anyway, what say you we get back to our research?" She makes the offer, but she doesn't get up to return to her place, instead pulling her materials over to her new seat with the crook of a finger.
								
								"Sure." You pick your book up again, as well. That's something that could have been a hurdle in your relationship cleared with aplomb, and you can't deny the way it helps you relax. 
								
								That feeling of sweet ease lasts through the rest of the afternoon.
								*goto chap3end
					#"I do understand that if we want to have any kind of sexual relationship, we'll have to touch sometimes. I just really don't like this kind."
						*set intimate_touch "middling"
						"I do understand that if we want to have any kind of sexual relationship, we'll have to touch sometimes. I just really don't like this kind."
						
						Hekate considers this for a moment, humming softly. "So, to be clear, you're all right with being touched in a sexual way, as long as it isn't kissing specifically?"
						
						"More or less." There are nuances, but you're sure you can address those when they come up. [i]If[/i] they do. Rather than just trying to list them all, or something like that, it seems best to handle organically.
						
						"Interesting…" There's a playful lilt to her tone, and you blink.
						
						"You have an idea?"
						
						"Ideas," she corrects, with a hint of mischief in her smile. "Nothing for today, but some things that might suit us in the future. For the meantime, shall we get back to our research?" 
								
						She makes the offer, but she doesn't get up to return to her place, instead pulling her materials over to her new seat with the crook of a finger.
						*goto hekate_transitionout2
					#"I don't like being touched casually, and I don't want to be kissed on the mouth, but other kinds of touching or kissing in this context are okay."
						*set intimate_touch "fine"
						*set kissing "notface"
						"I don't like being touched casually, and I don't want to be kissed on the mouth, but other kinds of touching or kissing in this context are okay."
						
						Hekate considers this for a moment, humming softly. "So, to be clear, you're all right with being touched in a sexual way, as long as it isn't kissing on the mouth specifically?"
						
						"Yes, that's basically it." You don't mind clarifying; you have a feeling this is not a specific combination of preferences she's likely to have run across before. 
						
						"Interesting…" There's a playful lilt to her tone, and you blink.
						
						"You have an idea?"
						
						"Ideas," she corrects, with a hint of mischief in her smile. "Nothing for today, but some things that might suit us in the future. For the meantime, shall we get back to our research?" 
								
						She makes the offer, but she doesn't get up to return to her place, instead pulling her materials over to her new seat with the crook of a finger.
						*goto hekate_transitionout2
					#"I don't like being touched casually, or any kind of kissing, but other kinds of touching in this context are okay."
						*set intimate_touch "fine"
						"I don't like being touched casually, or any kind of kissing, but other kinds of touching in this context are okay."
						
						Hekate considers this for a moment, humming softly. "So, to be clear, you're all right with being touched in a sexual way, as long as it isn't kissing specifically?"
						
						"Yes, that's basically it." You don't mind clarifying; you have a feeling this is not a specific combination of preferences she's likely to have run across before. 
						
						"Interesting…" There's a playful lilt to her tone, and you blink.
						
						"You have an idea?"
						
						"Ideas," she corrects, with a hint of mischief in her smile. "Nothing for today, but some things that might suit us in the future. For the meantime, shall we get back to our research?" 
								
						She makes the offer, but she doesn't get up to return to her place, instead pulling her materials over to her new seat with the crook of a finger.
						*goto hekate_transitionout2
			*if (hekate_touch2 != "averse")
				She tilts her head. "Would that be a suitable substitution?"
				
				*fake_choice
					#@{convotoggle [♥]|} "Yes, definitely. I'd love to."
						"Yes, definitely. I'd love to." That sounds much more enjoyable, and you find even the notion itself puts a little grain of warmth in the pit of your stomach. 
						
						"Ah, excellent. My only other suggestion for today at least was to keep at the research. Which I wouldn't mind, of course, but this is something altogether preferable to me." 

						*label hekate_gettingsettled2
						Standing, Hekate offers a hand down to you, and you slip yours into it, not pulling against her too hard as you find your feet. She leads you over to one of the library's few, scattered reclined couches for reading, and hums thoughtfully. 
						
						*if (height > 3)
							"You're taller than me, though I don't think that's necessarily the relevant point, here. Would you prefer to lay down first or second?"
						*if (height <= 3)
							"Our heights aren't too different, though I don't think that's necessarily the relevant point here, anyway. Would you prefer to lay down first or second?"
						
						First would likely mean that she's against you, possibly with her head atop you in some way, while second would be the opposite, you suppose. There's certainly going to be a lot of contact involved, if you're both going to fit on the couch lengthways.
						
						*fake_choice
							#"I'll go first."
								"I'll go first." 
								
								You get yourself settled against the reclined arm, stretching your legs out in along the cushions and making yourself comfortable. With a gesture, you invite Hekate to take a place as well, and she climbs on, maneuvering her long tunic layers and tucking herself into your side. Her temple comes to rest against the front of your shoulder, and she throws an arm over your waist, whether for stability or just to enjoy the contact isn't clear, and probably doesn't much matter. 
								
								You wind your arm around her back, your other loose at your opposite side, and let out a breath.
								*page_break
								*goto hekate_cuddle
							#"I'll go second."
								"I'll go second." 
								
								She gets herself settled against the reclined arm, stretching her legs out along the cushions and shifting her tunic's hem about until she's comfortable. Then she invites you on with a small gesture and a smile, and you climb into place, tucking yourself against her side and wrapping an arm around her middle, letting your head rest just inside the front of her shoulder. 
								
								It leaves you looking down at the swell of her chest, mostly, but it's undeniably comfortable, and she winds her arm around your back, letting the one on the opposite side of you rest loosely next to her. 
								*page_break
								*goto hekate_cuddle
					#"I suppose we could do something like that, sure."
						"I suppose we could do something like that, sure." You can't claim to be [i]overjoyed[/i] by the idea, but it sounds nice enough. You [i]have[/i] put paid to the other idea she had, and it's not as though you want to reject her, either. A bit of proximity could be enjoyable. 
						
						"Ah, excellent. My only other suggestion for today at least was to finish our game. Which I wouldn't mind, of course, but this is something altogether preferable to me."						
						*goto hekate_gettingsettled2
					#@{convotoggle [♥]|} "You can kiss me places that aren't my mouth, just so you know. But cuddling is also fine."
						*set kissing "notface"
						"You can kiss me places that aren't my mouth, just so you know. But cuddling is also fine." You offer her a small smile, and she returns it with a chuckle. 
						
						"That is something I'll keep in mind. For now, though, I rather think being holding and being held sounds delightful. My only other suggestion for today at least was to finish our game. Which I wouldn't mind, of course, but this is something altogether preferable to me."						
						*goto hekate_gettingsettled2
					#@{convotoggle [♥]|} "Could we just... hold hands for now?"
						"Could we just... hold hands for now?" You hate to say no yet again, but it's important that you're honest, and that degree of contact just doesn't feel like something you're quite up to, right now. But you still want to be close with her. 
						
						Hekate considers this for a moment, though you're not exactly sure why, because her answer doesn't come out like something she had to think about. "Of course we can."
						
						*if (touching)
							You're already close, and she only has to shift her hand a little to grasp yours, pressing her palm gently against your own.
						*if not (touching)
							You're not sitting so far apart that she can't reach, and you meet her halfway over that distance. She grasps your hand, pressing her palm gently against your own. 
						
						*label hekate_holdhands
						"You know," she offers, her lips tilting slightly upwards again. "I'm not one of those people who thinks of some forms of intimacy as 'more' than others. They're different, to be sure, and some of them can be more than one type, but I've never been fond of the idea that something like this is 'less than' a kiss, or whatever else." 
						
						*fake_choice
							#"It really is, though, isn't it? Less intimate?"
								"It really is, though, isn't it? Less intimate?" You press your lips together. You do think that there is more intimacy to some acts than others. Saying they're all basically on the same level and differ only by type seems a bit… well. You're not really sure how she could think that. 
								
								"Not to me," she replies with a small shrug. "I think it comes down to how you think about things. It's possible to have sex without any intimacy involved at all. Whereas something as simple as holding hands can be very significant, in the right context. It's not about the act. It's about the way the people involved are approaching it."
								
								You suppose there's some truth to that, at least, but you're not entirely sure if you're convinced just yet. 
								
								Perhaps inferring as much, she chuckles. "Well, in any event, know that [i]I[/i] find this very satisfying, and that I am not disappointed that this is where we wound up. At the very least I think we can agree that the only intimacy worth the name is the kind we both enjoy, no?"
								
								That much, at least, is entirely correct. 
							#"That's a relief to hear. A lot of the things that people think of as 'more,' I'm not really sure about."
								"That's a relief to hear. A lot of the things that people think of as 'more,' I'm not really sure about." Perhaps it's just a lack of familiarity, but you don't particularly need to figure out exactly why that is right now. 
								
								Hekate, after all, doesn't ask. 
								
								"That's more than fine," she replies, giving your hand a comforting squeeze. "Whatever happens, we just do what we're comfortable with, and that'll always be enough." 
								
								Her lips twitch. "In any event, know that I find this very satisfying, and that I am not disappointed that this is where we wound up. At the very least I think we can agree that the only intimacy worth the name is the kind we both enjoy, no?"
								
								That much, at least, is entirely correct. 
							#"I hadn't been thinking of this as less than anything else, either." 
								"I hadn't been thinking of this as less than anything else, either." Maybe you can see a sense in which it is, but only one, and probably not even the most important one, presently. 
								
								"Ah, good, then. I'm glad to hear you don't think so." Hekate gives your hand a playful squeeze. 
								
								Her lips twitch. "In any event, know that I find this very satisfying, and that I am not disappointed that this is where we wound up. I'm sure we can agree that the only intimacy worth the name is the kind we both enjoy, no?"
								
								That much is entirely correct. 
							#"What do you mean by more than one type?"
								"What do you mean by more than one type?" You aren't sure you completely grasped what she was saying, given the vagueness of some of her terms. 
								
								"Ah. Nothing too profound or anything. I just meant that certain things could be intimate in more than one way. Like… holding hands could express that I'm your friend, or that I'm romantically involved with you, or both at the same time. It doesn't mean that, when used to express the romantic part, that it's any less so than another form of expression would be. At least, not to me." 
								
								You nod slowly. That makes sense, you suppose. People can do all kinds of things with all kinds of intentions. That doesn't have to affect the meaning of the things [i]you[/i] do. 
								
								Her lips twitch. "In any event, know that I find this very satisfying, and that I am not disappointed that this is where we wound up. I'm sure we can agree that the only intimacy worth the name is the kind we both enjoy, no?"
								
								That much is entirely correct. 
						*page_break
						Her thumb rubs over the back of your hand, tracing the shapes of your knuckles, and Hekate lets out a soft breath, leaning back against the sofa behind both of you. "Either way, this is exactly what I need, right now."
						
						It feels nice, if also a little strange. Like your awareness has narrowed to so few things that everything about them is more apparent to you. The drag of her fingertip, which could in another context be something you easily ignored, seems to take the lion's share of your attention, now. 
						
						But it isn't a focus that comes with any sense of urgency. You don't need to do anything about it. Don't need to act a certain way, or try to think about anything else. You can just… sit here and enjoy it, for a little while. Enjoy talking to Hekate. 
						
						And right now, that feels like everything you want.
						*goto chap3end
		#"I really don't like the idea of kissing, if I'm being honest." 
			*set kissing "dislike"
			"I really don't like the idea of kissing, if I'm being honest." You clear your throat, only a little awkwardly, and shrug. You know she'd rather know. You've never tried it, but you know you don't want to. Even the idea of it just makes you uncomfortable, if you really think about it for more than a couple of seconds. 
			
			"Entirely fair," Hekate says, with a soft huff. "It's such a strange thing if you think about it, isn't it? Putting your mouth to someone else's. I used to be rather disgusted by the thought, myself." 
			
			"What changed your mind?"
			
			She lifts her shoulders, casually letting them fall again. "The way it felt. But you and I are different people, and you seem certain, so let's think about alternatives, hm? What about holding each other?"
			*goto hekate_nokissmenu2
		*if (hekate_touch2 = "averse")
			#"You know I don't like touching. This is no different. We're going to need to have a relationship without any of the physical stuff, okay?" 
				*set kissing "dislike"
				*set intimate_touch "averse"
				"You know I don't like touching. This is no different. We're going to need to have a relationship without any of the physical stuff, okay?" You suppose it was a fair thing for her to ask about, because, well… casual touch and intimate touch [i]are[/i] different things. You, however, don't think of them all that differently.
				
				It's been on your mind for a while, that this might be something of a problem. Most people enter into relationships like this expecting [i]some[/i] kind of physical intimacy, but it's not something you can give. 
						
				If she's not going to be able to cope with that, it would be much better to know now.

				Hekate hums, but her expression is thoughtful, you think, and she isn't giving you any sense of disappointment. 

				"All right," she says, nodding slowly. "That's clear now, so I'd like to ask you a separate question. Do you feel any desire for sexual intimacy at all? Or do you desire me in a sexual way? Don't worry about touching for a moment." 
				*goto hekate_acequestion2
	*goto chap3end
*elseif (hekate_justfriends)
	Sure enough, she closes over her book completely and meets your eyes with an ambiguous smile. 
	
	"You know… perhaps this is so obvious that it hardly bears saying, but… I do consider you family, now. You and the others. I hope that doesn't seem too onerous a burden." 
	
	*fake_choice
		#"Of course it isn't a burden."
			"Of course it isn't a burden." You're trying to imagine how something like that [i]could[/i] be, and frankly getting nowhere. It's a great comfort, to know that you're cared about so much, and you're quite relieved to have settled so readily into a bond like this. They're not common in your life, in the least. 
			
			"Good to know," she replies with a little chuckle. "I just felt like I should say it, since we were on the topic already."
		#"Well, maybe it is, after a fashion, but it's one I bear gladly, and I hope you'll shoulder the same feelings from me."
			"Well, maybe it is, after a fashion, but it's one I bear gladly, and I hope you'll shoulder the same feelings from me." Certainly, there's a certain weight that comes with such things. A responsibility to do right by one another in a way that exceeds your obligations to someone else. But it's not an [i]onerous[/i] burden, as she'd put it. Not in the least. 
			
			"That's a good way of putting it," she replies with a little chuckle, "and I certainly will." 
		#"I don't know if I'd use the word 'family,' but you [i]are[/i] important to me just the same."
			"I don't know if I'd use the word 'family,' but you [i]are[/i] important to me just the same." You think, perhaps, sometimes the word is overused, when 'friends' is perfectly serviceable and descriptive. Besides, a friend is someone you chose, and family… isn't necessarily that. You'd prefer to emphasize that, were you to describe how you feel about her to anyone else. 
			
			"You know, that's fair," she replies with a small nod, expression thoughtful. "I think I'm equally happy to be called either, so use what you prefer, my friend."
	*page_break
	It's easy, with that said, for both of you to return to your reading. There's a sense of warmth to her company, even if the conversation tapers off to nearly nothing, and by the time you're finished, you're deeply relaxed, at home in a way you haven't always felt, even here.
	
	It's been a good day, and you're quite content with that.
	*goto chap3end
*elseif (npc_init)
	Sure enough, she closes over her book completely and meets your eyes with an ambiguous smile. 
	
	"There was something I wanted to ask you about," she admits, tilting her head a little. "Since we've been on the topic of people close to us. I thought, perhaps, I'd been pondering things long enough. So please allow me to ask you: if I were to say I had developed… certain feelings, with respect to you, would you perhaps be interested in pursuing such a connection?"
	
	*label hekateconfess2
	*fake_choice
		*if (tag_unintuitive)
			*disable_reuse #@{convotoggle [❋]|} "I... don't think I see what you're getting at, sorry. Can you just say whatever it is?"
				"I... don't think I see what you're getting at, sorry. Can you just say whatever it is?" Your brows knit. It's a bit unfortunate, because she seems to be choosing her words carefully, but you just don't… get it. 
				 
				She huffs softly, lips quirking. "I suppose that's on me. Allow me to say it this way, then: would you be interested in a romantic relationship with me?" 
				
				"Oh. That's what you meant." 
				
				Her laugh is light, almost a giggle. "So it is. Answer honestly, now; that's the most important thing." 
				
				You can certainly manage that.
				*goto hekateconfess2
		#@{convotoggle [♥]|} "I do think of you that way, yes. Or at least, I think it would be nice if we were in that kind of relationship."
			*set hekate_romance true
			"I do think of you that way, yes. Or at least, I think it would be nice if we were in that kind of relationship." In the end, the words come to you easily. Simply, without any hesitation or particular playfulness, either. It just is how you feel, and plain sincerity seems like the best way to convey something of such import. 
			
			Hekate's shoulders ease—you hadn't even realized she was carrying any tension in them, perhaps because you never would have expected it. Her confidence is so complete that you'd have thought she took this to be the obvious answer. 
			
			"Delightful," she says, a soft curve gracing her mouth. "Then in that case, there are many other things to talk about, but I hope you will forgive me for putting an obvious question first."
			
			"What's that?" you ask, blinking slowly.
			*page_break
			*goto hekate_intimatesolo
		#@{convotoggle [♥]|} "I actually hadn't thought about it much before, but... I think I'd like to give something like that a try."
			*set hekate_romance true
			"I actually hadn't thought about it much before, but... I think I'd like to give something like that a try." In the end, the words come to you easily. Simply, without any hesitation or particular playfulness, either. It just is how you feel, and plain sincerity seems like the best way to convey something of such import. 
			
			It may not have much crossed your mind, before, but hearing the words feels like something [i]clicks[/i] in your head, fitting several things together that hadn't made the most sense until now. Until you could categorize them with this kind of feeling.

			Hekate's shoulders ease—you hadn't even realized she was carrying any tension in them, perhaps because you never would have expected it. Her confidence is so complete that you'd have thought she took this to be the obvious answer. 
			
			"Delightful," she says, a soft curve gracing her mouth. "Then in that case, there are many other things to talk about, but I hope you will forgive me for putting an obvious question first."
			
			"Uh, what's that?" you ask, blinking slowly.
			*page_break
			*goto hekate_intimatesolo
		#@{convotoggle [♥]|} "I've been waiting for you to ask me that for a while now."
			*set hekate_romance true
			*set overt +1
			"I've been waiting for you to ask me that for a while now." You don't mince your words about it, but the little smile you give her is a wry one, accompanied by a slight rolling of your eyes. "It took you long enough to catch up."
			
			"Have you, now?" Her smile is full, blooming over her face with a relaxed ease. "Then in that case, there are many other things to talk about, but I hope you will forgive me for putting an obvious question first."
			
			"Such as?" You can think of a few possibilities, but you're curious as to which she has in mind.
			*page_break
			*goto hekate_intimatesolo
		#{convotoggle [♥]|} "Yes! I mean... yes. I do think of you like that. I have for... a bit, now."
			*set hekate_romance true
			*set subtle +1
			"Yes! I mean... yes. I do think of you like that. I have for... a bit, now." You wince at your initial answer, quickly amending at a much softer volume. It's not easy for you to talk about things like this; most often your words are awkward, or you blurt them, or whatever else. But you couldn't risk being unclear [i]now[/i] of all times, and what emerged as your answer was honest, even if it wasn't elegant. 
			
			Hekate's shoulders ease—you hadn't even realized she was carrying any tension in them, perhaps because you never would have expected it. Her confidence is so complete that you'd have thought she took this to be the obvious answer. 
			
			"Delightful," she says, a soft curve gracing her mouth. "Then in that case, there are many other things to talk about, but I hope you will forgive me for putting an obvious question first."
			
			"Uh, what's that?" you ask, blinking slowly.
			*page_break
			*goto hekate_intimatesolo
		#"I'm sorry, Hekate. You're a good friend, but that's how I think about you. There's no other component to it."
			*set hekate_justfriends true
			*set hekate_rejected true
			"I'm sorry, Hekate. You're a good friend, but that's how I think about you. There's no other component to it."
			
			She nods once, slow and ponderous. "I see. Easily enough done, I suppose."
			
			"I'm—"
			
			"Oh, no, don't misunderstand, ${name}. You've done nothing that needs apologizing for. Your friendship is dear to me, and I am most pleased to be able to keep it, regardless of any little awkward hitch I've put in things."
			*page_break
			Hekate offers a little shrug, something almost diffident in it, if that word could ever be applied to anything about her. "However, I [i]do[/i] admit to feeling slightly awkward right now, so I hope you will be willing to excuse any less than sparkling conversation that results? You're welcome to stay and read with me still, of course." 
	
			*if (tag_unintuitive)
				Honestly, you don't notice anything awkward about her at all, but if she says she's feeling that way, you'll believe her. You [i]also[/i] believe, though, that you're genuinely welcome to stay, and she's still very much your friend, so you do. 
			*if not (tag_unintuitive)
				You can sort of detect that without being told, but you have to give her credit for being able to exhibit small signs of it without making the atmosphere uncomfortable. Perhaps it's because she was so sincere, in saying you really could stay despite it all. So you will.
			
			The both of you return to your reading, and if it's punctuated with slightly fewer questions or scraps of conversation than usual, well… that's all right.

			It's been a good day, minor awkwardness aside, and you don't need it to be anything more than that. 
			*goto chap3end
		#"I... I won't say I haven't ever considered it, but I'm not ready to make a decision about what I want, just yet. Can you ask me again later?"
			*set hekate_deferred2 true
			"I... I won't say I haven't ever considered it, but I'm not ready to make a decision about what I want, just yet. Can you ask me again later?" There's just too much going on in your life right now for you to feel like you can make a decision about this. At least now you know you need to consider it seriously and come up with an answer for her, instead of speculating about that part. 
			
			She nods once, slow and ponderous. "I see. Easily enough handled, I suppose."
			
			"I'm—"
			
			"Oh, no, don't misunderstand, ${name}. You've done nothing that needs apologizing for. Your friendship is dear to me, and I am most pleased to be able to keep it, regardless of any little awkward hitch I've put in things. And of course, you are welcome to as much time to decide as you like, though… I would advise that if it takes you too long to be sure, the answer is probably 'no.'" 
			*page_break
			Hekate offers a little shrug, something almost diffident in it, if that word could ever be applied to anything about her. "However, I [i]do[/i] admit to feeling slightly awkward right now, so I hope you will be willing to excuse any less than sparkling conversation that results? You're welcome to stay and read with me still, of course." 
	
			*if (tag_unintuitive)
				Honestly, you don't notice anything awkward about her at all, but if she says she's feeling that way, you'll believe her. You [i]also[/i] believe, though, that you're genuinely welcome to stay, and she's still very much your friend, so you do. 
			*if not (tag_unintuitive)
				You can sort of detect that without being told, but you have to give her credit for being able to exhibit small signs of it without making the atmosphere uncomfortable. Perhaps it's because she was so sincere, in saying you really could stay despite it all. So you will.
			
			The both of you return to your reading, and if it's punctuated with slightly fewer questions or scraps of conversation than usual, well… that's all right.

			It's been a good day, minor awkwardness aside, and you don't need it to be anything more than that. 
			*goto chap3end
*else
	Sure enough, she closes over her book completely and meets your eyes with an ambiguous smile. 
	
	"You know… perhaps this is so obvious that it hardly bears saying, but… I do consider you family, now. I hope that doesn't seem too onerous a burden." 
	
	*fake_choice
		#@{convotoggle [♥]|} "I've been thinking of you a little bit differently." More like someone I might want to court, in fact.
			*set hekate_romance true
			*set overt +1
			"I've been thinking of you a little bit differently." More like someone you might want to court, in fact. She's not completely wrong to use the word 'family' or anything, but you do think of her very separately from the way you think of the others. 
			
			Hekate blinks, surprised, and then smiles a bit. "Is that so? I'm not sure I was expecting that, but I can't say I dislike hearing it. Perhaps we could give… some sort of liaison a try?"
		#@{convotoggle [♥]|} "Not onerous, just... is there a chance that perhaps that's not all there is to it?"
			*set hekate_romance true
			*set subtle +1
			"Not onerous, just... is there a chance that perhaps that's not all there is to it?" You swallow a little bit past the small lump at the back of your throat. It feels like your nerves are live at once, like a mild breeze would knock you over, but you ask anyway. 
			
			She studies you for a long moment, then slowly shakes her head. "Not [i]all[/i] there is to it, to borrow your phrasing. But I must ask, ${name}. Are you perhaps suggesting that the two of us pursue a liaison of a more romantic nature?"
		#It's a nice thing to say, certainly, and pretty much exactly what I want out of our relationship. I have a strong affinity for Hekate, and it's decidedly platonic. 
			*set hekate_justfriends true
			It's a nice thing to say, certainly, and pretty much exactly what I want out of our relationship. I have a strong affinity for Hekate, and it's decidedly platonic. 
			
			"Thank you, Hekate. I think much the same of you." 
			
			It's easy, with that said, for both of you to return to your reading. There's a sense of warmth to her company, even if the conversation tapers off to nearly nothing, and by the time you're finished, you're deeply relaxed, at home in a way you haven't always felt, even here.
	
			It's been a good day, and you're quite content with that.
			*goto chap3end
		#I sort of want to ask if maybe there's a chance she has [i]other[/i] feelings, too, but I'm not sure I'm quite ready for the discussion, just yet. 
			You sort of want to ask if maybe there's a chance she has [i]other[/i] feelings, too, but you're not sure you're quite ready for the discussion, just yet. It could change an awful lot of things, and not for the better if you aren't certain when you broach the topic. Plus, it's… hard to guess what the chances might be, because Hekate is the sort of person who is always warm and playful, so it's hard to pin down the exact nature of some of her remarks. Like this one.
			
			You just can't risk it, at this point. 
			
			"Thank you, Hekate," you say, because you mean that, but also mostly to have said something without leaving a too-long silence in the middle. 
			
			It's… relatively easy, with that said, for both of you to return to your reading. There's a sense of warmth to her company, even if the conversation tapers off to nearly nothing, and by the time you're finished, you're deeply relaxed, at home in a way you haven't always felt, even here. Even with the subtle disquiet of the unknown.
	
			It's been a good day, and you can be content with that.
			*goto chap3end

	*fake_choice
		#@{convotoggle [♥]|} "I think that would be really nice."
			"I think that would be really nice." In the end, the words come to you easily. Simply, without any hesitation or particular playfulness, either. It just is how you feel, and plain sincerity seems like the best way to convey something of such import. 
			
			Hekate's shoulders ease—you hadn't even realized she was carrying any tension in them, perhaps because you never would have expected it. Her confidence is so complete that you'd have thought she took this to be the obvious answer. 
			
			"Delightful," she says, a soft curve gracing her mouth. "Then in that case, there are many other things to talk about, but I hope you will forgive me for putting an obvious question first."
			
			"What's that?" you ask, blinking slowly.
			*page_break
			*goto hekate_intimatesolo
		#@{convotoggle [♥]|} "I actually hadn't thought about it much before, but... I think I'd like to give something like that a try."
			"I actually hadn't thought about it much before, but... I think I'd like to give something like that a try." In the end, the words come to you easily. Simply, without any hesitation or particular playfulness, either. It just is how you feel, and plain sincerity seems like the best way to convey something of such import. 
			
			It may not have much crossed your mind, before, but saying what you said, and hearing the response feels like something [i]clicks[/i] in your head, fitting several things together that hadn't made the most sense until now. Until you could categorize them with this kind of feeling.

			Hekate's shoulders ease—you hadn't even realized she was carrying any tension in them, perhaps because you never would have expected it. Her confidence is so complete that you'd have thought she took this to be the obvious answer. 
			
			"Delightful," she says, a soft curve gracing her mouth. "Then in that case, there are many other things to talk about, but I hope you will forgive me for putting an obvious question first."
			
			"Uh, what's that?" you ask, blinking slowly.
			*page_break
			*goto hekate_intimatesolo
		#@{convotoggle [♥]|} "I've been waiting for you to ask me that for a while now."
			*set overt +1
			"I've been waiting for you to ask me that for a while now." You don't mince your words about it, but the little smile you give her is a wry one, accompanied by a slight rolling of your eyes. "It took you long enough to catch up."
			
			"Have you, now?" Her smile is full, blooming over her face with a relaxed ease. "Then in that case, there are many other things to talk about, but I hope you will forgive me for putting an obvious question first."
			
			"Such as?" You can think of a few possibilities, but you're curious as to which she has in mind.
			*page_break
			*goto hekate_intimatesolo
		#{convotoggle [♥]|} "Yes! I mean... yes. I would like that. I've thought so for... a bit, now."
			*set subtle +1
			"Yes! I mean... yes. I would like that. I've thought so for... a bit, now." You wince at your initial answer, quickly amending at a much softer volume. It's not easy for you to talk about things like this; most often your words are awkward, or you blurt them, or whatever else. But you couldn't risk being unclear [i]now[/i] of all times, and what emerged as your answer was honest, even if it wasn't elegant. 
			
			Hekate's shoulders ease—you hadn't even realized she was carrying any tension in them, perhaps because you never would have expected it. Her confidence is so complete that you'd have thought she took this to be the obvious answer. 
			
			"Delightful," she says, a soft curve gracing her mouth. "Then in that case, there are many other things to talk about, but I hope you will forgive me for putting an obvious question first."
			
			"Uh, what's that?" you ask, blinking slowly.
			*page_break
			*goto hekate_intimatesolo
*goto chap3end

*label chap3alekto
A few days later, Demeter has returned to Olympus. You're not sure exactly when or if she'll be back, but for now at least, she has obviously seen Iasion and confirmed his identity. What difference it will make in the long run, you can't be sure, but some things are surely worth doing even if they don't change how the world works. 

You wonder, for a moment, what you would do in her position, but the thought is easily enough brushed aside. 
*page_break
Instead, you pick at the small spread in front of you, piling bits and pieces onto your plate. Across from you, Alekto waits politely, her own empty one settled beside her. The slight breeze out in the fields stirs her thick, heavy hair, gently separating the strands in her ponytail and blowing a few of them over one broad shoulder. 

Her armor lies in carefully-arranged pieces on the opposite end of the blanket from both of you, drying out after the morning's activity.

*if (job = "guard")
	Yours, of course, is right beside it. This morning's Guard review had been hands-on, after all, with the two of you putting guards both new and experienced through a series of drills and tests, to check their progress. 
	
	Once you're done picking out what you want to eat for now, Alekto leans a bit forward over her crossed legs to do the same, cutting a small wedge of cheese off the miniature wheel and slicing herself some bread. The thin sheen of sweat on her arms catches the low light overhead.

	"What did you think?" she asks.
	
	*label alekto1
	*fake_choice
		*if (rotation = 0)
			*disable_reuse #@{convotoggle [♥]|} "Hm? Sorry, I was distracted." By her, though I'm not going to say that part.
				*set subtle +1
				*set rotation +1
				"Hm? Sorry, I was distracted." By her, though you're not going to say that part. It'd be a little bit too much for you to want to address, particularly when the distraction was accidental. It's just… sometimes Alekto looks really [i]good[/i], and there's definitely an appeal to the picture she makes after hard work like that. 
				
				She blinks at you, but repeats the question nonetheless. 
				
				"I was asking how you thought the assessment went."
				*goto alekto1
		*if (rotation = 0)
			*disable_reuse #@{convotoggle [♥]|} "Say again? I was too busy looking at you to pay attention."
				*set overt +1
				*set rotation +1
				"Say again? I was too busy looking at you to pay attention." You offer a little grin to go with the words, but there's truth to them. Sometimes Alekto looks really [i]good[/i], and there's definitely an appeal to the picture she makes after hard work like that. 
				
				She blinks at you, clearing her throat softly. It's hard to tell for sure, but you wonder if she isn't just a little bit bashful, at that. 
				
				"…I was asking how you thought the assessment went."
				*goto alekto1
		#"Well... I'm glad they don't actually need to defend us from much, I'll say that."
			"Well... I'm glad they don't actually need to defend us from much, I'll say that." You shake your head a little. You can't say you were all that impressed by anything you saw. Granted, some of the veteran officers are quite good, but overall, you have to wonder if spirits really [i]do[/i] retain some shade of the skills they had in life, because there was very little evidence of it this time around. 
			
			Alekto hums, lifting her hands as she finishes chewing. [i]I didn't think it was so bad,[/i] she says, lifting an eyebrow. [i]One must remember that spirits are still more or less human, and even in this form have similar limitations to those they do in human bodies.[/i]
			
			"Even taking that into account, though…" You click your tongue. "We're probably going to have to add in more drills." 
			
			"That is not a bad idea, in any case."
		#"I was impressed, actually. I haven't gone easy on them, but they're really mastering things quickly."
			"I was impressed, actually. I haven't gone easy on them, but they're really mastering things quickly." You tilt your head a little. One has to remember human limitation, of course; even in their present forms, spirits have similar physical capabilities to the humans they once were. But when you look at things through that lens, they're actually quite extraordinary, collectively speaking. 
			
			Alekto hums, lifting her hands as she finishes chewing. [i]I think their increased regimen is showing,[/i] she observes. [i]It is good for improvement, but a few also seemed a tad weary. May I suggest a rest period before training resumes?[/i]
			
			You nod slowly. "I noticed that, too. So probably not a bad idea. Honestly, at this point I could likely afford to push them a little less. They're all up to a good standard, after all. Now they need to focus on maintaining it." 
			
			"That is sound thinking."
		#"I think it was okay. There's still room for improvement, but they are getting better."
			"I think it was okay. There's still room for improvement, but they are getting better." You tilt your head a little. One has to remember human limitation, of course; even in their present forms, spirits have similar physical capabilities to the humans they once were. But even with that considered, they're still not quite where you'd most prefer them to be.
			
			Alekto hums, lifting her hands as she finishes chewing. [i]They are improving, though,[/i] she observes, [i]and their regimen has not fatigued anyone too much, which is a good sign. Keep at it, and I think the rest will get there.[/i]
			
			You nod slowly. "You're probably right. Time is the key factor, at this point." 
			
			"Which is good. You have plenty of it."
	*page_break
*if (job != "guard")
	She's just finished a Guard review, apparently. You saw the end of it—quite clearly, she and @{megaira_dead Tisiphone|her sisters} had been putting the recruits and veterans alike through their paces. Some of them seemed downright exhausted. 
	
	Once you're done picking out what you want to eat for now, Alekto leans a bit forward over her crossed legs to do the same, cutting a small wedge of cheese off the miniature wheel and slicing herself some bread. The thin sheen of sweat on her arms catches the low light overhead.
	
	"Do you…" she pauses, words slowing, and sets the knife down. "I think I may have been working the Guard too strictly. It is clear that they need to rest, and yet I am not sure that when I tell them this, all of them listen. I wonder how I might encourage them to do so."
	
	*label alekto2
	*fake_choice
		*if (rotation = 0)
			*disable_reuse #@{convotoggle [♥]|} "Hm? Sorry, I was distracted." By her, though I'm not going to say that part.
				*set subtle +1
				*set rotation +1
				"Hm? Sorry, I was distracted." By her, though you're not going to say that part. It'd be a little bit too much for you to want to address, particularly when the distraction was accidental. It's just… sometimes Alekto looks really [i]good[/i], and there's definitely an appeal to the picture she makes after hard work like that. 
				
				She blinks at you, but repeats the question nonetheless. 
				
				"I was asking how you thought I should encourage the Guard to rest."
				*goto alekto2
		*if (rotation = 0)
			*disable_reuse #@{convotoggle [♥]|} "Say again? I was too busy looking at you to pay attention."
				*set overt +1
				*set rotation +1
				"Say again? I was too busy looking at you to pay attention." You offer a little grin to go with the words, but there's truth to them. Sometimes Alekto looks really [i]good[/i], and there's definitely an appeal to the picture she makes after hard work like that. 
				
				She blinks at you, clearing her throat softly. It's hard to tell for sure, but you wonder if she isn't just a little bit bashful, at that. 
				
				"…I was asking how you thought I should encourage the Guard to rest."
				*goto alekto2
		#"Well... I [i]have[/i] heard that some of them come into the main building or do patrols on their rest days. Maybe start by putting a stop to that?" 
			"Well... I [i]have[/i] heard that some of them come into the main building or do patrols on their rest days. Maybe start by putting a stop to that?" You can understand the impulse, in a way. If you find your work important, if it gives you satisfaction to do it, it's easier to push past the amount you really should be doing. 
			
			But you know no one in the Underworld would have a schedule that actually demands they exhaust themselves, so maybe the thing to do is to enforce the schedule they do have a little more.
			
			"It is difficult," Alekto murmurs, taking a bite of her food and lifting her hands to continue. [i]I do not wish to make them dissatisfied. They do what they do because they find it important. But perhaps you are right.[/i]
			
			"It's not as though you have to come down with an iron fist about it, especially not at first. Just gradually start encouraging everyone to respect the schedule, or what have you." 
			
			Alekto nods, clearly giving it some thought.
		#"Look, they have free will, you know? If they won't rest, you can't force them. They'll just... have to handle the consequences of burning out, later."
			"Look, they have free will, you know? If they won't rest, you can't force them. They'll just... have to handle the consequences of burning out, later." You can understand the impulse, in a way. If you find your work important, if it gives you satisfaction to do it, it's easier to push past the amount you really should be doing. 
			
			But if people are going to do that, it's not Alekto's responsibility to stop them. As long as it isn't her scheduling or demands creating the problem—and you know it wouldn't be—the rest is up to the people involved. 
			
			"Perhaps you are correct," Alekto murmurs, taking a bite of her food and lifting her hands to continue. [i]I do not wish to make them dissatisfied. They do what they do because they find it important. But it is also important that they take care of themselves, in part because otherwise they are not as good at doing it.[/i]
			
			"Well, if you think it's affecting the quality of their work, then maybe that's something you could intervene about. But I'd err on the side of letting them be responsible for themselves, and just [i]tell[/i] them that." 
			
			Alekto nods, clearly giving it some thought.
		#"Do [i]you[/i] get enough rest? Maybe a proper example would help."
			"Do [i]you[/i] get enough rest? Maybe a proper example would help." You can understand the impulse, in a way. If you find your work important, if it gives you satisfaction to do it, it's easier to push past the amount you really should be doing. 
			
			More to the point, you think [i]Alekto[/i] understands that impulse, and probably gives into it more often than not. She's definitely one of the busiest people in the Underworld, and her job is [i]not[/i] a leisurely one. If she wants people to get enough rest, she should probably start with herself.
			
			"…Perhaps you are correct," she murmurs, taking a bite of her food and lifting her hands to continue. [i]And yet I am a deity, and need far less rest than they. I am unsure that my example will ever be the right one to follow.[/i]
			
			"I doubt it has to be exact," You reply with a small shrug. "Just let them see you taking care of yourself sometimes. Having a break during the day to eat a meal, or something." Food might be optional for almost everyone down here, but it's good for everyone's well-being, too. 
			
			Alekto nods, clearly giving it some thought.
	*page_break
The subject turns for a while to how you've been occupying yourself recently, and you catch her up on your present projects. It's nothing revolutionary, of course, just steady forward movement on
*if (job= "none")
	your latest hobby project, which is coming along well enough. As the discussion fully moves into what might be called the 'fun and leisure' topic area, Alekto turns her eyes out over the landscape for a moment.
*if ((job != "none") and (job != "guard"))
	your job, which is going well enough. After that, the topic turns to more leisurely matters—hobbies and the like—and as it does, Alekto turns her eyes out over the landscape for a moment. 
*if (job = "guard")
	the training you were just discussing, and a few hobby projects in various stages of completion. As the discussion fully moves into what might be called the 'fun and leisure' topic area, Alekto turns her eyes out over the landscape for a moment.

"I suppose I've been painting more, recently," she observes. "I don't know if you've noticed much of it, but the Underworld's landscape has been changing, of late. It's been interesting, cataloging the small differences over time." 

*fake_choice
	*if (tag_intuitive)
		#@{convotoggle [❋]|} "I had noticed something similar, yes." It's only very subtle, but I imagine side-by-side artworks would capture it well.
			"I had noticed something similar, yes." It's only very subtle, but you imagine side-by-side artworks would capture it well. It's something you'd be interested to look at, honestly. To see if Alekto's perception of the changes is anything like your own. 
			
			She smiles, a rare enough event, but this one even warms the amber-hazel of her eyes a bit. 
			
			[i]You've a discerning eye, then. I know the changes are so small lately that few would take note of them, but I have enjoyed doing so.[/i]
			
			[i]It just goes to show that it's an ecosystem like any other,[/i] you add with a small smile of your own. [i]If a very unique one.[/i]
	#"Has it really? I can't say I've noticed much." I follow her eyes, trying to remember if the Fields are any different.
		*set forthright +1
		"Has it really? I can't say I've noticed much." You follow her eyes, trying to remember if the Fields are any different. It really doesn't [i]seem[/i] so, but then you can't claim to particularly have an eye for this sort of thing.
		
		*if (tag_intuitive)
			You are, of course, rather observant of your environs in general, but you've always been focused on other things: people, mostly, and the rest only as it relates to people. When it comes to things like the Fields themselves, you've just always had your attention elsewhere. 
		*if not (tag_intuitive)
			It's difficult enough to notice changes in your more immediate environment, especially with how busy you are. Noticing any subtle changes in the Fields themselves is probably entirely beyond you. 
		
		Alekto nods slowly. [i]That is understandable,[/i] she replies readily. [i]Few would take notice of them, in any case. But I have enjoyed doing so.[/i]
		
		[i]I suppose if it's changing, that just goes to show that it's an ecosystem like any other,[/i] you reply, offering her a small smile as you sign. [i]If a very unique one.[/i]
	#"The changes have clearly been... subtle." I've not especially noticed any, in fact.
		*set reserved +1
		"The changes have clearly been... subtle." You've not especially noticed any, in fact. Perhaps in large part because the physical environment out in the Fields is not a major concern of yours, and especially lately, your attention has been divided rather a large number of ways that all demand focus. 
		
		*if (tag_intuitive)
			You are, of course, observant of your environs in general, but you've always been mostly concerned on other things: people, primarily, and the rest only as it relates to people. 
		*if not (tag_intuitive)
			It's difficult enough to notice changes in your more immediate environment, especially with that considered. Noticing any subtle changes in the Fields themselves is probably entirely beyond you. 
		
		Alekto nods slowly. [i]That is understandable,[/i] she replies readily. [i]Few would take notice of them, in any case. But I have enjoyed doing so.[/i]
		
		[i]I suppose if it's changing, that just goes to show that it's an ecosystem like any other,[/i] you reply, offering her a small smile as you sign. [i]If a very unique one.[/i]
	#"Do you think I could see the paintings at some point?" Alekto's work is always something special, and I'd be very interested to see more.
		*set forthright +1
		"Do you think I could see the paintings at some point?" Alekto's work is always something special, and you'd be very interested to see more. Considering how often she seems to work at some craft or another, you're sure that the few you've seen are only a small percentage of the ones she works on, but she seldom makes occasion of finishing anything. You have to assume she keeps most of her completed works in her own quarters, or something. 
		
		She blinks, frowning as if pondering it. [i]I suppose that depends on how they come out,[/i] she admits, her motions a touch awkward. [i]I tend to destroy most of my pieces once they are complete, but I've not yet done so with these. If I am satisfied with them, I will show you.[/i] 
		
		You sort of want to ask her why she [i]destroys[/i] things she makes, but she's still signing, so for the moment, you decide to leave it be. 
	#"How are you finding that?" I'd like to ask to see them, but it doesn't feel quite right to just say it.
		*set reserved +1
		"How are you finding that?" You'd like to ask to see them, but it doesn't feel quite right to just say it. Considering how often she seems to work at some craft or another, you're sure that the few you've seen are only a small percentage of the ones she works on, but she seldom makes occasion of finishing anything. You have to assume she keeps most of her completed works in her own quarters, or something. It seems almost intrusive, then, to ask. 
		
		She blinks, as if pondering the question you [i]did[/i] venture. [i]It's been… interesting,[/i] she replies, the motions of her hands slightly slower than usual. [i]It has given me much cause to think about what is around me, and how things are connected to one another.[/i]
		
		[i]I suppose if it's changing, that just goes to show that it's an ecosystem like any other,[/i] you reply, offering her a small smile as you sign. [i]If a very unique one.[/i]
*page_break
[i]Truth be told,[/i] she adds, [i]I think having someone with your particular domains here in a more long term way is changing the environment by degrees. I do not think it is just you, though. We are all changing, a little bit at a time. I suppose it is only natural for the world to change with us.[/i]

*fake_choice
	#"My domains, huh? Well, if they're doing something good for the Underworld, I can be happy about that." I've always been quite comfortable with the ones I have.
		*set domains "happy"
		"My domains, huh? Well, if they're doing something good for the Underworld, I can be happy about that." You've always been quite comfortable with the ones you have. You were born with them, and they suit you. Sure, you're not the most powerful being out there, or anything, but you can usually do what you want to do, and they have a broad applicability, to say the least. 
		
		"Certainly, in this context they are far more influential than mine," Alekto observes, eyes narrowing slightly out at the landscape. "And you, I think, have been influential on the Underworld. Not just directly through your power, but also through the friendships and connections you have built here. There is a power in that, as well." 
		
		"I suppose I hadn't thought about it that way." 
	#"That sounds nice, but at the same time, I can't help but feel that my domains don't really suit me." 
		*set domains "unhappy"
		"That sounds nice, but at the same time, I can't help but feel that my domains don't really suit me." It's clear enough why you have them, of course, but that doesn't mean they suit who you really are. You've always felt vaguely uncomfortable with them, not because they're especially confronting in any usual sense, but because they're so misaligned with your sense of yourself. 
		
		"You do not?" Alekto tilts her head, regarding you curiously for a moment. "Perhaps… I could see that. I think there are some ways in which you have managed to make them your own, but I do understand that feeling, nevertheless."
		
		"You do?"
		
		She dips her chin solemnly. "I do. But these changes are not simply because of your domains. You have been influential on the Underworld not just through your power, but also through the friendships and connections you have built here. There is a power in that, as well." 
		
		"I suppose I hadn't thought about it that way." 
	#"I like my domains, but I wouldn't complain about having a couple more. I wonder how that would change things?"
		*set domains "more"
		"I like my domains, but I wouldn't complain about having a couple more. I wonder how that would change things?" You've always been quite comfortable with the ones you have. You were born with them, and they suit you. But you can't help but feel that they're not [i]all[/i] that suits you, either. Maybe someday, you'll be able to develop others more reflective of the rest of who you are. 
		
		Alekto huffs softly. "I suppose that is understandable. Even those you already have are certainly more influential than mine, in this particular context. And you, I think, have been influential on the Underworld. Not just directly through your power, but also through the friendships and connections you have built here. There is a power in that, as well." 
		
		"I suppose I hadn't thought about it that way." 
*page_break
[i]It wouldn't make sense to do so,[/i] Alekto replies knowingly. [i]If you begin to think of your friendships as modes of power, they are that much closer to no longer being real friendships.[/i]

That's… probably a fair point. You've seen some examples of transactional alliances and the like on Olympus, but such things just don't really feel like they'd have a point here, where no one is trying to topple anyone else. 

"But as someone whose domains have changed a great deal with time," she continues, pressing her lips together briefly, "I can understand feeling like they fit… and feeling like they don't. The latter can be quite unsettling, as it was when I first acquired my current role." She shakes her head. 

[i]And yet… I think that despite what I do now suiting me more, I would also be better now at what I did before.[/i]

*fake_choice
	#"'Before' as in when you were on Olympus?"
		"'Before' as in when you were on Olympus?" It's the obvious answer, because you know she was exiled from there, as Charon was. You just have no idea who she might have been before she wound up here, as Minister of Punishments. 
		
		[i]Yes,[/i] she replies, drawing in a quiet breath.
	#@{convotoggle [☆]|} "Let me guess... goddess of training regimens and administrative paperwork?"
		*set humorous +1
		"Let me guess... goddess of training regimens and administrative paperwork?" You offer a sly smile with the 'guess,' lifting your shoulders in an offhanded shrug. 
		
		Alekto rolls her eyes. [i]Close,[/i] she replies, and somehow her motions and expression convey the same level of insincerity, just without any smiling involved. Still, she draws in a breath, and you suppose somehow that the real answer is forthcoming.
	#"Can I ask what you [i]did[/i] do, before?"
		*set serious +1
		"Can I ask what you [i]did[/i] do, before?" It might be a sensitive question, of course, and you want to treat that with respect, but it does seem as though she's opened the door to the query by mentioning it this way. 
		
		[i]You can,[/i] she replies, drawing in a breath.
*page_break
"I was once one of the muses," she says, her tone flat and controlled. "As were my sisters, I'm sure you can imagine. In particular, my area of concern was musical composition. I was called Aoide, back then."

"I thought the muses numbered nine. Are the rest your sisters as well?" 

Her expression becomes complicated. "Yes and no," she replies, expelling a breath. [i]Originally, there were three. When we were exiled, we were replaced with the nine of today. Megaira, Tisiphone, and I were born nymphs, from the same spring. The others are our 'sisters' in the sense of also being water nymphs, but we have no closer relation to them than that.[/i]

*fake_choice
	#"What happened, for you to end up here?"
		*set forthright +1
		*set cold +1
		"What happened, for you to end up here?" A direct question, perhaps, but Alekto has never seemed to take offense at those.
		
		"Apollo happened," she replies bluntly, her expression briefly taking on a glint of something like hatred. It's nothing you've seen her show before, and in this moment, you recognize that whatever suspicion she felt for you when you got here, it was nothing like this. You're almost surprised she's allowing you to see it, but of course some feelings aren't easy to hide. 
		
		And maybe, by this point, there's enough trust between you that things like that are okay.
		
		She lifts her hands, the explanation clearly as yet unfinished. [i]Perhaps that is somewhat unfair. What I should say is that my own deeds brought me into conflict with he who had once been my superior, and the result of that conflict was that I was banished. My sisters, good as they are, followed me.[/i]
		
		*if (megaira_dead)
			A hesitation. [i]Or were. Good as one of them is, and one of them was.[/i]
		
		A heavy silence sits for a moment, then Alekto shakes her head. [i]I think this is a topic for another time. I will tell you the story, I promise. But… I must prepare myself, for that.[/i]
		
		You bring your own hands up in turn. [i]I understand. No need to force it.[/i]
	#"I can't imagine whatever changed between now and then was easy to go through."
		*set forthright +1
		*set warm +1
		"I can't imagine whatever changed between now and then was easy to go through." It's… fairly direct, as a way of asking the question, but you don't want her to feel that you fail to recognize how difficult it might be to answer. 
		
		"It wasn't," she replies bluntly. "The wrath of Apollo is never an 'easy' thing to endure." Her expression briefly takes on a glint of something like hatred. It's nothing you've seen her show before, and in this moment, you recognize that whatever suspicion she felt for you when you got here, it was nothing like this. You're almost surprised she's allowing you to see it, but of course some feelings aren't easy to hide. 
		
		And maybe, by this point, there's enough trust between you that things like that are okay.
		
		She lifts her hands, the explanation clearly as yet unfinished. [i]Perhaps that is somewhat insufficient. What I should say is that my own deeds brought me into conflict with he who had once been my superior, and the result of that conflict was that I was banished. My sisters, good as they are, followed me.[/i]
		
		*if (megaira_dead)
			A hesitation. [i]Or were. Good as one of them is, and one of them was.[/i]
		
		A heavy silence sits for a moment, then Alekto shakes her head. [i]I think this is a topic for another time. I will tell you the story, I promise. But… I must prepare myself, for that.[/i]
		
		You bring your own hands up in turn. [i]I understand. Please take your time.[/i]
	#"You needn't say any more, if you do not wish it."
		*set reserved +1
		*set cold +1
		"You needn't say any more, if you do not wish it." You don't particularly feel a need to ask after it, if it's going to be uncomfortable to discuss further. You're curious, of course—learning that Alekto was once a muse makes a certain amount of sense, but it brings up a number of questions about the circumstances between then and now. Still, pushing isn't anything you desire to do, here. 
		
		"I know," she replies simply. [i]I will explain it to you, at another time. For now, suffice to say that my own deeds brought me into conflict with he who had once been my superior, and the result of that conflict was that I was banished. My sisters, good as they are, followed me.[/i]
		
		*if (megaira_dead)
			A hesitation. [i]Or were. Good as one of them is, and one of them was.[/i]
		
		A heavy silence sits for a moment, then Alekto shakes her head. [i]But as I said, a topic for another time. I will tell you, but I must prepare myself, for that.[/i]
		
		You bring your own hands up in turn. [i]I understand. No need to force it.[/i]
	#"If... you'd ever like to talk about any of that, I'm here."
		*set reserved +1
		*set warm +1
		"If... you'd ever like to talk about any of that, I'm here." It's not something you want to put to her in the form of a direct question. Something like that could feel like pressure to discuss things she might not be prepared to share with you. You're curious, obviously, but it's not worth pressing the matter too far. 
		
		"I know," she replies, tone gentling slightly. [i]I will explain it to you, at another time. For now, suffice to say that my own deeds brought me into conflict with he who had once been my superior, and the result of that conflict was that I was banished. My sisters, good as they are, followed me.[/i]
		
		*if (megaira_dead)
			A hesitation. [i]Or were. Good as one of them is, and one of them was.[/i]
		
		A heavy silence sits for a moment, then Alekto shakes her head. [i]But as I said, a topic for another time. I will tell you, but I must prepare myself, for that.[/i]
		
		You bring your own hands up in turn. [i]I understand. Please, take your time.[/i]
*page_break
*if (domains != "happy")
	Hemming quietly, she draws herself up where she sits. "At any rate. We were discussing domains. Unsurprisingly, many of them come from one's parents, or a combination thereof. But if you are unsatisfied with the nature or number of them, I'm sure Hekate's already told you at some point that work and temperament can change them. It tends to be easier to move to something adjacent than to gain a new one from nowhere, though. Hermes is… exceptional, in this respect, as he has many unrelated domains."

	*fake_choice
		#"How did you do it?"
			"How did you do it?" She obviously has very different domains now than she would have, as a muse. Though she is still very clearly artistically-inclined, so you have to wonder how much of that stuck, too. 
			
			Alekto presses her lips together. 
			
			[i]The circumstances were unusual. Technically, I still do have my artistic domain. But the new muses have more or less made it redundant, and I do not receive prayers related to it, so the power that goes with it is quite weak. Apollo is not capable of the feats of magic required to strip a domain from another deity, not even one directly subservient to him.[/i]
			
			She pauses a moment, opening and closing her fingers as if to fill the stillness. [i]Those that I otherwise have now were bestowed upon me when I agreed to take a position as an Erinys. It was work that needed doing, and the power was made available accordingly. Of course, since we took up the task, the roles have expanded, and the domains grown accordingly. My own are as much 'mine' now as anything ever has been.[/i]
			
			*if (humorous > serious)
				"I don't suppose there are any more untethered domains just floating around for the taking?"
			*if not (humorous > serious)
				"Is there a chance I could acquire an untethered domain in the same manner?"
			
			[i]There is no such thing as an untethered domain,[/i] she replies, expression solemn. [i]Mine once belonged to Hades, who in turn had taken them from another. But in the spirit of the question, there are not any 'spare' any longer, that I am aware of.[/i]
			
			That makes sense, you suppose. This was a while ago, so most likely if there [i]were[/i] any others to spare, they've since been assigned.
		#"I know this much, yes. It's actually doing it that's the hard part."
			"I know this much, yes. It's actually doing it that's the hard part." You shake your head. "It seems like the only real way to get there is to spend ages trying to cultivate one, and hope I'm lucky enough to encounter the right opportunities." 
			
			[i]More or less, yes,[/i] she admits. [i]There are a few other methods by which you might obtain one, but they are irregular, to say the least, and not currently available to you. Still… the time will pass anyway, will it not?[/i] 
			
			You can't help but huff softly. "That's true too, I suppose."
		#"To be honest, I'm not sure I can be bothered. I'd [i]prefer[/i] something different, but isn't the effort involved supposed to take centuries or something?"
			"To be honest, I'm not sure I can be bothered. I'd [i]prefer[/i] something different, but isn't the effort involved supposed to take centuries or something?" A very long time and a lot of effort that you're not sure is worth it for something that ultimately doesn't [i]have[/i] to affect you a great deal. 
			
			[i]More or less, yes,[/i] she admits. [i]There are a few other methods by which you might obtain one, but they are irregular, to say the least, and not currently available to you. Still… the time will pass anyway, will it not?[/i] 
			
			You can't help but huff softly. "That's true too, I suppose."
	*page_break
*if (domains = "happy")
	Hemming quietly, she draws herself up where she sits. "At any rate. We were discussing domains. Unsurprisingly, many of them come from one's parents, or a combination thereof. But of course, with those who are 'raised' to godhood from another position, they can also in rare instances be bestowed… and they can be taken, as well."
	
	*fake_choice
		#"How did you come to acquire yours?"
			"How did you come to acquire yours?" She obviously has very different domains now than she would have, as a muse. Though she is still clearly artistically-inclined, so you have to wonder how much of that stuck, too. 
			
			Alekto presses her lips together. 
			
			[i]The circumstances were unusual. Technically, I still do have my artistic domain. But the new muses have more or less made it redundant, and I do not receive prayers related to it, so the power that goes with it is quite weak. Apollo is not capable of the feats of magic required to strip a domain from another deity, not even one directly subservient to him.[/i]
			
			She pauses a moment, opening and closing her fingers as if to fill the stillness. [i]Those that I otherwise have now were bestowed upon me when I agreed to take a position as an Erinys. It was work that needed doing, and the power was made available accordingly. Of course, since we took up the task, the roles have expanded, and the domains grown accordingly. My own are as much 'mine' now as anything ever has been.[/i]
			
			*if (humorous > serious)
				"I don't suppose there are any more untethered domains just floating around for the taking?"
			*if not (humorous > serious)
				"Is there a chance I could acquire an untethered domain in the same manner?"
			
			[i]There is no such thing as an untethered domain,[/i] she replies, expression solemn. [i]Mine once belonged to Hades, who in turn had taken them from another. But in the spirit of the question, there are not any 'spare' any longer, than I am aware of.[/i]
			
			That makes sense, you suppose. This was a while ago, so most likely if there [i]were[/i] any others to spare, they've since been assigned.
		#"So I've heard, though I have no idea how taking or bestowing would work."
			"So I've heard, though I have no idea how taking or bestowing would work." It's been mentioned offhand by a few people before, the idea of domains being stripped away, or things like that. You're fairly sure that's how the Underworld's permanent residents came to share the domain 'Erebus.' But it's not clear to you how it's meant to happen. 
			
			Alekto frowns thoughtfully. [i]I couldn't give you the granular details of the process,[/i] she replies, [i]but the basic idea as I understand it is that one must drive the subject to exhaustion and weakness, at which point certain magic may be performed that transfers a domain from that person to oneself. If they're not willing, of course. I believe it can be done more easily if they allow it, or if you are already significantly more powerful than they are.[/i]
			
			There's a small pause, and then: [i]but the only person I know who has ever successfully taken another's domain is Hades.[/i]
			
			Certainly not likely to be something that would work for you, then, even if you decided for some reason that taking someone else's domain would be a good idea. You have no such plans of course, being quite content with what you have.
		#"Well, a person could also change their own over time, right?"
			"Well, a person could also change their own over time, right?" Bestowal is unlikely, and taking is something that still [i]sounds[/i] impossible, even if you know it isn't. You aren't really looking to change your domains, or acquire more, but if you did do it, it's fairly obvious that you'd use a much milder method to do so. 
			
			Alekto nods readily. [i]Yes. Though this is of course the most time consuming method. Still… time passes anyway, and it is not as though we have anything but a surfeit of that.[/i]
			
			That's true, too, though you do still sometimes have trouble really grasping longer lengths of time. You haven't lived through all that much of it yet, after all. 
	*page_break
Alekto hums, running her thumb along the side of her index finger. [i]By the way… I apologize if this is an unwelcome question, but how have things been progressing with your parents? I believe Demeter recently returned to Olympus?[/i]

"She did," you confirm, considering your answer to the larger question.

It's not an unexpected one, obviously. You'd handled all of that essentially on your own, and you have no doubt plenty of people are concerned with how it went. 

*fake_choice
	#"Maybe this is selfish, but I'm really ready for things to be quiet again."
		"Maybe this is selfish, but I'm really ready for things to be quiet again." You can't say you begrudge anyone anything, exactly, but all of this has been quite disturbing to your ordinary routine. That's not [i]unacceptable[/i], but it's been exhausting, and you really need some time to not have to think about things as personally significant—and fraught—as your relationships to your parents. 
		
		The fact that Demeter has left for now is certainly helping with that. 
		
		Alekto tilts her head. [i]I fail to see the selfishness,[/i] she replies. [i]You are entitled to rest, and peace of mind, when you need them. Perhaps the world does not always comply, but that is a separate matter.[/i]
		
		"Peace of mind would be nice. Perhaps I'll have a little more of it, now, for a while."
		
		At least until the next inevitable development.
	*if not (iasionstatus = "cutoff")
		#"It's confusing, and often difficult, but I'm glad for the chance to build and repair my relationships."
			"It's confusing, and often difficult, but I'm glad for the chance to build and repair my relationships." 
		
			*if (demeterstatus = "open")
				Not that you necessarily think either of them need much repairing, on your side. You need to build one with Iasion, but while you have had the occasional disagreement with your mother, you don't consider that relationship one that needs a fix. 

				Theirs, though, is another matter, you're sure. 
			*if not (demeterstatus = "open")
				And there's certainly a relationship to repair, as well as a relationship to build. Oddly enough, you think your mother's being here was a step in the right direction, even if
				*if (demeter_sequel_1 = false)
					you didn't go to see her. It means you know that she cared enough to show up, and also that she respected your boundaries by not seeking you out against your will. Maybe there's a chance all of this ends well.
				*if (demeter_sequel_1)
					you hadn't explicitly given her permission to visit you. After all, it showed that she cares enough about Iasion to come and visit him, and she didn't seek you out against your will—you went to her. Maybe there's a chance all of this ends well.

			Alekto tilts her head. [i]Well, as long as you find it a good thing rather than too onerous, that is good news. Perhaps further good news would be that I am certain Demeter will return before too long. Hades will not force her away while Iasion still remembers her, though I am sure he will hope for a less-sudden visit, next time.[/i]
			
			"I'll consider it a positive, yes."
	*if not (iasionstatus = "cutoff")
		#"I think I'm enjoying getting to know Iasion, in spite of everything. I'd prefer to do so without Demeter's intervention, though."
			"I think I'm enjoying getting to know Iasion, in spite of everything. I'd prefer to do so without Demeter's intervention, though."
			
			*if (demeterstatus = "open")
				It's not like you don't want your mother around at all, of course; it's just that your relationship with him and yours are different entities, and you don't necessarily want them blending together too much, especially at this fragile, early stage of things. 
			*if not (demeterstatus = "open")
				You'd have preferred not to need to handle your mother or anything to do with her until you were ready—if you're ever ready. But this complicates things. You can hardly expect her not to see your father at all, so you're left trying to navigate the situation as well as you can.
				
			Alekto tilts her head. [i]That is understandable. However, I believe such efforts will be somewhat complicated. Hades is unlikely to refuse Demeter access to the Underworld while Iasion still remembers her. Though I am sure he will require somewhat more notice next time. You should be able to avoid her.[/i]
			
			"I'll manage somehow, I suppose. I usually do."
	*if not (demeterstatus = "cutoff")
		#"I don't think I'll be spending much time with Iasion, if I can avoid it, but I suppose mother and I are getting along well enough."
			"I don't think I'll be spending much time with Iasion, if I can avoid it, but I suppose mother and I are getting along well enough."
			
			*if (iasionstatus = "cutoff")
				You'd made the decision not to pursue that relationship in any capacity, given the circumstances and your own emotional needs.
			*if not (iasionstatus = "cutoff")
				You'd made some attempt at getting to know him, but you just don't think it makes sense to go any further than you have. You know what you need to know about him, and… 'he,' the person with memories that are at all relevant to you, may not be around much longer.  
			
			*if (demeterstatus = "open")
				You and your mother have [i]always[/i] gotten along well enough, you suppose, so the news is more or less that there is no news. 
			*if not (demeterstatus = "open")
				As for Demeter, well. That was a bit of a surprise, but you can respect that she didn't seek you out against your will, even if she came here without your explicit permission. That means something, considering what your biggest problems with how she does things have always been. 
			
			Alekto tilts her head. [i]It will not be more difficult to avoid him than any other individual spirit, if that is your wish. Still, I am glad you are…[/i] She pauses, lips thinning. [i]It may be presumptuous of me, but I think it fortunate that you are getting along with at least one parent.[/i]
			
			"And the harder one to avoid by far," you reply, a touch dryly.
	*if not (iasionstatus = "cutoff")
		#"It's exciting, of course! It feels like I'm... I don't know if 'repairing' my family is the right word, but things are developing in a way I'm really pleased with."
			"It's exciting, of course! It feels like I'm... I don't know if 'repairing' my family is the right word, but things are developing in a way I'm really pleased with."
			
			*if (demeterstatus = "open")
				You do need to build a relationship with Iasion, but while you have had the occasional disagreement with your mother, you don't consider that one something that needs a fix. 

				Theirs, though, is another matter, you're sure. 
			*if not (demeterstatus = "open")
				Maybe repair is at least partly appropriate to one of the two relationships you're involved in, whereas 'build' makes more sense for the other. Oddly enough, you think your mother's being here was a step in the right direction, even if
				*if (demeter_sequel_1 = false)
					you didn't go to see her. It means you know that she cared enough to show up, and also that she respected your boundaries by not seeking you out against your will. Maybe there's a chance all of this ends well.
				*if (demeter_sequel_1)
					you hadn't explicitly given her permission to visit you. After all, it showed that she cares enough about Iasion to come and visit him, and she didn't seek you out against your will—you went to her. Maybe there's a chance all of this ends well.

			[i]Then that is good,[/i] Alekto replies, something at the corners of her eyes easing. [i]Perhaps further good news would be that I am certain Demeter will return before too long. Hades will not force her away while Iasion still remembers her, though I am sure he will hope for a less-sudden visit, next time.[/i]
			
			"Definitely good news."
*page_break
She pauses a moment, hands hovering in front of her chest as she studies you. [i]I admit, such conundrums are utterly foreign to me in the first place, as I have no parents.[/i]

Considering she's a nymph, that's not uncommon, you know. They're like as not to spring, fully-formed but untutored, from a tree or river as to come to be in the more conventional sense. 

*fake_choice
	#"Likewise, it's hard for me to imagine being in your situation."
		"Likewise, it's hard for me to imagine being in your situation." While you didn't know your father growing up, you knew you [i]had[/i] one, and of course for a very long time your mother was the largest and most important presence in your life. Trying to imagine what it would have been like [i]without[/i] her is frankly just about impossible. 
		
		But then, it's also difficult to imagine having never had the body of a child, having never grown. 
		
		"Well… I suppose it would be." Alekto shakes her head. "I was familiar enough with the concept even in the newness of my existence that I did sometimes think I was missing something, but for the most part I think it is difficult to miss what you never had."
		
		A pause. [i]Or at least, you don't miss it in the same way.[/i]
	#"Well... I effectively 'didn't have a father' for quite some time. How do you—does it feel like anything is missing?"
		"Well... I effectively 'didn't have a father' for quite some time. How do you—does it feel like anything is missing?" While you didn't know your father growing up, you knew you [i]had[/i] one, and of course for a very long time your mother was the largest and most important presence in your life. Trying to imagine what it would have been like [i]without[/i] her is frankly just about impossible. 
		
		But then, it's also difficult to imagine having never had the body of a child, having never grown. 
		
		"Yes and no." Alekto shakes her head. "Or rather, I was familiar enough with the concept even in the newness of my existence that I did sometimes think I was missing something, but for the most part I think it is difficult to miss what you never had."
		
		A pause. [i]Or at least, you don't miss it in the same way.[/i]
	#"...Lucky you." 
		"...Lucky you."  You can't help rolling your eyes a bit. While you didn't know your father growing up, you knew you [i]had[/i] one, and of course for a very long time your mother was the largest and most important presence in your life. Trying to imagine what it would have been like [i]without[/i] her is frankly just about impossible, and that's… a mixed bag, to say the least. 
		
		But then, it's also difficult to imagine having never had the body of a child, having never grown. 
		
		Alekto huffs, shaking her head. "I don't know if I'd call it that, exactly. I was familiar enough with the concept of 'parents' even in the newness of my existence that I did sometimes think I was missing something, but I suppose for the most part it is difficult to miss what you never had."
		
		A pause. [i]Or at least, you don't miss it in the same way.[/i]
*page_break
"You had sisters, though, right? I've never had a sibling, but I imagine that might have helped?"

She considers this for a few moments. 

[i]I would not say it was compensatory, but it did help. There are many different sorts of family, I suppose. Many different sorts of bond that fit under the umbrella of things like 'familial' or 'friendly.' As many as there are people to be in those relationships.[/i]

*if (npc_init)
	*if (alekto_receptive)
		Shifting slightly in her seat, Alekto drops her eyes to her half-eaten plate, then sets it aside. She's already facing you square on, and yet you get the impression that she's doing it as if to remove some kind of impediment between you. 
		
		[i]Take, for example, the one I believe we share.[/i] She meets your eyes directly, posture rigid and hands somehow a little bit uncertain. [i]I would say that this is… one of a kind. But perhaps that is only because I believe[/i] you [i]are.[/i]
		
		*fake_choice
			#@{convotoggle [♥]|} "No, I think you're right. You're special to me, and the way I feel about you isn't the same way I feel about anyone else."
				*set subtle +1
				"No, I think you're right. You're special to me, and the way I feel about you isn't the same way I feel about anyone else." You offer her a small smile, and something in her face softens, barely perceptibly. 
				
				Everything you've said is true. You know she's struggling to work out her own feelings, or come to terms with something in her history, and you intend to give her all the space and time she needs to do that. But it can't hurt to remind her that you care about her, that you're looking forward to figuring out who to be for one another, when she's ready. 
				
				Or maybe this is the 'figuring out' part, in which case you might as well enjoy it. 
				
				Alekto expels a quiet breath, and her lips curve just the slightest bit. "Thank you, ${name}. I hope… that means you will accept something from me."
				
				"Accept…?"
			#@{convotoggle [♥]|}  "Are you sure that's not just because I'm your [i]favorite[/i] person?"
				*set overt +1
				"Are you sure that's not just because I'm your [i]favorite[/i] person?" You offer her a grin, and something in her face softens, barely perceptibly. 
				 
				You're lighthearted about it, but the sentiment beneath the words is sincere. You know she's struggling to work out her own feelings, or come to terms with something in her history, and you intend to give her all the space and time she needs to do that. But it can't hurt to remind her that you care about her, that you're looking forward to figuring out who to be for one another, when she's ready. 
				
				Or maybe this is the 'figuring out' part, in which case you might as well enjoy it. 
				
				Alekto expels a quiet breath, and her lips curve just the slightest bit. "Perhaps you are, ${name}. I hope… that means you will accept something from me."
				
				"Accept…?"
			#I can see where this is going, and I need to head it off clearly, once and for all. "We do have a very important friendship. A unique one." 
				*set alekto_justfriends true
				*set alekto_receptive false
				I can see where this is going, and I need to head it off clearly, once and for all. "We do have a very important friendship. A unique one." 
				
				You know Alekto is struggling to work out her own feelings, or come to terms with something in her history, and it's only fair that she be allowed time and space to do that. But you've been working out your own, as well, since your return to the Underworld, and you've decided that the friendship you share with her is everything you want. 
				
				And it's best to let her know that, now that you do. 
				
				She blinks, face shuttering for a moment and leaving her expression unreadable. After a few seconds, though, her shoulders relax, and she nods slowly. "We do," she agrees. "It is… very worthwhile, and I hope you consider it as valuable as I." 
				
				You manage a smile at that. "Of course I do."
				
				Nodding again, Alekto picks up her plate once more, setting it in her lap. An unspoken cue that the conversation is resuming its former trajectory, and the time to speak in detail about your emotions has passed. She's recognized your intention, and accepted it. 
				
				Maybe there's a [i]little[/i] awkwardness in the air, but it's not going to stop either of you from enjoying the rest of your time together. 
				*goto chap3end
			#"I think... I think you're right, but I can't be sure [i]why[/i] I think so."
				*set alekto_receptive false
				*set alekto_unsure true
				"I think... I think you're right, but I can't be sure [i]why[/i] I think so." It's a bit difficult to admit, but you want to be truthful. 
				
				You know Alekto is struggling to work out her own feelings, or come to terms with something in her history, and it's only fair that she be allowed time and space to do that. But you're trying to work out your own, too, and you're not finding it to be as simple as you might have hoped. 
				
				It's best to let her know that, even if it might be a disappointment, given your relative receptiveness last time she brought it up. 
				
				She blinks, face shuttering for a moment and leaving her expression unreadable. After a few seconds, though, her shoulders relax, and she nods slowly. "I would that I could simply tell you the answer," she says, "but I do not know it. Perhaps we both simply need more time, to consider things." 
				
				You manage a smile at that. "Perhaps neither of us is the best with working out how we feel." 
				
				"Perhaps not." Nodding again, Alekto picks up her plate once more, setting it in her lap. An unspoken cue that the conversation is resuming its former trajectory, and the time to speak in detail about your emotions has passed. She's recognized your intention, and accepted it. 
				
				Maybe there's a [i]little[/i] awkwardness in the air, but it's not going to stop either of you from enjoying the rest of your time together. 
				*goto chap3end
		*page_break
		*label alekto_gift
		She clears her throat quietly, reaching into the large satchel she'd been carrying with her 
		*if (job = "guard")
			since the two of you met up this morning for the review.
		*if not (job = "guard")
			when you met her here for lunch. 
		*if (((((tag_pacifist) or (tag_pacifistvow)) or (violencesucks)) or (pc_weapon = "unknown")) or (pc_weapon = "none"))
			*if (hairlength < 3)
				*set alekto_gift "headband"
				From it, she withdraws an intricately-woven piece of fabric, a thick band apparently made of silk strands, or something similar, from the way the light hits it. 
				*if ((fav_color != "none") and (fav_color != "unknown"))
					There are several different colors in the geometrical pattern of it, but ${fav_color} is perhaps the most prominent, the others clearly selected to complement. 
				*if ((fav_color = "none") or (fav_color = "unknown"))
					There are several different colors in the geometrical pattern of it, but 
					*if ((eyecolor != "hazel") and (eyecolor != "brown"))
						${eyecolor} seems to be the most prominent shade, the hue almost an exact match for the color of your eyes. The others have evidently been chosen to complement.
					*if ((eyecolor = "hazel") or (eyecolor = "brown"))
						a striking emerald green seems to be the most prominent shade, the others clearly selected to complement.
					
				"This," she replies, offering it towards you. "I've seen you use similar bands to hold back some of your hair when you are to do an activity that demands a bit more vigor, so I thought you might be able to use it. 
				*if (((hairtexture = "curly") or (hairtexture = "coily")) or (hairtexture = "dense"))
					I believe the fabric should be sufficiently smooth and gentle for the task, as well."
				*if not (((hairtexture = "curly") or (hairtexture = "coily")) or (hairtexture = "dense"))
					It should hold well, I hope."
			*if (hairlength > 2)
				*set alekto_gift "hairtie"
				From it, she withdraws an intricately-woven piece of fabric, a thin band apparently made of silk strands, or something similar, from the way the light hits it. 
				*if ((fav_color != "none") and (fav_color != "unknown"))
					There are several different colors in the geometrical pattern of it, but ${fav_color} is perhaps the most prominent, the others clearly selected to complement. 
				*if ((fav_color = "none") or (fav_color = "unknown"))
					There are several different colors in the geometrical pattern of it, but 
					*if ((eyecolor != "hazel") and (eyecolor != "brown"))
						${eyecolor} seems to be the most prominent shade, the hue almost an exact match for the color of your eyes. The others have evidently been chosen to complement.
					*if ((eyecolor = "hazel") or (eyecolor = "brown"))
						a striking emerald green seems to be the most prominent shade, the others clearly selected to complement.
					
				"This," she replies, offering it towards you. "I've seen you use similar ties to hold back your hair when you are to do an activity that demands a bit more vigor, so I thought you might be able to use it. 
				*if (((hairtexture = "curly") or (hairtexture = "coily")) or (hairtexture = "dense"))
					I believe the fabric should be sufficiently smooth and gentle for the task, as well."
				*if not (((hairtexture = "curly") or (hairtexture = "coily")) or (hairtexture = "dense"))
					It should hold well, I hope."
			
			*fake_choice
				#"A hair accessory? I'm not sure I'd have expected that."
					"A hair accessory? I'm not sure I'd have expected that." You're not displeased with the gift—far from it. You're just not sure you ever would have thought to receive such a thing from Alekto, of all people. 
					
					Then again, maybe it makes sense. She's in armor a lot of the time, but when she isn't, she dresses quite elaborately, compared to most people, at least in things made of good fabric in lovely colors. And you know she's well capable of making something like this. 
					
					Plus, there's a certain practicality to it. 
					
					"Is that… not all right?" she asks, her voice steady but her lips pursed. 
					
					"Of course it's all right." You reach forward to accept the object from her. "It's a gift from you, and you're right that I'll probably have a use for it. Thank you, Alekto." 
					
					She clears her throat. "Of course."
				#"You're right—I can absolutely use something like this."
					"You're right—I can absolutely use something like this." It's not the [i]first[/i] guess you'd have had, if someone had suggested Alekto was going to give you a gift, but it suits her perfectly. 
					
					She's in armor a lot of the time, but when she isn't, she dresses quite elaborately, compared to most people, at least in things made of good fabric in lovely colors. And you know she's well capable of making something like this. 
					
					Plus, there's a certain practicality to it. 
					
					"Good," she says, a note of relief in her usually-flat tone. "I was hoping so." 
					
					You reach forward to accept the object from her, and she hands it over carefully, her fingers brushing your palm. 
					
					"And… you're welcome."
				#"It's so lovely! Did you make it yourself?"
					"It's so lovely! Did you make it yourself?" It's not the [i]first[/i] guess you'd have had, if someone had suggested Alekto was going to give you a gift, but it suits her perfectly. 
					
					She's in armor a lot of the time, but when she isn't, she dresses quite elaborately, compared to most people, at least in things made of good fabric in lovely colors. And you know she's well capable of making something like this. 
					
					Plus, there's a certain practicality to it. 
					
					"I did," she confirms, a note of relief in her usually-flat tone. 
					
					"Thank you." You reach forward to accept the object from her, and she hands it over carefully, her fingers brushing your palm. 
					
					"You're… welcome."
				#"This is... really very nice."
					"This is... really very nice."  It's not the [i]first[/i] guess you'd have had, if someone had suggested Alekto was going to give you a gift, but it suits her perfectly. 
					
					She's in armor a lot of the time, but when she isn't, she dresses quite elaborately, compared to most people, at least in things made of good fabric in lovely colors. And you know she's well capable of making something like this. 
					
					Plus, there's a certain practicality to it. 
					
					"Good," she says, a note of relief in her usually-flat tone. "I was hoping you would think so." 
					
					You reach forward to accept the object from her, and she hands it over carefully, her fingers brushing your palm. 
					
					"And… you're welcome."
			*page_break
			Alekto picks up her plate once more, setting it in her lap. An unspoken cue that the conversation is resuming its former trajectory, and the more emotionally-laden things are finished for the moment. 
			
			Which is perfectly fine with you. It's been nice—and for today, it's plenty.
			*goto chap3end
		*if not (((((tag_pacifist) or (tag_pacifistvow)) or (violencesucks)) or (pc_weapon = "unknown")) or (pc_weapon = "none"))
			*if (((pc_weapon = "knife") or (pc_weapon = "swordboard")) or (pc_weapon = "bigsword"))
				*set alekto_gift "scabbard"
				From it, she withdraws what looks to be a leather scabbard, decorated with intricate geometric etchings, which in turn have been darkened with some kind of staining process, so they show better against the material. It looks to be of the right size to carry your ${weapon}, and somehow you have no doubt it was custom-measured to the purpose. 
				
				"This," she replies, offering it towards you. "I've noticed that the one you use for your ${weapon} is a bit old, so I thought perhaps a replacement would not go awry."
			*if ((pc_weapon = "spear") or (pc_weapon = "bigaxe"))
				*set alekto_gift "weapondeco"
				From it, she withdraws an intricately-woven piece of fabric, a thin, long band apparently made of woven strands, you think some mixture of leather and something else. 
				*if ((fav_color != "none") and (fav_color != "unknown"))
					There are several different colors in the geometrical pattern of it, but ${fav_color} is perhaps the most prominent, the others clearly selected to complement. 
				*if ((fav_color = "none") or (fav_color = "unknown"))
					There are several different colors in the geometrical pattern of it, but 
					*if ((eyecolor != "hazel") and (eyecolor != "brown"))
						${eyecolor} seems to be the most prominent shade, the hue almost an exact match for the color of your eyes. The others have evidently been chosen to complement.
					*if ((eyecolor = "hazel") or (eyecolor = "brown"))
						a striking emerald green seems to be the most prominent shade, the others clearly selected to complement.
				
				"This," she replies, offering it towards you. "It's meant to be wrapped around the haft of a weapon, like your ${weapon}, to provide better grip, but… considering none of us have any plans to go to war, you might as well consider it decoration, I suppose."
			
			*fake_choice
				#"Something for a weapon? Somehow, that seems exactly like what you'd get someone."
					"Something for a weapon? Somehow, that seems exactly like what you'd get someone." You're not displeased with the gift—far from it. It's just so quintessentially [i]Alekto[/i] that you can't help but mention it. 
					
					And it [i]does[/i] make sense. She's in armor a lot of the time, but when she isn't, she dresses quite elaborately, compared to most people, at least in things made of good fabric in lovely colors. And you know she's well capable of making something like this. 
					
					Most of all, though, it's the practicality. 
					
					"Is that… not all right?" she asks, her voice steady but her lips pursed. 
					
					"Of course it's all right." You reach forward to accept the object from her. "It's a gift from you, and I'll be able to use it. Thank you, Alekto." 
					
					She clears her throat. "Of course."
				#"I could absolutely use something like this."
					"I could absolutely use something like this." As a gift, it suits her perfectly, too. It might have even been your guess, if you had to make one about something she might give you.
					
					She's in armor a lot of the time, but when she isn't, she dresses quite elaborately, compared to most people, at least in things made of good fabric in lovely colors. And you know she's well capable of making something like this. 
					
					Most of all, though, it's the practicality. 
					
					"Good," she says, a note of relief in her usually-flat tone. "I was hoping so." 
					
					You reach forward to accept the object from her, and she hands it over carefully, her fingers brushing your palm. 
					
					"And… you're welcome."
				#"It's so lovely! Did you make it yourself?"
					"It's so lovely! Did you make it yourself?" As a gift, it suits her perfectly. It might have even been your guess, if you had to make one about something she might give you.
					
					She's in armor a lot of the time, but when she isn't, she dresses quite elaborately, compared to most people, at least in things made of good fabric in lovely colors. And you know she's well capable of making something like this. 
					
					Most of all, though, it's the practicality. 
					
					"I did," she confirms, a note of relief in her usually-flat tone. 
					
					"Thank you." You reach forward to accept the object from her, and she hands it over carefully, her fingers brushing your palm. 
					
					"You're… welcome."
				#"This is... really very nice."
					"This is... really very nice." As a gift, it suits her perfectly. It might have even been your guess, if you had to make one about something she might give you.
					
					She's in armor a lot of the time, but when she isn't, she dresses quite elaborately, compared to most people, at least in things made of good fabric in lovely colors. And you know she's well capable of making something like this. 
					
					Most of all, though, it's the practicality. 
					
					"Good," she says, a note of relief in her usually-flat tone. "I was hoping you would think so." 
					
					You reach forward to accept the object from her, and she hands it over carefully, her fingers brushing your palm. 
					
					"And… you're welcome."
			*page_break
			Alekto picks up her plate once more, setting it in her lap. An unspoken cue that the conversation is resuming its former trajectory, and the more emotionally-laden things are finished for the moment. 
			
			Which is perfectly fine with you. It's been nice—and for today, it's plenty.
			*goto chap3end
	*if (alekto_justfriends)
		Taking another bite from her plate, Alekto considers for a moment, then brings her hands up to chest-height once more. [i]Take, for example, the one I believe we share.[/i] Her expression becomes slightly wry, one eyebrow lifting just a touch. [i]I never expected to end up thinking of you as my friend, and yet I have. One of my closest, if I may say so. I'm not sure if my initial feelings of animosity were really necessary in any sense, but I do think they occasionally color how I think about things.[/i]
		
		"How so?"
		
		She tips her head to the side. [i]Well, I think I am in some ways more defensive of you than I might otherwise be. Perhaps some part of me still feels there is something to make up for.[/i]
		
		*fake_choice
			#"There's not, Alekto. That's all in the past, and I don't worry about it anymore."
				"There's not, Alekto. That's all in the past, and I don't worry about it anymore." You suppose you could have held it against her, but you don't. Her desire to defend what she cares about was sincere, and it was hard [i]not[/i] to find the situation baffling, back then. Still, she's probably right that it shaped things between you to some extent, at least at first. 
			#"Maybe you're right. Believe it or not, I think it might have made me more protective of [i]you[/i]."
				"Maybe you're right. Believe it or not, I think it might have made me more protective of [i]you[/i]." You like to think you would have been, anyway, of course, but perhaps it's just as she says. There isn't really 'more' or 'less' about it, it's just [i]different[/i]. How things started has echoed, in its own little way, into how they are now, and it's not a bad thing.
			#"I could see that. Your reaction to me made me want to know more about you, and I still do."
				"I could see that. Your reaction to me made me want to know more about you, and I still do." You like to think you would have anyway, of course, but perhaps it's just as she says. There isn't really 'more' or 'less' about it, it's just [i]different[/i]. How things started has echoed, in its own little way, into how they are now, and it's not a bad thing.
			#"I'd say that I was wary at first, but maybe that makes me treasure the fact that we're friends more?"
				"I'd say that I was wary at first, but maybe that makes me treasure the fact that we're friends more?" You like to think you would have anyway, of course, but perhaps it's just as she says. There isn't really 'more' or 'less' about it, it's just [i]different[/i]. How things started has echoed, in its own little way, into how they are now, and it's not a bad thing.
		*line_break
		*line_break
		"I suppose that means we have a very unique friendship, since I don't think many start like ours did."

		Her shoulders relax, and she nods slowly. "We do," she agrees. "It is… very worthwhile, and I hope you consider it as valuable as I." 

		You manage a smile at that. "Of course I do."

		Nodding again, Alekto picks up her plate once more, setting it in her lap. An unspoken cue that the conversation is resuming its former trajectory, and the time to speak in detail about your emotions has passed.

		Which is perfectly fine with you. It's been nice—and for today, it's plenty.
		*goto chap3end
	*if ((alekto_receptive = false) and (alekto_justfriends = false))
		Shifting slightly in her seat, Alekto drops her eyes to her half-eaten plate, then sets it aside. She's already facing you square on, and yet you get the impression that she's doing it as if to remove some kind of impediment between you. 
		
		[i]Take, for example, the one I believe we share.[/i] She meets your eyes directly, posture rigid and hands somehow a little bit uncertain. [i]I would say that this is… one of a kind. But perhaps that is only because I believe[/i] you [i]are.[/i]
		
		*fake_choice
			#@{convotoggle [♥]|} "No, I think you're right. You're special to me, and the way I feel about you isn't the same way I feel about anyone else."
				*set subtle +1
				*set alekto_receptive true
				"No, I think you're right. You're special to me, and the way I feel about you isn't the same way I feel about anyone else." You offer her a small smile, and something in her face softens, barely perceptibly. 
				
				*if (initiative_ending)
					You know she's struggling to work out her own feelings, or come to terms with something in her history, and you intend to give her all the space and time she needs to do that. But it can't hurt to let her know that you care about her, that you're looking forward to figuring out who to be for one another, when she's ready. You hadn't been quite so receptive last time, after all.
					
				Alekto expels a quiet breath, and her lips curve just the slightest bit. "Thank you, ${name}. I hope… that means you will accept something from me."
				
				"Accept…?"
				*goto alekto_gift
			#@{convotoggle [♥]|}  "Are you sure that's not just because I'm your [i]favorite[/i] person?"
				*set overt +1
				*set alekto_receptive true
				"Are you sure that's not just because I'm your [i]favorite[/i] person?" You offer her a grin, and something in her face softens, barely perceptibly. 
				 
				*if (initiative_ending)
					You're lighthearted about it, but the sentiment beneath the words is sincere. You know she's struggling to work out her own feelings, or come to terms with something in her history, and you intend to give her all the space and time she needs to do that. But it can't hurt to let her know that you care about her, that you're looking forward to figuring out who to be for one another, when she's ready. You hadn't been quite so receptive last time, after all.
				
				Alekto expels a quiet breath, and her lips curve just the slightest bit. "Perhaps you are, ${name}. I hope… that means you will accept something from me."
				
				"Accept…?"
				*goto alekto_gift
			#I can see where this is going, and I need to head it off clearly, once and for all. "We do have a very important friendship. A unique one." 
				*set alekto_justfriends true
				I can see where this is going, and I need to head it off clearly, once and for all. "We do have a very important friendship. A unique one." 
				
				*if (initiative_ending)
					You know Alekto is struggling to work out her own feelings, or come to terms with something in her history, and it's only fair that she be allowed time and space to do that. But you've been working out your own, as well, since your return to the Underworld, and you've decided that the friendship you share with her is everything you want. 
				
					And it's best to let her know that, now that you do. 
				
				She blinks, face shuttering for a moment and leaving her expression unreadable. After a few seconds, though, her shoulders relax, and she nods slowly. "We do," she agrees. "It is… very worthwhile, and I hope you consider it as valuable as I." 
				
				You manage a smile at that. "Of course I do."
				
				Nodding again, Alekto picks up her plate once more, setting it in her lap. An unspoken cue that the conversation is resuming its former trajectory, and the time to speak in detail about your emotions has passed. She's recognized your intention, and accepted it. 
				
				Maybe there's a [i]little[/i] awkwardness in the air, but it's not going to stop either of you from enjoying the rest of your time together. 
				*goto chap3end
			#"I think... I think you're right, but I can't be sure [i]why[/i] I think so."
				*set alekto_unsure true
				"I think... I think you're right, but I can't be sure [i]why[/i] I think so." It's a bit difficult to admit, but you want to be truthful. 
				
				*if (initiative_ending)
					You know Alekto is struggling to work out her own feelings, or come to terms with something in her history, and it's only fair that she be allowed time and space to do that. But you're trying to work out your own, too, and you're not finding it to be as simple as you might have hoped. 
				
					It's best to let her know that, even if it might be a disappointment, given that you were much more ambiguous last time she brought it up.
				
				She blinks, face shuttering for a moment and leaving her expression unreadable. After a few seconds, though, her shoulders relax, and she nods slowly. "I would that I could simply tell you the answer," she says, "but I do not know it. Perhaps we both simply need more time, to consider things." 
				
				You manage a smile at that. "Perhaps neither of us is the best with working out how we feel." 
				
				"Perhaps not." Nodding again, Alekto picks up her plate once more, setting it in her lap. An unspoken cue that the conversation is resuming its former trajectory, and the time to speak in detail about your emotions has passed. She's recognized your intention, and accepted it. 
				
				Maybe there's a [i]little[/i] awkwardness in the air, but it's not going to stop either of you from enjoying the rest of your time together. 
				*goto chap3end
*if (npc_init = false)
	Taking another bite from her food, Alekto considers for a moment, then brings her hands up to chest-height once more.  [i]Take, for example, the one I believe we share.[/i] Her expression becomes slightly wry, one eyebrow lifting just a touch. [i]I never expected to end up thinking of you as my friend, and yet I have. One of my closest, if I may say so. I'm not sure if my initial feelings of animosity were really necessary in any sense, but I do think they occasionally color how I think about things.[/i]
		
	"How so?"

	She tips her head to the side. [i]Well, I think I am in some ways more defensive of you than I might otherwise be. Perhaps some part of me still feels there is something to make up for.[/i]
	
	*fake_choice
		#@{convotoggle [♥]|} "I can't begin to tell you how far past that I am, Alekto. To me, you're... you're my friend, but I think of you also as someone I want to be closer to."
			*set alekto_receptive true
			*set overt +1
			"I can't begin to tell you how far past that I am, Alekto. To me, you're... you're my friend, but I think of you also as someone I want to be closer to." You pull in a breath, meeting her eyes squarely. In truth, you're not so sure how she's going to handle that information, but you wanted her to know. Needed her to know. 
			
			For a moment, she looks at you in obvious shock, lips parted and eyes just ever so slightly wide. For Alekto, that's a glaring spotlight, highlighting her surprise, and perhaps a hint of confusion. 
			
			To her credit, she recovers after a moment, clearing her throat. [i]I don't think I was ever expecting you to say such a thing,[/i] she admits. [i]Not in any… seriousness.[/i] A pause; she shakes her head. 
			
			[i]I am… I cannot yet answer you,[/i] she admits, mouth curling into a frown. [i]But know that I very much wish to, and that, if you are willing to give me a bit of time… I will. I will definitely answer you properly.[/i]
			
			"Of course you can have time." You offer a bit of a smile. Considering what you think is a very slight tinge to her complexion, you think you have an idea what that answer might be, and for now, you're content to wait for it.
			*goto chap3end
		#@{convotoggle [♥]|} "It's really all right, you know." It's more than all right—I honestly think I want to be closer to her, and not just as friends.
			*set alekto_receptive true
			*set subtle +1
			"It's really all right, you know." It's more than all right—you honestly think you want to be closer to her, and not just as friends. The thing is, you're not quite prepared to [i]say[/i] that, and so for the moment, the words remain locked behind your teeth. 
			
			"And I suppose that means we have a very unique bond, since I don't think many start like ours did," you say instead.
			
			Her shoulders relax, and she nods slowly. "We do," she agrees. "It is… very worthwhile, and I hope you consider it as valuable as I." 
				
			You manage a smile at that. "Of course I do."

			Nodding again, Alekto picks up her plate once more, setting it in her lap. An unspoken cue that the conversation is resuming its former trajectory, and the time to speak in detail about your emotions has passed.
			
			Which is perfectly fine with you. It's been nice—and for today, it's plenty. You'll find a way to say what you need to, when the time is right.
			*goto chap3end
		#"Sincerely, don't worry about it. That's all in the past, and I don't think of it, anymore." She's a good friend now, and that's the important part.
			*set alekto_justfriends true
			"Sincerely, don't worry about it. That's all in the past, and I don't think of it, anymore." She's a good friend now, and that's the important part. "I suppose that means we have a very unique friendship, since I don't think many start like ours did."

			Her shoulders relax, and she nods slowly. "We do," she agrees. "It is… very worthwhile, and I hope you consider it as valuable as I." 

			You manage a smile at that. "Of course I do."

			Nodding again, Alekto picks up her plate once more, setting it in her lap. An unspoken cue that the conversation is resuming its former trajectory, and the time to speak in detail about your emotions has passed.

			Which is perfectly fine with you. It's been nice—and for today, it's plenty.
			*goto chap3end
		#"If there ever was, you've already made up for it, you know?" Honestly... how I feel about her is confusing, but there's definitely no animosity involved. 
			*set alekto_unsure true
			"If there ever was, you've already made up for it, you know?" Honestly... how you feel about her is confusing, but there's definitely no animosity involved. What is there, exactly, well… that's something you'll figure out, in time. 
			
			"I suppose that means we have a very unique friendship, since I don't think many start like ours did," you add. Because that much, at least, you know is certainly true.

			Her shoulders relax, and she nods slowly. "We do," she agrees. "It is… very worthwhile, and I hope you consider it as valuable as I." 

			You manage a smile at that. "Of course I do."

			Nodding again, Alekto picks up her plate once more, setting it in her lap. An unspoken cue that the conversation is resuming its former trajectory, and the time to speak in detail about your emotions has passed.

			Which is perfectly fine with you. It's been nice—and for today, it's plenty.
			*goto chap3end
*label chap3charon
A few days later, Demeter has returned to Olympus. You're not sure exactly when or if she'll be back, but for now at least, she has obviously seen Iasion and confirmed his identity. What difference it will make in the long run, you can't be sure, but some things are surely worth doing even if they don't change how the world works. 

You wonder, for a moment, what you would do in her position, but the thought is easily enough brushed aside. 
*page_break
Today, you're out at the lakeside with Charon.

*if (date = "charon")
	It's much as you left it last time, of course; little in the Underworld changes much, and it's a piece of the landscape besides. The ghostly apparitions of fish drift and swirl about in its depths, presumably in similar ways to how actual fish would, though you can draw on no expertise to say for certain.
*if (date != "charon")
	It's an unusual place. You walked through a petrified grove of sorts to get here, to this small lake, which seems to be inhabited by ghostly apparitions of fish, drifting and swirling about in its depths, each shedding a faint but perceptible luminescence. Combined with the dark, vitreous water, you could be forgiven for thinking they were floating through nothing at all.

There is a small dock on the near side, recently-built from the look of it, despite there being no boats here, nor any connection to any of the rivers. It makes for a pleasant place to sit, though, your bare feet dipped into the water, a plate of snacks between you and Charon. 

For once, they look quite relaxed, leaned back on one hand with their hood down and hair only slightly disheveled in its absence. 

"I hope you don't mind my asking," he says, pale blue eyes finding yours. "But I was wondering how things had gone, with Demeter's visit. Or perhaps with your parents in the general sense."

It's not an unexpected question, obviously. You'd handled all of that essentially on your own, and you have no doubt plenty of people are concerned with how it went. 

*fake_choice
	#"Maybe this is selfish, but I'm really ready for things to be quiet again."
		"Maybe this is selfish, but I'm really ready for things to be quiet again." You can't say you begrudge anyone anything, exactly, but all of this has been quite disturbing to your ordinary routine. That's not [i]unacceptable[/i], but it's been exhausting, and you really need some time to not have to think about things as personally significant—and fraught—as your relationships to your parents. 
		
		The fact that Demeter has left for now is certainly helping with that. 
		
		"I think it would take a rather impressive amount of mental contortion to come to the conclusion that such a sentiment was 'selfish,'" Charon replies, a hint of amusement gracing the faint curve of his lips. "It is hardly a negative thing, to desire some peace of mind, now and then."
		
		"Peace of mind would be nice. Perhaps I'll have a little more of it, now, for a while."
		
		At least until the next inevitable development.
	*if not (iasionstatus = "cutoff")
		#"It's confusing, and often difficult, but I'm glad for the chance to build and repair my relationships."
			"It's confusing, and often difficult, but I'm glad for the chance to build and repair my relationships." 
		
			*if (demeterstatus = "open")
				Not that you necessarily think either of them need much repairing, on your side. You need to build one with Iasion, but while you have had the occasional disagreement with your mother, you don't consider that relationship one that needs a fix. 

				Theirs, though, is another matter, you're sure. 
			*if not (demeterstatus = "open")
				And there's certainly a relationship to repair, as well as a relationship to build. Oddly enough, you think your mother's being here was a step in the right direction, even if
				*if (demeter_sequel_1 = false)
					you didn't go to see her. It means you know that she cared enough to show up, and also that she respected your boundaries by not seeking you out against your will. Maybe there's a chance all of this ends well.
				*if (demeter_sequel_1)
					you hadn't explicitly given her permission to visit you. After all, it showed that she cares enough about Iasion to come and visit him, and she didn't seek you out against your will—you went to her. Maybe there's a chance all of this ends well.

			Charon hums. "Then perhaps it will count as a good thing that Demeter is likely to return, in time. Hades will not bar her from the Underworld entirely whilst Iasion yet remembers her, though I do think she understands that subsequent visits will need to be somewhat less impromptu."
			
			"I'll consider it a positive, yes." Both parts, really. It would be nice to have notice, even if you want to see her.
	*if not (iasionstatus = "cutoff")
		#"I think I'm enjoying getting to know Iasion, in spite of everything. I'd prefer to do so without Demeter's intervention, though."
			"I think I'm enjoying getting to know Iasion, in spite of everything. I'd prefer to do so without Demeter's intervention, though."
			
			*if (demeterstatus = "open")
				It's not like you don't want your mother around at all, of course; it's just that your relationship with him and yours are different entities, and you don't necessarily want them blending together too much, especially at this fragile, early stage of things. 
			*if not (demeterstatus = "open")
				You'd have preferred not to need to handle your mother or anything to do with her until you were ready—if you're ever ready. But this complicates things. You can hardly expect her not to see your father at all, so you're left trying to navigate the situation as well as you can.
				
			Charon hums. "A reasonable desire, albeit one somewhat… complicated, now. Hades will not bar her from the Underworld entirely whilst Iasion yet remembers her, though I do think she understands that subsequent visits will need to be somewhat less impromptu."
			
			"I'll manage somehow, I suppose. I usually do."
	*if not (demeterstatus = "cutoff")
		#"I don't think I'll be spending much time with Iasion, if I can avoid it, but I suppose mother and I are getting along well enough."
			"I don't think I'll be spending much time with Iasion, if I can avoid it, but I suppose mother and I are getting along well enough."
			
			*if (iasionstatus = "cutoff")
				You'd made the decision not to pursue that relationship in any capacity, given the circumstances and your own emotional needs.
			*if not (iasionstatus = "cutoff")
				You'd made some attempt at getting to know him, but you just don't think it makes sense to go any further than you have. You know what you need to know about him, and… 'he,' the person with memories that are at all relevant to you, may not be around much longer.  
			
			*if (demeterstatus = "open")
				You and your mother have [i]always[/i] gotten along well enough, you suppose, so the news is more or less that there is no news. 
			*if not (demeterstatus = "open")
				As for Demeter, well. That was a bit of a surprise, but you can respect that she didn't seek you out against your will, even if she came here without your explicit permission. That means something, considering what your biggest problems with how she does things have always been. 
			
			Charon hums. "If that is your wish, it will not be terribly difficult to achieve, I am sure. For now, he is confined to the far bank, and eventually, he will not know to look for you." Their tone is ambiguous; you have no idea what they make of the situation at all. "But it is good that you are getting along with at least one of your parents."
			
			"And the harder one to avoid by far," you reply, a touch dryly.
	*if not (iasionstatus = "cutoff")
		#"It's exciting, of course! It feels like I'm... I don't know if 'repairing' my family is the right word, but things are developing in a way I'm really pleased with."
			"It's exciting, of course! It feels like I'm... I don't know if 'repairing' my family is the right word, but things are developing in a way I'm really pleased with."
			
			*if (demeterstatus = "open")
				You do need to build a relationship with Iasion, but while you have had the occasional disagreement with your mother, you don't consider that one something that needs a fix. 

				Theirs, though, is another matter, you're sure. 
			*if not (demeterstatus = "open")
				Maybe repair is at least partly appropriate to one of the two relationships you're involved in, whereas 'build' makes more sense for the other. Oddly enough, you think your mother's being here was a step in the right direction, even if
				*if (demeter_sequel_1 = false)
					you didn't go to see her. It means you know that she cared enough to show up, and also that she respected your boundaries by not seeking you out against your will. Maybe there's a chance all of this ends well.
				*if (demeter_sequel_1)
					you hadn't explicitly given her permission to visit you. After all, it showed that she cares enough about Iasion to come and visit him, and she didn't seek you out against your will—you went to her. Maybe there's a chance all of this ends well.

			Charon hums. "Then I am pleased to hear it. It may come as further good news that Hades will not bar Demeter from the Underworld entirely whilst Iasion yet remembers her, though I do think she understands that subsequent visits will need to be somewhat less impromptu."
			
			"Definitely good news."
*page_break
For a moment, Charon looks almost anxious about something, his fingers tapping lightly against the knee farther away from you. He's not one for unnecessary gestures, so this alone is something notable, but there's also something about the set of his mouth, thin lips pressed together close enough as to almost disappear. 

"My parents," they begin, a touch haltingly, "both perished in the Titanomachy. Perhaps it's a little too generous to call them my [i]parents[/i], considering that I was born of the commingling of their blood as they died." 

It's certainly not where you were [i]expecting[/i] them to take the conversation, but the connection between one topic and the other is obvious enough.

*fake_choice
	#"I—that's terrible. I'm so sorry, Charon."
		*set warm +1
		*set forthright +1
		"I—that's terrible. I'm so sorry, Charon." You pull in a breath. There's something particularly unkind about such a scenario. Not only did he not get to know his parents, but he [i]couldn't[/i] have. Their deaths were the very thing that made his life possible at all. 
		
		"You don't need to apologize," he replies quietly, staring out at the lake. The tension in his frame has not eased; if anything, the fingers on his knee are moving faster. "It is difficult to say I feel much at their loss—I never knew them, after all." 
		
		Cold, perhaps, but you can see how it would be the case. 
	#"I can't imagine what that's like."
		*set warm +1
		*set reserved +1
		"I can't imagine what that's like." And more to the point, you don't want to project about it. There's an instinct, of course, to express sympathy in a situation like this, but you don't know if Charon wants or needs that kind of thing, so you wait for some cue as to the right response. 
		
		"You certainly don't need to try," he replies quietly, staring out at the lake. The tension in his frame has not eased; if anything, the fingers on his knee are moving faster. "It is difficult to say I feel much at their loss—I never knew them, after all." 
		
		Cold, perhaps, but you can see how it would be the case. 
	#"So if they hadn't fought, you wouldn't have been born. Perhaps this is impolite to say, but... it's good that they did."
		*set cold +1
		*set forthright +1
		"So if they hadn't fought, you wouldn't have been born. Perhaps this is impolite to say, but... it's good that they did." You know Charon, and he's important to you. He may have been born from something that could be considered tragic, but it's not a tragedy in which you were personally involved, so it's hard for that to color things much, for you. 
		
		His eyes snap to you from where he was staring out at the lake, and he lets out a soft huff of air. "You know, that could almost have been offensive," he murmurs, shaking his head. "It isn't, of course." The tension in his frame has not eased; if anything, the fingers on his knee are moving faster. "It is difficult to say I feel much at their loss, myself—I never knew them, after all." 
		
		Cold, perhaps, but you can see how it would be the case for him as it is for you.
	#I find I don't really have much to say to that. Better just to let Charon finish saying what they need to.
		*set cold +1
		*set reserved +1
		You find you don't really have much to say to that. Better just to let Charon finish saying what they need to. There's a convention, of course, to express sympathy in a situation like this, but you don't know if Charon wants or needs that kind of thing, so you wait instead.
		
		"Perhaps I am meant to see this as an omen of what was to come," he continues quietly, staring out at the lake. The tension in his frame has not eased; if anything, the fingers on his knee are moving faster. "But it is difficult to say I feel much at their loss, or make anything of it—I never knew them, after all, and it wasn't my fault." 
		
		Cold, perhaps, but you can see how that would be the case. 
*page_break
"As with many deific offspring, my first domain was related to those of my parents. Not the oceans, of course—that domain had been taken and was soon reassigned to Poseidon. But I was allotted some minor control of storms. The violent, shipwrecking kind."

He scoffs softly. "Blood and violence, and an unhealthy measure of ambition. Hardly a wonder, I suppose, that I wound up as the god of war, for a time."

[i]That[/i] was clearly what they'd been meaning to say since the topic of their parents came up. The tension in the air could fire an arrow, you think, if you could form it into a string, and their eyes have fixed on your face. Waiting for your reaction to this piece of information, no matter how casually it was dropped between you.

*fake_choice
	#"Wait, what? There's an Ares on Olympus, so how could you also be...?"
		"Wait, what? There's an Ares on Olympus, so how could you also be...?" You blink, trying to get your head around the idea that there are two Ares. 

		Charon expels a breath; perhaps one they'd been holding for some time. "That domain was once a part of me," they say. "Just as the name was once mine. Both were stripped from me as part of the terms of my exile to the Underworld. I… like to think I was an entirely different person, then, but the truth is not quite so convenient." 
		
		"What do you mean?"
		
		"Violence," he replies calmly. "Killing. Bloodlust, if you will. They are all very much part of my nature, regardless of what I try to project to the contrary."
		
		That answers the question, but leaves several more in its wake.
	#My eyes widen in shock. I'd never have guessed such a thing, and I'm not even sure how that would work, since there already [i]is[/i] an Ares.
		Your eyes widen in shock. You'd never have guessed such a thing, and you're not even sure how that would work, since there already [i]is[/i] an Ares.

		Charon expels a breath; perhaps one they'd been holding for some time. "That domain was once a part of me," they say. "Just as the name was once mine. Both were stripped from me as part of the terms of my exile to the Underworld. I… like to think I was an entirely different person, then, but the truth is not quite so convenient." 

		"What do you mean?"
		
		"Violence," he replies calmly. "Killing. Bloodlust, if you will. They are all very much part of my nature, regardless of what I try to project to the contrary."
		
		That answers the questions you'd only begun to form, but leaves several more in their wake.
	#I press my lips together. Now that I really think about it... maybe it sort of makes sense. Their self-loathing, their obvious talent for physical tasks. Their exile from Olympus—but for a few gaps I don't know how to fill, I could see it. 
		You press your lips together. Now that you really think about it... maybe it sort of makes sense. Their self-loathing, their obvious talent for physical tasks. Their exile from Olympus—but for a few gaps you don't know how to fill, you could see it. 

		Charon expels a breath; perhaps one they'd been holding for some time. "That domain was once a part of me," they say. "Just as the name 'Ares' was once mine. Both were stripped from me as part of the terms of my exile to the Underworld. I… like to think I was an entirely different person, then, but the truth is not quite so convenient." 

		"What do you mean?"
		
		"Violence," he replies calmly. "Killing. Bloodlust, if you will. They are all very much part of my nature, regardless of what I try to project to the contrary."
		
		That answers the questions you'd only begun to form, but leaves several more in their wake.
	#@{convotoggle [✘]|} "Do you take me for some kind of fool? I've not met Ares personally, but I've seen him, and you look nothing alike."
		"Do you take me for some kind of fool? I've not met Ares personally, but I've seen him, and you look nothing alike." It's a bit offensive that they could think you [i]so[/i] cloistered as to not even know something so basic. 

		Charon expels a breath; perhaps one they'd been holding for some time. "That domain was once a part of me," they say. "Just as the name 'Ares' was once mine. Both were stripped from me as part of the terms of my exile to the Underworld. I… like to think I was an entirely different person, then, but the truth is not quite so convenient." 

		"What do you mean?"
		
		"Violence," he replies calmly. "Killing. Bloodlust, if you will. They are all very much part of my nature, regardless of what I try to project to the contrary."

		You suppose that would explain it, and you feel your metaphorical hackles relax, just slightly.
*page_break
"I hope," Charon says, brows knitting, "that this does not change your opinion of me by too great a degree… though I would understand if it did. Above all, I want to assure you that you have nothing to fear from me." 

A pause. "Truly, it's the opposite. I—" he clears his throat, and no further words escape. 

*fake_choice
	#"Well... I don't know. It's a lot to take in, but I don't think it changes much."
		"Well... I don't know. It's a lot to take in, but I don't think it changes much." 

		Obviously, it's a bit surprising, but then you already knew that Charon, like Alekto, was an Olympian exile. It's not so strange, in your mind, for an exile to have taken on a new identity, even if you're not exactly sure just [i]how[/i] taking a domain away from someone works. 

		But Charon is Charon. Whomever they used to be, it's obvious that they've not been deceptive about who they are [i]now[/i]. It's always been clear that there are parts of their past they aren't comfortable talking about, and that's fine. You're not entitled to know everything about them. 

		You're glad you have enough of their trust that they [i]would[/i] tell you something like this, but that's really it. 

		Their shoulders relax, "That is… gracious," they murmur, eyes finding their hand. Its motion stills, and the fingers curl instead into a loose fist. "Thank you."

		"You don't have to thank me for something like this, Charon." 

		He turns his head towards you, eyes slightly narrow. "On the contrary, I absolutely must. What for you changes little could very reasonably have changed everything. And if you had thought of me the way I deserve to be thought of, what I lost would have been indescribably important."

		You suppose you can understand what he means, but was he really expecting that, all at once, nothing else you knew about him would have any weight?

		*if ((tag_pacifist) or (violencesucks))
			You're certainly disinclined to violence, but knowing that there's something like that in his past doesn't change who he is today. 
	#"Of course it [i]changes[/i] things, but it's not as though it makes anything worse."
		"Of course it [i]changes[/i] things, but it's not as though it makes anything worse."

		Obviously, it's a bit surprising, but then you already knew that Charon, like Alekto, was an Olympian exile. It's not so strange, in your mind, for an exile to have taken on a new identity, even if you're not exactly sure just [i]how[/i] taking a domain away from someone works. 

		New information inevitably changes your understanding, of course, and so you won't say that nothing is different. You'd be a fool, were that the case. But it's always been clear that there are parts of their past they aren't comfortable talking about, and that's fine. You're not entitled to know everything about them. 

		You're glad you have enough of their trust that they [i]would[/i] tell you something like this, but that's a different matter. 

		Their shoulders relax, "That is… gracious," they murmur, eyes finding their hand. Its motion stills, and the fingers curl instead into a loose fist. "Thank you."

		"You don't have to thank me for something like this, Charon." 

		He turns his head towards you, eyes slightly narrow. "On the contrary, I absolutely must. What for you changes little could very reasonably have changed everything. And if you had thought of me the way I deserve to be thought of, what I lost would have been indescribably important."

		You suppose you can understand what he means, but was he really expecting that, all at once, nothing else you knew about him would have any weight?

		*if ((tag_pacifist) or (violencesucks))
			You're certainly disinclined to violence, but knowing that there's something like that in his past doesn't change who he is today. 
	*if ((tag_pacifist) or (violencesucks))
		#"I don't know... I just. War is..." It's antithetical to everything you are.
			*set charon_sequelinitial2 "complicated"
			"I don't know... I just. War is..." It's antithetical to everything you are. Everything you believe. The idea that someone you're close to, someone you're friends with, had at one point been not just a participant in willing violence but its very avatar, is… difficult to accept, right away. 

			"That, of course, makes sense," they say, tone as deliberately-neutral as you've ever heard it. 
			*if (tag_intuitive)
				You catch the smallest flicker of hurt over their expression, but they mask it quickly. 
			"And you are welcome to do with this information whatever you feel you must. As I have said, I am no danger to you, and I no longer have the specific domain that troubles you, but I [i]am[/i] someone who finds satisfaction in my strength. I will not pretend that part of me has disappeared completely." 

			You struggle for a moment for further words. "It's not… I don't—" You have to stop, because you [i]do[/i] think a little differently of him, now. You can't pretend that you don't, and you wouldn't want to lie. 

			Charon offers you a small smile. "Please do not fret," he says quietly. "You have all the time in the world to decide how you feel about this, and about me. In the meantime, I hope you will continue to permit me to behave as though we are friends. If I need to do otherwise, please let me know." 

			You nod. That much, at least, you can do. 

			The revelation certainly makes things considerably more awkward, on some level, and as soon as you have both finished eating, Charon pulls their feet from the water. "My apologies for bringing you all the way out here to say something so unpleasant," he says. "If, at a later time, you would like to discuss this in greater detail, I would be willing. For now, perhaps, let us return to the Keep." 

			You stand, too, quickly gathering up your few things. You can understand why they might not want to discuss it [i]right now[/i]. Probably you've made them about as uncomfortable as they've made you. For the moment, a little distance is probably best. 

			Or so you tell yourself, when the two of you part ways.
			*goto chap3end
	#"I do wish you'd felt like you could tell me this sooner. That's the only part that bothers me."
		"I do wish you'd felt like you could tell me this sooner. That's the only part that bothers me."

		Obviously, it's a bit surprising, but then you already knew that Charon, like Alekto, was an Olympian exile. It's not so strange, in your mind, for an exile to have taken on a new identity, even if you're not exactly sure just [i]how[/i] taking a domain away from someone works. 

		You know you aren't [i]entitled[/i] to the specifics of their life or experience, but still. You find yourself wishing that perhaps they had trusted you with it a little sooner. 

		"I…" Charon pauses, considering for a long moment "I will not apologize for that. I wish as well that trust were easier for me to give, but it is not. You were never in any danger because of what I keep to myself, and so it is mine to keep. But perhaps we have somewhat different understandings of time. It took me years to tell everyone else who didn't already know themselves." 

		His smile is a bit thin, but it's present. 

		You suppose, perhaps, that might be true. For you, a year is still quite a long time. For them… it's probably not much at all. 

		"But… thank you," they add, something in their shoulders relaxing. Their eyes find their hand, and its motion stills, fingers curling instead into a loose fist. "You are… most gracious."

		"You don't have to thank me for something like this, Charon." 

		He turns his head towards you, eyes slightly narrow. "On the contrary, I absolutely must. What for you changes nothing could very reasonably have changed everything. And if you had thought of me the way I deserve to be thought of, what I lost would have been indescribably important."

		You suppose you can understand what he means, but was he really expecting that, all at once, nothing else you knew about him would have any weight?

		*if ((tag_pacifist) or (violencesucks))
			You're certainly disinclined to violence, but knowing that there's something like that in his past doesn't change who he is today. 
*page_break
*if (charon_justfriends)
	Their eyes closing for a moment, Charon releases a soft breath, opening them again with a faint smile. "I hope you understand what I mean, of course," they say softly. "How valuable your regard and friendship truly are to me. It is a strange feeling, to have known someone for such a relatively short time and yet… to have felt so strongly that I could trust ${him} with this. With the worst of my secrets."
	
	*fake_choice
		#"If that's the worst of your secrets, then there was never anything to worry about, Charon." 
			*set serious +1
			"If that's the worst of your secrets, then there was never anything to worry about, Charon."  You manage a smile, though perhaps only a small one. The subject [i]is[/i] a grave one, after all, and you want them to know you're taking it seriously. 
			
			"Hm." For a moment, their brows pucker. "Now I find myself wondering if perhaps I should not have explained in greater detail what it [i]meant[/i] to be who I was… or if perhaps I have secrets that are worse still." 
			
			You can understand the sentiment, but it's not as though you have no idea what 'Ares' presides over. Warfare is an ugly thing, and you are not oblivious to the fact that Charon may well have done some very ugly things as part of it. 
			
			"Then let me rephrase: there's still nothing to worry about. I won't say the past doesn't matter at all, but I know you. And whatever is in yours, I won't let it ruin our friendship." 
			
			For the first time in… at least since you got here, but perhaps [i]ever[/i], you think you might actually see the last little bit of tension escape them. Only briefly, but for long enough that you can notice it. 
			
			"Then I will hope that is true, and do my very best to believe it," he says softly. "Thank you, ${name}."
			
			The relaxation makes the rest of your time together easy. Perhaps, eventually, Charon will be willing to say more about that part of his life, but for now, you are content. And you think perhaps he might be as well. 
			
			That's more than enough, for now.
		#@{convotoggle [☆]|} "I've got some pretty terrible ones of my own. Did you know I once stole flowers from my mother's garden?"
			*set humorous +1
			"I've got some pretty terrible ones of my own. Did you know I once stole flowers from my mother's garden?" You offer them a smile, genuine if a little humorous. It's a joke, of course, in the sense that what you've described is hardly a 'terrible secret,' but you have to hope that helps. 
			
			Charon frowns slightly. "I appreciate what you're trying to do," they reply, "but this isn't the kind of thing I can feel amusement at, I'm afraid. In fact it makes me wonder if perhaps I should not have explained in greater detail what it [i]meant[/i] to be who I was… or if perhaps I have secrets that are worse still." 
			
			You can understand the sentiment, but it's not as though you have no idea what 'Ares' presides over. Warfare is an ugly thing, and you are not oblivious to the fact that Charon may well have done some very ugly things as part of it. 
			
			"Then let me rephrase: there's still nothing to worry about. I won't say the past doesn't matter at all, but I know you. And whatever is in yours, I won't let it ruin our friendship." 
			
			For the first time in… at least since you got here, but perhaps [i]ever[/i], you think you might actually see the last little bit of tension escape them. Only briefly, but for long enough that you can notice it. 
			
			"Then I will hope that is true, and do my very best to believe it," he says softly. "Thank you, ${name}."
			
			The relaxation makes the rest of your time together easy. Perhaps, eventually, Charon will be willing to say more about that part of his life, but for now, you are content. And you think perhaps he might be as well. 
			
			That's more than enough, for now.
		#"That's because our friendship isn't the kind of thing that can just disappear like that. Who you were doesn't change who you are, and [i]that[/i] person is my friend."
			*set warm +1
			"That's because our friendship isn't the kind of thing that can just disappear like that. Who you were doesn't change who you are, and [i]that[/i] person is my friend." You focus on the sincerity of your feelings, trying to convey that warmth and genuine affection to Charon, who still seems a bit like they might need it. 
			
			"Hm." For a moment, their brows pucker. "Now I find myself wondering if perhaps I should not have explained in greater detail what it [i]meant[/i] to be who I was. I cannot agree that it has no bearing on who I am today. As I said… I still sometimes [i]feel[/i] similarly to how I did, then." 
			
			You can understand the sentiment, but it's not as though you have no idea what 'Ares' presides over. Warfare is an ugly thing, and you are not oblivious to the fact that Charon may well have done some very ugly things as part of it. Nor did you miss the part about the unwelcome emotions. 
			
			But that's the thing. They're [i]unwelcome[/i], now.
			
			"Then let me rephrase: there's still nothing to worry about. I won't try to argue that the past doesn't matter at all, but I know you. And whatever is in yours, I won't let it ruin our friendship." 
			
			For the first time in… at least since you got here, but perhaps [i]ever[/i], you think you might actually see the last little bit of tension escape them. Only briefly, but for long enough that you can notice it. 
			
			"Then I will hope that is true, and do my very best to believe it," he says softly. "Thank you, ${name}."
			
			The relaxation makes the rest of your time together easy. Perhaps, eventually, Charon will be willing to say more about that part of his life, but for now, you are content. And you think perhaps he might be as well. 
			
			That's more than enough, for now.
		#"I really don't think you need have agonized so much about it. Has anyone here [i]ever[/i] rejected you because of this?"
			*set cold +1
			"I really don't think you need have agonized so much about it. Has anyone here [i]ever[/i] rejected you because of this?" You can't imagine that they have, and so it's hard for you to understand why he would make it so large in his own head. It doesn't really make sense, frankly, and you're not above pointing that out, especially if it might save him doing more of the same. 
			
			"Here? Yes and no." For a moment, their brows pucker. "There were certainly cases where someone did not accept my deeds so easily. Which makes me wonder if perhaps I should not have explained in greater detail what it [i]meant[/i] to be who I was… or if perhaps I have secrets that are worse still." 
			
			You can understand the sentiment, but it's not as though you have no idea what 'Ares' presides over. Warfare is an ugly thing, and you are not oblivious to the fact that Charon may well have done some very ugly things as part of it. 
			
			"Then let me rephrase: there's still nothing to worry about. I won't say the past doesn't matter at all. That would be incorrect. But whatever is in yours, I believe is quite insufficient to ruin our friendship. Perhaps I am mistaken, and will think differently with further evidence. But to be honest, that's highly unlikely."
			
			For the first time in… at least since you got here, but perhaps [i]ever[/i], you think you might actually see the last little bit of tension escape them. Only briefly, but for long enough that you can notice it. 
			
			"Then I will hope that is true, and do my very best to believe it," he says softly. "Thank you, ${name}."
			
			The relaxation makes the rest of your time together easy. Perhaps, eventually, Charon will be willing to say more about that part of his life, but for now, you are content. And you think perhaps he might be as well. 
			
			That's more than enough, for now.
	*goto chap3end
*if ((charon_justfriends = "false") and (npc_init))
	Their eyes closing for a moment, Charon releases a soft breath, opening them again with a faint smile. "I hope you understand what I mean, of course," they say softly. "How valuable your regard and friendship truly are to me. It is a strange feeling, to have known someone for such a relatively short time and yet… to have felt so strongly that I could trust them with this. With the worst of my secrets."
	
	There's a hint of strain in the subtle furrow of their brow, the way their eyes bore into yours, the striking pale blue somehow more intense even than the color itself would otherwise be. "And yet you cannot imagine how terrified I was that somehow, I would turn out to be incorrect. That this would cost me [i]you[/i]. Do you have any idea how unbearable that thought was?"
	
	*fake_choice
		#@{convotoggle [♥]|} "You wouldn't lose me, Charon. You couldn't."
			*set overt +1
			*set charon_romance true
			"You wouldn't lose me, Charon. You couldn't." You're surprised that they admitted anything quite so personal as that, because it almost sounds like… 
			
			Well, it almost sounds like they feel the same way about you that you do about them. 
			
			But this is definitely not the time to ask about [i]that[/i]—rather, you want to offer as much reassurance as you can, and let your feelings come through in it to the extent you're able. That much, surely, would be all right. 
			
			Charon swallows; you can see their throat work, as if they'd struggled to do so. "Now I find myself wondering if perhaps I should not have explained in greater detail what it [i]meant[/i] to be who I was… or if perhaps I have secrets that are worse still." They shake their head. "To hear that, and to wonder still if it could possibly be true, I…"
			
			You can understand the sentiment, but it's not as though you have no idea what 'Ares' presides over. Warfare is an ugly thing, and you are not oblivious to the fact that Charon may well have done some very ugly things as part of it. 
			
			But even so.
			
			"It is true, Charon. It is. I [i]promise[/i] you that."
			
			For the first time in… at least since you got here, but perhaps [i]ever[/i], you think you might actually see the last little bit of tension escape them. Only briefly, but for long enough that you can notice it. 
			
			"Then I hope, someday soon, I can permit myself to believe it," he whispers. "Thank you, ${name}."
			
			Perhaps, eventually, Charon will be willing to say more about that part of his life, but for now, you are content. You've said what you needed to say, and he's at least willing to try and believe it.
			
			That's more than enough, for now.
		#@{convotoggle [♥]|} "I think... I can get close, if I imagine what losing you would feel like."
			*set subtle +1
			*set charon_romance true
			"I think... I can get close, if I imagine what losing you would feel like." You're surprised that they admitted anything quite so personal as that, because it almost sounds like… 
			
			Well, it almost sounds like they feel the same way about you that you do about them. 
			
			But this is definitely not the time to ask about [i]that[/i]—you're not even sure you're prepared to take that kind of leap. In any case it would only complicate things at this moment, and so you do your best to offer your feelings sincerely, truly, while allowing them to remain an undercurrent to your reassurance. 
			
			Charon swallows; you can see their throat work, as if they'd struggled to do so. "Now I find myself wondering if perhaps I should not have explained in greater detail what it [i]meant[/i] to be who I was… or if perhaps I have secrets that are worse still." They shake their head. "To hear that, and to feel it must mean something so…"
			
			You can understand the sentiment, but it's not as though you have no idea what 'Ares' presides over. Warfare is an ugly thing, and you are not oblivious to the fact that Charon may well have done some very ugly things as part of it. 
			
			But even so.
			
			"Then let me make it clearer. Charon, whatever is in your past, whatever other secrets you have that make you worry what I'll think… I'll accept them. I won't let them change how I feel about you. I promise."
			
			For the first time in… at least since you got here, but perhaps [i]ever[/i], you think you might actually see the last little bit of tension escape them. Only briefly, but for long enough that you can notice it. 
			
			"Then I hope, someday soon, I can permit myself to believe that," he whispers. "Thank you, ${name}."
			
			Perhaps, eventually, Charon will be willing to say more about that part of his life, but for now, you are content. You've said what you needed to say, and he's at least willing to try and believe it.
			
			That's more than enough, for now.
		#"Even if that did happen, you'd be all right, you know? We're friends, but you have many. Please don't hold my opinion up so high."
			*set charon_justfriends true
			"Even if that did happen, you'd be all right, you know? We're friends, but you have many. Please don't hold my opinion up so high." You're surprised that they admitted anything quite so personal as that, because it almost sounds like… 
			
			Well it almost sounds like they feel a way about you that you don't feel about them. And you think it's worth drawing a boundary there, but it's more important right now that you reassure them that your friendship is not at peril from any of this. 
			
			"I—" they clear their throat. "Perhaps you are correct. And still, I have few enough friends that it would hurt to lose any one of you." Their smile is awkward, sitting uncomfortably on their face. "Now I find myself wondering if perhaps I should not have explained in greater detail what it [i]meant[/i] to be who I was… or if perhaps I have secrets that are worse still." 
			
			You can understand the sentiment, but it's not as though you have no idea what 'Ares' presides over. Warfare is an ugly thing, and you are not oblivious to the fact that Charon may well have done some very ugly things as part of it. 
			
			"Then let me add this: there's still nothing to worry about. I won't say the past doesn't matter at all, but I know you. And whatever is in yours, I won't let it ruin our friendship." 
			
			For the first time in… at least since you got here, but perhaps [i]ever[/i], you think you might actually see the last little bit of tension escape them. Only briefly, but for long enough that you can notice it. 
			
			"Then I will hope that is true, and do my very best to believe it," he says softly. "Thank you, ${name}."
			
			Perhaps, eventually, Charon will be willing to say more about that part of his life, but for now, you are content. You've said what you needed to say, and he's taking it into consideration.
			
			That's more than enough, for now.
		#"Surely there was no need to be so worried. I can't imagine anyone here has ever rejected your friendship because of this, have they?"
			"Surely there was no need to be so worried. I can't imagine anyone here has ever rejected your friendship because of this, have they?"
			
			You can't imagine that they have, and so it's hard for you to understand why he would make it so large in his own head. It doesn't really make sense, frankly, and you're not above pointing that out, especially if it might save him doing more of the same. 
			
			"Here? Yes and no." For a moment, their brows pucker. "There were certainly cases where someone did not accept my deeds so easily. Which makes me wonder if perhaps I should not have explained in greater detail what it [i]meant[/i] to be who I was… or if perhaps I have secrets that are worse still." 
			
			You can understand the sentiment, but it's not as though you have no idea what 'Ares' presides over. Warfare is an ugly thing, and you are not oblivious to the fact that Charon may well have done some very ugly things as part of it. 
			
			"Then let me rephrase: there's still nothing to worry about. I won't say the past doesn't matter at all. That would be incorrect. But whatever is in yours, I believe is quite insufficient to ruin our friendship. Perhaps I am mistaken, and will think differently with further evidence. But to be honest, that's highly unlikely."
			
			For the first time in… at least since you got here, but perhaps [i]ever[/i], you think you might actually see the last little bit of tension escape them. Only briefly, but for long enough that you can notice it. 
			
			"Then I will hope that is true, and do my very best to believe it," he says softly. "Thank you, ${name}."
			
			The relaxation makes the rest of your time together easy. Perhaps, eventually, Charon will be willing to say more about that part of his life, but for now, you are content. And you think perhaps he might be as well. 
			
			That's more than enough, for now.
	*goto chap3end
*if (npc_init = false)
	Their eyes closing for a moment, Charon releases a soft breath, opening them again with a faint smile. "I hope you understand what I mean, of course," they say softly. "How valuable your regard and friendship truly are to me. It is a strange feeling, to have known someone for such a relatively short time and yet… to have felt so strongly that I could trust them with this. With the worst of my secrets."

	There's a hint of strain in the subtle furrow of their brow, the way their eyes bore into yours, the striking pale blue somehow more intense even than the color itself would otherwise be.
	
	*fake_choice
		#@{convotoggle [♥]|} Leaning in, I kiss their cheek. "What I feel about you isn't the kind of thing that can just disappear like that. Who you were doesn't change who you are, and [i]that[/i] person is the one I care about."
			*set overt +1
			*set charon_romance true
			Leaning in, you kiss their cheek. It's not so far to go, considering they're sitting right next to you, and they remain frozen, perfectly still as you approach, pulling in an audible breath when your lips touch the smooth skin of their face.
			
			You shift back carefully, clearing your throat with a gentle hemming sound. "What I feel about you isn't the kind of thing that can just disappear like that. Who you were doesn't change who you are, and [i]that[/i] person is the one I care about."
			
			This is, of course, a fairly overt way of making clear just what it [i]is[/i] that you feel for them, and you can hardly blame Charon for the way they look at you, eyes wide enough that the full blueness of their iris is visible on every side, lips slightly parted. 
			
			"I…" They cough, turning away slightly so as not to do so in your direction. You don't think you're imagining the slight darkening of the ear you can see, though. 
			
			"Now, I…" They trail off, turning back to you with a conflicted expression. "I wonder if perhaps I should not have explained in greater detail what it [i]meant[/i] to be who I was. I cannot agree that it has no bearing on who I am today. As I said… I still sometimes [i]feel[/i] similarly to how I did, then, and you…" 
			
			You can understand the sentiment, but it's not as though you have no idea what 'Ares' presides over. Warfare is an ugly thing, and you are not oblivious to the fact that Charon may well have done some very ugly things as part of it. Nor did you miss the part about the unwelcome emotions. 
			
			But that's the thing. They're [i]unwelcome[/i], now.
			
			"Then let me rephrase: there's still nothing to worry about. I won't try to argue that the past doesn't matter at all, but I know you. And whatever is in yours, I won't let it ruin this. You're more important to me than any of that." 
			
			For the first time in… at least since you got here, but perhaps [i]ever[/i], you think you might actually see the last little bit of tension escape them. Only briefly, but for long enough that you can notice it. 
			
			"Then I hope, someday soon, I can permit myself to believe that," he whispers. "Thank you, ${name}."
			
			Perhaps, eventually, Charon will be willing to say more about that part of his life, but for now, you are content. You've said what you needed to say, and he's at least willing to try and believe it.
			
			That's more than enough, for now.
		#@{convotoggle [♥]|} I take up their hand gently. "If that's the worst of your secrets, then there was never anything to worry about, Charon." 
			*set subtle +1
			*set charon_romance true
			You take up their hand gently. "If that's the worst of your secrets, then there was never anything to worry about, Charon." Your fingers squeeze softly around their own. You manage a smile, though perhaps only a small one. The subject [i]is[/i] a grave one, after all, and you want them to know you're taking it seriously. 
			
			"Hm." For a moment, their brows pucker, but their grip tightens on yours in turn. "Now I find myself wondering if perhaps I should not have explained in greater detail what it [i]meant[/i] to be who I was… or if perhaps I have secrets that are worse still." 
			
			You can understand the sentiment, but it's not as though you have no idea what 'Ares' presides over. Warfare is an ugly thing, and you are not oblivious to the fact that Charon may well have done some very ugly things as part of it. 
			
			"Then let me rephrase: there's still nothing to worry about. I won't say the past doesn't matter at all, but I know you. And whatever is in yours, I won't let it ruin this." 
			
			For the first time in… at least since you got here, but perhaps [i]ever[/i], you think you might actually see the last little bit of tension escape them. Only briefly, but for long enough that you can notice it. 
			
			"Then I hope, someday soon, I can permit myself to believe that," he whispers. "Thank you, ${name}."
			
			Perhaps, eventually, Charon will be willing to say more about that part of his life, but for now, you are content. You've said what you needed to say, and he's at least willing to try and believe it.
			
			That's more than enough, for now.
		#"Even if that did happen, you'd be all right, you know? We're friends, but you have many. Please don't hold my opinion up so high."
			*set charon_justfriends true
			"Even if that did happen, you'd be all right, you know? We're friends, but you have many. Please don't hold my opinion up so high." You're a little worried by the implications of what they've said. You can't be sure, but they almost make it sound like…
			
			Well it almost sounds like they feel a way about you that you don't feel about them. And you think it's worth drawing a boundary there, but it's more important right now that you reassure them that your friendship is not at peril from any of this. 
			
			"I—" they clear their throat. "Perhaps you are correct. And still, I have few enough friends that it would hurt to lose any one of you." Their smile is awkward, sitting uncomfortably on their face. "Now I find myself wondering if perhaps I should not have explained in greater detail what it [i]meant[/i] to be who I was… or if perhaps I have secrets that are worse still." 
			
			You can understand the sentiment, but it's not as though you have no idea what 'Ares' presides over. Warfare is an ugly thing, and you are not oblivious to the fact that Charon may well have done some very ugly things as part of it. 
			
			"Then let me add this: there's still nothing to worry about. I won't say the past doesn't matter at all, but I know you. And whatever is in yours, I won't let it ruin our friendship." 
			
			For the first time in… at least since you got here, but perhaps [i]ever[/i], you think you might actually see the last little bit of tension escape them. Only briefly, but for long enough that you can notice it. 
			
			"Then I will hope that is true, and do my very best to believe it," he says softly. "Thank you, ${name}."
			
			Perhaps, eventually, Charon will be willing to say more about that part of his life, but for now, you are content. You've said what you needed to say, and he's taking it into consideration.
			
			That's more than enough, for now.
		#"Surely there was no need to be so worried. I can't imagine anyone here has ever rejected your friendship because of this, have they?"
			"Surely there was no need to be so worried. I can't imagine anyone here has ever rejected your friendship because of this, have they?"
			
			You can't imagine that they have, and so it's hard for you to understand why he would make it so large in his own head. It doesn't really make sense, frankly, and you're not above pointing that out, especially if it might save him doing more of the same. 
			
			"Here? Yes and no." For a moment, their brows pucker. "There were certainly cases where someone did not accept my deeds so easily. Which makes me wonder if perhaps I should not have explained in greater detail what it [i]meant[/i] to be who I was… or if perhaps I have secrets that are worse still." 
			
			You can understand the sentiment, but it's not as though you have no idea what 'Ares' presides over. Warfare is an ugly thing, and you are not oblivious to the fact that Charon may well have done some very ugly things as part of it. 
			
			"Then let me rephrase: there's still nothing to worry about. I won't say the past doesn't matter at all. That would be incorrect. But whatever is in yours, I believe is quite insufficient to ruin our friendship. Perhaps I am mistaken, and will think differently with further evidence. But to be honest, that's highly unlikely."
			
			For the first time in… at least since you got here, but perhaps [i]ever[/i], you think you might actually see the last little bit of tension escape them. Only briefly, but for long enough that you can notice it. 
			
			"Then I will hope that is true, and do my very best to believe it," he says softly. "Thank you, ${name}."
			
			The relaxation makes the rest of your time together easy. Perhaps, eventually, Charon will be willing to say more about that part of his life, but for now, you are content. And you think perhaps he might be as well. 
			
			That's more than enough, for now.
	*goto chap3end

*label chap3pyri
Today, you've been out 'for 'target practice' with Pyri, an exercise which
*if (hasbow)
	has mostly involved shooting entire volleys of arrows, both at stationary and moving clay targets, while Pyri attempts to do the same in alternate turns. 
*if ((hasbow = false) and (training = "magic"))
	which has mostly involved shooting continuous volleys of magical projectiles, both at stationary and moving clay targets, while Pyri attempts to do the same with a bow in alternate turns. 
*if ((hasbow = false) and (training != "magic"))
	which has mostly involved shooting entire quiversful of arrows from a borrowed bow, both at stationary and moving clay targets, while Pyri attempts to do the same in alternate turns. 

It seems they've had enough for now, though, because they collapse to their rear end in the grass, not far from where you've laid out a blanket for ground cover, your lunch in a basket atop it. 

*if (tag_athletic)
	"I'm never going to beat you," they admit on a long sigh. "You're just too good at aiming fast." 
	
	You don't know about 'never,' but you did fairly thoroughly defeat them most rounds. Their problem isn't that they can't do well, it's that they're inconsistent.
*if not ((tag_athletic) or (tag_unathletic))
	"I almost had you that time," they say on a long sigh. "I've got to keep practicing."
	
	Some of the rounds were quite close, you must admit.
*if (tag_unathletic)
	"I think… we both need some more practice," they admit on a long sigh. "Alekto would be ashamed of us. Our aim is kind of terrible."
	
	You doubt Alekto would really much mind, but they do have a point otherwise, you must confess. 
	
"Anyway, did you have fun? That's the important part, really."

*fake_choice
	#"Of course I did. I was with you, after all."
		*set warm +1
		"Of course I did. I was with you, after all." You offer them a warm smile, and Pyri huffs, looking a bit pleased by the reply. 
		
		"Well, good. The point was that you got a break, you know? Time away from all the heavy stuff. Whether you like it or not, it's still heavy."
		
		That's not an unfair way of describing your recent situation, and you nod a little along with the words. They hadn't mentioned such a motive for the activity when they asked you to participate, but 
		*if (tag_unintuitive)
			even you had a feeling they might be looking to take your mind off things.
		*if not (tag_unintuitive)
			it was obvious they meant to help you take your mind off things. 
	#"I suppose so, yes."
		*set cold +1
		"I suppose so, yes." It's not the first activity you would reach for, if you were choosing your own 'fun,' and perhaps enjoyment is seldom your primary consideration, but… it was nice enough. You suppose the company had more to do with that than the activity, though. 
		
		"Well, good. The point was that you got a break, you know? Time away from all the heavy stuff. Whether you like it or not, it's still heavy."
		
		That's not an unfair way of describing your recent situation, you suppose, and you nod once. They hadn't mentioned such a motive for the activity when they asked you to participate, but 
		*if (tag_unintuitive)
			even you had a feeling they might be looking to take your mind off things.
		*if not (tag_unintuitive)
			it was obvious they meant to help you take your mind off things. 
	#"I'm not sure it was the most efficient use of my time, but breaks are important."
		*set cold +1
		"I'm not sure it was the most efficient use of my time, but breaks are important." It's not the first activity you would reach for, if you were choosing your own 'fun,' and perhaps enjoyment is seldom your primary consideration, but… it was nice enough. You suppose the company had more to do with that than the activity, though. 
		
		"Well, good. That was the point, you know? That you got a break. Time away from all the heavy stuff. Whether you like it or not, it's still heavy."
		
		That's not an unfair way of describing your recent situation, you suppose, and you nod once. They hadn't mentioned such a motive for the activity when they asked you to participate, but 
		*if (tag_unintuitive)
			even you had a feeling they might be looking to take your mind off things.
		*if not (tag_unintuitive)
			it was obvious they meant to help you take your mind off things. 
	#"I think it was good for stress relief, honestly."
		*set warm +1
		"I think it was good for stress relief, honestly." You offer them a warm smile, and Pyri huffs, looking a bit pleased by the reply. 
		
		"Shooting things can be pretty relaxing, right? Anyway, good. That was the point, you know? That you got a break. Time away from all the heavy stuff. Whether you like it or not, it's still heavy."
		
		That's not an unfair way of describing your recent situation, and you nod a little along with the words. They hadn't mentioned such a motive for the activity when they asked you to participate, but 
		*if (tag_unintuitive)
			even you had a feeling they might be looking to take your mind off things.
		*if not (tag_unintuitive)
			it was obvious they meant to help you take your mind off things. 
*page_break
Pyri shuffles their way properly onto the blanket, removing their sandals at the edge to sit barefoot and cross-legged next to you. 

"About all that stuff, though… I was wondering how it went, you know? How you feel about it." 

It's not an unexpected question, obviously. You'd handled all of that essentially on your own, and you have no doubt plenty of people are concerned with how it went. 

*fake_choice
	#"Maybe this is selfish, but I'm really ready for things to be quiet again."
		"Maybe this is selfish, but I'm really ready for things to be quiet again." You can't say you begrudge anyone anything, exactly, but all of this has been quite disturbing to your ordinary routine. That's not [i]unacceptable[/i], but it's been exhausting, and you really need some time to not have to think about things as personally significant—and fraught—as your relationships to your parents. 
		
		The fact that Demeter has left for now is certainly helping with that. 
		
		"I think it makes sense," Pyri says with a shrug. "If it were me, I'd definitely be hoping for a break, soon. The mental kind, if that makes sense."
		
		You do, of course, understand exactly what they mean. "Peace of mind would be nice. Perhaps I'll have a little more of it, now, for a while."
		
		At least until the next inevitable development.
	*if not (iasionstatus = "cutoff")
		#"It's confusing, and often difficult, but I'm glad for the chance to build and repair my relationships."
			"It's confusing, and often difficult, but I'm glad for the chance to build and repair my relationships." 
		
			*if (demeterstatus = "open")
				Not that you necessarily think either of them need much repairing, on your side. You need to build one with Iasion, but while you have had the occasional disagreement with your mother, you don't consider that relationship one that needs a fix. 

				Theirs, though, is another matter, you're sure. 
			*if not (demeterstatus = "open")
				And there's certainly a relationship to repair, as well as a relationship to build. Oddly enough, you think your mother's being here was a step in the right direction, even if
				*if (demeter_sequel_1 = false)
					you didn't go to see her. It means you know that she cared enough to show up, and also that she respected your boundaries by not seeking you out against your will. Maybe there's a chance all of this ends well.
				*if (demeter_sequel_1)
					you hadn't explicitly given her permission to visit you. After all, it showed that she cares enough about Iasion to come and visit him, and she didn't seek you out against your will—you went to her. Maybe there's a chance all of this ends well.

			"Well… just don't push yourself too hard," Pyri advises, adjusting the headband holding their hair back. "And, uh… you've probably guessed this already, but I think Boss is probably going to be pretty easy on Demeter while Iasion's here and let her in if she wants to see him. But I guess that's probably a good thing, for you?"
			
			"I'll consider it a positive, yes."
	*if not (iasionstatus = "cutoff")
		#"I think I'm enjoying getting to know Iasion, in spite of everything. I'd prefer to do so without Demeter's intervention, though."
			"I think I'm enjoying getting to know Iasion, in spite of everything. I'd prefer to do so without Demeter's intervention, though."
			
			*if (demeterstatus = "open")
				It's not like you don't want your mother around at all, of course; it's just that your relationship with him and yours are different entities, and you don't necessarily want them blending together too much, especially at this fragile, early stage of things. 
			*if not (demeterstatus = "open")
				You'd have preferred not to need to handle your mother or anything to do with her until you were ready—if you're ever ready. But this complicates things. You can hardly expect her not to see your father at all, so you're left trying to navigate the situation as well as you can.
				
			"Sounds tricky," Pyri says, adjusting the headband holding their hair back. "But, uh… you've probably guessed this already, but I think Boss is probably going to be pretty easy on Demeter while Iasion's here and let her in if she wants to see him." They frown. "Not that she can just show up whenever, obviously; she'll have to give [i]some[/i] warning. I just… figured that might be important to know."
			
			"I'll manage somehow, I suppose. I usually do."
	*if not (demeterstatus = "cutoff")
		#"I don't think I'll be spending much time with Iasion, if I can avoid it, but I suppose mother and I are getting along well enough."
			"I don't think I'll be spending much time with Iasion, if I can avoid it, but I suppose mother and I are getting along well enough."
			
			*if (iasionstatus = "cutoff")
				You'd made the decision not to pursue that relationship in any capacity, given the circumstances and your own emotional needs.
			*if not (iasionstatus = "cutoff")
				You'd made some attempt at getting to know him, but you just don't think it makes sense to go any further than you have. You know what you need to know about him, and… 'he,' the person with memories that are at all relevant to you, may not be around much longer.  
			
			*if (demeterstatus = "open")
				You and your mother have [i]always[/i] gotten along well enough, you suppose, so the news is more or less that there is no news. 
			*if not (demeterstatus = "open")
				As for Demeter, well. That was a bit of a surprise, but you can respect that she didn't seek you out against your will, even if she came here without your explicit permission. That means something, considering what your biggest problems with how she does things have always been. 
			
			"I'm not sure I get it," Pyri admits, adjusting the headband holding their hair back. "He seems like a really neat person, but I guess maybe the 'dad' part makes it more complicated. At least you're getting along with one of them?"
			
			"And the harder one to avoid by far," you reply, a touch dryly.
	*if not (iasionstatus = "cutoff")
		#"It's exciting, of course! It feels like I'm... I don't know if 'repairing' my family is the right word, but things are developing in a way I'm really pleased with."
			"It's exciting, of course! It feels like I'm... I don't know if 'repairing' my family is the right word, but things are developing in a way I'm really pleased with."
			
			*if (demeterstatus = "open")
				You do need to build a relationship with Iasion, but while you have had the occasional disagreement with your mother, you don't consider that one something that needs a fix. 

				Theirs, though, is another matter, you're sure. 
			*if not (demeterstatus = "open")
				Maybe repair is at least partly appropriate to one of the two relationships you're involved in, whereas 'build' makes more sense for the other. Oddly enough, you think your mother's being here was a step in the right direction, even if
				*if (demeter_sequel_1 = false)
					you didn't go to see her. It means you know that she cared enough to show up, and also that she respected your boundaries by not seeking you out against your will. Maybe there's a chance all of this ends well.
				*if (demeter_sequel_1)
					you hadn't explicitly given her permission to visit you. After all, it showed that she cares enough about Iasion to come and visit him, and she didn't seek you out against your will—you went to her. Maybe there's a chance all of this ends well.

			"Well… just don't push yourself too hard," Pyri advises, adjusting the headband holding their hair back. "And, uh… you've probably guessed this already, but I think Boss is probably going to be pretty easy on Demeter while Iasion's here and let her in if she wants to see him. So, good news?"
			
			"Definitely good news."
*page_break
Pyri reaches into the basket, tearing a chunk off a loaf of bread for each of you, then opening theirs up further to stuff with cheese and dried fruits. Something about the motions is practiced, almost mechanical, and their eyes look… far away, is how you'd characterize it. 

Whatever else might be said of them, they've seldom been anything but transparent with their feelings. 

*fake_choice
	#"Hey, Pyri? Are you all right?"
		*set warm +1
		*set forthright +1
		"Hey, Pyri, are you all right?" You tilt your head at them, trying to convey your concern in the question as gently as possible. They've not quite… bounced back, you suppose you'd call it, from whatever the incident with Theseus was. 
		
		They blink, pulling in a breath and sitting up straighter. "Huh? Uh… well, yeah. I mean—not exactly, but it's…" They trail off, brows knitting.
		
		This time, you wait patiently. They need a bit of time to put the words together, and that's perfectly fine. 
	#"Something wrong?"
		*set cold +1
		*set forthright +1
		"Something wrong?" You lift an eyebrow at them. You [i]are[/i] perhaps a tad concerned, but there's no need to make a fuss about it. They've not quite… bounced back, you suppose you'd call it, from whatever the incident with Theseus was. 
		
		They blink, pulling in a breath and sitting up straighter. "Huh? Uh… well, no. I mean—kind of, but it's…" They trail off, brows knitting.
		
		This time, you wait patiently. They need a bit of time to put the words together, and that's perfectly fine. 
	#I try to catch their eyes and offer a smile. They'll talk when they're ready.
		*set warm +1
		*set reserved +1
		You try to catch their eyes and offer a smile. They'll talk when they're ready, but you want them to know you're more than willing to listen when that happens. They've not quite… bounced back, you suppose you'd call it, from whatever the incident with Theseus was. 
		
		It takes them a few long seconds to notice what you're doing, but then they blink, pulling in a breath and sitting up straighter. "Huh? Oh, uh…" A soft hemming noise follows. "Sorry. I'm kind of out of it, aren't I? It's…" They trail off, brows knitting.
		
		Again, you wait patiently. They need a bit of time to put the words together, and that's perfectly fine. 
	#I'll leave them be. If they want to talk, they will.
		*set cold +1
		*set reserved +1
		You'll leave them be. If they want to talk, they will. You [i]are[/i] perhaps a tad concerned, but there's no need to make a fuss about it. They've not quite… bounced back, you suppose you'd call it, from whatever the incident with Theseus was. 
		
		It takes them a few long seconds to snap out of it, but then they blink, pulling in a breath and sitting up straighter. A soft hemming noise follows. "Sorry. I'm kind of out of it, aren't I? It's…" They trail off, brows knitting.
		
		Again, you wait patiently. They need a bit of time to put the words together, and that's perfectly fine. 
*page_break
Pyri takes a large bite of their improvised sandwich, which seems to help a bit, as by the time they've swallowed, they're pushing a breath out and trying to get the tension in their shoulders to relax. 

"It's the same thing it always is, lately. I've remembered… I guess I've started to remember my parents, so talking about yours kind of… reminded me, is all." 

*if (forthright > reserved)
	"Reminded you of what?"
*if not (forthright > reserved)
	You regard them expectantly, but offer no verbal prompt. 

Their hand moves up to the back of their neck, rubbing at it awkwardly. "It's just bits and pieces," they explain. "Stuff with no context, really. Like… I have this impression that both of them were busy a lot. And my mother was… sad a lot? I don't know if that's exactly right, but the only bits I have of her face, she looks that way. It's my aunt I remember most clearly, but… she's dead, it seems, so." They wince, dropping their hand back to their lap. 

"I don't know. I just feel like it's all going to be miserable when it's all there. There has to be a reason I wanted to forget in the first place, you know?"

*fake_choice
	#"I'm sorry this is happening to you."
		*set serious +1
		"I'm sorry this is happening to you." You can't imagine what it must be like. As they said, they surely chose to forget their past for a reason, and to be confronted now with more and more of it as the magic fails… you wouldn't wish that on anyone, least of all Pyri. 
		
		They swallow thickly, just audibly enough that you can hear their throat click, and nod. 
		
		"I wish it wasn't, but it is. So… I've got to figure out how to deal with that. At least it's really vague stuff, so far, and a few really specific small things that aren't so bad. Like my aunt is the one who taught me how to work metal, so… that was nice to know, I guess."
		
		But from their tone, clearly on balance what they're getting isn't 'nice.'
	#"Wouldn't it be better to know, though?"
		"Wouldn't it be better to know, though?" You just can't understand the mindset of wanting to forget in the first place. If your memories had been locked away, you'd be not only curious but desperate to fill in the gaps, to understand yourself by understanding your life up until this point. And you couldn't do that while most of it was still missing. 
		
		They swallow thickly, just audibly enough that you can hear their throat click. "I don't know about that," they admit, shaking their head. "I wish it wasn't coming back at all, but it is. So… I've got to figure out how to deal with that. At least it's really vague stuff, so far, and a few really specific small things that aren't so bad. Like my aunt is the one who taught me how to work metal, so… that was nice to know, I guess."
		
		But from their tone, clearly on balance what they're getting isn't 'nice.'
	#"But I thought you wanted to look into this now? Find out more about those memories?"
		"But I thought you wanted to look into this now? Find out more about those memories?" That was basically the gist of your earlier conversation, wasn't it? 
		
		They swallow thickly, just audibly enough that you can hear their throat click. "Just because I feel like I have to doesn't mean I really want to," they reply, shaking their head. "I don't have a choice, now. Things are coming back, so if I don't put them together, it's going to… to mess with my head. But… I'd prefer it if I could just go back to when I'd forgotten everything." 
		
		Pyri expels a breath. "But, I can't. So… I've got to figure out how to deal with that. At least it's really vague stuff, so far, and a few really specific small things that aren't so bad. Like my aunt is the one who taught me how to work metal, so… that was nice to know, I guess."
		
		But from their tone, clearly on balance what they're getting isn't 'nice.'
	#@{convotoggle [☆]|} "At least you haven't remembered anything really embarrassing yet, right?"
		*set humorous +1
		"At least you haven't remembered anything really embarrassing yet, right?" You do your best to inject some levity into the situation, well aware that anything else will probably just make matters [i]more[/i] miserable. 
		
		Pyri struggles to smile, only managing about half of one before it falls off their face. "I'm sure I will, eventually. But I think I'd rather that than all this." They shake their head. "But I don't have even that much choice in it. So… I've got to figure out how to deal with that. At least it's really vague stuff, so far, and a few really specific small things that aren't so bad. Like my aunt is the one who taught me how to work metal, so… that was nice to know, I guess."
		
		But from their tone, clearly on balance what they're getting isn't 'nice.'
*page_break
"Are you going to be okay? Is there anything I can do?" 

They're pertinent questions, you can't help but think. Pyri is clearly having a hard time with this, even if they're doing their best to handle it. 
*if (warm > cold)
	You can't just let them go through something like that by themselves.
*if not (warm > cold)
	You're not the most sensitive or empathetic person, maybe, and you doubt you'd be much help with emotional support, but you don't just want to leave someone you care about to suffer by themself, either. 

"I don't… I don't know," Pyri admits on a sigh, taking the last bite of their sandwich with what sounds like a frustrated groan. Once that's done, they scrub both hands up and down their face. "I just, it—all this keeps making me wonder how many people I've lost, you know? And then I can't help thinking about how many I'm [i]going[/i] to lose, and how awful that would be. Like… like what if I lost [i]you[/i]? I don't know if I could—could cope with that, you know?"

*fake_choice
	#"You won't lose me, Pyri. I plan to be here for the foreseeable future."
		"You won't lose me, Pyri. I plan to be here for the foreseeable future." You can understand why they'd worry about it. Pyri came from the mortal world, where just about everything is temporary by nature. Even in the realms of gods, not everything is permanent. Loss is a possibility, even if it feels like a distant one. 
		
		But you can be quite sure that you're not destined to suddenly die or disappear, and so you feel confident asserting that they don't have to worry about something like that with respect to you. 
		
		"But what about the [i]not[/i] foreseeable future?" they ask, brows knit and mouth twisted uncomfortably. "That's the kind of thing I'm worried about. Of course I know it won't happen if everything is normal. But what happens if something gets free from Tartarus, or Zeus decides to kidnap you back to Olympus, or… I don't know." 
		
		You want to tell them all those things are quite unlikely, but there [i]is[/i] at least a little bit of precedent for each of them. 
		
		"Then… we'll protect each other, or I'll trust you to get me back like before," you reply, offering them what you hope is a reassuring smile. "But I really do think those things won't happen again." 
	#@{convotoggle [☆]|} "One nice thing about being basically immortal is that it's pretty hard to be lost."
		"One nice thing about being basically immortal is that it's pretty hard to be lost." You can understand why they'd worry about it. Pyri came from the mortal world, where just about everything is temporary by nature. Even in the realms of gods, not everything is permanent. Loss is a possibility, even if it feels like a distant one. 
		
		But you can be quite sure that you're not destined to suddenly die or disappear, and so you feel confident asserting that they don't have to worry about something like that with respect to you. 
		
		"Pretty hard, maybe, but not impossible," they reply, brows knit and mouth twisted uncomfortably. "That's the kind of thing I'm worried about. Of course I know it won't happen if everything is normal. But what happens if something gets free from Tartarus, or Zeus decides to kidnap you back to Olympus, or… I don't know." 
		
		You want to tell them all those things are quite unlikely, but there [i]is[/i] at least a little bit of precedent for each of them. 
		
		"Then… we'll protect each other, or I'll trust you to get me back like before," you reply, offering them what you hope is a reassuring smile. "But I really do think those things won't happen again." 
	#"I... know how that feels. Sometimes, I think about it, too. What might happen. Who I might lose."
		"I... know how that feels. Sometimes, I think about it, too. What might happen. Who I might lose." You can understand why they'd worry about it. Pyri came from the mortal world, where just about everything is temporary by nature. Even in the realms of gods, not everything is permanent. Loss is a possibility, and it doesn't always [i]feel[/i] as distant as it probably is. 
		
		You're relatively sure that you won't just die or disappear all of a sudden, but you worry about other people. About them. Whatever half-deific nature they have is completely foreign to you, different from your own, and if the protections on their memory are fading, what else might be lost along with them? 
		
		It's not the most comfortable thought, but it's struck you before, as such things sometimes do. 
		
		"How do you deal with that?" they ask, brows knit and mouth twisted uncomfortably. "Of course I know it won't happen if everything is normal. But what happens if something gets free from Tartarus, or Zeus decides to kidnap you back to Olympus, or… I don't know." 
		
		You want to tell them all those things are quite unlikely, but there [i]is[/i] at least a little bit of precedent for each of them. 
		
		"I think you just… remind yourself that no one here is just going to let something like that happen," you reply. "We saved Lethe, after all. No one died from the Giant attack, and when I was taken back to Olympus, the rest of you came after me, and I'm here again. Maybe it's possible that something will happen. But it's also possible that it won't turn into a disaster." 
		
		That's the best you've been able to do, yourself. Maybe it's the best that anyone can do.
	#"You know, loss is part of living. Not everything can stay the same forever. That doesn't mean it's easy, but you'll be okay, even if things like that have happened. Even if they [i]will[/i] happen."
		"You know, loss is part of living. Not everything can stay the same forever. That doesn't mean it's easy, but you'll be okay, even if things like that have happened. Even if they [i]will[/i] happen." You can understand why they'd worry about it. Pyri came from the mortal world, where just about everything is temporary by nature. Even in the realms of gods, not everything is permanent. Loss is a possibility, and it doesn't always [i]feel[/i] as distant as it probably is. 
		
		You're relatively sure that you won't just die or disappear all of a sudden, but anything is possible. The important thing is that you try to embrace the fact that things change, and it would be more worrying if they didn't. Sometimes there's nothing good about the changes themselves, but that's part of life, too. 
		
		"I don't know if I will be," Pyri admits. "I mean, maybe, before all this, I'd have agreed with you. I didn't worry much about that stuff to begin with. But lately it feels like it's hard to think about anything else, sometimes. What happens if something gets free from Tartarus, or Zeus decides to kidnap you back to Olympus, or… I don't know." 
		
		"I think you need to just… remind yourself that no one here is just going to let something like that happen," you reply. "We saved Lethe, after all. No one died from the Giant attack, and when I was taken back to Olympus, the rest of you came after me, and I'm here again. Maybe it's possible that something will happen. But it's also possible that it won't turn into a disaster." 
		
		Accepting that some bad things will can be difficult. Perhaps the right first step for them right now is just… remembering that not every bad thing is a horrible thing.
*page_break
*if ((npc_init) and (pyri_justfriends = false))
	Pyri's quiet for a while, obviously thinking. Their brows are knit so deeply their nose scrunches as well, and they seem to forget the food. It's a somber contemplation that doesn't last more than a minute or two, though, before they turn a golden gaze on you—unusually intense, for Pyri. 
	
	"Hey, so. I… have something to say." In contrast to their appearance, their tone is almost tentative, and you think perhaps their bronzed skin takes on a little more red in the undertone. At least on their face, beneath the dense smattering of freckles there. 
	
	*if (warm > cold)
		"Well, then by all means," you reply, offering a smile in return. "Take your time, though."
	*if not (warm > cold)
		"I shan't stop you from saying it," you reply, perhaps a touch dryly.
	
	"Right, uh." They swallow, hands curling into fists on their knees before they press their palms flat to the fabric over their thighs instead. "I… care about you. A lot. And in a way that's r-romantic. So. How would you feel if… we were friends, but also… something like that?" They don't drop eye contact, though for a moment you have to wonder if they're [i]seeing[/i] your face or somehow looking beyond it, because their eyes look a little unfocused. 
	
	*fake_choice
		#@{convotoggle [♥]|} "You know... I was sort of wondering if you might ask me this. And the answer is I'd like that very much."
			*set overt +1
			"You know... I was sort of wondering if you might ask me this. And the answer is I'd like that very much." Pyri hasn't been subtle in their admiration for you, and part of you had wondered if there might not be something like this in the offing. It's… gratifying, in a way, that they'd clearly decided to put their feelings out there in spite of apparently being entirely unaware of how you'd react. 
			
			It's not an easy thing to do, after all. Not when a friendship possibly hangs in the balance. But they'd done it for you. 
			
			"You would?" Their expression becomes one of almost exaggerated surprise, lips parting and eyes rounding, but they master it as best they can. "That's… that's great, ${name}. It's… really great. I need a better word but I don't have one, right now." 
		#@{convotoggle [♥]|} "Y-you do? I mean, that's great news, but I don't think... I was expecting it at all." 
			*set subtle +1
			"Y-you do? I mean, that's great news, but I don't think... I was expecting it at all." You'd figured out that Pyri liked you, in a friendly sense. They've never once been the least bit ambiguous about that. But you'd never expected something like this was in the offing. It's… gratifying, in a way, that they'd clearly decided to put their feelings out there in spite of apparently being entirely unaware of how you'd react. 
			
			It's not an easy thing to do, after all. Not when a friendship possibly hangs in the balance. But they'd done it for you. 
			
			"It is?" Their expression becomes one of almost exaggerated surprise, lips parting and eyes rounding, but they master it as best they can. "That's… that's great, ${name}. It's… really great. I need a better word but I don't have one, right now." 
			
			Clearly you both have had some surprises in the last minute or so.
		#"I'm really flattered that you feel that way, Pyri, but I'm afraid I don't feel the same."
			"I'm really flattered that you feel that way, Pyri, but I'm afraid I don't feel the same." It's a bit awkward, now that they've just gone and put their feelings out there like that—there's no chance of subtly directing them away from the idea before they have to give it such robust voice. But then, with them, perhaps that wouldn't have worked anyway. 
			
			Pyri is nothing if not straightforward, and for this, you'll have to be the same. 
			
			They lift a hand to rub at their nose, the motion obviously awkward. "Yeah… I sort of figured that." Clearing their throat, they drop the hand. "I'm sorry if I made anything uncomfortable. Is it… we can still be friends, right?"
			
			"Of course we can," you reply, finding them a smile. "I hope you don't think I'd want to stop over a little strangeness." 
			
			They huff softly. "That's true. I'm plenty strange, so I guess if that would have put you off, it'd have happened already."
			
			Shaking their head, they return their attention to the food, pushing one of the plates towards you. "You should try this, by the way. Empusa wants more opinions." 
			
			And just like that, everything is normal again. Perhaps a little awkwardness still lingers, but Pyri has a way of making you forget that entirely, and the two of you while away the rest of a pleasant afternoon without mentioning it again. 
			*goto chap3end
		#"I... I don't know how I feel about that, honestly. Can I have a little more time to think about my answer?"
			"I... I don't know how I feel about that, honestly. Can I have a little more time to think about my answer?" You'd figured out that Pyri liked you, in a friendly sense. They've never once been the least bit ambiguous about that. But you'd never expected something like this was in the offing, and you're honestly unsure what to make of it now that you know.
			
			They lift a hand to rub at their nose, wearing a sheepish smile. "'Course," they reply. "I only figured all this out a little bit ago, so it's not like I expect you to have an answer in five seconds, you know? Just, uh, think about it, and we can check in later?" 
			
			You feel a twinge of relief, and offer a nod. "That… sounds like a good idea." 
			
			"Okay, good then." 			Shaking their head, they return their attention to the food, pushing one of the plates towards you. "You should try this, by the way. Empusa wants more opinions." 
			
			And just like that, everything is normal again. Perhaps a little awkwardness still lingers, but Pyri has a way of making you forget that entirely, and the two of you while away the rest of a pleasant afternoon without mentioning it again. 
			*goto chap3end
	*page_break
	Pyri lets out a long breath, their shoulders slumping and hands relaxing. Some of the easy warmth returns to their gaze as well, and they shake their head a little, sending gingery curls in all directions. "I, uh. Well to be honest I don't really know much about [i]how[/i] to be in this kind of relationship, or if I did, I've forgotten." Their brows crease for only a moment before smoothing again. 
	
	"But I asked Hekate, and she thinks we should talk about what we're comfortable with or not. Physically, I mean. Which seems kind of important, since there's probably something you should know about me, when it comes to that."
	
	*label pyri_whatkindofrelationship
	*fake_choice
		#"Right. That's a pretty clear next topic, I suppose."
			"Right. That's a pretty clear next topic, I suppose." The conversation [i]is[/i] important, and while maybe you could say it's a little jarring to be suddenly talking about this when five minutes ago you weren't completely sure they [i]felt[/i] that way about you, well… Pyri's never been one to waste time, as far as you can tell, and it will be good to get this sort of information out there to avoid any misunderstandings later on. 
		#"This is just theoretical for now, right? I'd like to take things slowly."
			"This is just theoretical for now, right? I'd like to take things slowly." The conversation [i]is[/i] important, but with as direct and straightforward as Pyri seems to be about mostly everything, you want to make sure to specify that not everything that might come up as good or wanted for or by you necessarily applies immediately. 
			
			It's important to ease into these things, and take them at the right pace, you think. There's still value in discussing matters up front, but only if that is also part of the discussion. 
			
			They nod immediately. "Yeah, of course. It's going to take a while for it to even sink in that this is [i]happening[/i], to be honest. So I'm not looking to go too fast, either."
	*line_break
	*line_break
	Pyri clears their throat. "So, uh, I guess the first obvious thing is probably… how do you feel about kissing, and cuddling, and touching? Er, in general. I'm not sure how specific I could get with examples, right now." They grin, but there's a bit of sheepishness to it. 
	
	*if (pyri_touch2 = "averse")
		"I guess I'm just asking because, you know, you don't really like being touched in general, and I… I don't know. I figured I'd check whether it was the same or different if we're… together, and doing those kinds of things."
	*if not (pyri_touch2 = "averse")
		"I guess I'm just asking because, you know, it's different. Some of it's really different. And so even if you're okay with me holding your hand, it's… you get what I mean." 
		
	*fake_choice
		#"I appreciate you asking, but I'm fine with both of those things."
			*set kissing "fine"
			*set intimate_touch "fine"
			"I appreciate you asking, but I'm fine with both of those things." It's a natural thing to ask about, as the relationship evolves into whatever version of it this is going to become, but your answer is the easiest one to give. 
			
			*if (pyri_touch2 = "averse")
				You know you've surprised them, saying something like that. 
				
				"But… I think I'm confused, now," they admit. "You don't like normal touching, but this kind of touching is okay?"
				
				"It is," you reply with a shrug. Casual touching for no reason isn't something you like, but intimacy like this is deliberate. Planned, if not necessarily in advance, then at least a few seconds beforehand. You know what you're getting into, and you [i]do[/i] want to be intimate in this way. You can put aside your response to touch long enough to make it work. 
			
			"Okay, well… that works, then." Pyri offers you a little smile. "Maybe this is weird to say, but I think I'm looking forward to that kind of thing? At least, I felt pretty… relieved, right now, when you said it was okay." 
			
			Clearly, this is all very new to them, which… makes sense, considering they don't remember much of anything before a fairly short time ago. 
		*if (pyri_touch2 = "averse")
			#"I just can't do touching. Not in any form. So this is going to need to be a relationship without any of the physical stuff. Okay?" 
				*set intimate_touch "averse"
				*set kissing "dislike"
				"I just can't do touching. Not in any form. So this is going to need to be a relationship without any of the physical stuff. Okay?" It's… you know most people expect things out of relationships that go beyond the intimacy of deep conversations and trust and going through life together, but those dimensions aren't anything you can provide. 
				
				Pyri's eyes widen a little bit, and they hold up their hands at about shoulder height. "Hey, that's—that's completely okay. I sort of figured it would be the answer, and I don't mind. I don't have to touch you to care about you, you know?"
				
				"Are you really just… all right with that?" Considering how physically expressive you know them to be, it's a bit hard to believe. 
				
				But they nod, face completely serious. "Yeah. I do like holding hands and hugs and things, but I don't [i]need[/i] it, and you know I do that sort of thing with my friends anyway. As for anything else… well, I've never cared about, uh… you know." A soft cough. "The more intense stuff. Never been interested in that. And kissing, and the other things in between…" They shrug. "That's just not anything I feel like I'm missing out on, honestly. So, we can definitely do this."
				
				You feel a hint of tension in your chest uncurl and relax. 
		#"I don't really want to be kissed on the mouth, but otherwise I'm fine with anything in that area."
			*set kissing "notmouth"
			*set intimate_touch "fine"
			"I don't really want to be kissed on the mouth, but otherwise I'm fine with anything in that area." It's a natural thing to ask about, as the relationship evolves into whatever version of it this is going to become, and an important one, considering that your answer is not what a lot of people would assume. 
			
			*if (pyri_touch2 = "averse")
				You know you've surprised them, saying something like that. 
				
				"But… I think I'm confused, now," they admit. "You don't like normal touching, but this kind of touching is okay, except that one thing?"
				
				"It is," you reply with a shrug. Casual touching for no reason isn't something you like, but intimacy like this is deliberate. Planned, if not necessarily in advance, then at least a few seconds beforehand. You know what you're getting into, and you [i]do[/i] want to be intimate in this way. You can put aside your response to touch long enough to make it work. 
			*if not (pyri_touch2 = "averse")
				You've probably surprised them, but they look more curious than anything. 
				
				"Okay… so no kissing your lips. It's okay if it's other places, though?"
				
				"That's the idea," you reply, dipping your chin. It's probably a somewhat novel concept, so confirming is hardly troublesome. 
				
			"Okay, well… that works, then." Pyri offers you a little smile. "Maybe this is weird to say, but I think I'm looking forward to that kind of thing? At least, I felt pretty… relieved, right now, when you said most of it was okay." 
			
			Clearly, this is all very new to them, which… makes sense, considering they don't remember much of anything before a fairly short time ago. 
		#"I really don't like the idea of kissing at all, to be honest, but some touching should be fine, I think."
			*set kissing "dislike"
			*set intimate_touch "fine"
			"I really don't like the idea of kissing at all, to be honest, but some touching should be fine, I think." It's a natural thing to ask about, as the relationship evolves into whatever version of it this is going to become, and an important one, considering that your answer is not what a lot of people would assume. 
			
			*if (pyri_touch2 = "averse")
				You know you've surprised them, saying something like that. 
				
				"But… I think I'm confused, now," they admit. "You don't like normal touching, but this kind of touching is okay, as long as it's hands?"
				
				"It is," you reply with a shrug. Casual touching for no reason isn't something you like, but intimacy like this is deliberate. Planned, if not necessarily in advance, then at least a few seconds beforehand. You know what you're getting into, and you [i]do[/i] want to be intimate in this way. You can put aside your response to touch long enough to make it work, provided they can keep to these parameters.
			*if not (pyri_touch2 = "averse")
				You've probably surprised them, but they look more curious than anything. 
				
				"Okay… so no kissing. It's okay if it's other touching, though?"
				
				"That's the idea," you reply, dipping your chin. It's probably a somewhat novel concept, so confirming is hardly troublesome. 
				
			"Okay, well… that works, then." Pyri offers you a little smile. "Maybe this is weird to say, but I think I'm looking forward to that kind of thing? At least, I felt pretty… relieved, right now, when you said some of it was okay." 
			
			Clearly, this is all very new to them, which… makes sense, considering they don't remember much of anything before a fairly short time ago. 
		#"I understand that there will probably need to be some touching involved for a relationship of this kind to work. Just make sure I know it's coming, and the same for kissing."
			*set kissing "fine"
			*set intimate_touch "middling"
			"I understand that there will probably need to be some touching involved for a relationship of this kind to work. Just make sure I know it's coming, and the same for kissing." It's a natural thing to ask about, as the relationship evolves into whatever version of it this is going to become, but your answer is a relatively simple one to give.
			
			*if (pyri_touch2 = "averse")
				Still, you know you've surprised them, saying something like that. 
				
				"But… I think I'm confused, now," they admit. "You don't like normal touching, but this kind of touching is okay, as long as I've warned you?"
				
				"It is," you reply with a shrug. Casual touching for no reason isn't something you like, but intimacy like this is deliberate. Planned, if not necessarily in advance, then at least a few seconds beforehand. You know what you're getting into, and you [i]do[/i] want to be intimate in this way. You can put aside your response to touch long enough to make it work. 
			
			"Okay, well… that works, then." Pyri offers you a little smile. "Maybe this is weird to say, but I think I'm looking forward to that kind of thing? At least, I felt pretty… relieved, right now, when you said it was okay." 
			
			Clearly, this is all very new to them, which… makes sense, considering they don't remember much of anything before a fairly short time ago. 
		#"I understand that there will probably need to be some touching involved for a relationship of this kind to work. Just make sure I know it's coming, and don't kiss me."
			*set kissing "dislike"
			*set intimate_touch "middling"
			"I understand that there will probably need to be some touching involved for a relationship of this kind to work. Just make sure I know it's coming, and don't kiss me." It's a natural thing to ask about, as the relationship evolves into whatever version of it this is going to become, and an important one, considering that your answer is not what a lot of people would assume. 
			
			*if (pyri_touch2 = "averse")
				You know you've surprised them, saying something like that. 
				
				"But… I think I'm confused, now," they admit. "You don't like normal touching, but this kind of touching is okay, as long as it's hands and I warn you first?"
				
				"It is," you reply with a shrug. Casual touching for no reason isn't something you like, but intimacy like this is deliberate. Planned, if not necessarily in advance, then at least a few seconds beforehand. You know what you're getting into, and you [i]do[/i] want to be intimate in this way. You can put aside your response to touch long enough to make it work, provided they can keep to these parameters.
			*if not (pyri_touch2 = "averse")
				You've probably surprised them, but they look more curious than anything. 
				
				"Okay… so no kissing. It's okay if it's other touching, though, as long as I warn you?"
				
				"That's the idea," you reply, dipping your chin. It's probably a somewhat novel concept, so confirming is hardly troublesome. 
				
			"Okay, well… that works, then." Pyri offers you a little smile. "Maybe this is weird to say, but I think I'm looking forward to that kind of thing? At least, I felt pretty… relieved, right now, when you said some of it was okay." 
			
			Clearly, this is all very new to them, which… makes sense, considering they don't remember much of anything before a fairly short time ago. 
	*page_break
	"This does… kind of lead to another question, though?" Pyri scrunches their brows, dropping their hands. 
	*if (npc_init)
		"Hekate says there's like… ways you can do the more intense stuff kind of together, even in a situation like ours. And I'm fine trying that, if it's something you want, so… would you be interested?"
	*if not (npc_init)
		"Hekate said one time that there were… ways people could do the more intense stuff kind of together, even without touching. And I'm fine trying that, if it's something you want, so… would you be interested?"
	
	*if (intimate_touch = "averse")
		*fake_choice
			#"No, I really don't think would be, even if it didn't involve touching."
				*set tag_ace true
				*set pyri_acerelationship true
				"No, I really don't think would be, even if it didn't involve touching." They're right to bring the questions up separately, but in your case, the answer is the same, regardless. You don't enjoy being touched, and you don't want to share what other people would call 'physical intimacy.'
				
				Pyri offers you a grin. "Well, that makes things really simple, then. I can't complain about simple." 
				
				Any remaining tension you were feeling evaporates. It's almost hard to believe it would be this easy, to get someone to understand how you felt, never mind [i]accept[/i] it with such readiness. But then, Pyri has always been like that, as far as you can tell. 
				
				"Then… I suppose that's how we'll do things." Perhaps there are further details to worry about at some other time, but for now you feel a quiet, relaxed contentment with it all. 
			#"I'd be willing, if you decide you want to try, but we'd need to figure out what exactly that involved."
				*set tag_posace true
				*set pyri_acerelationship true
				"I'd be willing, if you decide you want to try, but we'd need to figure out what exactly that involved." It's not something you personally have interest in, and it seems like that's the same for them, but if for some reason they wanted to experiment, you could do something like that, you suppose. 
				
				Pyri considers it for a moment, humming a short note then shaking their head. "No. Not really, honestly. So I guess that means we're both indifferent enough to just give it a miss, right?" 
				
				"I guess we are." Any remaining tension you were feeling evaporates. It's almost hard to believe it would be this easy, to get someone to understand how you felt, never mind [i]accept[/i] it with such readiness. But then, Pyri apparently feels just the same about this part, at least. So maybe you're both exactly who the other needs. 
				
				"So… I suppose that's how we'll do things." Perhaps there are further details to worry about at some other time, but for now you feel a quiet, relaxed contentment with it all. 
			#"I'm interested, but it's not as though I can make how I feel about being touched go away, you know? So it doesn't sound very feasible."
				"I'm interested, but it's not as though I can make how I feel about being touched go away, you know? So it doesn't sound very feasible." They're right to bring the questions up separately, because they [i]are[/i] separate. You don't want to be touched, but your desire for sexual intimacy is still present. It's always been difficult to reconcile, for you, and you're not sure exactly what Hekate might have been referring to, when she told them this information.
				
				"Well, I don't know what would be 'feasible' or not in this situation, but I don't think she'd have mentioned it if it weren't [i]possible[/i], so… I guess I'll ask her about it, sometime, and figure out exactly what she means." Pyri offers you a small smile. "If that works?"
				
				You nod. "That would be good, I think." You sense no hesitation or reluctance in their offer, despite their purported lack of interest in such things, so you can only suppose their willingness to do this with you is genuine. 
				
				Then again, pretty much everything about Pyri is genuine, so it's not a difficult guess. 
				
				"So… I suppose that's how we'll do things." Perhaps there are further details to worry about at some other time, but for now you feel a quiet, relaxed contentment with it all. 
			#"If you're not interested in this kind of thing for your own sake, definitely don't do it for mine. I don't need that kind of intimacy at all."
				*set pyri_acerelationship true
				"If you're not interested in this kind of thing for your own sake, definitely don't do it for mine. I don't need that kind of intimacy at all." They're right to bring the questions up separately, because they [i]are[/i] separate. But while you wouldn't necessarily shun such things, were they possible, you don't feel any need for them, either. And the fact that they have no interest only makes you even less interested, yourself. 
				
				Pyri offers you a grin. "Well, that makes things really simple, then. I can't complain about simple." 
				
				"Nor can I." Any remaining tension you were feeling evaporates. It's almost hard to believe it would be this easy, to get someone to understand how you felt, never mind [i]accept[/i] it with such readiness. But then, Pyri apparently has their own quirks, which you can accept as well. So maybe you're both exactly who the other needs. 
				
				"So… I suppose that's how we'll do things." Perhaps there are further details to worry about at some other time, but for now you feel a quiet, relaxed contentment with it all. 
		*page_break
	*if not (intimate_touch = "averse")
		"Anyway, uh… I think the other big question is—" They lift a hand to the nape of their neck, fingers awkwardly scrunching into their curls there. "Well… sex. And… things like that. To be honest, I—"
		
		They cut themself off for a moment, clearly searching for the words. "It's hard to figure out how to describe this. It's like… I've never really cared about it, or been interested. I don't ever look at somebody and go 'I really want to have sex with that person,' but then I'm not sure if anybody actually does [i]that[/i]. Uh. What I'm saying is, I don't really care about it, but if it's something [i]you[/i] care about, that's okay. I wouldn't mind giving it a try." 
		
		*fake_choice
			#"I'm really not interested in anything in that area, either."
				*set tag_ace true
				*set pyri_acerelationship true
				"I'm really not interested in anything in that area, either." They're right to bring the questions up separately, because they [i]are[/i] separate, but in this case as well, your answer is the same as their own. 
				
				Pyri offers you a grin. "Well, that makes things really simple, then. I can't complain about simple." 
				
				Any remaining tension you were feeling evaporates. It's almost hard to believe it would be this easy, to get someone to understand how you felt, never mind [i]accept[/i] it with such readiness. But then, maybe someone else who feels the same way is the easiest type to 'convince.' 
				
				"Then… I suppose that's how we'll do things." Perhaps there are further details to worry about at some other time, but for now you feel a quiet, relaxed contentment with it all. 
			#"I'd be willing, if you decide you [i]want[/i] to try, but I'm not really interested for my own sake, either."
				*set tag_posace true
				*set pyri_acerelationship true
				"I'd be willing, if you decide you [i]want[/i] to try, but I'm not really interested for my own sake, either." It's not something you personally have interest in, and it seems like that's the same for them, but if for some reason they wanted to experiment, you could do something like that, you suppose. 
				
				Pyri considers it for a moment, humming a short note then shaking their head. "No. Not really, honestly. So I guess that means we're both indifferent enough to just give it a miss, right?" 
				
				"I guess we are." Any remaining tension you were feeling evaporates. It's almost hard to believe it would be this easy, to get someone to understand how you felt, never mind [i]accept[/i] it with such readiness. But then, Pyri apparently feels just the same. So maybe you're both exactly who the other needs. 
				
				"So… I suppose that's how we'll do things." Perhaps there are further details to worry about at some other time, but for now you feel a quiet, relaxed contentment with it all. 
			#"I'm interested, but I don't want you to do anything that makes you uncomfortable."
				"I'm interested, but I don't want you to do anything that makes you uncomfortable." That would defeat the entire point of everything. Intimacy of that kind should be something you can both find some kind of enjoyment in. If that enjoyment isn't exactly the [i]same[/i], that's one thing, but you couldn't stand the thought of them making themself endure something they find unpleasant just for your sake. 
				
				Pyri shakes their head. "Not uncomfortable," they reply readily. "At least, I don't think so. We can talk about it more when, y'know. It's closer to the time or whatever. But I definitely won't agree to do anything I think I'm going to not like, okay?"
				
				You nod, your remaining tension evaporating. That's a plenty good answer for now; it's not like you can expect them to know precisely how unfamiliar things will make them feel in the moment, but their willingness to try and see is obviously genuine. 
				
				"Then… I suppose that's how we'll do things." Perhaps there are further details to worry about at some other time, but for now you feel a quiet, relaxed contentment with it all. 
			#"If you're not interested in this kind of thing for your own sake, definitely don't do it for mine. I don't need that kind of intimacy at all."
				*set pyri_acerelationship true
				"If you're not interested in this kind of thing for your own sake, definitely don't do it for mine. I don't need that kind of intimacy at all." They're right to bring the questions up separately, because they [i]are[/i] separate. But while you wouldn't necessarily shun such things, you don't feel any need for them, either. And the fact that they have no interest only makes you even less interested, yourself. 
				
				Pyri offers you a grin. "Well, that makes things really simple, then. I can't complain about simple." 
				
				"Nor can I." Any remaining tension you were feeling evaporates. It's nice to know there's a way of doing things that will work equally as well for the both of you. Like maybe you're both just what the other needs.
				
				"So… I suppose that's how we'll do things." Perhaps there are further details to worry about at some other time, but for now you feel a quiet, relaxed contentment with it all. 
		*page_break
	Pyri pulls in a deep breath, then lets it out, the sound tinged with relief. "Well. I'm glad we got through that part. I was kind of worried that it was going to be more awkward than that." Their lips slant into a relaxed smile, and they lean back on their hands. "Actually, I guess there's one more thing I want to ask, but… this part shouldn't be awkward. I just… is it okay if I tell people we're, y'know, together?" 
	
	They glance in your direction, evidently doing their best to keep a [i]somewhat[/i] neutral expression, but just from the tone of their voice, you can tell they're hoping for the affirmative. Which makes sense, of course. Why wouldn't they want to tell the others?
	
	*fake_choice
		#"Of course it is! I know I plan to."
			"Of course it is! I know I plan to." A fairly large percentage of those people either of you would be inclined to tell would probably guess within five seconds anyway, but that's not really the point. Even after the slight awkwardness, as they put it, what you feel most is [i]happiness[/i], at this development. 
			
			Pyri has feelings for you, and you for them. That feels like something [i]very much[/i] worth sharing with your friends. 
			
			Their smile grows, spreading across their face like a flower opening to the sun. "Good. I wasn't sure what I was going to do if you wanted to keep it to ourselves. I'm not very good with secrets." 
			
			"I can imagine you're not." With a face that expressive, and a tendency towards both honesty and talkativeness, it wouldn't stay a secret for long. 
			
			But you don't want it to.
		#"Sure, but maybe don't [i]announce[/i] it or anything."
			"Sure, but maybe don't [i]announce[/i] it or anything." A fairly large percentage of those people either of you would be inclined to tell would probably guess within five seconds anyway, but that's not really the point. You'd just prefer the distribution of this information be handled with… [i]grace[/i], might be the best word. Anything else would be a bit embarrassing. 
			
			Pyri nods, their expression sobering slightly. "I won't. I'll just, you know. If someone asks, or it comes up in conversation. That kind of thing. I wasn't sure what I was going to do if you wanted to keep it to ourselves. I'm not very good with secrets." 
			
			"I can imagine you're not." With a face that expressive, and a tendency towards both honesty and talkativeness, it wouldn't stay a secret for long. 
			
			But you don't need it to.
		#"I suppose if you must, but try to limit it to people who really ought to know."
			"I suppose if you must, but try to limit it to people who really ought to know." A fairly large percentage of those people either of you would be inclined to tell would probably guess within five seconds anyway, but that's not really the point. You just really don't feel the need to have your personal affairs made a topic of general Underworld gossip or conversation.
			
			Pyri nods, their expression sobering slightly. "I won't. I'll just, you know. If someone asks, or it comes up in conversation. That's easy enough. I wasn't sure what I was going to do if you wanted to keep it to ourselves. I'm not very good with secrets." 
			
			"I can imagine you're not." With a face that expressive, and a tendency towards both honesty and talkativeness, it wouldn't stay a secret for long. 
			
			But you don't need it to.
	*page_break
	The rest of your afternoon is one of the most pleasant you can remember.
	*goto chap3end
*if ((npc_init = false) and (pyri_justfriends = false))
	Pyri's quiet for a while, obviously thinking. Their brows are knit so deeply their nose scrunches as well, and they seem to forget the food. It's a somber contemplation that doesn't last more than a minute or two, though, before they turn a golden gaze on you—unusually intense, for Pyri. 
	
	"Hey, so. I… have something to say." In contrast to their appearance, their tone is almost tentative, and you think perhaps their bronzed skin takes on a little more red in the undertone. At least on their face, beneath the dense smattering of freckles there. 
	
	*if (warm > cold)
		"Well, then by all means," you reply, offering a smile in return. "Take your time, though."
	*if not (warm > cold)
		"I shan't stop you from saying it," you reply, perhaps a touch dryly.
	
	"Right, uh." They swallow, hands curling into fists on their knees before they press their palms flat to the fabric over their thighs instead. "I just… I care about you. A lot. All this remembering got me thinking about what I really want out of life, and I guess… I guess one of the things that stuck out to me is how much I want you in it. So… maybe don't go anywhere. At least not for too long, you know?" They offer a grin, but that intentness doesn't quite leave their gaze, either.
	
	*fake_choice
		#@{convotoggle [♥]|} "I care about you, too, Pyri. As a matter of fact... I have feelings for you."
			*set overt +1
			"I care about you, too, Pyri. As a matter of fact... I have feelings for you." It feels like the right time to say it. They didn't say it first, but in their words, you probably have the closest thing they ever [i]will[/i] say, without some indication that it's all right. And that's enough for you to want to take the step. To bridge the gap. 
			
			Pyri's eyes, always bright, round in fresh surprise, and from the way their lips part, then close, then part again, you know that whatever response they were expecting from you, this wasn't it. Still… it doesn't take them more than a moment to recover. 
			
			"You do? Uh. I mean—" they clear their throat, a hint of redness tinting the coppery skin beneath their freckles. "That's—that's good, because I feel… a lot about you. A lot more than I just said. And I think it's the same kind of thing." 
			
			"Really?" The information isn't quite the same shock to your system as it clearly had been to theirs, but you can't help the flutter of something in your stomach even so. "Then… perhaps the thing to do is be together." 
			
			"Yeah," they reply, so quickly it's right on the heels of your own words. "Yeah, that sounds like a great idea. Let's do that."
		#@{convotoggle [♥]|} "Pyri, uh... rather than just me not leaving, how would you feel about maybe being actually [i]together?[/i]"
			*set subtle +1
			"Pyri, uh... rather than just me not leaving, how would you feel about maybe being actually [i]together?[/i]" It feels like the right time to ask it. They haven't exactly proclaimed that their feelings are romantic, but yours are, and… maybe they've said something close enough. Close enough to risk putting your feelings out there, and seeing how they respond. 
			
			Pyri's eyes, always bright, round in fresh surprise, and from the way their lips part, then close, then part again, you know that whatever response they were expecting from you, this wasn't it. Still… it doesn't take them more than a moment to recover. 
			
			"Is that—uh. I mean—" they clear their throat, a hint of redness tinting the coppery skin beneath their freckles. "That's—if that's a real suggestion, that's good, because I feel… a lot about you. A lot more than I just said. And… I think I want that. To be together." 
			
			"Really?" The information isn't quite the same shock to your system as it clearly had been to theirs, but you can't help the flutter of something in your stomach even so. "Then… maybe we should." 
			
			"Yeah," they reply, so quickly it's right on the heels of your own words. "Yeah, that sounds like a great idea. Let's do that."
		#"Don't worry, Pyri. There's nothing that could convince me to leave. So many of my friends are here, including you."
			*set pyri_justfriends true
			"Don't worry, Pyri. There's nothing that could convince me to leave. So many of my friends are here, including you."
			
			They relax, just a little, shoulders easing and some of the gentler warmth returning to their eyes. "Well then, I don't have to worry about anything, do I?"
			
			Shaking their head, they return their attention to the food, pushing one of the plates towards you. "You should try this, by the way. Empusa wants more opinions." 
			
			And just like that, everything is normal again. Perhaps a little of your recent experiences still linger, in the back of your mind, but Pyri has a way of making you forget that entirely, and the two of you while away the rest of a pleasant afternoon without mentioning anything particularly trying or emotionally-laden again. 
			*goto chap3end
		#"I'm not going anywhere." The reason I feel so strongly about that is... ambiguous, but I know I feel it, at least.
			"I'm not going anywhere." The reason I feel so strongly about that is... ambiguous, but I know I feel it, at least. You're not the most sure of your feelings, right now, especially as they relate to Pyri specifically. But one thing you do know is that you want to be around them for a very long time. 
			
			You want to support them, as they've supported you. 
			
			They relax, just a little, shoulders easing and some of the gentler warmth returning to their eyes. "Well then, I don't have to worry about anything, do I?"
			
			Shaking their head, they return their attention to the food, pushing one of the plates towards you. "You should try this, by the way. Empusa wants more opinions." 
			
			And just like that, everything is normal again. Perhaps a little of your recent experiences still linger, in the back of your mind, but Pyri has a way of making you forget that entirely, and the two of you while away the rest of a pleasant afternoon without mentioning anything particularly trying or emotionally-laden again. 
			*goto chap3end
	*page_break
	Pyri lets out a long breath, their shoulders slumping and hands relaxing. Some of the easy warmth returns to their gaze as well, and they shake their head a little, sending gingery curls in all directions. "I, uh. Well to be honest I don't really know much about [i]how[/i] to be in this kind of relationship, or if I did, I've forgotten." Their brows crease for only a moment before smoothing again. 
	
	"But I… think we should talk about what we're comfortable with or not. Physically, I mean. Hekate says people in relationships should know that stuff about each other. And… there's probably something you should know about me, when it comes to that."
	*goto pyri_whatkindofrelationship
*if (pyri_justfriends)
	Pyri's quiet for a while, obviously thinking. Their brows are knit so deeply their nose scrunches as well, and they seem to forget the food. It's a somber contemplation that doesn't last more than a minute or two, though, before they turn a golden gaze on you—unusually intense, for Pyri. 
	
	"Hey, so. I… have something to say." In contrast to their appearance, their tone is almost tentative, and you think perhaps their bronzed skin takes on a little more red in the undertone. At least on their face, beneath the dense smattering of freckles there. 
	
	*if (warm > cold)
		"Well, then by all means," you reply, offering a smile in return. "Take your time, though."
	*if not (warm > cold)
		"I shan't stop you from saying it," you reply, perhaps a touch dryly.
	
	"Right, uh." They swallow, hands curling into fists on their knees before they press their palms flat to the fabric over their thighs instead. "I just… I want you to know that you've been really good to me. And with as much as all this remembering stuff feels like it's… messing with my head, having you around helps a lot. I'm grateful you'll be coming with me when I go to try and sort it out, you know?"
	
	*fake_choice
		#"Of course, Pyri. I wouldn't miss it for anything."
			"Of course, Pyri. I wouldn't miss it for anything." You know how important this is, to them. How much it's affecting them, little by little. And while you don't know if their choice to ask you to accompany them was spur of the moment or something they decided in advance, you [i]do[/i] know they're trusting you a lot with this, and you want to be there for them. 
			
			You want to support them, as they've supported you. 
			
			Pyri lets out a long breath, their shoulders slumping and hands relaxing. Some of the easy warmth returns to their gaze as well, and they shake their head a little, sending gingery curls in all directions, as if banishing a thought. "Then… okay. Thanks, ${name}. I feel like we'll be able to figure this out, if it's us." 
		#"It's going to be okay, you know? We'll get it figured out, somehow."
			"It's going to be okay, you know? We'll get it figured out, somehow." You know how important this is, to them. How much it's affecting them, little by little. And while you don't know if their choice to ask you to accompany them was spur of the moment or something they decided in advance, you [i]do[/i] know they're trusting you a lot with this, and you want to be there for them. 
			
			You want to support them, as they've supported you. 
			
			Pyri lets out a long breath, their shoulders slumping and hands relaxing. Some of the easy warmth returns to their gaze as well, and they shake their head a little, sending gingery curls in all directions, as if banishing a thought. "Then… okay. Thanks, ${name}. I feel like we'll be able to do that, if it's us." 
		#"I'm still not sure how helpful I'll be, but if you want me there, that's where I'll be."
			"I'm still not sure how helpful I'll be, but if you want me there, that's where I'll be." You know how important this is, to them. How much it's affecting them, little by little. And while you don't know if their choice to ask you to accompany them was spur of the moment or something they decided in advance, you [i]do[/i] know they're trusting you a lot with this, and you want to be there for them. 
			
			You want to support them, as they've supported you. Even if you're not entirely sure how.
			
			Pyri lets out a long breath, their shoulders slumping and hands relaxing. Some of the easy warmth returns to their gaze as well, and they shake their head a little, sending gingery curls in all directions, as if banishing a thought. "Then… okay. Thanks, ${name}. I feel like we'll be able to figure this out, if it's us." 
	*page_break
	The rest of your afternoon is pleasant, in spite of looming difficulties. Whatever happens, the two of you will manage. 
	*goto chap3end
*goto chap3end

*label chap3hades
*if (makaria2 = "dislike")
	The Keep, you've long since learned, has a number of rooms seemingly designed for the sole purpose of enjoyment, with or without other people. They come in various sizes, with various fixtures—bookshelves in some, instruments or easels in others, and the like—and some of them certainly see more use than others. 
	
	This one, you've never seen before. It seems familiar to Hades, however, who has invited you here to partake of a new flavor of cake he'd recently been working on, something light and citrusy, with an almost velvety texture to it, and a rich glaze similarly infused with the juice and zest of the fruit. 
	
	The bronze spoon he holds is a bit dwarfed by the size of his hands, but he still manages to make its use look refined, somehow. 
	
	After you've both had an opportunity to savor the first couple of bites, he hums softly, lifting his eyes to where you sit across from him and tilting his head. 
	
	"I'm given to understand that Demeter has since made her departure," he murmurs, using the side of the spoon to cut another small bite from his slice of cake. "If… I may inquire, how has all of that left you, so to speak?"
*if (makaria2 != "dislike")
	The Keep, you've long since learned, has a number of rooms seemingly designed for the sole purpose of enjoyment, with or without other people. They come in various sizes, with various fixtures—bookshelves in some, instruments or easels in others, and the like—and some of them certainly see more use than others. 
	
	This one, you've never seen before. It seems familiar to Hades and Makaria, however, who have invited you here to partake of a new flavor of cake they'd recently been working on, something light and citrusy, with an almost velvety texture to it, and a rich glaze similarly infused with the juice and zest of the fruit. 
	
	The bronze spoon Hades holds is a bit dwarfed by the size of his hands, but he still manages to make its use look refined, somehow. Makaria, for her part, has almost the opposite problem, but you can tell she's working hard to mimic her father's impeccable table manners, holding her plate on the steeple of her fingers in the same way in spite of the relative unsteadiness and cutting each bite carefully. 
	
	After you've all had an opportunity to savor the first couple of bites, Hades hums softly, lifting his eyes to where you sit across from him and tilting his head. 
	
	"I'm given to understand that Demeter has since made her departure," he murmurs, using the side of the spoon to cut another small bite from his slice of cake. "If… I may inquire, how has all of that left you, so to speak?"
	
	Makaria, clearly interested in this answer, turns her attention to you as well, watching you with wide eyes.

It's not an unexpected question, obviously. You'd handled all of that essentially on your own, and you have no doubt plenty of people are concerned with how it went. 

*fake_choice
	#"Maybe this is selfish, but I'm really ready for things to be quiet again."
		"Maybe this is selfish, but I'm really ready for things to be quiet again." You can't say you begrudge anyone anything, exactly, but all of this has been quite disturbing to your ordinary routine. That's not [i]unacceptable[/i], but it's been exhausting, and you really need some time to not have to think about things as personally significant—and fraught—as your relationships to your parents. 
		
		The fact that Demeter has left for now is certainly helping with that. 
		
		*if (makaria2 != "dislike")
			Makaria suppresses something that might have been the beginning of a surprised laugh. "Sorry," she says, smiling in a way that suggests she isn't particularly contrite. "It was just a little funny." 
			
			Hades raises an eyebrow at her. "Regardless," he adds, turning his attention to you, "I don't think it's selfish to seek peace of mind. It is a shame that such a situation is one that leaves you needing to do so, but there's nothing wrong with feeling relief on occasions like that." 
		*if (makaria2 = "dislike")
			He tilts his head. "I don't think it's selfish to seek peace of mind. It is a shame that such a situation is one that leaves you needing to do so, but there's nothing wrong with feeling relief on occasions like that." 
		
		The reassurance, mild as it is, is welcome. "Peace of mind would be nice. Perhaps I'll have a little more of it, now, for a while."
		
		At least until the next inevitable development.
	*if not (iasionstatus = "cutoff")
		#"It's confusing, and often difficult, but I'm glad for the chance to build and repair my relationships."
			"It's confusing, and often difficult, but I'm glad for the chance to build and repair my relationships." 
		
			*if (demeterstatus = "open")
				Not that you necessarily think either of them need much repairing, on your side. You need to build one with Iasion, but while you have had the occasional disagreement with your mother, you don't consider that relationship one that needs a fix. 

				Theirs, though, is another matter, you're sure. 
			*if not (demeterstatus = "open")
				And there's certainly a relationship to repair, as well as a relationship to build. Oddly enough, you think your mother's being here was a step in the right direction, even if
				*if (demeter_sequel_1 = false)
					you didn't go to see her. It means you know that she cared enough to show up, and also that she respected your boundaries by not seeking you out against your will. Maybe there's a chance all of this ends well.
				*if (demeter_sequel_1)
					you hadn't explicitly given her permission to visit you. After all, it showed that she cares enough about Iasion to come and visit him, and she didn't seek you out against your will—you went to her. Maybe there's a chance all of this ends well.

			*if (makaria2 != "dislike")
				"Well then that should be good," Makaria says, smiling and turning to her father with an expectant look.
			
			Hades clears his throat. "I should inform you that if Demeter wishes to return, I have decided to allow it," he says, tilting his head slightly. "I do not wish to keep her from someone who wishes fervently to see her, and she him. Though… I have requested that she provide slightly more advance notice next time she wishes to enter the Underworld. So… perhaps this will facilitate your efforts."
			
			"I'll consider it a positive, yes."
	*if not (iasionstatus = "cutoff")
		#"I think I'm enjoying getting to know Iasion, in spite of everything. I'd prefer to do so without Demeter's intervention, though."
			"I think I'm enjoying getting to know Iasion, in spite of everything. I'd prefer to do so without Demeter's intervention, though."
			
			*if (demeterstatus = "open")
				It's not like you don't want your mother around at all, of course; it's just that your relationship with him and yours are different entities, and you don't necessarily want them blending together too much, especially at this fragile, early stage of things. 
			*if not (demeterstatus = "open")
				You'd have preferred not to need to handle your mother or anything to do with her until you were ready—if you're ever ready. But this complicates things. You can hardly expect her not to see your father at all, so you're left trying to navigate the situation as well as you can.
				
			*if (makaria2 != "dislike")
				"Uh-oh," Makaria says, turning to her father with an expectant look.
			
			Hades clears his throat. "I should inform you that if Demeter wishes to return, I have decided to allow it," he says, tilting his head slightly. "I do not wish to keep her from someone who wishes so fervently to see her, and she him. Though… I have requested that she provide slightly more advance notice next time she wishes to enter the Underworld. And of course, such permission carries with it no right to see anyone here who does not wish to be seen. I apologize for any problems this may cause you."
			
			His expression becomes genuinely contrite. "If there are any further measures you would like me to take at such times, please inform me." 
			
			"I'll manage somehow, I suppose. I usually do." It's not as though Demeter merely being in the same [i]realm[/i] as you is going to do much of anything. You might feel a little uncomfortable or on-edge, but you believe him when he says she won't be allowed to visit you without your consent. 
	*if not (demeterstatus = "cutoff")
		#"I don't think I'll be spending much time with Iasion, if I can avoid it, but I suppose mother and I are getting along well enough."
			"I don't think I'll be spending much time with Iasion, if I can avoid it, but I suppose mother and I are getting along well enough."
			
			*if (iasionstatus = "cutoff")
				You'd made the decision not to pursue that relationship in any capacity, given the circumstances and your own emotional needs.
			*if not (iasionstatus = "cutoff")
				You'd made some attempt at getting to know him, but you just don't think it makes sense to go any further than you have. You know what you need to know about him, and… 'he,' the person with memories that are at all relevant to you, may not be around much longer.  
			
			*if (demeterstatus = "open")
				You and your mother have [i]always[/i] gotten along well enough, you suppose, so the news is more or less that there is no news. 
			*if not (demeterstatus = "open")
				As for Demeter, well. That was a bit of a surprise, but you can respect that she didn't seek you out against your will, even if she came here without your explicit permission. That means something, considering what your biggest problems with how she does things have always been. 
			
			*if (makaria2 != "dislike")
				"You don't like your father?" Makaria asks, turning to her own with a confused look.
				
				Hades shakes head slightly. "That's something for ${name} to elaborate on only if they choose to," he chides gently, before shifting his eyes back to you. 
			
			"Avoiding such a circumstance should be a simple enough matter," he says. "Iasion will remain on the far bank until such time as it is his turn for judgement, and whatever that might entail afterwards." He pauses. "I am glad, however, to hear that you are enjoying your time with at least one of your parents."
			
			"And the harder one to avoid by far," you reply, a touch dryly.
	*if not (iasionstatus = "cutoff")
		#"It's exciting, of course! It feels like I'm... I don't know if 'repairing' my family is the right word, but things are developing in a way I'm really pleased with."
			"It's exciting, of course! It feels like I'm... I don't know if 'repairing' my family is the right word, but things are developing in a way I'm really pleased with."
			
			*if (demeterstatus = "open")
				You do need to build a relationship with Iasion, but while you have had the occasional disagreement with your mother, you don't consider that one something that needs a fix. 

				Theirs, though, is another matter, you're sure. 
			*if not (demeterstatus = "open")
				Maybe repair is at least partly appropriate to one of the two relationships you're involved in, whereas 'build' makes more sense for the other. Oddly enough, you think your mother's being here was a step in the right direction, even if
				*if (demeter_sequel_1 = false)
					you didn't go to see her. It means you know that she cared enough to show up, and also that she respected your boundaries by not seeking you out against your will. Maybe there's a chance all of this ends well.
				*if (demeter_sequel_1)
					you hadn't explicitly given her permission to visit you. After all, it showed that she cares enough about Iasion to come and visit him, and she didn't seek you out against your will—you went to her. Maybe there's a chance all of this ends well.

			*if (makaria2 != "dislike")
				"Well then that should be good," Makaria says, smiling and turning to her father with an expectant look.
			
			Hades clears his throat. "I should inform you that if Demeter wishes to return, I have decided to allow it," he says, tilting his head slightly. "I do not wish to keep her from someone who wishes fervently to see her, and she him. Though… I have requested that she provide slightly more advance notice next time she wishes to enter the Underworld. So… perhaps this will facilitate your efforts."
			
			"It's definitely good news."
*page_break
*if (makaria2 = "dislike")
	"I suppose I've been thinking on such subjects as well, lately," he says quietly, setting his spoon down on his plate and then his plate on the table. "Parents, children. How they should relate to each other." He shakes his head. "How I can avoid becoming my father, and be a better one for Makaria than she would have had otherwise."
	
	*fake_choice
		#"For what it's worth, I don't think it will be difficult for you to be a better father than Kronos. You're certainly a better [i]person[/i]."
			*set warm +1
			"For what it's worth, I don't think it will be difficult for you to be a better father than Kronos. You're certainly a better [i]person[/i]." You don't know what Kronos might have done [i]as a father[/i], but considering the things he's attempted just since you've been here, you have no trouble making the assertion. Anyone who can act with such disregard for the wellbeing of everyone in the Underworld is not someone who would have made a good parent. Besides, his own children fought a [i]war[/i] against him, and even knowing the type of person Zeus is, you can't imagine him doing that for [i]no reason[/i]. Especially since his brothers and lots of other people, including your mother and aunt, all participated. 
			
			"I would like to think so," Hades admits, brows knitting. "And at those times when I am considering it with the full clarity of reason, I know it must be so, and yet… doubt is a strange creature. I find myself caught in the swirls and eddies of it so often I wonder if perhaps it has become a domain of mine." 
			
			*if (confident > unsure)
				You huff softly. "That sounds difficult. I try not to let it creep in too often, myself." And you're honestly usually pretty successful at that. 
				
				"I can tell," he replies warmly. "Sometimes it makes me a little envious of your confidence."
			*if not (confident > unsure)
				You huff softly. "I know what that feels like," you admit. "It can make the most obvious things seem… much less so, I suppose."
				
				"It can," Hades agrees with a small nod. "We cope as we're able, I suppose."
		#"Something tells me you can't have had an easy youth, considering what happened."
			*set warm +1
			"Something tells me you can't have had an easy youth, considering what happened." You don't know what Kronos might have done [i]as a father[/i], but considering the things he's attempted just since you've been here, you have no trouble making the assertion. Anyone who can act with such disregard for the wellbeing of everyone in the Underworld is not someone who would have made a good parent. Besides, his own children fought a [i]war[/i] against him, and even knowing the type of person Zeus is, you can't imagine him doing that for [i]no reason[/i]. Especially since his brothers and lots of other people, including your mother and aunt, all participated. 
			
			"It was… certainly not something I would wish on anyone else," Hades replies, shaking his head. "Would that I could muster [i]something[/i] in my father's defense, but the best I can say of him is that he is not so very extraordinary in his cruelty. He heard his child would usurp his place, and like many people, human or deity, he felt he could not stand for that." 
			
			"So… he knew the Titanomachy was going to happen before it did?" 
			
			Hades hums. "Not in so many words, but effectively, yes. He received a prophesy, and acted to prevent it coming about. Of course, making such attempts typically has the opposite effect, and did so in his case as well."
		#"I'm not sure how you could be worried about something like that, unless you're planning to be bad enough that she'll start a war against you."
			*set cold +1
			"I'm not sure how you could be worried about something like that, unless you're planning to be bad enough that she'll start a war against you." You don't know what Kronos might have done [i]as a father[/i], but considering the things he's attempted just since you've been here, you have no trouble making the assertion. Anyone who can act with such disregard for the wellbeing of everyone in the Underworld is not someone who would have made a good parent. Besides, his own children fought a [i]war[/i] against him, and even knowing the type of person Zeus is, you can't imagine him doing that for [i]no reason[/i]. Especially since his brothers and lots of other people, including your mother and aunt, all participated. 
			
			A short, almost amused breath escapes Hades, and he nods. "I concede the point, of course. At those times when I am considering it with the full clarity of reason, I know it must be so, and yet… doubt is a strange creature. I find myself caught in the swirls and eddies of it so often I wonder if perhaps it has become a domain of mine." 
			
			*if (confident > unsure)
				You huff softly. "That sounds difficult. I try not to let it creep in too often, myself." And you're honestly usually pretty successful at that. 
				
				"I can tell," he replies warmly. "Sometimes it makes me a little envious of your confidence."
			*if not (confident > unsure)
				You huff softly. "I know what that feels like," you admit. "It can make the most obvious things seem… much less so, I suppose."
				
				"It can," Hades agrees with a small nod. "We cope as we're able, I suppose."
		#"If you were in any danger of that, I'm sure someone would say so, right?"
			*set cold +1
			"If you were in any danger of that, I'm sure someone would say so, right?" You don't know what Kronos might have done [i]as a father[/i], but considering the things he's attempted just since you've been here, you have no trouble making the assertion. Anyone who can act with such disregard for the wellbeing of everyone in the Underworld is not someone who would have made a good parent. Besides, his own children fought a [i]war[/i] against him, and even knowing the type of person Zeus is, you can't imagine him doing that for [i]no reason[/i]. Especially since his brothers and lots of other people, including your mother and aunt, all participated. 
			
			You can't imagine Hades would get anywhere near that point without very many people objecting very loudly. 
			
			A short, almost amused breath escapes Hades, and he nods. "One of many reasons it is good to have so many people around myself whose opinions carry weight," he replies. "At those times when I am considering it with the full clarity of reason, I know it must be so, and yet… doubt is a strange creature. I find myself caught in the swirls and eddies of it so often I wonder if perhaps it has become a domain of mine." 
			
			*if (confident > unsure)
				You huff softly. "That sounds difficult. I try not to let it creep in too often, myself." And you're honestly usually pretty successful at that. 
				
				"I can tell," he replies warmly. "Sometimes it makes me a little envious of your confidence."
			*if not (confident > unsure)
				You huff softly. "I know what that feels like," you admit. "It can make the most obvious things seem… much less so, I suppose."
				
				"It can," Hades agrees with a small nod. "We cope as we're able, I suppose."
	*page_break
	He observes you with some curiosity now, or at least you [i]think[/i] that's the expression currently sharpening his eyes and softening his mouth. They're all so subtle it can be very difficult to tell them apart, at times. 
	
	"I cannot help but have noticed," he begins, taking a sip from the cup of water next to his plate, "that you are not particularly… I shouldn't say 'fond,' but I fear it is the closest word I can come up with. Of Makaria, that is. I was wondering if perhaps that was something you thought might just take time, or if you would prefer to keep your distance in a more permanent way." 
	
	*fake_choice
		*if not (opinion_children = "like")
			#"I think it'll be fine, eventually. I'm just never sure what to do with young children, to be honest." 
				"I think it'll be fine, eventually. I'm just never sure what to do with young children, to be honest." You suppose it can't hurt to make that clear; if you really think about it, your tendency to avoid her could be easily interpreted as something worse than
				*if (opinion_children = "dislike")
					not being too fond of kids in general. You wouldn't want him to think it was something specific about his daughter. She seems fine, as children go. 
				*if (opinion_children = "nervous")
					being nervous around kids in general. You wouldn't want him to think it was something specific about his daughter. She seems lovely, as children go. 
				*if (opinion_children = "neutral")
					a profound neutrality about children in general, which translates into a disinterest in them. You wouldn't want him to think it was something specific about his daughter. She seems fine, as children go. 
				
				"…I see." Hades considers this for a moment, and nods. "They do have particular needs and quirks, as I've learned. I can understand feeling unequipped to handle that." 
				
				A pause. "Still… I hope that as she grows, you won't mind getting to know her a little better. She is my family, after all, and anyone who spends much time with me will of necessity spend quite a bit with her, as well." 
				
				"I understand." You dip your chin, because you really do. It's clear how much Hades cares for his daughter, and honestly you don't want to avoid her forever, either. Just for as long as it takes to not be so unsure of yourself around her, anymore. 
		#"I'm uneasy around people her age, but it shouldn't be permanent, or anything. I just need time to get used to her."
			"I'm uneasy around people her age, but it shouldn't be permanent, or anything. I just need time to get used to her." You suppose it can't hurt to make that clear; if you really think about it, your tendency to avoid her could be easily interpreted as something worse than
			*if (opinion_children = "dislike")
				not being too fond of kids in general. You wouldn't want him to think it was something specific about his daughter. She seems fine, as children go. 
			*if (opinion_children = "nervous")
				being nervous around kids in general. You wouldn't want him to think it was something specific about his daughter. She seems lovely, as children go. 
			*if (opinion_children = "neutral")
				a profound neutrality about children in general, which translates into a bit of awkwardness around them. You wouldn't want him to think it was something specific about his daughter. She seems fine, as children go. 
			*if (opinion_children = "like")
				a bit of uncertainty about how to form a proper relationship with her. There's nothing wrong with her; you just need to figure out how to approach her.

			"…I see." Hades considers this for a moment, and nods. "They do have particular needs and quirks, as I've learned. I can understand feeling unsure of how to handle that." 

			A pause. "Still… I hope that as she grows, you won't mind getting to know her a little better. She is my family, after all, and anyone who spends much time with me will of necessity spend quite a bit with her, as well." 

			"I understand." You dip your chin, because you really do. It's clear how much Hades cares for his daughter, and honestly you don't want to avoid her forever, either. Just for as long as it takes to not be so unsure of yourself around her, anymore. 
		#"I don't know how it's going to work out. I suppose it depends on what kind of person she becomes."
			"I don't know how it's going to work out. I suppose it depends on what kind of person she becomes." It's difficult to be too interested in forming some sort of bond with a child; you're not her parent or teacher, and there's not really anything in common between you. But you have no expectation that things will necessarily remain that way as she grows. 
			
			"…I see." Hades considers this for a moment, and nods. "Then I hope that as she grows, you won't mind getting to know her a little better. She is my family, after all, and anyone who spends much time with me will of necessity spend quite a bit with her, as well." 

			"I understand." You dip your chin, because you really do. It's clear how much Hades cares for his daughter, and honestly you don't want to avoid her forever, either. Just for as long as it takes to feel as though you can actually relate to her, on some level or other. 
	*page_break
*if (makaria2 != "dislike")
	"Parents are strange," Makaria remarks, taking another bite of cake. "Sometimes you get bad ones, sometimes you get good ones, and it's got nothing to do with [i]you[/i]. And then sometimes you get bad ones and [i]then[/i] a good one." Her expression remains solemn through her words, but Hades is clearly watching her intently. Perhaps for any sign of distress?
	
	She's not showing any, though.
	
	*fake_choice
		#"It really does seem to come down to luck, doesn't it?"
			*set warm +1
			"It really does seem to come down to luck, doesn't it?" You offer her a small smile, and Makaria nods gravely. 
			
			"I was unlucky, and then [i]really[/i] lucky," she adds, her brow knitting. "It makes me feel bad, for people who are just unlucky." 
			
			"Fate is not always kind," Hades agrees softly. "But even people who don't have very good parents can end up happy, so what we should do is try to help them with that, where we can." 
			
			"Yeah. I think so, too. What about you, ${name}?"
			
			"I think that's a pretty good way of putting it." You're not keen to contradict Hades when he's obviously parenting, here, but it's a kind sentiment, expressed in a way someone of Makaria's apparent age will easily understand, so it's not hard to endorse on that level. 
		#"Bad ones and [i]then[/i] a good one, huh? Is that how it happened for you?"
			*set warm +1
			"Bad ones and [i]then[/i] a good one, huh? Is that how it happened for you?" You're genuinely curious, but hopefully the question is carefully-put enough that she doesn't feel a need to divulge too much. 
			
			"Mhm." She nods gravely. 			"I was unlucky, and then [i]really[/i] lucky," she adds, her brow knitting. "It makes me feel bad, for people who are just unlucky." 
			
			"Fate is not always kind," Hades agrees softly. "But even people who don't have very good parents can end up happy, so what we should do is try to help them with that, where we can." 
			
			"Yeah. I think so, too. What about you, ${name}?"
			
			"I think that's a pretty good way of putting it." You're not keen to contradict Hades when he's obviously parenting, here, but it's a kind sentiment, expressed in a way someone of Makaria's apparent age will easily understand, so it's not hard to endorse on that level. 
		#"I suppose one must play the hand one is dealt."
			*set cold +1
			"I suppose one must play the hand one is dealt." It's certainly more or less down to Fate, what parents a person has, or luck, if one prefers a slightly less-cosmic phrasing. 
			
			"Mhm." She nods gravely. 			"I was unlucky, and then [i]really[/i] lucky," she adds, her brow knitting. "It makes me feel bad, for people who are just unlucky." 
			
			"Fate is not always kind," Hades agrees softly. "But even people who don't have very good parents can end up happy, so what we should do is try to help them with that, where we can." 
			
			"Yeah. I think so, too. What about you, ${name}?"
			
			"…That's a reasonable response, yes." You're not keen to contradict Hades when he's obviously parenting, here, but it's a decent sentiment, expressed in a way someone of Makaria's apparent age will easily understand, so it's not hard to endorse on that level. 
		#"I don't know if I think that's uniquely strange. Lots of things in life are like that."
			*set cold +1
			"I don't know if I think that's uniquely strange. Lots of things in life are like that." Not only one's parents, but everything one is born with, or without, is basically the same. 
			
			"That's true," Makaria observes, brows knitting a bit. "I guess I don't know how I did with a lot of things, but with parents, I was unlucky, and then [i]really[/i] lucky. It makes me feel bad, for people who are just unlucky." 
			
			"Fate is not always kind," Hades agrees softly. "But even people who don't have very good parents can end up happy, so what we should do is try to help them with that, where we can." 
			
			"Yeah. I think so, too. What about you, ${name}?"
			
			"…That's a reasonable response, yes." You're not keen to contradict Hades when he's obviously parenting, here, but it's a decent sentiment, expressed in a way someone of Makaria's apparent age will easily understand, so it's not hard to endorse on that level. 
	*page_break
	Hades's face softens, losing a bit of the tension around his eyes, and he offers you a small smile. "It seems the two of you get along quite well," he observes. "I must admit, it…" He expels a quiet, deep breath, setting a large hand on Makaria's head. 
	
	"It's a good thing to see." 
	
	*fake_choice
		#"We do well enough, I suppose."
			"We do well enough, I suppose." It's a bit of a lukewarm response, but that's what feels most appropriate to the situation. 
			
			*if (makaria2 = "neutral")
				It's not as though you have any great affection for Makaria, after all. You just happen to mostly get along fine with her. But then, perhaps that's enough, if her initial situation with the adults in her life is what even she would describe as 'unlucky.'
			*if (makaria2 = "like")
				You do like her, but you don't think you get along any better than she does with Hermes, for instance, or Pyri, or really any of the others. Then again, perhaps that's enough, if her initial situation with the adults in her life is what even she would describe as 'unlucky.'
			
			Hades hums, glancing at his daughter for a moment, as if considering your assessment. 
			
			Makaria, for her part, offers a small smile around her last mouthful, nodding vigorously. 
			
			He huffs softly, eyes narrowing with affection, and ruffles her hair gently. "Well, I suppose 'well enough' is just that." 
		#"Of course we do! We're friends, right Makaria?"
			"Of course we do! We're friends, right Makaria?" You shift your attention to the young goddess, who is presently trying to scoop the last, large bite of her cake onto her spoon, an enterprise which is clearly proving tricky. 
			
			She looks up at you at the prompt, blinking. 
			*if (makaria2 = "like")
				"Definitely," she replies, enthusiasm giving the words just a touch more volume that would normally be called for at this proximity. The cake also falls off her spoon and back onto the plate, and she winces. "Uh, I mean, definitely, but not that loud." 
				
				Hades huffs softly. "A little excitement is forgivable," he observes. "Friends are very exciting things to have, after all." 
				
				The smile he offers you across the table is soft and sincere.
			*if (makaria2 = "neutral")
				"Um. That would be nice," she agrees tentatively. "I definitely think you're my friend, ${name}." 
				
				Her uncertainty is understandable. Children can be perceptive, and she probably picked up on your general neutrality towards her. But you mean what you've said—as time goes on and you get used to each other, you do think things are improving. 
				
				Hades hums gently, ruffling her hair with his hand. "Well, that's good to hear," he says gently. "Friends are a welcome thing to have."
		#"It's hard to imagine [i]not[/i] getting along, but I suppose it was a possibility at some point."
			"It's hard to imagine [i]not[/i] getting along, but I suppose it was a possibility at some point." 
			*if (makaria2 = "neutral")
				After all, you've been quite neutral about her presence for quite some time. But you find yourself warming to her, even so, and even when things were a little cooler, it was hard to imagine disliking her, or not being able to hold a conversation. 
				
				Makaria, presently trying to to scoop the last, large bite of her cake onto her spoon, looks up at you and blinks. 
				
				"S-so… it's okay if I think of you as my friend, ${name}?"
				
				You nod. "Of course. I think that's a perfectly fair thing to say." 
				
				Hades hums gently, ruffling her hair with his hand. "Well, that's good to hear," he says gently. "Friends are a welcome thing to have."
			*if (makaria2 = "like")
				Definitely not for very long, though. Makaria is a genuinely likable person, in addition to being a rather cute child, so it's difficult to really speculate about how such a situation might have come to be. 
				
				Makaria, presently trying to to scoop the last, large bite of her cake onto her spoon, looks up at you and blinks. 
				
				"Well, it wasn't for me," she points out, she replies, enthusiasm giving the words just a touch more volume that would normally be called for at this proximity. The cake also falls off her spoon and back onto the plate, and she winces. "Uh, I mean, what I said, but not that loud." 
				
				Hades huffs softly. "A little excitement is forgivable," he observes. "Friends are very exciting things to have, after all." 
				
				The smile he offers you across the table is soft and sincere.
		#"We're still getting to know one another, but I think we'll get along just fine."
			"We're still getting to know one another, but I think we'll get along just fine."
			
			*if (makaria2 = "neutral")
				It's not as though you have any great affection for Makaria, at this point. You just happen to mostly get along fine with her. But then, perhaps that's enough, if her initial situation with the adults in her life is what even she would describe as 'unlucky.' And it's not as though you're closed off to the possibility of things between you warming.
			*if (makaria2 = "like")
				You do like her, but you also think how well things go between you is still mostly to be determined. Then again, perhaps that's enough, if her initial situation with the adults in her life is what even she would describe as 'unlucky.' You're far from closed off to the possibility of becoming closer, after all.  
			
			Hades hums, glancing at his daughter for a moment, as if considering your assessment. 
			
			Makaria, for her part, offers a small smile around her last mouthful, nodding vigorously. 
			
			He huffs softly, eyes narrowing with affection, and ruffles her hair gently. "Well, I suppose 'just fine' is just that." 
	*page_break
	Makaria, presently finished with her cake, tilts her head to the side. "It's time for my lesson, now," she says. "Empusa's outside. May I be excused?" 
	
	"Of course," Hades replies, gently lifting the hand off her head. The two exchange a hug before she goes, and she offers you a smile and a wave before heading out the door, closing it again behind her.
	
	Hades stares at the door for a few moments before shaking his head and returning his attention to you. "I've been wondering something, actually," he admits, clearing his throat softly.
	
	*if (forthright > reserved)
		"Wondering what?" you ask. It likely has something to do with you and Makaria, given what prompted this thought, but you're not sure what's on his mind. 
	*if not (forthright > reserved)
		You tilt your head to the side. It likely has something to do with you and Makaria, given what prompted this thought, but you're not sure what's on his mind. 
	
	"It's just…" he pauses a moment, thinking. "Most everyone around us has some role or other in Makaria's life. I think she benefits from all of it greatly, but there's no mistaking the fact that some are rather closer than others. I thought, perhaps… I would ask you what sort of role you wanted to have." 
	
	*if ((marriage_choice = "kept") or (marriage_choice = "delayed"))
		His lips purse. "To be clear, I don't expect anything in particular of you just because we're married, so… please don't let that fact alone shape how you think about this." 
	*if (marriage_choice = "annulled")
		His lips purse. "To be clear, I don't have any specific expectations for what your answer will be. I just want to know how you're thinking about it."
	
	*fake_choice
		#"I think the amount of involvement I have now is for the best." 
			*set makaria3 "acquaintance"
			"I think the amount of involvement I have now is for the best." It's certainly not nothing, but it's not particularly close, nor is it something that requires a lot of responsibility, which is about what you're prepared for, in this respect. 
			
			Hades dips his chin. "I understand. She could always use more people to associate with, and I've no doubt your attention will benefit her greatly, over time." 
			
			"I don't know if it will be anything as significant as that, but I'll be around, certainly." 
			
			One side of his mouth quirks upwards. "Sometimes, 'being around' is exactly what's called for," he replies, a shrug lightly lifting his massive shoulders. "So I thank you for it." 
		#"I'd definitely like to be more involved. I want to be a safe adult for her, someone she can rely on for things that might be a bit uncomfortable to share with a parent."
			*set makaria3 "safeadult"
			"I'd definitely like to be more involved. I want to be a safe adult for her, someone she can rely on for things that might be a bit uncomfortable to share with a parent." There's definitely a difference between being that and being a parent—what you have in mind is something like what your aunt has always been for you. A refuge, when things were difficult at home, and someone fun and kind when they weren't. 
			
			Hades dips his chin. "I think that sounds like a wonderful idea," he admits softly. "I know I am not always a perfect parent, and I'd like her to have people with whom she feels comfortable expressing such frustrations. Considering how much she likes you, I think you may well already occupy a role like that, anyway." 
			
			"Does she really enjoy my company that much?" You know Makaria is at least a little bit fond of you, but you suppose you hadn't thought it was quite so obvious.
			
			Hades's lips quirk. "She talks about you rather a lot," he admits. "But I fear I must keep her disclosures in confidence. You understand." 
			
			*if (humorous > serious)
				"But of course. You'd best keep her secrets, or she'll be running to me about how embarrassing you are, eventually." 
				
				He chuckles at that, a low and rolling bass sound you can almost feel through your feet. 
			*if not (humorous > serious)
				"I do," you reply. Even 'secrets' that seem benign or unimportant can be quite significant to a child, and he's right not to just reveal Makaria's offhandedly to you. 
				
				"I appreciate it," he replies gently. 
		#"To be honest, I think I'd just like to be her friend, in whatever way is age-appropriate as she grows."
			*set makaria3 "friend"
			"To be honest, I think I'd just like to be her friend, in whatever way is age-appropriate as she grows." Intergenerational friendships can be healthy, and they're good things to have, helping you gain perspective. Of course, what really counts as 'intergenerational' among gods is difficult to pin down, but the idea is roughly the same regardless. 
			
			Hades dips his chin. "I think that sounds like a wonderful idea," he admits softly. "I sometimes worry that her circumstances leave her with very few options for friends. There aren't really many other children, here. At least, not any she can grow up with. Speaking from experience, that can be a rather lonely thing." He pauses, considering you for a moment. "Considering how much she likes you, I think you may well already occupy a role like that, anyway." 
			
			"Does she really enjoy my company that much?" You know Makaria is at least a little bit fond of you, but you suppose you hadn't thought it was quite so obvious.
			
			Hades's lips quirk. "She talks about you rather a lot," he admits. "But I fear I must keep her disclosures in confidence. You understand." 
			
			*if (humorous > serious)
				"But of course. You'd best keep her secrets, or she'll be running to me about how embarrassing you are, eventually." 
				
				He chuckles at that, a low and rolling bass sound you can almost feel through your feet. 
			*if not (humorous > serious)
				"I do," you reply. Even 'secrets' that seem benign or unimportant can be quite significant to a child, and he's right not to just reveal Makaria's offhandedly to you. 
				
				"I appreciate it," he replies gently. 
		#"If... you don't object, I might want to help you with the parenting. If you need it."
			*set makaria3 "coparent"
			"If... you don't object, I might want to help you with the parenting. If you need it."
			*if ((marriage_choice = "kept") or (marriage_choice = "delayed"))
				It's not something you feel pressured to do because you're still married to him, either. 
			*if (marriage_choice = "annulled")
				Of course, you're not married to Hades anymore, but that's hardly required for what you're suggesting. 
			You want to help him raise Makaria—you know it's a difficult task, doubly so if he's the only figure with that relationship with her. 
			
			She's certainly surrounded by capable adults, from Empusa to Hekate and the others, but they all seem to relate to her in ways that are distinctly [i]not[/i] parental, leaving that job to Hades alone. 
			
			He takes in a breath, quickly enough that you think you might really have surprised him with that. "…I'm not opposed to that," he says after a long moment. "But I think it will be something we have to work on slowly. I don't want to subject her to a sudden change in this regard." 
			*if (makaria2 = "neutral")
				He presses his lips together. "Especially, I think since she is still clearly not used to the idea of you having an interest in her, if you'll forgive me for saying so." 
				
				"No, that makes sense," you reply with a nod. "I didn't suggest this supposing I'd start tomorrow, just that it might be something we aim for over time." 
				
				His shoulders ease a little, and he returns the nod. "That's fortunate. I suppose there will be many things we must discuss, in time, but for now, this is enough."
			*if (makaria2 = "like")
				He shakes his head. 
				
				"That makes sense," you reply with a nod.  "I didn't suggest this supposing I'd start tomorrow, just that it might be something we aim for over time." 
				
				His shoulders ease a little, and he returns the nod. "That's fortunate. I suppose there will be many things we must discuss, soon enough, but for now, this is enough." 
			
			Another pause. "You know, I think in some ways it will be rather simple to make the transition, given how much she likes you." 
			
			"Does she really enjoy my company that much?" You know Makaria is at least a little bit fond of you, but you suppose you hadn't thought it was quite so obvious.
			
			Hades's lips quirk. "She talks about you rather a lot," he admits. "But I fear I must keep her disclosures in confidence. You understand." 
			
			*if (humorous > serious)
				"But of course. You'd best keep her secrets, or she'll be running to me about how embarrassing you are, eventually." 
				
				He chuckles at that, a low and rolling bass sound you can almost feel through your feet. 
			*if not (humorous > serious)
				"I do," you reply. Even 'secrets' that seem benign or unimportant can be quite significant to a child, and he's right not to just reveal Makaria's offhandedly to you. 
				
				"I appreciate it," he replies gently. 
	*page_break
Expelling a breath, Hades sits back a bit, expression faintly wry as he does it. "The business of parenting is exactly as difficult as I always thought it must be," he admits. 

You feel your eyebrows lift. "Really? I think parents usually say it's [i]more[/i] difficult than they could have imagined." 'More challenging and more rewarding,' or something like that. 

Hades shakes his head. "Perhaps so, but my mother had a very difficult time of it, and so my expectations may be colored by that. It is not just anyone who could handle trying to raise Kronos's children, knowing full well that he would not suffer any of them to live long enough to become a threat to him." 

*fake_choice
	#"'Not suffer—' That sounds... awful, to put it mildly." 
		*set serious +1
		"'Not suffer—' That sounds... awful, to put it mildly." Not that you would necessarily expect better of Kronos, considering the way he acts [i]now[/i], but it had been hard to tell if that was simply his nature or the rage of a usurped king. Apparently, it's the former. 
		
		"It was," he admits, "but not entirely. As you can imagine, she took care to keep me in contact with my father as little as possible, and so for my early years, while I was still coming into my power, my life was rather pleasant, if solitary." 
		
		His brows knit. "But I came to recognize the fear in her eyes for what it was, eventually. Only after a much longer time did I truly understand how difficult it must have been, trying to protect us from him. Losing us, one by one. I hope she lived long enough to learn that we escaped, but I confess I do not know whether that is true."
		
		"That's…" you're not even sure what to say to that. "I'm sorry, Hades." 
		
		The Lord of the Dead shakes his head. "Do not be. Fate was cruel to her, but she never wished for others to feel sorrow on her behalf. I… try to do as she asked in that respect, but often fail." 
		
		You might point out that at least half the sorrow is on [i]his[/i] behalf, but you're not sure his answer would differ at all, if he knew that.
	#@{convotoggle [☆]|} "And yet all of them did. She must have been rather formidable."
		*set humorous +1
		"And yet all of them did. She must have been rather formidable." You offer a small smile, aware that this is probably not a topic that would normally approached with levity. 
		
		But yours doesn't seem to be received poorly. "She was, but I fear it was not [i]quite[/i] as simple as that," he replies, before his tone sobers. "As you can imagine, she took care to keep me in contact with my father as little as possible, and so for my early years, while I was still coming into my power, my life was rather pleasant, if solitary." 
		
		His brows knit. "But I came to recognize the fear in her eyes for what it was, eventually. Only after a much longer time did I truly understand how difficult it must have been, trying to protect us from him. Losing us, one by one. I hope she lived long enough to learn that we escaped, but I confess I do not know whether that is true."
		
		"That's…" you're not even sure what to say to that, and your humor evaporates. "I'm sorry, Hades." 
		
		The Lord of the Dead shakes his head. "Do not be. Fate was cruel to her, but she never wished for others to feel sorrow on her behalf. I… try to do as she asked in that respect, but often fail." 
		
		You might point out that at least half the sorrow is on [i]his[/i] behalf, but you're not sure his answer would differ at all, if he knew that.
	#"That's... do you think you could explain that a little more? I have no idea what to think, right now."
		*set serious +1
		"That's... do you think you could explain that a little more? I have no idea what to think, right now." It's probably as bad as you're guessing, considering what Kronos is like [i]now[/i], but it's sort of hard to tell if that was simply his nature or the rage of a usurped king.
		
		"It's not the most pleasant tale," he admits. "As you can imagine, she took care to keep me in contact with my father as little as possible, and so for my early years, while I was still coming into my power, my life was rather pleasant, if solitary." 
		
		His brows knit. "But I came to recognize the fear in her eyes for what it was, eventually. Only after a much longer time did I truly understand how difficult it must have been, trying to protect us from him. Losing us, one by one. I hope she lived long enough to learn that we escaped, but I confess I do not know whether that is true."
		
		"That's…" you're not even sure what to say to that. "I'm sorry, Hades." 
		
		The Lord of the Dead shakes his head. "Do not be. Fate was cruel to her, but she never wished for others to feel sorrow on her behalf. I… try to do as she asked in that respect, but often fail." 
		
		You might point out that at least half the sorrow is on [i]his[/i] behalf, but you're not sure his answer would differ at all, if he knew that.
	#@{convotoggle [☆]|} "Ah yes. Wishing the death of his own children. Sounds rather par for the course for him, doesn't it?"
		*set humorous +1
		"Ah yes. Wishing the death of his own children. Sounds rather par for the course for him, doesn't it?" You offer a small smile, aware that this is probably not a topic that would normally approached with levity. 
		
		But yours doesn't seem to be received poorly. "He certainly does seem to strive to make the lives of others difficult," he replies, before his tone sobers. "As you can imagine, she took care to keep me in contact with my father as little as possible, and so for my early years, while I was still coming into my power, my life was rather pleasant, if solitary." 
		
		His brows knit. "But I came to recognize the fear in her eyes for what it was, eventually. Only after a much longer time did I truly understand how difficult it must have been, trying to protect us from him. Losing us, one by one. I hope she lived long enough to learn that we escaped, but I confess I do not know whether that is true."
		
		"That's…" you're not even sure what to say to that, and your humor evaporates. "I'm sorry, Hades." 
		
		The Lord of the Dead shakes his head. "Do not be. Fate was cruel to her, but she never wished for others to feel sorrow on her behalf. I… try to do as she asked in that respect, but often fail." 
		
		You might point out that at least half the sorrow is on [i]his[/i] behalf, but you're not sure his answer would differ at all, if he knew that.
*page_break
*if (hades_justfriends)
	Hades expels a soft breath, offering you what is unmistakably a smile this time, even if a wry one. "I like to think she would be proud of what I and the people I love have accomplished." He laces his fingers together in his lap, running the pad of one thumb back and forth along the side of the other. 
	
	"And, as well, of what we still will. I believe there's more we can do. More [i]I[/i] can do, to make the Underworld a more comfortable, easy place to live out one's afterlives." His lips purse. "If that's even the right way to describe it."
	
	Really, as far as you've been able to tell, the Underworld is more like a 'pause.' People do exist here in a way that is [i]like[/i] a version of life, but without their previous memories in most cases, and without as much… effort. That might be the right way to describe it. It's like a rest between lives, more than anything. 
	
	*fake_choice
		#"Considering how dangerous the environment actually is here, I think you've done an incredible job making it hospitable." 
			"Considering how dangerous the environment actually is here, I think you've done an incredible job making it hospitable." You're not honestly sure how he could improve on it. Well, of course, there are infrastructure projects that would make life easier, but people are always working on those. The core idea of what a spirit's time in the Underworld is like, though… it's hard to imagine him making that better.
			
			Hades presses his lips together. "It… is better than it used to be," he admits. "But there are still people who end up in Tartarus. And very many people are still… very upset when they first find themselves here. Traumatized, even. And perhaps death is just… that way, but I would like to believe there are still things I can do to ease it all." 
			
			"It sounds like it would be difficult," you admit. "Is this why you want to meet with more living people?"
			
			"Part of it," he admits on a quiet sigh. "I have no idea how to achieve my aims, but I think at least knowing more about what life is really like for humans will be the right first step." 
			
			"I suppose it might." You nod slightly, thinking about it a little more. Perhaps you could try thinking of some suggestions of your own, now that you understand more about his goals. 
			
			"At any rate." Hades lifts his shoulders a bit, letting them fall again. "I think perhaps I have kept us from our dessert for too long, now." He picks his own back up with a faint curl to his lips. 
			
			You do the same. For now, dessert sounds like a good idea.
		#"Do you have ideas in mind for how to do that?"
			"Do you have ideas in mind for how to do that?" You know, of course, that at any given time, there are several different smaller projects in progress that aim to make life easier here, but that doesn't change the core idea of what a spirit's time in the Underworld is like. It's hard to imagine him making that better, given the constraints of Fate and so on.
			
			Hades presses his lips together. "Nothing terribly concrete," he admits. "But there are still people who end up in Tartarus. And very many people are still… very upset when they first find themselves here. Traumatized, even. And perhaps death is just… that way, but I would like to believe there are still things I can do to ease it all." 
			
			"It sounds like it would be difficult," you admit. "Is this why you want to meet with more living people?"
			
			"Part of it," he admits on a quiet sigh. "I have no idea how to achieve my aims, but I think at least knowing more about what life is really like for humans will be the right first step." 
			
			"I suppose it might." You nod slightly, thinking about it a little more. Perhaps you could try thinking of some suggestions of your own, now that you understand more about his goals. 
			
			"At any rate." Hades lifts his shoulders a bit, letting them fall again. "I think perhaps I have kept us from our dessert for too long, now." He picks his own back up with a faint curl to his lips. 
			
			You do the same. For now, dessert sounds like a good idea.
		#"Well, I hope you know that I'm among the people who will help you with that." 
			"Well, I hope you know that I'm among the people who will help you with that." You proffer a smile, lifting your shoulders in a shrug. You don't really know [i]how[/i] anyone would do that, but you're willing to help if he can come up with anything. Of course, at any given time, there are several different smaller projects in progress that aim to make life easier here, but that doesn't change the core idea of what a spirit's time in the Underworld is like. It's hard to imagine him making that better, given the constraints of Fate and so on.
			
			Hades presses his lips together. "I do appreciate that," he says. "Though I fear all of my ideas thus far are quite vague. But there are still people who end up in Tartarus. And very many people are still… very upset when they first find themselves here. Traumatized, even. And perhaps death is just… that way, but I would like to believe there are still things I can do to ease it all." 
			
			"It sounds like it would be difficult," you admit. "Is this why you want to meet with more living people?"
			
			"Part of it," he admits on a quiet sigh. "I have no idea how to achieve my aims, but I think at least knowing more about what life is really like for humans will be the right first step." 
			
			"I suppose it might." You nod slightly, thinking about it a little more. Perhaps you could try thinking of some suggestions of your own, now that you understand more about his goals. 
			
			"At any rate." Hades lifts his shoulders a bit, letting them fall again. "I think perhaps I have kept us from our dessert for too long, now." He picks his own back up with a faint curl to his lips. 
			
			You do the same. For now, dessert sounds like a good idea.
		#"Aren't you also thinking of interacting more with the living? Please be careful not to take on too much."
			"Aren't you also thinking of interacting more with the living? Please be careful not to take on too much." Whatever he did would probably be a lot of work. Of course, at any given time, there are several different smaller projects in progress that aim to make life easier here, but those don't change the core idea of what a spirit's time in the Underworld is like. Any change to [i]that[/i] would probably require a very large commitment of time and effort. 
			
			Hades presses his lips together. "The two are not completely unrelated," he admits. "My ideas are not yet concrete, but there are still people who end up in Tartarus. And very many people are still… very upset when they first find themselves here. Traumatized, even. And perhaps death is just… that way, but I would like to believe there are still things I can do to ease it all." 
			
			"So that's why you want to meet with more living people? To get a better sense of how to change the Underworld?"
			
			"Part of it," he admits on a quiet sigh. "I have no idea how to achieve my aims, but I think at least knowing more about what life is really like for humans will be the right first step." 
			
			"I suppose it might." You nod slightly, thinking about it a little more. Perhaps you could try thinking of some suggestions of your own, now that you understand more about his goals. More than that, though, this doesn't make you less concerned that he might overwork himself.
			
			"At any rate." Hades lifts his shoulders a bit, letting them fall again. "I think perhaps I have kept us from our dessert for too long, now." He picks his own back up with a faint curl to his lips. 
			
			You do the same. For now, dessert sounds like a good idea.
	*goto chap3end
*if (hades_justfriends = false) 
	Hades expels a soft breath, offering you what is unmistakably a smile this time, even if a wry one. "I like to think she would be proud of what I and the people I love have accomplished." He laces his fingers together in his lap, running the pad of one thumb back and forth along the side of the other. 
	
	"And, as well, of what we still will. I believe there's more we can do. More [i]I[/i] can do, to make the Underworld a more comfortable, easy place to live out one's afterlives." His lips purse. "If that's even the right way to describe it."
	
	He seems…
	*if not (tag_unintuitive)
		it's hard to tell, as is typical of the few emotions Hades displays, but you could swear he's a little uneasy, somehow.
	*if (tag_unintuitive)
		well. You've never been any good at figuring out how people are feeling, and Hades gives far fewer clues than most people. But it [i]almost[/i] seems like he might be a little uncomfortable, somehow. 
	
	*fake_choice
		#I move to sit next to him. "Is something bothering you?"
			*set hadessituation "next"
			You move to sit next to him. "Is something bothering you?"
		#I move to sit next to him, placing a hand over both of his. "Are you all right?"
			*set hadessituation "hand"
			You move to sit next to him, placing a hand over both of his. "Are you all right?"
		#I remain where I am, tilting my head. "What's the matter?"
			You remain where you are, tilting your head. "What's the matter?"
		#I stay both still and quiet. He'll say what he needs to, in his own time.
			You stay both still and quiet. He'll say what he needs to, in his own time.
	*if (npc_init)
		"I've just been thinking about it a great deal, of late," he admits quietly,
		*if (hadessituation = "default")
			lifting his hand halfway to his shoulder before dropping it again.
		*if (hadessituation = "next")
			turning slightly so as to orient himself towards you.
		*if (hadessituation = "hand")
			turning one of his hands up to press your palms lightly together.
			*if (hades_touch2 = "averse")
				If he's surprised by such a gesture, he doesn't show it.
			
		"The Underworld. How to make it a home for everyone who dwells here. And that includes the more long-term residents as well." He pulls in a breath, meeting your eyes with what seems to be considerable effort. 
		
		"I… worry a lot about it, I suppose. Particularly when it comes to you. More than anything, I think… I want you to like it here." His brows knit faintly, and he shakes his head. "No, it more than that. I want this to be, unequivocally and without hesitation, your [i]home[/i]." 
		
		There's still a sense of faint dissatisfaction with his words, but he seems to run out of them, there, still holding your eyes. Still boring into them with the intense carmine of his own. 

		*label hadeschoice3-1
		*fake_choice
			#@{convotoggle [♥]|} "As long as you're here, it will be."
				*set overt +1
				"As long as you're here, it will be." You don't hesitate to tell him the truth. By this point, you don't think it can even be counted as 'forward' anymore, exactly. He means something to you, and you know you mean something to him, too. He wouldn't say things like that to you if you didn't. 
				
				"Is that… really all it would take?" he wonders aloud,
				*if (hadessituation = "hand")
					running the pad of his middle finger up and down your hand, from your own to the heel of your palm and back. The cool touch is a little distracting, actually. 
				*if (hadessituation = "next")
					tilting his head to better look down at your face. 
				*if (hadessituation = "default")
					blinking across the table at you.
				
				"It is," you reply, straightforwardly and without hesitation. "I'm sure it's easier now to live here than it was when you first arrived, but even if it had been then. Even if it had been awful. So don't feel like you have to do anything else just for my sake." 
				
				"You are…" Hades trails off, exhaling a breath with enough gustiness that it's almost a wry laugh. "I'm caught," he admits softly. "You say something like that, and I, contrary man that I am, feel I must be even better, to deserve you in my life, never mind my realm." 
				
				*if (hadessituation = "hand")
					He gives your hand a soft squeeze, gently lifting it and brushing his lips over your fingertips with the lightest gossamer touch before releasing it just as softly.
				*if (hadessituation = "next")
					*if (hades_touch2 = "averse")
						He offers you a melancholy smile, albeit one genuine in its cast, and shakes his head. You don't know if you've ever seen his eyes so soft.
					*if (hades_touch2 != "averse")
						He reaches closer to you, giving you plenty of time to protest, you realize, before he takes up one of your hands and gently lifts, brushing his lips over your fingertips with the lightest gossamer touch before releasing it just as softly.
				*if (hadessituation = "default")
					He offers you a melancholy smile, albeit one genuine in its cast, and shakes his head. You don't know if you've ever seen his eyes so soft.
				
				"But… I will keep what you've said in mind. Perhaps I can at least take a bit more time to try and decide what the Underworld needs. And perhaps… I can manage to be what [i]you[/i] need, if it's really so simple as you claim." 
				
				It absolutely is, and when he looks at you that way… you don't think he'll have a difficult time at all.
			#@{convotoggle [♥]|} "I appreciate that you're thinking about this so much for my sake, but I promise, I do think of it that way, already."
				*set subtle +1
				"I appreciate that you're thinking about this so much for my sake, but I promise, I do think of it that way, already." You don't hesitate to tell him the truth. Or at least, a version of it that focuses on the easier part. Explaining to him just how significant his own role is in that way of thinking would be a little more difficult, to say the least. 
				
				"Is that… really so?" he wonders aloud,
				*if (hadessituation = "hand")
					running the pad of his middle finger up and down your hand, from your own to the heel of your palm and back. The cool touch is a little distracting, actually. 
				*if (hadessituation = "next")
					tilting his head to better look down at your face. 
				*if (hadessituation = "default")
					blinking across the table at you.
				
				"It is," you reply, straightforwardly and without hesitation. "I'm sure it's easier now to live here than it was when you first arrived, but it's the kind of place that can be a home, now. The one that [i]is[/i] a home, to me and the others, too. So don't feel like you have to do anything else just for my sake." 
				
				"You are…" Hades trails off, exhaling a breath with enough gustiness that it's almost a wry laugh. "I'm caught," he admits softly. "You say something like that, and I, contrary man that I am, feel I must be even better, to deserve you in my life, never mind my realm." 
				
				*if (hadessituation = "hand")
					He gives your hand a soft squeeze, 
					*if (hades_handkiss)
						gently lifting it and brushing his lips over your fingertips with the lightest gossamer touch before releasing it just as softly.
					*if not (hades_handkiss)
						before releasing it just as softly.
				*if (hadessituation = "next")
					*if (hades_touch2 = "averse")
						He offers you a melancholy smile, albeit one genuine in its cast, and shakes his head. You don't know if you've ever seen his eyes so soft.
					*if (hades_touch2 != "averse")
						He reaches closer to you, giving you plenty of time to protest, you realize, before he takes up one of your hands and 
						*if (hades_handkiss)
							gently lifts, brushing his lips over your fingertips with the lightest gossamer touch before releasing it just as softly.
						*if not (hades_handkiss)
							gently squeezes, before releasing it just as softly.
				*if (hadessituation = "default")
					He offers you a melancholy smile, albeit one genuine in its cast, and shakes his head. You don't know if you've ever seen his eyes so soft.
				
				"But… I will keep what you've said in mind. Perhaps I can at least take a bit more time to try and decide what the Underworld needs." 
				
				You nod, glad you got at least most of your point across. The rest of it, well… you'll get there, eventually. 
			#"Well... it is. So is Olympus, of course, but having two homes doesn't make either of them less important to me."
				"Well... it is. So is Olympus, of course, but having two homes doesn't make either of them less important to me." You shake your head. That kind of thought would be ridiculous, so you hope it wasn't on his mind.
				
				"Ah. I apologize for my lack of clarity. I meant no comparison or competition with Olympus by the thought. It is more than possible for a person to have multiple homes, of course. I was concerned only with the adequacy of the Underworld as a potential one of those, for you." 
				
				Well, that's a relief. You'd have been uncomfortable if it turned out someone was trying to make you choose, again, not that you really expected he would. 
				
				"But, I'm glad to hear it apparently already counts." 
				
				"It does," you confirm with a nod. "I'm sure it's easier now to live here than it was when you first arrived, but it's the kind of place that can be a home, now. The one that [i]is[/i] a home, to me and the others, too. So don't feel like you have to do anything else just for my sake." 
				
				"You are…" Hades trails off, exhaling a breath with enough gustiness that it's almost a wry laugh. "I'm caught," he admits softly. "You say something like that, and I, contrary man that I am, feel I must be even better, to deserve you in my life, never mind my realm." 
				
				*if (hadessituation = "hand")
					He gives your hand a soft squeeze, 
					*if (hades_handkiss)
						gently lifting it and brushing his lips over your fingertips with the lightest gossamer touch before releasing it just as softly.
					*if not (hades_handkiss)
						before releasing it just as softly.
				*if (hadessituation = "next")
					*if (hades_touch2 = "averse")
						He offers you a melancholy smile, albeit one genuine in its cast, and shakes his head. You don't know if you've ever seen his eyes so soft.
					*if (hades_touch2 != "averse")
						He reaches closer to you, giving you plenty of time to protest, you realize, before he takes up one of your hands and 
						*if (hades_handkiss)
							gently lifts, brushing his lips over your fingertips with the lightest gossamer touch before releasing it just as softly.
						*if not (hades_handkiss)
							gently squeezes, before releasing it just as softly.
				*if (hadessituation = "default")
					He offers you a melancholy smile, albeit one genuine in its cast, and shakes his head. You don't know if you've ever seen his eyes so soft.
				
				"You needn't," you reply, shaking your head. "Things like this aren't about 'deserving.'" 
				
				"You're right, of course," he murmurs. "And intellectually, I know that. But it is difficult, at times, to make myself [i]believe[/i] it. Still. I will try." 
				
				You dip your chin again. "Please do." It's hard, of course, to change the way a person thinks about things like this, but in his case… you hope he can. 
			*if (chose != "olympusmostly")
				#"I'm not sure it can be. I don't know what 'home' feels like."
					"I'm not sure it can be. I don't know what 'home' feels like." It's such a foreign concept that you don't really know what to look for even, what way such a thing would make you act or think or feel or anything. It could already be home, but you're not at all sure. Shouldn't it be a profound feeling, one immediately recognizable? 
					
					The way people talk about it makes you think so. 
					
					Hades hums softly,
					*if (hadessituation = "hand")
						running the pad of his middle finger up and down your hand, from your own to the heel of your palm and back. The cool touch is a little distracting, actually. 
					*if (hadessituation = "next")
						tilting his head to better look down at your face. 
					*if (hadessituation = "default")
						blinking across the table at you.

					"…A difficult conundrum," he admits. "I have never been especially adept at recognizing or describing emotions, either. For what it is worth, I think the feeling of belonging in this place came over me slowly. And what it feels like for me is simply a form of ease I do not feel elsewhere. To be honest, I suspect 'home' is more a function of people than physical location." 

					That doesn't particularly gift you with any revelations about your own feelings, but you suppose it's good to know it might come on gradually rather than all at once or immediately. 

					"So… I suppose, for now, just think about whether there is anything that will make you more comfortable, here, and let me know if so." You detect a hint of melancholy in his smile, but his tone of voice remains as even and steady as ever. 

					"I will." 

					That much shouldn't be too difficult.
			*if (chose = "olympusmostly")
				#"I'm not sure it can be. I didn't want to spend quite so much time here, after all."
					"I'm not sure it can be. I didn't want to spend quite so much time here, after all." This is very much a consequence of your own actions, but you wouldn't call the result 'voluntary' by any means. In the end, you'd chosen Olympus over the Underworld, because [i]that[/i] felt more like your home.
					
					Hades hums softly,
					*if (hadessituation = "hand")
						running the pad of his middle finger up and down your hand, from your own to the heel of your palm and back. The cool touch is a little distracting, actually. 
					*if (hadessituation = "next")
						tilting his head to better look down at your face. 
					*if (hadessituation = "default")
						blinking across the table at you.

					"…A difficult conundrum," he admits. "I cannot return you to Olympus—it is not my realm to decide for. But… at the very least I would like to hope that someday, the Underworld could [i]also[/i] be a home for you. One that appeals for what it is, rather than its resemblance to your other." 
					
					You both know, of course, that the Underworld will never be [i]like[/i] Olympus, so perhaps that is the correct approach. 
					
					"I just… don't know," you admit. "I hope you can do that, but I'm not sure what it would take." 
					
					*if (hadessituation = "hand")
						He gives your hand a soft squeeze, 
						*if (hades_handkiss)
							gently lifting it and brushing his lips over your fingertips with the lightest gossamer touch before releasing it just as softly.
						*if not (hades_handkiss)
							before releasing it just as softly.
					*if (hadessituation = "next")
						*if (hades_touch2 = "averse")
							He offers you a melancholy smile, albeit one genuine in its cast, and shakes his head. You don't know if you've ever seen his eyes so soft.
						*if (hades_touch2 != "averse")
							He reaches closer to you, giving you plenty of time to protest, you realize, before he takes up one of your hands and 
							*if (hades_handkiss)
								gently lifts, brushing his lips over your fingertips with the lightest gossamer touch before releasing it just as softly.
							*if not (hades_handkiss)
								gently squeezes, before releasing it just as softly.
					*if (hadessituation = "default")
						He offers you a melancholy smile, albeit one genuine in its cast, and shakes his head. You don't know if you've ever seen his eyes so soft.
					
					"Nevertheless," he murmurs, "we will try. So, please let me know if anything occurs to you that would improve your comfort here." 
					
					"I will," you reply, just as quietly. 
					
					You understand that he's trying. And, perhaps, the best choice you have is to try, as well. To try to come to love this place as your own.
		*goto chap3end
	*if not (npc_init)
		"I've just been thinking about it a great deal, of late," he admits quietly,
		*if (hadessituation = "default")
			lifting his hand halfway to his shoulder before dropping it again.
		*if (hadessituation = "next")
			turning slightly so as to orient himself towards you.
		*if (hadessituation = "hand")
			turning one of his hands up to press your palms lightly together.
			*if (hades_touch2 = "averse")
				If he's surprised by such a gesture, he doesn't show it.
			
		"The Underworld. How to make it a home for everyone who dwells here. And that includes the more long-term residents as well." He pulls in a breath, meeting your eyes with what seems to be considerable effort. 
		
		"I… worry a lot about it, I suppose. Particularly when it comes to you. I would like this place to be one you think of as your home." 
		
		There's still a sense of faint dissatisfaction with his words, but he seems to run out of them, there, still holding your eyes. Still boring into them with the intense carmine of his own. 
		*goto hadeschoice3-1
*goto chap3end

*label chap3end
*finish Chapter Four: Past and Present