[Placeholder Title Screen]

Chapter 9

(Author's Note: In its final form, the opening scene of this update will vary depending on the shop pastime you selected in Chapter 7. In the interest of plot progression, only one of the variations have been developed for this update, namely the tavern-keeper fork. The other variants will be included with the next update. Thank you for your understanding in the meantime!)

*page_break

A chill steals into the room and sets your teeth to chattering as you wipe down the tavern counter, the drops of ale scattered there disappearing into your rag. The patron seated in front of you glances back over his shoulder, scowling, as another edges the door open and slips inside. The new entrant shakes off his coat and paws at his wet hair, but it's a futile attempt. His drench is thorough, water seeping from his garments and into the wooden flooring as he ambles towards the fireplace.

You stifle a sigh. The building wasn't exactly in prime shape when you purchased it, and at this rate you'll have to invest in renovation sooner rather than later.

Casting your gaze towards the window, you find that the weather outside still retains its persistent gloom. It's been weeks since you left the storm-battered lands of Aulain, but the rain appears to insist on your company. And so it was that your return to Thulrum ushered in a full week of rainy weather, by all accounts a rarity in the normally-temperate city.

"Oi, Kess! Close the door proper behind you," shouts Maren, the glum-faced man in front of you. A laborer for Thulrum's projects deeper in the West Ward, as are many of those who patronize your establishment. "Bad enough that I have to look at your damned face. Don't bring the storm in with you!"

The man called Kess gives Maren the finger but obliges him, pushing the door shut with his heel. The man's overalls are splattered with stray flecks of paint. Evidence of his trade—despite his brawny, intimidating stature, the man is one of Thulrum's finest painters, responsible for some of the newer murals on the Seat of Isha.

He doffs his rucksack in a vacant chair, then, and plops himself right in front of the fireplace. Notably, without ordering a drink.

*choice
    #"Afternoon, Kess. Can I get you anything?"
        *set charming %+ 15
        "Barkeep," he says, vacantly staring into the flickering flames. "Got anything for a broken heart?"
        
        You give him a sympathetic smile. It appears his budding romance with the local seamstress has proved to be short-lived. "I've only got the one type of ale, and you know it," you say, pressing a mug to one of the taps. "But tell you what. First one's on the house."
        
        The lithe man seated next to Maren squints at you. "Playing favorites?"
        
        *label marenslap
        Maren gives him a slap upside the head, scowl deepening. "You let ${them} be, Reller. At these prices, you might as well be drinking for free yourself," he scolds. "If ${fname} decides to close up shop and we're forced to go crawling back to Old Gogia, I'll dump his damn spittoon on your fool head."
        
        Reller grabs Maren by the collar and shouts, words slurred by the alcohol, "You fancy yourself some kind of white knight, Maren? Them's fightin' words, and you'd better be ready to make good on them," he sneers.
        
        "I could snap you in half if I had a mind to."
        
        "Do it, bastard. Just don't blame me if your wife happens to find out about—"
        
        "Lessee how freely your tongue flaps when I've broken your teeth in!"
        
        You slip past the bickering pair, tiredly handing Kess his free mug. "Any fists go flying, you're both banned from the establishment."
        
        Reller turns his gaze on you, looking far meeker than he did mere moments ago. "For a week? A month?"
        
        "For life."
        
        Reluctantly, Reller's grip on Maren's collar comes loose. "Nothin' scarier than a @{pronvar man|woman|shopkeep} with power, and the knowledge of howta use it."
        
        "Ain't that the truth," Kess grumbles, taking the drink gratefully. Then, after catching himself, "Oh, Barkeep. I'm not talking about you, mind. It's just…my sweet Olara, it turns out a wealthy merchant has had his eyes on her for a while now…"
    #"Hope you haven't soaked my floorboards through just to freeload."
        "You've been good to me, Barkeep," Kess says, vacantly staring into the flickering flames. "I'll leave something for you in the will if I don't make it through the night."
        
        You turn sharply towards the burly man, but your concern dies as soon as you catch the expression on his face. "I know that look," you sigh. "Things aren't going well with Olara, I take it."
        
        *label faintsmile
        Kess smiles faintly and shakes his head. "It's over. After everything…"
        
        You give him a sympathetic smile. Kess's relationship with the local seamstress had been notorious for a multitude of reasons, and there was a quiet consensus among the locals that there was only one way things could go. You had all been proven right, in the end. "I'll pour one out for you," you say, pressing a mug to one of the taps. "On the house. With our condolences, and all that."
        
        Kess manages a weak laugh. "Condolences, not compliments? Pity. I could use a few after the beating my ego took."
        
        The lithe man seated next to Maren appears to mull over something. "Free ale…" he says, considering his empty mug, before turning his gaze up at you. "Playing favorites?"
        
        *goto marenslap
    #Leave the man be. It's not like I run this place for the money.
        *set charming %- 10
        *set noble %+ 10
        You picked a hell of a trade for that, if so. The margins on your drinks are razor thin, and it is only sheer volume that keeps your ledgers in the green. You're starting to sympathize a little with Old Gogia, these days. Had you not the steady stream of income from services rendered to the Saber, you may well have become every bit the grouch he is.
        
        *label youlookamess
        "You look a mess," Maren calls out to Kess over his shoulder. "Churchfolk putting you through your paces?"
        
        "Can it," Kess replies sourly.
        
        "That'll teach me to worry about you," Maren scoffs. "Oi, at least order something to drink. Think it's your brooding what keeps the hearth burning?"
        
        "I'll have one, Barkeep," Kess says after a while, not turning his gaze. "The strongest you got."
        
        "I only have the one kind, and you know it," you say, pressing a mug to one of the taps. You recognize the look on his face—you see it often enough in your line of work. "I'll take it things aren't going so well with Olara?"
        
        *goto faintsmile
    #I'll let him lounge around. Kess is a valuable customer.
        *set noble %- 15
        As one of the artists regularly commissioned by the Church, Kess is among the more affluent residents of the West Ward. That doesn't mean much at present, seeing as the only thing you have on tap is fermented bathwater, but you've been considering expansions to the menu, these days. Should the day come that rare vintages grace your shelves, Kess is one of your only hopes in making them sell.
        
        *goto youlookamess

Before Kess can regale you with his unsolicited tale, a cold draft carries into the room as the door swings open once more. You hear a grumble from Maren's general direction—[i]Barkeep, what say you we bar the doors?[/i]—but you're too distracted to reply. For emerging from the downpour outside are a pair of familiar faces, each with a flower wreath in their hands. The both of them are completely dry despite the foul weather, and you sense a familiar crackle of magic around them.

You frown. Perhaps you ought to learn that wind spell yourself, given how much mileage it's seen these days.

${yusuha} sweeps into the room with a smile, for once dressed in civilian
*if (gyusuha = "male")
    clothes—a light brown tunic and dark pants, complete with leather boots—though that does little to make him blend into the local populace, given his distinctly Yotai coloring.
*else
    clothes—a plain white dress with a dark corset, her hair pulled back with a bandanna—though that does little to make her blend into the local populace, given her distinctly Yotai coloring.
Following in ${yhis} wake is Eli, dressed in a bright green tunic. You can feel the whole of your tavern raking judgmental gazes over ${ehis} choice of dress—worrying, given that your establishment is hardly highbrow—though the @{evar man|woman} ${ehim}self appears blissfully ignorant.

*if (alias)
    "${fakename}!" ${yusuha} calls out, striding over to you. You're almost surprised to hear ${yhim} calling you by your alias, when you've abandoned it in Aulain. Regardless, ${yhe} strides over to you, laying ${yhis} wreath on the bar
*else
    "${fname}!" ${yusuha} calls out, striding over to you. $!{yhe} lays ${yhis} wreath on the bar
counter—an assortment of white and red flowers, which you know from its purplish tinge has been dipped in a preservative potion. It's a Thulrum tradition, as you've recently learned—when a friend moves to a new house or opens a business, then one is expected to give them a wreath in congratulation. "The fabled Thul Rums, in the flesh," ${yhe} says, looking around the tavern. "Can't believe ${falco} beat me to the punch, and by so wide a margin, at that."

*choice
    #"Good to see you, ${yusuha}. Ale?"
        "Jumping straight to business, are we? How cold," ${yusuha} chuckles. "Alas, I come not as a patron."
        
        You tilt your head. "Then?"
        
        "As a barkeep," ${yusuha} says. "With your permission, of course."
        
        You blink at ${yhim}, confused, as Eli draws ${ehim}self up beside ${yusuha}. "I asked ${yhim} for a favor. $!{yhe}'s kindly obliged," Eli explains, setting ${yhis} own wreath down on the table. Pretty white blooms arranged carefully, shot through with squat green vines. Some things, it appears, never change. "There were…things left unsaid. Before Aulain. I would say them now, if you're willing to hear."
        
        "And I'll watch over your fair establishment in the meantime," ${yhe} says. "A little bird told me that there's only one thing on the taps—I should be able to manage it."
    #"You're the only one to blame for that, you know."
        "Painfully aware," ${yusuha} agrees, sighing. "My master runs a tight ship, as you know. And things have certainly been eventful enough to keep plenty on my plate."
        
        "Well, thanks for taking the time to visit."
        
        "I'll do you one better," ${yusuha} says, grinning. "I'll take over the bar for you."
        
        You feel your brows knitting together. "What?"
        
        Eli draws ${ehim}self up beside ${yusuha}, then, offering you a small smile. "I asked ${yhim} for a favor," Eli explains. "There were…things left unsaid. Before Aulain. I would say them now, if you're willing to hear."
        
        "And I'll watch over your fair establishment in the meantime," ${yhe} says. "A little bird told me that there's only one thing on the taps—I should be able to manage it."
    #"Move out of the way, you're blocking my view of Eli."
        ${yusuha}'s jaw drops in mock offense. "That's a little harsh,
        *if (alias)
            ${fakename}.
        *else
            ${fname}.
        I daresay I'm every bit ${ehis} rival in looks. Not to mention I'm [i]infinitely[/i] better-dressed."
        
        Maren lets out a snort on the counter.
        
        "Something funny, old man?" ${yusuha} asks.
        
        "Ain't a fair fight, is all," he says, pointedly not looking at Eli. "Like getting into a brawl with a baby."
        
        "It's not so bad," Eli protests weakly, drawing ${ehim}self up beside ${yusuha}. $!{ehe} sets ${ehis} own wreath down on the table. Pretty white blooms arranged carefully, shot through with squat green vines. Some things, it appears, never change. 
        
        For ${yhis} part, ${yusuha} grins at Maren. "We will get along swimmingly, good sir."
        
        You pat Eli softly on the shoulder by way of consolation. "Can I get you both something to drink?"
        
        ${yusuha} shakes ${yhis} head. "Alas,
        *if (alias)
            ${fakename}.
        *else
            ${fname}.
        I come not as a patron."
        
        You tilt your head. "Then?"
        
        "As a barkeep," ${yusuha} says. "With your permission, of course."
        
        You blink at ${yhim}, confused, but it is Eli who rushes to answer. "I asked ${yhim} for a favor. $!{yhe}'s kindly obliged," ${ehe} explains. "There were…things left unsaid. Before Aulain. I would say them now, if you're willing to hear."
        
        "And I'll watch over your fair establishment in the meantime," ${yhe} says. "A little bird told me that there's only one thing on the taps—I should be able to manage the feat."

*choice
    #"You sure took your time, Eli."
        The older mage has the grace to look sheepish. "Sorry. Things have been hectic after Aulain, as you might imagine. And there was a lot of information to sift through, besides."
        
        You get the sense that ${ehe}'s not talking about Ralos and Altea's faction. It appears Eli didn't have the full picture of things whilst ${ehe} served under Tahlia. But that's not a conversation you can have out in the open like this. And so, ${yusuha}.
        
        "Very well," you say. "${yusuha}, you're sure you can hold down the fort?"
        
        The wind mage makes a point of saluting you. "You can count on me."
        
        The matter of your business safely settled, you nudge open the door behind the counter, motioning for Eli to follow as you slip into your tavern's back room.
    #"You're a bit overqualified for the role, ${yusuha}."
        "I could say the same about you," ${yusuha} points out. "It won't be for too long, at any rate." He squints at you and Eli both, then. "Or at least, I hope it won't."
        
        "I'm not sure what you're implying," you say opaquely, brushing ${yhim} off. "But thanks."
        
        The wind mage makes a point of saluting you. "Happy to help."
        
        The matter of your business safely settled, you nudge open the door behind the counter, motioning for Eli to follow as you slip into your tavern's back room.
    #"Did this have to happen while I'm on the clock?"
        *set noble %- 15
        "Ah, our master is the one to blame for that," ${yusuha} says, winking. Tahlia, then. "Eli's had it rough lately. Lots of things happened in the time ${ehe}'s been away, and there was a backlog of things no one could see to but ${ehim}. Note the past tense—${ehe} had been very motivated to see them through."
        
        You turn to look at Eli, sighing. "Don't let them push you around too much."
        
        "I wanted to help out," Eli admits sheepishly. "A lot of the work had to do with the refugees. I could meet with [i]her[/i] often besides—and I had no shortage of questions for her."
        
        "And they've been answered?"
        
        Eli nods in confirmation.
        
        "Very well," you say. "${yusuha}, you're sure you can hold down the fort?"
        
        The wind mage makes a point of saluting you. "You can count on me."
        
        The matter of your business safely settled, you nudge open the door behind the counter, motioning for Eli to follow as you slip into your tavern's back room.

*page_break

"Shut the door behind you," you say, making your way to the wooden counter towards the back of the living space. Eli obliges you and steps awkwardly into the room, taking a look around as he does. There's not much to see, alas. Only a small dining table and a simple kitchen, next to which is a door leading to the outhouse. A narrow stepladder is pressed up against the edge of the room, leading up to the second story, which contains your bedroom and an attic you use for storage. You motion for Eli to sit at the table, and ${ehe} does. In the meantime, you reach for a jar of leaves sitting by the windowsill. Once green, now yellowed by the sun.

You're pleased at the coloring, which signals that it's ready to brew. Yivari tea is a local specialty, and you luckily had the foresight of purchasing some before the rain grew intense enough to lay the uptown markets to rest. You plop them down into cups and steep them in water, using your magic to flash-heat the mixture. The bitter-edged taste of mana will linger in the resulting brew, but you find that it enhances the taste. You can only hope that Eli agrees.

"Thanks," Eli says as ${ehe} accepts the cup. The liquid steams as it meets Eli's mouth, though ${ehe} seems unbothered by the heat. "It's been a while since I've had yivari. It wasn't in season when I left Thulrum."

*choice
    #"They say it's an acquired taste, but I seem to have acquired it swiftly."
        "Doesn't come as a surprise," Eli says, grinning. "It's said that in Cavangen, they know yivari tea as the Witch's Brew, so called because it's a favorite among mages. Fitting, given that it's sourced from Arcadian lands."
        
        You note ${ehis} words with surprise. "Thulrum exports that far abroad?" Cavangen is on the far east of the Imperial continent, one of the few independent nations in that section of the world which still holds out against the Empire's aggression. To get there, merchants would have to cross the Imperial Ocean and traverse the whole length of the Imperial Continent—or go the other way risk braving the Sailgraves, with its foul weather and infestation of seadrakes.
        
        Eli nods in confirmation. "They do, if Myst is to be believed. They sell it at—and I'm quoting her on this—a disgusting premium. But they have no troubles finding buyers, it seems. I think the price might have added to the mystique."
        
        "I feel rather inspired," you say, chuckling. "I wonder how my clientele would react to a price hike."
        
        "Long as they don't catch wind it's me that slipped you the idea," Eli says.
        
        The conversation comes to a slow stop, then, and the purpose of ${ehis} visit—which had hung in the air like a shroud over your small talk—begins to make itself felt. The time is come, and from the look of ${ehim}, Eli knows it too.
        
        "${fname}…you're owed an explanation. You shared much with me when we reunited. What you'd been up to, your relationship with Arcadia, and Param before that. I would return the favor."
    #"You should probably let it cool a bit before drinking."
        Eli grins. "Access to healing arcana carries certain perks."
        
        "How excessive," you say, more surprised than chiding. You comb through your memories all the while—the Eli of the past had been somewhat put off by the thought of using Thaubal's gift to ${ehim}. $!{ehis} arcana hadn't imposed a grievous toll on ${ehim} the way yours did, but ${ehe} used it just as sparingly. That ${ehe} would now frivolously use it to drink ${ehis} tea before it properly cools almost beggars belief. "You seem to have grown into your powers," you note vaguely.
        
        Eli's smile turns lukewarm. "Mm. It was always difficult, knowing that this power came by way of [i]him[/i]," ${ehe} says, ${ehis} tone growing harsh momentarily. "But I can't deny that it's been useful. I've been able to do a lot of good—more than I would've with just a sword and some fighting words. So even after everything, I'm grateful that I have it."
        
        "I'm glad," you say, and mean it. Eli had nursed a hatred for Thaubal Altinier greater still than yours and Sister's, for ${ehe} had been the one forced to bury ${ehis} own kin. You had felt that hatred chafe and strain against ${ehis} gentle spirit over the years, witnessed the way it chewed ${ehim} up on the inside. If nothing else, it's good to know that ${ehe}'s found peace of mind.
        
        The conversation comes to a slow stop, then, and the purpose of ${ehis} visit—which had hung in the air like a shroud over your talk—begins to make itself felt. The time is come, and from the looks of ${ehim}, Eli knows it too.
        
        "${fname}…you're owed an explanation. You shared much with me when we reunited. What you'd been up to, your relationship with Arcadia, and Param before that. I would return the favor."
    #"Let's cut to the chase. You and I have much to discuss."
        Eli studies you for a moment, a wistful look on ${ehis} face. "To the chase, then," ${ehe} assents. "You shared much with me when we reunited. What you'd been up to, your relationship with Arcadia, and Param before that. I would return the favor."

$!{ehe} steeples ${ehis} hands over the cup, ${ehis} gaze expectant. The message is clear: whatever question you might have, ${ehe} will answer.

*temp eliexpocount 0
*temp elistayby false
*temp sincenight false
*label eliexpohub
*if (eliexpocount = 6)
    *goto eliexpodone
*else
    *goto eliexpo

*label eliexpo
*choice
    *disable_reuse #"Tell me everything that happened to you since that night."
        *set eliexpocount +1
        *set sincenight true
        "The night when I…" Eli trails off, and you meet ${ehis} hesitance with a nod. "The last thing I remember was you, standing in the light. I don't think you were running; I distinctly remember that I told you to." The @{evar man|woman} smiles fondly, shaking ${ehis} head. "Next thing I remember, I woke up in the Seat. Some two years had passed by then, and I found myself drafted into the [i]ashai's[/i] service. In that regard, my circumstances were quite similar to your current one."
        
        You study ${ehim} intently. "And you served her willingly?"
        
        Eli bobs ${ehis} head. "When she relaid her intentions for Thulrum to me, as well as the tasks she'd have me take on, I thought her goal a noble one. Something worthy of pursuing."
        
        You had suspected as much, in truth. The Eli you knew had been a gentle soul, someone who responded to emotional appeals with great dedication. Whatever else Tahlia is up to, it's undeniable that she's forging Thulrum into a sanctum for Arvanand's refuse, a fact she had no doubt weaponized to swiftly secure Eli's loyalty. But… "How much did you truly know? Of the scope of her operations."
        
        Eli glances up, looking as if ${ehe} had anticipated your question. "Not much at all, at least at the start. She brought me back for my arcana, and so I found myself stationed in sickbays and clinics. I was still young, then—fifteen, perhaps sixteen—and the [i]ashai[/i] kept me in the dark about most things. I was content with trusting she was a good person, in the beginning. And when her excesses began coming to light, I still thought her decisions had merit. She wasn't perfect, and she definitely wasn't pristine. But she has my respect—then, as well as now."
        
        You ponder that for a moment. "But you left her service, in the end."
        
        "I owed her a one-year tenure as she recovered from the [i]aresei[/i]. I told her I'd stay on longer than that, if she promised to locate your whereabouts in the meantime," ${ehe} confesses. "Thulrum's intelligence network spans all of Arvanand, and I thought they were bound to hear one thing or another if I stayed a few years. And when that failed to bear fruit, I decided to take matters into my own hands. Walk my own path out there, find whatever netters might be up to the job."
        *choice
            #I sigh fondly. "You should've focused on looking after yourself, you fool."
                *set reli %+ 8
                "I wasn't as selfless as you're making me out to be," Eli says sheepishly.
                *comment speaking of making out, eli...
                *comment i know u got it bad
                *comment kiss kiss fall in love
                
                Has ${ehe} already forgotten how ${ehe} ended up needing the [i]aresei[/i] to begin with? You have to fight to keep from rolling your eyes.
                
                Your effort must have shown on your face, for Eli is quick to clumsily clarify ${ehis} words. "I mean, my life was hardly wanting back then. The Church takes good care of its people," ${ehe} says. "I don't want you thinking I made some great sacrifice when it was just the decision that made sense at the time."
                
                "So living here was all that, and you still left it behind to look for me. From where I'm standing, that sure sounds like sacrifice."
                
                "I…"
                
                "Take credit for it. And then never do it again."
                
                "I can never win against you," Eli says, chuckling. "Still, I wish I were less zealous about it. Leaving Thulrum was a mistake. My contacts operated mostly in Salantira, while you resurfaced in the Parami court. The Seat caught wind of your whereabouts then, but [i]I[/i] was long gone. Slumming it up with the Order in Aulain."
                *goto eliexpohub
            #I grin at ${ehim}. "I almost feel sorry for hiding myself so well."
                *set charming %+ 15
                *set reli %+ 4
                "You ought to feel proud instead," Eli says, chuckling. "It's no small matter, to give the [i]ashai[/i] the slip."
                
                "Yes, well. I don't think I'd be able to repeat the feat," you say. "Still, it's a wonder that you kept up the search for so long. For all you know, I might have been across the Sailgraves by then, if not entirely…" You shake your head. "I expected you to keep an ear out, of course, but you went to rather extreme lengths."
                
                A thoughtful look enters Eli's face. "When I first awakened in the Seat, the last memory I had was of you. The anguish on your face, the terror we both felt," ${ehis} eyes flutter shut, jaw turning tense. "I will confess that my hope…waned, the more that time went by. But even if reunion was no longer a possibility, I at least wanted to know what became of you. No, I [i]had[/i] to know."
                
                *goto firmly
            #I knit my brows. "You didn't think that Tahlia would keep the information from you?"
                *set optimistic %- 15
                *set reli %+ 4
                Eli blinks at that. "To what end?"
                
                "You've been telling me that your search was what tethered you to the Church," you point out. "If Tahlia knew as much, then she had every cause to keep my whereabouts a mystery. You might leave her service, otherwise—whether that's because she had nothing left to offer, or because you'd leave Thulrum to…"
                
                "Be with you?" Eli cuts in, grinning.
                
                "I wouldn't phrase it quite like that," you mumble.
                
                "You wouldn't have been wrong if you did," ${ehe} says. "But I made no secret of considering leaving her service if nothing turned up. And she made no move to stop me as I left, besides making it clear that I would be missed in the Saber. So if anything, revealing your location to me then would've been beneficial for her. I would've felt so indebted…"
                
                "I suppose, given everything you went through to find me," you concede. "It's a wonder you kept up the search for so long. For all you know, I might have been across the Sailgraves by then, if not entirely…" You shake your head. "I I expected you to keep an ear out, of course, but you went to rather extreme lengths."
                
                A thoughtful look enters Eli's face. "When I first awakened in the Seat, the last memory I had was of you. The anguish on your face, the terror we both felt," ${ehis} eyes flutter shut, jaw turning tense. "I will confess that my hope…waned, the more that time went by. But even if reunion was no longer a possibility, I at least wanted to know what became of you. No, I [i]had[/i] to know."
                
                *goto firmly
            #I feel grateful, despite ${ehis} technical failure. "Good to know you were looking for me."
                *set reli %+ 8
                Eli blinks in disbelief. "Of course. How could that ever be in doubt?"
                
                "I know, I know," you say. "It's just—you had nothing to go off of, and for all you know I might have been across the Sailgraves by then, if not entirely…" You shake your head. "I expected you to keep an ear out, of course, but you went to rather extreme lengths."
                
                "When I first awakened in the Seat, the last memory I had was of you. The anguish on your face, the terror we both felt," ${ehe} says, jaw tense. "I will confess that my hope…waned, the more that time went by. But even if reunion was no longer a possibility, I at least wanted to know what became of you. No, I [i]had[/i] to know."
                
                *label firmly
                "Eli…thank you," you say, firmly. "I mean it."
                
                $!{ehis} smile is weak, almost guilty. "I wish I were less zealous about it, though," ${ehe} mourns. "Leaving Thulrum was a mistake. My contacts operated mostly in Salantira, while you resurfaced in the Parami court. The Seat caught wind of your whereabouts then, but [i]I[/i] was long gone. Slumming it up with the Order in Aulain."
                *goto eliexpohub
    *disable_reuse *if (sincenight) #"If you started as a healer, why did you end up joining the Saber?"
        *set eliexpocount +1
        "The Saber was in desperate want of one, especially in those early days. A healer, I mean," ${ehe} says. "Thulrum's position was a lot weaker then, and the missions more ambitious. ${yusuha} and ${falco} were still finding their footing as arcanists. The casualty rate was high, and more than a few left of their own accords. The Saber was operating below its ideal capacity—and the number of refugees coming to Thulrum was slowing to a trickle as a result. I knew something had to be done."
        
        "So you were eager to offer them your services."
        
        "I'll not deny it," Eli admits. "Though I wasn't a member back then, I still counted many among the Saber as friends. When some of them failed to come back from missions—having succumbed to their injuries, while I knew full well I had the means to heal them—the decision had been a simple one to make."
        *goto eliexpohub
    *disable_reuse *if (sincenight) #"You were aware that Tahlia worked with Mireil?"
        *set eliexpocount +1
        "I…had an inkling," Eli admits, not quite meeting your gaze. "I never saw them meeting in the flesh, but some of the intelligence the Saber came into, the deals the [i]ashai[/i] managed to secure…she would've had to have an ally in Salantira. Someone on a very high perch. And I know Mireil, how she operated—I could feel her at work, sometimes. But I judged that it would be better not to know for certain."
        
        "Why?"
        
        "Because I believed in Thulrum's cause—then, as I do now—and fought against anything that would make me falter in my commitment," ${ehe} confesses. "I was the city's best healer, and so held responsibility over many of the refugees who needed treatment. I would talk with them then, know the extent of their grief and pain, everything they had been subjected to. It's…a cruel world out there. The Parami and Salantir both hold no love for Arcadians, for all the latter's careful veneer of benevolence." $!{ehe} pauses, then, brown eyes darkened by somber recollection. "${fname}—have you ever held a baby in your arms, not yet out of her first year, but plague-scarred and maimed all the same? It…changes something within you. I'll not forget it for the rest of my days."
        *choice
            #"You should've still confronted Tahlia. You can't just close your eyes to the truth."
                "Perhaps you're right," Eli sighs. "Mireil was responsible for unspeakable things. Our tutor…"
                *choice
                    #"What she did to him was grotesque, inexcusable."
                        "He perished at her hands, his mind lost, his hands drenched in the blood of others. All so that she could seize a place by the Grand Duke's side," you say darkly. "You knew what she was capable of. You should have made certain she wasn't involved."
                        
                        "I was irresponsible," Eli admits. "I was in the thick of it, then. Many of the [i]ashai's[/i] gambits were yet to bear fruit, then, and so things were very different. The state the refugees were in as they arrived, what we were able to do for them…everything had been far from ideal. Very far."
                        
                        "So you just—what? Ignored one monster to stem the excesses of another?"
                        
                        "It had been too late for Sir Hevlin, but not for little Lira, who drew shaky breaths as she fought against moonvein. Not for Sabrim, who already had to bury two sons," ${ehe} says. "I made the choice I felt was right, ${fname}. And even now knowing everything, I would do it again."
                        *goto eliexpohub
                    #"Our [i]tutor[/i]? Eli,  I'm talking about [i]you[/i]."
                        *set reli %+ 5
                        Eli startles at your vehemence, looking as if ${ehe}'s only considered that for the first time. Jove, there should be a limit to one's selflessness. "Since evidently you need to be reminded, Eli, she all but took your life. She chased you down to the ends of Salantira, set her dogs on you, [i]forced you to cast that damn spell[/i]. You had every right to leave Thulrum to its fate, and damn the refugees for it. It would've only been self-defense. It would've been [i]just[/i]."
                        
                        Eli pauses for a moment, considering. And then, "I…don't think I could've done that," ${ehe} admits, eyes downcast. "I wouldn't have been able to live a peaceful life. They would've haunted my every waking moment, and my nightmares thereafter."
                        
                        You look at ${ehim} sharply. "And what Mireil did to you doesn't?"
                        
                        "I couldn't undo what had already happened. What she did will stay with me forever, but there was no changing that. It was too late," Eli says. "But it hadn't been too late for little Lira, who drew shaky breaths as she fought against moonvein. Not for Sabrim, who already had to bury two sons. I made the choice I felt was right, ${fname}. And even now knowing everything, I would do it again."
                        *goto eliexpohub
            #"I understand, Eli. Better than you know."
                It's impossible to not think of Merdel Village and the plague which nearly broke it, of pale blood dripping from desiccated limbs. The dead had to be carried out in wagons, and the gravesite spanned nearly a quarter of the village's perimeter. The air had been choked with the scent of death, and in moments of weakness it would come to you again. A specter ripped from your memories, come to haunt you once more.
                
                Eli's gaze is intent as it meets yours, but shifts down after a while, the healer's shoulders slumping. "I…knew that I wouldn't be able to live with myself. To abandon them to their fate, when I knew full well I could stem the tide of their suffering…it was out of the question," ${ehe} says weakly. "And so I avoided confirming my suspicions. I didn't want to resent my work, give any less than my best to the people who needed it. I let the matter rest, and even with hindsight, I would do so again." 
                *goto eliexpohub
            #"You were valuable to Tahlia; you could've bargained with her."
                "My position was not so powerful," Eli counters, grimacing. "I helped those few which managed to knock on Thulrum's gates in time, and I'm sure the [i]ashai[/i] appreciated it. But the plays she made spanned the whole continent, dethroned nobles and freed Arcadians in a single stroke. She cut the suffering off at the source. Were some to die within these walls, I'm sure she would mourn them. But you must know what she's like, ${fname}. She would never lose sight of the bigger picture."
                
                "It's not lining up," you say, sighing. "In one breath, you say that your presence here was vital, and so you couldn't afford to leave things behind. Next you're telling me you're so expendable that Tahlia wouldn't have given you the time of day." You cross your arms, staring ${ehim} down. "Either you're valuable or you're not. Choose one."
                
                "I was an important piece, but ultimately unneeded to win the game."
                
                "With how much you're talking down on yourself, it's no surprise Tahlia's walking all over you."
                
                "Perhaps it was a conscious effort, once. Making myself and my own concerns smaller, so that greater concerns could prevail," Eli admits with some discomfort. "I can't tell anymore, in truth. But I did know that whatever vendetta I held against Mireil doesn't measure up against the Arcadians' plight. What she did will stay with me forever, but there was no changing that. It was too late." Eli pauses and leans back on ${ehis} chair, mulling over ${ehis} words. "But it hadn't been too late for little Lira, who drew shaky breaths as she fought against moonvein. Not for Sabrim, who already had to bury two sons. I made the choice I felt was right, ${fname}. And even now knowing everything, I would do it again."
                *goto eliexpohub
    *disable_reuse #"Will you ally yourself with Thulrum now, after everything?"
        *set eliexpocount +1
        *set elistayby true
        "I'll follow where you go," Eli says, with the kind of certitude which implies ${ehe}'s thought it over. "It's been many years. I…want to make up for lost time, where I can. And I intend to make myself useful for Thulrum in the meantime. Though it was a winding path to get here, the [i]ashai[/i] was still responsible for our reunion. And her noble work for Thulrum continues. I would assist her in that."
        
        "Even understanding her history, the lengths she would go to for the sake of her goals."
        
        Eli exhales a long breath. "Her involvement with Mireil is over. For now, I am content with that," ${ehe} says. "I will be stationed in the city, mostly. When I leave with Nightsaber, it will only be with you—and as I understand it, you've been promised that you won't need to bloody your hands senselessly. Should that promise be betrayed, then I will join you in confronting the [i]ashai[/i]."
        
        "And after? What if I choose to leave Thulrum when my arrangement with Tahlia expires?" you ask, eyeing ${ehim} carefully. "What if I choose to go back to Param?"
        
        Eli's jaw tenses, but when ${ehe} speaks, it is with assertion. "Then I would go with you."
        *choice
            #"Do you think Tahlia will just see you off with well wishes and a smile?"
                Eli shrugs. "I have cause to believe as much. I served under her for a good chunk of my life, and I've always known her to be a woman of her word. She let me go without issue when I left the first time, though doubtless that introduced complications to her plans."
                
                "You left on your own to pursue some nebulous quest," you point out. "But this time you'd leave with me—another arcanist—possibly to become a problem for her later down the line. You don't think she'd be ruthless enough to put down a hound before it could bite her hand?"
                
                Eli appears thoughtful. "You…have a point. Still, she has always looked after members of the Saber, even those who had failed their duties or decided to leave the service. She understands that she asks much of its members, and is not without honor in the way she treats them," Eli says. "She is callous to her enemies, this much I will admit. But I would still leave with you, even if she tries to stop me."
                
                You sigh. "It could get dangerous."
                
                "Wouldn't be the first time," ${ehe} says, smiling as ${ehe}
                *if (hairlength = "bald")
                    places ${ehis} hand on  your head.
                *else
                    ruffles your hair.
                A gesture ${ehe}'d taken to doing when you were both under Thaubal Altinier's watch, meant to reassure you even in the face of the researcher's brutality. One that carried over to your stint running from Sister—and now, as a conflict threatening to swallow the continent whole simmers all around you. "I will do all I can to be of help to you. I can't say that I won't fail you again—such a promise would hold no weight, given how I've already broken it before—but I will do everything in my power to stay by your side. To the end this time, be it bitter or otherwise."
                *goto eliexpohub
            #"You're your own person, Eli. You ought to follow your own convictions."
                *set reli %+ 5
                "Then hear my convictions now," ${ehe} declares. "Nothing matters more to me than staying by your side. The time I spent without you, not knowing whether you were dead or alive, not being able to do anything about it—it was torturous. I never want to repeat feeling like that again, and I'm willing to do whatever it takes."
                
                You purse your lips, considering. "Did you not say that leaving Thulrum behind would be hard? That failing these refugees would haunt you?"
                
                "But I failed you first and foremost, didn't I?" ${ehe} reasons, shaking ${ehis} head all the while. "I promised to look after you, ${fname}, to make sure whatever torture you experienced under Thaubal would remain in his estate, buried there for eternity. But I failed to protect you from Mireil, even as I spent my life in the attempt. ${fname}, I forced you to watch as I died. I knew it was a cruel thing I was doing—and I did it anyway. I can only imagine the pain I caused you."
                
                You feel your breathing growing labored. "It was…a lot to take in."
                
                "And so, this," ${ehe} says, smiling as ${ehe}
                *if (hairlength = "bald")
                    places ${ehis} hand on your head.
                *else
                    ruffles your hair.
                A gesture ${ehe}'d taken to doing when you were both under Thaubal Altinier's watch, meant to reassure you even in the face of the researcher's brutality. One that carried over to your stint running from Sister—and now, as a conflict threatening to swallow the continent whole simmers all around you. "I will do all I can to be of help to you. I can't say that I won't fail you again—such a promise would hold no weight, given how I've already broken it before—but I will do everything in my power to stay by your side. To the end this time, be it bitter or otherwise."
                *goto eliexpohub
            #"Thank you, Eli. Know that I would do the same for you."
                *set reli %+ 12
                Eli beams at you. "Then we're in agreement. The most important thing is that we remain at each other's side, when all is said and done," Eli says. $!{ehe} leans back on the chair, then, shoulders slumped in relief. "I…I can't put into words how much this means to me, ${fname}. So many things have happened since we last met all those years ago, and I feared it was inevitable. That we would have changed enough to drift apart, even if we somehow managed to meet again."
                
                "You're a fool for thinking that. I've not forgotten everything you did for me, Eli—in Thaubal's mansion, in the Grand Duchy, and even in Aulain," you say. "You're not the only one willing to fight for this."
                
                "Then I should be glad that you're here to remind me," ${ehe} says, grinning. "Let's decide together, when the time comes. Neither of us have the full picture of things yet, and there's still the matter of your deal with Tahlia. It wouldn't be a bad idea to observe things for the time being, see where the chips fall before we come to a proper decision."
                
                A sound plan, all told. "Alright, Eli," you say. "Let's do that."
                
                Eli holds your gaze, for a long moment, and there's such a fondness in ${ehis} eyes that it threatens to bowl you over. "${fname}…" ${ehe} says, and you see ${ehis} lips part for a moment, though ${ehe} quickly reins ${ehim}self in. "I'm glad. I'll do everything in my power to stay by your side. To the end, this time."
                
                "I'll hold you to that," you sigh, noting the way some of that same fondness has crept into your tone.
                *goto eliexpohub
            #"It's good to know that you're in my corner."
                *set reli %+ 5
                Eli's smile is warm, true, but you don't miss the flicker of concern in ${ehis} eyes. You don't doubt that ${ehe} means what ${ehe} says, but at the same time it's clear ${ehe} maintains ${ehis} own preferences.
                
                Well, time enough to cross that bridge later.
                
                "So long as you don't doubt that," Eli says, smiling as ${ehe}
                *if (hairlength = "bald")
                    places ${ehis} hand on your head.
                *else
                    ruffles your hair.
                A gesture ${ehe}'d taken to doing when you were both under Thaubal Altinier's watch, meant to reassure you even in the face of the researcher's brutality. One that carried over to your stint running from Sister—and now, as a conflict threatening to swallow the continent whole simmers all around you. "I will do all I can to be of help to you. I can't say that I won't fail you again—such a promise would hold no weight, given how I've already broken it before—but I will do everything in my power to stay by your side. To the end this time, be it bitter or otherwise."
                *goto eliexpohub
            #"It's hypothetical, to be clear. I share your opinions on Tahlia and Thulrum at large."
                *set reli %+ 8
                Eli sits up straighter in ${ehis} chair, ${ehis} eyes wide. "Truly?"
                
                "Why do you look so surprised?" you ask, knitting your brows. "It's as if you don't think her cause is worth believing in."
                
                "Come on, it's not like that," Eli says. "It's just—I know she can be…a lot. I held my own reservations for a while, even after arriving at the conclusion that something must be done for Arcadians. Her methods aren't exactly easy to swallow…"
                
                "It's starting to sound like you don't [i]want[/i] me to have a high opinion of her."
                
                Eli sighs at ${ehim}self. "I [i]am[/i] tripping over my own words, aren't I?" ${ehe} says. "I guess what I'm trying to say is…I'm glad. That you're able to see past the rough surface of Thulrum's deeds, and see what lies at its heart. While you're still beholden to Tahlia, I'll assist in Thulrum's efforts, as I had done before I left. As for what comes next…" Eli reaches over and
                *if (hairlength = "bald")
                    places ${ehis} hand on your head.
                *else
                    ruffles your hair.
                A gesture ${ehe}'d taken to doing when you were both under Thaubal Altinier's watch, meant to reassure you even in the face of the researcher's brutality. One that carried over to your stint running from Sister—and now, as a conflict threatening to swallow the continent whole simmers all around you. "I'd like it if we could decide together. But if not, know that I will do everything in my power to stay by your side. To the end, this time."
                *goto eliexpohub
            *selectable_if (elihired = false) #"You presume overmuch, thinking I'd want you along at all."
                *set reli %- 12
                *set elichilly true
                Eli flinches, looking as if you've pressed a dagger to ${ehis} heart. "I see," ${ehe} says, after a while. "Sorry for overstepping. I thought…no, it doesn't matter what I thought."
                
                Your gaze on ${ehim} is steely, and you make sure ${ehe} doesn't miss it. "You'll let me have that much, I take it."
                
                "Of course. I won't stand in your way," ${ehe} says. "But while you're here, at least, I'd like to be of help to you."
                
                You sigh, leaning back in your chair. You suppose that if you're stuck in "And after?"
                
                "I'm not sure," Eli confesses. "I suppose it depends on the path you take. If you intend to come to blows with Thulrum, then I'd remove myself from the picture. Perhaps travel back up to Aulain. Perhaps overseas. Somewhere beyond the [i]ashai's[/i] reach. Otherwise, I may stick around here, help the Church out for a few more years." The healer exhales a long breath, valiantly schooling ${ehis} dismay into a smile. "I'll use that time to figure things out. You…do what you have to do."
                *goto eliexpohub
    *disable_reuse *if (elistayby) #"If what I want is vengeance. Will you stop me?"
        *set eliexpocount +1
        Eli studies you with concern. "Vengeance?"
        
        "I know you heard me the first time," you sigh. "Plenty of wrong has been done unto me. If what I seek is to make them pay for the mistake, will you stand in my way?"
        
        *if (elichilly = false)
            "…No," Eli admits, with some difficulty. You know ${ehim} well enough to know that ${ehe}'s telling the truth, however reluctantly. And then, with a steely resolve that surprises you, ${ehe} meets your gaze. "But I would stand by your side."
        
        
            You feel a stab of wistfulness at ${ehis} answer, a feeling retrieved from the faded memories. Promising assistance to another in their blood quest is no light thing, but Eli appears ready to stand beside you, no matter what. And really, you should have seen it coming. Did ${ehe} not lay down ${ehis} life so that you could keep yours? The healer has changed in many small ways, and there are things about ${ehim} that you're still relearning. But ${ehe}'s not changed so much that you need reinspect ${ehis} integrity, ${ehis} [i]loyalty[/i]. Indeed, out of everyone you've ever known, Eli perhaps deserves that the least.
        
            $!{ehis} declaration hangs heavy in the room. $!{ehis} gaze on you does not break, and neither does ${ehis} evident resolve.
        
            "…A discussion for another day," is what you end up saying. It's early days yet, when all is said and done. There are many variables you have yet to glean the true nature of, and so lofty a goal requires careful planning at every step. For now, it's good enough that you can count on Eli among your allies. $!{ehis} healing is invaluable in a battle of attrition, and given your numerical disadvantage, such a boon becomes all but necessary. And that's to make no mention of ${ehis} skills as a @{evar swordsman|swordswoman}, which saw ${ehim} favored enough by the knights that ${ehe}'d have been a shoe-in for the Salantir Royal Knights.
            
            But that's for future ${fname} to consider. For the time being, you can be content that the option has gained some true viability.
            
            Relief and concern wars on Eli's features at your words, though in the end ${ehe} holds on to ${ehis} silence. Content to let the matter be tabled.
            *goto eliexpohub
        *else
            "…No," Eli admits, ${ehis} gaze downcast. "I would remove myself from the picture, as best as I can."
            
            You feel the grating difficulty with which ${ehe} pushes out the words, and know that ${ehe}'d rather say something else—[i]anything[/i] else. But your words had been clear, and they had cut deep. You have no place for ${ehim} in your plans. Where you are concerned, Eli is the greatest meddler and worrywart there is, and it's clearly taking a lot out of ${ehim} to fight ${ehis} instincts like this.
            
            If nothing else, ${ehis} restraint speaks well of ${ehim}.
            
            "I will hold you to that," you declare.
            
            "If you change your mind on anything," Eli says quickly, before the matter could be closed, "you'll tell me?"
            
            You ponder the matter for a moment. Eli is a more valuable resource than you care to admit. $!{ehis} healing is invaluable in a battle of attrition, and given your numerical disadvantage, such a boon becomes all but necessary. And that's to make no mention of ${ehis} skills as a @{evar swordsman|swordswoman}, which saw ${ehim} favored enough by the knights that ${ehe}'d have been a shoe-in for the Salantir Royal Knights.
            
            "Perhaps," is what you settle on, in the end. And though Eli doesn't quite look mollified, that much is enough to quiet any further concern. You'll have to take your victories where you can get them.
            *goto eliexpohub
    *disable_reuse #"What do you plan on doing now?"
        *set eliexpocount +1
        "Thulrum has a number of health facilities throughout the city. My services so a healer will be availed to them on request," Eli says. "It's the same arrangement I had with the Church prior to my leaving, though as I understand it, my workload will be far less now. The [i]ashai[/i] has managed to recruit a number of proper theurges into the Church's ranks, and I hear Specter has gotten a lot better in the time I've been gone. ${yusuha} will be around to help out, too…"
        
        "I've seen a lot of alchemist ateliers down Thulrum's main street," you point out. "Three coppers say that the Church provides them their primary custom."
        
        "I'm certain it does. I've been to their storehouse recently—it's filled to the brim with all sorts of goods. Small wonder the [i]ashai[/i] was so generous with Aulain's aid package," ${ehe} muses. "Regardless, that leaves me with plenty of free time, especially now that a lot of the loose ends I left behind has been tied up."
        
        "Got anything to fill it up?"
        
        "Oh, this and that."
        
        *choice
            *selectable_if (elichilly = false) #"Then come work for me instead."
                Eli's eyes widen—clearly, the thought had never occurred to ${ehim}. "Yeah?" ${ehe} asks, a smile quirking on ${ehis} lips. "You'll have me?"
                
                "It's getting a bit too busy around here for my tastes.
                *if (thulshopvar = 1)
                    As it turns out, bottom-of-the-barrel ale goes over well with the taste buds of laborers and refugees alike," you reply. "'Course, feel free to say no. I can't offer more than standard wages with the profits I'm turning, and I'm sure someone of your talents would be wanted—"
                    
                    *label illdoit
                    Eli chuckles, placing a hand over yours. "I'll do it," ${ehe} says. "Even at a copper a month, I'll do it."
                    
                    "Careful what you wish for," you grumble, though Eli is too preoccupied with ${ehis} stupid grin to properly hear you.
                    
                    "It'll be a few days until I can start," Eli says, finally regaining ${ehis} faculties. "I've promises to keep in the meantime, but I'll keep my schedule free thereafter. Well, as free as it can get."
                    
                    "Do that, then. I can hold down the fort in the meantime."
                    *goto eliexpohub
                *elseif (thulshopvar = 2)
                    Every alchemist and their mother is knocking on my doors these days, asking if I've got this and that in store. And maybe I would, if I didn't have to spend half the day rubbing their spittle from my face," you reply. "'So yes, your help would be welcome, but feel free to say no. I can promise decent wages, but I'm sure someone of your talents would be wanted—"
                    
                    *goto illdoit
                *else
                    Who knew that a curio shop in the middle of nowhere would attract such custom as to rival a main street atelier?" You sigh, massaging your temples. "I need to keep up appearances so that my true business doesn't get disturbed, but it's getting difficult to juggle things. So yes, your help would be welcome, but feel free to say no. I can promise decent wages, but I'm sure someone of your talents would be wanted—"
                    
                    *goto illdoit
            #"Care to explain what that means?"
                "Have you been to the Common House yet? There's an adventurer's guild based out of there," Eli says. "Technically affiliated with the Church, but pretty much independent in practice."
                
                *label takeupquest
                "You plan on taking up quests with them?" The work would suit ${ehim} well, you have to admit. Eli's proficiency with swords and healing both means that ${ehe}'s as self-sufficient a fighter as they come. Solo adventurers can bleed their pockets dry off of healing potions and the like, but one of Eli's talents would have no need of such concerns.
                
                "Some simple ones I can turn in within a couple of days or so. Nothing that takes me beyond Thulrum's immediate environs," Eli replies. "I can't be out and about too much in case the Saber has need of me. And besides…"
                
                You meet ${ehis} gaze evenly. "What?"
                
                "I have my own reasons for wanting to stick around in Thulrum," ${ehe} says.
                *if (thulshopvar = 1)
                    "Maybe I'll stop for a mug on my way back. I'm bound to work up a thirst after a full day's work."
                *elseif (thulshopvar = 2)
                    "Maybe I'll run into some useful herbs while I'm out there. Might know a shopkeep or two who'd be in the market for them."
                *else
                    "The woods can get pretty dangerous, this time of year. Might be that I'm in the market for a combat artifact or two—luckily, I happen to know someone who has it in stock."
                
                "That right?" you say, quirking your brows. "Hope you're not expecting a discount."
                
                "Wouldn't dream of it."
                *goto eliexpohub
            #"Alright, Eli. You and your secrets."
                "Secrets? Hardly," Eli chuckles. "I just don't want to bore you. It's nothing particularly exciting."
                
                "Yeah? I'll be the judge of that."
                
                "Alright, ${fname}," Eli says, looking amused. "Have you been to the Common House yet? There's an adventurer guild based out of there. Technically affiliated with the Church, but pretty much independent in practice."
                
                *goto takeupquest

*label eliexpodone
*page_break

"Well, I suppose that settles that," you say, stretching as you rise out of your chair. Your cup still sits half-full, with you only having managed distracted sips as the conversation went on. No matter—a full plant still sits by your windowsill, so you've stock enough for many cups yet. "I should get back to my shop before ${yusuha} kicks up a fuss about having been worked to the bone." Never mind that ${yhe} all but forced ${yhim}self into the role, you wryly think.

"That's a good idea, I think,"
*if elichilly
    Eli says, valiantly managing a small smile. It's clear the conversation's left somewhat of a foul taste in ${ehis} mouth, but ${ehe} seems intent on keeping up this veneer of easy friendship. If nothing else, you have to admit that ${ehe}'s dedicated.
    
    A cold draft enters the room as Eli swings the shop door open, straight-backed in a way that speaks of forced composure. $!{ehe} is scarcely out the door before ${yusuha} whisks ${ehim} away, recruiting ${ehim} to work the counter; one of their limbs bangs against the door in the scuffle, edging it to a gentle shut.
    
    Leaving you alone to your thoughts. Specifically, your thoughts about Eli.
    
    *comment housekeeping: see author's note below
    (Author's Note: The following section contains choices intended to appear for when Eli has not been rebuffed by the mage. In the interest of allowing for more story progression to be included, the other version of the scene will be completed in an upcoming housekeeping update.
    *goto postdiscourse
*else
    Eli says, an easy smile on ${ehis} lips as ${ehe} follows you to rise. $!{ehe} drains ${ehis} cup before going, and you feel ${ehis} eyes lingering on you all the while. Simple affection, unburdened with some grand design for which you serve as a moving part. A more welcome change than you can rightly express.
    
    A cold draft enters the room as Eli swings the shop door open, posture easy and confident, as if the weight of the world has been lifted from ${ehis} shoulders. $!{ehe} is scarcely out the door before ${yusuha} whisks ${ehim} away, recruiting ${ehim} to work the counter; one of their limbs bangs against the door in the scuffle, edging it to a gentle shut.
    
    Leaving you alone to your thoughts. Specifically, your thoughts about Eli.
    
    *label postdiscourse
    *choice
        #It really is a relief. To have someone who'd have my back no matter what.
            Tahlia has granted you a great many amenities in the hopes of securing your loyalty—enough for you to forget, however occasionally, what it is you've gotten yourself into. Beyond the quaint shop you've managed to set up, beyond the busy, peaceful streets of bustling Thulrum, the Seat rises in jagged spires like a skyward claw, and within it brews a conspiracy which threatens to swallow Arvanand whole. Tahlia's designs are as grand as they are vicious, and you know she has a place carved out for you. She withholds the full measure of her intentions now, is content to give reasonable leeways and make kindly promises, but time will tell whether the fate she has in mind for you is half as gentle.
            
            Perhaps rightfully, the priestess inspires in her people a loyalty so fervent so as to put Parami knights to shame. And so should she brand you an enemy or a threat, the procession of smiling faces you've seen in the past month may yet turn sour. You stand among allies, for the time being, but also would-be enemies—and for all of Thulrum this holds true, save for Eli.
            
            Steadfast, reliable Eli, who has proven ${ehim}self a worthwhile friend and confidant time and time again.
            
            Given the turmoil you can feel simmering underneath Arvanand's surface, tense as a tiger about to pounce, you need as many allies as you can get. And though at present that's in no short supply, having one who would stay beside, you come hell or high water—least of all an arcanist and @{evar swordsman|swordswoman}  of Eli's caliber—is a greater triumph than you had dared hope for.
            
            With vivid relief flooding your heart, you follow in Eli's wake and step through the door, greeting the shop front beyond with renewed resolve.
        #Gods preserve me. I think I have a crush on ${ehim}.
            *set eliinterest true
            In the silence of the room, the beat of your heart is like thunder in your ears. The heat you've been fighting finally rushes to your cheeks, with such ferocity so as to bowl you over the table. You press your hands against your face as the realization settles, trying not to think of the way it's warm to the touch.
            
            When did it begin? Just now? $!{ehe} declared that ${ehe}'d do anything to stay by your side, and really, that's the kind of sentiment that's liable to sweep anyone off their feet. But it matters that it's [i]${ehim}[/i], doesn't it? Lends credence to ${ehis} words, because ${ehe} really [i]has[/i] made good on ${ehis} words. Except for the unfortunate incident of ${ehis} death—and really, it wouldn't be fair to pin that on ${ehim}. Least of all when ${ehe} did it to save you.
            
            So ${ehe}'s been by your side all along, when circumstances permitted. What changed? Why now? Why is it that when you're finally able to settle into a comfortable, easy rhythm of friendship that this new feeling arises, threatening to throw a wrench into the one good thing you have going on?
            
            You ponder the question for a while, and find that no answers are forthcoming from the tangled mess you call a heart. Just pure, unadulterated affection, if underpinned by a reasonable current of panic.
            
            *label romconflictscene1
            *if (leonrom)
                *set romconflictscene true
                And like a river branching off into tributaries, your panic swells and shoots in a hundred different directions. And among all the complications, one rises taller than the rest: what then becomes of you and Leon? You had made grand declarations for one another, and meant them, too. Convinced yourself that your love would persevere, through the war, through the crowning, through it all.
                
                And then your dagger found its way to the saintess's heart, and Leon all but fastened you to the pyre. And who knows? He may well have taken a new lover since your passing. He's a handsome man, and the people surely clamor for
                *if (gender = "female")
                    a queen.
                *else
                    a consort.
                Much as the thought puts a foul taste in your mouth, you can't discard the possibility.
                
                Everything about the situation points to the conclusion. You do not owe him your loyalty, and certainly not your love.
                *choice
                    #And so I give him neither. He is dead to me.
                        *set noble %- 15
                        *set leondeadtome true
                        *set leonoldflame true
                        And really, what else is there to say? Even if your paths were to one day cross again, Leon would be a fool to assume that your love still burns bright for him, the way that it once did. Whatever traces of affection you still held for him, the pyre has long reduced to ashes. He must expect as much, and so your conscience is clear. You doubt he can say the same for himself.
                        
                        You smile wryly into your cup. They had hailed him as the Sun King, towards the end, held him up as a symbol of Param's restored glory. And he had taken on the mantle with such certitude, such dignity, that everything else fell by the wayside. His love for you had been true—of that, you have no doubt—but he loves his kingdom most of all. And you had burned for it. You will never forget that.
                        
                        Should you have seen it coming? Perhaps. Ante made no secret of her suspicions, and neither did Julius before her. Living as he did in his brother's towering shadow, Leon was bound to have been affected, one way or another. But if he ever showed the signs, you were blind to them. Such is the power of love, that it managed to reduce you, a perennial survivor—and an archmage at that—into a doting, babbling mess.
                        
                        And here you are again. Making the same mistake, leaping headfirst into the same mess.
                    #He is a traitor and a fool. And I love him, despite everything.
                        *set noble %- 15
                        *set leonunforgivenlove true
                        *set leontorch true
                        You stare sullenly at the half-full cup in front of you, as if it were personally responsible for your foolishness. Elsewhere on this blasted continent, Leon must be preening over his court of sycophants and hangers-on, acting every bit the part of a perfect king. He could do that, was always well-suited to the role. He had charisma in spades, a disarming smile, and looks which bordered on unfair. You've seen for yourself the effect he had on people, the way he could uplift spirits long-broken, stoke a fire in the hearts of those who'd given up. He is, in the end, a hero. The fact that he ordered you to the pyre does little to change that.
                        
                        You smile wryly into your cup. The effect he had on people…who are you kidding? The biggest victim of all is [i]you[/i]. You had fallen for his easy charm, his righteous spirit. You gave it all for your cause, withered daily under the strain of your powers, all so that his nation could be saved, and he could sit upon its throne. He had all but spat in the face of your sacrifice, and still you believe him a good person, underneath it all. His betrayal cuts deep, stings even now, but your love for him carries on. Unerring, unbending.
                        
                        Until now.
                    #All is forgiven, and I know that my love for him persists.
                        *set leonforgivelove true
                        *set noble %+ 15
                        *set leontorch true
                        As much as it pains you to admit, Leon made the only choice he could, in the end. His was a war-torn kingdom smarting from a gruesome war, brought about by a wicked witch—one whom you had called Sister, and whose powers echo your own. And before he could so much as solidify his rule and weave together Param's fractured power, you planted a dagger in the heart of the saintess, thereby making an enemy of the strongest player in his court. The Jovian Church, whose demand for your head had been so zealous that you'd heard about it, all the way down in your dungeon cell.
                        
                        The war was scarcely ended, and Leon was once more staring a civil war in the face. Coupled with the suspicions Ante had been feeding him over the years, the way they echoed Julius's sentiments before her…the pyre was the only possible conclusion.
                        
                        The eventuality was so apparent that it seems foolish to hold a grudge over it. It was between you or the lives of countless Parami—you can hardly blame him for the choice he made.
                        
                        And…perhaps it's wishful thinking, but you cannot imagine that Leon is without remorse, after everything is said and done. You've been christened as the Hero of Sienan, doubtless with the approval of the crown and Church both—pointing to the fact that everything had been discovered, your innocence proven. And despite it all, you know for certain that his love for you was true. Would it be presumptuous to think he's currently in ruins? Mourning the way everything had turned out, the fact that he all but killed you with his own hands?
                        
                        You shake your head; you're getting ahead of yourself. There's no use mulling hypotheticals about a king half a continent away, when you have your own problems in the here and now. Problems like…
                    #I forgive him, but can do no more. What we had between us is over.
                        *set leondeadtome true
                        *set noble %+ 15
                        *set leonoldflame true
                        You consider the moments you spent fighting alongside him, and those somber moments in the war-tents where you were each other's only comforts. You think of his easy smile, so radiant so as to banish your worries. His righteous spirit, the figure he cuts as he leads the march to Sienan…it's a small wonder that you fell as hard as you did. You nearly chuckle with amusement at your naivete, at the fact that you had envisioned a happy life together, stretching far into the nebulous horizon. Ignorant to the twisting of your stars, you had loved him with all your heart.
                        
                        And you [i]did[/i] love him; it would be a farce to pretend otherwise. But to continue to do so after he all but fastened you to the pyre is a level of foolishness you cannot commit yourself to. What sweet promises you made to him were true, when they first left your lips. But they burned in the fire with you, and his was the command which saw it lit. The dishonor is his. The [i]betrayal[/i] is his.
                        
                        You can forgive him his transgression—that part is easy. You can understand the circumstances of a man caught between a rock and a hard place. Someone who had to tend to the fragile balance of power in a newly-reforged Param couldn't afford to show mercy to a saintess-killer. Balanced on the scales were your life against that of countless Parami, who stood to bear the costs of civil war before the ink dried on the Salantir treaty.
                        
                        As a king, he obeyed his rationale. And as one scarred by fate's cruel hand, you must now obey yours.
                        
                        [i]Easier said than done,[/i] you wryly think, glancing up at the door Eli went through. You're poised to make it again, aren't you? The same misstep, the same breathless fall. What lies in wait for you at the bottom of the cliff? Have you even enough courage to make the leap?
                        
                        The healer's smile surfaces once more in your mind, and you groan into your hands. May Jove take you. And Isha too, if she has any sense.
                        *goto sitwhile
            *elseif (ilyarom)
                *set romconflictscene true
                And like a river branching off into tributaries, your panic swells and shoots in a hundred different directions. And among all the complications, one rises taller than the rest: what then becomes of you and Ilya? You had made grand declarations for one another, and meant them, too. Convinced yourself that your love would persevere, through the war, through her anointment as saintess, through it all.
                
                And then your dagger found its way to her mentor's heart.
                
                She had believed in your innocence to the bitter end, but ultimately she was a lone voice in a Param which called for your blood, powerless to stop Church and crown both from marching you to the pyre. She had promised you forever, but forever had perished within the flames. There was no use pining for a dead @{pronvar man—and|woman—and|mage—and} neither would you have wanted her to—but none would know that better than Ilya. Practical, sensible Ilya, who tempered Leon's foolhardy idealism with a steady hand. So infallible to the sway of emotions, but for one pivotal, precious moment.
                
                You sigh tiredly, fighting the memory of her face in the wan dungeon light. You cannot linger too much on the memory, lest it corrupt your way forward.
                
                Think. A woman of her beauty and stature would have had no shortage of courtship offers, you wryly think. How long was it before the court judged her mourning over, before the letters pounced on her in droves, like a landslide come unstuck?
                
                How long until she properly considered them?
                
                And how wretched would it be if you came back from the dead, appeared on her doorstep, and demanded her drop everything to love you once more?
                *choice
                    #What we had is over. It's better for us both to walk away from it.
                        *set ilyaover true
                        *set ilyaoldflame true
                        Ilya may well have built a new life for herself after your passing. You know well her family's situation, and the devotion with which she cares for them. Even with the position of saintess safely secured, she will be eager to seize every advantage she could for her siblings, do whatever it takes to allay her parents' fears. She carries all her family's burdens on her shoulders, and with it now the weight of her grief. For you. For the @{pronvar man|woman|mage} who had told her to leave @{pronvar him|her lover|them} for dead.
                        
                        You refuse to interfere in her life. Not now, after everything. You don't doubt that she loved you, that she grieved you; but equally, you don't doubt that she's managed to find steady ground once more, a plateau from which to build her life anew. You would not stand in her way, throw a wrench into her plans. You are dead to her, and as much as it pains you to admit, that may be for the best.
                        
                        The crossing of your stars have morphed, twisted into something irreparable. She is strong enough to survive the violent whims of her heart, and so you too must be strong enough to survive yours.
                        
                        Survive yours…
                        
                        Eli's smile surfaces once more in your mind, and you groan into your hands. Have you always been so crude? So eager to chase after what affection is thrown your way, even though the scars of your heart are long from healing?
                        
                        May Jove take you. And Isha too, if she has any sense.
                    #I will not presume her thoughts without seeing things for myself.
                        *set ilyawaitsee true
                        *set ilyatorch true
                        Ilya had fought for your freedom even with the apparent undeniability of your crime, carried her faith through even as the Church she serves called for your death. Even as she beheld you in the dungeon, heard no attempt from you to absolve yourself, she still fought for your escape. Fought for a future in which all truths could be laid bare, no matter how long it might take. She was willing to wait for you, so that you can tell your side of the story. Unburdened by Sister's curse, though she hadn't known it then.
                        
                        It feels only proper, then, to extend her that same courtesy. Ilya may well have built a new life for herself, perhaps betrothed to some eligible bachelor or other. You've no doubt she has the presence of mind to see it through, even as you knew that her love for you had been true. But even if seeing her in such a state—seeing her smiling in the arms of another—will only break your heart anew, you feel you still owe it to her. To see what's become of your love for each other, and whether a path forward—together—yet exists.
                        
                        The crossing of your stars have twisted, but things may yet be put to rights. The flame you carry for her yet endures, in spite of all the complications…
                        
                        Complications…
                        
                        Eli's smile surfaces once more in your mind, and you groan into your hands. Have you always been so crude? So eager to chase after what affection is thrown your way, even though the scars of your heart are long from healing?
                        
                        May Jove take you. And Isha too, if she has any sense.
                    #What we had was true, and nothing will not stand in our way.
                        *set ilyalove true
                        *set ilyatorch true
                        You remember with vivid clarity the days you spent in that harrowing war, where you unraveled daily and she rushed to heal you, stitch together all your broken pieces with her gentle touch. You remember the sweet whispers exchanged, on the night of your departure; the anguish on her face when you returned a criminal, a villain, bound by magicked chains in the depths of Param's dungeons. How she fought to free you nevertheless, betting everything she's built for herself in the meantime, because in the end she had [i]faith[/i]. In endless amounts, [i]foolish[/i] amounts, for you, and for the love that you shared.
                        
                        To think that her feelings may have changed in the span of a year would be a disservice to her. An assassination of her character, the fortitude with which her affection endures. You have never known her to be a fickle woman; hers was always a grounded, steady heart, one owed that selfsame faith that she so freely gave.
                        
                        Were that your own heart was so honorable.
                        
                        Eli's smile surfaces once more in your mind, and you groan into your hands. Have you always been so crude? So eager to chase after what affection is thrown your way, even though the scars of your heart are long from healing?
                        
                        May Jove take you. And Isha too, if she has any sense.
                        
            *label sitwhile
            You sit there a while longer, willing for your traitorous heart to settle down, before plastering what you hope might pass as composure on your face. The day's great tragedy is that you still have a shop to run, and a great many hours lie between you and closing time. You suppose you'll have to see if you can make it there in one piece, or unravel in the trying.
            
            You steel your nerves as you step to the door, mustering more courage than you've ever had to before as you greet the shop front beyond.
        #I always knew I felt this way, but damn it, it's gotten [i]bad[/i].
            *set eliinterest true
            Thinking back on it, it would be stranger if you [i]hadn't[/i] developed feelings for ${ehim}. $!{ehe} had been a steadying presence for much of your life, and when all is said and done, the night of ${ehis} sacrifice was likely not the first time ${ehe} saved your life. $!{ehe} had offered comfort and healing both as you withered under Thaubal's scalpel again and again, tempered the worst of Sister's excesses as you fought to carve a place for yourselves in the Grand Duchy. $!{ehe} had been reliable, kind, and stronger than you could imagine yourself being. Unwittingly, ${ehe} had left a trail of broken hearts in and around the Grand Duke's castle, and time was that you counted yours among them.
            
            Why did you never act on your feelings, in the end? Was it the fear of ruining your comfortable friendship, the steady dynamics you had with ${ehim} and Sister? Was it the fear that ${ehe} would rebuff you with an awkward smile and mumbled apologies, the way ${ehe} did to squires and training maids alike?
            
            You suppose it doesn't matter. What feelings you had for him had long since been drowned out by your grief, by the pained whispers of Eli's specter as ${ehe} appeared in your nightmares. You thought yourself free of this torturous affection, when in fact it had simply been biding its time. And now that the impossible has happened—that Eli has come back from beyond the veil, ${ehis} eyes as kind as you remember, ${ehis} presence as steady—you find yourself pulled back into the field of ${ehis} gravity.
            
            And oh, how it pulls. The warmth you feel blossoming in your chest is vivid enough to [i]hurt[/i], to sear your flesh red and set your ribs to brittling. You can't even pretend at this point; what you feel for ${ehim} is pure, unadulterated affection, if underpinned by a reasonable current of panic.
            *goto romconflictscene1
        #I'm not sure how I feel about ${ehim} yet. I'll have to see more.
            *set optimistic %- 15
            In many ways, Eli is just as you remember ${ehim}—solid, steadfast, and kind to a fault. You've no doubt that ${ehis} words to you are sincere, that ${ehe}'s willing to stay by your side even if it means leaving everything ${ehe}'s been standing for behind. But for all ${ehis} loyalty, Eli's sense of righteousness is more stubborn and demanding than ${ehe}'d readily admit. You know ${ehe} will be tortured if forced to lift ${ehis} blade against Arcadians, if faced with the need to work against their interests. That necessarily translates to a certain degree of loyalty to Tahlia; and though for the time being it appears pale compared to ${ehis} devotion to you, only time can tell whether ${ehis} heart's grown fickle in the period you've been apart.
            
            You heave a sigh, forcibly laying rest to your harsh-edged suspicions for the time being. Things are not so dire that you need to look for enemies where professed allies stand. Many months yet remain before your arrangement with Tahlia expires, and you can use that time to gain the full measure of Eli. A friend, a savior, a @{evar man|woman} whose fate has grown so twisted that ${ehe} may yet become a foe.
            
            Given the turmoil you can feel simmering underneath Arvanand's surface, tense as a tiger about to pounce, you have no shortage of would-be enemies. You can only hope that Eli's words prove true—that you may once more rely on ${ehim}, come hell or high water.
            
            Burying your worries with a mask of quiet composure, you follow in Eli's wake and step through the door, greeting the shop front beyond with resolve.

*page_break

The business day draws to a close some five hours later, and the last of your customers unwillingly trudge out the door, their lips still wet with beer-foam. ${yusuha} wears a smile which tenses at the edges, and even from a distance, you can spot ${yhis} brows twitching.

"Please come back again," ${yhe} grates out, before firmly shutting the door, pressing ${yhis} back against it, and sinking slowly to the floor.

*if (eliinterest)
    "You might not be cut out for this, ${yusuha}," Eli says from the bar counter, where ${ehe}'s wiping down mugs of ale. $!{ehe} has a leather apron on over ${ehis} offensively green tunic; the ensemble should rightly kill any interest you have in ${ehim}, but instead you find yourself thinking ${ehe}'s…cute.

    The groan dies before it can leave your mouth, but it's a damn near thing. You'll have to watch yourself, you solemnly think.
    
    ${yusuha} is sharp enough to have picked up on your gaffe, had ${yhe} the presence of mind to do so. Luckily, ${yhe}'s preoccupied with scowling up at Eli from ${yhis} perch by the door.
*else
    "You might not be cut out for this, ${yusuha}," Eli says from the bar counter, where ${ehe}'s wiping down mugs of ale.
    
    ${yusuha} scowls at ${ehim} from ${yhis} perch by the door.
"Really? And which generous deity of perception endowed you with the revelation?"

"I have to confess, I thought you'd be better at this," you cut in,
*if (charming > 50)
    grinning.
    *if (eliinterest)
        Pointedly blocking Eli from even your peripheral vision.
    "You always seemed to me the personable sort. I would never have guessed tavern work, of all things, would put you out so much."
*else
    shrugging.
    *if (eliinterest)
        Pointedly blocking Eli from even your peripheral vision.
    "You always seemed to me the personable sort—much moreso than I am, at any rate. I would never have guessed tavern work, of all things, would put you out so much."
    
"I thought the same, but your clientele is really something else," ${yusuha} mourns, fingers pressed to ${yhis} temple. "I've never seen a more raucous, chatty bunch in my life. Has Balessa ever told you that she had five husbands, all of whom died within a decade of each other? If I hear one more word out of her about her handsome, charming, long-dead, likely [i]fictional[/i] grooms, Isha-on-high stand witness, I may have her join them in the Source before long." The wind mage rises from the ground, dusting ${yhim}self off as ${yhe} does. "And you say you work this tavern, what, six days of the week? All by your lonesome, at that. You're made of sterner stuff than I, ${fname}, and I don't know whether to fear or respect you."

*choice
    #"Come on, it's not as bad as you're making it out to be."
        *set charming %+ 15
        "And the color of Eli's tunic is a gentle, faded sea-green," ${yusuha} says, eyeing the healer's garment with distaste.
        
        "Hey."
        
        "No, I won't stop giving you trouble for it," ${yusuha} says, holding a hand up. "There are consequences to the choices you make—including what raiment of the green hells you've decided to terrorize the residents of fair Thulrum with. It's high time you learned that, [i]healer[/i]."
        
        Eli sighs in defeat, and returns to ${ehis} scrubbing in lieu of engaging ${yusuha}. "Still, tomorrow is the Day of Renewal," Eli muses, and you realize ${ehe}'s right. It will be the first of the week's seven days, and customarily the one in which businesses break from their activities. The trend is long since bucked for larger shops, which can afford to pay a premium for workers on Renewal shifts, but it's still typically held by many of the smaller, self-run shops, including yours. "Good time to take a break. Do you have any plans lined up, ${fname}?"
        
        *label frantichaze
        In the frantic haze of your first week being back in business, you hadn't even realized that Renewal was coming up. You had planned on getting things ready for tomorrow as soon as you wrapped up here, and only now does the realization come that it will have been for naught.
        
        The sheepishness you feel must have shown on your face, because Eli soon chuckles as ${ehe} inspects a washed tankard. "I'll take that as a no,"
        *if (elichilly)
            ${ehe} says with a smile. Still a bit tense—understandable, given the air which permeated your conversation—but valiant in its pretension of nonchalance.
        *else
            ${ehe} says, sounding a bit too cheerful for your tastes.
        "Then won't you join us, ${fname}? ${yusuha}, ${falco}, and I all have business upstairs. And I, for one, would be happy to have you along."
        
        You tilt your head at ${ehim}, brows knit in confusion. "'Upstairs'?"
        
        Eli's smile does not falter. "Mm. In the highcity."
        
        You pause to consider the term. You had thought the highcity unique to Aulain, with its storm-laden landscape and the desperate necessity for a separate holding, carved higher into the valley it sits on. But Thulrum is as temperate a city as they come, and sits high enough in the local topography that even the [i]specter[/i] of a greatflood has never haunted the city. And besides, you've called this city home for quite some time now. Ostensibly, enough to know if a whole other city is tethered to this one, somewhere along its perimeter.
        
        In the end, you tell Eli the only thing you can. "I have no idea what you're talking about."
        
        Eli meets your confused gaze with one of ${ehis} own, before finally turning to face ${yusuha} on the other side of the room. For ${yhis} part, the redhead has found sudden interest in ${yhis} Church-issued boots, refusing to meet either of you in the eyes. "About that…"
        
        Eli draws a long breath, and it's heavy in the exhaling. "Let me get this straight," ${ehe} finally says, ${ehis} tone frigid. "You decided to make ${fname} a full member of the Saber—"
        
        "—now, I don't know about [i]full[/i]—"
        
        "—a [b]full[/b] member of the Saber, having ${them} along on missions reserved for the top brass and the most experienced members—"
        
        "—so ${they} @{plural were|was} in good company, you see, properly assisted—"
        
        "—and not once did you ever think to show them—"
        
        "—we thought it would be overwhelming! ${fname} was just getting settled in—"
        
        "Halt," you say, feeling a migraine come on which threatens to split your skull wide open. "Let's…let's go back to the basics. Just what is this highcity you speak of?"
        
        Eli and ${yusuha} exchange glances then, the tension between them all but evaporating; in its place is instead a quiet agreement, a mischievous sort of kinship which you mislike the look of.
        
        "I suppose," ${yusuha} finally says, "it would be easier to show you."
    #"It's alright, ${yusuha}. You have talent enough in other areas."
        "Hm?" ${yusuha} ponders, tilting ${yhis} head at you from across the counter. "Those are very comforting words, so why do I feel offended?"
        
        "Do you have a low opinion of yourself, by any chance?" you offer airily.
        
        "Come now, ${fname}. It's like you don't even know me."
        
        "Then you should take it for the compliment it is," Eli says, grinning. "You really are talented in a great many things. Philandering the countryside, for one."
        
        "Slander!" ${yusuha} calls out, not missing a beat. "It is no sin to be an attractive @{yvar man|woman} in the prime of ${yhis} youth. If some stablehand falls for my razor-sharp wit and blinding smile, then why should my honor be stained for it? You're being terribly unfair, [i]healer[/i]."
        
        Eli's snort is not without amusement, but ${ehe} nonetheless chooses not to engage the redhead further. "Tomorrow is the Day of Renewal," Eli muses instead, turning to you as ${ehe} does. You realize then that ${ehe}'s right. It will be the first of the week's seven days, and customarily the one in which businesses break from their activities. The trend is long since bucked for larger shops, which can afford to pay a premium for workers on Renewal shifts, but it's still typically held by many of the smaller, self-run shops, including yours. "Good time to take a break. Do you have any plans lined up, ${fname}?"

        *goto frantichaze
    #"It's not easy, but you get used to it after a while."
        *set charming %- 15
        "Ah, the quiet resignation of one who's seen too much, and received too few apologies for it," ${yusuha} says, nodding thoughtfully. "You ply a difficult trade, ${fname}. But inquiring minds wish to know: why? The folks over at the guild would have tripped over themselves trying to recruit you, had they known what you're capable of."
        
        "It's a change of pace," you answer, stretching your arms. "I get my fill of combat just from Saber work. The last thing I want is to do more of the same in my day-to-day job."
        
        "Combat? Please." ${yusuha} snorts. "You've seen the rabelhans crawling around the forest, I'd bet. Their hides sell for a pretty penny, and a mage of your caliber would hardly need to lift a finger slaying them."
        
        "It's still a lot of work traveling back and forth, hides in tow," you point out. "Not half as attractive as just sitting here and refilling mugs of ale, all the while pretending I'm not tuning out the relentless chatter of drunk laborers."
        
        "I suppose when you put it that way…"
        
        "Still, you have the day off tomorrow, right?" Eli pipes up, glancing over at you as ${ehe} sets down a washed tankard. "It's the Day of Renewal, after all."
        
        After a moment's consideration, you realize that ${ehe}'s right. It will be the first of the week's seven days, and customarily the one in which businesses break from their activities. The trend is long since bucked for larger shops, which can afford to pay a premium for workers on Renewal shifts, but it's still typically held by many of the smaller, self-run shops, including yours. "Good time to take a break. Do you have any plans lined up, ${fname}?"

        *goto frantichaze
*page_break
*goto_scene Checkpoint_9-1