*comment Chapter 2 - Hero's Overture
*image header_c2.png center Chapter Two, Hero's Overture. Speak of legends fit to bend the ear of gods.
*page_break

[i]Ah, I really should have stayed at Leaf End.[/i]

You collapse under the shade of the Esteram Forest, the cruel heat beating down on you like a mallet. For a moment you fantasize about Aunt Bess' warm, clean sheets, and the cozy fireplace providing warmth in the dead of winter. What a wonderful life that was...

You shake yourself out of your reverie. Leaf End is two months behind you, and if you keep dwelling on the memories you just might turn around and march back to the Bellgrove Inn, begging Aunt Bess to take you back. But staying in the town puts everyone in Leaf End at risk. It was already a huge gamble, staying for a year—you really must keep moving.

Having taken a swig from your deerskin flask, you draw up a spell circle in a wide area around the tree. At your will, the runes blaze to life and create a transparent, luminescent wall around your soon-to-be area of rest. This will keep lower-level monsters away from you as you take a well-deserved nap. Anything more dangerous, and your survival instincts will kick in and wake you as a failsafe.
*page_break You drift off.
Hours later, you are awakened by the familiar sound of combat—metal clanging against scales, if your ears are to be trusted—accompanied by guttural growls and battle-cries. Assessing the direction of the clamor, there's really only one place the battle could be taking place in. The road you're taking is a narrow one that meanders around the forest; the only space big and open enough for a fight of that scale must have been the clearing you crossed earlier, not three minutes from where you're sitting under the shade.

You gather your things immediately, briskly stowing combat-potions in your robe and everything else in your sack. It's time for you to join the fight, because...
*choice
    #Someone could be in trouble. I should help if at all possible.
        *set noble %+ 15
        *set prenoble %+ 15
        You can recall multiple instances where the timely intervention of strangers had saved your life. Life on the road is a difficult one, and it's only right for you to help out one another.
    #The beast's cry is unfamiliar. Rare hides fetch a high price in the big city.
        *set noble %- 15
        *set prenoble %- 15
        Your purse has considerably tightened ever since you left Leaf End, and this seems to be a perfect opportunity to rectify that. Warm meals and clean bedsheets are just a hunt away.
    #The beast sounds [i]dreadful[/i]. I won't risk it cornering me as I run.
        *set optimistic %- 15
        *set preoptimistic %- 15
        Most high-level beasts are able to smell and hear human activity from miles away. You're far too close to the fight to comfortably make a clean escape—teaming up with whoever is currently holding their own against is your best bet at surviving this encounter.
    #It's been a little too peaceful lately—a proper beast would be great target practice.
        *set optimistic %+ 15
        *set preoptimistic %+ 15
        There's no reason to think that the beast could outdo you, not when your mana ducts are fully rested and you've got backup besides. This encounter will be a challenge, but one that is easily overcome—and you'll come out a better fighter for it.
        
*set kleon 10
*set ksaine 10
*set rleon 20
*set rsaine 20

Rushing into the clearing, you catch sight of a tremendous beast, green-blue scales glittering like seawater against the harsh noon sunlight. Locked in combat against it are a pair of fighters, one a blond swordsman sporting an impossibly large blade, the other a chestnut-haired rogue that seems a hair too young for the battlefield.

The beast turns its head to face you upon your arrival, as if assessing a new threat. And judging from the guttural growl it throws your way, you know you have been marked as such.
*page_break
"Look out!"

You curse to yourself, narrowly dodging the beast's enraged charge through a mixture of luck and reflex. The swordsman quickly rushes to your location, placing himself between you and the monster. "Alright?"

You nod in the affirmative, trying not to show your panic. "That's an Elyssian beast," you hastily inform him. "Physical attacks will do next to nothing to it."

"Right. We've been learning that the hard—" The two of you dodge the beast's charge a second time, dispersing so as not to give it a static target. "Say, those robes!" he's shouting, on the other side of the clearing. "You're a mage, aren't you?"

"I am. But this beast—don't get your hopes up!" 

You felt the warning necessary. After all, of all the Elyssian beasts in existence, this one is the worst possible matchup for you. While it does have a single, easily-exploitable weakness, you've unfortunately been neglecting your...

*temp beast ""
*temp recoildone false
*choice
  *if (alchemy < 75) #Alchemy
    *set beast "rhino"
    *set alchemy 30
    Elyssian rhinos are famously known for their magical outer shells, which confer to them resistance to both physical and magical attacks. While 
    *if specialty = "Thaum"
      your elemental attacks will undoubtedly fare much better than the strangers' bladed weapons,
      *goto vial
    *elseif specialty = "Spiritism"
      the more incorporeal spirits you can summon will undoubtedly fare much better than the strangers' bladed weapons,
      *goto vial
    *elseif specialty = "Enchantment"
      there are enchantments you can cast to increase the strangers' odds of success in direct physical combat,
      *goto vial
    *label vial
    a simple vial of Lachrimal poison thrown into the beast's gaping maw would've had the beast neutralized in less than ten minutes. However, with alchemy being far from your strong suit, you wouldn't have been able to brew the complex solution even if you knew in advance of this eventuality.
    *goto combat  
  *if (enchantment < 75) #Enchantment
    *set enchantment 30
    *set beast "chimera"
    Elyssian chimera are famously known for their ability to erect a magical field around themselves, which would cause any attacks they sustain to recoil on the attacker as well. While the magical recoil you'd sustain would be significantly less than if these strangers were the ones leading the charge, you'd still be hard-pressed to win in a battle of endurance against the mighty beast.

    A steady stream of spellbreaking enchantments would have dissipated much of the field, clearing the way for your compatriots to get clean hits in. Alas, with enchantment being far from your strong suit, such a high-level spell is beyond your meager capabilities to cast.
    *page_break
    *goto combat
  *if (thaum < 75) #Thaum
    *set beast "ogre"
    *set thaum 30
    Elyssian beasts in general are notoriously immune to physical attacks, but the ogre is also known to have a high resistance to magic. And while the spells and vials in your arsenal will likely fare much better than the strangers' bladed weapons, access to high-end Thaum would have enabled you to exploit its host of elemental weaknesses—really the only reliable way to slay one of these monsters. Alas, you will have to make do with what you have.
    *goto combat
  *if (spiritism < 75) #Spiritism
     *set beast "crow-harpy"
     *set spiritism 30
     Elyssian crow-harpies are famously known for their ability to fade into an incorporeal form, letting them phase away from an incoming attack before countering with unforgiving talons.
     *if specialty = "Thaum"
       Unlike the strangers' physical attacks, your elemental magic will still be able to graze the beast even in its incorporeal form. Still, it will likely be a long and arduous battle, and you're not sure your endurance will be a match for the beast's.
       *goto ifonly
     *elseif specialty = "Alchemy"
       Unlike the strangers' physical attacks, your vials of Everfire will be able to stick to the beast and do some damage even while it takes on an incorporeal form. Still, its Elyssian scales offer a fairly potent heat resistance, and you're not sure you'll be survive the beast's assault in the meantime.
       *goto ifonly
     *elseif specialty = "Enchantment"
       While a Binding enchantment will force it to stay corporeal for longer periods of time, the majority of the pair's physical attacks will still pass through the beast harmlessly. In the meantime, the harpy will counterattack relentlessly, and you're not sure your endurance is quite up to the task.
       *goto ifonly
     *label ifonly
     If only your spiritism was up to par. Most of the spirits you could call upon are incorporeal by default, and they'd be able to neutralize the harpy in short order. Alas, you will have to settle with what you have, and hope for the best.
     *goto combat

*label combat

The ${beast} charges at the swordsman at an incredible speed, but the blond simply lays flat on the ground just a second before impact. Unable to stop its own advance, the beast slams into a tree, stunning itself. The young rogue wastes no time in seizing the momentum, twin daggers making decently deep cuts into the beast's iridescent hide.

"Take this, you oversized
*if beast = "chimera"
  dog!"
  *goto exclaim
*elseif beast = "crow-harpy"
  turkey!"
  *goto exclaim
*elseif beast = "ogre"
  monkey!"
  *goto exclaim
*else
  armadillo!"
  *goto exclaim
*label exclaim
he yells, rather childishly—and it's fitting. The boy can't be older than fifteen, despite his strikes matching the skill level of a trained assassin. Behind him, the swordsman's blade transforms before your eyes, forming a large spiked bludgeon that he aims at the ${beast}'s head. Their flurry of attacks sends the beast reeling, and it retreats to the clearing's perimeter as soon as it gains its bearings.
*page_break
You don't know who these people are, but they're incredibly skilled fighters. They are still [i]physical[/i] fighters when all is said and done, though, and thus are at a tremendous disadvantage against an Elyssian beast. You had best join the fray immediately.

You hold out your arms and feel your mana ducts flare, circulating the magical nectar onto your limbs as spell circles bloom from your fingertips. In a battle of attrition, as this one is bound to be, the most important spell to cast is one that increases your odds of survival—and victory—over a long period of time. Several spells in your library come to mind, but eventually you settle on:

*label spellselect
*temp spell1 ""
*choice
    *if (alchemy > 30) #Everblaze
        Everblaze is an alchemic attack spell fueled by vials of Everfire, a condiment that—true to its moniker—will inflict continuous, inextinguishable burns to the target. It can only be put out by another mage of high skill—something the beast is sorely lacking access to.

        Continuous exposure to Everfire will inflict small, but continuous damage against the beast until it has been neutralized. It will also soften the iridescent scales that cover the entirety of its body, allowing your compatriots' blades to do some real damage. Though the burning scales might inflict some backlash to the warriors, the earlier display has made you reasonably confident that the pair will be able to avoid—or, failing that, endure—the risks involved.

        Will you cast Everblaze?
        *choice
            #Yes, cast this spell.
                *set alchemy %+ 10
                *set spell1 "everblaze"
                *set everblaze true
                *set acounter +1
                Vials autonomously float out of their storage in your coat pockets, shattering as they touch the spell circle and igniting its linings with green embers. Thin, wispy beams of green fire emerge from the circle at your command, launching themselves at the beast's retreating figure. Upon impact they turn into patches of flames on the beast's hide, and it gives an irritated snarl but remains otherwise unfazed.

                The flames will soften the beast's hide after some time and provide an instrumental opening for assault, but for now it certainly does look...unimpressive.
                *goto jerk
          #No, I think there's a better option.
            *goto spellreselect
    *if ((enchantment > 30) and (beast = "crow-harpy")) #Glyph of Binding
        Glyph of Binding is an enchantment specifically developed to counter beings that can enter a state of incorporeality like the crow-harpy. When successfully cast, the debuff will interfere with the target's capability to phase out of its material form, forcing it to stay corporeal for much longer periods of time. Needless to say, it will provide significant windows for your compatriots to land hits on the beastly werebird.

        Will you cast Glyph of Binding?
        *choice
            #Yes, cast this spell.
                *set enchantment %+ 10
                *set spell1 "binding"
                *set glyphofbinding true
                *set ecounter +1
                At your command, an identical spell circle materializes underneath the beast, runes alighting in a sinister glow. When both runes dissipate into thin air you know the spell has been successfully concluded, and that the battle is about to become that much easier.

                There is a beat of silence as the beast resumes its retreat unfazed, and you can't help but feel mildly embarassed. This spell will be instrumental in providing an opening for assault on the harpy, but for now it certainly does look...unimpressive.
                *goto jerk
            #No, I think there's a better option.
                *goto spellreselect
    *if (enchantment > 30) #Glyph of Runefire
        Glyph of Runefire is a buff-type enchantment designed to support high-level physical fighters, a category for which your compatriots doubtlessly qualify. When successfully cast, it allows the enchanted to channel explosive flames into their weapons at will, dramatically increasing their offensive power.

        It is an enchantment that requires a high level of mastery on the enchanted's behalf, as the blessing can only be used in short bursts and the explosive impact of their weapons often disorients their muscle memory. Having witnessed the earlier display, though, you're reasonably confident that the pair will be able to put the enchantment to good use.

        Will you cast Glyph of Runefire?
        *choice
            #Yes, cast this spell.
                *set enchantment %+ 10
                *set spell1 "glyphofrunefire"
                *set glyphofrunefire true
                *set ecounter + 1
                At your command, smaller but otherwise identical spell circles materialize around the twosome's weapons, casting them in a glowing red sheen. The older of the two swings his newly-reinforced weapon close to his face to assess the changes, face falling when he can only feel a warm glow radiating from the magicked steel.

                The display feels mildly embarassing. Your enchantment will turn into a huge advantage against the beast once they actually begin close combat, but for now it certainly does look...unimpressive.
                *goto jerk
            #No, I think there's a better option.
                *goto spellreselect
    *if (thaum > 30) #Boomerang Gale
        Boomerang Gale is a long-distance thaum spell that forms air currents into razor-edged blades of wind, each one acting autonomously to attack the target for as long as the caster's mana can sustain it. Due to its magical property, the gale will fare better against the beast's thick scales compared to your compatriots' blades. It will also slowly chip away at the beast's armor, allowing the pair of blade-wielders to get cleaner hits in.

        Will you cast Boomerang Gale?
        *choice
            #Yes, cast this spell.
                *set thaum %+ 10
                *set spell1 "gale"
                *set boomeranggale true
                *set tcounter +1
                At your command, several blades of wind materialize from the spell circle and launch themselves against the retreating beast. They graze against the beast's hide, chipping away at the iridescent scales before passing into the forest; the beast lets out an annoyed grunt but seems otherwise unfazed.

                You know the spots where the wind had grazed will now be around four times more vulnerable to physical attacks, and that the blades will return with a vengeance in a minute or so. This spell will provide an instrumental opening for assault against the beast, but for now it certainly does look...unimpressive.
                *goto jerk
            #No, I think there's a better option.
                *goto spellreselect
    *if (spiritism > 30) #Visions of the Damned
        Effectively an illusion spell, Visions of the Damned calls upon the aid of low-level spirits to serve as illusory enemies for the target, making them more vulnerable to attacks and less likely to strike the caster's allies. The spirits take on an incorporeal form while summoned, and though this means they do not deal any real damage to the target, they are also immune to most attacks. This allows them to stay on the battlefield for as long as the caster's mana can sustain the spell.

        While typically used against humans for whom the ghosts' ghastly appearance cause distress on top of distraction, it's also useful against beasts, who are less likely to differentiate the ghosts from the fighters. This may allow your compatriots to land more hits and avoid more attacks than they otherwise would.

        Will you cast Visions of the Damned?
        *choice
          #Yes, cast this spell.
            *set spiritism %+ 10
            *set spell1 "visions"
            *set visionsofthedamned true
            *set scounter +1
            *label visions    
            At your command, your spell circle turns an ominous shade of purple and spits out a number of ghastly apparitions, all launching themselves in unison against the beast's retreating figure. Upon impact they dissipate into thin air, becoming invisible to all but the beast itself.

            There is a beat of silence as the ${beast} resumes its retreat unfazed, and you can't help but feel mildly embarassed. You know the beast's newfound distraction will be instrumental in providing openings for assault, but for now it certainly does look...unimpressive.
            *goto jerk
          #No, I think there's a better option.
            *goto spellreselect
*label spellreselect
The spell circle crackles with tension in front of you as you rethink your decision. What spell will you cast?
*goto spellselect
*label jerk
The blond bites his fingernails in a nervous tic. "Please tell me you've got something else up your sleeve."
*choice
    #"Jerk! This'll be more useful than anything you're gonna do, you'll see!"
        *set emotional %+ 15
        *set preemotional %+ 15
        "$!{theyre} right, you know," the rogue chimes in,
        *if (spell1 = "everblaze") or (spell1 = "gale")
            starry-eyed. 
        *else
            pouting in disapproval.
    #Smile sweetly. "Keep this up and my next spell will be headed your way, [i]blondie[/i]."
        *set charming %+ 15
        *set precharming %+ 15
        "Brother, knock it off. I wouldn't test ${them}, if I were you," the rogue chimes in.
    #Just roll your eyes at this swordbrain.
        *set charming %- 15
        *set precharming %- 15
        "That's rude, you know," the rogue says, chiding the older.
    #It's a fair reaction, all things considered. I'll be happy to prove him wrong, though.
        *set emotional %- 15
        *set preemotional %- 15
        "That's rude, you know," the rogue says, chiding the older.
*if spell1 = "everblaze"
    "This will make our attacks more effective. Look for the charred spots when you attack, Brother! The hide will give way a lot easier."
*elseif spell1 = "binding"
    "You should know a Binding spell when you see one, Brother. Maybe if you hadn't skipped all those magic classes..."

    The supposed elder brother has the grace to look sheepish. "Right, right. So uh, what does the spell do exactly?"

    [i]Oh, for Jove's sake[/i]. "You saw how the harpy phased through your attacks earlier, right?" you say, summoning all the patience you're capable of. "It'll only be able to do that some of the time, now."
*elseif spell1 = "glyphofrunefire"
    "You should know a Glyph of Runefire spell when you see one. Maybe if you hadn't skipped all those magic classes..."

    The supposed elder brother has the grace to look sheepish. "Right, right. So uh, what does the spell do exactly?"

    [i]Oh, for Jove's sake[/i]. You point to his sword, and then the beast. "Sword go boom. Big magic damage. Go!"
*elseif spell1 = "gale"
    "This will make our attacks more effective. Look for the thinned out spots when you attack, Brother! The hide will give way a lot easier."
*else
    "You should know a Visions spell when you see one, Brother. Maybe if you hadn't skipped all those magic classes..."

    The supposed elder brother has the grace to look sheepish. "Right, right. So uh, what does the spell do exactly?"

    [i]Oh, for Jove's sake[/i]. You point at the beast on the other side of the clearing, jabbing erratically at apparitions only it can see. "You don't need us to explain this to you, right?"

The blond smiles, then, a wide toothy grin that lights up his entire face. "Thanks for that!" he says, jumping immediately back into the fray. The rogue—his brother, evidently—lets out an amused sigh and follows after him.

*page_break
As you begin working on your next spell circle, the pair engages in an efficient and eerily coordinated assault. The swordsman appears to have taken on the more aggressive role, distracting the beast's attention with big, flashy blows while the rogue targets its weak points in sleek, seamless movements. But the beast, sensing the heightened threat level, responds in kind. A crystal-blue ooze forms in its mouth, and with a deafening roar it launches out of the beast's mouth, shooting in an array of projectiles.

"Don't let it touch you!" you yell out, dodging a beam yourself.

"Wasn't gonna! Look here, you mangy beast!"

