//===========================================================================
//
// Unknown Hazard
//
//===========================================================================
ACTOR UnknownHazard 20110
{
	Tag "Unknown Hazard"
	Health 50
	PainChance 50
	Speed 10
	Radius 16
	Height 56
	Mass 400
	Monster
	Gravity 1.5
	+FLOORCLIP +FASTER +FASTMELEE +JUMPDOWN -COUNTKILL
	Renderstyle Translucent
	Alpha .5
	Bloodcolor Green
	Maxstepheight 62
	MaxDropoffheight 96
	SeeSound "Hazard/See"
	PainSound "Hazard/Pain"
	DeathSound "Hazard/Death"
	ActiveSound "Hazard/Idle"
	MeleeSound "Hazard/Melee"
	Obituary "%o gazed into the static."
	Meleerange 70
	States
	{
	Spawn:
		HZRD IJJ 12 A_Look
		Loop
	See:
		HZRD AAAABBBCCCDDD 2 A_Chase
		Loop
	Melee:
		HZRD F 0 A_jump(32,"Melee2_2")
		HZRD E 6 A_FaceTarget
		HZRD F 4 A_FaceTarget
		HZRD F 0 A_jump(72,"Melee2")
		HZRD G 8 A_custommeleeattack(3 * random(1, 6), "Hazard/melee")
		Goto See
		Melee2:
		HZRD G 4 A_custommeleeattack(3 * random(1, 6), "Hazard/melee")
		Melee2_2:
		HZRD G 1 A_FaceTarget
		HZRD E 0 A_changevelocity(0,0,frandom(5,10),CVF_RELATIVE)
		HZRD E 0 A_recoil(frandom(10,20))
		Goto Missile2
	Missile:
		HZRD G 0 A_jump(128,"Missile_projectile")
		HZRD G 6 A_FaceTarget
		HZRD E 0 A_playsound("Hazard/Jump",0,.75)
		HZRD E 0 A_changevelocity(0,0,frandom(5,20),CVF_RELATIVE)
		HZRD E 0 A_FaceTarget
		HZRD E 0 A_recoil(frandom(-10,-20))
		Missile2:
		HZRD K 2 A_FaceTarget
		HZRD K 1 A_recoil(-1)
		HZRD E 0 A_checkfloor("Missile3")
		Goto Missile2
		Missile3:
		TNT1 A 0 A_Stop
		TNT1 A 0 A_playsound("Hazard/land",0)
		HZRD G 6 A_FaceTarget
		Goto See
	Pain:
		HZRD H 2
		HZRD H 2 A_Pain
		Goto See
	Death:
		HZRD L 4 A_NoBlocking
		HZRD M 4 A_Scream
		HZRD N 4
		HZRD O -1
		Stop
		XDeath:
		HZRD P 4 BRIGHT A_NoBlocking
		HZRD Q 4 BRIGHT A_XScream
		HZRD R 4 BRIGHT
		HZRD STUV 4 BRIGHT
		HZRD W -1
		Stop
	}
}

ACTOR UnknownHazard_Ambush : UnknownHazard 20111
{
	States
	{
	Spawn:
		TNT1 A 12 A_Look
		Loop
	}
}