//Try to not throw up with this guy in your side.

Class SacoDeSangreA : Actor
{
	//$Category Desgraciados
	//$Title Saco De Sangre Normal
	
	Actor boladenada;
	Default
	{
	health 40;
	radius 20;
	height 24;
	mass 100;
	speed 4;
	scale 0.8;
	PainChance 256;
	seesound "blob/sight";
	painsound "blob/pain";
	activesound "blob/active";
	MONSTER;
	+FLOORCLIP;
	+LOOKALLAROUND;
	obituary "%o was popped by a pustule.";
	Tag "Pustule";
	}
	States
	{
	Spawn:
		FLOB A 10 A_Look();
		loop;
	See:
		FLOB AABBCCBB 3 A_Chase();
		loop;
	Pain:
		FLOB A 1 A_Pain();
		FLOB A 0 A_Wander();
		FLOB ABBCCBB 1 A_Wander();
		FLOB AABBCCBB 1 A_Wander();
		goto See;
	Melee:
		FLOB A 0 A_Die();
	Death:
		FLOB F 2 A_PlaySound ("Blob/Explode");
		FLOB F 0 A_SpawnItem ("SacoDeDano");
		FLOB FFFFFFFFFFFFFFFFFFFF 0 A_SpawnItemEX("MalaSangre", 0, 0, 0, random (4, 12), 0, random (4, 12), random(0, 360));
		FLOB GH 2;
		stop;
	}
}

Class SacoDeSangreB : SacoDeSangreA
{
	//$Category Desgraciados
	//$Title Saco De Sangre Pequeño
	
	Default
	{
	health 20;
	radius 16;
	height 20;
	Scale 0.6;
	}
}

Class SacoDeSangreC : SacoDeSangreA
{
	//$Category Desgraciados
	//$Title Saco De Sangre Grande
	
	Default
	{
	health 60;
	radius 30;
	height 34;
	Scale 1.8;
	}
}

Class SacoDeSangreD : SacoDeSangreA
{
	//$Category Desgraciados
	//$Title Saco De Sangre Gigante
	
	Default
	{
	health 80;
	radius 36;
	height 40;
	Scale 2.4;
	}
}

Class SacoDeDano : Actor //I will not risk it by just putting an "Ñ" there.
{
	Default
	{
	Radius 20;
	Height 24;
	+NOINTERACTION;
	obituary "%o was popped by a pustule.";
	}
	States
	{
	Spawn:
		TNT1 A 0;
		TNT1 A 1 A_Explode (35, 64, 0, 1, 1);
		stop;
	}
}

Class MalaSangre : Actor
{
	Default
	{
	Radius 2;
	Height 2;
	Speed 1;
	Damage 0;
	Decal "BloodSplat";
	Projectile;
	-NOGRAVITY;
	}
	States
	{
	Spawn:
		TNT1 A 1 A_SpawnItemEX("MalaSangreTail", random(-2, 2), 0, random(-2, 2), 0, 0, 0, random(0, 360));
		loop;
	Death:
		TNT1 A 4;
		stop;
	}
}

Class MalaSangreTail : Actor
{
	Default
	{
	Radius 2;
	Height 2;
	+NOINTERACTION;
	+CLIENTSIDEONLY;
	}
	States
	{
	Spawn:
		BLUD CBA 3;
		stop;
	}
}