The swordsman's blade transforms into a large square weapon reminiscent of a guillotine blade, and he attacks in exaggerated motions. After landing a few successful strikes,
*if spell1 = "everblaze"
  one of the everfires on its hide reacts with the beast's blue toxin, causing a small explosion none of you expected.
  *goto blink
*elseif spell1 = "binding"
  the harpy suddenly falls out of rhythm and chose to not phase out in a moment where the pair expected it to. As they are thrown out of balance, the beast takes advantage of its newfound momentum, holding out its talons and rotating into a deadly whirlwind attack.
  *goto blink
*elseif spell1 = "glyphofrunefire"
  one of the swordsman's explosive blows makes contact with the beast's blue toxin, causing an explosion far larger than either of them expected.
  *goto blink
*elseif spell1 = "gale"
  the blades of wind make their reappearance, having replenished themselves with newfound air currents.

  "Look out!" you yell, but the pair did not react until the blades were inches away, much of their attention seized by the beast.
  *goto blink
*else
  the beast makes an unexpected, sweeping blow—likely targeting one of the invisible apparitions—that just so happens to perfectly align with the pair's positions around it. With their muscle memory too accustomed to dealing with erratic, inaccurate attacks, they didn't realize the threat until the blow was inches from their vitals.
  *goto blink
*label blink

The young rogue was able to blink out in time and reappear on a nearby tree—to manage such a feat in his adolescent years, he must have a fair bit of magical talent to go with his knife—but the swordsman took the brunt of the damage and was sent reeling. The beast doubles down on its advantage, dealing a blow that lays the blond flat on his back, sword brought up in front of him as a makeshift shield.

"Little help here!"

"Hang on!" the rogue says. He looks ready to leap into action, but you motion for him to stop. Your spell circle shines like a beacon as it achieves completion, and you cast:
*label spell2select
*choice
  *if (alchemy > 30) #Clay Cannon
    Perhaps the most straightforward attack spell in the alchemist's repertoire, Clay Cannon transforms bits of alchemic clay into large cannonballs that can match even the ${beast} in size. Though not the most powerful individually, you can fire multiple Clay Cannons in quick succession; such a barrage would definitely be instrumental in halting the beast's momentum.

    Will you cast Clay Cannon?
    *choice
      #Yes, cast this spell.
        *set alchemy %+ 10
        *set temp1 "claycannon"
        *set firstspell "Clay Cannons"
        *set claycannon true
        *set acounter +1
        Small mounds of alchemic clay float out of your robe and enter the magic circle, and it rumbles with the tension of a cannon unfired. "Lay flat!" you yell, and the swordsman brings his sword close to his chest. "Fire!"

        The sound catches the attention of the ${beast}, and it looks away from the swordsman and locks eyes with you, but it was too late. Three large clay cannonballs fire in quick succession at the ${beast}, each one turning back to its original size after impact so the beast would take full damage from the next. The ${beast} roars as it is sent flying several paces from where it once stood—far enough for the rogue to blink in and out of there without much hassle, with the swordsman in his arms.
        *goto okay
      #No, I think there's a better option.
        *goto spell2reselect
  *if (enchantment > 30) #Glyph of Subjugation
    Glyph of Subjugation is an enchantment designed to override the target's control over their body, though they would still be 'present' and fully conscious of their surroundings and what is happening to them. Though more commonly used outside of battle, enchanters often use the spell to halt an assault or break an opponent's momentum—something this situation definitely calls for.

    However, the mana cost of casting the spell increases exponentially with the effect duration and overall strength of the target. Given the size and strength of the beast you're currently facing, you think it prudent to only maintain control for a few seconds at most. Still, that should be enough time to get the beast off of the swordsman's back and make it hurt itself a little for good measure.

    Will you cast Glyph of Subjugation?
    *choice
      #Yes, cast this spell.
        *set enchantment %+ 10
        *set temp1 "subjugation" 
        *set firstspell "Glyphs of Subjugation"
        *set glyphofsubjugation true
        *set ecounter +1
        As you complete the spell circle, an identical one crackles to life on the ground beneath the ${beast}. In a moment of salience, the beast looks up to identify the source of the new danger, and locks eyes with you as you mutter the last words of spell—but it's too late. Before it could lunge forward, the Glyph overrides its body, confining the beast's consciousness in the depths of its own mind.

        Having successfully subjugated the ${beast}, you order it to scramble away from the swordsman and slam itself—repeatedly—against nearby tree trunks. As much of the beast's targets become uprooted, the rogue blinks in and out of the spot where the ${beast} once stood, transporting the swordsman out of harm's way.
        *goto okay
      #No, I think there's a better option.
        *goto spell2reselect
  *if (thaum > 30) #Morana's Wail
    Morana's Wail is a higher-end thaum spell that allows the caster to summon multiple large icicles to fire at their enemies. Though not as powerful in terms of sheer destructive strength as other thaum spells of its caliber, it is second to none in breaking an opponent's momentum and moving them away from endangered allies. You have a feeling that's what the swordsman would appreciate the most right now.

    Will you cast Morana's Wail?
    *choice
      #Yes, cast this spell.
        *set thaum %+ 10
        *set temp1 "morana" 
        *set firstspell "Morana's Wails"
        *set moranaswail true
        *set tcounter +1
        The icicles manifest into existence with a frigid blast of air, which the wind carried to the rampaging ${beast}. In a moment of salience it is alerted to the new threat and locks eyes with you, but it's far too late. The icicles launch themselves at high speed against the beast's form, bludgeoning it with tremendous force one after the other. The ${beast} roars as it is sent flying several paces from where it once stood—far enough for the rogue to blink in and out of there without much hassle, with the swordsman in his arms.
        *goto okay
      #No, I think there's a better option.
        *goto spell2reselect
  *if (spiritism > 30) #Fist of the Dark Lord
    Fist of the Dark Lord is one of the few directly offensive spells in the spiritist's repertoire, and so sees high usage by those able to cast it. It opens a gate to the otherworld and borrows the power of countless smaller spirits to form a single solid construct, manifesting in this world as a colossal forearm completely pitch-black in color. It then launches itself against the target with a bludgeoning strength that rivals even that of the stronger thaum spells.

    Will you cast Fist of the Dark Lord?
    *choice
      #Yes, cast this spell.
        *set spiritism %+ 10
        *set temp1 "darklord"   
        *set firstspell "Fists of the Dark Lord"
        *set fistofthedarklord true
        *set scounter +1
        Your spell circle gives off a sinister shriek as it opens the gates to the otherworld. The sound catches the attention of the ${beast}, and it looks away from the swordsman and locks eyes with you, but it was too late. The Fist of the Dark Lord's colossal form manifests and launches itself with surprising velocity, slamming into the beast with a tremendous bludgeoning force. The ${beast} roars as it is sent flying several paces from where it once stood—far enough for the rogue to blink in and out of there without much hassle, with the swordsman in his arms.
        *goto okay
      #No, I think there's a better option.
        *goto spell2reselect
*label spell2reselect
The spell circle crackles with tension in front of you as you rethink your decision. What spell will you cast?
*goto spell2select
*label okay

"I'm okay," you hear the blond say, mainly to reassure his brother but loud enough for you to hear. "See, I can stand up fine."

You're not sure you trust him, but luckily you've stocked a recovery potion in your sack for this kind of emergency. There should be enough time for you to retrieve it before the beast—

*page_break
"Oh, come on!" You yell out, along with a couple of colorful expletives as the ${beast} roars back to life, having already recovered from the beating it took. It renews its attention on you, and charges with a fervor you've never seen before, 
*if (beast = "chimera")
  front claws like knives
  *goto glint
*elseif (beast = "crow-harpy")
  talons like knives
  *goto glint
*elseif (beast = "rhino")
  horn like a knife
  *goto glint
*else
  claws like knives
  *goto glint
*label glint
glinting in the sunlight. Out of the corner of your eye, you catch the young rogue trying to blink—presumably to rescue you—and being dropped off right where he started. Tough luck for you, it seems. He's run out of mana, and you're on your own.

You hold your ground and muster all the mana you have at your disposal, channeling them into the arms you've stretched out in front of you. If you are to survive this, then there's only one thing you can do:

*fake_choice
  #Cast the most powerful spell at your disposal.
*if specialty = "Thaum"
  *temp ult "thaum"
  *set ultima "thaum"
  *set skywrath true
  *set tcounter +1
  *achieve skywrath
  The air prickles with tension, and soon a veritable thunderstorm pours out of your palms and slams into the beast. Skywrath—the costliest, most powerful spell you know—crackles angrily against the beast and paints its scales a charred black.
  *goto recoil
  *label ultthaum
  flayed and burning, but [i]still charging[/i]—
  *goto plunge
*elseif specialty = "Alchemy"
  *temp ult "alchemy"
  *set ultima "alchemy"
  *set widowsstream true
  *set acounter +1
  *achieve widowsstream
  Alchemic runes manifest and expand from the surface of your palms, poisonous vials floating from your pockets as if compelled by magnets. The runes then spit out a stream of thick, viscous venom which slams into the beast at a dizzying velocity. Widow's Stream—the costliest, most powerful spell you know—settles like a coat upon the body of the beast and begins to corrode against its scales, toxic smoke rising where the venom is thickest.
  *goto recoil
  *label ultalchemy
  flayed and smoking, flesh peeling from bones—but [i]still charging[/i]—
  *goto plunge
*elseif specialty = "Spiritism"
  *temp ult "spiritism"
  *set ultima "spiritism"
  *set gatebreaker true
  *set scounter +1
  *achieve gatebreaker
  Ancient runes manifest and expand from the surface of your palms, the air prickling with arcane energy. "[b]Merije alvad kuholen[/b]," you chant in the ancient tongue, and the runes blaze to life, forming a pitch-black void large enough to swallow you whole. Five ghastly apparitions emerge from the portal one by one, letting out blood-curdling wails as they launch themselves at high velocity and slam against the beast. The spirits of Gatebreaker—the costliest, most powerful spell you know—settles like a coat upon the body of the beast and begins to rot its very flesh, melting sinews giving way to bones. 
  *goto recoil
  *label ultspirit
  flayed and rotting, clumps of flesh precariously dangling from its bones—but [i]still charging—[/i]
  *goto plunge
*else
  *temp ult "enchantment"
  *set ultima "enchantment"
  *set banecircle true
  *set ecounter +1
  *achieve banecircle
  The ground around you is bathed in a sudden light, and a magic circle blooms underneath your feet. "[b]Garathen olstaat mier[/b]," you chant, and the circle blazes to life, streams of light searing as it emerges in a blinding array. Banecircle—the costliest, most powerful spell you know—crackles like lightning as the beast crosses its borders, and parts of its body—
  *if beast = "crow-harpy"
    a wingtip, a talon, a jaw—one
    *goto chantult
  *elseif beast = "chimera"
    a tail, a leg, even one of its three heads—one
    *goto chantult
  *elseif beast = "rhino"
    a tusk, a leg, part of its stomach—one
    *goto chantult
  *else
    a leg, a shoulder, part of its head—one
    *goto chantult
  *label chantult
  by one phase out of existence, leaving only bloody orifices in their stead.
  *goto recoil
  *label ultchant
  largely deconstructed, blood gushing in a million different places where flesh and organs once were—but [i]still charging[/i]—
  *goto plunge
*label recoil

*if beast = "chimera"
  You throw your head back in pain as the recoil blooms in your system, shredding at your nerves like graters.
  *goto pain
*elseif beast = "rhino"
  You brace yourself, wincing in pain as part of the magic is deflected back onto you, nerves screaming as 
  *if ult = "enchantment"
    the skin on your forearms are flayed by a magical force.
    *goto endrhino
  *elseif ult = "thaum"
    lightning grazes against your skin and burns through your epidermis.
    *goto endrhino
  *elseif ult = "spiritism"
    part of the curse sinks into your skin, shriveling and rotting your epidermis.
    *goto endrhino
  *label endrhino
  *goto pain
*elseif beast = "crow-harpy"
  The harpy phases away momentarily, escaping the worst of the damage, but it shrieks as some of your attack evidently still hit the mark. You redouble your efforts, pouring all the mana you can muster into the spell and hoping for the best.
  *goto pain
*else
  The ogre charges through the spell with a loud battle-cry, as if unaware of the tremendous damage it has sustained. You redouble your efforts, pouring all the mana you can muster into the spell and hoping for the best.
  *goto pain

*label pain
*if (beast = "chimera") or (beast = "rhino") 
  You close your eyes for the pain—it's [i]unbearable[/i]—and when you open them again the beast is 
  *goto ultjunction
*else
  Your close your eyes as your mana ducts hum and strain from the overexertion, every nerve in your body telling you to [i]stop casting[/i]—and when you open them again the beast is
  *goto ultjunction

*label ultjunction
*if (ult = "thaum")
  *goto ultthaum
*elseif (ult = "alchemy")
  *goto ultalchemy
*elseif (ult = "spiritism")
  *goto ultspirit
*else
  *goto ultchant

*label plunge
*page_break
And then the brown-haired boy falls upon the ${beast}, as if dropping from the sky, his daggers plunging into the back of its
*if (beast = "chimera")
  central neck.
  *goto rear
*else
  neck.
  *goto rear
*label rear
The beast rears back in pain, throwing its body every which way,
*if (beast = "chimera")
  scorpion tail jabbing at the boy as he dances around the strikes.
*elseif (beast = "rhino")
  saber-like horn jabbing at the boy as he dances around the strikes.
*elseif (beast = "crow-harpy")
  saber-like talons jabbing at the boy as he dances around the strikes.
*else
  saber-like claws jabbing at the boy as he dances around the strikes.

"Brother, now!"

"I got it!" The blond man lets out a guttural battle-cry as he charges, his blade growing in size, twice, three times as big; its sharp edge meets with the beast's unprotected abdomen and slices clean through, bisecting the body as blood and guts spill out like a fountain.

The beast lays dead at your feet.

*page_break
*achieve elyssianslay
*set prestige +5
"Gross," grunts the younger, whose perch atop the beast meant he took the brunt of the carnage. He perks up suddenly, a look of realization dawning on his face. "Brother, we need to get back to Ilya!"

"Right!"

With that, the pair all but leap to the edge of the clearing, where you notice for the first time an unconscious woman in healer's garbs, long white hair a tangled mess around her slim figure.

*page_break
*set kilya 10
"She has a fever," the blond notes, a hand upon her temple. "Ilya. Ilya, can you hear me?"

You hobble over to the site, heaving from your wounds and near mana exhaustion. The woman appears to still be drawing breath, albeit harsh, shallow ones that rattle her whole body with each inhale. There's a sickly placidness to her features, and most worryingly, a faded purple tinge to her lips—you fear the worst. "What happened?"

"The beast got to her, right before you came. It spat that...that blue [i]goo[/i] at her and she got knocked out cold."

Your close your eyes, fears confirmed. "Elyssian venom."

"You know of it?" pipes the brown-haired boy. "Will Ilya be okay? What do we need to do?"

You shake your head. "It's deadly, if not treated by a healer. She has less than a day."

The younger boy's face contorts in worry, teeth biting down upon his lip while his brother launches into an outburst. "What? No, Calinger isn't for another two days! Are you saying she'll die here?"

You avoid his gaze. "There...there might be a way," you mutter, hesitant. The brothers whirl on you with hope and surprise plain on their features.

"Please," the younger begs, voice small and trembling. "Please help her. We—we can pay. Anything you want, but just save her, please—"

"That's not the issue. I-I don't know if..." you swallow, and try again. "The risks involved are very big."

The swordsman stares at you, bewildered. "Just what exactly are you planning to do?"
*temp spell3 ""
*choice
  *if (alchemy > 30) #I can concoct an antivenom potion to remove the toxins.
    *set alchemy %+ 10
    *set spell3 "alchemy"
    *set heimantivenom true
    *set acounter +1
    *set ilyarescue "alchemy"
    "How is that risky?" asks the younger, knuckles white as he grips the hand of the unconscious woman.

    "Elyssian poison requires a specific type of antivenom, and I don't have all the ingredients I need with me. I can make a modified one, but it may have adverse effects depending on how her body is wired."

    The rogue's eyes are fixated on you, bright green and piercing. "And if that happens...? Would she?"

    "Yes," you confirm. "She would pass within the hour."

    The pair's faces fall. "Can we not check beforehand what her reaction's likely to be?" the older brother asks. "Scan her body with magic, something like that?"
    *goto thereis
  *if (enchantment > 30) #I can bolster her poison resistance to increase her odds of survival.
    *set enchantment %+ 10
    *set glyphofimmunity true
    *set ecounter +1
    *set ilyarescue "enchantment"
    "How is that risky?" asks the younger, knuckles white as he grips the hand of the unconscious woman.

    "Resistance enchantments work by putting the body into overdrive. They really should only be used on healthy, conscious targets. Otherwise the load might be too much on the body and the effects will backfire."

    The rogue's eyes are fixated on you, bright green and piercing. "And if that happens...? Would she?"

    "Yes," you confirm. "She would pass within the hour."

    The pair's faces fall. "Can we not check beforehand what her reaction's likely to be?" the older brother asks. "Scan her body with magic, something like that?"
    *goto thereis
  *if (spiritism > 30) #I can construct a series of spirit gates to hasten our travel to the city.
    *set spell3 "gates"
    *set spiritgate true
    *set scounter +1
    *set ilyarescue "spiritism"
    *set spiritism %+ 10
    "What are the risks?" asks the younger, knuckles white as he grips the hand of the unconscious woman.

    "Mana exhaustion, for me. For the two of you, maybe fatigue and disorientation; quite severe, but nothing you can't handle. In [i]her[/i] case, though...she's already vulnerable. I don't know if she can handle the strain of successive spirit gate travels."

    The rogue's eyes are fixated on you, bright green and piercing. "And if that happens...? Would she?"

    "Yes," you confirm. "She would pass within the hour."

    The pair's faces fall. "Can we not check beforehand what her reaction's likely to be?" the older brother asks. "Scan her body with magic, something like that?"
    *goto thereis
  *if (thaum > 30) #I can use thaum to extract an antidote from the Elyssian beast's carcass.
    *set thaum %+ 10
    *set ilyarescue "thaum"
    "How is that risky?" asks the younger, knuckles white as he grips the hand of the unconscious woman.

    "The antidote is stored in the beast's medulla, under layers of enchanted flesh and bone. Extraction is a tricky business; there needs to be at least three mages for it to be safely done. As it stands, I'm very likely to damage the organ as I take it out."

    The rogue's eyes are fixated on you, bright green and piercing. "And if that happens...? Would she?"

    "Yes," you confirm. "She would pass within the hour."

    The pair's faces fall. "Can we not check beforehand what her reaction's likely to be?" the older brother asks. "Scan her body with magic, something like that?"
    *goto identical

