アセンブリのセキュリティ設定

アセンブリのセキュリティ設定

ゲーム開発チームの中には、開発ツールをネットワークドライブなどで共有することで、全員の作業環境を統一したい場合があります。 このように設定しておくことで、ツールのバージョンアップごとに全員の席を回って再設定しなければならない手間を省略することが出来ます。 しかし、Message StudioはMicrosoft .NET Frameworkで作成されている関係上、直接ネットワークドライブ(共有フォルダ)上の実行ファイルを起動することが出来ません。 このような場合、Caspolというツールを使ってネットワークドライブ上に「信頼できるエリア」を設定して、この制限を回避することが出来ます。

以下のサンプル（DOSコマンド）を参考にして、各チームの内容に合うように変更したものを、Message Studioを実行する各PCに対して実行する必要があります。

参考：
Caspol.exe によるセキュリティ ポリシーの問題の解決
ttp://msdn.microsoft.com/ja-jp/library/073ba759(VS.80).aspx

セキュリティ登録のサンプル

@echo off

SET CASPOL=%windir%\Microsoft.NET\Framework\v2.0.50727\CasPol.exe^
 -quiet -machine 

SET MESSAGE_STUDIO_ROOT_DIR=X:\path\to\message_studio_file_dir
SET ZONE_NAME=Message_Studio_Zone
SET DESCLIPTION="MessageStuido Directory"

IF NOT EXIST %MESSAGE_STUDIO_ROOT_DIR% GOTO errordir

IF "%MESSAGE_STUDIO_ROOT_DIR%" == "" GOTO errordir

REM # Clean up
%CASPOL% -remgroup %ZONE_NAME%

REM # Register command
%CASPOL% -addgroup All_Code -url "%MESSAGE_STUDIO_ROOT_DIR%\*"^
 FullTrust -name %ZONE_NAME% -d %DESCLIPTION%

ECHO MessageStudio Directory Registration was Success.
ECHO [%MESSAGE_STUDIO_ROOT_DIR%]
GOTO end

:errordir
ECHO MessageStudio Directory Registration was Failed.
ECHO [%MESSAGE_STUDIO_ROOT_DIR%] not found.
:end

PAUSE

セキュリティ登録を解除するサンプル

@echo off

SET CASPOL=%windir%\Microsoft.NET\Framework\v2.0.50727\CasPol.exe^
 -quiet -machine 
SET ZONE_NAME=Message_Studio_Zone

REM # Unregister command
%CASPOL% -remgroup %ZONE_NAME%

ECHO MessageStudio Directory Unregistration was Success.

PAUSE

プラグインに対するセキュリティ設定

上記の例では、単一のディレクトリのみに対してセキュリティ設定を行いましたが、 Message Studioがプラグインを読み込むように設定されている場合には、そちらにも「信頼できるディレクトリ」設定を行う必要があります。 もしプラグインが読み込めない場合はプロジェクトを開いたタイミングでエラーが発生しますのでご注意ください。