"${callsign}, it's time."

${yusuha}'s face comes into focus as you blink the sleep out of your eyes. $!{yhis} features are lined with tiredness and concern, the kind that not even the forced smile teasing the corners of ${yhis} lips could hide.

"I take it your [i]perimeter-scouting[/i] didn't turn up anything of value, then," Specter notes solemnly. The bespectacled man is already up and about, looking entirely recharged as he dispels the protective barrier. "Then our options remain the same, and it's time to move to a vote."

${falco} nods at ${fhis} mentor's words, already pulling ${fhis} mask back into place. "To recap, then, said options are the following: we can stick to our original plan, which would have us all enter the dungeon with a spirit gate. As best as we can tell, there is a high chance of an immediate ambush upon entry, and it is also likely that the skirmish will attract the attention of the guards' main host. In the best case scenario, the ambush does not exist, and we can be in and out with the target in tow within minutes. At worst, however, we would be cornered by a host that outnumbers us twenty-to-one. Casualties on our part would be a near-certainty in that scenario.

"The alternative is to have Fox cast Zephyros. The spell will decimate the bulk of the force stationed within the castle, which would render the castle pliant to a frontal assault. The ambushers, if they exist, would escape unscathed by virtue of the dungeon being underground; regardless, they would lose the element of surprise. The cost is that Fox would not be in fighting shape after casting the spell, and we will have to leave Specter behind to tend to ${yhim} and ${yhis} mana exhaustion."

"That's a fair representation of our state of affairs, I feel," Specter says. "Then there is the matter that our even numbers leave us without a majority vote. But I think it proper to assign Fox an additional vote, given ${yhis} pivotal role in the plan."

"Choose wisely, ${fname}," ${falco} warns, and you don't have to turn your head to know that ${fhe}'s staring daggers at you. "Remember that your friend's safety hangs in the balance. I should hate for ${ehis} blood to end up on your hands."

"Then it's time," Specter says. "I vote in favor of the frontal assault."

${falco} nods ${fhis} agreement. "Seconded."

"I'm in favor of the spirit gate," ${yusuha} says, resolute despite ${yhis} unease. "Razor as well."

"That's right," the rogue confirms, before casting a wary glance towards the towering man beside her. "Colossus?"

The axe-fighter makes a show of considering his options, but when he speaks there is not a shred of hesitation in his voice. "Zephyros."

"That leaves you with the deciding vote, ${callsign}," Specter says, his gaze on you appraising. "All our lives are in the palm of your hands. Which path will it be?"

*choice
    #"We go by spirit gate."
        *set noble %+ 25
        *set rfalco %- 10
        *set ryusuha %+ 10
        A dark look crosses ${falco}'s features, but it is gone as quickly as it came. "Very well," ${fhe} says, curt and businesslike. "Specter and I require some time to set things up."
        
        ${yusuha}'s expression softens at ${yhis} companion's words. "Sorry, ${falco}. I'll fight tooth and nail to make sure we all get out in one piece."

        ${falco} regards ${yhim} coolly in response, piercing golden eyes catching the light as ${fhis} mana flares to life around ${fhim}. "Soft-hearted fool," ${fhe} mutters, though the edge in ${fhis} voice speaks of resignation rather than malice. "If you perish here, I'll be sure to spit on your grave."

        ${yusuha} chuckles lightly in response. "You be careful too, ${falco}."
        *page_break
        *goto spiritgatepath
    #"Zephyros it is."
        *set noble %- 25
        *set rfalco %+ 10
        *set ryusuha %- 10
        ${yusuha} looks away quickly, but it's a futile effort. You could still catch the expression adorning ${yhis} face: downcast, with a palpable edge of disappointment.

        "Very well," ${yhe} finally forces out. "I will require time to prepare."
        
        Specter's gaze on the red-haired mage is gentle, almost serene. "Godspeed, Fox. I do not envy your position, but it is our lot to do what must be done."

        ${yusuha} does not look at him when ${yhe} responds. "I know. All too well."
        *page_break
        *goto zephyrospath

*label spiritgatepath
${falco} and Specter's mettle as spiritists are showcased in full as they set the spirit gates up. The spell is often a tricky one to manage, especially when circumstances demand that it transport six people in a single casting. And yet as the tangle of violet and deep green mana form fissures in the air—precise, harsh-edged runes ebbing and pulsating with carefully controlled power—you can tell that the spell will do exactly what is required of it.

A hum, a jolt, a violent streak of light, and the spirit gate yawns open, like the maw of a great beast.

"Be prepared," ${falco} warns at the portal's edge. "If the ambush exists, we will be faced with immediate resistance upon entry. They will have us backed into a corner, and it'll be difficult for us to set another gate up unless you keep the heat off of Specter and I."

"The best way to do so, of course, is simply to neutral what opposition we find," Specter says. "Even you would spare no pity for ambushers, would you, Fox?"

"You've seen me in action, Specter," the redhead responds. "I can do what must be done, if there's no way around it."

Specter nods understandingly. "I believe you."

${falco} looks over at Colossus and jerks ${fhis} chin towards the open gate. "Colossus, take point."

With a grunt, the larger man brandishes his broadaxe and steps into the portal, the mass of his body fading into shadowy wisps before vanishing entirely. The rest of the Saber move after him in a wordless flurry, and one by one they disappear into the spirit gate's depths.

You pull your mask on,
*if ((mask = "plain") or (mask = "imperial"))
    its cold clay edge
*elseif (mask = "flame")
    the cold edge of its iron
*elseif (mask = "flower")
    the fine edge of its petals
*elseif (mask = "veil")
    its fine samite edge
*else
    the cold edge of its steel
strangely chafing against your bare skin, and follow them into the breach.

*page_break

The world spins into view with a dizzying flurry as the spirit gate closes behind you. Blinking hard to regain your bearings, you look around to ensure that all your allies had made the trip safely. Sure enough, five masked figures stand in an array around you, each of them alert and ready, muscles taut as they grip their weapons with force.

Wherever you are is a poorly-lit space, with only the lingering remains of ${falco}'s mana painting the room with a dim violet glow. You could make out a shadowy outline in the farthest cell to your left, arms spread upwards and presumably chained to the walls, and you feel your hearbeat quicken as you realize that the form may very well be Eli.

*temp wefeeling ""
*choice
    #If it weren't for fear of the ambush, I'd have sprinted to ${ehis} side.
        *set emotional %+ 15
        *set wefeeling "turmoil"
        You miss ${ehim}—more than you can rightly express. It feels like an eternity has passed since you last felt ${ehis} gentle companionship, steady and stalwart even in the face of ${ehis} suffering. $!{ehis} visage had graced your dreams for as long as you can remember—in turns anguished, happy, and serene—and it feels like a gentle fiction, too good to be true, that ${ehe} could be a part of your life once more.
    #$!{ehe}'ll have to wait. Recklessness will only lead us both to our demise.
        *set emotional %- 15
        *set wefeeling "onguard"
        And it wouldn't be the first time for either of you, either. You had both spent your life willingly for the benefit of others—a touch of self-preservation this time around could only do you both good.
    #I have to rescue ${ehim}. $!{ehe}'s an arcanist, and one I can trust unreservedly.
        *set noble %- 15
        *set wefeeling "onguard"
        You're in uncertain territory now, after all, and there's no telling what designs Arcadia has waiting for you and for Arvanand as a whole. Having someone you can trust by your side—someone Tahlia is desperate to get on hers—would be a powerful bargaining chip against them, ensuring you don't get sucked into their plans against your will.
    #Guilt overwhelms me. Just one other way ${ehe}'s had to suffer—all because of me.
        *set noble %+ 15
        *set wefeeling "turmoil"
        You have always known Eli to be competent and resourceful, so much so that ${ehe} would have never allowed ${ehim}self to be in this position. But ${ehis} sacrifice—through which ${ehe} had purchased your survival—had placed ${ehim} at Tahlia's mercy. And you're willing to bet good coin that ${ehe} would have steered clear of this mess were it not for ${ehis} involvement with Arcadia.
    #$!{ehe}'s pitiful, as am I. I wish things could have been different for us both.
        *set wefeeling "turmoil"
        In another world, perhaps you could have led simple and content lives, so far removed from mages with grand ambitions and the burdens of ancient bloodlines. Perhaps you could have been spared the torture of watching everyone you love slowly march to their demise, of being powerless as death then turns its savage attention on you. What a privilege that would have been.

*if (wefeeling = "turmoil")
    ${falco} drinks in the sight of the dungeon, ignorant of your inner turmoil. You can feel ${fhis} mana prickling underneath ${fhis} skin, taut and ready to be unleashed at the first sign of hostility. And though the dungeon remains perfectly silent all six of you are experienced combatants, and there is tension in the air that feels distinctly hostile.

"Tch, I knew it," ${falco} hisses, ${fhis} mana spiking to dangerous levels. For a moment you nearly ask ${fhim} what ${fhe} means by that, but you are instead stunned into silence as the white-haired mage bodily tackles you to the side.

You feel the cold stone flooring against your bare skin for less than a second before ${falco} pulls you back to your feet, and through your disorientation you realize that in the spot you had been standing in is now a pincushion of throwing knives. The whole of their lengths are coated by a strange blue sheen, too bright and viscous to be anything but poison.

"Reon venom," Razor growls, her tone thick with disbelief. "This shouldn't be possible."

You can't help but to share in her astonishment. The Reon viper is a species exclusive to the Cold South, an imperial territory far beyond Arvanian waters. So seldom is its poison seen in Arvanand that barely any alchemist in the continent has even heard of it, let alone have its antidote on hand.

You'd be hard-pressed to identify it on your own, but with Razor's claim to go off of, you find that you can confirm her theory. Had the knives found their mark—found [i]you[/i]—the venom would be creeping through your bloodstream by now, ravaging any organ it passes through. Without the appropriate antidote, your body would have sustained permanent damage, if not given up the ghost outright.

The blood chills in your veins as ${falco} draws ${fhim}self up beside you. The mage quickly disentangles ${fhis} hands from your arms and hisses at the looming darkness. "Show yourselves," ${fhe} calls out, brandishing ${fhis} spear.

${falco}'s demand is answered by a baleful silence, for a while, but soon there's a series of slow footsteps from the other side of the hall and a cloaked figure comes into view. "Well done," he says, lowering his hood to reveal a black-haired man looking to be well into his forties. His Salantir accent sounds studied, and the lilts of his true tongue—one you're presently unable to place—peek out through his consonants. "We had been so confident that the poor count's guards would keep you all at bay—it certainly speaks well of both your magical and tactical prowess for you to have bypassed them entirely. Would you bestow upon me the names of such fine fighters?"

${yusuha} answers the question with a spike of ${yhis} mana, and a lift of the stranger's eyebrows signals to you that he has registered the threat. A mage, then. One powerful enough to feel comfortable in the limelight, rather than behind the ranks of his armored knights, cowering. A dangerous enemy, if ever there was one."

"There's no need for us to exchange pleasantries, sir," ${yusuha} says, sickly-sweet. "Release our ally to us. I can promise you won't like the alternative."

"It's poor manners to make such lofty demands of your host, dear visitor," the man responds with a sneer. He maintains an expertly neutral expression as he steps forward, his gait marking the fact that he's wholly assured of his own power. "Especially when the man has you surrounded. Yours is a strange place from which to mete out threats, wouldn't you agree?"

"You're a fool for thinking so," ${falco} spits. "The curs on your leash pose no threat to us. We'll put them down as soon as you set them on us, and their master won't be far behind."

The man cackles at the threat, the ring of his laughter sinister as it echoes through the dungeon. "We shall see just who puts down who if we come to blows. But I think you'll find that aggression will be quite costly for you," he warns, a derisive smile tugging at the corner of his lips. "Come join us, won't you, my good Count?"

*page_break

You hear a second set of footsteps behind the stranger's back, then, and out of the gloom a balding, heavyset man appears, dragging a barely conscious @{evar man|woman} with him.

Your eyes nearly bulge out of your skull as they trail over the familiar form, and for all that you knew that ${ehe} would be here it is a different thing entirely, to see ${ehim} in the flesh. Many things have changed about the @{evar man|woman} since you last saw ${ehim}, all those years ago—${ehe} is much taller now, but still keeps ${ehis} @{evar black hair shorter, neat and tidy as ${ehis} sword instructor had required|hair longer, the locks a luminous black even under the clots of blood and sweat}. There is a sliver of defiance percolating those familiar brown eyes, but against the enchanted bindings clasped around ${ehis} wrists ${ehe} is powerless, arms hanging limply at ${ehis} side.

Eli is alive. Close enough to reach out to. Close enough to touch.

And ${ehe} has a dagger pressed against ${ehis} throat.

"D-don't come any closer," the count says, his voice trembling with fear. "I-I don't know who you are, but just leave us be! Leave us be and I'll f-forget about this incident."