*label thereis

"There is a way to do that, yes. But that requires a proper healer," you state grimly. Eli's visage flashes briefly in your mind's eye; you shake ${ehim} off. "I'm not a healer, needless to say."
*goto silence
*label identical

"No, they're almost identical until they interact with the body. Maybe a really good healer could..." you trail off, tone grim. Eli flashes briefly in your mind's eye—you shake ${ehim} off. "I'm not a healer, needless to say."
*label silence

There is silence, for a while, and you pretend not to hear the younger brother beginning to sob. Eventually, the blond looks at you with a grim resolution in his eyes. "We can't just sit still while she wastes away. Please, we have to try."

*if charming > 50
  "Alright, I've got it. I'll start preparing, then."
  *goto pagebreak
*else
  "I understand. I'll begin preparations."
  *goto pagebreak
*label pagebreak
*page_break
*set kleon 1
*set ksaine 1
*set kilya 1
*achieve healilya
"That should do it. She should be stable for now."

You lean back on the bedside chair, wiping at the sweat beading down your forehead. It's been three days since you began treating the girl, and in that time you've arrived at Calinger and set up a makeshift sickbay at the local inn. With access to a magic shop, you've also been able to concoct a treatment that gets her out of the critical stage.

"Thank you," says Leon—the blond swordsman you encountered by chance en route to this city. "You've worked hard. Ilya owes you her life."

"And us as well, probably," chimes Saine, his teenage brother. "I really don't see a way we could've made it out of that fight in one piece, if you hadn't been there."

*choice
    #"I only did what anyone would have done."
        *set noble %+ 15
        *set prenoble %+ 15
        "I've also had to rely on the kindness of strangers," you say, eyes closed from the exertion. "Just paying it forward. Pay it no mind."
        
        "Nonsense. You've not only helped us defeat the beast, but now you've saved our comrade's life, as well—far beyond what a simple helpful passerby would do." Leon reachs into his pocket and casually takes out five gold coins, offering them to you with an outstretched hand. "It's only fair that we compensate you. I won't take no for an answer."
        
        You balk at the offer, regarding the trio with a fresh pair of eyes. You were ready to refuse whatever they offered, but this changes your calculus quite a bit. These people aren't hurting for money at all—and this is more of it than you've earned in Leaf End in your entire year-long stay.
    #"Hey, don't worry about it. What are random strangers in the woods for?"
        *set charming %+ 15
        *set precharming %+ 15
        "Things wouldn't have ended well for me either if I was alone, anyway," you say, valiantly smiling through your exhaustion. "So lets call this even. We saved each other's lives, after all."

        "That may be, but you still saved Ilya's life after the danger had passed. Let us compensate you for that, at least." Leon reaches into his pocket and casually takes out five gold coins, offering them to you with an outstretched hand. "Will this be okay?"

        You balk at the offer, regarding the trio with a fresh pair of eyes. You weren't about to say no if they had insisted on paying you, but you were expecting fifty, maybe sixty silver at the most. [i]Five gold coins[/i] is an outright ridiculous price for your services, life-saving maneuver or not. If you were smart with your spending, you could laze around for two years and still live in perfect comfort.
    #"This is a business transaction—there's no need for thanks."
        *set noble %- 15
        *set prenoble %- 15
        "Just hold up your end of the bargain," you say, eyes closed from the exertion. "Compensate me appropriately and we'll be all good."

        "Of course," Leon grins. He reaches into his pocket and casually takes out five gold coins, offering them to you with an outstretched hand. "Will this be okay?"

        You balk at the offer, regarding the trio with a fresh pair of eyes. You were ready to ask for [i]one[/i] of these coins as a starting price, fully expecting to be haggled down to eighty silver at most. Being paid five of them for your services is outright ridiculous, life-saving maneuver or not. If you were smart with your spending, you could laze around for two years and still live in perfect comfort.
    #"It's fine. Just take better care of yourselves, next time."
        *set emotional %- 15
        *set preemotional %- 15
        "It would be good to stock up on antidotes, for starters. It was ill luck for you to meet with an Elyssian beast, but even antidotes for sandviper venom would have at least improved her odds."
        
        Leon grins as he takes your tirade in stride. "You helped us defeat the beast, saved our comrade, and now you're giving us free advice, too? That settles it," the blond says, reaching into his pocket and casually taking out five gold coins. He offers them to you with an outstretched hand. "For all you've done for us. I won't take no for an answer."
        
        You balk at the offer, regarding the trio with a fresh pair of eyes. You weren't about to say no if they had insisted on paying you, but you were expecting fifty, maybe sixty silver at the most. [i]Five gold coins[/i] is an outright ridiculous price for your services, life-saving maneuver or not. If you were smart with your spending, you could laze around for two years and still live in perfect comfort.

"Just...who are you people..."
*page_break
"We're the White Fangs," Saine says, pride plain in his tone. "Adventurers, and very successful ones at that. There's never been a monster we couldn't slay. Until that ${beast}, anyway."

"Come on, you don't make this kind of money killing bandits and selling panther hides."

"Take our word for it," Leon laughs. "It's really what we do."

You don't doubt for a second that there's more to the story, but you know how to read the mood. "I see," you say, dropping the issue. "I've stabilized her mana flow, so she should regain consciousness by tonight. I'll stick around until then, just in case."

"And after that? Where are you headed next, ${fname}?"

You pause for a moment, but decide there is no harm in telling them. "Sienan, the capital. I'd like to register with the guild there, find some work."
*page_break
*set rleon 30
*set rsaine 30
*set prestige +10
Saine all but leaps off the table he's been sitting on, arresting your hands in his own. "Then you should come with us!" says the young rogue, starry-eyed. "Our quests pay really well, I promise. And you've already seen us in combat, you know we're top-notch!"

"It's rude to pressure ${them} like that, Saine," Leon chides. He has the courtesy to pull Saine away, but his own eyes imitate the hopeful look his brother is giving you. "But it's true that we could really use a mage. And you're by far the best we've seen, ${fname}. What do you say?"

You make a show of considering the offer, but really this works out for the best, because…

*choice
    #...I've had enough of packed earth and leathery game. To the high life I go.
        *set noble %- 15
        *set prenoble %- 15
        No adventurer worth their salt would say no to a party that can dole out gold coins like sand. Compared to the uncertain future waiting for you in Sienan, the offer seemed almost too good to be true.
    #...they've only got [i]three members[/i]. They're bound to run into hot water again like that.
        *set noble %+ 15
        *set prenoble %+ 15
        Skilled fighters they may be, but when outnumbered a trained warrior will fall as easily as a village farmer. It wouldn't sit right with you to let them be on their way, knowing they very nearly died for lacking a proper offensive mage.
    #...these people are the type I want watching my back when things inevitably turn south.
        *set optimistic %- 15
        *set preoptimistic %- 15
        The blond's brute strength is unmatched, and his brother's knifework features some of the most masterful strokes you've ever seen. You don't know what the white-haired woman is capable of, but you have no reason to believe she's any less skilled than her companions. Compared to the uncertain future waiting for you in Sienan, the offer seemed almost too good to be true.
    #...I'm flattered, so sue me. Having my talents acknowledged fills me with a swelling pride.
        *set emotional %+ 15
        *set preemotional %+ 15
        It certainly doesn't hurt that they are skilled fighters and well-financed besides. Compared to the uncertain future waiting for you in Sienan, the offer seemed almost too good to be true.

*if (charming > 50)
  You nod in the affirmative. "That works for me. I'll be in your care, then."
  *goto care
*else
  You nod in the affirmative. "Mm. I'll be in your care, then."
  *goto care
*label care

Leon slings his arms around you good-naturedly. "Glad to have you on board," he says, beaming.
*page_break
*set rilya 30
The healer really did regain consciousness that night, though you were out on a restock run at the local magic shop when it happened. When you walk back into the room with your purchases in tow, you find Saine weeping against Ilya's nightgown as the healer embraces him. "There, there, Saine. I'm really alright, see?"

"I-I really thought y-you were gone," he manages between sobs. "I'm g-glad you're okay."

Ilya looks at the boy fondly, the way one might look at a kitten. "That's right, I'm okay. And here comes my savior now."
*page_break
Alerted to your presence, Saine pulls away and wipes at his tears. "${fname}, you're back," he whimpers.

You nod, feeling a little guilty for intruding, and turn to regard the healer. "I'm glad you've woken up."

"Yes, and thank you for that," Ilya smiles. It may just be the sickness, but she looks like a wisp of a woman—small and slight in stature, with beautiful, ethereal white locks and kind blue eyes. It's a bit hard picture her as the rough-and-tumble adventurer that Saine and Leon make her out to be. "I've caused you a lot of trouble."

"Not at all. You also really helped me out—the mana potions in your satchel saved me from mana exhaustion," you deflect. "Ah, I hope you don't mind. I've bought replacements."

She laughs, the sound gentle but clear as a bell. "Don't mind that. You're part of our party now, after all."

You grin. "I guess I am, huh."

"That's right!" Saine chimes, his mood having picked up. "It's gonna be a golden age for the White Fangs!" His over-the-top praise is a little embarassing, but it's hard not to feel a little giddy from his infectious energy.

You excuse yourself from the room to let Ilya properly rest, dragging a pouting Saine with you. When you hit the sheets later in the night, the feeling that pools in your stomach is one of optimism and excitement—the first you've felt this way in a long time.
*page_break
*set kleon 2
*set ksaine 2
*set kilya 2
Your days with the White Fangs pass by in a rowdy, eventful haze. The party is apparently quite famous in and around Calinger, commanding respect from other adventurers and even the major guilds. Clients whose pockets run deep enough would often seek you out specifically and refuse all others, and just like that the four of you clear numerous high-profile missions over the course of the next year. Bandit exterminations, beast hunts, investigations—no matter the nature of the mission, word on the street is that the White Fangs are the best for the job.

The group's pristine reputation ensures you never want for work, and need only concern yourself with seeing your missions properly handled. It feels strangely peaceful overall, despite the high degree and frequency of action, as for the first time you have people who would watch your back and cover for your weaknesses.

The experience is at once foreign and pleasant, and you find the apocalyptic paranoia that once frayed your nerves and gave you nightmares has mellowed out by no small measure. You've always shied away from parties before, thinking keeping your companions alive is likely more trouble than it's worth. But with these three around, you're beginning to see the appeal.
*page_break
As promised, Ilya is a talented healer and a great enchantress besides, ensuring no one in the party is hurt for more than a few minutes. And with Leon and Saine at the helm, the vast majority of battles go so smoothly that you feel a little bit like you've cheated them out of their money. Sure, you cast a few simple spells here and there, but unlike the battle with the Elyssian ${beast}, Leon and Saine do far more of the legwork.

In any case, your companions seem quite content with the arrangement. And it's easy to see why—for the next few months, you and the rest of the White Fangs settle into a comfortable groove, clearing all the missions thrown your way with barely any complications.

That is, until one winter's day.
*page_break
*comment ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ BANDIT ENCAMPMENT SECTION~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
*comment outcome 1: Use Spirit Gate to sneak the children out. MC is hit by stray bandit, blacks out, and becomes permanently injured. Saves all the kids. Prestige gain 20. GETS FULL OFF-DAY
*comment outcome 2: Use Enchantment to sneak the children out. MC is cornered inside the encampment, and becomes permanently injured. Saves all the kids but one. Prestige gain 15. GETS FULL OFF-DAY
*comment outcome 3: Calls reinforcements using Spirit Gate. MC retains no injuries. Saves 5 of the kids. Prestige gain 10. GETS LEON SCENE. GETS HALF OFF-DAY
*comment outcome 4: Saine calls the reinforcements. MC retains no injuries. Saves 3 of the kids. Prestige gain 5. GETS LEON SCENE. GETS HALF OFF-DAY
*comment outcome 5: Use Thaum to break the children out. MC is cornered inside the encampment, and becomes permanently injured. Saves all the kids if Thaum > 74, prestige gain 20. If Thaum 60 < x < 74, saves all but one. Prestige gain 15. Otherwise, saves only one. No prestige gain

"You're saying there's [i]children[/i] there? Inside a bandit encampment?"

The four of you are huddled together under the shade of a pine tree, fur coats wrapped around your bodies to repel the biting cold. It is the height of winter, but you've received a request to eliminate a bandit encampment that's been plaguing small villages along the Parami highway. The pay seemed quite small compared to the scale of the mission, but as usual Leon insisted the White Fangs take it on when no one else would. You wonder how the party makes so much money when they're constantly acting on their altruistic inclinations.

Saine nods, his expression grim. "Seven children in all. It looks like human trafficking to me, but I can't be sure," he pauses, still a bit winded from his consecutive blinking. "Whatever it is, they're starving and abused. If we don't rescue them now, I think they might be done for."

"These bandits know of us White Fangs, too," Ilya notes. "They know the innocents are a bargaining chip against us. They'll exploit it well."

"Damn them all!" Leon curses under his breath. "I don't see a way we could save them. With these many bandits around, I need Saine in top form. I can't just spare him on some rescue sidequest!"

"But you can spare me," you say, almost instinctively. Regardless, there is wisdom in the suggestion: in closed, crowded spaces like the encampment will inevitably be, offensive spells are as much a liability as they are an advantage. "I could get them out."

Leon looks up at you, cautiously optimistic. "How?"

*temp banditoutcome ""
*temp kidsafe ""
*choice
  #"I'll break them out the old-fashioned way—by force."
    *set banditoutcome 5
    "I can use the chaos to my advantage and just clear any stragglers from the main battle—"

    "It's not possible," Ilya rebuts. "You'll be their main target, seeing as you're escaping with their bargaining chips. Both you and the children will die before you ever step out of the fort. I'm against this plan."

    "I have to agree with her," Saine says, vaguely reluctant. "We shouldn't send ${fname} on a suicide mission."
    *goto whatpropose    
  *selectable_if (spiritism > 60) #"I could use a spirit gate to take them back out here."
    *set banditoutcome 1
    *if (spell3 = "gates")
       "I've done it for Ilya before, I can do it for them," you add.
       
       "Fourteen trips in a row? That's too reckless, ${fname}," Ilya chides, arms crossed. "You're just asking to die of mana exhaustion.
    *else
       "It'll be tough work given the circumstance, but I think I can pull it off."
       
       "Fourteen trips in a row? That's too reckless, ${fname}," Ilya chides, arms crossed. "You're just asking to die of mana exhaustion.
  *selectable_if (enchantment > 60) #"I could use an invisibility enchantment to sneak them out."
    *set banditoutcome 2
    "I just need Saine to sketch a rough map of the encampment, and I'll take care of the rest."

    "You're insane if you think you can sustain eight Glyphs of Invisibility at once," Ilya chides, arms crossed. "That's just asking to die of mana exhaustion.
Leon, you can't approve of this."
*label whatpropose

"Then what do you propose we do?" Leon says, frustrated. "We can't just leave them there to die!"

Ilya bites her fingernails, and you can almost hear the cogs whirring in her brain. "We'll have to go back to town," Ilya tries, though doubt colors her voice. "Find some proper support. The risks are unfortunate, but rushing in there with a half-baked plan is irresponsible. It endangers both the children and ${fname}."

"That'll be a two-day return trip, if we're being generous," Saine mourns, eyes downcast. "Plenty of time for the kids to be sold off. Or die."

"Then three of us will stay here, scouring the perimeter for any outgoing shipments," Ilya suggests. "We'll ambush them and rescue the kids from the caravan while
*if (spiritism > 60)
  ${fname}
  *goto size
*else
  Saine
  *goto size
*label size
goes back to town."

"But the size of that encampment...I'm sure some will slip through the cracks," Saine says. "And we can't split up. Even if we can take them on by ourselves, some might slip away to alert the base, and then this will all have been for nothing."

"I'm sorry. You know I don't like this any more than you do. But we'll have to learn to forgive ourselves if the circumstances are stacked against us."

*choice
  #Agree with Ilya.
    *set rilya %+ 15
    *set rleon %- 15
    "Alright," you say, looking at Ilya. "I'm sorry to have worried you."

    Ilya's grin is crooked, at once relieved and mournful. "Thank you. Thank you for seeing reason."

    There's something dark and conflicted in Leon's eyes as he gazes towards the encampment, but it's gone as quickly as it appeared.
    *if (spiritism > 60)
      *set banditoutcome 3
      *set spiritgate true
      *set scounter +1
      "Okay, then that's what we'll do. You can use Spirit Gate to get back faster, right ${fname}?"

      You nod in confirmation. "If I'm hiring two fighters..." you pause, doing the calculation in your head. "I should be back the dawn after tomorrow."

      "Then we strike at noon, after you've had a bit of rest. Godspeed, ${fname}."
      *page_break
      *achieve retreat
      *goto outcome3
    *else
      *set banditoutcome 4
      "Okay, then that's what we'll do. Saine, an estimate?"

      "I'll be able to go to town pretty quickly, but the way back will be slow because of the hired goons," he says matter-of-factly. "I'd say...afternoon, two days from now?"

      Leon closes his eyes, a pained expression on his face. "We'll have to settle for that, then. Godspeed, Saine."
      *page_break
      *achieve retreat
      *goto outcome4
  #Insist on your plan.
    *set rleon %+ 15
    *set rilya %- 10
    "If there are to be risks either way, I'd rather be the one to bear them," you say, steeling yourself. "Please have a little faith in me. I can do this."

    "Don't you have any regard for your own safety?" Ilya snarls, concern and anger in the same breath. "Why are you so hell-bent on throwing your life away like this?"
    *choice
        #"Because I know what it feels like to lose family."
            "If my blood can see even one child returned to their mother's arms, then so be it."
            *set emotional %+ 15
            *set preemotional %+ 15
        #"It's seven lives against one. This is the only justifiable choice to make.."
            *set emotional %- 15
            *set preemotional %- 15
        #"You know what I'm capable of, Ilya. Trust me, I can handle a few bandits."
            *set optimistic %+ 15
            *set preoptimistic %+ 15
        #"Biding our time would spell a death sentence for those kids."
            *set optimistic %- 15
            *set preoptimistic %- 15
    Leon looks at you fondly, though it's hard not to notice the worried crease in his brow. "You're a good person, ${fname}," he says, before turning his gaze back towards the encampment. "We'll move forward with your plan, then."

    Ilya immediately whirls on Saine, looking to the last hope of support she has. The rogue shrugs his shoulders apologetically. "I think it should be ${fname}'s call to make."

    The healer looks ready to throw a tantrum, but soon thinks better of it. "I don't like this one bit," she sighs, resigned. "But I seem to be outvoted."

    "Thank you for your concern, really. I'll be fine."

    "You better," she says, and then her arms are around you. "Come back safe. Come back safe."

    Leon and Saine join her in the hug, and you stay like that for a while, a bundle of bodies under the cold winter snow. You pretend not to hear Ilya praying under her breath, her voice quiet and trembling.

    "Alright," Leon finally says as he breaks away. "Let's do this."
    *page_break
    *if (banditoutcome = 1)
      *achieve rushin
      *goto outcome1
    *elseif (banditoutcome = 2)
      *achieve rushin
      *goto outcome2
    *else
      *achieve rushin
      *goto outcome5
