
actor Doom_Imp : ZBaseActor 19382
{
  HitObituary "$OB_IMPHIT"
  Obituary "$OB_IMP"
  Health 60
  Radius 20
  height 55
  mass 1000
  Speed 10
  SeeSound "imp/sight"
  attacksound ""
  PainSound "imp/pain"
  DeathSound "imp/death"
  ActiveSound "imp/active"
  dropitem "PistolAmmo" 192 12
  dropitem "Dual Pistol" 16
  painchance 85
  Painchance "Shrinker", 256
  painchance "FireBurning", 200
  painchance "MightyBoot", 128
  painchance "BootStun", 256
  painchance "MicrowaveBlast", 256
  MONSTER
  +FLOORCLIP
  Scale 1.05
  damagefactor "AlienzShrinker", 0.0
  damagefactor "Shrinkerhit", 0.0
  Species "Imps"
  +DOHARMSPECIES
  +NOINFIGHTSPECIES
  +DONTHARMCLASS
  WoundHealth 10
  +MISSILEMORE
  Damage (11)
  meleerange 50
  States
  {
  Spawn:
    TROO A 0
    "####" "#" 0 Thing_ChangeTID(0,1000)
    TROO AA 10 A_Look
    Loop
  See:
    TROO AABBCCDD 2 A_ChaseD3D
    Loop
  Missile:
    "####" "#" 0 A_FaceTarget
    "####" "#" 0 A_CustomMissile("MuzzleFlashFast",32,5,0)
    TROO EEE 2 A_CustomMissile ("FlameTrailsSmall1", 35, 30, random (0, 40), 2, random (0, 160))
    "####" "#" 0 A_CustomMissile("MuzzleFlashFast",32,5,0)
    TROO EEE 2 A_CustomMissile ("FlameTrailsSmall1", 35, 30, random (0, 40), 2, random (0, 160))
    TROO F 2 A_CustomMissile ("FlameTrailsSmall1", 35, 30, random (0, 40), 2, random (0, 160))
    "####" "#" 0 A_FaceTarget
    "####" "#" 0 A_CustomMissile("MuzzleFlashFast",32,5,0)
    TROO G 6 bright A_CustomMissile("Doom_ImpBall",35,5,0)
    TROO F 4
    goto See
  Melee:
    "####" "#" 0 A_GiveInventory("Thrusting",1)
  Melee2:
    TROO EF 4 A_FaceTarget
    TROO G 4 A_CustomMeleeAttack(random[RIDMONSTERAT](10,15),"imp/melee","alienz/melee")
    TROO FE 4 A_FaceTarget
    "####" "#" 0 A_JumpIfHealthLower(1,"See",AAPTR_TARGET)
    "####" "#" 0 A_JumpIfCloser(70,"Melee")
    "####" "#" 0 A_JumpIfInventory("Thrusting", 1, "Thrust")
    goto See
  Thrust:
    "####" "#" 0 A_TakeInventory("Thrusting",1)
    "####" "#" 0 A_PlayVoiceSoundPitch("","imp/sight",4)
    TROO E 1 A_FaceTarget
    TROT CD 2 A_SkullAttack
    TROT E 2 A_SkullAttack
    "####" "#" 0 A_Recoil(15)
    TROT F 6 A_FaceTarget
    TROT G 5 A_FaceTarget
    TROT H 4 A_CustomMeleeAttack(random[RIDMONSTERAT](10,15),"imp/melee","alienz/melee")
    "####" "#" 0 A_Stop
    goto See
  Pain.BootStun:
    "####" "#" 0 A_Jump(128,"Pain2BootStun")
    TROO H 9
    TROO H 9 A_PlayVoiceSoundPitch("Pain")
    Goto See
  Pain2BootStun:
    TROO I 9
    TROO I 9 A_PlayVoiceSoundPitch("Pain")
    Goto See
  Pain:
    "####" "#" 0 A_Jump(128,"Pain2")
    TROO H 3
    TROO H 3 A_PlayVoiceSoundPitch("Pain")
    Goto See
  Pain2:
    TROO I 3
    TROO I 3 A_PlayVoiceSoundPitch("Pain")
    Goto See
  Pain.MicrowaveBlast:
    TROO H 1
    "####" "#" 0 A_CheckThump("Pain.BootStun")
    loop
  Death:
    IMPC A 7 A_PlayVoiceSoundPitch("Death")
    IMPC B 7
    IMPC C 7 A_NoBlocking
    TRO2 F 7
    TRO2 G 7
    IMPC I 1 A_SpawnItemEx("DeadDoom_Imp", 0,0,0,0,0,0,0, SXF_TRANSFERTRANSLATION|SXF_TRANSFERSTENCILCOL|SXF_SETMASTER)
    "####" "#" 0 A_SpawnItemEx("DukeRedBloodPool")
    TNT1 A -1
    stop
  Pain.Shrinker:
    "####" "#" 0 A_PlaySound("shrinker/shrink")
    "####" "#" 0 A_InvulnerablePlus(1)
    TROO H 5 A_PlayVoiceSoundPitch("Pain")
    "####" "#" 0 A_CustomMissile("ShrinkEffect",8,0,0)
  Shrink:
    TROO H 2 {A_SetScale(ScaleX - 0.04, ScaleY - 0.04); A_SpawnItemEx("ShrunkBlur",0,0,0,0,0,0,angle,SXF_TRANSFERSPRITEFRAME|SXF_TRANSFERSCALE|SXF_TRANSFERTRANSLATION|SXF_NOCHECKPOSITION|SXF_ABSOLUTEANGLE);}
    "####" "#" 0 A_JumpIf(ScaleX > 0.2 && ScaleY > 0.2, "Shrink")
    "####" "#" 0 A_Shrink("A","B","C","D",0.3)
    "####" "#" 0 A_Remove(AAPTR_DEFAULT)
    stop
  XDeath:
  Death.BossStomp:
    "####" "#" 0 A_XScream
    "####" "#" 0 A_NoBlocking
    "####" "#" 0 A_SpawnDebris("DukeGibs1NF", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs2NF", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs3NF", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs4NF", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs5NF", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("Doom_ImpHead1",TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("Doom_ImpArm1",TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("Doom_ImpLeg1",TRUE, 1.0, 1.0)
    "####" "#" 0 A_Jump(256,"Gib1","Gib2","Gib3","Gib4","Gib5","Gib6")
    TNT1 A 1
    Stop
  Death.PlasmaGib:
    "####" "#" 0 A_SpawnItemEx("DukePlasmaExplosion",0,0,32,0,0,0,0,1,0)
    "####" "#" 0 A_XScream
    "####" "#" 0 A_NoBlocking
    "####" "#" 0 A_SpawnDebris("DukeGibs1NFP", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs2NFP", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs3NFP", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs4NFP", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs5NFP", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("Doom_ImpHead1",TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("Doom_ImpArm1",TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("Doom_ImpLeg1",TRUE, 1.0, 1.0)
    "####" "#" 0 A_Jump(256,"Gib1","Gib2","Gib3","Gib4","Gib5","Gib6")
    TNT1 A 1
    Stop
  Death.Explosion:
  Death.RocketExplosion:
    "####" "#" 0 A_XScream
    "####" "#" 0 A_NoBlocking
    "####" "#" 0 A_SpawnDebris("DukeGibs1", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs2", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs3", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs4", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs5", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("Doom_ImpHead1",TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("Doom_ImpArm1",TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("Doom_ImpLeg1",TRUE, 1.0, 1.0)
    "####" "#" 0 A_Jump(256,"Gib1","Gib2","Gib3","Gib4","Gib5","Gib6")
    TNT1 A 1
    Stop
  Death.ExplosiveShotgun:
  Death.ShellExplosion:
    "####" "#" 0 A_XScream
    "####" "#" 0 A_NoBlocking
    "####" "#" 0 A_Jump(FAS_AltShotgunGibFireProb,3)
    "####" "#" 0 A_SpawnDebris("DukeGibs1NF", TRUE, 1.0, 1.0)
    "####" "#" 0 A_Jump(256,2)
    "####" "#" 0 A_SpawnDebris("DukeGibs1", TRUE, 1.0, 1.0)
    "####" "#" 0 A_Jump(FAS_AltShotgunGibFireProb,3)
    "####" "#" 0 A_SpawnDebris("DukeGibs2NF", TRUE, 1.0, 1.0)
    "####" "#" 0 A_Jump(256,2)
    "####" "#" 0 A_SpawnDebris("DukeGibs2", TRUE, 1.0, 1.0)
    "####" "#" 0 A_Jump(FAS_AltShotgunGibFireProb,3)
    "####" "#" 0 A_SpawnDebris("DukeGibs3NF", TRUE, 1.0, 1.0)
    "####" "#" 0 A_Jump(256,2)
    "####" "#" 0 A_SpawnDebris("DukeGibs3", TRUE, 1.0, 1.0)
    "####" "#" 0 A_Jump(FAS_AltShotgunGibFireProb,3)
    "####" "#" 0 A_SpawnDebris("DukeGibs4NF", TRUE, 1.0, 1.0)
    "####" "#" 0 A_Jump(256,2)
    "####" "#" 0 A_SpawnDebris("DukeGibs4", TRUE, 1.0, 1.0)
    "####" "#" 0 A_Jump(FAS_AltShotgunGibFireProb,3)
    "####" "#" 0 A_SpawnDebris("DukeGibs5NF", TRUE, 1.0, 1.0)
    "####" "#" 0 A_Jump(256,2)
    "####" "#" 0 A_SpawnDebris("DukeGibs5", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("Doom_ImpHead1",TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("Doom_ImpArm1",TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("Doom_ImpLeg1",TRUE, 1.0, 1.0)
    "####" "#" 0 A_Jump(256,"Gib1","Gib2","Gib3","Gib4","Gib5","Gib6")
    TNT1 A 1
    Stop
  Gib1:
    "####" "#" 0 A_SpawnDebris("DukeGibs6", FALSE, 1.0, 1.0)
    GIB1 E 1 A_SpawnItemEx("Gib1DeathSkin", 0,0,0,0,0,0,0, SXF_TRANSFERTRANSLATION)
    Stop
  Gib2:
    "####" "#" 0 A_SpawnDebris("DukeGibs6", FALSE, 1.0, 1.0)
    GIB2 E 1 A_SpawnItemEx("Gib2DeathSkin", 0,0,0,0,0,0,0, SXF_TRANSFERTRANSLATION)
    Stop
  Gib3:
    "####" "#" 0 A_SpawnDebris("DukeGibs6", FALSE, 1.0, 1.0)
    GIB3 E 1 A_SpawnItemEx("Gib3DeathSkin", 0,0,0,0,0,0,0, SXF_TRANSFERTRANSLATION)
    Stop
  Gib4:
    "####" "#" 0 A_SpawnDebris("DukeGibs6", FALSE, 1.0, 1.0)
    GIB4 E 1 A_SpawnItemEx("Gib4DeathSkin", 0,0,0,0,0,0,0, SXF_TRANSFERTRANSLATION)
    Stop
  Gib5:
    "####" "#" 0 A_SpawnDebris("DukeGibs6", FALSE, 1.0, 1.0)
    GIB5 E 1 A_SpawnItemEx("Gib5DeathSkin", 0,0,0,0,0,0,0, SXF_TRANSFERTRANSLATION)
    Stop
  Gib6:
    "####" "#" 0 A_SpawnDebris("DukeGibs6", FALSE, 1.0, 1.0)
    TROO N 5
    TROO O 5
    TROO P 5
    TROO Q 5
    TROO RST 5
    TROO UUUUUUUUUUUUUUUUUUUUUUUUUUUUUU 35 A_Gravity
    TROO UUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUUU 1 A_FadeOut(0.1)
    Stop
  Wound.Expander:
   "####" "#" 0 A_Die("Expander")
  Death.Expander:
    "####" "#" 0 A_ChangeFlag("DONTCORPSE",1)
    "####" "#" 0 A_PlaySound("expander/expand")
    "####" "#" 0 {A_UnsetShootable; A_UnsetSolid;}
  Expand:
    TROO H 1 A_SetScale(ScaleX + 0.01, ScaleY + 0.01)
    "####" "#" 0 A_JumpIf(ScaleX < 1.5 && ScaleY < 1.5, "Expand")
    TROO HHHHH 1
    "####" "#" 0 A_SetScale(1.05, 1.05)
    "####" "#" 0 A_PlayVoiceSoundPitch("Death","",4)
    "####" "#" 0 A_SpawnItemEx("ExpanderExplosion",0,0,32,0,0,0,0,1,0)
    "####" "#" 0 A_SpawnDebris("DukeGibs1", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs2", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs3", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs4", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs5", TRUE, 1.0, 1.0)
    goto Death.Explosion
  Wound.Ice:
    "####" "#" 0 A_Freeze("See")
    "####" "#" 0 A_Remove(AAPTR_DEFAULT)
    TNT1 A 1
    stop
  Death.MonsterSlimer:
    TROO H 10 {A_PlayVoiceSoundPitch("Death"); A_SpawnItemEx("SlimerEatingMonster");}
    TROO HH 10
    stop
  Death.Headshot:
    "####" "#" 0 A_XScream
    "####" "#" 0 A_SpawnDebris("DukeGibs2NF", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs2NF", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs5NF", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs6", FALSE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs6", FALSE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs6", FALSE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("Doom_ImpHead1",TRUE, 1.0, 1.0)
    IMPH A 21 A_NoBlocking
    IMPH B 14
    IMPH C 7
    IMPH D 7
    IMPH E 1 A_SpawnItemEx("DeadDoom_ImpBehead", 0,0,0,0,0,0,0, SXF_TRANSFERTRANSLATION|SXF_TRANSFERSTENCILCOL)
    "####" "#" 0 A_SpawnItemEx("DukeRedBloodPool")
    stop
  Death.SSG:
    "####" "#" 0 A_JumpIf(d3d_extradeathgore==1, "Death")
    "####" "#" 0 A_JumpIfCloser(210, 1)
    Goto Death
    "####" "#" 0 A_XScream
    "####" "#" 0 A_SpawnDebris("DukeGibs1NF", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs2NF", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs3NF", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs4NF", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs5NF", TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("DukeGibs6", FALSE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("Doom_ImpHead1",TRUE, 1.0, 1.0)
    "####" "#" 0 A_SpawnDebris("Doom_ImpArm1",TRUE, 1.0, 1.0)
    TROG A 21 A_NoBlocking
    TROG B 14
    TROG C 7
    TROG D 7
    TROG E 1 A_SpawnItemEx("DeadDoom_ImpHalf", 0,0,0,0,0,0,0, SXF_TRANSFERTRANSLATION|SXF_TRANSFERSTENCILCOL)
    "####" "#" 0 A_SpawnItemEx("DukeRedBloodPool")
    stop
  Possessed:
    "####" "#" 0 A_ChangeFlag("NOPAIN", 1)
    IMPC I 7 {A_XScream; A_AdjustTics(1.0,1.0);}
    TRO2 G 7 {A_XScream; A_AdjustTics(1.0,1.0);}
    TRO2 F 7 A_AdjustTics(1.0,1.0)
    IMPC C 7 A_AdjustTics(1.0,1.0)
    IMPC B 7 A_AdjustTics(1.0,1.0)
    IMPC A 7 A_AdjustTics(0,1.0)
    "####" "#" 0 A_ChangeFlag("NOPAIN", 0)
    goto See
  }
}

Actor Doom_ImpBall : ZMissile
{
  Radius 6
  Height 8
  Speed 20
  Damage (random(10,15))
  Projectile
  Obituary "$OB_IMP"
  Decal "DukeScorch"
  DamageType BulletFlame
  RenderStyle "Add"
  Alpha 1
  SeeSound "imp/attack"
  DeathSound "imp/shotx"
  +BLOODLESSIMPACT
  +FORCEXYBILLBOARD
  +THRUGHOST
  +GHOST
  +RANDOMIZE
  -THRUSPECIES
  Species "none"
  ThruBits 1
  States
  {
  Spawn:
    BAL1 A 0 A_SpawnItem("RedFlareMedium")
    BAL1 AA 1 BRIGHT {A_SpawnItem ("CoolandNewFlameTrails"); A_CustomMissile ("OldschoolRocketSmokeTrail2", 2, 0, random[RIDFX](70, 110), 2, random[RIDFX](0, 360));}
    BAL1 A 0 A_SpawnItem("RedFlareMedium")
    BAL1 AA 1 BRIGHT {A_SpawnItem ("CoolandNewFlameTrails"); A_CustomMissile ("OldschoolRocketSmokeTrail2", 2, 0, random[RIDFX](70, 110), 2, random[RIDFX](0, 360));}
    BAL1 B 0 A_SpawnItem("RedFlareMedium")
    BAL1 BB 1 BRIGHT {A_SpawnItem ("CoolandNewFlameTrails"); A_CustomMissile ("OldschoolRocketSmokeTrail2", 2, 0, random[RIDFX](70, 110), 2, random[RIDFX](0, 360));}
    BAL1 B 0 A_SpawnItem("RedFlareMedium")
    BAL1 BB 1 BRIGHT {A_SpawnItem ("CoolandNewFlameTrails"); A_CustomMissile ("OldschoolRocketSmokeTrail2", 2, 0, random[RIDFX](70, 110), 2, random[RIDFX](0, 360));}
    Loop
  Death:
    TNT1 A 0 A_SpawnItemEx("FlameExplosion",0,0,0,0,0,0,0,0)
    TNT1 AAAAA 0 A_CustomMissile ("RedPlasmaParticle", 0, 0, random[RIDFX](0, 360), 2, random[RIDFX](0, 360))
    TNT1 AAAAA 0 A_CustomMissile ("RedPlasmaParticle", 0, 0, random[RIDFX](0, 360), 2, random[RIDFX](0, 360))
    TNT1 AAAAA 0 A_CustomMissile ("RedPlasmaParticle", 0, 0, random[RIDFX](0, 360), 2, random[RIDFX](0, 360))
    BAL1 C 1 bright {A_SpawnItem("RedFlareMedium",0,0); A_FadeOut(0.075);}
    BAL1 C 1 bright {A_SpawnItem("RedFlareMedium",0,0); A_FadeOut(0.075);}
    BAL1 C 1 bright {A_SpawnItem("RedFlareMedium",0,0); A_FadeOut(0.075);}
    BAL1 C 1 bright {A_SpawnItem("RedFlareMedium",0,0); A_FadeOut(0.075);}
    TNT1 A 0 A_Explode(2,64)
    BAL1 D 1 bright {A_SpawnItem("RedFlareMedium",0,0); A_FadeOut(0.075);}
    BAL1 D 1 bright {A_SpawnItem("RedFlareMedium",0,0); A_FadeOut(0.075);}
    BAL1 D 1 bright A_FadeOut(0.075)
    BAL1 D 1 bright A_FadeOut(0.075)
    BAL1 E 1 bright A_FadeOut(0.075)
    BAL1 E 1 bright A_FadeOut(0.075)
    BAL1 E 1 bright A_FadeOut(0.075)
    BAL1 E 1 bright A_FadeOut(0.075)
    Stop
  }
}

actor DeadDoom_Imp : DeadDukeNukemP 19383
{
  Radius 20
  Height 12
  scale 1.05
  States
  {
  Spawn:
    IMPC I -1
    Stop
  Death.Fire:
    "####" "#" 0 A_SetTranslation("Burned")
    "####" "#" 0 A_NoBlocking
    "####" "#" 0 A_SpawnItemEx("DeadDoom_Imp", 0,0,0,0,0,0,0, SXF_TRANSFERTRANSLATION|SXF_TRANSFERSTENCILCOL)
    TNT1 A 1
    Stop
  Ice:
    "####" "#" 0 Thing_ChangeTID(0,3500)
    IMPC I 5 A_GenericFreezeDeath
    IMPC I 1 A_FreezeDeathChunks
    wait
  Gib1:
  Gib2:
  Gib3:
  Gib4:
  Gib5:
    TNT1 A 0 A_SpawnDebris("DukeGibs6", FALSE, 1.0, 1.0)
    TNT1 A 1 A_SpawnItemEx("Gib4DeathSkin", 0,0,0,0,0,0,0, SXF_TRANSFERTRANSLATION)
    Stop
  }
}

actor DeadDoom_ImpBehead : DeadDukeNukem
{
  Radius 20
  Height 12
  scale 1.05
  States
  {
  Spawn:
    IMPH E -1
    Stop
  Death.Fire:
    "####" "#" 0 A_SetTranslation("Burned")
    "####" "#" 0 A_NoBlocking
    "####" "#" 0 A_SpawnItemEx("DeadDoom_ImpBehead", 0,0,0,0,0,0,0, SXF_TRANSFERTRANSLATION|SXF_TRANSFERSTENCILCOL)
    TNT1 A 1
    Stop
  Ice:
    "####" "#" 0 Thing_ChangeTID(0,3500)
    IMPH E 5 A_GenericFreezeDeath
    IMPH E 1 A_FreezeDeathChunks
    wait
  Gib1:
  Gib2:
  Gib3:
  Gib4:
  Gib5:
    TNT1 A 0 A_SpawnDebris("DukeGibs6", FALSE, 1.0, 1.0)
    TNT1 A 1 A_SpawnItemEx("Gib4DeathSkin", 0,0,0,0,0,0,0, SXF_TRANSFERTRANSLATION)
    Stop
  }
}

actor DeadDoom_ImpHalf : DeadDukeNukem
{
  Radius 20
  Height 12
  scale 1.05
  States
  {
  Spawn:
    TROG E -1
    Stop
  Death.Fire:
    "####" "#" 0 A_SetTranslation("Burned")
    "####" "#" 0 A_NoBlocking
    "####" "#" 0 A_SpawnItemEx("DeadDoom_ImpHalf", 0,0,0,0,0,0,0, SXF_TRANSFERTRANSLATION|SXF_TRANSFERSTENCILCOL)
    TNT1 A 1
    Stop
  Ice:
    "####" "#" 0 Thing_ChangeTID(0,3500)
    TROG E 5 A_GenericFreezeDeath
    TROG E 1 A_FreezeDeathChunks
    wait
  Gib1:
  Gib2:
  Gib3:
  Gib4:
  Gib5:
    TNT1 A 0 A_SpawnDebris("DukeGibs6", FALSE, 1.0, 1.0)
    TNT1 A 1 A_SpawnItemEx("Gib4DeathSkin", 0,0,0,0,0,0,0, SXF_TRANSFERTRANSLATION)
    Stop
  }
}