"Don't presume to make demands of us!" ${falco} yells, and as the count flinches backward at the aggression his dagger digs into the skin of Eli's neck. It is a shallow cut, by all measures, but the way it only misses the @{evar man|woman}'s carotid by a hair sends shivers up your spine. Eli lets out a distressed grunt, but remains otherwise silent.

"Provoke the count at your own peril, dear guests," the stranger jeers. "But lucky for you, he is not an unreasonable man—and neither am I. You are such curious existences, after all! Do not think me ignorant to the skill it must have taken, to engage Spirit Gate as you have. To think such talented mages have managed to hide themselves from the world's stage. I imagine the Hero of Sienan was much the same way before ${they} decided to crown the Sun King." Your jaw tenses at the mention of the epithet—it appears your reputation has grown even more outsized than you imagined. "Our interest in such firepower is quite keen, as you might imagine. So let us negotiate: what will you give us in exchange for this @{evar man|woman}'s safe return?"

${falco} bristles beside you, and you recognize with some alarm that ${fhe} will likely try ${fhis} chances at a frontal assault. The white-haired mage is fast, and a competent fighter besides—it is very likely that ${fhe}'ll be able to free Eli if you let ${fhim} push forward. But for all that the stranger's confidence could be naught but a bold-faced bluff, the count is still very much in position to end Eli's life.

You hear ${yusuha} shift behind you, then, ${yhis} feet scraping deliberately against the stone floor. A signal, clearly, but for what...?

You've yet to gain the full measure of ${yusuha}'s talents, but by all accounts ${yhe} is far and away one of the Saber's best fighters. Clearly ${yhe} has some sort of trick up ${yhis} sleeve, some way to free Eli from ${ehis} captor's clutches without endangering ${ehis} safety. Seeing the blade pressed against Eli's throat, you have half a mind to whirl on ${yusuha} and tell ${yhim} to get on with it already. But it's apparent ${yhe} needs time to prepare ${yhis} gambit, and the task falls to you to keep the stranger distracted in the meantime.

*comment HOUSEKEEPING revisionpoint = add learning (educated guess on what yu is up to)
*comment HOUSEKEEPING revisionpoint = add do nothing path (f does heavy lifting)

*choice
    *selectable_if (charisma > 59) #I'll play-act at negotiating to stall for time.
        *goto charismapath2
    *selectable_if (enchantment > 59) #${yusuha}'s gambit should be magical in nature. A Glyph of Manaburn should prove helpful.
        *goto enchantmentpath2
    #There's nothing I can do to help ${yusuha}, but I have faith that ${yhe} can get the job done and do it well.
        (This path is currently not yet complete. You will be redirected to the charisma path of the previous choice branch.)
        *goto charismapath2

*label charismapath2
"Return our friend to us, and we will provision you with information," you say judiciously, and the man's lips curl into a satisfied smirk. Clearly, this the prize he'd been angling to get. "You think us a curious existence? Be curious no more. Swear that you will let our associate go, and we'll answer any questions you have for us."

"Very good. I knew we could come to an agreement," he says, preening like a bird. "Of course, whether I see through my end of the bargain largely hinges on the quality of your information. And please, for both our sakes—let's not try to lie, shall we? I am trained in the art of seeing through deception, and I would so hate for our amicable negotiations to fall through."

"You have my word," you say, and mean it.
*if (noble > 50)
    You would rather see the stranger keep his head, but you get the distinct impression that the Saber will see him dead tonight, one way or another. It does Thulrum no harm to have its secrets disclosed to a man whose fate is already sealed.
*else
    There is no harm in telling secrets to a dead man, after all. And he [i]will[/i] lose his head tonight—by the Saber's hand, if not by yours.

You speak of Arcadia in grandiose flourishes then, of a network with roots spanning the entire continent, of magic long thought to be lost to the annals of history. The man listens intently with fascination and barely-contained glee—as if he hadn't just made an enemy of one of the strongest factions in the land—but you achieve the desired effect. He is lulled into a false sense of security as he latches onto your every word, and it is then that ${yusuha} brings ${yhis} gambit to fruition.
    
It starts off almost innocuously, as a quiet seethe of mana where ${yusuha} stands behind you. And then a spell ripples through the air from ${yhis} fingertips—masterfully subtle, detectable to you only because you know to look for it—and slithers its way towards the unsuspecting stranger and Count Reglaire. It latches onto the space around them like a barely perceptible smog, and when both men began to show signs of discomfort it is already far too late for them.

The count is first to drop onto the ground, wheezing and choking as if the air had been stolen from his very lungs. There is a clatter as his knife drops harmlessly onto the ground next to him, and though Eli looks poised to fall as well Razor is quick on the uptake. She leaps forward like a bolt of lightning—enchanted with ${falco}'s Glyph of Swiftness, judging by the violet mana surrounding her body—and retreats with the healer in her arms before ${ehis} form meets the ground.

The stranger is red in the face with anger even as he joins the count on the floor, haphazard Glyphs scattered in the air around him in an attempt to counter ${yusuha}'s spell. "Get them!" he roars through gritted teeth, and in a single second it is as if the whole room is closing in on you.
*goto encroach2

*label enchantmentpath2
*set glyphofmanaburn true
*set ecounter +1
There is a quirk in the flow of ${yusuha}'s mana as you weave your own with it, subtle enough that the stranger hasn't a hope of detecting the change in the atmosphere. Though you yourself can't see it, the Glyph will have appeared under ${yusuha}, hidden by the long fabric of ${yhis} robes as it feeds ${yhis} spell and causes it to quicken. To ${fhis} credit, ${falco} seems to notice the shift in energy—and judging by the imperceptible tensing of ${fhis} stance, ${fhe} seems to know that something has been set into motion. You can almost hear the shifting gears in ${fhis} head, ${fhis} posture relaxing to appear almost diplomatic.

"We are not closing the possibility of partnership, if your group can make itself useful to us," ${falco} says judiciously, though you know full well the white-haired mage would love nothing more than to rip the stranger's head from his torso. "But taking a hostage is a poor way of soliciting our cooperation."

"Now, now, I wouldn't use the word [i]hostage[/i]," the man chides. "We are simply seeking fair compensation for services rendered. After all, is it not the case that your friend here—"

His spiel is interrupted as ${yusuha} finally brings ${yhis} gambit to bear. It starts off almost innocuously, as a quiet seethe of mana where ${yusuha} stands behind you. And then a spell ripples through the air from ${yhis} fingertips—masterfully subtle, detectable to you only because you know to look for it—and slithers its way towards the unsuspecting stranger and Count Reglaire. It latches onto the space around them like a barely perceptible smog, and when both men began to show signs of discomfort it is already far too late for them.

The count is first to drop onto the ground, wheezing and choking as if the air had been stolen from his very lungs. There is a clatter as his knife drops harmlessly onto the ground next to him, and though Eli looks poised to fall as well Razor is quick on the uptake. She leaps forward like a bolt of lightning—enchanted with ${falco}'s Glyph of Swiftness, judging by the violet mana surrounding her body—and retreats with the mage in her arms before ${ehis} form meets the ground.

The stranger is red in the face with anger even as he joins the count on the floor, haphazard Glyphs scattered in the air around him in an attempt to counter ${yusuha}'s spell. "Get them!" he roars through gritted teeth, and in a single second it is as if the whole room is closing in on you.
*label encroach2
*page_break
It takes you a second to realize that the encroaching darkness is actually a mass of black-clad warriors, the air around them still crackling from dispelled Glyphs of Invisibility. You wonder for a second just how it is that they managed to conceal their presence so perfectly, but the sudden flurry of throwing knives bid you focus on the battle instead.

All around you the Saber move in perfect unison as they shift into combat stances. ${yusuha} is quick to dismiss the incoming projectiles with a burst of cutting gales, proceeding to wrap the winds into a dome-like construct designed to protect your group from any future assault. Colossus handily deals with any knives and arrows that slip through the cracks, weaving his axe through the air with weightless ease. Behind him, ${falco} and Specter take the opportunity to mount a counteroffensive, casting Fists of the Dark Lord to swipe the attackers off balance and stymie their relentless assault, while Razor returns fire with throwing knives of her own.

And yet your opponents seem  to shrug off most of your counterattacks, quickly regaining their footing and encroaching upon your position. You suspect that the icy blue aura surrounding their forms might have something to do with it—a cocktail of enchantment spells woven into one, if you had to guess, resulting in a nearly impervious wall of fighters surrounding you on all sides.

Colossus grunts in front of you as a flurry of blue-coated throwing knives plant themselves in his arm—a non-fatal location for Reon venom, thank Jove, though you imagine the wound is painful all the same—and then ${falco} calls out beside you. "${callsign}!"

$!{fhe} would not have to tell you twice. Your mana grows and crests as the spell you've been preparing finally settle on your fingertips, and you unleash...

*choice
    *selectable_if (enchantment > 65) #...Glyphs of Dispel, mass-casted. The Saber should be able to triumph if given equal ground.
        *goto enchant4
    *selectable_if (enchantment > 74) #...Glyphs of Dispel, and Glyphs of Protection for my allies. I'll turn the tables entirely.
        *goto enchant3
    *selectable_if (thaum > 74) #...Sunflame. It should be strong enough to eat through resistance enchantments.
        *goto thaum3
    *selectable_if (thaum > 65) #...Stone Graveyard. I'll break our opponents' momentum and create an opening.
        *goto thaum4
    *selectable_if (spiritism > 49) #...Fist of the Dark Lord. Reinforcing ${falco} and Specter's assault may help tip the balance.
        *goto spirit2
    *selectable_if (alchemy > 49) #...Clay Cannon. Reinforcing ${falco} and Specter's assault may help tip the balance.
        *goto alchemy2

*label enchant3
*set glyphofdispel true
*set glyphofprotection true
*set ecounter +1
You feel your mana ducts going into overdrive as the Glyphs manifest, the sensation not unlike that of calling upon ${phant1}'s power, if without the painful searing sensation of @{phantvar him|them|him|her} overloading your synapses. Your enemies' enchantments initially hold strong against your efforts—whoever is behind them must be an enchanter of true mettle—but with a final, straining push you manage to overpower them, and you feel their magic hemorrhaging into the air before dissipating into nothingness.

${falco} is quick to seize the advantage, leaping forward as projectiles careen off ${fhis} body due to your Glyph of Protection, and launches a deadly assault against the attackers' front line. No longer on ${fhis} backfoot, the white-haired mage calls upon ${fhis} phantasma once more, the scaled serpent all fangs and bludgeoning strength as it wreaks havoc behind enemy lines. Colossus follows suit behind ${fhim}, a terror in his own right as he forcefully bashes the enemies' skulls open, Razor and Specter using his hulking form as cover as they launch attacks of their own.
*goto successplus2

*label enchant4
*set glyphofdispel true
*set ecounter +1
You feel your mana ducts going into overdrive as the Glyphs manifest, the sensation not unlike that of calling upon ${phant1}'s power, if without the painful searing sensation of @{phantvar him|them|him|her} overloading your synapses. Your enemies' enchantments initially hold strong against your efforts—whoever is behind them must be an enchanter of true mettle—but with a final, straining push you manage to overpower them, and you feel their magic hemorrhaging into the air before dissipating into nothingness.

${falco} and Specter leap forward to seize the opportunity, launching themselves into a deadly dance of lanceplay and spiritism. The fighters' disorientation at having their enchantments removed allows the pair to advance past enemy lines easily, at first, but it isn't long before your opponents regain their footing and begin responding in kind. The spiritists hiss as knives and blades alike dig into their skin, but then Colossus rushes forward to buy them cover—enough for Specter to catch his breath, and for ${falco} to call upon ${fhis} arcana.

The scaled serpent rears its head from the mage's back, then, all fangs and bludgeoning strength as it wreaks havoc amidst your foes. Colossus follow suit behind ${fhim}, your enchantment allowing him to swing his broadaxe in wide, brutal arcs. Razor uses his hulking form as cover from which to launch attacks of her own, her Glyph-propelled form a streak on the battlefield.
*goto success2

*label thaum3
*set sunflame true
*set tcounter +1
With a last flourish of mana, you combust the air around you, weaving them into gouts of flame. The spell launches forward in violent streams, carefully controlled to veer past your allies and engulf your enemies in a deadly inferno. Your enemies' enchantments initially hold strong against your efforts—whoever is behind them must be an enchanter of true mettle—but with a final, straining push you manage to overpower them, the blessing shriveling under the unforgiving might of your spell.

${falco} is quick to seize the advantage, leaping forward as projectiles careen off ${fhis} body due to your Glyph of Protection, and launches a deadly assault against the attackers' front line. No longer on ${fhis} backfoot, the white-haired mage calls upon ${fhis} phantasma once more, the scaled serpent all fangs and bludgeoning strength as it wreaks havoc behind enemy lines. Colossus follows suit behind ${fhim}, a terror in his own right as he forcefully bashes the enemies' skulls open; behind him, Razor and Specter uses his hulking form as cover as they launch their attacks amidst Sunflame's orange glare.
*goto successplus2