*label outcome1
*set spiritgate true
*set scounter +1
*set survivorcount 7
You spend an hour or so finalizing the finer points of the plan. It's a simple and straightforward one: using a rough map of the encampment Saine provided, you are to construct a spirit gate that links the encampment prison to a clearing inside the woods. Then, after having transported all seven of the kidnap victims, you are to guard them as the rest of the White Fangs begin their assault in earnest. If you're in critical condition, Ilya will have to stay behind with you, placing Leon and Saine at tremendous risk during the assault.

"We can't delay the assault, can we?" Leon wonders. "Even if it's me and Saine, two against twenty is a bit..."

"Not if we don't want them to take the fight to us," Ilya says, shaking her head. "They'll do it as soon as they realize the children are missing. And if that happens the children would still be in the line of fire, not to mention we'd be down a mage."

"Alright, we'll just have to make do, then. ${fname}, ready when you are."

You nod and construct the spell circle's foundation, imagining the dark hallways of the encampment and the dingy prison on its northwest corner. Once you have a good grasp on the location, you call upon the spirits to construct a direct pathway, opening a dark purple portal that should transport you directly to the hostage children.

"Godspeed, ${fname}," you hear Leon say as you enter the portal.
*page_break
When your eyes open once more, it is to behold the sight of seven children, nearly skeletal from starvation, various marks of abuse like brands upon their tiny bodies. Some are alarmed by your sudden appearance, but too weak to yell—others seem to have resigned themselves to any fate, regarding you with a tired indifference.

"I'm here to help," you whisper quietly, holding a finger to your mouth. "I'll take you somewhere safe, okay?"

You offer your hand to the child closest to you. For a moment, she appears conflicted, clearly suffering trust issues as a result of her abuse. But eventually she seems to decide that any fate is better than her current one, and takes your hand willingly. You feed her a makeshift healing tonic to strengthen her for the ride, and together you both step into the portal.

Ilya rushes you both as you emerge on the other side, immediately working her theurgy on the weakened girl.

"This is horrible," she says under her breath, quietly furious. "To such a young girl, how could they..."

"We'll be sure to make their deaths painful," Leon swears. "These lowlifes deserve no mercy."

You nod in agreement, winded from the trip but already working on your second portal.
*page_break Six trips later
Despite Ilya's fears, you don't end up dying from mana exhaustion, though you definitely cut it a little close. Leon tries to leave Ilya with you anyway, fearing a delayed recoil. You had to sock him in the face to show him you've still got plenty of fight in you should worse comes to worst.

[i]Too bad it was all a bluff[/i], you mourn as you stand face-to-face with a burly bandit you recognize as one of the pack's top dogs. He must've had some sort of tracking ability to find you all the way out here, alone and barely functional with the kids all scattered in the woods behind you.

"Ye piece of shit," he growls, taking a menacing step forward. "Ye an' ye lil friends gonna pay for what ye done." And he charges, cutlass swinging every which way.

You manage to sidestep his first blow, rolling under him while throwing a fistful of snow and dirt into his eyes. Knowing this is the only opportunity for a counterattack you're gonna get, you quickly build the first spell circle that comes to mind, pouring all the mana you've got remaining into
*if temp1 = "claycannon"
  Clay Cannon.
  *goto ducts
*elseif temp1 = "subjugation"
  Glyph of Subjugation.
  *goto ducts
*elseif temp1 = "morana"
  Morana's Wail.
  *goto ducts
*else
  Fist of the Dark Lord.
  *goto ducts
*label ducts

Unfortunately, it seems you've overestimated your own capabilities, as your mana ducts scream in protest and the spell grinds to a halt. The bandit leader seizes upon the momentum, closing in on you as you reel from the effects of mana exhaustion, and this time his attack connects:
*label damaged
*choice
  #The blunt side of his cutlass slams into the side of my head with tremendous force.
    *set learning %- 50
    *set injury "concussion"
    *goto blackout
  #His cutlass slices clean across my face, flaying a good bit of flesh around my cheek.
    *set charisma %- 50
    *set injury "facecut"
    *goto blackout
  #He body slams me into the ground, his knees on top of my own as I feel something break.
    *set intrigue %- 50
    *set injury "brokenknee"
    *goto blackout
*label outcome2
*set glyphofinvisibility true
*set ecounter +1
*set survivorcount 7
*set campsurvivor "sheltered"
You spend an hour or so finalizing the finer points of the plan. It's a simple and straightforward one: you are to cast the Glyph of Invisibility on yourself to sneak into the encampment, and cast the Glyph again on the children before sneaking your way back out. The rest of the White Fangs will be stationed right outside, ready to leap into combat either when you've arrived back to safety or when the encampment launches itself into a commotion, signifying that you've been found out.

"I'll handle the first enchantment," Ilya says beside you. "You're a better enchanter than me, but you need to conserve your mana."

Sure enough, Ilya completes the spell and the Glyph's effects settle upon you like a cloak. "Godspeed, ${fname}," you hear Leon say as you make your way inside the encampment.

Once inside the building, it was a straight shot to the bandits' holding cells thanks to Saine's reconnaissance and his subsequent directions. You hold the cell lock in your hand and melt it with a simple flame thaum, its remains clattering harmlessly to the stone floor. You step into the jail cell, having dispelled the enchantment to properly present yourself to your rescuees. As promised, there are seven children altogether—all of them nearly skeletal from starvation, with various marks of abuse like brands upon their tiny bodies. Some are alarmed by your sudden appearance, but too weak to yell—others seem to have resigned themselves to any fate, regarding you with a tired indifference.

"I'm here to help," you whisper quietly, holding a finger to your mouth. "I'll take you somewhere safe, okay?"

You offer healing potions to the child closest to you, knowing she and the others will have to walk out of this place on their own two feet. For a moment, she appears conflicted, clearly suffering trust issues as a result of her abuse. But eventually she seems to decide that any fate is better than her current one, and drinks the draught willingly. As color returns to her cheeks, she passes the draught around for her cellmates to drink, and the others obey her request faithfully, seemingly regarding her as a leader of sorts.

Once you're confident they've got enough strength to make it back out, you cast eight separate Glyphs of Invisibility, feeling your mana ducts strain and stretch due to the load. Despite Ilya's worries, the spell was successfully cast, and you carefully guide the children through the bandit-infested camp.

Unfortunately, your luck doesn't hold out the whole way through. As you pass the last throng of bandits before the exit, you feel your chest begin to heave from the early signs of mana exhaustion, and your spell begins to fail. You and the children flicker in and out of sight for a few moments, but those moments were fatal—the bandits had quickly caught on to what was going on. They began rushing your invisible group, cutlasses and scimitars waving every which way, and as the children run to safety one slides dangerously under a bandit's blade. Your feet move before you could even realize what you were doing, and placing yourself between the boy and the bandit, you take the full brunt of the attack:
*goto damaged

*label outcome3
*set prestige +10
*set survivorcount 5
*set campsurvivor "taken"

Through the use of spirit gates, you were able to clear hours of travel in a single step, though the exertion leaves you winded and needing of brief rests along the way. You make good time in returning back to Calinger, arriving at the city at daybreak and allowing yourself a brief rest at the local inn. With your vitality restored, you pay a visit to the local guild and hire two fighters at higher-than-standard rates, explaining that they'll have to go through spirit gates to get to the area of conflict.

You find two willing fighters by noon and manage to arrive back at the encampment at midnight, a few hours before the promised time. Ilya ushers you and the fighters into a makeshift tent, working her theurgy to get your health and stamina back up to par. Leon decides to take advantage of the early arrival, suggesting an assault before dawn to catch the bandits at their sloppiest.

The plan works out to be a resounding success. With the two fighters picking up the slack, Leon was able to dispatch Saine as an escort for the prisoners, a duty he fulfilled with flying colors. After Leon beheads the last of the bandits, the five of you go to meet them outside the building.

"There's only five of them,"
*label mourn
Saine mutters mournfully, handing out flatbreads to the starving survivors. "They say two of them had been taken away before we came. We don't know what happened to them."

Leon looks ready to punch something, before he notices the timid stares of the survivors and thinks better of it. "Damn it all," he finally says.

"We have to be satisfied with this," Ilya advises, voice weak—as is to be expected, given that she provided support for five fighters compared to the usual three.

You notice her begin to sway on her feet, eyes losing focus. The others appear none the wiser.
*choice
  #"Ilya, you don't look so good. Anything we can do for you?"
    *set charming %+ 15
    *set precharming %+ 15
    She blinks her eyes hard, seemingly to force consciousness. "I'll be fine, thank you. Anyway, I meant what I said.
  #Ilya is well aware of her limits—she'll let us know if she needs help.
    *set charming %- 15
    *set precharming %- 15
    She blinks her eyes hard, seemingly to force consciousness. "I mean it, Leon.
  *selectable_if (Alchemy > 60) #I offer her a potent mana recovery potion I brewed back in Calinger.
    *set rilya %+ 15
    *set manarecoverypotion true
    *set acounter +1
    Ilya smiles fondly at the offer, and thanks you before downing the draught in one go. Color returns to her features almost instantly, and she thanks you before turning to Leon once more. "I mean it, Leon.
  *selectable_if (Enchantment > 74) #I quietly cast a Glyph of Magesong, sacrificing my own mana to replenish Ilya's.
    *set rilya %+ 15
    *set glyphofmagesong true
    *set ecounter +1
    You had intended the action to be discreet, but you catch Ilya's eyes widen with recognition and surprise as color quickly returns to her features. She gives you a grateful look before turning to Leon once more. "I mean it, Leon.
We shouldn't beat ourselves up over externalities."

The swordsman nods, pursing his lips. "You're right, Ilya. I know you're right. It's just...they were right there. I can't help thinking, if we'd done something different..." he trails off, taking deep breaths to calm himself down. "I'm sorry. Let's get back to town."

You nod your head in agreement, and the White Fangs begin their quiet march back to Calinger.
*page_break Three days later
You part ways with the hired fighters at Calinger's gates, Leon dispensing a generous amount of silver to them for a job well done. With the children in tow you make your way to the local inn in Calinger, where the White Fangs have essentially set up base. As the sun sets on the horizon, locals endow the procession with the most blatant of stares, ranging from horror to curiosity to wonder. By the market stalls a milkmaid fans herself in distress, furiously whispering in a cadence only she could've thought of as discreet: "L-Leon has children?
*if (banditoutcome = 3)
  Five
  *goto ofthem
*else
  Three
  *goto ofthem
*label ofthem
of them? Oh, my husband!"

Her gaze then turns on Ilya, features distorted in barely-concealed hatred—the healer only sighs at the accusation, clearly long-suffering. A few paces behind her, Saine makes a sound remarkably like that of a dying cat.
*choice
  #Mess with the milkmaids.
    *set intrigue %+ 10
    *set rleon %+ 10
    *set glyphofailment true
    *set ecounter +1
    You quietly work on the spell, the casting hand nestled between your robes to mask the circle's light. With a barely-audible [i]whoosh[/i] the spell make its way to the milkmaids, all of whom were immediately stunned into silence. Their faces twisted into a veritable opera—plastered first with surprise, then confusion, then sheer, unadulterated [i]terror[/i] as their bowels, as if possessed, began to move of their own accord. They scattered to the four winds as the cacophony of noises were released, the unmistakable pungent smell pervading the air.

    A cheap trick, really, and the oldest one in the book, but effective nonetheless. You allow yourself a small smirk; it does not escape Leon's notice.

    "You shouldn't have done that," he scolds, though there's light dancing in his eyes.

    "I don't know what you're talking about," you shrug, putting on an air of indifference as you make your way to the inn.

    Leon breaks out into his trademark grin in response, all dimples and crinkled eyes. His right arm slings around your shoulder good-naturedly, and it remains there for the rest of your journey. You don't quite have it in you to tell him he smells of days of sweat and dirt—you suppose it's some sort of karmic punishment for the putrid trick you wrought on the milkmaids.
    *goto easysleep
  #Tease Leon about it.
    *set charisma %+ 10
    *set rsaine %+ 10
    "I must say, I'd have never pegged you for the...[i]precocious[/i] type."

    Leon rewards your betrayal with a withering gaze. "Not you too."

    "What, wrong adjective? Would you have preferred [i]prolific[/i]?"

    "Oi!" The swordsman yells as he strong-arms you into a chokehold. Between the laughter and the blocked airways you find yourself struggling for breath—not that Leon cares, as he drags you fuming in the direction of the inn.

    "Mercy, mercy!" you gasp, still laughing. Leon is deaf to your pleas, his face burning a dangerous shade of red as he marches furiously towards the inn.
    *page_break
    Ilya immediately corrals the children upstairs the moment you step into the building, judiciously ignoring the ruckus brought on by her companions. The fussy innkeep is directed to Leon to formulate a new lodging arrangement, and it is only as you reach the reception table that the swordsman releases you from his deadly vicegrip.

    The elderly innkeep finishes totaling the expenses and hands Leon some loose change with a smile. "You've got a beautiful family," she says guilelessly, eyesight too poor to notice the look of pure vitriol the blond had shot her. You and Saine wheeze at the sidelines as Leon immediately makes for the stairs, stomping his feet all the way.

    "Oh, my husband," Saine shouts after him between peals of laughter. You cover the teen's ears as his brother launches into a rare outburst, his stream of increasingly creative profanities fading in the distance as he climbs.
    *label easysleep
    
    Sleep comes easily to you that night.
    *page_break
    *goto dream
*label outcome4
*set prestige +5
*set survivorcount 3
*set campsurvivor "taken"
Saine returns at the promised time with two burly, reliable-looking fighters in tow. Ilya ushers him and the hired fighters into a tent, working her theurgy to get them back to their prime, and informs Leon that they should be combat-ready. Leon eventually decides on a night assault, hoping to catch most of the bandits sleepy and unprepared.

The plan works out to be a resounding success. With the two fighters picking up the slack, Leon was able to dispatch Saine as an escort for the prisoners, a duty he fulfilled with flying colors. After Leon beheads the last of the bandits, the five of you go to meet them outside the building.

"There's only three of them,"
*goto mourn
*label outcome5
*set survivorcount 1
*set campsurvivor "jania"
You spend an hour or so finalizing the finer points of the plan. It's a simple and straightforward one, almost worryingly so: as Leon, Saine, and Ilya draw the brunt of the bandits' assault, you are to clear a path to the holding cells with sheer firepower, free the kids, and run back outside. The rest of the White Fangs will do what they can to keep the heat off you, but it falls to you to protect the children and see them out safely.

Saine takes the lead in the assault, taking advantage of the bandits' unawareness to launch a preemptive strikes. Two of the bandits lay dead on the ground before one can properly counterattack his strikes, and the building devolves entirely into a chaotic battlefield.

Sticking to the plan, you rush towards the holding cells as detailed by Saine's reconaissance results, slinging
*if (thaum > 60)
  Morana's Wail
  *goto path
*elseif temp1 = "claycannon"
  Clay Cannon
  *goto path
*elseif temp1 = "subjugation"
  Glyph of Subjugation
  *goto path
*elseif temp1 = "morana"
  Morana's Wail
  *goto path
*else
  Fist of the Dark Lord
  *goto path
*label path
to smack aside all enemies in your path and successfully reaching the cell before anyone else does. As promised, there are seven children altogether—all of them nearly skeletal from starvation, with various marks of abuse like brands upon their tiny bodies. Some are alarmed by your sudden appearance, but too weak to yell—others seem to have resigned themselves to any fate, regarding you with a tired indifference.

"I'm here to help," you whisper, winded from the exertion. "I'll take you somewhere safe, okay?"

You offer healing potions to the child closest to you, knowing she and the others will have to walk out of this place on their own two feet. For a moment, she appears conflicted, clearly suffering trust issues as a result of her abuse. But eventually she seems to decide that any fate is better than her current one, and drinks the draught willingly. As color returns to her cheeks, she passes the draught around for her cellmates to drink, and the others obey her request faithfully, seemingly regarding her as a leader of sorts.

Once you're confident they've got enough strength to make it back out, you tell them to follow you as attack spells form on your fingertips. You are assaulted by a bandit almost immediately upon exit from the holding cell, but through a mixture of luck and your survival instincts kicking in, you successfully spear the man with an icicle before he could reach the children.

Unfortunately, your luck doesn't hold out the whole way through. As you pass the last throng of bandits before the exit, you feel your chest begin to heave from the early signs of mana exhaustion, and your spells begin to fail. What was intended to be a flurry of icicles instead materialize as a frigid blast of wind, and your normally massive Clay Cannons only materialize to cannonballs the size of a fist. The bandits seize upon their momentum, and before long you are overwhelmed by stragglers from the main battle. Cutlasses and scimitars wave every which way, and as the children run to safety one slides dangerously under a bandit's blade. Your feet move before you could even realize what you were doing, and placing yourself between the boy and the bandit, you take the full brunt of the attack:
*goto damaged

*label blackout

You think you hear someone calling your name as your consciousness slips away.
*page_break

…

*page_break
*label dream
[i]The rain comes down in sheets, and yet the smoke billows all the same.[/i]

[i]You are besieged by the familiar, acrid smell of gasoline and magefire as blue-green tongues of flame lash and swallow up the place you had reluctantly begun calling home. As thunder rends the sky asunder you can't help but fear your newfound freedom: for all that you had suffered within these walls, it had presented a steady, familiar routine. Nevertheless, the ensorcelled flames burn on relentlessly, iron beams and wooden panes withering under the unforgiving heat.[/i]

