//===========================================================================
//
// Industrial Stalker
//
//===========================================================================
ACTOR IndustrialStalker 20100
{
	Tag "Industrial Stalker"
	Health 250
	Radius 20
	Height 56
	Mass 1000
	Speed 6
	PainChance 20
	Monster
	//+PUSHABLE
	+FLOORCLIP
	-COUNTKILL
	+NORADIUSDMG
	Bloodcolor Black
	SeeSound "Stalker/See"
	PainSound "Stalker/Pain"
	DeathSound "Stalker/Death"
	ActiveSound "Stalker/Idle"
	MeleeSound "Stalker/Melee"
	AttackSound "Stalker/Attack"
	Obituary "%o ran into a dead end."
	Meleerange 70
	States
	{
	Spawn:
		INDS B 1 A_Look
		TNT1 AAAAAAAA 0 A_SpawnParticle(191919, SPF_RELATIVE, random(32,128), random(1,5),0, frandom(-360,360),frandom(-360,360),frandom(0,75), 0,0,0, 0,0,0.0, 1.0, -1)
		Loop
	See:
		TNT1 AAAAAAAAAA 0 A_SpawnParticle(191919, SPF_RELATIVE, random(32,128), random(1,5),0, frandom(-360,360),frandom(-360,360),frandom(0,75), 0,0,0, 0,0,0.0, 1.0, -1)
		INDS AAABBB 2 A_Chase
		TNT1 AAAAAAAAAA 0 A_SpawnParticle(191919, SPF_RELATIVE, random(32,128), random(1,5),0, frandom(-360,360),frandom(-360,360),frandom(0,75), 0,0,0, 0,0,0.0, 1.0, -1)
		INDS CCCDDD 2 A_Chase
		Loop
	Melee:
		TNT1 A 0 A_Playsound("Stalker/Swing",0)
		INDS EF 3 A_FaceTarget
		INDS G 8 A_custommeleeattack(4 * random(1, 8), "Stalker/Melee")
		Goto See
		Missile:
		TNT1 A 0 A_jump(128,"Missile_2")
		TNT1 A 0 A_jump(128,"Missile_projectile")
		INDS B 6 A_FaceTarget
		TNT1 A 0 A_SpawnItemEx("StalkerFog")
		TNT1 AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA 0 A_ExtChase(0,0,0)
		TNT1 A 0 A_playsound("Stalker/port",0)
		TNT1 A 1 A_FaceTarget
		INDS B 6 A_FaceTarget
		TNT1 A 0 A_jump(128,"See")
		INDS B 3 A_FaceTarget
		TNT1 A 0 A_SpawnItemEx("StalkerFog")
		TNT1 AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA 0 A_ExtChase(0,0,0)
		TNT1 A 0 A_playsound("Stalker/port",0)
		TNT1 A 1 A_FaceTarget
		INDS B 6 A_FaceTarget
		TNT1 A 0 A_jump(200,"See")
		INDS B 3 A_FaceTarget
		TNT1 A 0 A_SpawnItemEx("StalkerFog")
		TNT1 AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA 0 A_ExtChase(0,0,0)
		TNT1 A 0 A_playsound("Stalker/port",0)
		TNT1 A 1 A_FaceTarget
		INDS B 6 A_FaceTarget
		Goto See
	Missile_2:
		INDS AABBCCDD 2 A_Chase
		INDS AAAABBBBCCCCDDDDAAAABBBBCCCCDDDD 1 A_Chase
		TNT1 A 0 A_SpawnItemEx("StalkerFog")
		TNT1 AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA 0 A_ExtChase(0,0,0)
		TNT1 A 0 A_playsound("Stalker/port",0)
		TNT1 A 1
		INDS B 6 A_FaceTarget
		Goto See
	Missile_Projectile:
		TNT1 A 0 A_Playsound("Stalker/Attack",0)
		INDS EF 12 A_FaceTarget
		INDS GGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGGG 1 A_custommissile("Stalkerball")
		Goto See
	Pain:
		INDS G 2
		INDS G 2 A_Pain
		Goto See
	Death:
		TNT1 A 0 A_NoBlocking
		INDS I 4 A_Scream
		INDS J 4
		INDS K 4
		INDS LM 4
		INDS N 128
		Death_Fade:
		TNT1 A 0 A_spawnparticle(191919,SPF_FULLBRIGHT,96,frandom(2,4),0,frandom(-8,8),frandom(-8,8),frandom(2,10),frandom(0,1),frandom(0,0),frandom(0,1),0,0,0)
		INDS N 2 A_Fadeout(.005)
		TNT1 A 0 A_spawnparticle(191919,SPF_FULLBRIGHT,96,frandom(2,4),0,frandom(-8,8),frandom(-8,8),frandom(2,10),frandom(0,1),frandom(0,0),frandom(0,1),0,0,0)
		INDS N 2 A_Fadeout(.005)
		Loop
	}
}

ACTOR Stalkerball : fastprojectile
{
	Radius 2
	Height 4
	Speed 120
	Damage 0
	Projectile 
	+RANDOMIZE
	DeathSound "Stalker/shotx"
	States
	{
	Spawn:
		TNT1 A 1
		Loop
	Death:
		TNT1 AAAAA 0 A_SpawnParticle(191919, SPF_RELATIVE, random(8,75), random(1,5),0, frandom(-32,32),frandom(-32,32),frandom(-32,32), 0,0,0, 0,0,0.0, 1.0, -1)
		TNT1 A 0 A_Jump(196,"Death2")
		TNT1 A 1 A_Explode(4,75)
		Death2:
		TNT1 AAAAAAAAAAAAAA 1 A_SpawnParticle(191919, SPF_RELATIVE, random(8,75), random(1,5),0, frandom(-32,32),frandom(-32,32),frandom(-32,32), 0,0,0, 0,0,0.0, 1.0, -1) 
		Stop
	}
}

ACTOR StalkerFog
{
	+NOBLOCKMAP
	+NOTELEPORT
	+NOGRAVITY
	States
	{
	Spawn:
		TNT1 A 0
		INDS BBBBBBBBBB 1 A_FadeOut(.1)
		Stop
	}
}