*label thaum4
*set stonegraveyard true
*set tcounter +1
You weave the spell into existence with a last flourish of mana, and all around you the ground heaves and quakes as earthen spires surface from the ground and bludgeon your enemies with vicious force. Their enchantment holds strong despite your efforts, dampening the bulk of the spell's impact; but many are flung sideways or swept off their feet, and though their assault is never truly broken it is enough to give your allies the window they need.

${falco} and Specter leap forward to seize the opportunity, launching themselves into a deadly dance of lanceplay and spiritism. The fighters' disorientation at having their blessing removed allows them to advance past enemy lines easily, at first, but it isn't long before your opponents regain their footing and begin responding in kind. The spiritists hiss as knives and blades alike dig into their skin, but then Colossus rushes forward to buy them cover—enough for Specter to catch his breath, and for ${falco} to call upon ${fhis} arcana.

The scaled serpent rears its head from the mage's back, then, all fangs and bludgeoning strength as it wreaks havoc amidst your foes. You cast a second round of Stone Graveyard to seize on the momentum, and with that last bit of support your allies push through their injuries and finish off your opponents once and for all.
*goto success2

*label spirit2
*set fistofthedarklord true
*set visionsofthedamned true
*set scounter +1
You weave the spell into existence with a last flourish of mana, and the Fist burrows deep behind enemy lines with great bludgeoning strength. And yet the enemies' enchantment hold strong despite your efforts, dampening the bulk of the spell's impact and allowing your opponents to escape mostly unscathed as they redouble their assault.

${falco} stirs beside you, then, and with a snarl ${fhe} launches ${fhim}self into a desperate assault, teeth bared and lance brandished. $!{fhe} does decently against the enemy, at first, but is soon overwhelmed by their sheer numbers and begins to falter as knives and blade alike dig into ${fhis} skin.

"Colossus!" ${fhe} calls out, and the larger man then charges forward with a guttural bellow, his body forming a shield around the mage to cover ${fhim} from the brunt of the attacks. You and Specter do everything you can to aid the twosome—another Fist, a Visions spell—until eventually ${falco}'s mana crests like a tidal wave and ${fhe} brings ${fhis} arcana into being.

The scaled serpent rears its head from the mage's back, then, all fangs and bludgeoning strength as it wreaks havoc amidst your foes. You cast a second round of Fist of the Dark Lord to seize on the momentum, and with that last bit of support your allies push through their injuries and finish off your opponents once and for all.
*goto fail2

*label alchemy2
*set claycannon true
*set acounter +1
You command the cannonballs to lurch forward with a last flourish of mana, and they burrow deep behind enemy lines one after another. And yet the enemies' enchantment hold strong despite your efforts, dampening the bulk of the spell's impact and allowing your opponents to escape mostly unscathed as they redouble their assault.

${falco} stirs beside you, then, and with a snarl ${fhe} launches ${fhim}self into a desperate assault, teeth bared and lance brandished. $!{fhe} does decently against the enemy, at first, but is soon overwhelmed by their sheer numbers and begins to falter as knives and blade alike dig into ${fhis} skin.

"Colossus!" ${fhe} calls out, and the larger man then charges forward with a guttural bellow, his body forming a shield around the mage to cover ${fhim} from the brunt of the attacks. You and Specter do everything you can to aid the twosome—another Cannon, a Visions spell—until eventually ${falco}'s mana crests like a tidal wave and ${fhe} brings ${fhis} arcana into being.

The scaled serpent rears its head from the mage's back, then, all fangs and bludgeoning strength as it wreaks havoc amidst your foes. You cast a second round of Clay Cannon to seize on the momentum, and with that last bit of support your allies push through their injuries and finish off your opponents once and for all.
*goto fail2

*label successplus2
*set prestige + 3
*set rfalco %+ 10
*set ryusuha %+ 10
*page_break
At the end of it all, only their leader is left alive, crumpled on the floor in a state of near mana exhaustion. "Damn you," he curses, his broken grimace a far cry from his earlier confidence. "Inhumans."

${falco} kicks him squarely on the jaw then, and you hear the crack of a bone snapping out of place as the hit connects. You can't help but be astonished that ${falco} could still summon such strength, when you're at the edge of collapsing yourself. "Who are you?" ${fhe} snarls. "Who sent you here?"
*goto denouement2

*label success2
*set prestige +2
*set rfalco %+ 6
*set ryusuha %+ 6
*page_break
At the end of it all, only their leader is left alive, crumpled on the floor in a state of near mana exhaustion. "Damn you," he curses, his broken grimace a far cry from his earlier confidence. "Inhumans."

${falco} kicks him squarely on the jaw then, and you hear the crack of a bone snapping out of place as the hit connects. You can't help but be astonished that ${falco} could still summon such strength, when you're at the edge of collapsing yourself. "Who are you?" ${fhe} snarls. "Who sent you here?"
*goto denouement2

*label fail2
*page_break
At the end of it all, only their leader is left alive, crumpled on the floor in a state of near mana exhaustion.

"Damn it all," he curses, his broken grimace a far cry from his earlier confidence. "I almost...I almost had you."

${falco} kicks him squarely on the jaw, though you don't miss the way the mage winces as the hit connects—it's all too obvious that ${fhe}'s also at the end of ${fhis} rope. "Who are you?" ${fhe} snarls despite it all, intimidating even on the brink of collapse. "Who sent you here?"
*goto denouement2

*label denouement2
The man answers the demand with a bitter laugh as blood drips down his jaw. "Enjoy your victory," he says through gritted teeth. "Make no mistake...you [i]will[/i] die here tonight."

And with that final, ominous threat, an icy-blue light engulfs the stranger's form, and he falls slack onto the dungeon floor.

"We'll see," Specter scoffs, tendrils of mana already bleeding out from his fingertips. "I'll cut us a way out of here. It's a good thing that the knights haven't—"

As if in response to his words, a sudden thundering of steps ring out from the floor above. Specter hisses at the imminent threat, and you can feel his power shoot up in intensity as he works feverishly to bring his spirit gate to bear.

"You just had to jinx it," ${yusuha} sighs, affecting a humorous air, though you can detect the undercurrent of tension under ${yhis} voice.

"It would've happened either way," someone rasps behind you. You whip around to regard the familiar voice, at once gentle and strong, and see that Eli has regained ${fhis} consciousness. You suspect the empty bottle of potion Colossus holds in his hand had something to do with it. "That last flash of mana he had…was a beacon enchantment. Everyone in this group could cast it. They are…dangerous people, and whoever employs them even more so."

"[i]Now[/i] you tell us," ${falco} says blithely, rolling ${fhis} eyes. "Plague, can you fight?"

"Plague" gazes down at ${ehis} limp arms and gives the white-haired mage an apologetic look. "Sorry."

"Then stay out of our way," ${falco} replies, already adopting a combat stance. "Specter, get the spirit gate ready as fast as you can. Colossus, we're holding the chokepoint. Everyone else, support; I expect you all to pull your own weights, if you don't want this dungeon to be your grave."

*page_break You take your positions.

The knights make it to the dungeon stairway within the minute, their battle-cries discordant in the echoing dungeon. ${falco} greets the vanguard with ${fhis} arcana, the serpent rising from the skin of ${fhis} back and darting through the air like a dark bolt of lightning. Venomous black fangs protrude from its gaping maw, coated by an ominous purple sheen, and when they pierce through armor and skin both the knights are set to writhing on the stone floor.

The rest of the Saber move in unison to capitalize on the advantage. At the foot of the stairway, Colossus launches himself into a series of violent, exaggerated blows to draw the heat off of his vulnerable companion. ${yusuha} is quick to support him with bursts of wind and fire, carefully directed to weave past the hulking axeman and instead bury themselves in his opponents. Beside ${yhim} Razor has drawn a small crossbow from underneath her doublet, and before long the rogue is shooting bolts of poisoned arrows with masterful precision.

"Little help here," ${yusuha} mutters beside you, wheezing from the exertion of ${yhis} consecutive spells.

Your spell circle completes its circuit even before the red-haired mage finishes ${yhis} sentence. You feel your mana crest like a tidal wave, then, and with a final flourish it twists into…

*comment HOUSEKEEPING reserve prestige? unleash all at once identities merge

*choice
    *if (thaum > 74) #...a series of Thunderstrikes, perfectly aimed at the wave of incoming knights.
        *set prestige +2
        *set thunderstrike true
        The spells shoot out of your fingertips with a harsh flourish of mana. Bolts of lightning race across the dungeon then, loud and furious as they home in on the gaps between the knights' armor. The soldiers crumple like dolls with cut strings where your spells strike them, and ${falco} and Colossus's weapons find purchase on their vitals before they have the chance to recover.
        
        All of you stay like that in the middle of the dungeon, a storm of spells and weapon-swings which ravages the enemy's ranks. Privately you fear for ${falco} and Colossus both, as their stances begin to slacken under the weight of their exhaustion. Increasingly you begin to spot knights picking themselves back up after your spell has run its course, labored in their breathing but with grips firm on the hilt of their blades. Colossus and ${falco}'s blows come too late to make good on the advantage you gave them, and the knights begin to repel their attacks with increasing ease.
        
        Just as you begin to genuinely fear for your group's chances, Specter's mana bursts in the air behind you, alerting you to the fact that the gate has been completed. "Quickly!" the older mage yells from the other side of the room, straining to keep the gate open.
        
        ${falco} heeds the call by calling upon ${fhis} arcana once more, using its thick, serpentine body as a shield as ${fhe} and Colossus stage their retreat. ${yusuha} and Razor fire their parting shots before turning around to follow suit. "${callsign}, grab Eli!" the red-haired mage yells as a last burst of wind spirals out from ${yhis} fingertips.
    *selectable_if (enchantment > 74) #...multiple Glyphs of Protection, cloaking ${falco} and Colossus's forms in a protective barrier.
        *set prestige +2
        *set glyphofprotection true
        And just in time, too—a swordsman had successfully feinted his way past Colossus and was just about to bury his blade in ${falco}'s arm, but with the protection of your Glyph the blow skids off the white-haired mage's skin. Disoriented by his own shift in momentum, the swordsman stumbles backward into an awkward stance, perfectly positioned for ${falco} to stab him through the abdomen.
        
        "Good job, ${callsign}," ${yusuha} praises, ${yhis} red hair whipping backward from the force of ${yhis} spell. "Keep at it!"
        
        The both of you stay like that in the middle of the dungeon, ${yhis} spells volleying through the air and yours quietly glimmering into existence. Privately you fear for ${falco} and Colossus both, as their stances begin to slacken under the weight of their exhaustion, and increasingly you begin to feel recoils from your Glyphs where the knights had struck against it with deadly force.
        
        Just as you begin to genuinely fear for your group's chances, Specter's mana bursts in the air behind you, alerting you to the fact that the gate has been completed. "Quickly!" the older mage yells from the other side of the room, straining to keep the gate open.
        
        ${falco} heeds the call by calling upon ${fhis} arcana once more, using its thick, serpentine body as a shield as ${fhe} and Colossus stage their retreat. ${yusuha} and Razor fire their parting shots before turning around to follow suit. "${callsign}, grab Eli!" the red-haired mage yells as a last burst of wind spirals out from ${yhis} fingertips.
    *selectable_if (spiritism > 74) #...a dark flurry of spirits, designed to help Specter weave the spirit gate quicker.
        *set prestige +2
        *set spiritgate true
        ${yusuha} balks at your choice of spell—clearly it was not the one ${yhe} had had in mind—but quickly returns to form and shifts ${yhis} gaze on where the battle is thickest. "Keep at it, ${callsign}. We'll do what we can to buy you time!"
        
        The both of you stay like that in the middle of the dungeon, your spells volleying through the air in opposite directions, until eventually a burst of Specter's mana alerts you to the fact that the gate has been completed. "Quickly!" the older mage yells from the other side of the room, straining to keep the gate open.
        
        ${falco} heeds the call by calling upon ${fhis} arcana once more, using its thick, serpentine body as a shield as ${fhe} and Colossus stage their retreat. ${yusuha} and Razor fire their parting shots before turning around to follow suit. "${callsign}, grab Eli!" the red-haired mage yells as a last burst of wind spirals out from ${yhis} fingertips.
    *if (thaum < 75) #...a series of Thunderstrikes, as finely aimed as I could make it.
        *set thunderstrike true
        *set colossusinjury true
        The spells shoot out of your fingertips with a harsh flourish of mana. Bolts of lightning race across the dungeon then, loud and furious as they home in on the gaps between the knights' armor. The soldiers crumple like a doll with cut strings where your spells strike them, and before they could regain their footing, ${falco} has already planted ${fhis} spear in their abdomens.
        
        The both of you stay like that in the middle of the dungeon, your spells volleying through the air in a merciless flurry. But before long you begin to feel exhaustion set deep in your bones, and your control over the spells begin to falter. It is Colossus that ends up paying the price—one of the spells fail to curve around the axeman's form, and it catches him in the shoulder right as he tries to avoid an incoming blow. The shock of the moment forces his knees to buckle out from under him, and a blade catches him in his chest as he falls.
        
        "Damn it!" ${falco} yells out as ${fhe} fights to shield Colossus from the incoming assault. "Specter, I swear if you don't get the gate ready now—"
        
        The older mage answers him with a burst of mana, signaling that the gate is complete. "Quickly!" he yells out from the other side of the room, straining to keep the gate open.
        
        It is then that ${falco} lets loose ${fhis} arcana once more, and the serpent whips past Colossus's crumpled form and positions itself into a barrier covering the whole of the doorway. ${falco} stages ${fhis} retreat with Colossus in tow, and as they fire their parting shots ${yusuha} and Razor follow closely behind ${fhim}. "${callsign}, grab Eli!" the red-haired mage yells as a last burst of wind spirals out from ${fhis} fingertips.