[i]You turn to stand over the researcher's dead body, twisted and half-buried in the rubble of your former prison. It makes for an eerie sight, his broken form powerless under chipped bricks and shattered glass, joints bent at unnatural angles as the pelting rain washes away blood and mud alike. How quickly the wheel turns, when just yesterday he had held a knife against your forehead, your blood burning as it dripped, dripped down onto your jaw, mockingly steady against your trembling lips—[/i]
*page_break "${fname}."
[i]You whirl around to face Sister and Eli, each a silent mirror of the other, faces covered in soot and eyes indifferent. The ghost of a smile adorns Sister's lips as she bends and picks up a large piece of stone, black and jagged, and hangs it over the researcher's dead visage. The stone drops hard against his face, bashing the skull in with a wet, sickening crunch.[/i]

[i]"Bye-bye," she giggles, her voice sickly sweet.[/i]

[i]Wet hair sticks to her face in clumps, a striking midnight black against the sickly pallor of her skin. Beside her Eli is solemn as ${ehe} holds a hand out to you, and though ${ehis} gaze is on something far away you grip it hard and steady, the last remnant of life as you know it before the rug is to be pulled once more.[/i]

[i]$!{ehe} leads you to the copse just beyond the stone footpath, Sister trailing silently behind you. There are faces you do not recognize nestled between the trees, their forms darkened in the shade and sinister against the occasional lightning. The tallest of the bunch comes forward, a sword laid down on the muddy ground as he kneels in front of you.[/i]
*page_break
[i]"It's over, child," he says, a hand reaching for your own. You shrink away from the attempt, pointedly ignoring how his face falls—there is too much kindness in his features, his gestures carefully measured to engineer approachability. But you know better—you had to. There was a time when the researcher carried himself in much the same way, a time before the spells and the scalpels burnt against your skin every day.[/i]

[i]"I knew your mother," he tries, eyes gentle. There is a worldly weariness in the slopes of his aged face, shoulders hunched forward under the weight of time. "She was beautiful and kind, and there is much of her in you. She was Salantira's best and a dear friend of mine, the Countess..."[/i]

*label lnamechoice
*choice
  #[i]...Rynenhal.[/i]
    [i]You were born into House Rynenhal?[/i]
    *choice
      #[i]Yes[/i]
        *set lname "Rynenhal"
        *goto widen
      #[i]No[/i]
        *goto rename
  #[i]...Orlaigne.[/i]
    [i]You were born into House Orlaigne?[/i]
    *choice
      #[i]Yes[/i]
        *set lname "Orlaigne"
        *goto widen
      #[i]No[/i]
        *goto rename
  #[i]...Melmesne.[/i]
    [i]You were born into House Melmesne?[/i]
    *choice
      #[i]Yes[/i]
        *set lname "Melmesne"
        *goto widen
      #[i]No[/i]
        *goto rename
  #[i]...Arbolais.[/i]
    [i]You were born into House Arbolais?[/i]
    *choice
      #[i]Yes[/i]
        *set lname "Arbolais"
        *goto widen
      #[i]No[/i]
        *goto rename
  #[i]...Selencal.[/i]
    [i]You were born into House Selencal?[/i]
    *choice
      #[i]Yes[/i]
        *set lname "Selencal"
        *goto widen
      #[i]No[/i]
        *goto rename
  #[i]...Talovaire.[/i]
    [i]You were born into House Talovaire?[/i]
    *choice
      #[i]Yes[/i]
        *set lname "Talovaire"
        *goto widen
      #[i]No[/i]
        *goto rename
  #[i]...Edenhaut.[/i]
    [i]You were born into House Edenhaut?[/i]
    *choice
      #[i]Yes[/i]
        *set lname "Edenhaut"
        *goto widen
      #[i]No[/i]
        *goto rename
  #[i]...Saungalle.[/i]
    [i]You were born into House Saungalle?[/i]
    *choice
      #[i]Yes[/i]
        *set lname "Saungalle"
        *goto widen
      #[i]No[/i]
        *goto rename
  #[i]..Yulevine.[/i]
    [i]You were born into House Yulevine?[/i]
    *choice
      #[i]Yes[/i]
        *set lname "Yulevine"
        *goto widen
      #[i]No[/i]
        *goto rename
  #[i]...I belong to none of these Houses.[/i]
    *label inputlname
    Is that so? What house were you born into, then, all those years ago?
    *input_text lname
    You were born into House $!{lname}?
    *choice
      #Yes.
        *set lname "$!{lname}"
        *goto widen
      #No, I was born into another House.
        *goto inputlname
*label rename
[i]What House were you born into, all those years ago?[/i]
*goto lnamechoice

*label widen
[i]Your eyes widen in recognition of the name, though you avert your gaze still. You have not heard it in a long time, as much as it would always remain a part of you—and you had resigned yourself to never hearing it again.[/i]

[i]"I...I failed her, when I ignored her warnings. Her estate destroyed, her life taken, and her heir missing...I am sorry," he says, and there are genuine tears upon his cheeks, clearing pale streaks against the soot on his face. "Will you let me try to make amends?"[/i]

He reaches out with trembling fingers, then, and you find yourself too spellbound to pull away.

[i]"I beg of you, child, let me do right by your House."[/i]

*page_break

You break away from the dream with an atypical peace, though your vision still swims with the memory of that stormy night as you rise to a sitting position.  Again, instincts bid you do a cursory check on your seals, and you sigh in relief when they appear to have held strong this time around.

"${fname}, you're awake."
*if (((banditoutcome = 1) or (banditoutcome = 2)) or (banditoutcome = 5))
  Ilya rushes to your side, concern plain on her features. It appears you've wound up back at the inn in Calinger, where the White Fangs have essentially set up base for the past few months.

  "What...happened?" you try, immediately regretting it as your throat chafes from the effort.

  "You got hurt," Ilya says gently. "And you've been asleep for two days."

  "Well, that's not too bad," you sniff. Ilya looks ready to smack you. "The kids?"
  *page_break
  *if ((banditoutcome = 1) or ((banditoutcome = 5) and (thaum > 74)))
    *set prestige +20
    *set kidsafe "all"
    *set campsurvivor "sheltered"
    *achieve maxcamp
    *comment Two of the children abducted in this scenario were sheltered by the Father, where they would later fall victim to the twins.
    *set rilya %+ 20
    *set rleon %+ 20
    *set rsaine %+ 20
    A grin adorns her features as she looks at you fondly. "You saved them, ${fname}. Every last one. Seven children will be brought back to their families. All because of you."

    Relief washes over you like a tide, along with just a hint of disbelief. "You're serious?"

    "Completely."

    *choice
        #The news is overwhelming. I hug Ilya, almost as a reflex.
            *set rilya %+ 10
            *set emotional %+ 15
            *set preemotional %+ 15
            She seemed to be caught off guard for a moment, but soon returns the hug willingly. "You did well," she whispers. "You were reckless, but you did so well."
            *goto injuries
        #I bask in the satisfaction of a job well done.
            *set emotional %- 15
            *set preemotional %- 15
            You allow yourself a small smile, proud of the knowledge that those scared, broken children will go back to the arms of their loved ones. Happiness bubbles in your stomach as you feel a weight slide off your shoulders. "You did well," Ilya whispers, holding your hands in her own. "You were reckless, but you did so well."
            *goto injuries
        #It feels disrespectful to celebrate. We may have saved them, but there's no telling what kind of trauma they endured.
            *set optimistic %- 15
            *set preoptimistic %- 15
            You think back to the terrified, emaciated bodies and can feel nothing but sorrow and dread. It may be the case that they will be rejoined with their families once more, but it's unlikely that their scars and trauma will ever heal.
            *goto injuries
  *elseif ((banditoutcome = 2) or ((banditoutcome = 5) and (thaum > 60)))
    *set prestige +15
    *set rilya %+ 15
    *set rleon %+ 15
    *set rsaine %+ 15
    *set campsurvivor "sheltered"
    *comment Two of the children abducted in this scenario were sheltered by the Father, where they would later fall victim to the twins.
    A sad smile graces her features; she appears to contemplate holding back information from you. "Tell me," you insist, hand gripping her arm.

    "You saved most of them, ${fname}. We'll be spending the next few weeks escorting six children back to their homes. All because of you."

    "Six...? Oh no," you mutter, the realization sinking in like molten coal in the pit of your stomach.

    "You musn't blame yourself. We've saved more of them than anyone ought to have expected to, given the circumstances."

    "Did...did they suffer?"

    "No," she says, holding your hands in her own. "It was a quick death. We didn't know how to find his parents or relatives, but we've given him a proper burial in the local graveyard."

    *label wellup
    Ilya squeezes your hands tenderly, deciding she can do nothing more for you. "I'll leave you to rest," she says, and is gone.

    As her figure leaves the room, the emotion that wells up within you is one of...
    *choice
        #...quiet resignation. It is what it is.
            *set emotional %- 15
            *set preemotional %- 15
            Indeed. Life is a fragile, fleeting thing, as the dead boy has proven. Spending yours in guilt over factors outside your control is the height of foolishness. You repeat the words over and over in your head, willing yourself to believe them as sleep takes you once more.
            *goto injuries
        #...crippling guilt. If only I had done better.
            *set emotional %+ 15
            *set preemotional %+ 15
            You remember well the frightened faces of the children, how they overcame their fears to trust you with their lives. How you've failed them, in the end. You mourn them and their tragic fate as the silent room fills with your sobs, and sleep takes you once more.
            *goto injuries
        #...acceptance. It could've gone much, much worse.
            *set optimistic %- 15
            *set preoptimistic %- 15
            The bandits had a numerical and geographical advantage, not to mention hostages they could exploit to their benefit. That all of the White Fangs survived the encounter despite it all is already a small miracle.
            *goto injuries
  *else
    *goto finalelse
*elseif ((banditoutcome = 3) or (banditoutcome = 4))
    
  Leon is sitting on an outcropping of wall by the windowsill, the top buttons of his shirt undone and a glass of hazy liquid in his hand. In the light of the full moon, his dishevelled hair gleams like platinum against the night sky. It makes his eyebags and the tired linings of his face that much more prominent.

  "Rough night?" you croak, your voice still laden with sleep. Saine stirs in the bed next to you, but falls right back to sleep.

  "Yeah," Leon slurs, taking a sip from his glass. It's clear that the man is at least tipsy, and that there's a lot on his mind.

  *choice
    #Offer him a listening ear.
      *set charming %+ 15
      *set precharming %+ 15
      You stretch and rise from the bed, taking a seat opposite of him by the window. "You wanna talk about it?"

      Leon's gaze is intense as he scrutinizes you. The man wears his emotions on his sleeves—it is plain that whatever thoughts are plaguing him right now, he isn't proud of them, and he'll clam up at the first sight of any judgment.

      *if charming > 50
        You flash him an easy, open smile—the best you could manage, given the drowsiness that still hangs heavy in your system. Leon sniggers as he looks away, appearing to find whatever countenance you end up putting on terribly amusing.

        "You're hurting my feelings," you yawn.

        The blond leans his head against the pane, a light smile on his lips and his guard clearly down. "Right, I'm sorry," he doesn't look all that apologetic, "It's just..."

        He swallows, and tries again.
        *goto justch
      *else
        Your years of brooding and silence (and the drowsiness still in your system, probably) serve you well as your poker face slips on like a mask. Leon searches your blank slate of an expression for anything that could confirm his insecurities; he sighs as he comes up empty.

        *goto justch
      *label justch
      "It's just the children we couldn't get to in time. They...must be in a bad place right now."

      "That's a likely scenario," you confirm. No sense in sugarcoating when neither of you would be fooled.

      "That day just keeps playing back in my head, over and over again. If we had taken a different approach, if we had split up while waiting for reinforcements—would they be here with us? Waiting to be reunited with their mothers?" His voice is breaking, knuckles white at his side. "I must've made the wrong call, ${fname}. And those children are paying the price."

      The silence is deafening as you search for the words to say. Leon pours himself another shot, clearly looking to get drunk tonight. "I'm sorry, ${fname}. You must think I'm being childish."
      *choice
        #"Not at all."
          *set rleon %+ 25
          "It's not a bad thing, to value life," you say, hugging your knees. "And it's okay to take it as it comes, you know? Ilya means well, but that kind of mentality...just isn't for everyone. It's okay to feel guilt, or sadness, or whatever else is going through your head right now. That's just part of processing."

          Leon is still as he stares out the window. "I'm not sure I follow."

          "There's no one right way to go about this, is what I'm saying," you try again. "It's okay to be feeling whatever you're feeling right now. At some point, in some kind of way, you'll be able to find closure. But you shouldn't be in any hurry to get there."

          "I see." He purses his lips together, looking uncertain. "You've...been through something like this before."

          It's not a question, so you don't answer. The blond looks away, the ghost of a smile on his face. "I get it. I think," he says, and downs the rest of his drink. "Thank you, ${fname}. I needed this."
          *label nodsmile

          You nod, returning his smile, and steer the conversation towards small talk.
          
          The night passes in a quiet, companionable silence.
          *page_break
          *goto spendday
        #"A little, yeah."
          *set rleon %+ 10
          *set noble %- 15
          *set prenoble %- 15
          "I think Ilya had the right idea," you say, treading carefully. "This may have been the first time something like this has happened for you, but it definitely won't be the last. Callousness is a virtue, in this line of work."

          Leon is still as he stares out the window. "I get that, I think. But it's...easier said than done."

          "I know. And the feeling won't go away easily, not at first," you say, shaking the memories out of your own head. "But you've got to put in conscious effort, or it will stay with you forever, eating at you from the inside. You deserve better than that."

          The blond looks away, grim and chastened. "I'll try, ${fname}," he finally sighs. "Thanks for the talk. I needed it."
          *goto nodsmile
        #"It was me that made the call, not you."
          *set rleon %+ 15
          *set emotional %- 15
          The swordsman slowly turns his gaze on you, lips tightly pursed together, imploring you to continue.
          
          "The call to seek reinforcements was [i]mine[/i], made out of concern for [i]my[/i] safety," you say, matter-of-fact. "For the outcome to have been any different, you would have needed to send me into danger against my will—no, against the entire party's agreement. With the benefit of hindsight, is that what would you have done?"
          
          "No," Leon says, quick, urgent. "${fname}, you know I would never…"
          
          "I do know," you interject, holding a hand up to him. "But that's just the thing. Where you see opportunities not taken, you should also see risks not braved. I could very well have [i]died[/i] there, Leon. Instead, I live to fight another day—and if fate should see our paths cross again, I will be far better prepared to save the kids that remain."
          
          "…I see," Leon pensively concedes, after a while. "You've always been so strong, ${fname}, so sturdy—in my mind, I think I might've always taken your survival for granted," he murmurs, wry. "Foolish."
          
          "We made the right call, in the end. That's all that matters," you supply with a chuckle. "You've got a heart a couple sizes too big for your station in life. It's bound to lead you to ill judgments every now and again—and that's exactly what we're here for."
          
          "You're right," he sighs, shooting you a hesitant smile. "As you always are."
          
          "Glad we can come to an agreement," you say, before deftly steering the conversation towards small talk.
          
          The night passes in a quiet, companionable silence.
          *page_break
          *goto spendday
    #Go back to sleep. No sense in prying if he doesn't think I could help.
      *set emotional %- 15
      *set preemotional %- 15
      "Feel better soon," you say. Leon smiles wanly in return, taking another sip of his drink. You lay your head back down and let sleep take you once more.
      *page_break
      *goto spendday
*else
  *label finalelse
  The look that crosses her face is one of pure trepidation; she appears to contemplate holding back information from you. "Tell me," you insist, hand gripping her arm.

  There's a troubled crease in her brow, but she eventually yields. "The bandits...got to them, after you blacked out. We managed to save one child, but..."

  "No," you say, the knowledge settling like molten coal in the pit of your stomach. "No."

  "You musn't blame yourself. You did the best you could, alright? We all did."

  "Did...did they suffer?"

  "No," she says, holding your hands in her own. "All of them passed quickly. We didn't know how to find their parents or relatives, but we've given them a proper burial in the local graveyard."

  "I see," you manage, not knowing quite how to react to the news.
  
  *goto wellup
*label injuries
*page_break
*achieve injury
You spend some three more days recovering, and it is only as Ilya weans you off her potent anaesthetics that you come to realize the full scope of your injuries.

*if injury = "facecut"
  Looking into the mirror, you observe the large, raw gash that runs from the top of your nose to the right side of your chin, the extent of the damage surprising even yourself. Ilya assures you that you'll regain vision in your right eye in due time, but your injuries will remain an unsightly scar on your face until the day you die.
  *goto disheart
*elseif injury = "concussion"
  You learn you received a concussion from the sheer blunt force trauma of the bandit's attack, and were about to die of blood loss when Ilya could finally reach you. Though she was able to stymie the bleeding and avoid any immediate danger to your life, the incident will likely impair your memory and brainpower in the long-term. The condition will likely plague you until the day you die.
  *goto disheart
*else
  You learn that your entire right knee was all but shattered from the bandit's assault, the pain so overwhelming it caused you to black out back in the encampment. Though Ilya did what she could, the damage was so extensive that a full recovery proved impossible; you'll ease out of your hobble in due time, but it will only recover into a limp. The condition will likely plague you until the day you die.
  *goto disheart
*label disheart

Unwelcome news, certainly, but not unexpected. Regardless, you find it a bit difficult to feel too bad about the disfigurement, considering what it bought in its stead.
*page_break
*goto spendday
*label spendday

*temp fdcounter 0
*temp freeleon 0
*temp freesaine 0
*temp freeilya 0
*temp freecharisma 0
*temp freelearning 0
*temp freeintrigue 0
*temp freealchemy 0
*temp freethaum 0
*temp freeenchantment 0
*temp freespiritism 0
*if ((banditoutcome = 3) or (banditoutcome = 4))
  You spend the following day the regular post-mission errands, getting assigned administrative works as the others focus on getting the kids healed and home. You make a stop at the mission guild to report the mission's outcome. The task takes you the better part of the day, despite the guild's famously efficient bureaucracy. Following that, you make restock runs to various local shops—whetstones for Saine, armor for Leon, ingredients for Ilya, the works—and sigh in relief as you drop your haul back at the inn, arms feeling like they're ready to fall off.

  When all is said and done, the sun is hanging low on the horizon, painting the sky fuchsia and amber.
  *set fdcounter 3

  It appears you have the rest of the day free. How will you spend it?
  *goto fdoptions
*else
  You spend the day doing the regular post-mission errands—what remains of it, anyway, seeing as the rest of the White Fangs had seen to most of the work when you were out of commission. You make a cursory visit to the mission guild to finalize the White Fang's reports, and drop by the magic store to restock on potions and ingredients.
  *set fdcounter 1
  *goto howspend

*label fdtime
*if fdcounter = 1
  When all is said and done, the sun is hanging directly above your head.
  *goto howspend
