
actor PigCop : ZBaseActor 19137
{
  obituary "%o was gunned down by a Pigcop."
  health 100
  radius 16
  height 51
  mass 1000
  speed 7
  seesound "pig/sight"
  painsound "pig/pain"
  deathsound "pig/death"
  activesound "pig/active"
  dropitem "PigCopShotgun" 
  dropitem "DukeArmor" 16
  painchance 85
  Painchance "Shrinker", 256
  painchance "FireBurning", 200
  painchance "MightyBoot", 128
  painchance "BootStun", 256
  painchance "MicrowaveBlast", 256
  MONSTER
  +FLOORCLIP
  scale 0.7
  damagefactor "AlienzShrinker", 0.0
  damagefactor "Shrinkerhit", 0.0
  Species "Pigcops"
  +DOHARMSPECIES
  +NOINFIGHTSPECIES
  +DONTHARMCLASS
  WoundHealth 10
  MeleeRange 50
  states
  {
  Spawn:
    ENE2 A 0
    "####" "#" 0 Thing_ChangeTID(0,1000)
    ENE2 AA 10 A_Look
    loop
  See:
    "####" "#" 0 A_SetHeightOffset(0)
    ENE2 AABBCCDD 3 A_ChaseD3D
    loop
  Melee:
    ENE2 RRR 3 A_FaceTarget
    "####" "#" 0 A_CustomMeleeAttack(15, "duke/kick", "duke/kick", "LowPush")
    "####" "#" 0 Radius_Quake (2, 6, 0, 5, 0)
    ENE2 S 5
    ENE2 S 3
    "####" "#" 0 A_Jump(224,"Missile")
    Goto See
  Missile:
    "####" "#" 0 A_Jump(96,"Missile2")
    ENE2 FF 12 A_FaceTarget
    "####" "#" 0 A_CustomMissile("MuzzleFlashMedium",32,0,0)
    "####" "#" 0 A_PlaySound("shotgun/shoot", 1)
    "####" "######" 0 A_CustomMissile("EnemyProjectile", 32, 12, random[RIDMONSTERAT](-9, 9), CMF_OFFSETPITCH, random[RIDMONSTERAT](-1, 1))
    ENE2 G 10 bright
    ENE2 E 5
    ENE2 E 10 A_PlaySound("shotgun/pump")
    "####" "#" 0 A_SpawnItem ("ShotCaseSpawn", 0, 30, 0)
    "####" "#" 0 A_CPosRefire
    ENE2 E 7 A_Jump(64,"Missile")
    goto See
  Missile2:
    ENE2 H 7 A_FaceTarget
    "####" "#" 0 A_SetHeightOffset(-24)
    ENE2 II 7 A_FaceTarget
    "####" "#" 0 A_CustomMissile("MuzzleFlashMedium",32,0,0)
    "####" "#" 0 A_PlaySound("shotgun/shoot", 1)
    "####" "######" 0 A_CustomMissile("EnemyProjectile", 20, 15, random[RIDMONSTERAT](-9, 9), CMF_OFFSETPITCH, random[RIDMONSTERAT](-1, 1))
    ENE2 J 10 bright
    ENE2 I 15
    ENE2 I 5 A_PlaySound("shotgun/pump")
    "####" "#" 0 A_SpawnItem ("ShotCaseSpawn", 0, 18, 0)
    ENE2 I 5 A_FaceTarget
    "####" "#" 0 A_CustomMissile("MuzzleFlashMedium",32,0,0)
    "####" "#" 0 A_PlaySound("shotgun/shoot", 1)
    "####" "######" 0 A_CustomMissile("EnemyProjectile", 20, 15, random[RIDMONSTERAT](-9, 9), CMF_OFFSETPITCH, random[RIDMONSTERAT](-1, 1))
    ENE2 J 10 bright
    ENE2 I 11
    ENE2 I 10 A_PlaySound("shotgun/pump")
    "####" "#" 0 A_SpawnItem ("ShotCaseSpawn", 0, 18, 0)
    "####" "#" 0 A_SetHeightOffset(0)
    ENE2 H 7
    goto See
  Pain.BootStun:
    "####" "#" 0 A_SetHeightOffset(0)
    "####" "#" 0 A_Jump(128,"Pain2BootStun")
    ENE2 K 9 A_PlayVoiceSoundPitch("Pain")
    ENE2 K 9
    goto See
  Pain2BootStun:
    ENE2 Q 9 A_PlayVoiceSoundPitch("Pain")
    ENE2 Q 9
    goto See
  Pain:
    "####" "#" 0 A_SetHeightOffset(0)
    "####" "#" 0 A_Jump(128,"Pain2")
    ENE2 K 3
    ENE2 K 3 A_PlayVoiceSoundPitch("Pain")
    goto See
  Pain2:
    ENE2 Q 3
    ENE2 Q 3 A_PlayVoiceSoundPitch("Pain")
    goto See
  Pain.MicrowaveBlast:
    "####" "#" 0 A_SetHeightOffset(0)
    ENE2 K 1
    "####" "#" 0 A_CheckThump("Pain.BootStun")
    loop
  Death:
    ENE2 K 7 A_PlayVoiceSoundPitch("Death")
    ENE2 L 7
    ENE2 M 7 A_NoBlocking
    ENE2 NO 7
    ENE2 P 1 A_SpawnItemEx("DeadPigCop", 0,0,0,0,0,0,0, SXF_TRANSFERTRANSLATION|SXF_TRANSFERSTENCILCOL|SXF_SETMASTER)
    "####" "#" 0 A_SpawnItemEx("DukeRedBloodPool")
    TNT1 A -1
    stop
  Pain.Shrinker:
    "####" "#" 0 A_PlaySound("shrinker/shrink")
    "####" "#" 0 A_InvulnerablePlus(1)
    ENE2 K 5 A_PlayVoiceSoundPitch("Pain")
    "####" "#" 0 A_CustomMissile("ShrinkEffect",8,0,0)
  Shrink:
    ENE2 K 2 {A_SetScale(ScaleX - 0.04, ScaleY - 0.04); A_SpawnItemEx("ShrunkBlur",0,0,0,0,0,0,angle,SXF_TRANSFERSPRITEFRAME|SXF_TRANSFERSCALE|SXF_TRANSFERTRANSLATION|SXF_NOCHECKPOSITION|SXF_ABSOLUTEANGLE);}
    "####" "#" 0 A_JumpIf(ScaleX > 0.2 && ScaleY > 0.2, "Shrink")
    "####" "#" 0 A_Shrink("A","B","C","D",0.2,1000,2,"See","PigCop")
    "####" "#" 0 A_Remove(AAPTR_DEFAULT)
    stop
  XDeath:
  Death.BossStomp:
    "####" "#" 0 A_XScream
    "####" "#" 0 A_NoBlocking
    "####" "#" 0 A_SpawnDebris("DukeGibs1NF", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs2NF", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs3NF", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs4NF", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs5NF", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs1NF", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs2NF", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs3NF", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs4NF", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs5NF", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("PigcopHead1",TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("PigcopArm1",TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("PigcopLeg1",TRUE, 1.0, 1.0)
    "####" "#" 0 A_Jump(256,"Gib1","Gib2","Gib3","Gib4","Gib5")
    TNT1 A 1
    Stop
  Death.PlasmaGib:
    "####" "#" 0 A_SpawnItemEx("DukePlasmaExplosion",0,0,32,0,0,0,0,1,0)
    "####" "#" 0 A_XScream
    "####" "#" 0 A_NoBlocking
    "####" "#" 0 A_SpawnDebris("DukeGibs1NFP", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs2NFP", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs3NFP", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs4NFP", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs5NFP", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs1NFP", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs2NFP", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs3NFP", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs4NFP", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs5NFP", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("PigcopHead1",TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("PigcopArm1",TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("PigcopLeg1",TRUE, 1.0, 1.0)
    "####" "#" 0 A_Jump(256,"Gib1","Gib2","Gib3","Gib4","Gib5")
    TNT1 A 1
    Stop
  Death.Explosion:
  Death.RocketExplosion:
    "####" "#" 0 A_XScream
    "####" "#" 0 A_NoBlocking
    "####" "#" 0 A_SpawnDebris("DukeGibs1", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs2", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs3", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs4", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs5", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs1", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs2", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs3", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs4", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs5", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("PigcopHead1",TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("PigcopArm1",TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("PigcopLeg1",TRUE, 1.0, 1.0)
    "####" "#" 0 A_Jump(256,"Gib1","Gib2","Gib3","Gib4","Gib5")
    TNT1 A 1
    Stop
  Death.ExplosiveShotgun:
  Death.ShellExplosion:
    "####" "#" 0 A_XScream
    "####" "#" 0 A_NoBlocking
    "####" "#" 0 A_Jump(FAS_AltShotgunGibFireProb,3)
    "####" "#" 0 A_SpawnDebris("DukeGibs1NF", TRUE, 1.0, 1.0)
    "####" "#" 0 A_Jump(256,2)
    "####" "#" 0 A_SpawnDebris("DukeGibs1", TRUE, 1.0, 1.0)
    "####" "#" 0 A_Jump(FAS_AltShotgunGibFireProb,3)
    "####" "#" 0 A_SpawnDebris("DukeGibs2NF", TRUE, 1.0, 1.0)
    "####" "#" 0 A_Jump(256,2)
    "####" "#" 0 A_SpawnDebris("DukeGibs2", TRUE, 1.0, 1.0)
    "####" "#" 0 A_Jump(FAS_AltShotgunGibFireProb,3)
    "####" "#" 0 A_SpawnDebris("DukeGibs3NF", TRUE, 1.0, 1.0)
    "####" "#" 0 A_Jump(256,2)
    "####" "#" 0 A_SpawnDebris("DukeGibs3", TRUE, 1.0, 1.0)
    "####" "#" 0 A_Jump(FAS_AltShotgunGibFireProb,3)
    "####" "#" 0 A_SpawnDebris("DukeGibs4NF", TRUE, 1.0, 1.0)
    "####" "#" 0 A_Jump(256,2)
    "####" "#" 0 A_SpawnDebris("DukeGibs4", TRUE, 1.0, 1.0)
    "####" "#" 0 A_Jump(FAS_AltShotgunGibFireProb,3)
    "####" "#" 0 A_SpawnDebris("DukeGibs5NF", TRUE, 1.0, 1.0)
    "####" "#" 0 A_Jump(256,2)
    "####" "#" 0 A_SpawnDebris("DukeGibs5", TRUE, 1.0, 1.0)
    "####" "#" 0 A_Jump(FAS_AltShotgunGibFireProb,3)
    "####" "#" 0 A_SpawnDebris("DukeGibs1NF", TRUE, 1.0, 1.0)
    "####" "#" 0 A_Jump(256,2)
    "####" "#" 0 A_SpawnDebris("DukeGibs1", TRUE, 1.0, 1.0)
    "####" "#" 0 A_Jump(FAS_AltShotgunGibFireProb,3)
    "####" "#" 0 A_SpawnDebris("DukeGibs2NF", TRUE, 1.0, 1.0)
    "####" "#" 0 A_Jump(256,2)
    "####" "#" 0 A_SpawnDebris("DukeGibs2", TRUE, 1.0, 1.0)
    "####" "#" 0 A_Jump(FAS_AltShotgunGibFireProb,3)
    "####" "#" 0 A_SpawnDebris("DukeGibs3NF", TRUE, 1.0, 1.0)
    "####" "#" 0 A_Jump(256,2)
    "####" "#" 0 A_SpawnDebris("DukeGibs3", TRUE, 1.0, 1.0)
    "####" "#" 0 A_Jump(FAS_AltShotgunGibFireProb,3)
    "####" "#" 0 A_SpawnDebris("DukeGibs4NF", TRUE, 1.0, 1.0)
    "####" "#" 0 A_Jump(256,2)
    "####" "#" 0 A_SpawnDebris("DukeGibs4", TRUE, 1.0, 1.0)
    "####" "#" 0 A_Jump(FAS_AltShotgunGibFireProb,3)
    "####" "#" 0 A_SpawnDebris("DukeGibs5NF", TRUE, 1.0, 1.0)
    "####" "#" 0 A_Jump(256,2)
    "####" "#" 0 A_SpawnDebris("DukeGibs5", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("PigcopHead1",TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("PigcopArm1",TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("PigcopLeg1",TRUE, 1.0, 1.0)
    "####" "#" 0 A_Jump(256,"Gib1","Gib2","Gib3","Gib4","Gib5")
    TNT1 A 1
    Stop
  Gib1:
    "####" "#" 0 A_SpawnDebris("DukeGibs6", FALSE, 1.0, 1.0)
    GIB1 EEEEEEEEEEEEEEEEEEEEEEEEEEEEEE 35 A_Gravity
    GIB1 EEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEE 1 A_FadeOut(0.1)
    Stop
  Gib2:
    "####" "#" 0 A_SpawnDebris("DukeGibs6", FALSE, 1.0, 1.0)
    GIB2 EEEEEEEEEEEEEEEEEEEEEEEEEEEEEE 35 A_Gravity
    GIB2 EEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEE 1 A_FadeOut(0.1)
    Stop
  Gib3:
    "####" "#" 0 A_SpawnDebris("DukeGibs6", FALSE, 1.0, 1.0)
    GIB3 EEEEEEEEEEEEEEEEEEEEEEEEEEEEEE 35 A_Gravity
    GIB3 EEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEE 1 A_FadeOut(0.1)
    Stop
  Gib4:
    "####" "#" 0 A_SpawnDebris("DukeGibs6", FALSE, 1.0, 1.0)
    GIB4 EEEEEEEEEEEEEEEEEEEEEEEEEEEEEE 35 A_Gravity
    GIB4 EEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEE 1 A_FadeOut(0.1)
    Stop
  Gib5:
    "####" "#" 0 A_SpawnDebris("DukeGibs6", FALSE, 1.0, 1.0)
    GIB5 EEEEEEEEEEEEEEEEEEEEEEEEEEEEEE 35 A_Gravity
    GIB5 EEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEE 1 A_FadeOut(0.1)
    stop
  Wound.Expander:
   "####" "#" 0 A_Die("Expander")
  Death.Expander:
    "####" "#" 0 A_ChangeFlag("DONTCORPSE",1)
    "####" "#" 0 A_PlaySound("expander/expand")
    "####" "#" 0 {A_UnsetShootable; A_UnsetSolid;}
  Expand:
    ENE2 K 1 A_SetScale(ScaleX + 0.01, ScaleY + 0.01)
    "####" "#" 0 A_JumpIf(ScaleX < 1.15 && ScaleY < 1.15, "Expand")
    ENE2 KKKKK 1
    "####" "#" 0 A_SetScale(0.7, 0.7)
    "####" "#" 0 A_PlayVoiceSoundPitch("Death","",4)
    "####" "#" 0 A_SpawnItemEx("ExpanderExplosion",0,0,32,0,0,0,0,1,0)
    "####" "#" 0 A_SpawnDebris("DukeGibs1", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs2", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs3", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs4", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs5", TRUE, 1.0, 1.0)
    goto Death.Explosion
  Wound.Ice:
    "####" "#" 0 A_Freeze("See")
    "####" "#" 0 A_Remove(AAPTR_DEFAULT)
    TNT1 A 1
    stop
  Death.MonsterSlimer:
    ENE2 K 10 {A_PlayVoiceSoundPitch("Death"); A_SpawnItemEx("SlimerEatingMonster");}
    ENE2 KK 10
    stop
  Death.Headshot:
    "####" "#" 0 A_XScream
    "####" "#" 0 A_SpawnDebris("DukeGibs2NF", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs2NF", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs5NF", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs6", FALSE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs6", FALSE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs6", FALSE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("PigcopHead1",TRUE, 1.0, 1.0)
    3NE2 K 21 A_NoBlocking
    3NE2 L 14
    3NE2 M 7
    3NE2 NO 7
    3NE2 P 1 A_SpawnItemEx("DeadPigCopBehead", 0,0,0,0,0,0,0, SXF_TRANSFERTRANSLATION|SXF_TRANSFERSTENCILCOL)
    "####" "#" 0 A_SpawnItemEx("DukeRedBloodPool")
    stop
  Possessed:
    "####" "#" 0 A_ChangeFlag("NOPAIN", 1)
    ENE2 P 7 {A_XScream; A_AdjustTics(1.0,1.0);}
    ENE2 O 7 {A_XScream; A_AdjustTics(1.0,1.0);}
    ENE2 NM 7 A_AdjustTics(1.0,1.0)
    ENE2 L 7 A_AdjustTics(1.0,1.0)
    ENE2 K 7 A_AdjustTics(0,1.0)
    "####" "#" 0 A_ChangeFlag("NOPAIN", 0)
    goto See
  Death.Unmorph:
    "####" "#" 0 A_PlayVoiceSoundPitch("","pighuman/transform",6)
    "####" "#" 0 A_PlaySound("pig/pain",7,1,1)
    "####" "#" 0 A_ChangeFlag("DONTCORPSE",1)
    "####" "#" 0 A_NoBlocking(false)
    "####" "#" 0 {A_UnsetShootable; A_SetSolid;}
    "####" "#" 0 A_SetHeightOffset(0)
    "####" "#" 0 A_PlaySound("shrinker/shrink")
    "####" "#" 0 A_SpawnItemEx("ShrinkerMorphFX",0,0,height*0.5)
    PHUM WWWWWWW 1 A_ShrinkBeamMorph
    PHUM VVVVVVV 1 A_ShrinkBeamMorph
    PHUM UUUUUUU 1 A_ShrinkBeamMorph
    PHUM TTTTTTT 1 A_ShrinkBeamMorph
    PHUM SSSSSSS 1 A_ShrinkBeamMorph
    PHUM RRRRRRR 1 
    PHUM QQQQQQQ 1 
    PHUM PPPPPPPPPPPPPP 1 
    PHUM OOOOOOO 1 
    "####" "#" 0 A_StopSound(7)
    "####" "#" 0 A_UnsetSolid
    PHUM O 1 A_SwitchActorTransferHealth("PigHuman","See",false)
    stop
  Morph:
    "####" "#" 0 A_ChangeFlag("NOPAIN", 1)
    "####" "#" 0 A_PlaySound("shrinker/shrink")
    "####" "#" 0 A_SpawnItemEx("ShrinkerMorphFX",0,0,height*0.5)
    PHUM OOOOOOO 1 A_ShrinkBeamMorph(false)
    PHUM PPPPPPPPPPPPPP 1 A_ShrinkBeamMorph(false)
    PHUM QQQQQQQ 1 A_ShrinkBeamMorph(false)
    PHUM RRRRRRR 1 A_ShrinkBeamMorph(false)
    PHUM SSSSSSSSSS 1
    PHUM TTTTTTTTTT 1
    PHUM UUUUUUUUUU 1
    PHUM VVVVVVVVVV 1
    PHUM WWWWWWWWWW 1
    "####" "#" 0 A_ChangeFlag("NOPAIN", 0)
    goto See
  }
}

actor PigCopHurt : PigCop
{
  health 50
  +LOOKALLAROUND
  States
  {
  Spawn:
    ENE2 A 0
    ENE2 A 2 A_Look
    "####" "#" 0 A_ChangeFlag("LOOKALLAROUND", 0)
  Idle:
    "####" "#" 0 Thing_ChangeTID(0,1000)
    ENE2 AA 10 A_Look
    loop
  }
}

actor DeadPigCop : DeadDukeNukemP 19138
{
  Radius 16
  Height 12
  scale 0.7
  States
  {
  Spawn:
    ENE2 P -1
    Stop
  Death.Fire:
    "####" "#" 0 A_SetTranslation("Burned")
    "####" "#" 0 A_NoBlocking
    "####" "#" 0 A_SpawnItemEx("DeadPigCop", 0,0,0,0,0,0,0, SXF_TRANSFERTRANSLATION|SXF_TRANSFERSTENCILCOL)
    TNT1 A 1
    Stop
  Ice:
    "####" "#" 0 Thing_ChangeTID(0,3500)
    ENE2 P 5 A_GenericFreezeDeath
    ENE2 P 1 A_FreezeDeathChunks
    wait
  }
}

actor DeadPigCopBehead : DeadDukeNukem
{
  Radius 16
  Height 12
  scale 0.7
  States
  {
  Spawn:
    3NE2 P -1
    Stop
  Death.Fire:
    "####" "#" 0 A_SetTranslation("Burned")
    "####" "#" 0 A_NoBlocking
    "####" "#" 0 A_SpawnItemEx("DeadPigCopBehead", 0,0,0,0,0,0,0, SXF_TRANSFERTRANSLATION|SXF_TRANSFERSTENCILCOL)
    TNT1 A 1
    Stop
  Ice:
    "####" "#" 0 Thing_ChangeTID(0,3500)
    3NE2 P 5 A_GenericFreezeDeath
    3NE2 P 1 A_FreezeDeathChunks
    wait
  }
}