Propelled by the adrenaline coursing through your vein, you rush to obey ${yhim}. You scramble frantically across the dungeon and lean down to where Eli is sat on the ground. The older mage lets you sling ${ehis} arm across your shoulder and you help ${ehim} up, the weight of ${ehim} almost surreal against your body.
        
"Thank you," ${ehe} says quietly into your ear, and you swallow the involuntary gulp already thickening in your throat. Regardless, you grip Eli's form hard and steady, and note with a sharp pang of nostalgia that ${ehe} still smells as ${ehe} always did, under all the blood and sweat.

Wet earth and juniper trees.

Specter's portal looms over you both like a dark and strange beast, and without looking at each other you step as one into the abyss.
*page_break
*set reglairespiritgate true
*goto endchapter7

*comment ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ ZEPHYROS BORDER ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

*label zephyrospath
${yusuha} is true to ${yhis} word, and gets to work within the next five minutes. The redhead situates ${yhim}self upon a large clearing, forearm taut as ${yhe} grips the ground with force. You watch as ${yhe} speaks in the ancient tongue—sharp, harsh-edged words unfamiliar even to your trained ears—and feel the air shift as ${yhe} brings the spell into being.

Within seconds, an array of concentric spell circles bloom where the mage's fingers dig into the earth, growing larger by the second as the vibrant red of ${yhis} mana manifests into layers and layers of runes around ${yhim}. ${yusuha} looks up, then, the circle under ${yhim} vibrating with the thrum of ${yhis} power, and as ${yhe} gazes south towards the castle with blinding, irisless eyes, the spell circle disappears in a single instant.

A long, pregnant silence permeates the air.

And then the very horizon twists upon itself.

*page_break

Zephyros comes into being in violent, scathing arcs, painted in streaks by the red of ${yusuha}'s mana. It dawns upon Reglaire Castle in rending gales, savagely uprooting trees and tearing walls asunder, armored bodies bursting through windows as the cyclone cleaves their forms in two. Your jaw falls slack of its own volition as you witness the rampant destruction that ${yusuha} wreaks, the monstrous power ${yhe} holds at ${yhis} beck and call. Thulrum's meteoric ascent appears to you as an increasingly smaller wonder, given that these are the sorts of resources it has at its disposal.

The spell could not have lasted more than a minute, but as it dulls into repose the carnage it had wrought is plain enough to see. Whole sections of Reglaire Castle had been rent into rubble, and in its courtyard, where there were once thickets and topiaries there are now burnt grass overrun by clumps of mangled bodies, their forms casting crooked shadows under the harsh moonlight.

*choice
    #I feel myself trembling. The sight is grislier than anything I could've prepared for.
        *set emotional %+ 15
        You know this is what needed to be done. If Eli is to survive this ordeal, if [i]you[/i] are to survive it, then your opponents needed to fall in their hundreds. You had accepted the cost the moment you cast your vote. But it is one thing to speak of this devastation as a hypothesis, an uncertain thing which yet waits in the horizon. It is another entirely to behold it and know that the sin is yours to bear.
        
        You can scarcely imagine how ${yusuha} must feel.
        
        "Go," the redhead mutters numbly. $!{yhe} does not meet your gaze, does not even register Specter's hasty ministrations of theurgy. "Now, while you have the advantage."
    #I force myself to focus on the lives we've likely saved down the line.
        *set noble %+ 15
        It would be disingenuous to say that you didn't have a selfish stake in this, not when Eli's safety is on the line. But it is also true that your opponents are responsible for some truly heinous acts. They've shown little regard for the lives of others, and would readily sacrifice them in service of a cause stained red with the blood of the powerless.
        
        And so here lays the cruel charge of those with the power to stop them. A merciless pruning, in service of a merciful future.
        
        You can only hope that ${yusuha} can learn to agree.
        
        "Go," the redhead mutters numbly. $!{yhe} does not meet your gaze, does not even register Specter's hasty ministrations of theurgy. "Now, while you have the advantage."
    #It was either me or them. And it certainly wasn't going to be me—not again.
        *set noble %- 15
        You know well the price of trying to do the right thing, no matter what. You've paid it with your lifeblood, again and again, until there was naught left to wring, and nothing to accompany you but a solemn stake and a raging pyre. There at the end of your days, your deeds mattered little, for it had been trivial for others to recast your virtues as villainy. And so if you make it out of your present ordeal in one piece, perhaps the reverse can hold true. Perhaps you can hold to the pretense that it was all for the greater good, and learn to believe it, too.
        
        All of that hinges on your survival today. On whether you are willing to do what must be done.
        
        You can only hope that ${yusuha} can learn to agree.
        
        "Go," the redhead mutters numbly. $!{yhe} does not meet your gaze, does not even register Specter's hasty ministrations of theurgy. "Now, while you have the advantage."
    #I force myself to focus on the mission. No sense dwelling on lives already lost.
        *set emotional %- 15
        There is little space in your thoughts for anything other than the mission's success—and consequently, Eli's safety. You can learn to contemplate the morality of your actions, and indeed the course you have taken, once danger is no longer staring you in the face. For now, the die has been cast, and all that remains is to ensure that something good comes of this carnage.
        
        That task falls to you, for ${yusuha} seems past the point of consolation.
        
        "Go," the redhead mutters numbly. $!{yhe} does not meet your gaze, does not even register Specter's hasty ministrations of theurgy. "Now, while you have the advantage."

*page_break

Specter moves quickly to heed ${yhis} words, his mana bleeding into the air until it forms a sizeable spirit gate. "This will take you to the castle's front door. Retrieve the target and be back as soon as you can; I'll take care of Fox in the meantime."

The rest of the Saber move towards the gate in a wordless flurry, and one by one they disappear into its depths. You pull your mask on,
*if ((mask = "plain") or (mask = "imperial"))
    its cold clay edge
*elseif (mask = "flame")
    the cold edge of its iron
*elseif (mask = "flower")
    the fine edge of its petals
*elseif (mask = "veil")
    its fine samite edge
*else
    the cold edge of its steel
strangely chafing on your bare skin, and follow them into the breach.

*page_break
*label ironscent
The first breath you draw is thick with the iron scent of blood, and the first sight that greets your eyes is one of butchery.

Armored corpses are strewn haphazardly around the large atrium, their expressions twisted in horror and joints bent at unnatural angles. Zephyros has made its mark on the room's every corner, from the deep, burrowing gashes in the obsidian walls to the scattered pieces of heraldic flags painted scarlet by the pooling blood.

You realize with a flash of insight that this is all the work of a single arcanist. Only one of the four in Thulrum's employ, barring yourself, and by all accounts not even its strongest one.

Understanding dawns on you, chilling and slow, of why the Parami were so quick to name you a Demon.

"You!"

The shout rings clearly from across the hall, and as one the four of you turn to regard its source: a stocky, well-built woman, the heraldry of Count Reglaire painted onto her shield—the sign of a Knight Commander. Though her armor is battered and her flaxen hair clotted with blood, her eyes are burning with indignant fury. "You did this!"

The Saber answers her accusation by moving into a combat stance, Colossus taking vanguard with ${falco} and Razor just a step behind him. Around the woman what remains of the comital knights responds in kind, some twenty men with varying degrees of injury rushing at your front line with no regard for the pain that Zephyros had inflicted upon them.

Colossus and ${falco} part from one another as they move to meet the knights in combat, noticeably giving you a wide berth to shoot at the charging knights as they do. They remain silent behind their masks, but you hear their request for support as plainly as if they had put it to word.

*temp marionette_able false
*temp curseofbonds_able false
*temp poltergeist_able false
*temp siegeoffrost_able false
*temp able_any false

*if ((alchemy > 74) and (thaum > 49))
    *set marionette_able true
    *set able_any true
*if ((enchantment > 74) and (spiritism > 49))
    *set curseofbonds_able true
    *set able_any true
*if ((spiritism > 74) and (alchemy > 49))
    *set poltergeist_able true
    *set able_any true
*if ((thaum > 74) and (enchantment > 49))
    *set siegeoffrost_able true
    *set able_any true