*if fdcounter = 2
  The sun has nestled itself between the westward mountains, bathing the city in a cool shade.
  *goto howspend
*if fdcounter = 3
  The sun is hanging low on the horizon, painting the sky fuchsia and amber.
  *goto howspend
*if fdcounter = 4
  The newly-risen moon is shining brightly tonight, casting a mystical glow over the darkened city.
  *goto howspend
*if fdcounter = 5
  The moon hangs high in the night sky, and the streets are empty but for a few homebound passers-by. The city is poised to slumber.

  You stroll aimlessly for a while, taking in the fresh night air and the forlorn streets, before deciding to head back to the inn.
  *page_break
  *goto backinn
*label howspend

*if fdcounter = 1
  It appears you have the rest of the day free. How will you spend it?
  *goto fdoptions
*else
  It appears you still have some free time. What will you do next?
  *goto fdoptions
*label fdoptions
*choice
  *selectable_if (freeleon = 0) #Meet up with Leon.
    *set freeleon 1
    Leon had made himself scarce early in the morning, but with some directions courtesy of the innkeep you're able to spot him browsing produce in the local market. He makes for an odd sight amidst the crowd of peddlers, and his tall, lean figure earns him an alarming number of libertine gazes. You get the distinct impression that these enthusiastic stallkeepers are hawking more than just cabbages.

    "${fname}!" Leon yells out, waving you over to a kiosk stocked with deer meat and spices. "Fancy seeing you here."

    "I was looking for you, actually. I'm done with my errands, so I'm just kind of drifting right now."

    "Oh, sorry," he frowns sympathetically. "I actually can't spend too long here. I need to be back at the inn in an hour or so."

    You shrug in nonchalance. Calinger has plenty other diversions to offer, anyway. "No problem. But what's got you in such a hurry?"

    "Oh, that. I was just thinking that all of us have had a pretty rough week," he says, pursing his lips thoughtfully. "So I thought I'd cook a feast for us. To celebrate clearing the mission, as well!"

    At the declaration, you feel your stomach drop in a traumatized reflex. Your mind immediately recalls the image of his infamous pot-roast deer, thrown together on the trail to Calinger some two months ago. [i]My friends back home really loved it,[/i] he'd assured you as he happily stirred the pot. You should've known something was amiss from the dubious expression on Saine's face.

    You could almost taste that foul concoction on your tongue all over again, the leathery taste of game somehow under [i]and[/i] overcooked, and feel something crawl up your throat, threatening to make you [i]retch[/i]...
    *page_break
    "${fname}? ${fname}, are you okay?" The swordsman waves a hand over your face, brows knitting in worry.

    "Hm? Yes, just peachy."

    His smile is all dimples. "So what do you think? Venison or veal?"
    *choice
        #Bless him, he tries his best. "Veal...I guess."
            *set noble %+ 15
            *set prenoble %+ 15
            *set rleon %+ 20
            He nods thoughtfully at your choice. "I've never tried cooking veal before. This should be interesting."

            You look at him despairingly. "Is it too late to switch to venison?" [i]Better the devil I know[/i], you don't say.

            "I already know what I'm gonna do now," he says, grinning as he points out cuts to the vendor. "What are the White Fangs without a sense of adventure, right?"

            "Right," you agree mournfully, resigning yourself to your impending fate.
        #Survival above all. "I'm sorry, Leon, but you can't cook."
            *set noble %- 15
            *set prenoble %- 15
            *set rleon %+ 20
            *achieve leoncantcook
            The swordsman frowns. "Look, I know the stew from last time didn't sit well with you, but you really are the odd one out. Everyone back home really liked it, and I really am a good cook. Give me another chance?"

            You look at him despairingly. "Leon, please. Spare my bowels."

            "If you don't like it, I'll buy you an ale to wash it down with."

            You don't know how he makes puppy-dog eyes work for him at over six feet tall, but he does. "...Veal, then."

            Leon positively beams. "You won't regret this."
        #Maybe the roast deer is just a one-off? "I'll take my chances with veal."
            *set optimistic %+ 15
            *set preoptimistic %+ 15
            *set rleon %+ 20
            He nods thoughtfully at your choice. "I've never tried cooking veal before. This should be interesting."

            Perhaps your faith was too hastily given. "Is it too late to switch to venison?" [i]Better the devil I know[/i], you don't say.

            "I already know what I'm gonna do now," he says, grinning as he points out cuts to the vendor. "What are the White Fangs without a sense of adventure, right?"

            "Right," you agree mournfully, resigning yourself to your impending fate.
        #I begin backing away slowly, even knowing I have no hope of ever outrunning him.
            *set optimistic %- 15
            *set preoptimistic %- 15
            *set rleon %+ 20
            Alas, you only made it all of three steps before he cuts your retreat short. "Please don't run away," he says, pouting as he hangs onto your wrist. "I know the stew from last time didn't sit well with you, but you really are the odd one out. Everyone back home really liked it, and I really am a good cook. Give me another chance?"
            
            You look at him despairingly. "Leon, please. Spare my bowels."

            "If you don't like it, I'll buy you an ale to wash it down with."

            You don't know how he makes puppy-dog eyes work for him at over six feet tall, but he does. "...Veal, then."

            Leon positively beams. "You won't regret this."
    *page_break
    Coins and meat exchange hands, and soon the both of you are making your way back to the inn. As you turn a street corner, you encounter—[i]are besieged by, more aptly[/i]—a gaggle of women, giggling into their fans as they saunter through the street. At their head is a tall, voluptuous woman, dressed from head to toe in perfectly-tailored black velvet. She walks with the gait of a woman confident in her beauty—and it is not as if it's unfounded. With her angular, symmetrical face and fiery red hair, you imagine she's won a lot of admirers in Calingrian circles.

    "If it isn't the White Fangs." 
    *if (gender = "female")
      She spares you a short, withering gaze—there's a glimmer of something fierce and haughty in her eyes, but it is gone as quickly as it appeared. She turns her attention instead to Leon, honey dripping from her eyes.
    *elseif (gender = "male")
      She spares you a short, inquisitive gaze, like a hunter spotting new prey. For a moment you get the distinct impression that you're being appraised, but as soon as you form the thought she has her attention turned instead on Leon, honey dripping from her eyes.
    *else
      She spares you a short, inquisitive gaze, as if she doesn't quite know what to make of you. For a moment you get the distinct impression that you're being appraised, but as soon as you form the thought she has her attention turned instead on Leon, honey dripping from her eyes.
    *page_break
    "Master Leon," she drawls, sickly-sweet to the point of revolting, though you imagine her beauty always made it work for her. "It's quite rare to see you in town. Are you having a nice day?"

    "Yes, it's pretty—wait, who are you?"

    She covers her stately giggle with a gloved hand. "It's quite rude to ask for a woman's name up front, you know. That is, before taking her on a proper outing."

    Oh, but she's aggressive. You guess she had to be, to compete for Leon's favor in such a...[i]competitive[/i] environment. "Outing...? But ${fname} and I were just heading back to the inn."

    "Yes, well, I'm sure ${they}'ll manage alone," she says, giving you a side-eye. "But Calinger is such a big place. You should try a day at the theatre, or maybe a walk down Coffee Avenue. I can take you there, you know; doesn't that sound better than a stuffy day back at that ratty old inn?"

    Leon takes a step back from her, looking mildly distressed. "No, that sounds horrible," he replies matter-of-factly. He did, in fact, generally find those types of diversions painfully boring. You know his rejection is genuine and bears no malice—and yet, no one in their right minds would take it as anything but blatant insult.

    The woman predictably splutters at the response, her face turning a shade that threatens to match her hair. "I-I see," she stutters, before whirling around on her giggling cadre of followers. It only takes a single furious gaze on her part to chasten them into silence. "Then, Master Leon," she says, having regathered her composure. She bows ever so slightly, excusing herself. "Perhaps another time."

    And with a flutter of her gaudy black dress, she is gone.
    *page_break
    "What an odd woman," Leon declares, scratching his head. "She has all those ladies with her, but she's still in need of company? From a stranger, no less..."

    He regards you with a questioning stare, as if hoping for an explanation. For your part, you find the whole spectacle to be...
    *choice
      #...deeply amusing. Really, this is the best laugh you've had in a week.
        *set charming %+ 15
        *set precharming %+ 15
        "By Jove, but you are painfully dense," you say, dutifully holding down your laughter.
        *goto dense
      #...quite a relief. You don't want any competition for Leon's attention.
        *set noble %- 15
        *set prenoble %- 15
        "By Jove, but you are painfully dense," you say, carefully concealing the smug sense of satisfaction budding in your chest.
        *goto dense
      #...exasperating. You'll definitely need to help him with his social skills in the future.
        *set noble %+ 15
        *set prenoble %+ 15
        "By Jove, but you are painfully dense," you say, willing away the tremendous secondhand embarassment you sustain from the exchange.
        *goto dense
      #...relatable. You imagine you'd stumble into the same confusions he did, were the roles swapped.
        *set charming %- 15
        *set precharming %- 15
        "By Jove, but you are painfully dense," you say, not unkindly. You must say, it is quite refreshing to finally not be the most obtuse in the room.
        *goto dense
    *label dense

    The swordsman frowns at you. "What do you mean?"
    *choice
      #Really, there's no point with this guy. Just drop the issue.
        *set optimistic %- 15
        *set preoptimistic %- 15
        "Oh, never mind. Let's just get you back to the inn,"
        *goto muse
      #His cluelessness is worrisome. Attempt to explain the situation.
        *set noble %+ 15
        *set prenoble %+ 15
        "She was coming on to you," you inform him, observing his expression as it turns into one of genuine surprise. "And very...aggressively at that. Are you saying you really didn't know?"

        "Of course not! ${fname}, I've never even met her before!"

        "You've sorely underestimated Calingrian maidens, if you think that much will stop them,"
        *label muse
        you muse, walking briskly ahead.
        *label trails

        Leon trails behind you, the expression on his face showing no small amount of confusion. He sagely decides not to press any further.
        *page_break
        You part ways with Leon at the front of the inn, the blond merrily waving goodbye as he takes his purchases inside. You shudder at the thought of the meal awaiting you tonight, but solemnly decide you'll cross that bridge when you get to it.
        *goto countup
      #I refuse to elaborate. Watching him fumble with social cues is far too entertaining.
        *set charming %+ 15
        *set precharming %+ 15
        "Sounds to me like you need to have a long hard think about what just happened," you deflect.
        
        "${fname}, come on," Leon says, grabbing at the hem of your sleeve. "Please?"
        
        "Let's get you back to the inn," you muse, shaking him off and walking briskly ahead.
        *goto trails
  *selectable_if (freesaine = 0) #See what Saine is up to.
    *set freesaine 1
    You find Saine several paces from the inn, a young, scrawny boy at his side. "${fname}," the rogue says, surprised. "What are you doing here?"

    "I'm all done on my end, so I thought I'd see if you needed any help. Who's this little guy?"

    *temp title ""
    *if (gender = "male")
      *set title "Mister"
      *goto peekout
    *elseif (gender = "female")
      *set title "Miss"
      *goto peekout
    *else
      *set title "none"
      *goto peekout
    *label peekout
    The boy peeks out from behind Saine's cloak, small hands gripping the hem of his tunic. He looks at you meekly, seemingly able to recognize you as one of his rescuers. "Alfon," he says, before pointing a small, chubby finger at you. 
    *if (title = "none")
      "Mister...Miss...?"

      "You can just call them ${fname}, little guy," Saine advises, features soft.

      "${fname}," he tries, then looks up at you with a hesitant grin.
      *goto hesgrin
    *else
      "${title} ${fname}," he recites, looking up at you with a hesitant grin.
      *goto hesgrin
    *label hesgrin
    *choice
      #"Hey there, little guy. Doing alright today?"
        *set charming %+ 15
        *set precharming %+ 15
        He gives you a small, determined nod. Given what he's gone through, you think it remarkably strong of him.
      #Just nod curtly. Saine's the better people-pleaser, anyway.
        *set charming %- 15
        *set precharming %- 15
        He cocks his head sideways, as if curious about your reaction. Saine distracts him with a pat on the head, and he giggles happily, seeming to forget you altogether.

    "Thanks for coming by, ${fname}," Saine says. "There's not really much to help out with, though...I'm just waiting with little Alfon here. His sister should arrive soon to take him home."

    "Home," Alfon repeats, no small amount of wonder in his voice.

    "I'll stick around anyway, Saine. I don't really have anything better to do."

    The rogue beams at you. "Sure, I could use the company."
    *page_break
    It is some fifteen minutes of small talk before Alfon's sister turns up as promised. She bounds up the main street almost like a madwoman, black hair trailing in the wind behind her as tears stream down her face.

    "Alfon! Alfon!"

    The boy immediately leaps from behind Saine's cloak, his own face contorted with tears of relief and disbelief. "Jania!" He's yelling as he meets her halfway, and the pair collapse into each other in a sobbing mess.
    
    Saine is glassy-eyed beside you, clearly happy for the siblings and their reunion. For your part, the scene seizes your chest with an acute sense of...
    *choice
      #...bliss. I'm happy we were able to make this happen.
        *set noble %+ 15
        *set prenoble %+ 15
        It's incredibly, impossibly gratifying to see that what you're doing has a positive impact on people's lives. You hope you'll get more opportunities like this in the future.
        *goto janiasis
      #...relief. The mission is over, finally.
        *set emotional %- 15
        *set preemotional %- 15
        This mission really was a lot more than you'd initially bargained for. You're just glad it's finally coming to a close.
        *goto janiasis
      *if (kidsafe = "all") #...satisfaction. This really was a job well done.
        *set emotional %- 15
        *set preemotional %- 15
        The mission was a lot more than you'd initially bargained for, and your performance was nothing if not exemplary. You give yourself a mental pat in the back.
      *if (kidsafe != "all") #...satisfaction. This was a job well done, all things considered.
        *set emotional %- 15
        *set preemotional %- 15
        The mission was a lot more than you'd initially bargained for, and given circumstances it's admirable that you performed as well as you did. You give yourself a mental pat in the back.
      *selectable_if (kidsafe != "all") #...guilt. More children should've been able to share their happy fate.
        *set noble %+ 15
        *set prenoble %+ 15
        *set emotional %+ 15
        *set preemotional %+ 15
        There are sisters out there who will never see their siblings come home, mothers who will forever wonder what had happened to her baby. And like it or not, you played a part in their suffering.
        *goto janiasis
    *label janiasis

    Jania, the sister, bows and profusely thanks you both for the rescue, solemnly regretting that she has naught to offer but her gratitude. Saine assures her that both of you are just doing your jobs, and are well-compensated by the guild besides.

    As the pair say their farewells, ready to make the long trek back to their village, Saine silently slips a coin pouch into Jania's pocket. You say nothing of it.
    
    "I'm almost envious of them," Saine says after the pair has left, quiet enough that he probably didn't mean for you to hear.

    "You are?"

    The rogue startles at your response. "Oh, sorry. It's a weird thing to say, huh?" He smiles sheepishly, looking again towards the siblings' retreating backs. "It's just...that kind of simple life, where family relationships are so...uncomplicated. I envy that."
    *choice
      #"I can see what you mean."
        *set rsaine %+ 15
        The chestnut-haired boy looks up at you, something akin to wonder in his eyes. "Do you really?"

        "Sure," you reply. "Before I joined up with you guys, I lived in a small town called Leaf End. I
        *if (gender = "male")
            was just an errand boy
            *goto herchild
        *elseif (gender = "female")
            was just an errand girl 
            *goto herchild
        *else
            ran errands 
            *goto herchild
        *label herchild
        for the local innkeep, and we always had our share of money problems…but she considered me a 
        *if (gender = "male")
            son, 
            *goto misspeace
        *elseif (gender = "female")
            daughter, 
            *goto misspeace
        *else
            one of her own, 
            *goto misspeace
        *label misspeace
        and I do miss those peaceful days often."

        Saine nods enthusiastically, as if this is the first time he's found someone that [i]gets it[/i]. "Right? The things I'd do for that kind of life..."

        You ponder his statement. "If that's the case, you seem poorly suited for adventuring."

        Saine laughs openly at that. "Don't I? Believe it or not, this is much closer to an uneventful life than what I have to deal with back home."
        *choice
          #Press him on the issue—they've been too tight-lipped to not inspire curiosity.
              "Saine, what do you—"
              
              The rogue takes a tentative step backwards at your inquiry, a mild sort of panic percolating in his eyes. He turns his gaze sharply towards the wide street.
          #Press him on the issue. Shouldn't we be able to trust each other by now?
              "Saine, what do you—"
              
              The rogue takes a tentative step backwards at your inquiry, a mild sort of panic percolating in his eyes. He turns his gaze sharply towards the wide street.
          #I have my share of secrets; I'll let him keep his.
              *achieve sainedoyou
              Unable to hear your inner monologue, Saine all the same takes a step back. There's a mild panic in his eyes: the boy is clearly wary of being interrogated on the subject.
              
        "Oh, look at that," he says, pointing to a weapons store by the main street. "I could do with a new dagger, so looks like this is where our paths split. I'll see you later, ${fname}!"

        He blinks away before you can see anything else, materializing right outside his destination. He waves at you in the distance, black cloak swaying to-and-fro, before disappearing behind the shop's tall wooden door.
        *goto countup
      #"Is there something up with you and Leon?"
        "Oh, no. We're really close, but..." he trails off, looking wistfully into the distance. "I wish it was like that with the rest of my family, too."
        *choice
          #"Well, screw them then."
            *set rsaine %+ 10
            *achieve foundfam
            Saine splutters at your statement. "Sorry?"

            "I'm saying they don't have to matter to you, if they made you feel like that," you say, determined. "We can stand in for them, Ilya and I. Your first family you're born into, but your real family you pick. And you've done a hell of a good job picking, haven't you?"

            The younger boy tentatively smiles at that. "You're right, ${fname}. I've got what I need right here."
            *page_break
          #"Do you want to talk about it?"
            *set rsaine %+ 10
            He smiles at you, hesitant. "I really want to, ${fname}. I bet you give good advice," he says, before sighing. "But I probably shouldn't."

            You nod in understanding. "Okay, if that's what you want. But I'm right here if you change your mind, okay?"

            "Thanks, ${fname}. I'll keep that in mind."
            *page_break
          #"I'm sure they love you, in their own way."
            *set rsaine %+ 5
            He smiles at you, hesitant. "I really wish you're right, ${fname}. But I'm not too optimistic about that."
            
            You nod in understanding. "I suppose you'd know better than me, but it pays to give people the benefit of the doubt."
            
            Saine looks to be deep in contemplation, and then flashes you a weak smile. "I'll give it some thought, ${fname}. Thanks for hearing me out."
            *page_break
        
        "Oh, look at that," he says, pointing to a weapons store by the main street. "I could do with a new dagger, so looks like this is where our paths split. I'll see you later, ${fname}!"

        He blinks away before you can see anything else, materializing right outside his destination. He waves at you in the distance, black cloak swaying to-and-fro, before disappearing behind the shop's tall wooden door.
      #"You're being ungrateful."
        *set rsaine %- 10
        "Ha...I should've known this was coming," Saine says, palpably disappointed. "Spare me the lecture, please. Yeah, I did notice the scars on Jania's arms, and I know Alfon's emaciation wasn't just from the kidnapping. I know they're unfortunate in that way...I'm telling you I envy them anyway."

        "Why?"

        "Because they treat each other with unconditional love. Because they're happy with just being able to put food on the table. Because they don't look at each other like—like some kind of tool." The rogue is almost vibrating with tension—clearly this is a sore topic for him. "Because they know what it really means to be a family."
        *choice
          #"I see. I apologize, Saine."
            "Well, so long as you understand," he sighs, arms crossed at his chest. He spies the weapons store at the edge of his vision, and prepares to blink away. "I need to buy a new knife, so I'll see you later, ${fname}." In a second, he is gone, and you're left feeling a little cold in his wake.
            *goto countup
          #"I'm sorry, but you just don't get it."
            *set rsaine %- 10
            "Then let's agree to disagree," he sighs sullenly, arms crossed in front of his chest. He spies the weapons store at the edge of his vision, and prepares to blink away. "I'll pretend this conversation never happened," he says as he leaves, though there's something dark in his eyes that promises otherwise.
            *goto countup
          #'Let's just drop the subject, shall we?"
            *set rsaine %- 5
            The rogue is silent at your words, for a long while, before eventually scoffing at the ground. "Sure," he says curtly, jaw tense. "Let's leave it at that."
            
            Saine casts his gaze away, then, intensely scrutinizing the horizon as if in search for an escape route. His gaze eventually lands upon the weapons store at the far end of the street, and at once he prepares to blink away.
            
            "Let's pretend this conversation never happened," he says flatly. "I need to buy a new knife, so I'll se you later, ${fname}."
            
            And in a second, he is gone, and you're left feeling a little cold in his wake.
            *goto countup
  *selectable_if (freeilya = 0) #Spend some time with Ilya.
    *set freeilya 1
    *set witchnight true
    *temp witchachieve false
    You go back to the inn to look for Ilya, only to find that she has transformed your shared lodging into a full-blown alchemy lab.

    "${fname}, you're back," she says, not looking up from the thick almanac she's got opened on her lap. The room is littered with sheafs of paper and ingredients you struggle to identify, and a faint, but unpleasant aroma pervades throughout. In the center of the bedroom lies a large iron cauldron, the inside already burning with alchemic fire. "Perfect timing. How good are you at alchemy?"
    *choice
      *selectable_if (spell3 = "alchemy") #"Pretty good. I saved your life with it, after all."
        *set rilya %+ 15
        *set witchachieve true
        "Right, of course. Thanks for that, by the way."
        *goto sheepishly
      *selectable_if (specialty = "Alchemy") #"Come on, you know it's my specialty."
        *set rilya %+ 15
        *set witchachieve true
        "Right, of course. Sorry, the mission's been running me ragged these past few days, as you know."
        *label sheepishly
        She grins sheepishly, jotting down notes in her textbook. "Do you have any experience with witchnight?"

        You feel your eyebrows raise at the question. Witchnight is notoriously difficult to synthesize, with a process that requires high skill and costly ingredients. Though it makes for a prized clothing dye in noble circles, most alchemists know to steer clear of it. "I can't say I do," you admit.

        Ilya sighs as she looks at the cauldron. "I figured as much. I've been trying to make some, but it hasn't been going well. And I don't even know where it went wrong."

        "Can you walk me through what you've been doing? Maybe I know enough to troubleshoot."

        Ilya beams at you, immediately flipping her textbook to a relevant page. "Please. You'd be a real lifesaver."

        You take a look at the recipe, applying what alchemic theory you can to make the necessary modifications.
        *page_break
        "I think if we use less black hazel and use a three-layer spell circle..."

        "No, of course. Really, I should've thought of that..."

        "And does it have to be that thick? I think adding more water would let the spell hold together better..."

        "You're annoyingly good at this, you know..."
        *goto explodecauld
      *selectable_if (alchemy > 58) #"It's not my best skill, but I'm pretty decent."
        *set rilya %+ 10
        "Great, that's great," Ilya says, jotting down notes in her textbook. "I just need a second brain to toss ideas around with."

        "Ideas about what, exactly?"

        *goto sheepishly
      #"I'm not very good at it."
        *if (alchemy > 50)
          "There's no need to be humble," she says, tone tinged with confusion. "From what I've gathered, you're at least decent."

          "Sure, I do know the basics," you concede. "But anything I can do, you can do better."

          Ilya sighs as she looks at the cauldron. "I guess so. I'm in a bind, then."

          "With what, exactly?"

          *goto trysynth
          *label notgoodbutgood
          "I don't know if I'll be of any help, but I do have some basics in alchemy. Maybe with two brains on the case we could make something happen?"

          Ilya startles at the offer, but is quick to agree. "Sure, of course. I could really use a second opinion on a lot of these. I appreciate it, ${fname}.
          *page_break
          You spend a good chunk of time going over Ilya's process, scraping together what little alchemic theorems you could still gather from your studies.

          "This is just a wild guess, but...what if we used a little less black hazel?"

          "But then the viscosity won't hold...maybe if we substitute it with beanmund?"

          "That'll mess with the third spell circle, won't it? But it's worth a try..."
          *goto explodecauld
        *else
          She nods at that, a little dejected. "I was afraid that might be the case. I figured ${specialty} was more your speed."

          "That's right," you confirm. "So what did you need me for, anyway?"

          Ilya sighs as she looks at the cauldron.
          *label trysynth
          "I've been trying to synthesize some witchnight." You feel your eyebrows raise at that—witchnight is notoriously difficult to synthesize, with a process that requires high skill and costly ingredients. Though it makes for a prized clothing dye in noble circles, most alchemists know to steer clear of it. "It hasn't been going all that well, and I don't know where I went wrong."

          *if (alchemy > 50)
            *goto notgoodbutgood
          *else
            "I don't know if I'll be of any help...I'm hopeless with alchemic theory. But if it's simple casting, I could probably help?"

            Ilya startles at the offer, but is quick to agree. "Sure, of course. It'll help me focus on the formula, if nothing else. I appreciate it, ${fname}."
            *page_break
            You spend a good chunk of time going over Ilya's process, listening intently to her instructions as she pores over the alchemy tomes once more.

            "Say ${fname}, could you extract a bit of the black hazel? I think that's what's screwing up the coagulation..."

            "Sure, I've found the particles. Do you want me to do a warp extract or a gradual one?"

            "Actually, maybe not? I think the viscosity won't hold..."

            "Um, my hold is slipping here. I need a decision, Ilya."

            "Oh, of course! We should substitute bearmund! Wait no, but what about the third spell circle...?"

            "Oi, Ilya!"
            *goto explodecauld
    *label explodecauld

    It doesn't take very long before you lose track of time, both of you completely engrossed in the project.
    *page_break
    *set witchnightspell true
    *set acounter +1
    *achieve witchnight
    The concoction explodes with a loud bang, and the force sends you and Ilya reeling to opposite sides of the room. [i]Glad we put up a soundproofing enchantment[/i], you think to yourself, propping yourself back up with a chair as support.

    "Have we done it?" Ilya asks, quietly dusting herself as she gets back up. She's positively shaking, you note—though whether that's from nerves or the poor landing she stuck, you can't say for sure. "That...that was a good explosion, right?"

    The smoke begins to clear around the cauldron, and when you peer back in, the liquid has turned a deep, glittering purple. Witchnight, if you've ever seen it.

    "It came out well," you say, relieved.

    "You can say that again," Ilya says, dipping a finger into the liquid. The viscous dye glimmers like the night sky on her fingertip. "It's so beautiful. ${fname}, I could kiss you."
    *choice
      *selectable_if (rilya > 35) #"Well, if you insist..."
        Ilya immediately turns an alarming shade of red. "${fname}! Th-that was just a figure of speech..."
        *choice
          #"Yeah? My offer stands anyway. And it is [i]very[/i] literal."
            *set rilya %+ 20
            "W-well," she responds, clearly flustered. "I'd be lying if I said I've never...imagined it..."

            "And just what was it you were imagining, huh?"

            The healer whirls around immediately to hide her blush, but even her ears have grown an angry shade of red. "You're absolutely insufferable. You're lucky you've got a cute face."
            *choice
              #"Cute enough to date?" I want to pursue something serious with her.
                Ilya carefully averts her gaze, a deep frown settling over her lips. It looks remarkably like you've been rejected.

                "Oh," you say dejectedly.

                Ilya looks back up at you, startled. "What? No, don't get the wrong idea," she says hurriedly. "It's not that I'm not interested. You're, um, cute enough to date, definitely."

                You ignore the little somersault your heart does at that, carefully anticipating her next words. "But?"

                "Well, I've got a...complicated background," she sighs. "One that makes it difficult to pursue things like a relationship."

                "Are you letting me down easy?"

                "No, of course not. I have no problem refusing something I don't want, you know that," she says, fiddling with a strand of her long white hair. "I just need some time to, um, sort things out on my end." She looks up at you sheepishly. "Wait for me?"
                *goto waitforme
              #"Cute enough to kiss?" I'm just looking for some fun.
                *set ilyafwb true
                Ilya catches on to the implication immediately, looking stricken as if she has just now considered something like this for herself. "Mm. Maybe."

                You place a hand over your heart in mock hurt, and that earns you a laugh out of her.

                "Alright, yes, cute enough to kiss," she allows. "But this kind of arrangement...is foreign to me. The whole no strings attached thing, I mean. I'm just not sure I'm built for it."

                A common response among the Parami, you think to yourself. "Yeah, I get it. It's not for everyone."

                "I'm still interested, you know. I just need some time...just to make sure I don't complicate things somewhere down the line." She takes your hand in hers, offering you a small smile. The witchnight on her finger is cool against your skin. "Wait for me?"
                *label waitforme
                *choice
                  #"Of course. As long as you need."
                    *set ilyarom true
                    "Thank you." She smiles, looking directly in your eyes, and for a time it's like the whole world has ground to a halt around you.

                    It takes far too long for you to realize that the cauldron of witchnight has begun to sizzle, producing a deeply unpleasant stench that begins to waft around the room.
                    *label ohyulio

                    "Oh Jove! We forgot to add the preservatives!"

                    The two of you immediately leap to action, fumbling through Ilya's bag for preservatives and chemical correctors.

                    Half an hour passes before you manage to salvage what you can of the spoiled dye. Neither of you could particularly focus on the task at hand, but you still end up with more than half the witchnight you started with. You chalk it up as a job well done.
                    *goto countup
                 #"Maybe it's better if we don't pursue this, then."
                   Ilya looks dejected at your answer, but soon schools her expression into an agreeable smile. It doesn't reach her eyes. "I understand. It wasn't meant to be, then," she says.

                   An awkward silence descends upon the room. It's mercifully short-lived, however, as the cauldron of witchnight begins to suddenly sizzle and produce a deeply unpleasant stench.
                   *goto ohyulio
          #"Oh, I guess I read the mood wrong."
            *set rilya %+ 10
            *temp yesfriends "Yes. Friends,"
            *temp yesfriends2 "she says, a pitch higher than normal."
            *temp yesfriends3 "Then don't"
            "I mean, well..." She holds your gaze for a while, and it's readily apparent that something is on the tip of her tongue. She seems to think better of it, in the end, and opts to drop the issue. 
            *label anyway 
            "A-Anyway! Thank you for all your help, ${fname}. I'll be sure to return the favor one of these days."
            *choice
              #"I'll hold you to that," you say, and mean it.
                *set noble %- 15
                *set prenoble %- 15
                *set rilya %+ 5
                She grins wide at your answer. "You're a breath of fresh air, really, after having been stuck with Leon for..."
                *goto midsentence
              #"Don't mention it. We're friends, aren't we?"
                *set noble %+ 15
                *set prenoble %+ 15
                "Yes. Friends," she says, a pitch higher than normal. "Then don't hesitate to ask me if you..."
                *label midsentence
                She stops mid-sentence, suddenly sniffing the air with a confused expression.

                It's a second, but you smell it as well—a deeply unpleasant stench, seemingly coming from...the cauldron of witchnight?

                "For Jove's sake! We forgot to add the preservatives!"

                The two of you immediately leap to action, fumbling through Ilya's bag for preservatives and chemical correctors.

                Half an hour passes before you manage to salvage what you can of the spoiled dye. Ilya seems to be distracted throughout, but with your stable hand you still end up with more than half the witchnight you started with. You chalk it up as a job well done.
                *goto countup2
          #"I'm joking, of course."
            *set charming %+ 15
            *set precharming %+ 15
            "Of course." The healer gives you a smile, but you can't help but notice the odd glint in her eyes. 
            *goto anyway
      #"I'm just glad it worked out."
        *set rilya %+ 15
        *temp distraction "With your combined efforts, you end up with"
        *temp yesfriends "We are, of course, but I insist,"
        *temp yesfriends2 "she says."
        *temp yesfriends3 "Don't"
        Ilya grins wide at your answer. "We are, of course, but I insist," she says. "Don't hesitate to ask me if you..." She stops mid-sentence, suddenly sniffing the air with a confused expression.

        It's a second, but you smell it as well—a deeply unpleasant stench, seemingly coming from...the cauldron of witchnight?

        "For Jove's sake! We forgot to add the preservatives!"

        The two of you immediately leap to action, fumbling through Ilya's bag for preservatives and chemical correctors.

        Half an hour passes before you manage to salvage what you can of the spoiled dye. With your combined efforts, you end up with more than half the witchnight you started with. You chalk it up as a job well done.
        *goto countup2
  *selectable_if (freecharisma = 0) #Watch a play at the local theatre.
    *set freecharisma 1
    *set charisma %+ 15
    The Karosa Theatre is something of a local legend, having survived three fires and a citywide raze, standing ever sturdy with its marble columns and jade-green dome. It is perhaps the most beloved building in all of Calinger, and its fame—and notoriety—had attracted much of Param's artistic types to perform or spectate under its auspices.

    The usher is a clean-looking boy with neatly pressed clothes and wire-rimmed glasses, all smiles as he shows you to your cheap seat. Today's screening is a particularly short drama, with a runtime of just over one hour.
    
    The lights dim, shining a spotlight on the grand wooden stage.
    *page_break
    *if (profession = "charisma")
      *set acting true
      *set charisma %+ 10
      Two familiar figures appear from behind the curtains, steps light as they glide across the stage. You'd recognize the husky voice and trademark pirouette anywhere. These are Rean and Sofiya's first leading roles in the famed theatre, and you've come to support them on their opening day. There's a rugged rawness to their performances, in stark contrast to their polished castmates—you find that it makes their characters all the more compelling. You are enchanted anew by the pair's sheer [i]je ne sais quoi[/i], swearing to yourself that you'll one day match their charisma.

      "${fname}!" you heard a voice yell out, just as you're about to leave with the rest of the audience. Rean motions for you to come backstage—a request you are happy to oblige.
      *page_break
      Sofiya and Rean bring you into a tight hug as soon as you step backstage. "Congratulations on the show," you say, struggling to breathe in their vicegrips. "I'm a little starstruck, you know."

      "You stop that," Sofiya says as she pulls away. "You're the biggest star around here, you know. I can't believe I used to dance in a tavern with a [i]White Fang[/i]."
      *choice
        #"What, you want an autograph or something?"
          "To sell, perhaps," Sofiya replies, sounding as if she's putting serious thought in the proposition. "I know no shortage of starstruck youths who look to be at the edge of groveling whenever the White Fangs pass by. I will supply the pen and parchment, and we can split the proceeds—"
          
          "Jeez, Sofiya," Rean sighs. "I appreciate that your enterprising got us through our rough patches as a wandering duo, but look around, will you? We're respectable adults, holding down respectable jobs at the [i]Karosa Theatre[/i]! We don't have to exploit our friends to get by anymore, alright?"
          
          Sofiya scrunches her nose and rounds on her companion. "Return the fifty silver you borrowed from me."
          
          Rean sheepishly averts his gaze. "Calinger is a scary place," he says, apropos of nothing. "Scarier still…is its gambling dens."
          *goto barbs
        #"We sure have come a long way, huh."
          "I'll say," Rean grunts, leaning against the wall. "To think you actually became a proper mage! I'm rather partial to your performing outfit, myself," he winks, a familiar roguish smile on his lips. "But you do fill out those robes very nicely."

          Behind him, Sofiya rolls her eyes. "Save it for the barmaids, you tool. This is the first time we've seen ${them} in years—and ${theyre} way out of your league, anyhow."

          Rean glares at his companion in mock disgust. "You're just bitter that I've got a higher body count."

          "Hey!"
          *goto barbs
        #"I really miss those days."
          "I bet," Rean says, leaning against the wall. "Heck, I was only there for a bit and I still miss the hell out of Old Bess. She really ruined pork stews for me."

          Sofiya clicks her tongue, appearing to take offense. "Well [i]I'm sorry[/i] I can't match the skill of Param's best innkeep. But you seem to keep my stew down fine!"
     
          Rean concedes the point, nodding sagely. "We do what we must to survive."

          "Hey!"
          *goto barbs
          *label barbs
          *page_break
          Sofiya's hand goes faster than you can see, slapping Rean hard upside the head, and the reunion quickly devolves into an all-too-familiar ruckus. A pang of painful nostalgia nestles itself in your chest as the sight reminds you vividly of your days in Leaf End.

          You part ways with the pair some time later, walking out of the theatre feeling recharged.
          *goto countup
    *else
      Performers filter out one by one from behind the curtains, expertly weaving a beautiful tale before your eyes. As always, the actors' performances are top-of-the-line. You're enraptured by their open demeanor and sheer je ne sais quoi, swearing to yourself that you'll be able to match their charisma one day.

      You leave the premises amidst a crowd of excited theatre-goers, all still murmuring about the drama's stunning lead performances. You nod to yourself in agreement with them as you walk past the theatre's ebony doors, feeling recharged.
      *if (profession = "charisma")
          *achieve charismacali
      *goto countup
  *selectable_if (freelearning = 0) #Visit the house of a local historian.
    *set freelearning 1
    *set learning %+ 15
    Sir Owain lives in a run-down little brown house built far away from the city center, its lawn a tangled mess of overgrowth and what remained of his dying passion for gardening. His neighbors swear that the garden was a marvel in its heyday, playing host to foreign spices and flowers that shouldn't be able to grow in the Parami clime. But the historian permanently retreated into his cottage when his wife passed of the devil's fever some three years ago, and so it was that Sir Owain's garden slowly began to share her fate.
    
    You duck under the boughs of an apple tree and slot the key into his door. "Sir Owain, I'm coming in."
    
    The man in question peeks his head out from behind a tower of precariously stacked books. He was never a tall man to begin with, but as his back sags under the weight of time he's begun to look rather reminiscent of a dwarf.
    
    "Thank you, 
    *if (gender = "male")
        boy," 
        *goto hesaysas
    *elseif (gender = "female")
        lass," 
        *goto hesaysas
    *else
        young'un," 
        *goto hesaysas
    *label hesaysas
    he says as you set down the supplies by the kitchen door. A week's worth of food, though you're convinced the hermit will stretch it out a fair bit.
    
    "There's no need for thanks when you're paying me so well," you say matter-of-factly, dusting yourself off. The air smells markedly of mildew and moss—you should probably clean for him when you can spare the time. "Speaking of which…"
    
    "Aye, I've managed to find it." Sir Owain plops down from his high chair and shuffles about the room, unearthing a solid black tome with green-gold bindings. Upon the cover is inscribed its title…
    *choice
        #"Ystalvius". An exhaustive chronicle of the first Grand Duke of Salantira's life.
           By all accounts one of the most capable statesmen to have ever graced Arvanand, the Grand Duke Ystalvius I remains a paragon in both administration and diplomacy. There is much to be learned from his legacy, for the discerning historian.
           *goto afterbookz
        #"Gloria de Jove". An exploration of the conception of Jovism and its relationship with Arvanand.
           Though the account often descends into diversions just a hair's breadth from blasphemy, the author's skillful maneuvers around the topic makes it unimpeachable by even the most ardent of Jovian believers. The nuanced approach allows them to give frank observations on the nature and conduct of the Church—a written miracle by any historian's standards.
           *goto afterbookz
       *selectable_if (profession = "learning") #"The Roads to Thulrum". A biting critique of the Parami conquest of Arcadia.
           *set learning %+ 10
           Like all books that portray the black sheep of history in a favorable light, the tome had been burned en masse by the Parami kings of old. The copies that escaped their thorough notice are few and far between, yet there it rests in your hand. It feels almost sacrilegious to hold such an unfathomable treasure.
           *goto afterbookz
        
    *label afterbookz
    
    "The way you're lookin' at that book, you might be fixin' to marry it," Sir Owain guffaws as he climbs back upon his chair. "Why don't you take that one? I've got it memorized from cover to cover, so I don't mind parting with it."
    
    Given the value of the tome, the offer is almost unfathomable. "Sir, are you sure?"
    
    "Yes, yes," he says, waving his hand dismissively. "You've been a great help to me. Take it now before I change my mind."
    
    You thank the old man and promise to drop by again before the week is out. Walking outside and clutching your newest acquisition close to your chest, you feel distinctly victorious.
    *if (profession = "learning")
        *achieve learningcali
    *goto countup
  *selectable_if (freeintrigue = 0) #Pay a visit to the local information dealer.
    *set freeintrigue 1
    *set intrigue %+ 15
    The small townhouse looked to be in a rather advanced stage of disrepair, with dilapidated roofing and a tangling of vines creeping up the masonry. Cal, the groundskeeper, seems to be an unassuming young man with a smattering of freckles and a wide, easy smile. He greets you warmly at the gate before resuming his work, trimming the topiary with masterful knife strokes no mere gardener should be capable of.

    You pass through the house's familiar hallways, all nondescript stone walls and sturdy mahogany doors, before arriving at the second-floor study. Against the wall-to-ceiling window—one-way glass, no doubt—stood a sturdy, greying man with a pipe in his hands and dossiers stacked precariously on his desk. "Master ${fname}," Hiovar greets. "We've been expecting you."

    "I'm sure you have," you reply drily, taking a seat opposite of the man.
    *page_break
    Larger guilds often have sufficient economies of scale to justify funding their own information division—netters, as they are usually called—typically linked to an extensive, nationwide network of outsourced 'talent'. For smaller operations like the White Fangs, however, contact with a specialized dealer can prove to be a reliable substitute—and it just so happens that Hiovar is one of the best.

    Still, due to the nature of his work, Hiovar is a rather elusive figure with a very exclusive clientele. Under what circumstances did you come into contact with him?
    *choice
      #I sought him out the moment I stepped foot in Calinger.
        *set noble %- 15
        *set prenoble %- 15
        To begin with, it was a horrible oversight for the White Fangs to operate without a good netter. Knowing how the chips fall prior to a mission can often be the difference between life and death, and this would have been the case with the Elyssian beast had you not stepped in. You suppose their high rate of success has made the White Fangs rather naive and complacent. Regardless, it was a mistake you quickly rectified.

        Securing a deal with Hiovar took a couple of traumatizing excursions into the shadier parts of town, but you couldn't have been happier with the result. There is nothing under the Parami sun that the balding gentleman doesn't have dirt on, and thus far each and every one of his 'goods' has been right on the money.
        *goto favorite
     #He was the one to seek me out, actually.
        Before you came along, he had sought out the rest of the White Fangs on multiple occasions—odd for an operation of his tier, though you suppose a connection to Calinger's top mercenaries [i]would[/i] be benefit his operation in turn. Unfortunately, the White Fangs had refused every time: they had never seen the need for a netter, seeing as they had never failed a mission without. Obviously, the Elyssian beast made for a rude awakening.

        Hiovar had deigned to make a visit to you himself, not one day after you had made it back to Calinger. He had dropped by with a complimentary bottle of Elyssian antidote—famously difficult to procure, but more to the point [i]he shouldn't have known, not when Ilya's symptoms largely matched that of the common cold[/i]—and offered the White Fangs a second shot at a partnership. You initially tried haggling him down on the terms of the deal, but when he managed to trace your origins all the way back to the Bellgrove Inn, you knew he was worth the asking price and then some.
        *goto favorite
     *selectable_if (profession = "intrigue") #He's an old...acquaintance, from my days of serving under Deacon Thomas.
        *set intrigue %+ 10
        Hiovar's name all too often came up in conversation with the Deacon, and when he spoke of Hiovar his tone would be colored with equal parts respect and contempt. From what you gathered, the balding gentleman is the Deacon's only real competition in the whole of Param. As a matter of fact, you've had several altercations with the man's agents back in the East, but in your new relationship he's given you nothing but businesslike smiles and reliable leads.
        *goto favorite
    *label favorite
    "How have you been, Master?" he drawls, dagger-like smile too big for his face. "I take it my last...[i]tip[/i] was satisfactory?"

    You nod, dropping a pouch of silver onto the man's desk. "Your agents are getting better these days."

    "I'm glad to hear it." The man's smile is a thin-lipped slit as he takes his cut of the mission's proceeds. "We will endeavor to provide even better services in the future."

    He rises, then, approaching the mahogany shelves that line both sides of his wall, fingers trailing against bindings before pulling out two thick manila dossiers. He returns to his desk and lays them out in a row, grey eyes glinting as he regards you once more.

    "New items of interest, Master. My usual rates apply."

    You can't help but smile as you scan the titles of these dossiers—one of the nation's top fugitives, a rare beast that hasn't been sighted in ten years, a local noble making waves in His Majesty's court. Many would kill to get their hands on these files. You imagine many tried.

    You leave the establishment a little over an hour later, pockets significantly lighter and head buzzing with all the new leads you've acquired.
    *if (profession = "intrigue")
        *achieve intriguecali
    *goto countup
  #Read one of Aunt Bess' tomes.
    Though you've been diligently picking apart the collection when you could, an adventurer' fast-paced lifestyle proved a poor complement to the scholarly demands of a mage. Now that you've caught a bit of a break, you might finally be able to make some decent progress in your studies.

    Which tome will it be today?
    *choice
      *selectable_if (freealchemy = 0) #Old Saarta's Compendium of Magicked Materials, Vol. VIII
        *set freealchemy 1
        *set alchemy %+ 20
        You set the book down on the inn table and get to work. Hours later, you decide you now know more about the uses of fae-hog feces than you wanted to, and decide to call it a day for alchemy.
        *goto countup2
      *selectable_if (freethaum = 0) #The Fourth Hieron Grimoire
        *set freethaum 1
        *set thaum %+ 20
        You pull the tome out of your luggage and get to work. Hours later, your head is buzzing with the thirteen different ways a well-placed wind spell can decapitate you. Having decided that's enough thaum study for one day, you close the book with a faint sense of horror.
        *goto countup2
      *selectable_if (freeenchantment = 0) #The Fae Records
        *set freeenchantment 1
        *set enchantment %+ 20
        You set the book down on the inn table and get to work. Hours later, as your head throbs with the sheer amount of spell circles and incantations the book demands you to absorb, you decide to call it a day for enchantment.
        *goto countup2
      *selectable_if (freespiritism = 0) #Book of the Hollow
        *set freespiritism 1
        *set spiritism %+ 20
        You pull the tome out of your luggage and get to work. Hours later, after the tome has outlined in extensive detail the gruesome cost of accidentally summoning a malevolent spirit, you decide to throw the towel in for today.
        *goto countup2
  #Just go back to the inn and rest.
    *set fdcounter 5
    You had thought yourself well-rested, but the inn's comfortable down mattresses persuade you otherwise. It takes no time at all before sleep descends upon you once more.

    When you awaken hours later, the room is still empty except for yourself. You resolve to stroll around the city while waiting for the others to come back.
    *page_break Outside
    *goto fdtime
