
// グローバル変数
float	g_TalkRand;

// プレイヤー性格判定用
bool	g_犬好き;
bool	g_猫好き;


// 開始時に呼び出される
Start()
{
	// カメラの設定
	@SetCameraPos(-0.02, 0.96, -1.07);
	@SetCameraAngle(251.0);
	
	// ライト設定
	@SetLightAngle(108.0, 30.5);
	
	// フィールドの読み込み
	@LoadField("UserFile\\Field\\MasisiHouse_ver1.0\\MasisiHouse_ver1.0_改.pmx");
	
	// キャラクターの読み込み
	@LoadChara("UserFile\\Model\\Tda式初音ミク・アペンドVer1.00\\Tda式初音ミク・アペンド_Ver1.00.pmx");
	
	// キャラクターの位置と角度設定
	@SetCharaPos(1.74, 0.0277368447, -1.95);
	@SetCharaAngle(90.0);
	
	// モーション読み込み
	@LoadMotion("sit", "sit.vmd", false);
	@LoadMotion("bow", "bow.vmd", false);
	@LoadMotion("sitwait", "sitwait.vmd", true);
	
	// モーション：座る
	@ChangeMotion("sit");
	@WaitMotion();
	
	// こっちを見る
	@LookAtMe(true);
	
	// モーション：おじぎ
	@ChangeMotion("bow");
	@WaitMotion();
	
	// モーション：座り続けるループ
	@ChangeMotion("sitwait");
	
}


// 何も関数が呼び出されていない時に定期的に呼び出される
OnIdle()
{
	// 遠ければ話しかけない
	if (@GetPlayerDistance() >= 8.0) return;
	
	// 近すぎる
	if (@GetPlayerDistance() < 1.0) {
		@Talk("ちょっと近すぎます");
		return;
	}
	
	//
	g_TalkRand = @GetRandF();
	
	//
	if (g_TalkRand < 0.3) {
		疲れているの();
	}
	else if (g_TalkRand < 0.6) {
		夕食の献立();
	}
	else {
		犬と猫();
	}

}


// 話しかけられた
OnTalk()
{
	if (挨拶反応()) return;
	if (口説かれ反応()) return;
	if (歌反応()) return;
	
	@Talk("はい、なんでしょう？");
	
}


//
void 夕食の献立()
{
	@Talk("ところで、晩ご飯は何が食べたいですか？");

	@WaitTalk();
	
	@Talk("そうですね。私もそれが食べたいと思ってました");
	
}


//
void 犬と猫()
{
	@Talk("もし飼うとしたら、犬と猫どっちがいいですか？");
	
	@WaitTalk();
	
	if (@IsExistWordReading("イヌ")) {
		@Talk("散歩に連れて行くのが楽しそうですよね");
		
		g_犬好き = true;
	}
	else {
		@Talk("いずれ飼いたいですね");
		
		g_猫好き = true;
	}
	
}


//
void 疲れているの()
{
	@Talk("ちょっと疲れているように見えるのですが、大丈夫ですか？");
	
	@WaitTalk();
	
	@Talk("無理はしないで下さいね");
	
}


// 挨拶
bool 挨拶反応()
{
	if (@IsExistWordReading("オハヨウ")) {
		@Talk("おはようございます");
		return true;
	}
	
	if (@IsExistWordReading("コンニチハ")) {
		@Talk("こんにちは");
		return true;
	}
	
	if (@IsExistWordReading("コンバンハ")) {
		@Talk("こんばんは");
		return true;
	}
	
	return false;
	
}


// 口説かれたときの反応
bool 口説かれ反応()
{
	if (@IsExistWordReading("カワイイ")) {
		@Talk("あ、は、はい。ありがとうございます");
		return true;
	}
	
	if (@IsExistWordBase("好き")) {
		@Talk("え、えーと");
		return true;
	}

	if (@IsExistWordBase("愛す")) {
		@Talk("ちょっと、恥ずかしいです");
		return true;
	}

	return false;
	
}


//
bool 歌反応()
{
	if (@IsExistWordBase("歌う")) {
		@Talk("私は歌わないですよ");
		return true;
	}
	
	return false;
	
}