*temp crowdspell ""
*temp crowdvar 1
*label spellselect
*choice
    #I cast Siege of Frost.
        Siege of Frost is a spell which forcibly chills the air in a large area and sets it into motion, causing a localized blizzard with a force seldom seen in its natural counterpart. Due to the spell's indiscriminate nature, a specialized barrier glyph is typically employed to limit the spell to a desired area. The limited confines also serves to further strengthen the spell, ensuring that it causes significant devastation over its short runtime. As a result of it requiring significant mastery of both thaum and enchantment, the spell seldom sees use on the battlefield. And yet its capability to wreak havoc against entire platoons makes it one of the true calling cards of any thaumer worth their salt.

        Will you cast Siege of Frost?
        *choice
            #Yes, I'll cast Siege of Frost.
                *label siegeoffrost_fork
                *set crowdspell "Siege of Frost"
                *set crowdvar 1
                *set siegeoffrost true
                *set tcounter +1
                At your will, twin spell circles emerge on either side of you, hungrily draining the mana you've let bleed into the air. The spell's thaum component is the first to reach completion, and immediately you feel the temperature drop as a blizzard begins to form, deep behind enemy lines. It begins subtly enough that many of the knights fail to notice the shift in atmosphere. And by the time it's fully brought to bear, the barrier glyph comes into existence, boxing them in with a spherical wall of force and trapping them with a blizzard at the height of its power.
                
                The true scale of your spell's decimation is obscured by the whirling sleet just under the barrier, which lasts for only a brief ten seconds. The knights outside of the barrier's perimeter react with surprise to its spawning, but discipline quickly takes over and bids them advance towards you. Colossus and ${falco} are quick to take point, the former letting out a battle-cry as he makes wild swipes with his greataxe, and the latter firing off spiritism spells to toss the knights into disarray.
                
                Eventually the spell subsides, and both the blizzard and the barrier dissipates into thin air. What is left in their wake is a battered host of knights, forms bloody and armor cracked, grips loose around the hilt of their weapons. 
                *goto razor
            #No, I think I'll cast something else.
                Which spell will you cast?
                *goto spellselect        
    #I cast Marionette.
        The human body is possessed of a complex biology, but any learned alchemist knows that when stripped down to its most basic elements, it is primarily composed of only a few things. Principal among these is water, that element which pervades flesh and blood and tissue with such ubiquity that control over it necessarily means control over the entire body. Were one possessed of the alchemical learning to know which parts to manipulate, as well as the thaum prowess necessary to execute it, directly hijacking the human body falls well within the domain of magic.
        
        Of course, learned mages and particularly talented fighters will have ways with which to circumvent your control. But the host before you sports a large number of ordinary soldiers and even a few recruits. As such, Marionette should be able to briefly turn some of your foes into allies, sowing chaos within their ranks and rendering them pliant to your companions' assault.
        
        Will you cast Marionette?
        *choice
            #Yes, I'll cast Marionette.
                *label marionette_fork
                *set crowdspell "Marionette"
                *set crowdvar 2
                *set marionette true
                *set acounter +1
                The contrast is strange, at first: your mana hemorrhages into the air, immediately drawing the attention of your opponents, but for a few moments it seems as if nothing tangible has happened. And so it was that when Colossus charges forward with his axe brandished, and ${falco} follows behind him wielding furious bursts of spiritism, the knights are all too eager to ignore you in favor of their showy assault.
                
                Their mistake costs them dearly. You feel the spell complete and settle on a scattering of knights within the host, and will for them to whirl on their own allies. Yelps of surprise resound as those who have fallen under your spell lose control of their own limbs, and begin to bodily charge against their allies, traitorous blades buried in their allies' flesh. The resulting chaos all but collapses their formation and sweeps a wave of panic over the ranks, rendering them pliant to your allies' assault.
                
                Given the spell's difficulty and scale, you could not maintain it for long before your control slips. But it matters little that the spell terminated as soon as it did. The discord is sown, and the knights' infighting yet continues—meaning you've more than accomplished what you set out to do.
                *goto razor
            #No, I think I'll cast something else.
                Which spell will you cast?
                *goto spellselect
    #I cast Curse of Bonds.
        The Curse of Bonds is a complex spell, achieved by harnessing the power of malevolent spirits and binding them to a Glyph-borne hex. Once cast, the curse will affect targets in a wide area. Any pain injury sustained by one of the afflicted will then be replicated by the curse, such that all afflicted will share in the pain. Though the curse inflicts no damage of its own, few will be able to fight effectively under such a relentless bombardment of pain. As such, it should aid a great deal in rebalancing your tremendous numerical disadvantage.
        
        The challenge lies in the construction of a Glyph capable of binding spirits, a feat availed only to true masters of enchantment. One must additionally possess sufficient understanding of the art of spirit-calling, making those capable of casting the curse few and far between.

        Will you cast Curse of Bonds?
        *choice
            #Yes, I'll cast Curse of Bonds.
                *label curseofbonds_fork
                *set crowdspell "Curse of Bonds"
                *set crowdvar 3
                *set curseofbonds true
                *set ecounter +1
                Mana pulses from your form, forging spell circles in midair, and in a second a portal to the beyond spins into existence and yawns open. From its depths emerge a host of screeching spirits, dark wisps trailing in their wake as they race towards your opponents. At the same moment, a massive Glyph completes under the knights' feet, deep within the host; in a panic, they sidestep the Glyph's brightening lines and brandishing weapons against the incoming wave of spirits. Their blades find only air, for the spirits race [i]past[/i their forms and instead moves to meet the Glyph under them, and it only takes another moment for the curse to complete.
                
                For a moment, it is as if nothing at all has happened. And then Colossus and ${falco} leap forward—the former charging like a bull while brandishing his axe, while the latter follows up with a furious barrage of spiritism spells. It is then that the curse properly takes its toll, as the pair's attacks cause phantom pains to reign in the battlefield. Your curse manages to stagger the bulk of the host, the inexplicable bouts of pain bringing them to their knees. Rendering them conveniently pliant to your allies' assault.
                *goto razor
            #No, I think I'll cast something else.
                Which spell will you cast?
                *goto spellselect  
    #I cast Poltergeist.
        Poltergeist deals in the summoning of minor spirits from the beyond, specifically ones capable of acting as a conduit for their summoners' magic. This feature is then combined with countless alchemical runes, which are imprinted upon the spirits as they are let loose upon ones' enemies. Objects and beings which come into contact with the spirits will then suffer random bouts of transmutation, with such effects as painful boils upon one's skin, or the transformation of one's armor into viscous goo. The resulting chaos, especially among large hosts of fighters, will typically disorient targets and compromise their ability to fight, rendering them pliant to your allies' assault.
        
        However, a successful cast of this spell hinges on one's ability to summon these tricky spirits en masse. One must further possess sufficient understanding of alchemy, such that theya re able to imprint upon the spirits the requisite runes.
        
        Will you cast Poltergeist?
        *choice
            #Yes, I'll cast Poltergeist.
                *label poltergeist_fork
                *set crowdspell "Poltergeist"
                *set crowdvar 4
                *set poltergeist true
                *set scounter +1
                Mana thrums in your ear as you bring the spell to bear, maintaining an image in your mind of the two requisite spell circles. The first emerges above you and ravenously sups on your power, coagulating it into a dark, turbulent mass—a gate to the beyond. It yawns open at your command, brimming with spirits eager to cross the border within realms. Before they do, you erect the second spell circle right in front of the gate, one which will impart the alchemical runes onto the spirits. The gate then breaks loose, and before long your opponents find themselves mired with otherworldly creatures which deliver havoc well behind their front lines.
                
                The effects are widespread and instantaneous. You watch as metal is heated and frozen at random, some knights screaming as their own armor sears their skin, while others are forced to drop their weapons as it crusts over with heavy rime. Some of the knights hit directly by the spirit grow green in the face as the very air they breathe are shot through with poison, and others still sustain great laceration wounds as their very skin are spirited into air. The spell descends upon the whole host with neither rhyme nor reason, and while many of the knights are lucky enough to escape Poltergeist's adverse effects, the chaos sown within their ranks is ubiquitous.

                Colossus and ${falco} are quick to take point, the former letting out a battle-cry as he makes wild swipes with his greataxe, and the latter firing off spiritism spells to toss the knights into even greater disarray. Razor spares you an appreciative nod, and a second later she's embedded herself deep within enemy ranks, joining her companions as they lock up with the opposing force in earnest combat.
                *goto threesaber
            #No, I think I'll cast something else.
                Which spell will you cast?
                *goto spellselect
    *if (able_any = false) #I am unable to cast any of these spells at present.
        (A/N. Due to the spells of this scene requiring many different permutations of spell proficiency parameters, it may be the case that you are presently unable to select any of the options presented. All the options listed above are the ones that will grant the best results (aka maximum prestige) in this scene, but in future builds there will be options with less demanding parameters and suboptimal results. Those options are not yet presented in this build. For the time being, please select which of the best-results spells you would like to cast.)
        *choice
            #I cast Siege of Frost.
                *goto siegeoffrost_fork
            #I cast Marionette.
                *goto marionette_fork
            #I cast Curse of Bonds.
                *goto curseofbonds_fork
            #I cast Poltergeist.
                *goto poltergeist_fork            

*label razor
Razor turns and nods at you approvingly, and not a second later she moves to join ${falco} and Colossus, locking up with the opposing force in earnest combat.

*label threesaber
The three Saber warriors display an uncanny level of coordination, Colossus playing frontline fighter as he throws his axe around in big, showy arcs meant to monopolize the enemy's attention. The distraction allows Razor to sneak past the brunt of the charge and plant poisoned daggers in the enemy's backs, any retaliation on the knights' part finding only air as she weaves through the battlefield with masterful ease.

${falco}, meanwhile, throws ${fhim}self deep behind enemy lines, ${fhis} ornate lance thrusting every which way, slipping through the gaps in the knights' armors and ripping through their flesh like butter. The white-haired mage doesn't so much as flinch even as the knights crowd around ${fhim}, the Knight Commander wading towards the front of the charge; an involuntary warning rises like bile in your throat as she raises her blade high, the silver steel slick with blood as she brings it down to bear—

And then that dark, serpentine creature rises out of the skin on ${falco}'s back, its scales harsh and glimmering and its jaw agape, revealing a full set of saber-like teeth. The knight commander's eyes widen, equal parts surprised and horrified, but she is propelled by her own forward momentum and is forced to meet her blade against the creature.

The serpent hisses as sanctified steel digs into its cheek, but with a backwards rear and a jerk of its head the blade is thrown edgewise and the knight Commander left unarmed. The creature then swoops downward at a dizzying speed, its fangs sinking into the woman's torso as an anguished bellow escapes her throat.

She falls into silence within moments, and the serpent—${falco}'s arcana—sinks back into its master's back.
*page_break
You swallow the thickness forming in your throat and rapidly cast a second round of ${crowdspell}, @{crowdvar the raging blizzard tearing asunder what formation the knights had managed to cobble together. The spell comes and goes in mere moments, but you successfully break your opponents' momentum, and your allies are quick to seize the advantage. The Saber's cold iron and spells find their mark again and again, with such brutal efficiency as to leave you feeling sorry for your opponents.|and once more a portion of the knights are relieved of the control of their own limbs. The spell was haphazardly crafted, and goes before long—still the chaos it sows endures long after the spell itself has expired, and your allies are quick to seize the advantage. The Saber's cold iron and spells find their mark again and again, with such brutal efficiency as to leave you feeling sorry for your opponents.|the affliction taking hold once more over a sizable bulk of the knights. Now knowing what to expect, your allies are quick to seize the advantage, and the phantom pains pervading across your opponents' ranks soon rends what momentum they had managed to take back.|and once more spirits sail across the atrium, their ensorcelled runes punching through what semblance of a formation the knights had managed to cobble together. As armor transmutes into dust and blades melt in their hands, the knights are once again rendered pliant, a fact which your allies are quick to seize advantage of. The Saber's cold iron and spells find their mark again and again, with such brutal efficiency as to leave you feeling sorry for your opponents.}

It becomes apparent to you that the battle will be settled in your favor before long.

Suddenly, out of the corner of your eye you catch sight of a leaping shadow, nimble and agile in a way that no heavily-armored knight could be. You reach instinctively for the first offensive spell that comes to mind, but even as @{specialvar Morana's Wail|Clay Cannon|the Glyph of Subjugation|Fist of the Dark Lord} is still forming the shadow is already perched behind Razor, their throwing knives slick with a venomous coat as they graze against the rogue's neck.

Razor lets out an expletive as she falls to her knees, and Colossus and ${falco} both respond by disengaging from their foes. ${falco} opts to leap forward in pursuit of the shadow, the back of ${fhis} garment roiling as the serpent rears its head. Meanwhile, Colossus rushes to Razor's side, clearing the path with large swings of his axe. You let loose the @{specialvar Morana's Wail|Clay Cannon|Glyph of Subjugation|Fist of the Dark Lord} you'd been casting to cover their retreat, yourself already en route to the injured rogue's side.

"Damn it," she hisses when you arrive, her hand pressed against the nape of her neck. "Reon venom. Of all the things…"

You can't help but to share in her astonishment. The Reon viper is a species exclusive to the Cold South, an imperial territory far beyond Arvanian waters. So seldom is its poison seen in Arvanand that barely any alchemist in the continent has even heard of it, let alone have its antidote on hand.

You'd be hard-pressed to identify it on your own, but with Razor's claim to go off of, you find that you can confirm her theory. The venom must presently be creeping into her bloodstream, and if untreated Razor will sustain permanent damage to her internal organs that may very well kill her within the year.
*temp venomalchemy false
*temp venomlearning false
*temp venomenchantment false
*temp cantreatvenom false
*if (alchemy > 65)
    *set venomalchemy true
*if (learning > 65)
    *set venomlearning true
*if (enchantment > 74)
    *set venomenchantment true
*if ((venomalchemy) or ((venomlearning) or (venomenchantment)))
    *set cantreatvenom true
*temp usedalchemy false
*temp usedenchantment false
*temp usedlearning false
*choice
    *selectable_if (alchemy > 65) #I give her homebrewed cure-alls that will stem the worst of the damage.
        *set cureall true
        *set usedalchemy true
        *set prestige +3
        No one sane would brew Reon antivenom in Arvanand, as the toxin it cures only sees widespread use in other parts of the world. To transport it to Arvanand would require a specific means of storage with a steep price tag, and so even those seeking to use exotic potions unknown to the land would typically opt for a bevy of other options.
        
        As it stands, the cure-all is the best yo can do. You've never had the resources to put the recipe to the test before, but the Church's pantry is stocked with medical herbs of all shapes, sizes, and origins. They're hardly a prime exhibit of your abilities, given the limited amount of time you had to work with, but they will have to do.
        
        You procure the medicine pouch from your belt with haste, spilling out its contents onto the palm of your hands: three gray, spherical pellets, unimpressive in appearance—a perfect contrast to the potency of its effects.
        
        "Cure-alls," Razor says between ragged breaths. "Damn, you'll have to teach me how to make these when we get back."
        
        *choice
            #"I will, but you'll have to survive first. Eat up."
                *set charming %+ 10
                Razor manages a weak grin. "You don't have to tell me twice." 
            #"Not a chance."
                Razor barks out a laugh. "And here I thought we were getting all chummy."
            #I grunt noncommittally.
                Razor barks out a laugh. "Don't underestimate me, ${callsign}. I'll get it out of you yet."
        
        Razor downs the pellets in a single big gulp, just as Colossus rises onto his feet to parry a blow from what remains of the comital guards. "Help him," the rogue rasps, her grip once again firm upon the hilt of her daggers. "I can still defend myself, if it comes down to it. I'll be fine."
        
        You nod at her words, mana pricking at the tip of your fingers as you rejoin the battle in earnest.
    *selectable_if (learning > 65) #I try an unconventional first-aid measure I've seen described in Imperial tomes.
        *set prestige +3
        What with Reon venom being a combat staple across the sea, the imperials have developed myriads of ways to deal with its effects. It just so happens that one of its more esoteric antidotes should be readily on hand, given Razor's affinity for poisons.
        
        You rummage through the rogue's combat pouch and find exactly the article you need: a small crystalline vial, containing drops of gleaming blue liquid, gleaming with a metallic sheen.
        
        In the Cold South, Heim and Reon vipers have been locked in a millenia-spanning rivalry as they compete for dominance over the barren wilds; as a result, each of their venoms have weak neutralizing properties against the other. Unlike the Reon, however, Heim vipers have shown resilience towards the Arvanian clime and could survive as a population in its wilderness. Their paralyzing venom has since become a favorite of any toxin user worth their salt.
        
        Razor, as it turns out, is no exception.
        
        The rogue recoils in horror as you unclog the vial and make to pour it over her injury.
        *choice
            #"Trust me, I know what I'm doing."
                Razor knits her eyebrows together, the beginnings of a protest already on the tip of her tongue.
                
                "Accept the treatment, Razor," Colossus calls out, already on his feet as he parries a blow from an assaulting knight. "@{pronvar He's|She's|They've} already said that they'll cooperate for this mission. We should trust ${them} with at least this much."
                
                Thought the hesitance never quite leaves her eyes, she rasps her concession all the same. "Alright," she says, resigned. "I'll leave it to you, then."
            #"Don't give me that. If I wanted you dead, I'd just let the venom run its course."
                Razor's protests die in her throat, and she looks chastened as she understands your words to be truth. "Alright," she rasps, resigned. "I'll leave it to you, then."
            #I roll my eyes. If she refuses to accept the treatment, then so be it.
                "Accept ${their} help, Razor," Colossus says, already on his feet as he parries a blow from an assaulting knight. "@{pronvar He's|She's|They've} already said that they'll cooperate for this mission. We should trust ${them} with at least this much."
                
                Thought the hesitance never quite leaves her eyes, she rasps her concession all the same. "Alright," she says, resigned. "I'll leave it to you, then."
                
        Razor lets out a strangled yelp when the venom makes contact with her exposed flesh, her entire form shaking as the toxin begins entering her bloodstream. "This isn't a perfect solution," you warn, tossing the vial edgewise. "It will dampen most of the long-term effects, but the pain won't be better for some time yet."
            
        "Fine. This…I can deal with this," the rogue hisses, sounding as if she's trying to convince herself, as well. "Go help Colossus—I'll be able to defend myself just fine. And—thank you."
    *selectable_if (enchantment > 74) #I cast a modified Glyph of Immunity, trying to at least stop the poison from reaching her vitals.
        *set glyphofimmunity true
        *set prestige +3
        It is delicate, hazardous work to cast the Glyph on one already inflicted. The bulk of the work has to do with mana control—too little would make it a poor salve in stopping the venom, while too much would only cause an adverse reaction.
        
        Regardless, you are left with no other alternatives. The Glyph gives off a dull ebbing glow as you will it into existence, and Razor jerks away almost reflexively at your proposed choice of treatment. You find it difficult to blame her—after all, it is common wisdom among mages that enchanters should not play-act at theurgy, lest their patient pays the price.
        *choice
            #"Trust me, I know what I'm doing."
                Razor knits her eyebrows together, the beginnings of a protest already on the tip of her tongue.
                
                "Accept ${their} help, Razor," Colossus says, already on his feet as he parries a blow from an assaulting knight. "@{pronvar He's|She's|They've} already said that they'll cooperate for this mission. We should trust ${them} with at least this much."
                
                Thought the hesitance never quite leaves her eyes, she rasps her concession all the same. "Alright," she says, resigned. "I'll leave it to you, then."
            #"Don't give me that. If I wanted you dead, I'd just let the venom run its course."
                Razor's protests die in her throat, and she looks chastened as she understands your words to be truth. "Alright," she rasps, at once hesitant and resigned. "I'll leave it to you, then."
            #I roll my eyes. If she refuses to accept the treatment, then so be it.
                "Accept ${their} help, Razor," Colossus says, already on his feet as he parries a blow from an assaulting knight. "@{pronvar He's|She's|They've} already said that they'll cooperate for this mission. We should trust ${them} with at least this much."
                
                Thought the hesitance never quite leaves her eyes, she rasps her concession all the same. "Alright," she says, resigned. "I'll leave it to you, then."
        
        Razor lets out a strangled yelp when the Glyph's effects course through her bloodstream, teeth ground together as she forces herself to remain still. "This isn't a perfect solution," you warn, after the Glyph has run its course. "It will dampen most of the long-term effects, but the pain won't be better for some time yet."
            
        "Fine. This…I can deal with this," the rogue hisses, sounding as if she's trying to convince herself, as well. "Go help Colossus—I'll be able to defend myself just fine. And—thank you."
    #There's nothing I can do for her, and I tell her as much.
        *set razorready false
        "There's nothing we can do," you say, resigned. "None of us could have expected Reon venom of all things."
        
        Razor heaves a resigned sigh, her form shaking as she pushes herself upright. "It's fine. Go," she breathes, her voice ragged with exertion. "The poison stings, but I can still defend myself. Perhaps if we could get to your friend in time, ${ehe} could…no, never mind that. The mission takes priority."
        
        Colossus gives a low grunt beside you, but a thundering of enemy footsteps forces him to pick up his broadaxe and engage them in combat once more. Razor motions for you to help him, and you find that it is all you could do to obey her words.

*page_break
${falco} returns just as you and Colossus finish off the last of the knights, dragging the shadow—the shadow's [i]corpse[/i], more accurately—by the hair.

"A troublesome foe," ${fhe} remarks, dumping the body face-down in front of the group. There is a chunk of flesh missing from the corpse's torso, and you find it easy to guess where it went. "Moreso than he should've been. Well-trained, lots of unconventional tactics…I have a feeling we're dealing with more than just the Count here."

"Zealot," Colossus interrupts, jerking his head towards Razor's limping form. "Razor is injured. Will you take her back to Specter?"

Razor lets out an offended noise at the proposition, swinging her gaze around to the hulking man.
*if (razorready = false)
    "Don't waste your breath. This isn't something Specter can treat, and Zealot needs to conserve—" Razor pauses, for a moment, and looks to be summoning her strength. Colossus reaches out a worried arm, and drops it when Razor glares through her mask. "$!{fhe} needs to conserve ${fhis} strength or the ambush."
    
    The towering man looks as if he's about to protest, but ${falco} holds a hand up to silence him. "Razor is the expert on toxins here. If she says Specter won't be able to treat her, then we'd best trust in her judgment," ${fhe} says tersely. "The person we came here for may well be our only hope. If we are to help Razor, then we must secure ${ehim} immediately."
    
    Razor looks up at Colossus, her gaze imploring. "I'm a fighter," she declares, and though her voice has begun to tremble you can't help but to think of it as [i]strong[/i]. "You know I can get through this."
    
    Colossus tosses his gaze to the ground, resigned. "Then stay here. Out of sight, Razor. We will bring ${ehim} to you quickly."
    
    Satisfied with Colossus's compliance, ${falco} turns ${fhis} gaze towards the castle's west wing. "The dungeon is that way. Whatever group this assassin belongs to is trouble; we'll need to be on our toes."

    You respond to ${fhis} warning with a solemn nod, knowing that despite the ambush being a near-certainty, there is nothing you could do but to keep moving forward. You shake the fatigue out of your bones and will your nerves to settle, and join your allies as they move as one towards the castle's dungeon.

    Towards Eli.
    *goto endatrium
*else
    *set rfalco %+ 8
    "I told you, I'm [i]fine[/i].
    *if (usedalchemy)
        ${callsign}'s cure-alls did the trick—for
    *elseif (usedenchantment)
        ${callsign}'s enchantment did the trick—for
    *else
        ${callsign}'s odd trick is working—for
the time being, at least. The best thing that can happen for me now is for [i]${ehim}[/i] to be freed. You know that as well as I do."

${falco} turns to regard you, eyes scrutinizing. You get the sense that ${fhe}'s trying to feel out the motivation behind your act. Evidently, ${fhe} finds it difficult to believe that you'd willingly help a Saber agent given your past loyalties.
*choice
    #"No, I don't have an angle. It was just the right thing to do."
        *set noble %+ 15
        *label preemptive
        Your preemptive retort catches the spiritist off-guard, for a moment, though ${fhe} is quick to regain ${fhis} composure. "I didn't say anything," ${fhe} points out.
        
        "Oh, you were trying to be subtle? Try it without the glare next time. It was a dead giveaway."
        
        ${falco} scoffs at that, before turning ${fhis} gaze towards the castle's west wing. "The dungeon is that way. Whatever group this assassin belongs to is trouble; we'll need to be on our toes."
    #"I wasn't about to just leave her to her fate. What do you take me for?"
        *set noble %+ 15
        *goto preemptive
    #"You needn't be so surprised. I intend to hold up my end of the bargain."
        *set noble %- 15
        *goto preemptive
    #What is ${fhe} looking at? I return ${fhis} glare with my own.
        *set charming %- 15
        Your silent war lasted all of five seconds before Colossus decides to step in. "You're wasting time," he says severely, shaking his head. "Our work is not finished."
        
        "No. No it isn't," ${falco} agrees, though it takes ${fhim} a moment more to properly withdraw ${fhis} glare. $!{fhe} turns then to the castle's west wing. "The dungeon is that way. Whatever group this assassin belongs to is trouble; we'll need to be on our toes."

You respond to ${fhis} warning with a solemn nod, knowing that despite the ambush being a near-certainty, there is nothing you could do but to keep moving forward. You shake the fatigue out of your bones and will your nerves to settle, and join your allies as they move as one towards the castle's dungeon.

Towards Eli.
*label endatrium
*page_break
The dungeon air is cold and musty, the stone flooring slippery where your blood-slick shoes graze against the surface.

Colossus leads the way with his broadaxe brandished—the sheer girth of which makes it something of a pseudo-shield—while the rest of the party trails behind him. You do your best to remain silent and discreet, but
*if (razorready)
    Colossus's massive form does away with any hope of stealth. His footsteps ring loudly across the empty stairway. If there is an ambush waiting, they will have heard your coming from the very first step.
*else
    Colossus weighs more than you and ${falco} combined, and his steps ring loudly across the empty stairway.

When you make it to the cell area—where Eli is held, if Razor's intel is to be trusted—the place is shrouded in darkness and perfectly silent. You could make out a shadowy outline in the farthest cell to your left, arms spread upwards and presumably chained to the walls, and feel your heart beat faster as you realize that the form may very well be Eli.

*temp wefeeling""
*choice
    #If it weren't for fear of the ambush, I'd have sprinted to ${ehis} side.
        *set emotional %+ 15
        *set wefeeling "turmoil"
        You miss ${ehim}—more than you can rightly express. It feels like an eternity has passed since you last felt ${ehis} gentle companionship, steady and stalwart even in the face of ${ehis} suffering. $!{ehis} visage had graced your dreams for as long as you can remember—in turns anguished, happy, and serene—and it feels like a gentle fiction, too good to be true, that ${ehe} could be a part of your life once more.
    #$!{ehe}'ll have to wait. Recklessness will only lead us both to our demise.
        *set emotional %- 15
        *set wefeeling "onguard"
        And it wouldn't be the first time for either of you, either. You had both spent your life willingly for the benefit of others—a touch of self-preservation this time around could only do you both good.
    #I have to rescue ${ehim}. $!{ehe}'s an arcanist, and one I can trust unreservedly.
        *set noble %- 15
        *set wefeeling "onguard"
        You're in uncertain territory now, after all, and there's no telling what designs Arcadia has waiting for you and for Arvanand as a whole. Having someone you can trust by your side—someone Tahlia is desperate to get on hers—would be a powerful bargaining chip against them, ensuring you don't get sucked into their plans against your will.
    #Guilt overwhelms me. Just one other way ${ehe}'s had to suffer—all because of me.
        *set noble %+ 15
        *set wefeeling "turmoil"
        You have always known Eli to be competent and resourceful, so much so that ${ehe} would have never allowed ${ehim}self to be in this position. But ${ehis} sacrifice—through which ${ehe} had purchased your survival—had placed ${ehim} at Tahlia's mercy. And you're willing to bet good coin that ${ehe} would have steered clear of this mess were it not for ${ehis} involvement with Arcadia.
    #$!{ehe}'s pitiful, as am I. I wish things could have been different for us both.
        *set wefeeling "turmoil"
        In another world, perhaps you could have led simple and content lives, so far removed from mages with grand ambitions and the burdens of ancient bloodlines. Perhaps you could have been spared the torture of watching everyone you love slowly march to their demise, of being powerless as death then turns its savage attention on you. What a privilege that would have been.

*if (wefeeling = "turmoil")
    ${falco} drinks in the sight of the dungeon, ignorant of your inner turmoil.
*else
    ${falco} drinks in the sight of the dungeon, your own wariness reflected in ${fhis} posture.
You can feel ${fhis} mana prickling underneath ${fhis} skin, taut and ready to be unleashed at the first sign of hostility. And though the dungeon remains perfectly silent all
*if (razorready)
    four
*else
    three
of you are experienced combatants, and there is tension in the air that feels distinctly hostile.

"Tch, I knew it," ${falco} hisses, ${fhis} mana spiking to dangerous levels. For a moment you nearly ask ${fhim} what ${fhe} means by that, but you are instead stunned into silence as the white-haired mage bodily tackles you to the side.

You feel the cold stone flooring against your bare skin for less than a second before ${falco} pulls you back to your feet, and through your disorientation you realize that in the spot you had been standing on is now a collection of throwing knives, their entire length coated by the blue sheen of Reon venom. You realize with sinking horror then that were it not for ${falco}'s timely intervention,
*if (cantreatvenom = false)
    you may well be sharing Razor's fate right now.
*else
    the venom would be coursing through your bloodstream right now.

The blood chills in your veins as ${falco} draws ${fhim}self up beside you. The mage quickly disentangles ${fhis} hands from your arms and hisses at the looming darkness. "Show yourselves," ${fhe} calls out, ${fhis} spear brandished.

${falco}'s demand is answered by a baleful silence, for a while, but soon there's a series of slow footsteps from the other side of the hall and a cloaked figure comes into view. "Well done," he says, lowering his hood to reveal a black-haired man looking to be well into his forties. His Salantir accent sounds studied, and the lilts of his true tongue—one you're presently unable to place—peek out through his consonants. "We had been so confident that the poor count's guards would keep you all at bay—it certainly speaks well of both your magical and tactical prowess for you to have bypassed them entirely. Would you bestow upon me the names of such fine fighters?"

${falco} answers the question by dropping into a combat stance. "You have one of our people," ${fhe} proclaims. "You'd best hand ${ehim} over while we're still asking nicely."

"It's poor manners to make such lofty demands of your host, dear visitor," the man responds with a sneer. He maintains an expertly neutral expression as he steps forward, his gait marking the fact that he's wholly assured of his own power. "Especially when you've just sent all my best pawns six feet underground."

"You will join them soon enough, unless you do as we ask," ${falco} spits.

The man cackles at the threat, the ring of his laughter sinister as it echoes through the dungeon. "We shall see just who puts down who if we come to blows. But I think you'll find that aggression will be quite costly for you," he warns, a derisive smile tugging at the corner of his lips. "Come join us, won't you, my good Count?"

You hear a second set of footsteps behind the stranger's back, then, and out of the gloom a balding, heavyset man appears, dragging a barely-conscious @{evar man|woman} with him.

Your eyes nearly bulge out of your skull as they trail over the familiar form, and for all that you knew that ${ehe} would be here it is a different thing entirely, to see ${ehim} in the flesh. Many things have changed about the @{evar man|woman} since you last saw ${ehim}, all those years ago—${ehe} is much taller now, but still keeps ${ehis} @{evar black hair shorter, neat and tidy as ${ehis} sword instructor had required|hair longer, the locks a luminous black even under the clots of blood and sweat}. There is a sliver of defiance percolating those familiar brown eyes, but against the enchanted bindings clasped around ${ehis} wrists ${ehe} is powerless, arms hanging limply at ${ehis} side.

Eli is alive. Close enough to reach out to. Close enough to touch.

And ${ehe} has a dagger pressed against ${ehis} throat.

"D-don't come any closer," the count says, his voice trembling with fear. "I-I don't know who you are, but just leave us be! Leave us be and I'll f-forget about this incident."

"Don't presume to make demands of us!" ${falco} yells, and as the count flinches backward at the aggression his dagger digs into the skin of Eli's neck. It is a shallow cut, by all measures, but the way it only misses the @{evar man|woman}'s carotid by a hair sends shivers up your spine. Eli lets out a distressed grunt, but remains otherwise silent.

"Provoke the count at your own peril, dear guests," the stranger jeers. "But lucky for you, he is not an unreasonable man—and neither am I. You are such curious existences, after all! Do not think me ignorant to the skill it must have taken, to engage Spirit Gate as you have. To think such talented mages have managed to hide themselves from the world's stage. I imagine the Hero of Sienan was much the same way before ${they} decided to crown the Sun King." Your jaw tenses at the mention of the epithet—it appears your reputation has grown even more outsized than you imagined. "Our interest in such firepower is quite keen, as you might imagine. So let us negotiate: what will you give us in exchange for this @{evar man|woman}'s safe return?"

${falco} bristles beside you, and you recognize with some alarm that ${fhe} will likely try ${fhis} chances at a frontal assault. The white-haired mage is fast, and a competent fighter besides—it is very likely that ${fhe}'ll be able to free Eli if you let ${fhim} push forward. But for all that the stranger's confidence could all be naught but a bold-faced bluff, you don't even want to think about what will happen to Eli on the off chance that it's not.

*if (razorready)
    You hear Razor shift behind you, then, her steps quiet and deliberate as they scrape forward on the stone floor. A signal, clearly, but for what...?

    And then it hits you like a Morana's Wail: the rogue is terrific at concealing her presence, even in plain sight of her enemies. You don't quite know how she achieves the effect, but she was able to make it deep enough into this castle to gather intel—all of which has been spot on up to this point. She has escaped the hostile party's notice once before, and there is no reason to believe that she can't repeat the feat.

    You just need to keep the stranger distracted.

*else
    Regardless, it may be a good idea to let ${fhim} take ${fhis} chances. If you can keep the stranger engaged with fibs and false leads, perhaps the twosome will be distracted enough to give ${falco} the window ${fhe} needs.


*if (razorready)
    *choice
        *selectable_if (charisma > 59) #I'll play-act at negotiating to stall for time.
            *goto charismapath
        *selectable_if (thaum > 59) #I go for the weak link, firing a Thunderstrike to prime him for a follow-up attack.
            *goto thaumpath
        *selectable_if (enchantment > 59) #I'll use a Glyph of Subjugation to force the count to release Eli. (Incomplete)
            (This path is currently in development. You will be redirected to the Charisma path).
            *goto charismapath
        #There's nothing I can do to help ${falco}, but I have faith that ${fhe} can get the job done and do it well. (Incomplete)
            (This path is currently in development. You will be redirected to the Charisma path).
            *goto charismapath
*else
    *choice
        *selectable_if (charisma > 59) #I'll play-act at negotiating to stall for time.
            *goto charismapath
        *selectable_if (thaum > 59) #I go for the weak link, firing a Thunderstrike to prime him for a follow-up attack.
            *goto thaumpath
        *selectable_if (enchantment > 59) #I'll use a Glyph of Subjugation to force the count to release Eli. (Incomplete)
            (This path is currently in development. You will be redirected to the Charisma path).
            *goto charismapath
        #There's nothing I can do to help ${falco}, but I have faith that ${fhe} can get the job done and do it well. (Incomplete)
            (This path is currently in development. You will be redirected to the Charisma path).
            *goto charismapath

*label charismapath
"Return our friend to us, and we will provision you with information," you say judiciously, and the man's lips curl into a satisfied smirk. Clearly, this the prize he's been angling to get. "You think us a curious existence? Be curious no more. Swear that you will let our associate go, and we'll answer any questions you have for us."

"Very good. I knew we could come to an agreement," he says, preening like a bird. "Of course, whether I see through my end of the bargain largely hinges on the quality of your information. And please, for both our sakes—let's not try to lie, shall we? I am trained in the art of seeing through deception, and I would so hate for our amicable negotiations to fall through."

"You have my word," you say, and mean it.
*if (noble > 50)
    You would rather see the stranger keep his head, but you get the distinct impression that ${falco} will see him dead tonight, one way or another. It does Thulrum no harm to have its secrets disclosed to a man whose fate is already sealed.
*else
    There is no harm in telling secrets to a dead man, after all. And he [i]will[/i] lose his head tonight—by ${falco}'s hand, if not by yours.
            
You speak of Arcadia in grandiose flourishes then, of a network with roots spanning the entire continent, of magic long thought to be lost to the annals of history. The man listens intently with fascination and barely-contained glee—as if he hadn't just made an enemy of one of the strongest factions in the land—but you achieve the desired effect. He is lulled into a false sense of security as he latches onto your every word, and
*if (razorready)
    *set prestige +3
    Razor seizes the first opportunity she is presented.
        
    She leaps forward like a bolt of lightning—enchanted with ${falco}'s Glyph of Swiftness, judging by the violet mana surrounding her body—and plants her dagger in the count's throat before the man could so much as react. The count makes a gargling noise as blood floods his trachea, the dagger he had held against Eli's throat clattering uselessly onto the stone floor.
    
    His companion widens his eyes in surprise and makes a grab at Razor, but the rogue is already retreating with Eli's incapacitated form in tow.
*else
    *set prestige +1
    ${falco} seizes the first opportunity ${fhe} is presented.
    
    $!{fhe} leaps forward like a viper uncoiling—enchanted with a Glyph of Swiftness, most likely, though you have to wonder how ${fhe} was able to cast it so discreetly—and makes to catch the count in the gut with ${fhis} spear. The man twists away from ${falco}'s assault just in time, his knife digging deeper into Eli's neck before he lets healer and dagger both go, choosing instead to cower behind his companion.
    
    Said companion's face twists in contempt—most of it directed towards the count, most likely—as he makes a grab at ${falco}, but the mage is already retreating with Eli's incapacitated form in tow.

"Get them!" the man bellows then, and in a single second it is as if the whole room is closing in on you.
*goto encroach

*label thaumpath
*set thunderstrike true
*set tcounter +1
It is delicate work to signal your plan to your allies, to make your mana spike in just the right amount to alert them—[i]and only them[/i]—that you're up to something. But years spent studying the volatile art of thaum has made you an expert in mana control and restraint, and when you see ${falco}'s eyebrows raise almost imperceptibly you know that the deed is done.

"We are not closing the possibility of partnership, if your group can make itself useful to us," ${falco} says judiciously, though you know full well the white-haired mage would love nothing more than to rip the stranger's head from his torso. "But taking a hostage is a poor way of soliciting our cooperation."

"Now, now, I wouldn't use the word [i]hostage[/i]," the man chides. "We are simply seeking fair compensation for services rendered. After all, is it not the case that your friend here—"

His spiel is interrupted as you bring the spell into being with a violent crackle, the bolt of thunder racing across the room to catch the count in the chest. The nobleman lets out an anguished yelp as the spell runs through his body in vicious bursts, the dagger he had held against Eli's throat clattering uselessly onto the stone floor.

*if (razorready)
    Razor leaps forward in great leaping strides, then—enchanted with ${falco}'s Glyph of Swiftness, judging by the violet mana surrounding her body—and plants her dagger in the count's throat before the man could so much as react. His companion widens his eyes in surprise and makes a grab at Razor, but the rogue is already retreating with Eli's incapacitated form in tow.
*else
    $!{fhe} leaps forward like a viper uncoiling—enchanted with a Glyph of Swiftness, most likely, though you have to wonder how ${fhe} was able to cast it so discreetly—and successfully aims a fatal blow at the count's throat. His companion widens his eyes in surprise and makes a grab at ${falco}, but the white-haired mage is already retreating with Eli's incapacitated form in tow.

"Get them!" the man bellows then, his face red with fury, and in a single second it is as if the whole room is closing in on you.
*label encroach
*page_break
It takes you a second to realize that the encroaching darkness are actually black-clad warriors, the air around them still crackling from dispelled Glyphs of Invisibility. You wonder for a second just how it is that they managed to conceal their presence so perfectly, but the sudden flurry of throwing knives bid you focus on the battle instead.

Colossus and ${falco} coordinate a serviceable if desperate defense plan, with the taller man weaving his axe through the air to repel the incoming projectiles. ${falco}, meanwhile, takes to casting Fists of the Dark Lord to swipe the attackers off balance and stymie their relentless
*if (razorready)
    assault, while Razor returns fire with throwing knives of her own.
*else
    assault.

And yet the black-clad warriors seemed to shrug off most of your counteroffensive, quickly regaining their footing and encroaching upon your position. You suspect that the icy blue aura surrounding their forms might have something to do with it—a cocktail of enchantment spells woven together, if you had to guess, resulting in a nearly impervious wall of fighters surrounding you on all sides.

Colossus grunts in front of you as a flurry of blue-coated throwing knives plant themselves in his arm—blessedly a non-fatal location for Reon venom, though you imagine the wound is painful all the same—and then ${falco} calls out to you. "${callsign}!"

You are on the task even before the last syllable is finished. Your mana grows and crests as the spell you've been preparing finally settle on your fingertips, and you unleash...

*choice
    *selectable_if (enchantment > 65) #...Glyphs of Dispel, mass-casted. ${falco} and Colossus should be capable of handling the enemies given equal ground.
        *goto enchant2
    *selectable_if (enchantment > 74) #...Glyphs of Dispel, as well as Glyphs of Protection for my allies. Why would I just settle on equal ground, after all?
        *goto enchant1
    *selectable_if (thaum > 74) #...Sunflame. Short of Skywrath, it's the only spell I have that's strong enough to eat through resistance enchantments.
        *goto thaum1
    *selectable_if (thaum > 65) #...Stone Graveyard. I'm not confident enough in my ability to control Sunflame in such close quarters, but Stone Graveyard should at least help my allies get a leg up.
        *goto thaum2
    *selectable_if (spiritism > 49) #...Fist of the Dark Lord. Perhaps reinforcing ${falco}'s assault with my own can help tip the balance.
        *goto spirit
    *selectable_if (alchemy > 49) #...Clay Cannon. Perhaps reinforcing ${falco}'s assault with my own can help tip the balance.
        *goto alchemy

*label enchant1
*set glyphofdispel true
*set glyphofprotection true
*set ecounter +2
You feel your mana ducts going into overdrive as the Glyphs manifest, the sensation not unlike that of calling upon ${phant1}'s power, if without the painful searing sensation of @{phantvar him|them|him|her} overloading your synapses. Your enemies' enchantment puts up quite the resistance to your efforts—whoever is behind them must be an enchanter of true mettle—but with a final, straining push you manage to overpower them, and the blessing hemorrhages into the air before dissipating into nothingness.

${falco} is quick to seize the advantage, leaping forward as projectiles careen off ${fhis} body due to your Glyph of Protection, and launches a deadly assault against the attackers' front line. No longer on ${fhis} backfoot, the white-haired mage calls upon ${fhis} phantasma once more, the scaled serpent all fangs and bludgeoning strength as it wreaks havoc behind enemy lines. Colossus follows suit behind ${fhim}, a terror in his own right as he forcefully bashes the enemies' skulls open,
*if (razorready)
    Razor using her hulking companion as cover as she aims poisoned daggers at their throats.
*else
    any resistance he faces dampened by your continued casting of the Glyph.
*goto successplus

*label enchant2
*set glyphofdispel true
*set ecounter +1
You feel your mana ducts going into overdrive as the Glyphs manifest, the sensation not unlike that of calling upon ${phant1}'s power, if without the painful searing sensation of @{phantvar him|them|him|her} overloading your synapses. Your enemies' enchantment puts up quite the resistance to your efforts—whoever is behind them must be an enchanter of true mettle—but with a final, straining push you manage to overpower them, and the blessing hemorrhages into the air before dissipating into nothingness.

${falco} is first to seize the opportunity, launching ${fhim}self into a deadly dance of lanceplay and spiritism. The fighters' disorientation at having their blessing removed allows ${fhim} to advance past enemy lines easily, at first, but it isn't long before your opponents regain their footing and begin responding in kind. The white-haired mage hisses as knives and blades alike dig into ${fhis} skin, but then Colossus rushes forward to buy ${fhim} cover—enough for ${fhim} to call upon ${fhis} arcana.

The scaled serpent rears its head from the mage's back, then, all fangs and bludgeoning strength as it wreaks havoc amidst your foes. You cast a second round of Stone Graveyard to seize on the momentum, and with that last bit of support your allies push through their injuries and finish off your opponents once and for all.
*goto success

*label thaum1
*set sunflame true
*set tcounter +1
You weave the gouts of flame into existence with a last flourish of mana, and the spell launches forward in violent streams, carefully controlled to veer past your allies and engulf your enemies in a deadly inferno. Your enemies' enchantment puts up quite the resistance to your efforts—whoever is behind them must be an enchanter of true mettle—but with a final, straining push you manage to overpower them, the blessing shriveling under the unforgiving load of your power.

${falco} is quick to seize the advantage, launching ${fhim}self into a deadly dance of lanceplay and spiritism, his advance uninterrupted as your enemies agonize over the flames still eating at their skin. No longer on ${fhis} backfoot, the white-haired mage calls upon ${fhis} phantasma once more, the scaled serpent all fangs and bludgeoning strength as it wreaks havoc behind enemy lines. Colossus follows suit behind ${fhim}, a terror in his own right as he bashes the enemies' skulls open,
*if (razorready)
    Razor using her hulking companion as cover as she aims poisoned daggers at their throats.
*else
    the silver of his axe gleaming like a beacon against Sunflame's orange glare.
*goto successplus

*label thaum2
*set stonegraveyard true
*set tcounter +1
You weave the spell into existence with a last flourish of mana, and all around you the ground heaves and quakes as earthen spires surface from the ground and bludgeon your enemies with vicious force. Their enchantment holds strong despite your efforts, dampening the bulk of the spell's impact; but many are flung sideways or swept off their feet, and though their assault is never truly broken it is enough to give your allies the window they need.

${falco} is first to seize the opportunity, launching ${fhim}self into a deadly dance of lanceplay and spiritism. $!{fhe} advances past enemy lines easily, at first, but it isn't long before your opponents regain their footing and begin responding in kind. The white-haired mage hisses as knives and blades alike dig into ${fhis} skin, but then Colossus rushes forward to buy ${fhim} cover—enough for ${fhim} to call upon ${fhis} arcana.

The scaled serpent rears its head from the mage's back, then, all fangs and bludgeoning strength as it wreaks havoc amidst your foes. You cast a second round of Stone Graveyard to seize on the momentum, and with that last bit of support your allies push through their injuries and finish off your opponents once and for all.
*goto success

*label spirit
*set fistofthedarklord true
*set scounter +1
You weave the spell into existence with a last flourish of mana, and the Fist burrows deep behind enemy lines with great bludgeoning strength. And yet the enemies' enchantment hold strong despite your efforts, dampening the bulk of the spell's impact and allowing your opponents to escape mostly unscathed as they redouble their assault.

${falco} stirs beside you, then, and with a snarl ${fhe} launches ${fhim}self into a desperate assault, teeth bared and lance brandished. $!{fhe} does decently against the enemy, at first, but is soon overwhelmed by their sheer numbers and begins to falter as knives and blade alike dig into ${fhis} skin.

"Colossus!" ${fhe} calls out, and the larger man then charges forward with a guttural bellow, his body forming a shield around the mage to cover ${fhim} from the brunt of the attacks. You do everything you can to aid the twosome—another Fist, a Visions spell—until eventually ${falco}'s mana crests like a tidal wave and ${fhe} brings ${fhis} arcana into being.

The scaled serpent rears its head from the mage's back, then, all fangs and bludgeoning strength as it wreaks havoc amidst your foes. You cast a second round of Fist of the Dark Lord to seize on the momentum, and with that last bit of support your allies push through their injuries and finish off your opponents once and for all.
*goto fail

*label alchemy
*set claycannon true
*set acounter +1
You command the cannonballs to lurch forward with a last flourish of mana, and they burrow deep behind enemy lines one after another. And yet the enemies' enchantment hold strong despite your efforts, dampening the bulk of the spell's impact and allowing your opponents to escape mostly unscathed as they redouble their assault.

${falco} stirs beside you, then, and with a snarl ${fhe} launches ${fhim}self into a desperate assault, teeth bared and lance brandished. $!{fhe} does decently against the enemy, at first, but is soon overwhelmed by their sheer numbers and begins to falter as knives and blade alike dig into ${fhis} skin.

"Colossus!" ${fhe} calls out, and the larger man then charges forward with a guttural bellow, his body forming a shield around the mage to cover ${fhim} from the brunt of the attacks. You do everything you can to aid the twosome—another Cannon, a
*if (spiritism > 49)
    Visions spell—until
*else
    Morana's Wail—until
eventually ${falco}'s mana crests like a tidal wave and ${fhe} brings ${fhis} arcana into being.

The scaled serpent rears its head from the mage's back, then, all fangs and bludgeoning strength as it wreaks havoc amidst your foes. You cast a second round of Clay Cannon to seize on the momentum, and with that last bit of support your allies push through their injuries and finish off your opponents once and for all.
*goto fail

*label successplus
*set prestige + 3
*set rfalco %+ 15
*page_break
At the end of it all, only their leader is left alive, crumpled on the floor in a state of near mana exhaustion. "Damn you," he curses, his broken grimace a far cry from his earlier confidence. "Inhumans."

${falco} kicks him squarely on the jaw then, and you hear the crack of a bone snapping out of place as the hit connects. You can't help but be astonished that ${falco} could still summon such strength, when you're at the edge of collapsing yourself. "Who are you?" ${fhe} snarls. "Who sent you here?"
*goto denouement

*label success
*set prestige +2
*set rfalco %+ 8
*page_break
At the end of it all, only their leader is left alive, crumpled on the floor in a state of near mana exhaustion. "Damn you," he curses, his broken grimace a far cry from his earlier confidence. "Inhumans."

${falco} kicks him squarely on the jaw then, and you hear the crack of a bone snapping out of place as the hit connects. You can't help but be astonished that ${falco} could still summon such strength, when you're at the edge of collapsing yourself. "Who are you?" ${fhe} snarls. "Who sent you here?"
*goto denouement

*label fail
*page_break
At the end of it all, only their leader is left alive, crumpled on the floor in a state of near mana exhaustion.

"Damn it all," he curses, his broken grimace a far cry from his earlier confidence. "I almost...I almost had you."

${falco} kicks him squarely on the jaw, though you don't miss the way the mage winces as the hit connects—it's all too obvious that ${fhe}'s also at the end of ${fhis} rope. "Who are you?" ${fhe} snarls despite it all, intimidating even on the brink of collapse. "Who sent you here?"
*goto denouement

*label denouement

The man answers the demand with a bitter laugh as blood drips down his jaw. "I am but a single...cog in the machine," he says through gritted teeth. "Make no mistake...you [i]will[/i] be ours."

And with those final, haunting words, an icy-blue light engulfs the stranger whole, and he falls slack onto the dungeon floor.

"A suicide enchantment," someone rasps behind you. You whip around to regard the familiar voice, at once gentle and strong, and see that Eli has regained ${fhis} consciousness. You suspect the empty bottle of potion Colossus holds in his hand had something to do with it. "Everyone in this group could cast it. They are…dangerous people, and whoever employs them even more so."

${falco} swings ${fhis} gaze around and scoffs. "Finally decided to join us, Plague?"

"It's been a long time since anyone's called me that," Eli says with a wry smile. "I never thought I'd say this, but it's good to see you, Zealot.
*if (razorready)
    Razor and Colossus as well, and…sorry, it seems we haven't met before?"
*else
    Colossus as well, and…sorry, it seems we haven't met before?"

*temp eliemotion ""
*choice
    #I freeze in place, unable to find the words. Eli is here. Eli is [i]talking to me[/i].
        *set emotional %+ 15
        *set eliemotion "panik"
        *set temp1 "panik"
        Eli cocks ${ehis} head curiously, before giving you a hesitant smile. "Thank you all the same for the rescue. That
    #I run up to hug ${ehim}, almost out of reflex. I fear nothing more than for ${ehim} to slip away from me again.
        *set emotional %+ 15
        *set eliemotion "panik"
        *set temp1 "panik"
        Before you could take a single step forward, you feel Colossus's cautioning grip on your shoulders. "Later," he says, not unkindly. "We are still in hostile territory. Against enemies who can conceal their presence…we must get out of here quickly."
        
        Eli nods ${ehis} head in agreement. "That seems wise. Still, let me at least thank you for the rescue…that
    #I introduce myself as ${callsign} and nothing more. Time enough for reunions later, when the setting is better fit for it.
        *set emotional %- 15
        *set eliemotion "kalm"
        *set temp1 "kalm"
        "${callsign}," Eli tries. There is a flicker of curiosity and hesitation in ${ehis} eyes, but the moment passes as quickly as it appeared. "Thank you for the rescue. That
    #It strikes me with sudden clarity that this person might not even be the Eli I knew. Who knows what Arcadia has done with ${ehim}, in the years you've been apart?
        *set optimistic %- 15
        *set eliemotion "kalm"
        *set temp1 "kalm"
        Eli cocks ${ehis} head curiously at your silence, before giving you a hesitant smile. "Thank you all the same for the rescue. That
was far closer a call than I care to admit."

*if (razorready)
    "Don't worry too much about it," Razor says. "Will you be able to travel by spirit gate, Plague? We could go outside by foot, but I'd rather not chance another ambush if we could help it."
    
    Eli nods at the rogue.
*else
    "You have a lot of explaining to do," ${falco} says curtly, crossing ${fhis} arms in front of ${fhis} chest. "But our priority is getting out for now. Will you be able to travel by Spirit Gate?"
    
    Eli nods at the white-haired mage.
"Yeah, I should be fine. Colossus's potion was potent, and given a bit of time I'll be able to heal myself as well."

"Good," ${falco} says, already drawing up the spell circle. "${callsign}, help ${ehim} walk. I'll have the gate ready in a bit."

You walk over to where Eli is crouched on the ground, offering the healer a
*if (eliemotion = "panik")
    trembling hand.
    
    "Are you alright?" ${ehe} asks, concerned as ${ehe} lets you pull ${ehim} up. "You don't have to push yourself if you're injured. I can make do on my own." 
    
    "Fine," you rasp, hoarse in a way that you haven't been since the days after ${ehis} death. "I'm fine."
    
    "Alright, just—let me know if it gets to be too much."
    
    "I will," you manage, your voice coming out quieter than you had intended. Regardless, you grip Eli's
*else
    hand.
    
    "Thank you," ${ehe} says, ${ehis} lips curling into a gentle smile. "You don't have to push yourself if you're injured, though. I can make do on my own."
    
    "I'm fine," you reply, after a beat. "You're the one who's been held captive by a madman. Worry about yourself first."
    
    The older @{evar man|woman} smiles, evidently unaffected by your rebuke. "Sorry,"
    ${ehe} says, though if you know ${ehim} at all then you know ${ehe} doesn't mean it. Regardless, you grip ${ehis}
form hard and steady, and note with a sharp pang of nostalgia that ${ehe} still smells as ${ehe} always did, under all the blood and sweat.

Wet earth and juniper trees.

${falco}'s portal rips through the air with a burst of violent magic, and without looking at one another you step as one into the abyss.

*label endchapter7
*page_break
*goto_scene Checkpoint_7-End