*label countup
*set fdcounter (fdcounter + 1)

You wind up back at the main street.
*page_break

*goto fdtime
*label countup2
*set fdcounter (fdcounter + 1)

You head back out to the main street.
*page_break

*goto fdtime

*label backinn
It's been said that Calingrian streets are second only to Sienan when it comes to traffic, but such wisdom does not appear to extend to its nightlife. Only a handful of people are passing through Calinger's myriad alleyways, and the streets seem much wider in absence of the pop-up stalls that hawk merchandise during daylight. There's a serene kind of quiet pervading the air that only a night-time walk would let you experience.

But as you turn the street corner, the very atmosphere seems to shift in a subtle and intangible way, and a sense of unease creeps up your spine. The street lights cast crooked shadows on your path, and the night breeze seemed to blow just a bit [i]wrong[/i] tonight.

Years of adventuring has sharpened your instincts, and you've been saved many times by heeding their wisdom. And right now, they're saying that [i]someone is following you[/i].
*temp followresp "nattack"
*choice
    #This can't mean anything good. Turn around and immediately cast an attack spell.
        *set optimistic %- 15
        *set preoptimistic %- 15
        *set noble %- 15
        *set prenoble %- 15
        *set followresp "attack"
        You quietly form magic circles on your fingertips as you continue to step forward, carefully maintaining a neutral facial expression and posture. You only have one shot at this pre-emptive attack before you'll have lost the element of surprise—not to mention the fact that your aim will suffer from the lack of a clear target. It's a long shot, all in all, but there's no time for second-guessing—
        *goto ilyafancy
    #Call them out. It might expose me to danger, but I can't immediately assume hostility.
        *set optimistic %+ 15
        *set preoptimistic %+ 15
        *set noble %+ 15
        *set prenoble %+ 15
        After all, it could just be a precocious adventurer-to-be, or an upstart mage seeking advice. Steeling your nerves, you prepare to turn around and call out into the dark.
        *goto ilyafancy
    #Their strength and numbers elude me.  I need to make a  run for it.
        *set optimistic %- 15
        *set preoptimistic %- 15
        You're not half the runner Saine is, but months of adventuring have given your legs a fair amount of workout—enough to be optimistic about your chances, at least. Steeling your nerves, you prepare to make your escape.
        *goto ilyafancy
*label ilyafancy

"${fname}, fancy meeting you here."
*page_break
Ilya smiles as she falls into step beside you, appearing to have emerged from an intersecting alleyway. She angles her face directly forward, white hair swaying as she mouths to you: [i]don't do it yet[/i]. You swallow and heed her
*if followresp = "attack"
    advice, shutting down your mana ducts and letting your spell circles dissipate into thin air.
*else
    advice, putting your foot forward and donning your best poker face.

"Heading back to the inn, Ilya?"

"Drop the small talk, they can't hear us," Ilya says, though her face maintains a friendly, easy-going facade. "No eavesdropping enchantments, I've checked. They've been following me for a while, too."

You give her a slight, imperceptible nod. "How many are there?"

"At least four on my tail—I don't know about yours. More than we can safely handle, in any case."

"This is bad," you say, and Ilya nods her agreement. "But we're in the middle of the city. Surely they won't—"
*page_break
Your instincts kick into overdrive as cloaked figures close in on you from all directions, bounding forward with a velocity that could only mean business. You realize, too late, that there's no one on the path save for a couple of haggard men, drunk out of their minds. No one to witness whatever plans your pursuers have for you.

"Over here!" Ilya yells, pulling on your arm and leading you to a well-lit alleyway. "If we can get out the other side, it'll be a straight shot to the inn—argh!"

Ilya groans in pain as three darts coated with a suspicious yellow sheen sail past her, one cutting open a small gash on her cheek. "Paralyzing darts," she huffs, squeezing at her wound to draw out the toxin. "But I've got something up my sleeve, too!"

The healer throws a handful of pellets behind her, and a noxious purple smoke blooms against the cobblestone path. An alchemic product, no doubt, though not one you've ever seen before. Regardless, judging from how the onslaught of darts have been brought to a halt, it seemed to have bought you a bit of reprieve.
*page_break
Operating purely on instinct, you grab Ilya's hand and lead her deeper into the alley. You know full well your path leads to a dead end, but any distance you create will go a long way in buying time for your more powerful spells to manifest. Against such adept assailants, overwhelming them with top-tier magic seems to be your best bet.

Looking back at the clearing smoke, you note with some relief that the sizable distance you've put between yourselves and the cloaked figures. There's time enough to cast the strongest spell in your repertoire:
*fake_choice
    *selectable_if (ult = "thaum") #Skywrath
    *selectable_if (ult = "enchantment") #Banecircle
    *selectable_if (ult = "alchemy") #Widow's Stream
    *selectable_if (ult = "spiritism") #Gatebreaker
You will the spell into existence, your mana cresting like a tidal wave and filling every inch of your body with immense magical power. As your spell circle completes its circuit, the air prickles with tension, and the very ground seemed to depress under the load of its magical energy—

And then nothing.
*page_break
"No..." Ilya slumps to the ground beside you, where a terrifying and familiar rune has bloomed in a sizable radius around you. It pulsates with an unusual, inky-black mana signature—well-cloaked in the darkness of the alleyway, but still unmistakable by any mage worth their salt. You're standing on the Glyph of Magebane.

There's no spell in your repertoire this glyph won't neutralize. You don't know how they've managed to cast such a complex spell with neither you nor Ilya noticing; regardless, your situation is unmistakable. You've been thoroughly outmaneuvered.
*page_break
"What do you want?" Ilya hisses, huffing from exertion. "We're part of the White Fangs, you know! You'll never get away with this!"

One of the cloaked figures step forward and approach you, their tense yet graceful steps reminding you of a crouching tiger circling its prey. If you are to resist—whatever it is they've got planned for you—now's the time to act.
*choice
    #I try to overpower the attacking figure. Perhaps holding them hostage will improve our chances.
        *set optimistic %+ 15
        *set preoptimistic %+ 15
        Solidifying your resolve, you bodily tackle the cloaked individual, hands grasping for purchase on their neck. Unfortunately, their reflexes outmatch yours by a wide margin, and you crash to the ground as they nimbly disentangle themselves from your makeshift assault.
    #I yell for help. Surely someone must be able to hear me?
        *set optimistic %+ 15
        *set preoptimistic %+ 15
        "Help! We're being a—" Your next words die in your throat as the figure bodily tackles you, pinning you to the ground and stuffing your mouth with a piece of black cloth.
    #I stay still. When outmatched, it's best not to aggravate your captors.
        *set optimistic %- 15
        *set preoptimistic %- 15
        Ilya does not share your resolution. She bodily tackles the cloaked individual, hands grasping for purchase on their neck. Unfortunately, their reflexes outmatch hers by a wide margin, and she crashes to the ground as the figure nimbly disentangle themselves from her makeshift assault.
    #I give up. Whatever happens next, so be it.
        *set optimistic %- 15
        *set preoptimistic %- 15
        *set emotional %- 15
        *set preemotional %- 15
        Ilya does not share your fatalistic outlook. She bodily tackles the cloaked individual, hands grasping for purchase on their neck. Unfortunately, their reflexes outmatch hers by a wide margin, and she crashes to the ground as the figure nimbly disentangle themselves from her makeshift assault.
*label ante
*page_break "That's enough!"
Like a fever dream, like a prayer answered, two familiar silhouettes leap forward from the parapet overhead, placing themselves between you and the cloaked figures. A flash of blond and brown hair, a pair of familiar stances, and the pit in your stomach all but evaporates.

"You've got a lot of guts, attacking the White Fangs like this," Leon spits. He stands vanguard with his blade already brandished, his entire posture taut and alert as a coiled spring. "I hope you're ready to face the consequences."

*page_break

"…We've finally found you," says the frontmost figure eventually, lowering her hood to reveal a spare woman with piercing eyes. "Peace. We only mean to talk."

"Then maybe diplomacy isn't your strong suit," Saine growls. His grip is white around his sheathed daggers, ready to be thrown at a moment's notice. "Drop your weapons, [i]now[/i], or we [i]will[/i] eliminate you."

The woman takes a step back, expression expertly neutral. "As you wish," she relents, motioning to her men in an unfamiliar gesture. Weapons drop to the floor in a chorus of clatters. And then, in mechanical unison, they bend their knees and place three fingers over their heart—the Parami sign of subservience and loyalty. Ilya's face blanches at the display, and in front of you Saine mutters a curse under his breath.

"My name is Ante, Vice Commander of the Royal Informants," she recites, brisk and methodical. "It has taken us a long time to find you, Your Highnesses."
*set memorypoint "complete_whitefangs"
*page_break
*goto_scene Junction