The sky is fully dark by the time you step out again, the night air a cool kiss upon your skin. You had only ever witnessed nighttime in Thulrum out the confines of your own chamber, recovering as you were from the remnants of death still weighing down upon you then. With the Seat being perched upon Thulrum's highest hill, you had a clear view of large swathes of the city; Thulrum had seemed lively and radiant then, with the bustle of activity continuing well into the night. Light would flood out from homes and taverns, and even the streets were illuminated by innumerable street lamps—a novelty among Arvanian cities.

It was almost as if Thulrum were intent on declaring itself a beacon in the looming dark, a haven which would welcome the abandoned and lost.

But tonight the cityscape lies muted and dark, made visible from this distance only by the pale moonlight. And snaking through the darkened buildings, it is as if small rivulets of light are flowing through the city streets, their flow languid and deliberate.

It takes you a moment to recognize it as Thulrum's residents, all of them carrying small lanterns in front of them, a palpable buzz of laughter and excitement hovering around them all the while. These rivulets then feed into the city's main thoroughfare, culminating in hotspots of activity which must hold the festival's main attractions. And the area you recognize as the city center, right near where the Common House is, has become a veritable nexus of light from the sheer amount of people it contains. They gather and shift in irregular motions, and from this distance the sight seems almost kaleidoscopic.

"Beautiful, isn't it?"

You find ${yusuha} walking up the path beside you, smiling as ${yhe} looks over the city. "I've been here for so many Days of Arrival now, but I never do grow tired of it."

*choice
    #"It's a very pretty sight, I'll give you that."
        "And you're viewing it from the best Seat in the house, as it were," ${yusuha} says, winking. "It's still beautiful up close, though. To be in the midst of near-total darkness, being guided only by each other's light…well. Perhaps it'd be best for you to see for yourself, hm?"
        
        ${yusuha} hands you a lantern, and you're surprised to find that it weighs practically nothing.
        
        *label standardissue
        "That's standard-issue, by the by," ${yusuha} remarks. "Everyone gets one of those on their own Days of Arrival. And ti's light enough so that you can hold it the entire night without straining your arm."
        
        You blink at that. It's clear that some kind of weight-manipulation spellwork has been engraved upon the lantern, to say nothing of the Everfire burning within its center. And yet you find no magic stones from which the lantern could draw power—meaning that both spells are likely being actively sustained by a mage as you speak.
        *choice
            #I ask ${yusuha} directly about the lantern's mechanism.
                "There are no magic stones here," you say, giving the lanterns another once-over for good measure. "How?"
                
                "I suspect you already know the answer," ${yusuha} says, smiling. "There exists a large spell circle in the heart of the Seat, tended to by the priests of the Ishavak Church, which sustains all the lanterns issued for the Day of Arrival. The mana it sups on is supplied by a single person, however—the most accomplished mage in all of Arvanand."
                
                It isn't difficult to guess the person ${yusuha} speaks of. The scale of this feat boggles the mind, but it hardly rewrites the laws of reality the way bringing you back from beyond the veil did. "Tahlia, then."
                
                ${yusuha} nods. "All of the Church gives their all for the Day of Arrival, but none moreso than the [i]ashai[/i]. This is a project many months in the making, and she's regularly fed her mana to the circle all the while. Silver lining's that the circle can sustain itself now, so she can at least enjoy the fruits of her hard work today."
                
                A flurry of figures pass by you and ${yusuha} both—young acolytes newly emerged from the Seat's doors, chattering excitedly among themselves about the festival that lies ahead. ${yusuha}'s eyes follow them as they leave, ${yhis} lips pulling into a soft smile. "Their first Day of Arrival as a resident. I can scarcely remember mine." ${yusuha} shakes ${yhis} head, then, as if to break ${yhim}self out of ${yhis} ponderous mood. "Well then, ${fname}, are you all ready to go?"
                
                You respond in the affirmative, and ${yusuha} breaks out into a grin. "Come on, then. The city awaits!"
            #I ask ${yhim} if all of the lanterns are being sustained the same way.
                "Your deduction does you credit," ${yusuha} says in response to your question. "They are all of them issued and sustained by the Ishavak Church."
                
                You shake your head in disbelief. No matter how many mages the Church has on retinue, to sustain tens of thousands of these lanterns—over long distances, no less—would be a feat that truly boggles the mind. "Not by active magic, surely?"
                
                "That depends on your definition," ${yusuha} answers. "These Everfires are sustained by an active magic circle within the Seat—a monstrous creation spanning the floor of a whole atrium, full of spellwork beyond even my comprehension. But it does so independently now. The mage responsible for the feat is likely partaking in the festival as we speak."
                
                A delayed, autonomous cast, then. Two more items added onto a list of impossibilities—in service to [i]festival lanterns[/i], no less. But if nothing else, ${yusuha}'s explanation leaves little room for doubt in your mind as to the caster's identity. For even this herculean excess would likely fall well within the capabilities of one who could rewrite the laws of mortality. "Tahlia, then."
                
                "Got it in one," ${yusuha} says. "All of the Church gives their all for the Day of Arrival, but none moreso than the [i]ashai[/i]. This is a project many months in the making, and she's regularly fed her mana to the circle all the while. It's a good thing that the circle can sustain itself—she can at least enjoy the fruits of her hard work today."
                
                A flurry of figures pass by you and ${yusuha} both—young acolytes newly emerged from the Seat's doors, chattering excitedly among themselves about the festival that lies ahead. ${yusuha}'s eyes follow them as they leave, ${yhis} lips pulling into a soft smile. "Their first Day of Arrival as a resident. I can scarcely remember mine." ${yusuha} shakes ${yhis} head, then, as if to break ${yhim}self out of ${yhis} ponderous mood. "Well then, ${fname}, are you all ready to go?"
                
                You respond in the affirmative, and ${yusuha} breaks out into a grin. "Come on, then. The city awaits!"
            #I say nothing of the matter.
                *set charming %- 15
                ${yusuha} smiles faintly, seemingly having recognized the glimmer of interest in your expression, as well as the choice you made to keep your peace. To ${yhis} credit, ${yhe} is happy to play along.
                
                "Aside from these lanterns, the entire city will be in a state of total blackout. Make sure to take care of yours—might get tricky getting around town without it," ${yusuha} says. "You can keep it after the festival, too. If you're still around this time next year, the [i]ashai's[/i] spell will power it back up again for the next Day of Arrival. Otherwise, it's not half bad to keep as a memento, eh?"
                
                "No," you say simply as you lift your lantern. The Everfire flickers within, its light illuminating the path ahead. As you do so, a flurry of figures pass by—young acolytes newly emerged from the Seat's doors, chattering excitedly among themselves about the festival that lies ahead. ${yusuha}'s eyes follow them as they leave, ${yhis} lips pulling into a soft smile. "Their first Day of Arrival as a resident. I can scarcely remember mine." ${yusuha} shakes ${yhis} head, then, as if to break ${yhim}self out of ${yhis} ponderous mood. "Well then, ${fname}, are you all ready to go?"
                
                You respond in the affirmative, and ${yusuha} breaks out into a grin. "Come on, then. The city awaits!"
    #"Is there some kind of symbolic meaning to this?"
        ${yusuha} brightens at your question. "But of course." ${yusuha} says. "Tonight the city of Thulrum is as it was during the fall of Arcadia—homes dark and deserted, with nothing to illuminate them but the moon and the stars." ${yusuha} then turns ${yhis} gaze towards the rivers below, the expression on ${yhis} face full of warmth. "But Arcadia has ever resided within her people, who bore the light of hope even as shackles were clapped onto their wrists, and their birthright was stolen from them. And though they may be forced to walk different paths, always will their roads converge in the end. To that land which holds the graves of their great grandparents, which once bore their hopes and dreams.
        
        "Ah, but look at me waxing poetic," ${yusuha} says sheepishly. The redhead hands you a lantern then, and as you take it into your hands, you're surprised to find that it weighs practically nothing.
        
        *goto standardissue
    #"I can't wait to go down there and experience it for myself."
        ${yusuha} laughs at that. "You are a delight," ${yhe} says. "I have faith that it will live up to your loftiest expectations."
        
        ${yusuha} hands you a lantern, then, and  as you take it into your hands, you're surprised to find that it weighs practically nothing.
        
        *goto standardissue

*page_break

You follow ${yusuha} down the Seat's hill, watching the glittering expanse of light before you grow and expand and twist in a million different directions as the festival comes alive. The cold bite of altitude air mellows out as the both of you crest down the hill, passing by the Seat's acolytes and priests as you do. They are all of them carrying the same lanterns as you, and the mood in the air is at once pleasant and sober. Given the Church's central role in organizing the festival, they must have toiled relentlessly so that this iteration would be one to remember. Like as not that they regard the whole affair as a backbreaking chore, but seeing it all come to fruition in the end must feel very fulfilling.

You join the thoroughfare at the base of the hill, where a mass of festival-goers are already gathered and flowing towards the city center. Here where thousands of lanterns congregate as one, each body no longer appears to you as a silhouette. Instead they appear to you as illuminated, beaming faces, couples chatting with their hands entwined, mothers laughing as she guides her children down the street. Faint traces of music and merriment flow out from the path ahead, mixing with the gentle whistle of wind in the leaves, which carries with it a floral scent you can't quite place.

"The festival grounds are organized in clusters," ${yusuha} says, falling into step beside you. "All of them will be open and active throughout the night, but for newcomers, there's a recommended order you might wish to peruse."

You turn your gaze on ${yhim}. "And what order would that be?"

"One traditionally begins with the dance of light," ${yusuha} says. "It's a simple jig that every Thulrum citizen knows by heart, but it truly takes on a new life given the festival's ambiance. Of course, the newcomers are typically unable to participate, since they will have had no opportunity to see or practice the dance. But it's still quite the spectacle to behold, even just as an audience."

"I suspect that will be the role I take, then," you say.

${yusuha} smiles sheepishly. "Should you wish it, I would be happy to teach you the steps in the coming days. To the Thulrum, imparting this knowledge is something of a sacred duty," ${yusuha} replies.

*choice
    #"I may have to take you up on that offer."
        *set ryusuha %+ 5
        "Nothing would please me more," ${yusuha} says, beaming. "Shall we set a date? The [i]ashai[/i] has little use for me next week, or so she says—I should be happy to accommodate your schedule."
        
        "We should wait and see what news ${falco} brings from ${fhis} mission," you point out. "You may find yourself very much employed again before long."
        
        ${yusuha} glumly concedes the point. "Then we'll make it a spontaneous affair. I'm sure we'll see more of each other as the days pass, hm?"
        
        "Perhaps we will," you allow with a faint smile. "But we've digressed. The dance of light will be the first of many attractions, you said?"
        
        *label strivebetter
        "Ah, right. You must find me a terrible guide. I shall strive to do better," ${yusuha} answers. "The path beyond the Dance of Light will take you to the floating markets. There will be no shortage of local delicacies offered on the boat-stalls. And for new arrivals such as yourself, not a single coin need be spent on your part. The Church will quite happily foot the bill, you see."
        
        *goto ratherlavish
    #"Aha, so I can select whoever I want as teacher?"
        *set ryusuha %+ 5
        ${yusuha} clutches at ${yhis} chest in a gesture of mock hurt. "You wound me terribly, ${fname}," ${yhe} says. "To think that another would occupy your thoughts even as I stand before you…I fear I shan't ever live this down."
        
        You scoff at that. "Surely someone as forward as you have dealt with your fair share of rejections."
        
        "Not so many as you seem to imply," ${yhe} protests. "And at any rate, never do they sting this bad."
        
        You wave ${yhim} off. "You still haven't told me what else the festival has to offer."
        
        *goto strivebetter
    #"Well and good. What comes afterwards?"
        "The floating markets, naturally," ${yusuha} says. "I don't know about you, but after the whole banditry affair, I'm feeling rather peckish. Luckily, there will be no shortage of local delicacies on the boat-stalls. And for new arrivals such as yourself, not a single coin need be spent on your part. The Church will quite happily foot the bill, you see."
        
        *label ratherlavish
        "That seems rather lavish," you point out. "Aren't there hundreds of new arrivals today?"
        
        "Over one thousand, actually," ${yusuha} answers. The number takes you by surprise; around the time of your passing, estimates had placed Thulrum's population at some twenty thousand souls, and it seems wildly ambitious to add such a large percentage to its existing citizenry. Regardless, "But you really needn't worry—Thulrum's government is quite lean, as you've probably gathered. It's a wonder how much budget a city can free up without noble fingers dipping into the pie."
        
        It's not difficult to see ${yhis} point. The Ishavak Faith calls for modesty as one of its central tenets. Though at its height the Sorcerium of Arcadia had paid little heed to it, you expect a theocracy like Thulrum to more closely follow the letter of the scripture. Considering the purses required to upkeep Salantira's lavish nobility and Param's legions of knights, it seems apparent that Thulrum's government would see greater financial efficiency.
        
        ${yusuha} has a wistful look about ${yhim} for a moment, but it passes as quickly as it came. "Where was I? Right, the floating market. On the other side of the river, you'll find the performance grounds. You'll be able to find all stripes of bards, dancers, and minstrels there, as well as a play put on by the city's children. Then the Hall of Memories—a restored Old Arcadian building, within which the history of Arcadia and Thulrum both are told through paintings, relics, and the like—and finally, Departure."

        Unfamiliar though you were with Thulrum's local customs and celebrations, Departure rings more than a few bells. This you owe to your Salantir education in Arcadian history, for Departure is one of the few Arcadian customs to survive the fall of the Sorcerium to then be practiced by contemporary believers of the Ishavak Faith. When the Ishavak burn their dead, custom dictates that families and loved ones take a handful of the ashes left behind. And then, on an auspicious day as dictated by the Sorcerium's astrologians, those very same ashes are to be magicked into the sky—in so doing, the deceased shall be blessed by fate upon their reincarnation to the mortal plane.
        
        Being that the last astrologians perished with the fall of Arcadia, the custom has since shifted into raising the ashes when the Star of Fortune shines brightest in the sky. A day which, you now realize, suspiciously coincides with the Day of Arrival.
        
        "All of that in due time, of course," ${yusuha} finishes. "The dance of light comes first—and look, we've arrived."
        
*page_break

True to ${yusuha}'s words, the pathway soon opens into a large, verdant space bearing a large, ornate fountain at its center and surrounded on all sides by darkened homes. The space is larger than any of the town squares you've seen in your travels across Arvanand—barring perhaps the Vesavian Crossing, where Sienan's Old Cathedral stands—but it is still densely packed with people throughout. They gather in two concentric circles; the large outer ring lines the cobblestone path nestled up against the homes, some of the people sitting upon doorsteps and patios, lanterns resting comfortably in their laps. The inner ring instead hugs the fountain at the square's center, the water it spouts cast with a mystical bluish hue by the Everfires' light.

It is in this inner circle, upon a grassy patch filled with fluorescent blooms, that the dance of light takes place. You are pleasantly surprised to find the music and steps both to be familiar—a Salantir jig or other you added to your repertoire through sheer muscle memory under the watchful gaze of your etiquette instructor. You remember it being a rather deep cut in the Salantir canon, something you were taught only after an endless procession of waltzes. Your instructor had insisted that you learn it anyway, for it would be remiss for the Grand Duke's wards not to know the steps in case the palace received guests…

…from the Thulrum Diocese. Of course.

You and ${yusuha} join the onlookers as the jig continues apace, the dancers' bodies shifting in the ring with a fluid, rhythmic ease. The lanterns the dancers had carried are placed all around the fountain's lip, such that the inner side of the dance is bathed in illumination. The outer side, on the other hand, is lit only by the distant, flickering lanterns of the onlookers, making it so that the dancers are cast with a mesmerizing interplay of shadow and light.

A young girl shifts where she stands next to you, hands pressed up against her mouth as she looks on in awe. As you cast your gaze around the onlookers, many of them are similarly transfixed—and even those who appear to be familiar with the sight gives the scene their undivided attention. And though you hear none of the chatter and laughter that you did on the way to the dance, you feel that selfsame joy present in the air regardless. Quiet and reverent, but jubilant all the same. That after a lifetime spent toiling under the most dire of circumstances, they are finally shown evidence that even Arcadians ought be allowed a beautiful and dignified life.

*choice
    #The sight fills me with a serene peace. Tahlia and her people are doing good work.
        *set optimistic %+ 15
        You are beginning to understand the fervor with which Thulrum treats the Day of Arrival's preparations. It goes without saying that the residents are motivated to ensure the newcomers feel happy and welcomed to their new city; but beyond that, you suspect that much of the zeal comes from a sense of nostalgia. That they are eager to relive the magic of their first Day of Arrival, and partake in the celebrations which had ushered in for them a new and radiant chapter of their lives.
        
        You must have let your approval show on your face, for ${yusuha} grins proudly when ${yhe} catches sight of it. "The dance always was my favorite part of the Day," ${yhe} says, keeping ${yhis} voice low so as not to intrude on the atmosphere. "I'm originally from Yotai, you know, where they hold a festival practically every other week. But they never come close to anything like this."
        
        It's a bold statement. Yotai spares no expense on its festivals, and the results are so opulent and highly-regarded that each one draws thousands of travelers from Param and Salantira both. You also know them to be a point of pride for the average Yotai—for ${yusuha} to so readily disparage them comes to you as a surprise. "Not fond of your homeland?"
        
        ${yusuha} laughs. "It's nothing like that," ${yhe} says. "They're always beautiful and appropriately festive, and the merchant-princes can always be relied upon to milk them for all they're worth, commerce-wise. But there's just…something different about this. A homecoming, but one that feels almost spiritual in nature. It's difficult to describe…"
    #This excess gives me pause. Shouldn't these resources be spent on bringing more to Thulrum?
        *set optimistic %- 15
        Everyone here seems taken by the lavishness of the whole affair, but for you, it instead becomes a glaring source of discomfort. Custom lanterns produced en masse and linked to cutting-edge magic, food offered forth in abundance and made free for newcomers, attractions which must have consumed significant labor and resources to put together. Any one of them in isolation would have given you pause, but Thulrum has instead chosen to bundle them all together into a single event.
        
        Whither the Arcadians who remain under the yoke of oppression, beyond Thulrum's bright lights and sturdy walls?
        
        ${yusuha} catches sight of your pensive look, ${yhis} brows furrowing in concern. "Is something the matter, ${fname}?"
        
        You mull your words over for a moment. "It just seems a bit…lavish," you say, keeping your voice low so as not to spoil the mood. "There must be no shortage of Arcadians clamoring for the chance to migrate to Thulrum. Would these resources not be better spent on granting them the opportunity?"
        
        ${yusuha} nods in understanding. "This matter is one the Church discusses at length as well, I assure you. We are keenly aware of the trade-off." $!{yhe} turns ${yhis} attention towards the crowd of dancers, merrily falling into step with one another. "Did you know that the average Arcadian will move to five or so cities over the course of their lifetimes? Eager to profit from their cheap labor and habituation to backbreaking work, many nobles and city lords will entice Arcadian refugees with promises of good wages and working conditions, only to fall short on their promises before the first year is out. Many of the people you see here have fallen victim to their machinations, and in moving to Thulrum, they expect only more of the same. It will take a tremendous effort to banish the suspicion from their minds. To make it clear that this is a place where they will at last be treated as [i]people[/i]. And so this lavishness, as you had put it, becomes necessary."
        
        You exhale and consider ${yhis} words. It remains uncertain whether Thulrum's decision is the correct one, but if nothing else, it's not so bleak an exchange as you had initially thought. And pragmatically speaking, a population assured in their leadership's good intentions will be a happier, more productive one. In that regard, perhaps Thulrum's policy on the matter is economic as much as it is sentimental.
        
        "We're also beginning to do more outreach to other Arcadian settlements out there. We'll hit a limit on how far we can build out this city in the short-term, and so we'll also try to ensure that Arcadians can prosper beyond Thulrum borders." ${yusuha} catches ${yhim}self at the end of ${yhis} tirade, and gives you a sheepish grin by way of apology. "I've digressed. I hope I haven't soured you on the dance. It really is quite beautiful…"
    #This does nothing to dispel Arcadia's brutality. The price paid for this is steep.
        You have not forgotten the Ishavak Church's hand in the Parami-Salantir war. It was by the Church's designs that Sister was elevated to a lofty position in Salantira, and empowered to wage her blood war against Param. You fought on the front lines every single day of the war, beheld broken bodies and rivers of blood, mourned friends and foes alike in the midst of that senseless war. Thulrum claims itself a place of refuge for the impoverished and downtrodden. Were that such succor was afforded to the widows and orphans of the war they helped set into motion.
        
        Still, Param and Salantira offered far less consideration for Arcadians following their conquest of the Sorcerium, and in the many years since. It's not difficult to imagine how an Arcadian leader might see the course they have taken to be justified. And if you are to believe Tahlia's words, she had never intended for things to go so far, and disapproved of what Sister did with the power she was bestowed. It remains to be seen whether her words are genuine—and even if they are, her lack of foresight still carried a terrible blood price. But it is at the very least more than the open disdain showed by Leon's father, and the many nobles across Param and Salantira who share in their stance.
        
        ${yusuha} catches sight of your pensive look, ${yhis} brows furrowing in concern. "Is something the matter, ${fname}?"
        
        You mull your words over for a moment. "It's clear that the Ishavak Church cares a great deal for the welfare of Arcadians," you say. "I only wish it showed the same concern for [i]everyone[/i]."
        
        ${yusuha} freezes, for a moment, before lowering ${yhis} gaze. "The [i]ashai[/i] has entrusted you with a great deal. Not even the Salantir court is aware of Mireil Altinier's link to the Seat," ${yusuha} says quietly. "I'd met Mireil in passing when she would come to visit the [i]ashai[/i]. She had a sharp tongue and a rather intimidating disposition, but seemed to me like the reasonable sort. I could have never imagined…"
        
        ${yusuha} shakes ${yhis} head. "I'll not fault you for having reservations. Isha-on-high knows that I have some of them myself." ${yusuha} then casts ${yhis} gaze out towards the dancers, who almost seem to flicker in the shifting light. "But I'm trying not to lose the forest for the trees. Thulrum is working with limited options in service to an admirable goal. Now that our position is a fair bit more solid, I have hope that our methods could be less brutish. And that we would still be able to achieve what we set out to do—to free every Arcadian from the yoke of oppression."
    #I have no opinion of the whole affair. It's a festival, same as any other.
        Param and Salantira both had their own share of festivals—though Param's Eventide Ceremony is so reverently religious in nature that it only barely qualifies—and they always offer the same things, in the end. A day off from the backbreaking drudgery and humdrum of common work, with food and merchants filling the streets, and one or two attractions and flavorings which serve to distinguish it from the next festival to be held. There will always be those who never tire of them—and for the people of Thulrum, that number is perhaps disproportionately high—and you suppose that's as good a reason as any to carry on the tradition.
        
        ${yusuha} plainly counts ${yhim}self among their numbers, for ${yhis} eyes light up with excitement as they follow the movements of the dance. "The dance always was my favorite part of the Day," ${yhe} says, keeping ${yhis} voice low so as not to intrude on the atmosphere. "I'm originally from Yotai, you know, where they hold a festival practically every other week. But they never come close to anything like this."
        
        It's a bold statement. Yotai spares no expense on its festivals, and the results are so opulent and highly-regarded that each one draws thousands of travelers from Param and Salantira both. You also know them to be a point of pride for the average Yotai—for ${yusuha} to so readily disparage them comes to you as a surprise. "Not fond of your homeland?"
        
        ${yusuha} laughs. "It's nothing like that," ${yhe} says. "They're always beautiful and appropriately festive, and the merchant-princes can always be relied upon to milk them for all they're worth, commerce-wise. But there's just…something different about this. A homecoming, but one that feels almost spiritual in nature. It's difficult to describe…"

In the center of the space, the music swells in both volume and cadence, a movement you recognize as the climactic finish of the piece. The dancers bow to their partners and then to the crowd, who greets them with raucous applause for their performance. As they filter away from the center of the space and rejoin the crowd, some of the people around you begin to shift, plainly planning to become part of the following dance. ${yusuha} smiles wistfully as ${yhe} makes way for a man-and-woman pair with the unmistakable air of romance around them.

"It's a right shame that I won't have the pleasure of dancing with you this year," ${yhe} says. "But I hope you'll grant me the honor on the next Day of Arrival."

*choice
    #I reveal that I'm actually familiar with the dance's steps.
        ${yusuha} immediately perks up in excitement. "Do you truly? Altach is hardly performed outside of Thulrum…though I suppose there are some dance halls in Salantira which had begun to teach it this past year…"
        
        You stifle the urge to scoff. You had learned the dance when you were barely in your teen years, though there's no reason ${yhe}'d need to know that. "I'm hardly proficient, mind you. I'm sure I'll get some of the steps wrong, but by my reckoning, so did plenty of the people in the previous batch."
        
        ${yusuha} laughs at that. "I'm sure they hoped the dim light would conceal their lack of practice, but they failed to account for your eagle eyes." ${yusuha} then offers ${yhis} hand, grinning roguishly at you as ${yhe} does. "Well then, ${fname}. Might you grant me the honor of this dance?"
        *choice
            #"If you insist."
                *set ryusuha %+ 10
                "Then insist I must," ${yusuha} says as you give ${yhim} your hand. The @{yvar man|woman} guides you towards the fountain, and together you join the crowd of would-be dancers, who seem to be excited and nervous in equal measure. As tradition demands, you lay your lanterns down at the fountain's lip, then make your way to an empty gap in the circle. The music swells to life, and in answer to its call, you and ${yusuha} both fall into step with the rhythm.
                
                The dance of light—or Altach, as it is known beyond the Day of Arrival's context—eschews the masculine-feminine divide that typically pervades most Arvanian dances. Instead, the steps demand that the paired dancers mirror their partner's movements to perfection, supposedly as a testament to the bond they share. The steps themselves are on the easier side—simple flourishes executed to midtempo accompaniment—but a single wrong move from either party will throw the whole pair off. It is said that in Old Arcadian high society, such a blunder would bring considerable shame upon the houses of both dancers.
                
                Needless to say, the dance of light carries no such lofty stakes. The dancers around you bungle every other step and laugh it off, at times even breaking into flourishes wholly divorced from the traditional dance. Your near-perfect execution—a testament to the viciousness of your instructor's teachings all those years ago—seems instead an unusual contrast. "You were too humble, it seems," ${yusuha} quips, ${yhis} dip forward a mirror of your own. "You're clearly a natural at this."
                
                You could say the same of ${yhim}. ${yusuha} executes ${yhis} steps with textbook perfection, in a way that puts you to mind of your own instructor. And yet ${yhe} shifts through the jig's forms with a limber grace, one which dispels much of the stiffness that typically pervades dancers in high society. "It sounds odd coming from someone who's dancing circles around me," you point out, "but thank you."
                
                ${yusuha} laughs at that. "A product of muscle memory, I fear. I've done the dance of light for nearly a decade now. If it were a [i]waltz[/i] being played instead, I'd trip over my own feet before the first bar is resolved," ${yhe} says. "Were that you shared in my struggles. But I suspect that it would be [i]you[/i] dancing in circles around me instead."
                *choice
                    #I extend an invitation for ${yusuha} to see for ${yhim}self—on another occasion.
                        *set charming %+ 15
                        "You should be quite glad, then. That you have me at a disadvantage," you say. "We should change that next time. Have you come on my turf."
                        
                        ${yusuha} perks up at that. "I rather like the sound of that," ${yusuha} admits. "There are few occasions for a waltz in Thulrum of all places, but one need only to create an opportunity if there is none."
                        
                        "You seem remarkably motivated."
                        
                        "You inspire that in me," ${yhe} says. "I rather fear that I've spent all my luck for the week, having had the honor of dancing with you."
                        
                        You scoff. "You're buttering me up too much."
                        
                        "Perhaps, if it were solely the dancing I was praising. But you fail to account for your scintillating company," ${yhe} says, winking. "Alas, loathe as I am to do so, I must let you go."
                    #Was that a soft probing of my background? I deflect gently from the matter.
                        *set optimistic %- 15
                        "I don't know about that," you say. "I'm just average, as far as these things go."
                        
                        "I should like to see these dancers you consider so expert, that [i]you[/i] might seem average by comparison," ${yusuha} laughs.
                        
                        "You need look no further than yourself."
                        
                        "Kindly remember this glowing opinion you've formed, just in case you manage to catch me out of my element in the future," ${yusuha} laughs.
                        
                        "A likely scenario."
                        
                        "I appreciate the vote of confidence. I do always endeavor to present my best side to scintillating company," ${yusuha} quips. "Alas, loathe as I am to do so, I must let you go."
                    #I'll let ${yhim} believe what ${yhe} wants.
                        "It seems you've formed a solid opinion on the matter," you quip. "I'm happy to accept your high estimations—be they deserved or otherwise."
                        
                        "Again with the humility!" ${yusuha} laughs. "They'd love you over at the Seat, you know. Modesty is one of the Ishavak's most celebrated virtues, and you seem to have that in spades."
                        
                        You give ${yhim} a wry look. "How very glad I am to have become a model Ishavak."
                        
                        "Perish the thought. They tend to be boring, that lot," ${yusuha} says. "And you are anything but."
                        
                        You scoff. "Thanks, I think."
                        
                        "None necessary. I speak only the truth," ${yusuha} says, winking. "Alas, loathe as I am to do so, I must let you go."
                
                As ${yusuha} says this, the music crests to a lush, sweeping melody, signifying that the dance has entered its second phase. The ring of dancers slowly separates into two concentric parts; you find yourself joining the outer layer, while ${yusuha} melts into the inner ring. The both of you then rotate in opposing directions, being introduced to new partners as a result. The girl who takes ${yusuha}'s place is young, pretty, and nervous, likely on her first or second try at the dance, and executes her steps with stiffness and uncertainty. You offer what help you can in guiding her through the steps, and she gives you a small nod of thanks before the circle shifts once more.
                
                Next comes a burly man with a long beard and high widow's peaks, who performs his part with practiced, if forceful, ease. And after that, a scholarly-looking boy who blushes a furious shade of red as his mother cheers him on from the sidelines.
                
                And just like that, the dance goes on until at last you are reunited with ${yusuha} for a final flourish. The music slowing to a halt, you dip into your bows and let yourself bask in the cheers and applause of the onlookers.
                
                "Thank you, ${fname}," ${yusuha} says, moving to fetch ${yhis} lantern off the fountain. "I had a great time."
                
                *choice
                    #"As did I."
                        "Music to my ears," ${yhe} says, grinning.
                        
                        *label prickly
                        The both of you depart from the inner ring, rejoining the crowd as others around you jostle and move to secure their spot in the next batch. ${yusuha} looks your way and points ${yhis} thumb out towards one of the pathways—you suppose ${yhe}'s offering to guide you to the next destination. Before ${yhe} can confirm as much, however, a woman in Church garbs—one that denotes her as a priestess of some standing—slips through the crowd and tugs at ${yusuha}'s sleeve. She whispers something in ${yhis} ears that you can't quite catch, and you watch as ${yusuha}'s expression shifts from mild intrigue to something closer to [i]concern[/i].
                        
                        *goto quitecertain
                    #"At least one of us did."
                        "How terribly prickly," ${yusuha} says. "The quest to earn your affection yet continues."
                        
                        *goto prickly
            #"I'm not really in the mood."
                If ${yusuha} is surprised by your rebuff, ${yhe} does not show it. "You'll have to forgive me for getting my hopes up," ${yhe} says smoothly, retracting ${yhis} hand back as ${yhe} does.
                
                "It's fine," you respond vaguely, waving ${yhim} off. In the center of the field, the new group of dancers sets their lanterns down on the fountain and take their positions. Soon, the music swells with a beautiful, lilting cadence, and the dance begins anew.
                
                The both of you stand there to watch the dance for some time. Before long, however, a woman in Church garbs—one that denotes her as a priestess of some standing—slips through the crowd and tugs at ${yusuha}'s sleeve. She whispers something in ${yhis} ears that you can't quite catch, and you watch as ${yusuha}'s expression shifts from mild intrigue to something closer to [i]concern[/i].
                
                *label quitecertain
                "Are you quite certain?" ${yhe} asks, ${yhis} brows furrowed. "Is there no one else that can be…?"
                
                The woman, having withdrawn herself from ${yusuha}'s ears, shakes her head. "We're loathe to do this, but with so many missing from our ranks, our options are limited," the priestess responds. "Information is still coming in, but I thought it'd be prudent to alert you early rather than…"
                
                "I understand," ${yusuha} answers. The redhead turns to regard you, then, and offers a regretful smile. "I must apologize, ${fname}. Something's been brought up that requires my attention—I'm afraid I won't be able to join you for the rest of the festival."
                *goto leavingme
    #I give ${yhim} vague assurances in the affirmative.
        In the end, you don't yet know whether your stint in Thulrum will last the full year. Much of the future still remains in flux, as Tahlia has no doubt kept many of her cards close to her chest. You have yet to find out where all the pieces fall on the board, and how much of the priestess's words it would be sage to believe. Many things may yet change before the next Day of Arrival. Enough to give rise to the possibility that you will not only no longer be of Thulrum, but perhaps even actively working against its machinations.
        
        "Perhaps I will," you say pleasantly. And then, to mask the true nature of your thoughts, "If you haven't found some other @{pronvar guy|girl|person} to pine after by then, that is."
        
        ${yusuha}'s jaw drops in mock offense. "You think I'm some kind of philanderer!"
        
        You cross your arms. "Am I wrong?"
        
        "Let it never be said that you're an excellent judge of character," ${yhe} sighs. "To think my pure intentions could be so misconstrued…"
        
        ${yusuha} rambles on some more about how unfairly ${yhe}'s being treated; you pay ${yhim} only half a mind, the bulk o fyour attention instead seized by the new group of dancers taking their positions by the fountain. Soon, the music swells with a beautiful, lilting cadence, and the dance begins anew.
        
        *label watchdance
        You stand there and watch the dance for some time, allowing ${yusuha} to regale you with information on the jig's origin and its significance to the Arcadian people. Things you're already familiar with, owing to your Salantir instructors, though you're happy to let ${yhim} prattle on and feel useful. Before long, however, a woman in Church garbs—one that denotes her as a priestess of some standing—slips through the crowd and tugs at ${yusuha}'s sleeve. She whispers something in ${yhis} ears that you can't quite catch, and you watch as ${yusuha}'s expression shifts from mild intrigue to something closer to [i]concern[/i].
        
        *goto quitecertain
    #I tell ${yhim} plainly that I'd rather not.
        You'll not deny that Tahlia and her people have been pleasant to you. But they have also admitted themselves to be the sort to have a rather singular determination to pursue their lofty ambitions. You are yet tethered to the Ishavak Church for the time being, the coil of your mortality taut around their priestess's finger. And though she's presently gracious enough not to play that card to her benefit, it remains to be seen whether that will hold true, when push comes to shove.

        ${yusuha} makes for a fine enough companion, but in the end, ${yhis} loyalty lies with the Seat. It is beyond you to treat ${yhis} kindnesses as entirely without motive; not when ${yhis} faction plainly stands to benefit from the securing of your loyalty. It seems wise to you, then, to keep the @{yvar man|woman} within arm's length.
        
        "I hate to disappoint you," you say, keeping your tone neutral. "But I don't think that will come to pass."
        
        There is a beat of silence—just long enough to betray ${yusuha}'s surprise—though to ${yhis} credit, the @{yvar man|woman} recovers quickly. "That's too bad, then. You'll have to forgive me my enthusiasm," ${yhe} replies pleasantly.
        
        "It's alright," you allow. "I still appreciate you showing me around."
        
        "Happy to be of service," ${yusuha} says, valiant in ${yhis} good cheer. "Ah, I really do want to brag about all the things that lie ahead, but I'd hate to spoil the surprise…"
        
        ${yusuha} easily slips into a lengthy ramble about the Day of Arrival's finer points, taking great care to remain vague in places so as not to give everything away. You pay ${yhim} only half a mind, the bulk of your attention instead seized by the new group of dancers taking their positions by the fountain. Soon, the music swells with a beautiful, lilting cadence, and the dance begins anew.
        
        *goto watchdance

*label leavingme
*choice
    #"I understand. Don't let me keep you."
        You can't help but be reminded of the time you had spent as top brass in Leon's army. Try as you might to forge personal connections with others, to break bread with the people ready to lay down their lives for you, in the end some matter or other would pull you back to the war table, and sometimes even the front lines. From what you can tell, ${yusuha}'s lot is nothing so lofty, and Thulrum has seen nothing but peace since the time of its founding. But you have not forgotten ${falco}'s warnings that the city may be at risk. And neither, you are certain, has ${yusuha}.
        
        "You're most gracious, ${fname}. I'll find a way to make it up to you." The @{yvar man|woman} then points down a path "You may wish to visit the floating markets next—it's the festival's beating heart, and I'm sure you'll find it plenty diverting even without me around. You'll want to go down that path," ${yusuha} says, pointing towards a shaded path where plenty of festival-goers have already begun their trek, "and it'll take you right to the riverbank."
        
        *label keepmind
        "I'll keep that in mind," you say simply. ${yusuha} nods towards the priestess and they both make their way through the crowd, towards a darkened passageway that plainly holds no place in the celebrations.
        
        Bodies shift and jostle around you, likely in preparation for a new round of the dance of light. You take that opportunity to find the gaps in the crowd, slipping languidly towards the illuminated side-street ${yusuha} had pointed to. Joining the light trickle of festival-goers en route to the next destination, you leave the clearing as music swells to life behind you.
    #"I'm sure you'll agree that this is poor manners on your part."
        "It pains me greatly to cut our engagement short, believe me," ${yusuha} says, looking sheepish. "I'll try my best to make it up to you. Forgive me?"
        
        You wave ${yhim} off. "What's got you in such a hurry, anyway?"
        
        The priestess turns a hard gaze in ${yusuha}, as if in warning. If the redhead had noticed her glare, ${yhe} hardly shows it; ${yhe} instead leans forward to whisper in your ear, ${yhis} tone serious. "Two city guards were found unconscious in their post by the west gate, presumably due to an alchemical condiment slipped into their drinks. Given the timing of the festival and the absence of a sizable number of Church knights, there's fear that something foul is brewing. They want me on the investigation team, just in case things happen to go sideways."
        
        $!{yhe} withdraws and gives you a thin-lipped smile. "Much hangs in the balance, as you might imagine. ${falco} warned us of something to this effect—praise unto Isha that ${fhe}'s otherwise occupied, or I'd never hear the end of it," ${yhe} says. "But I've digressed. I hope you enjoy the festival regardless. May I recommend the floating markets next? It's the festival's beating heart, and I'm sure you'll find it plenty diverting even without me around." ${yusuha} raises ${yhis} hand and points to a shaded path where plenty of festival-goers have already begun their trek. "That path will take you to the riverbank. You need only follow the light."
        
        *goto keepmind
    #"Is something the matter? Can I help?"
        *set noble %+ 15
        *set ryusuha %+ 8
        ${yusuha}'s eyes widen in surprise. $!{yhe} mulls something over for a moment before giving you ${yhis} reply. "While your, ah, expertise would be most welcome, I can't imagine imposing more on you than we already have," ${yhe} says. "This festival was supposed to be a day of rest and relaxation for newcomers—we count you among those numbers, lest you forget—and already you've missed so much of it due to tending to our affairs."
        
        "I wouldn't have offered to help if I minded so much," you point out. "Besides, it sounds like something rather serious is afoot."
        
        "There has been some cause for alarm, yes, but I believe we'll be able to resolve it on our end," ${yusuha} says. "How about this? I'll send for you should things fall out of hand."
        
        "And how will you do that?" you ask, glancing over at the countless people gathered in the dance of light square alone.
        
        "You needn't worry—the Church has a powerful diviner on retainer. She'll be able to find you should the need arise—though I'd rather it did not," ${yusuha} says. "In any case, I hope you enjoy the festival. May I recommend the floating markets next? It's the festival's beating heart, and I'm sure you'll find it plenty diverting even without me around." ${yusuha} raises ${yhis} hand and points to a shaded path where plenty of festival-goers have already begun their trek. "That path will take you to the riverbank. You need only follow the light."
        
        *goto keepmind

*page_break

The river has become extremely crowded by the time you make it to shore, seemingly having lived up to ${yusuha}'s declaration of it being the festival's beating heart. Out on the water, what seems like hundreds and hundreds of rafts crawl lazily along the rippling waters, propelled forward by strokes of their wooden paddles. Their numbers are such that the river has become congested in places, with rafts jostling and bumping against one another as they navigate the traffic. Rather than being miffed by the inconvenience, however, the festival-goers appear to laugh things off and take them in stride. It is plain to you that they consider this congestion to be a feature, rather than a flaw.

Floating amidst the sea of rafts are wooden boats with stout, squarish center platforms and curling bows and sterns, from which all sorts of foodstuffs are cooked and served by hawkers. A majority of them appear to be sugared delicacies and doughy snacks, which you had expected; what catches you by surprise, however, are the sizable amount of boat-stalls which hawk meaty dishes cooked over open fires. You rub your eyes before confirming that, yes, the stoves and grills are sitting upon [i]wooden crafts[/i]. It seems to you a pressing safety hazard, especially given how densely packed together the boats and rafts are, but no one else seems to be batting an eye.

"Rather strange, to be sure, but I assure you that it's nothing to be worried about."

You turn around to regard the source of the voice, and are surprised to find there a familiar face. With his mousy brown hair and unassuming demeanor, the man seems like the sort of person one could easily forget or mistake for another. But given that he's the one person you've come into the most contact with over the past week, it would be odd for you not to immediately recognize him. Indeed, this was the man Tahlia had charged with the task of overseeing your recovery, one which he fulfilled with a mix of alchemical tinctures and light theurgy.

In those early days, you were beset with such exhaustion that even small talk was beyond you. Luckily, the man hardly seemed to mind when his small talk was met with silence, dutifully seeing to his task until you were healthy and hale.

The man reaches up and adjusts his glasses, smiling all the while. "Every boat-stall and raft provided for the Day of Arrival are lacquered with cloudburst resin, which confers to them protection from catching fire. It takes specialized craftsmanship for the effect to manifest as desired, which is why you've likely not seen anything similar beyond Thulrum waters. But as you can see, our carpenters are rather learned in the craft. It's been some ten years now since fire has been allowed on the boat-stalls, and not once have we had an incident."

*choice
    #I engage the man on his chosen topic of conversation.
        "It still seems rather reckless," you say, startling a bit as a particularly powerful gout of flame licks at one of the boat-stalls' inner wall. "Couldn't they just cook on shore and bring the finished product onto the water?"
        
        "Clearly you've never had meven skewers fresh off the grill. It's worth the risk of going up in flames, I assure you," he says, eyes twinkling. "Speaking of, I don't believe we've been properly introduced. The [i]ashai[/i] was rather evasive when I asked—strange, given that you were to be my patient. After a fashion, anyhow."
        
        "${fname}," you allow. "And you are…?"
        
        "Senz is what they call me," he replies, not missing a beat. "Happy to make your acquaintance, ${fname}."
        
        *label tomarket
        "Likewise," you say. "Are you looking to go to the market? Or to the other side of the river, perhaps?"
        
        Senz shakes his head. "Neither, I'm afraid. Just here to keep watch over the market. Our knights are understaffed at the moment, so those among the clergy capable of combat has been deployed to fill the gaps."
    #Before anything, we should correct the issue of us not knowing each other's names.
        "I'll trust your word on that," you say. "But I don't believe we've been properly introduced."
        
        "Senz is what they call me," the man replies pleasantly. "A priest serving in the Seat of Isha, though you've probably gathered that."
        
        "${fname}," you say. "A guest of the Seat, or something to that effect. My situation is a bit unusual…though you've probably gathered that."
        
        *label thatihave
        "That I have, though I'm wont to pick at the finer details," Senz replies. "I'm content with my lot in the rank-and-file; matters like yours, I happily leave in the hands of the [i]ashai[/i]."
        
        You nod, unsure how to respond to that. In the end, you decide a change of topic would be best.
        *goto tomarket
    #Realizing I never properly thanked the man, I do so now.
        "Ah, it's you. I owe you a great deal," you say, dipping your head as you do. "Thank you for taking care of me."
        
        The man looks flustered by your show of gratitude. "Please, it was nothing," he says, urging you to raise your head. "I only did as I was bidden. I am only sorry that a more skilled theurge could not see to your case."
        
        That an Ishavak priest of all people could command any measure of theurgy is a strangeness unto itself. The art is generally thought to be entirely exclusive to the Jovian clergy; that the power would manifest in an Ishavak devout would doubtless give rise to controversy were it to be made known. "You risked a lot by aiding me in the way you did," you remark.
        
        "I don't believe you the sort of person who would betray our confidence," he says. "And it's a  small matter regardless. I'm protected by the Ishavak Church in many ways. I don't believe I have anything to fear from the Jovian."
        
        It's an interesting claim, given the scale and influence of the Jovian Church, but you feel it inappropriate to probe further. In the end, you decide a change of topic would be best. 
        *goto tomarket
    #I tell him I'll try this festival dish of his.
        "I'll trust your word on that," you say. "Far be it from me to question the wisdom of a local. One who clearly knows the festival's highlights by heart." What was it he had called the grilled treat again? Meven skewers? Perhaps you'll have to avail yourself to it as well.
        
        "And what a highlight it is," the man says. "Many find Thulrum cuisine to be something of an acquired taste, but meven is always a hit from the first bite. I must insist that you try it."
        
        "I'll keep that in mind," you say with a smile.
        
        The man nods, satisfied, before appearing to catch himself. "Ah, but where are my manners? I don't believe we've been properly introduced," he says. "I go by Senz. A priest serving in the Seat of Isha, though you've probably gathered that."
        
        "${fname}," you say. "A guest of the Seat, or something to that effect. My situation is a bit unusual…though you've probably gathered that."
        
        *goto thatihave
    
You find it difficult to imagine someone so peaceable and friendly on the battlefield—an assessment you keep to yourself. "Things do seem a bit on edge for a festival," you say. "I heard there's been troubling news."

"It's a failure on our part that it should reach your ears," the man sighs. "Pray push such thoughts from your mind for the night. I may look like this, but I served as young ${falco}'s magic tutor for a time. You may rest assured that things will be well in hand under my supervision."

*choice
    #"I'm plenty capable of looking after myself."
        "Ah, of course. I am aware of your gifts, involved as I was in your recovery process," he says. "I meant only that you ought not worry for the others' well-being. I will see to their safety to the best of my considerable abilities."
        
        "If you say so," you allow. "Then, if there's nothing else…"
        
        Senz nods. "Pray enjoy the festivities," he says. "And don't forget to try the meven skewers!"
    #"How reassuring. Thank you for your hard work, Senz."
        "Ah, but the pleasure is mine," he says. "I have been a Thulrum resident for nigh on two decades now, and it's been a privilege to see the city blossom and grow, and the Day of Arrival along with it. That I could serve to ensure it proceeds smoothly is a true honor."
        
        "Then I know it's in good hands," you say. "I'll leave you to your duties, then."
        
        Senz nods. "Pray enjoy the festivities," he says. "And don't forget to try the meven skewers!"
    #"You're making it sound like the markets are the only safe zone in Thulrum."
        "Ah, is that right? Nothing could be further from the truth," he says. "The festival grounds are expansive, but the Seat counts hundreds of capable knights and priests among its numbers. And that's to say nothing of the likes of ${yusuha} and the [i]ashai[/i], whose talents far eclipse my own."
        
        "I know ${yusuha}'s been deployed to help with security," you say. "But the [i]ashai[/i], too?"
        
        "Mm, deployed isn't quite the right word. She is always…involved. In ensuring that Thulrum remains in a peaceful state." The man ponders his words for a moment, and then shrugs. "It's difficult to explain. Perhaps you would be better served by asking the [i]ashai[/i] herself."
        
        You note his sudden shift towards avoidance, buy say nothing of it. "I see. Then the festival is in good hands," you say. "I'll leave you to your duties, then."
        
        Senz nods. "Pray enjoy the festivities," he says. "And don't forget to try the meven skewers!"

*page_break

The both of you part in opposing directions—Senz towards a patch of higher ground nearby, from which he has better vantage point across the whole river, and you towards the section of the shore occupied by a large mess of empty rafts. A bald man in workmanlike hempen garbs watches you as you approach, and introduces himself as the rafts' keeper.

"Will it be just you tonight?" he asks, leaning down to reach a stake on the ground where knots of rope connected to the rafts are entwined.

"That's right," you confirm. "Just me."

The man picks out one of the thinnest lengths of rope from the bunch, and your eyes follow it down to the smallest raft size available. It's just large enough to fit one person, with long boards set at an incline along its edges, presumably to protect the rider from splashing water. With a nod, he pulls the raft to shore and sets it in the water right next to your feet, motioning for you to get in. You do so, finding that the vessel has a pleasant buoyancy to it. Perhaps an effect of the cloudburst resin lacquer Senz had talked about.

You retrieve a long, almost oar-like paddle from within the vehicle, and thank the raft keeper for his help before setting out into the river. He gives you a grunt that might have been friendly before dutifully fetching another raft for the next person in line.

*page_break

You wade your vehicle out onto the open water, passing by festival-goers as they row their own crafts to and from shore. Your journey began at low light, with only the lanterns aboard sparse vessels casting dim light in the expansive darkness. As you get closer to the center of activity, though, it is as if a star has landed upon the waters to bestow its potent illumination. Here, the mystical flicker of the Everfire lanterns are drowned out by the bright, artifact-borne light aboard the boat-stalls, which are almost garish in their glare. Tens of wooden poles likely affixed onto the riverbed stand tall along the boat-stalls' perimeter, bearing iron cords which link all of them as one. And from these cords hang a wealth of lighting artifacts—the expensive kind, the ones you seldom see outside the home of nobles or wealthy merchants—sculpted into the shape of various celestial bodies.

You pass under one of these lights—made in the shape of the sun, with a perfectly spherical center and tendril-like rays—and find yourself in the middle of the festival. The air is thick with the noise of chatter, laughter, and the occasional screams of a child's tantrum, and the scent of baked treats and meat on the grill pull at you from a hundred different directions.

What will you do?

*temp food1 false
*temp food2 false
*temp food3 false
*temp food4 false
*temp foodcount 0

*label foodfork
*choice
    *selectable_if (food1 = false) #I'll have to check out this meven skewer Senz talked up so much.
        *set food1 true
        *set foodcount +1
        You gaze around to find the longest queue of the bunch is, and sure enough, you find that it leads towards a meven skewer boat-stall. You paddle over towards it, taking your place behind a five-man queue, which blessedly moves quickly. When you come up to the serving window, the hawker shoves freshly-grilled skewers onto a ceramic plate, while a man you presume to be his son does the grilling farther into the boat. He doesn't ask for payment, pointing briefly towards the green flame in your lantern. He sends you off with a friendly smile and a rapid wave of his hand, seemingly urging you to move along.
        
        With your famous meven skewers secured, you row back out onto the open waters and continue browsing the markets. Does anything else catch your interest?
        *goto foodfork
    *selectable_if (food2 = false) #I'm starving—I need a complete meal in me.
        *set food2 true
        *set foodcount +1
        Looking around the boat-stalls, it seems your best bet lies with a dish with an Old Arcadian name—kelvassi-rhai—which roughly translates to 'sun over waters'. As traditional a food as you can get in Thulrum, if what you've gleaned from texts on the city-state is of any indication.
        
        You guide your raft over to the seller, who takes one look at your lantern with its green flame and serves you the dish for free. The bowl is almost too hot to hold when you take it from the hawker, and upon catching your reaction, she quickly apologizes and produces a small tray from under the serving window. You thank her for the meal, place the dish on your raft, tray and all, and continue browsing the markets.
        
        Does anything else interest you?
        *goto foodfork
    *selectable_if (food3 = false) #Something simple and not too mealy sounds appetizing right now.
        *set food3 true
        *set foodcount +1
        After rowing past a couple of stalls, you decide to approach a boat-stall selling bread dipped in spiced soup, a dish style commonly served within Arcadian households. Under the influence of Arcadians' generational poverty, it had been watered down into what's tantamount to hard bread dipped in gruel. But as the seller hands you the meal, she remarks that Thulrum's style of the dish is an attempt of approximation at what might have once been served in Arcadia proper.
        
        Looking into the tall, almost spherical bowl, you find there braided breads around the size of your finger dipped into a pleasant-smelling soup. You thank the seller for the food, and she waves you off without asking to be paid for the meal.
        
        You continue browsing the markets. Does anything else catch your eye?
        *goto foodfork
    *selectable_if (food4 = false) #I'll go for the sweetest-looking treat I land my eyes on.
        *set food4 true
        *set foodcount +1
        That honor would wind up falling to colorful blocks small enough to fit four at a time on your open palm. The seller informs you, as she presses a pouch of the things into your hands, that they're known as prism cakes. A rather lavish name for a seemingly simple dessert, though you'll have to reserve judgment until you actually taste them. The seller, seemingly chatty by nature, additionally informs you that newcomers are given special lanterns which flicker green when approaching one of the boat-stalls. You suspect it has something to do with the artifact affixed beside each of the stalls' serving windows—a magicked disc you've never seen before, despite your extensive knowledge in arcane matters.
        
        You thank the seller for the food and information both, rowing away from the window just in time for the next raft to come in. A family of five with a crying toddler, whom the parents doubtless hope to pacify with festival sweets.
        
        Though that is, of course, none of your business. Does anything else interest you?
        *goto foodfork
    *if ((foodcount > 1) and (foodcount < 4)) #What I have is good enough. 
        You could probably fit one or two more items, given the fact that you've had barely anything to eat the whole day, but you don't feel the need to overstuff yourself so close to the festival's start.
        
        You guide your boat to a quieter corner of the river, where a mass of rafts have gathered in haphazard clusters along the riverbank—close enough to the markets to still catch sight of the festivities, but out of the way of the main thoroughfare. The locals have apparently picked out this spot as a place to enjoy their gathered delicacies; some of the bigger rafts with five or six people aboard have turned into full-fledged picnics, with empty containers and half-eaten dishes stacked precariously in its center.
        
        You find an empty spot in their midst and observe the food you've selected.
        *if (foodcount = 1)
            What will you eat?
        *else
            What will you eat first?
    *if (foodcount = 4) #What I have should be more than plenty.
        You look down at the spread laid out before you—a veritable [i]feast[/i], by all standards. Let it never be said that you weren't open to trying new things.
        
        You guide your boat to a quieter corner of the river, where a mass of rafts have gathered in haphazard clusters along the riverbank—close enough to the markets to still catch sight of the festivities, but out of the way of the main thoroughfare. The locals have apparently picked out this spot as a place to enjoy their gathered delicacies; some of the bigger rafts with five or six people aboard have turned into full-fledged picnics, with empty containers and half-eaten dishes stacked precariously in its center.
        
        You find an empty spot in their midst and observe the feast you've curated, wondering where it is that you will begin.

*temp eatcount 0
*temp eat1 false
*temp eat2 false
*temp eat3 false
*temp eat4 false
*temp eat5 false
*goto whateat2
*label eatfork
*if (eatcount = foodcount)
    *goto posteat
*else
    *goto whateat

*label whateat

You still have food left in your spread. What else will you be try?
*label whateat2
*choice
    *selectable_if ((eat1 = false) and (food1)) #Meven skewers.
        *set eat1 true
        *set eatcount +1
        The fabled meven skewers certainly [i]looks[/i] impressive. Meat is something of a luxury wherever you go, and as far as street food go, it tends to be sold in modest servings. But the skewers in your hands consist of chunky blocks of meat, well-grilled and seasoned; slight differences in marbling and color further denotes them to be sourced from different games. Slipped between the meat chunks are leafy greens and small tart fruits, but it's clear that the meat is the star of the show.
        
        You bite into the skewer, rolling the chunk around in your mouth for a second before understanding dawns. The taste is one you recognize, if only just barely, and you're likely the exception to the rule. After all, not many people will have had the opportunity to taste Elyssian beast meat.
        
        You turn your head to look over at the meven skewer stand again. Squinting at this distance, you can spy a fresh wave of supplies being delivered onto the boat—by a man in temple knight garbs. [i]Of course[/i]. Though Elyssian beasts are plentiful in Arvanand's western forests, they seldom venture out of their established territories, and even more seldom do they encounter people capable of felling them and butchering their meat.
        
        Your stint with the White Fangs gave you the opportunity to slay the beasts a total of five times, despite you essentially [i]living[/i] in the Esteram Forest. Saine had gotten quite good at butchering them after the second beast or so, and so you've been able to dine on their meat on occasion (though on the times that Leon was on cooking duty, he visited his own kind of butchery on the food, one that made them nigh unconsumable). The average Arvanian will never have the same opportunity—unless, apparently, they were a resident of Thulrum during the Day of Arrival. The beasts were too difficult to track, and more difficult still to lay low without casualties.
        
        The Seat of Isha's temple knights must be quite skilled. You make a mental note of that fact as you continue digging into your skewer. The meat is pliant and soft, such that the smaller bites very nearly melts in your mouth. But as someone who has tasted Elyssian meat before, the true star of the show is the seasoning—a blend of salt and exotic spices, only a few of which you can place. Clearly the shopowner is a more capable chef than four nobles play-acting at being adventurers.
        
        The skewers are gone in no time at all, and you find that the dish's lofty reputation is well-deserved.
        *goto eatfork
    *selectable_if ((eat2 = false) and (food2)) #Kelvassi-rhai.
        *set eat2 true
        *set eatcount +1
        You dig into the kelvassi-rhai and are surprised to find that it tastes rather mild, despite its colorful appearance.

        The dish's primary ingredient is felmin, a grain crop native to Arcadia which takes on a bluish-white hue when boiled and strained, and sheds its earthy taste and hard texture for a mild and soft finished product. It is then mixed together with a variety of spices and served with a large, circular cut of meat which nearly covers the bowl it's served on. The seller mentioned in passing that the meat comes from the yureg, a red boar-like creature with stout, stone-like horns and hard carapace covering its back and belly. It is a notoriously costly livestock to raise, taking a full ten years before it can be slaughtered and consuming nearly twice as much water and feed as another creature its weight in the meantime. However, its yuregin—gem-like casings encrusted onto the yureg's internal organs—are prized as a top-shelf material among magical artificers. It fetches such a high price that it makes raising the yureg very profitable for those patient enough to do so.

        The yureg's meat, largely considered a byproduct of the yuregin, sells for a much lower price. Still, as you sink your teeth into it, you find it to be pleasantly gamey and earthy, providing a nice interplay with the milder felmin it's served with. The dish as a whole is very filling, and you feel a warmth settle in your stomach as you set down the bowl.
        *goto eatfork
    *selectable_if ((eat3 = false) and (food3)) #Bread in soup.
        *set eat3 true
        *set eatcount +1
        You reach for the bowl of bread-soup and observe its contents. The soup at its base is dense, almost cream-like in consistency, with bits of green herbs packed into the mix. You reach for a piece of bread, lathering it with a generous helping of soup on its bottom edge before taking a full bite.

        The taste is instantly recognizable. The bread, as you had suspected, is made from tazal, a legume plant native to southern Arcadia—now a Parami territory—which is often ground to make the base ingredients of various alchemical powders. Compared to the hardy and adaptive Parami wheat, tazal is so limited and difficult a plant that it is seldom consumed as foodstuffs. There's a prevailing academic theory, however, that the Arcadians of old preferred tazal so massively that it still became more widely-consumed in the nation compared to its Parami and Salantir alternatives.

        You can't help but wonder what they'd seen in the thing. You've had tazal bread three or so times over the course of your life, and e,ach time it tasted as unremarkable as the last. Milder and chewier than wheat bread, which must be vastly cheaper to acquire.

        If nothing else, it provides an appropriate canvas for the soup, which bursts with spices, fresh herbs, and what tastes to you like goat's milk. Not flavors that you would traditionally mix into one, but the result here is surprisingly balanced and successful. You briefly wonder how it would taste paired with wheat bread.
        *goto eatfork
    *selectable_if ((eat4 = false) and food4) #Prism cakes.
        *set eat4 true
        *set eatcount +1
        You pop one of the prism cakes into your mouth and are surprised to find them even sweeter than you had expected, largely owing to the sticky brown jam at its center. Though considered rather exotic, anyone who's had a taste of it before is unlikely to forget it for a very long time. The jam is made from the fruits and sap of the lyngar tree, native to the wilderness surrounding Thulrum. The sweetness of the jam is so potent that recipes call for three times as much sugar—the more ubiquitous sweetener in Arvanian cuisine—than it does when lyngar jam is substituted. Presented on its own, accompanied only by what tastes to you like felmin-flour dough—means that the prism cake is a veritable blast of sweetness to the mouth.
        
        The only other time you've had whole lyngar jam like this was during your wardship in Salantira. To a child of ten or so years, it seemed to you then like heaven in a bite. Now, however, you're unsure if you can finish the small pouch the shopkeeper had given you.
        
        You gulp down another prism cake for good measure and set the rest to the side. One good thing about lyngar jam is that it keeps for half of forever; perhaps you'll find some other time to finish the pouch.
        *goto eatfork

*label posteat

You lay down the dish in front of you, admiring the way you picked the set clean. Some say that Arcadian dishes can be something of an acquired taste. You seem to have acquired it with great swiftness.

*page_break

You take a few minutes to let the food settle before lifting your paddle and rowing to the other side of the river, where apparently more of the festival's attractions await. A set of connected rafts by the shore obliges you to deposit your dirty dishes there, presumably to then be retrieved by their respective shopkeepers. You do so and step out to solid ground, stretching your body as you walk on.

Your clothes are slightly damp at this point, partly from sweat, and partly from droplets that had strayed into your vessel as you rowed down the river. You hold the Everfire lantern close to your form, hoping that the soft warmth radiating from it will help dry your garbs.

The path soon splits into two, and a poorly-lit sign declares that one leads to the performance grounds, and the other to the Hall of Memories. Without ${yusuha} to guide you, you seem to have taken longer traversing the earlier parts of the festival than ${yhe} intended. You think it likely that you'll only be able to visit one or the other before Departure begins.

Where will you go?

*choice
    #The performance grounds.
        The grassy path soon transitions into a lengthy walk across a wooden bridge, at the top of which several lightbearers—lantern-like artifacts cast with the telltale hue of Everfire—float and dance in unison, forming a suitably frivolous archway to the performance grounds. From some distance away, you can see that the place forms an islet amid the river's widest span. Traffic to it seems to be fed by three bridges on the side you face, and likely more on its other side. You know not what function this islet serves by day, but it's clear that the Church favors it as a central enough location for one of the Day's biggest attractions.

        As you close the final length of the bridge, it becomes clear to you that something had been built here once, in the days of Old Arcadia. Its time-weathered specter lingers still towards the outer edges of the islet: dull stone masonry with wide parapets rise along the coast, holding in its shade rows of stone bases which might have once been pillars. Topiaries and carefully-placed foliage have been planted along the path to obscure much of the once-structure's identity, but by chance, its most telltale sign peeks through the leaves anyway. Hoisted upon a weathered stone facade is a large crest cast from iron, seemingly enchanted as no rust had managed to find purchase through the ages. Twin swords point downwards and cross at the blades' midpoint, the hilts shadowed by a banner of stars. The emblem of the Knights Dynast, Arcadia's primary military force—which was slaughtered without exception during the fall of Thulrum.
        *choice
            #Unfortunate, but it's the way of things. They might've done the same, given the opportunity.
                *set  noble %- 15
                You're no stranger to the ugliness of war, which was made no gentler by the ferocity of your arcana. Every foe you spare is another knife to which you expose your neck, and you know that many would kill for the chance to plunge it in entirely. In the throes of war, even kindly Leon had forced himself to snuff out common cooks and nurses, into whose hands Salantira had slipped bottled poisons and whispered threats. That an invading force would extinguish the ones most capable of returning the favor seems almost a given in this grim game.
            #War or not, there's no excusing such brutality. What was done to them is unforgivable.
                *set noble %+ 15
                It's not as if you're a stranger to the horrors of war, but the depravity with which Param and Salantira had executed their invasion truly boggles the mind. You can only imagine what it had been like, to have been caught on the backfoot as the Knights Dynast were. They will have mounted as best a resistance as they could muster, one that demanded them watch as their friends and compatriots are slaughtered wholesale. And when their order is broken and the fight leaves their spirit, they were met not with the mercy of surrender, but instead the cold steel of the invaders' blades.

                Alas, their time is past now, and their lives gone. A new Thulrum grows around this relic of the past, like shoots rising from the earth come the dawn of a new spring. You can only hope that they would've been gladdened to know what their sacrifice has bought.

                Sweeping your gaze over the emblem once more, you find that it paints the islet in a new light.
                *goto landmass
            #Thulrum is a beast biding its time. All hell will break loose once it decides to pounce.
                *set optimistic %- 15
                Sister's invasion of Param—which by Tahlia's own admission was partially catalyzed by Thulrum—had by all accounts been a brutal one, with the king assassinated in his own stronghold, and key cities captured without so much as a proper siege. And yet you get the distinct impression that the gruesome war had been but a prelude of what's to come. Tahlia is plainly possessed of ambitions beyond your reckoning, as well as the power to see them through. You can only assume that her warpath will be paved with the bones of countless Parami and Salantir, and that she will care little and less for the blood-soaked cost of her utopia.
            #There would be no resistance more profound than growing back stronger, despite it all.
                *set optimistic %+ 15
                Arcadians have stood on history's margins for generations now, their ceaseless, back-breaking labor spent for the benefit of Param and Salantira. And yet despite what ought to have been insurmountable odds, Thulrum had managed to break free from its Salantir masters' yoke, and provide a place of refuge and dignity for the oppressed. Already the city's bustling streets prove a match for Sienan and Salantira City's thoroughfares, and the sprawl of tenements in its residential wards only grows with each passing day. Here was a sanctum reclaimed from the ashes, defiant of all the horrors visited upon Arcadians, a monument to their resilience.

                Sweeping your gaze over the emblem once more, you find that it paints the islet in a new light.
                *goto landmass

        Regardless, the sight of the emblem paints the islet in a new light.
        *label landmass
        This small landmass forms a valuable chokepoint between Thulrum's outer reaches and its heartlands, whereupon sits the High Ward, home to the Seat of Isha and—once upon a time—the estates of Arcadia's dynast caste. With the river forming a natural moat around it, the location becomes incredibly defensible. Aspiring invaders would've had to weather a storm of magic and arrows across the lengthy bridges, and what remained of them will have had to face Arcadia's finest on the other side.

        And yet, most records of Thulrum's fall hold that the Knights Dynast had been subdued with great swiftness. Caught unawares or not, it seems implausible that such a force had fallen so quickly and totally. You wonder what truth hides there, in the shadowed annals of history, and whether it deserves such censure so as to be hidden away like a pockmark by Arcadia's own successor state.

        Though the ruins and foliage both persist halfway into the islet's center, the area of the performance grounds itself is set upon an open plain. Evidently this far in, what remained of the Knight Dynasts' fort had fully surrendered to the passage of time, its masonry fully reclaimed by nature and rejoined to the earth below. In its place instead are pillars strung up with bits of black-and-white fabric, swaying in the night breeze. They loosely encircle areas made available to the night's performers, at the center of which stands the main attraction: an elevated wooden stage flooded with swirls of mist, which you were able to instantly discern as being magical in nature. A number of personnel in Church-issued garbs stand alongside the stage's edges, weaving spell circles in the air and forming the runes for illusion magic.

        ${yusuha} had mentioned that the play tonight would be performed by the city's children. It appears the festival's organizers have spared no expense in supporting their efforts.

        *if (thulrumbranch = "charisma")
            *goto lev_fork
        *else
            *goto anon_fork

        *label lev_fork
        *page_break "${fname}! You made it!"

        You turn to face the voice's general direction, and behold there a boy with a lithe build and straw-colored hair. It takes you a moment to place his face, and another to find his name. "Lev," you say after a pause, one which blessedly escapes his notice. "You're not out with the other cirque members?"

        "We're joined at the hip eleven months a year," he laughs, waving you off. "They're good people, as you yourself know. But I'm happy to be rid of them tonight, and I'm sure the feeling's mutual."

        "Can't fault you for that," you say, letting your eyes wander to the general direction of the stage. "Here for the play?"

        Lev shakes his head. "I caught the first showing, actually. I was just about to head over to the floating market, get something to eat," he says. And then, after a cursory glance at your clothes, still damp where you'd been sprayed by the river's water, he laughs. "Looks like our paths diverge here."

        *choice
            #"How was the play? Was it any good?"
                Your question startles a laugh out of the boy. "You want a good play to watch, you go to Karosa Theatre. Here, it'll be a blessing indeed if our wee singers manage to hit every other note, or remember every other step." A fond look enters his gaze, and he smiles up in the stage's direction. "It's pure chaos up there, every time. But we wouldn't have it any other way."

                "Sounds like a fun time," you admit, grinning. "I'm looking forward to it."

                "You had better," he agrees. "Just make sure you're laughing with them and not at them, yeah? They're doing their best, after all."
            #"They're making [i]children[/i] do multiple runs?"
                Lev nods by way of confirmation. "There are seven showings in all. Have to make sure everyone what wants to see the play gets to do it," he says. "The kids take turns, mind you! They only do two or three each, and typically what happens is that they insist on doing more."

                You snicker, amused. "Are you speaking from experience?"

                "I'm that obvious, huh?" he says, laughing. "Used to ask to do all seven, actually. But the Church staff runs a tight ship, so four was the most I could get out of them. I imagine that number hasn't been relaxed any this year."
            #"Make sure you get the meven skewers; they're a definite highlight."
                Your words earn a good-natured laugh from the boy. "You've got expensive taste, ${fname}!" he says. "I guess you wouldn't know this, what with your lantern and all, but the skewers are some real eye-gougers. I could get three bowls of kelvassi-rhai for a single skewer—matter fact, I might just do that!"

                You tilt your head, surprised. "You've quite the appetite, Lev."

                "And I stay stick-thin through it all," he says, sighing. "Sarai says I must have worms in me. You know, I'm starting to think she might be right…"

        Just then, a young woman calls out to Lev from further down the street, yelling that her stomach is about to eat itself. Laughing, Lev waves her off and gives you a parting salute. "Duty calls, ${fname}. You should go and find a seat—the next showing should be starting up soon."

        He jovially gives you a wave goodbye, which you return as he jogs up to the young woman. Bringing your attention around towards the theatre area, you find that the area is already crawling with people, chattering excitedly among themselves, occasionally pointing towards the stage. You decide then to follow Lev's advice, your pace quickening as what few seats remain are seized by new arrivals. You manage to secure one towards the back of the crowd, and though your viewing angle leaves something to be desired, you count yourself lucky to have managed to catch a showing so quickly.

        *label anon_fork
        *page_break "Welcome! Are you here for the show?"

        You turn to face the voice's general direction, and behold there a graying, heavyset acolyte. She regards you with a kind smile. "The play is one of the best things about Arrival—pray do not miss it."

        "Advertising on its behalf?" you ask, quirking an eyebrow. "Given the amount of people here, I don't think the play needs it."

        "It is a matter of courtesy," she says pleasantly, gesturing vaguely towards your lantern. "With how much there is on offer during Arrival, first-time attendees may find themselves easily diverted by other attractions. But the ones held during Arrival truly are special."

        *choice
            #"Aren't you overselling things? This is a lot for child performers to live up to."
                The acolyte nods thoughtfully. "I suppose I may be. You'll have to forgive me—I'm very fond of this play, and the children did a stellar job putting thigns together." She glances briefly towards the theatre area, the sound of props being shuffled around snaking out from behind the vibrant red curtains. "It'll be a blessing indeed if the little ones are able to hit every other note. But I think it charming, that the play isn't so note-perfect. Gives it a bit of heart, don't you think?"

                "Maybe," you say, shrugging. "I suppose I'll have to see for myself."

                The acolyte beams. "I'm happy to hear it! The next show is set to begin soon—hurry on and find a seat!"
            #"I can see that. You're even getting mages involved, after all."
                You feel the thrum of their mana even this far out in the field, meaning the spells they're weaving together are full ones, rather than simple cantrips. Anywhere else in Arvanand, deploying such magic for so frivolous a thing as a festival play would have been unthinkable. But the people of Thulrum are descended from the legendary Sorcerium, to whom works of great magic came as easily as breathing. And given how highly the Day of Arrival is regarded in local culture, you can only find it fitting that magic's taken such a central role in the proceedings.

                The acolyte seems pleased that you've noticed her organization's efforts. "The children worked very hard to bring this play to fruition. It seems only fitting that we offer them the best support we can."

                "I see," you say, giving her a casual smile. "I suppose I'll have to look forward to it."

                "Please do!" the acolyte says, beaming. "The next show is set to begin soon—hurry on and find a seat!"
            #"What's the play about?"
                The acolyte startles at your words. "Oh, I wouldn't want to spoil it for you."

                You quirk your brow at her. This is an odd thing to be so tight-lipped about. "Won't even tell me the title?"

                "She clasps her hands together and shuts her eye tight, as if begging for forgiveness. "Have faith in my words, I beg you. It would be far better for you to see it for yourself," she says. "You wouldn't have to wait very long at all. In fact, the next show is set to begin soon…"

                You sigh resignedly. "Very well, then. I suppose I'll go find a seat."

                The acolyte perks up and beams at you. "Please do so! I promise you won't regret it," she says. "Enjoy the play!"

        She jovially gives you a wave goodbye, then, and runs up to the next person carrying a newcomer lantern. You break your gaze from her fleeing form and turn towards the theatre area. You find that it's already crawling with people, chattering excitedly among themselves, occasionally pointing towards the stage. You decide then to follow the acolyte's advice, your pace quickening as what few seats remain are seized by new arrivals. You manage to secure one towards the back of the crowd, and though your viewing angle leaves something to be desired, you count yourself lucky to have managed to catch a showing so quickly.

        True to what you were promised, barely any time passes before the play begins in earnest. Mana crawls up to the stage from along its perimeter, swirling like mist, and you feel the illusion take hold behind the curtain. A stagehand draws it open, then, and murmurs of awe rise from the crowd around you at the illusionists' handiwork. There upon the stage rests an expansive forest filled with towering trees and tangled underbrush, all surrounding a humble hut hewn from dark, mottled wood. Though very much lifelike in scale and impression—complete with avian calls and the occasional falling leaves—you find that the scenes' visual elements have been made to take on a soft, painterly quality. As if it had jumped directly out of a child's picture book.

        At the top of the scene, a disembodied voice announces the play's name: [i]Darkwood Chronicles[/i]. The announcement draws a startled noise from you. [i]Chronicles[/i] is a Salantir classic penned over a hundred years ago, and one that is very much a reflection of its time. It centers on the Darkwood Witch, a red-skinned, hook-nosed woman who abducts lazy, rebellious children and keeps them in her hut. There she exploits the children's indolent nature and feeds them with copious amounts of food every day, so that she can slaughter them and dine on their meat. The story ends with the Witch's death at the hands of the village's courageous and disciplined children, hence making for a very on-the-nose moral statement. That children ought to listen to their parents and help out around the house, or risk a gruesome fate as what befell the lazy children of the [i]Chronicles[/i].

        Given its gruesome contents and dubious moral statement, the play has long lost favor with even the Salantir canon, from which it originates. Needless to say, it comes as a great surprise that Thulrum of all places would bid their children perform it for their most important festival.

        Thankfully, it is not long before your feelings of uncertainty and discomfort are laid to rest.

        *page_break

        You soon discover that Thulrum's iteration of the play is not a faithful rendition, but rather a complete retelling of that time-worn tale. At the end of the first scene, the Darkwood Witch unveils that her monstrous visage is but a mask, revealing that she is herself a child. Through flashbacks, her tale is then told: that she had been blessed with god's miracle at birth, one that allowed her to banish the monsters threatening her village. And while she happily did just that for the first span of her life, her village soon came to rely only on her powers, insulting and condemning her whenever she refused out of exhaustion.

        Eventually, the Witch had enough and egressed to the nearby woods, leaving the village to fend for itself. Her so-called abductions, then, are an attempt of sparing the village's innocent children from a grisly fate. Instead they are fed, clothed, and allowed a worry-free life by virtue of the Witch's miracle, who wishes for them what she herself was never allowed. A gentle, carefree childhood, free from the awful machinations of selfish adults.

        The tale moves forward at a tight, almost haphazard pace, doubtless to accommodate for the inexperience of its performers. And though plenty of mistakes were made regardless, held against the earnestness with which the children approach their performance, what gaffes there were only serves to endear them to you.

        In defiance of the original script, the play builds up to a happy, reconciliatory finale, with the Witch receiving her rightful apologies, and the village forming a militia to share the load of her responsibilities. The moral statement imparted at the play's conclusion changes as well: that children ought to be allowed the space to enjoy their youths. This message is relaid through a rousing, sing-along ditty, and as the opening notes are sung the illusion twists and transforms as if in answer. Light floods the entire span of the stage, transforming it into a veritable beacon against the Day of Arrival's dark. Mana swirls in the air, coloring the space with a sorcerous glimmer, a burst of colors that puts you to mind of a firework.

        And then the cast descends upon the audience, inviting the children among them to join in for the final celebration.

        *choice
            #Unsanctioned though they may be, I make my own magical contributions to the atmosphere.
                The priests' illusions are plenty competent to begin with, and so your contributions amount to little more than touch-ups and enhancements here and there. The colorful mist takes on an iridescent sheen, glimmering like a kaleidoscope under the magical light. A pervasive warmth emerges from the stage and wafts towards the audience, like a hand extended in invitation.
            #I begin an encouraging chant, urging the children among the audience to accept the offer.
                The chant catches like wildfire through the crowd, granting an uplifting air to the proceedings. The performers seem startled by the level of support—clearly, this is beyond the norm—and smile blindingly as they make their way through the crowd.
            #I'm awestruck by the scale of the production. One of the Day's highlights, indeed.
                You've been promised that the play is one worth seeing, but even with your expectations raised the spectacle is beyond your imagining. You spy the priests wiping sweat from their brows and drawing heavy breaths—clearly multiple showings of the play have begun taking its toll on them—but the smiles gracing their features are every bit a match for those of the actors.

        The performers' offer is met overwhelmingly with overjoyed shrieks, especially from among those children who carry residents' lanterns. They might have known something like this was forthcoming, and so are only too glad to partake in the festivities. That acceptance is not nearly so ubiquitous among the new arrivals, but still many of them hesitantly let themselves be guided onto the stage regardless. They blush a furious shade of red, eyes seldom leaving the ground. You are glad to find that the beginnings of a smile regardless tug at their lips.

        The gambit lends an air of chaos to the play's final number, but a quality show is no longer the order of the day. When the curtain closes upon the theatre and obscures both actors and invitees, the crowd rises to give a rip-roaring ovation which lasts a full five minutes. When the children of the audience filter out from backstage and make their way back to their guardians, they are met with exuberant laughter and congratulatory applauses, and from upstage the performers look on with a beatific smile.

        *page_break The play draws to a close.

        Following the show, you spend some time exploring the performance grounds, which stretches far onto the islet's other shore. Given the explosive opening, you can't help but feel a bit disappointed when the rest of the grounds offers only standard festival fare. The minstrels and bards prove competently entertaining, and the dancers showcase a variety of jigs from even beyond Arvanian shores. Still you find that your thoughts linger on [i]Darkwood Chronicles[/i], and that feeling of pure joy pervading the air following its conclusion.

        Echoes of the experience follow you even as you exit the performance grounds. Despite this being late into the night, the flow of festival-goers around you seem to be om high spirits still, and they chatter excitedly among themselves that Departure is soon set to begin. The final event of the Day of Arrival, which serves as both its emotional and aesthetic pinnacle. You tail the crowd as they make their way through darkened paths towards the site of Departure.
    #The Hall of Memories.
        You can spot the Hall long before you reach its threshold. It's a grand marble building standing all by its lonesome in the center of a wide clearing, illuminated on all sides by a flood of artifact-borne light. Like the floating markets before it, this is a place that does not adhere to the Day of Arrival's otherwise consistent lights-out policy. You suppose it only makes sense, given its role as a place of learning and exhibition—neither of which typically fare well in dim light.
        
        You join a throng of festival-goers gathered upon the building's front steps, who you soon discover are waiting their turn for a guided tour of the Hall. An artifact you recognize as a sending bell rests on a table next to the would-be guide. Supposedly, the bell will ring by itself when its pair is shaken some distance away. You imagine it will be used as a signal that the last batch of festival-goers have gone far enough into the Hall that a second batch could be dispatched without overlap.
        
        The would-be guide, a shorter man with the inoffensively competent air of a lifelong butler, explains some ground rules to the crowd visitors. Sensible stuff, in all—refrain from touching the exhibits, see that children do not run off and endanger themselves, and stay with the tour group—which he repeats a couple of times for the benefit of the newcomers who filter in after you. As expected, the bell beside him soon rings; the guide then tosses open the building's ornate marble doors, leading you and your group into the Hall proper.
        
        *page_break
        
        The first chamber beyond the door is something like a foyer, with tall arches and ornately-carved marble pillars. Twin streams of clear water rush down gullets on the middle section of the corridor, framing a line of statues in various stately poses. The floor is fashioned of black marble, smooth and immaculate, and vines poking out of the ceiling crawl freely along the walls, adding a splash of green to the pristine white. Boxy bushes dotted with colorful blooms squat along the edges of the statues, their roots crawling over the edge of the platform and drinking from irrigation panels connected to the gullets.
        
        The gentlemanly guide clears his throat as he begins describing the sight. "Much like the Param and Salantira of today, Arcadia was led by a class of nobles who were known as dynasts. They were capable of grand, ancient magic lost to the Arcadians of today, which granted them the capacity to defend and maintain their nation." And then, with surprising candor, "Unfortunately, it also granted them with a terrible propensity for infighting. Though there is little agreement among scholars, so wrought is our history with guesswork and conjecture, all of them agreed that the dynasts were fiercely competitive and territorial. Lords changed frequently as the Dynast Houses' stars rose and fell. It is a good thing that they were so fond of dueling that the common masses were mostly spared the battlefield."
        
        You find this to be an accurate retelling of recorded texts on Arcadian history. It seems the guide, and therefore the Seat he serves, has no desire to mask the uglier points of Old Arcadians.
        
        "Among these Dynast Houses, several rose to significant distinction—enough so that tales about them survived the purging of Arcadia," he says. "The statues you see before you bear their names, if not their likeness. Their deeds and the degree of their strength are known to us, but what information exists about their appearance are scant and often conflicting besides. Regardless, the Seat thought this an appropriate measure, to give faces to their lofty deeds."
        
        The guide then leads your group down the corridor, stopping at each statue and describing the dynast they represent. Among them were monarchs, war heroes, even a saint who purged a terrible plague from the land. Many of them bears the surname Mateus, the Dynast House from which you are apparently descended.
        
        The guide would speak at length about each of these figures, to the oohs and aahs of the crowd around you. But how do you feel about the whole affair?
        
        *choice
            #I appreciate the candor with which the guide explains Arcadian history.
                It is true that Arcadia fell victim to a fierce and unprecedented betrayal, an invasion brought to them on the heels of what was supposed to be a decades-long peace treaty. It is also true that her people has since suffered immensely in the hands of the Parami and Salantir, and has just cause to hold grievances against both nations.
                
                But before all of that, Arcadia was also a nation just like any other. It carried out fierce wars of conquest, engaged in pillage and plunder, and imposed a rigid caste system upon its own people. When describing the warriors and monarchs in the lineup, the guide both lauded their successes and reproached their flaws. He decried any incident in which these dynasts slew those weaker than them.
                
                You can't help but notice the emphasis with which he says [i]weaker[/i]. What would his stance be on the wanton slaying of Arcadia's oppressors?
                
                You don't give voice to the thought, but the answer comes to you just the same.
            #I admire the craftsmanship and architecture. I've seen little better.
                And coming from you—someone who spent a good chunk of your life prowling the halls of royal castles—that's quite the compliment.
                
                The Arcadian style is a study of contrasts: simple and elegant in design but executed with an excessiveness that borders on the absurd. The statues before you appear largely unremarkable from a distance: mere unpainted stone carved into practical, grounded poses. But a closer look reveals the painstaking detail with which each strand of hair is carved, the perfectly logical path with which the fabric flows. In a similar vein, a garden planted around sculptures are hardly a novel idea, but to have it be built and irrigated [i]indoors[/i] requires the sort of daftness you can only attribute to Arcadian architects.
                
                The guide claims in passing that Arcadians of old favored indoor gardens such as this, as a means of injecting color into the traditionally black-and-white Arcadian interior design. You've read nothing to that effect in your long years of studying the civilization, and so doubt the veracity of his claim. Blissfully ignorant of your questioning stare, he moves gracefully down the hall.
            #I'm surprised by the excess. I thought the Ishavak Church preached modesty.
                The Jovian Church certainly smiles upon the modesty of the common man, but also proudly declares that grandeur in religion is an act of worship before god. A stance you've always found a hair too convenient for members of the clergy, but at least they were honest about it. Whither the Ishavak, who urges simplicity in the home of kings?
                
                Before you can speculate further, however, a mousy-looking woman in your group asks the very same question to the guide, who does not miss a beat before answering.
                
                "The Hall of Memories is affiliated with the Seat of Isha, but it is not a religious site," he answers smoothly. "Its purpose is to display the ways of Old Arcadia to the uninitiated, and for this noble goal to be accomplished, accuracy is the order of the day. Modesty is of course a virtue, but so is learning, and there are times where one must be compromised such that the other may exist. The Hall of Memories is a better exhibit for this principle than others."
                
                He smiles at the woman after giving his answer, appearing to brook no discourse, before turning around and marching your group down the hall.

        *page_break
        
        The next chamber you find yourself in is much more expansive than the first, and much more haphazard in layout. Large highwork murals—indistinguishable from oil paintings, except for the fact that they somehow stick onto the marble wall as well as paint to canvas—decorate sectioned-off portions of the wall, depicting scenes of war, devotion, and works of great magic. Transparent cases affixed onto marble pillars line the room's perimeter, each one displaying an artifact of Old Arcadia, some of them positively [i]ancient[/i], and others recreations. And remarkably, at the center of the room, rising like smoke from an urn-like artifact is an illusion depicting a scene from Old Arcadia—from [i]this very building[/i], the guide proudly informs you—as it would have existed centuries ago.

        Beside you, a man furiously writes into a bound notebook he balances on his palm—Salantir of origin, judging by the lilt of his accent. He mumbles to himself as he takes in the sight. "A mouseion, right here on Arvanian soil…fascinating."
        
        You find that you disagree with his assessment. You've read quite extensively about the structures known as mouseions in the oversea Gespenst Empire, which serve as exhibition halls for the peoples of the world that the Empire has conquered. This ranged from the Rvuli people in the Imperial Continent's west, directly facing Arvanian shores, to the Yotai homeland in the Yire continent's south, which bent the knee to Imperial rule at the tail end of a grueling thirty-year naval campaign.
        
        Imperial policy demands an overwrite of existing religions in these places with the Empire's own, but goes to great lengths to preserve the existing culture where it does not conflict with the Authority Gospel. Ironically, as a part of this measure, many of the conquered nation's cultural artifacts and texts would be plundered and shipped to the Empire's core cities, where they would then be gawked at by true Imperial citizens in their many mouseions.
        
        In this regard, the Hall of Memories present a stark contrast. This was not a place where the plundered histories of others are presented for the enjoyment of conquerors. Instead, it is the shrine of a broken people, a desperate assembly of what little they know of their lost history, so that, if nothing else, it is immortalized for future generations.
        
        Indeed, Param and Salantira had gone to great lengths to expunge the Arcadian culture from Arvanian history. They burned texts, destroyed temples, razed cities, and murdered those who would keep Arcadia's story alive through word-of-mouth. In the end, all that remained was a people who knew little of their origins and cared even less. Ones who could not aspire to be greater than they are, because for all they know, it is all they've ever been. In this regard, if not in others, Param and Salantira had been crueler still than the blood-soaked Empire.
        
        The guide, though doubtless close enough to hear the scholar's mutterings, makes no effort to rebut him. He is instead content with pointing out the different segments of the room, and declares that everyone is free to browse its collection at their leisure. At his words, the crowd immediately departs for different corners of the room, though the bulk of them remains in step with the guide as he approaches the illusion at the center of the room.
        
        *temp memhallcounter 0
        *label memhallfork
        *choice
            *disable_reuse #I follow the guide towards the center of the room, next to the illusion.
                *set memhallcounter +1
                "The building we are currently in once served as the most prominent magical college in all of Arcadia," the man says as he gestures towards the illusion. It appears to depict a symposium of some sort, with a speaker standing upon large stone podium where the illusion currently is, overlooking rows and rows of seating, stacked up against one another like a series of steps. All of them are filled with distinguished-looking individuals, many of whom appear to be heatedly questioning and debating the speaker on her subject matter. "It is in this place that the finest magical minds would push the boundaries of magical learning and make countless discoveries which still inform magic as it is practiced in Arvanand today."
                
                The illusion shifts behind him—the speaker steps off the stage and wipes sweat from her brow, walking to a place where the illusion does not extend. She is replaced by an older man who dips her head in greeting, before immediately manifesting a magic circle in the air and summoning torrents of lightning to strike down around the podium. The illusion is possessed of neither sound nor color, but the sheer flashiness of it draws surprised yelps from the crowd. The unfortunate man who had been closest to the illusion is so surprised that he stumbles back and lands on his behind; a woman who appears to be his partner stifles a laugh as she pulls him up.
                
                "Historical evidence points to Arcadia being the birthplace of many of the higher-level spells in the Arvanian canon, including Skywrath, the magic you now see displayed on the screen," he says. "This claim is oft contested by Salantir mage towers, who credits their first tower master with the discovery. The man's own memoir—accused as a fabrication by Salantir mages, naturally—mentions in passing that he learned of the spell from his slave, an elderly former dynast who attended this very same college. And so though the veracity of this story still leaves room for doubt, we have chosen to commemorate the event in which he first presented the spell to the college, as he likely would have done."
                
                The scenes continue to morph and shift behind him, showing other speakers take the stage, showcasing their own magic. None of them were quite as impressive as Skywrath's alleged deviser, but the intent of the exhibition is clear. They mean to showcase Arcadian civilization at its height, and how it stood as the spearhead of Arvanian progress.
                
                The illusion would soon loop back into itself, showcasing again the mousy woman who shrinks back from her colleagues' questioning. The guide dips his head and urges you all to explore the chamber independently, saying that he will be waiting for you to gather near the room's exit.
                *goto memhallfork
            *disable_reuse #I make a beeline for the largest mural in the room, labeled Isha's Descent.
                *set memoryhallmural true
                *set memhallcounter +1
                It is immediately apparent to you that the mural is done in a markedly distinct style from the other highworks in the chamber, and indeed, every other highwork you've seen. It's comprised of countless shards of colorful glass, each one no bigger than the hole of a needle, arranged so carefully and perfectly that it's indistinguishable from a painting until you're inches away from it. True to its title, the mural depicts one of the most important scenes in the Ishavak canon. The moment when she descended to Arvanand, beheld all the suffering that mankind had created for themselves and for the land, and resolved that she could yet change the course man has set for his own destruction.
                
                Isha, Arbiter of the Chant, rests near the highest point of the mural, a woman with dark, flowing tresses and a simple white shift, rays of divine light beaming from her form and stretching towards the ground. She carries in one hand a chalice overflowing with clear liquid shot through with threads of gold, while in the other rests a sword with only half its blade, the pointy end sawed off such that a flat, blunt edge is all that remains. You recognize them as the offerings Isha brought upon her first descent and contact with mankind, the Twin Gifts of the Chant: mana, and mercy.
                
                Beneath her form unfolds a tapestry of icons representing the natural world, from the sun amidst its clouds, the winds blowing through the trees, rivers rushing through mountains. And at the very bottom of the mural are a what looks to be hundreds of human hands, outstretched towards Isha's form, begging for succor. Some of them appear feminine and unblemished, like the hands of noble maidens, while others are rough, crooked, snarled with scars. Curiously, a few of them bear sticks and daggers pointed directly at Isha. You can recall no parallel between this element and the Ishavak's founding myths, and silently file the observation away for later consideration.
                
                On the top right corner of the mural, hidden in the dark recesses between rays of Isha's light, lies a similarly divine figure. He gazes coldly at Isha as she bestows her Gifts unto the people, gnarled fingers tight around the broken tip of a sword. You do not need to look at Isha's hand to know that the sword she holds is its perfect pair.
                
                In the end, the mural tells a straightforward tale. That Isha had bestowed blessings upon mankind, allowing them to survive and triumph. Her divine brother, Orion the High Arbiter, disapproved of her actions; he corrupted the hearts of men in retaliation, such that the powers Isha had gifted them would instead become a curse. And so it was that the Ishavak Church's doctrines were established, that men would utilize Isha's blessings the way they were intended: as a means of securing peace and progress, rather than conflict and oppression, as bidden to them by Orion's machinations.
                
                One of the Hall's visitors pass by behind you, her arm grazing against your back and breaking you out of your reverie. Deciding that you've gleaned what you can from the mural, you turn around and head to your next destination.
                *goto memhallfork
            *disable_reuse #I go towards the nearest display case, where a large sword hangs suspended in midair.
                *set memoryhallghisan true
                *set memhallcounter +1
                You marvel at the sword as you approach it, as well as the magical mechanism which allows it to hover in midair. The weapon bounces softly as it's pushed by the twin force-appliers attached to the case's top and bottom. The plaque underneath tells you that it's an original artifact salvaged from Old Arcadia, rather than a recreation like many of the chamber's other artifacts, which you had expected. What does surprise you is that it names the specific dynast to whom the sword apparently belonged—Ghisan Lucerre, Lord Dynast of the House of Lucerre. 
                
                The plaque declares that he is seen as a noble martyr of the sacking of Thulrum, whose sacrifice saved many lives and allowed his fellow dynasts to mount a resistance to Parami and Salantir oppression for many years to come. It further says that though he was a mage of incredible repute, he tended to favor the sword in combat, as it allowed him to join his men in the front lines. The blade was apparently located in the remains of his mansion, many years after the fall of Arcadia. It seems that Param and Salantira's sudden invasion had caught him without his favored weapon.
                
                You have to wonder at the truth of that. Piecing together the scant details Tahlia and her arcanists have told you, it seems likely that someone in his lofty position would be an arcanist of significant mettle. You were never trained in the art of swordplay—outside of a couple of sparring sessions with Eli, who was too afraid to hurt you to be of any use—but you've still fought alongside some of the finest swordsmen of this age. And even the foremost among them, the Sun King himself, could not hold a candle to an arcanist like you when it came to wreaking sheer destruction on the battlefield.
                
                It seemed impossible that this Ghisan would give up such an advantage as a point of foolish pride. Then again, in the eyes of contemporary Arcadians, the powers wielded by the dynasts of old were mere magic, pushed beyond its limits through knowledge and discipline. To admit otherwise—that they were empowered by the dynast's contracts with great and incomprehensible beings—came dangerously close to confirming Param and Salantira's casus belli: that the Sorcerium as a whole consorted with demons.
            
                You watch the blade for some time, observing its still-keen edge and the ornate carvings on its hilt, imagining how it would have looked when wielded by its rightful owner. What sort of people were the dynasts? Had they lived through the fall of Arcadia, would they have been able to tell you the true nature of phantasma and the powers they bear? What did it mean that only Arcadians in all the world were privy to their gifts?
                
                Would that a sword could provision you with all the answers.
                
                You take a deep breath and tear your gaze away from the weapon, this relic of an age long gone, and make your way to your next destination.
                *goto memhallfork
            *if (memhallcounter > 0) #I've seen everything I want to. I join the guide near the exit.
                You do as much, and you're soon joined by the rest of the Hall's visitors, and the guide leads you all as one to the next chambers.
                
                The Hall would contain three more rooms after that, showcasing everything from Arcadia's theorized coinage and styles of dress to a city map of Thulrum before the fall. Though some of these items continue to pique your interest, it's clear to you that the Hall frontloads the most impressive pieces of its collection. You nod along as the guide drones on about salvaged pieces of correspondence from some merchant or other. Your thoughts, however, linger still on the dynasts of Arcadia and the long shadows they yet cast, centuries after the last of them have perished.
                
                Your tour of the Hall of Memories soon concludes, with the guide thanking you politely for your patronage—never mind that you had to pay aught in coin for the experience. The crowd soon disperses into the night, chattering among themselves that Departure is soon set to begin. The final event of the Day of Arrival, which serves as both its emotional and aesthetic pinnacle. You tail the crowd as they make their way through darkened paths towards the site of Departure.
                *page_break
                *goto departure

*label departure
You eventually arrive at the base of a small knoll, upon which sits a stone tower some five levels tall—though from the way it hugs the ground you suspect that there are underground layers built into the hill itself. Extending from its central, pillar-like base are stone ridges with banisters half the height of the average man, wrapping around the tower like the disc of a sundial. Curiously, there are [i]three[/i] sets of stairs which spiral around the central pillar and crawl up through the levels, and all of them side by side takes up nearly the entire width of the disc.

The odd structure only begins to make sense as you come upon its base and get a clear look up. The stairs are in fact no stairs at all, but flat planes set at an incline so soft that one could comfortably stand on them for hours without discomfort. Given the amount of people present for Departure, the space-efficient design of the tower seems to you a lucid piece of wisdom.

An acolyte you don't recognize rushes up to you as you approach the tower proper, wiping sweat from her brow as she dips her head in greeting. "Welcome to Departure. Will you be sending light today?"

You blink at that. "What?"

The young woman returns your confusion for a moment, before realization dawns on her. "Oh, you're a new arrival! Pardon me, pardon me, it's been quite a busy night," she says. "Departure is a ceremony in which the Ishavak faithful among us honor our deceased, by taking a handful of their ash and sending it into the sky. We do so through the use of the lanterns—yes, like the very one you're holding!—and in so doing, the ashes become cast with a magical light. As such, we have taken to referring to the practice as 'sending light'. It carries a double meaning, you see! By light, we refer to the ashes themselves, which are [i]literally[/i] aglow, as well as the people they represent, which—"

*choice
    #I cut her explanation and tell her that no, I will not be 'sending light'.
        *set noble %- 15
        "Are lights in their own right, yes. I understand," you cut in. "I'll just be watching today, if that's alright."
        
        The young woman looks chastened for all of one second before returning to her chipper mood. "An observer! Yes, that's alright, of course. I will be happy to show you the way!"
        
        You cast a glance around you, where people are already staking their own claims in the grass. "It seems like this is as good a place as any, though?"
        
        "Oh, do pardon me, but this space is reserved for those who have light to send," she explains, dipping her head in what might have been an apologetic gesture. "It can get a little cramped up in the tower, you see, and the process of sending is a bit complicated, so the space—"
        
        "Yes, I can imagine," you say, this time nipping her tirade in the bud. "So that leaves the tower for the rest of us?"
        
        "Quite right!" she says, nodding twice in quick succession. "Not to worry, the view is excellent from up there! I believe we still have free spots in all of the levels, but oh, I think it'd be best to see it from the top. Come on, I'll take you where you need to go!"
        
        *goto excitewave
    #I nod along pleasantly while pretending to listen.
        *set charming %+ 15
        The young acolyte is happy to prattle on about the upcoming event—you might even find the excitement with which she regards Departure endearing, if it wasn't also just a little morbid—and you ooh and aah at her explanation for a good five minutes or so. It is only after you exhaust your supply of stock phrases—from 'Is that right?' to 'That's very interesting!'—that your new acquaintance catches herself mid-speech, a horrified expression etched onto your face.
        
        "Oh no, I've been rambling again, haven't I? Madam Junne will never let me hear the end of it…" she turns to you, then, and bows low and quick in a gesture of apology. "All that talking, and I don't even know whether or not you'll be sending light. I'm sorry!"
        
        "It's quite alright," you assure her. "It's not a bad thing to be passionate. And no, I won't participate this time. I'll just be watching, if that's okay."
        
        The woman brightens immediately and nods—twice, in quick succession. "Of course! Those who have light to send will gather here on the grass, so onlookers are encouraged to go up to the tower. I believe we still have free spots in all of the levels, but oh, the view will be best from up high! Come on, I'll take you where you need to go."
        
        *label excitewave
        She excitedly waves you forward, leading you to the base of the incline. She spends some time explaining to you the path upward—never mind that it's as straightforward as a path can get—and leaves you with a chipper 'Have fun!' before going out to find a new person to guide.
    #I sigh inwardly, letting her finish her explanation.
        *set charming %- 15
        The young acolyte is happy to prattle on about the upcoming event; you let her do as much, though less than half of what she says registers in your mind. She has a way of speaking that puts you to mind of a carriage whose horse has gone mad, pulling up some new trivia or other before the previous one has had time to settle. The way she never seems to run out of topics to talk about is almost impressive. You imagine she might have had a sterling career as a bureaucrat, were she privy to different circumstances of birth.

        After five minutes or so—though it feels like far longer—your new acquaintance catches herself mid-speech, a horrified expression etched onto her face. "Oh no, I've been rambling again, haven't I? Madam Junne will never let me hear the end of it…" she turns to you, then, and bows low and quick in a gesture of apology. "All that talking, and I don't even know whether or not you'll be sending light. I'm sorry!"
        
        "It's…fine," you say, struggling to calm the ringing in your ears. Jove, but she's a loud one. Forget being a bureaucrat, her true calling might be at a hawkers' alley. "And no, I won't be participating. Just here to watch."
        
        The woman nods eagerly in response. "Right, of course. Those who have light to send will gather here on the grass, so onlookers are encouraged to go up to the tower," she says. "I believe we still have free spots in all of the levels, but oh, the view will be best from up high! Come on, I'll take you where you need to go."
        
        *goto excitewave
    #I ask her whether hers is the appropriate mood for what's essentially a funeral.
        She blathers on for a bit more before you can seize the chance to get a word in. "Say, isn't this an event for mourning?" you ask, brows furrowed. "Is it okay to be so chipper about the whole thing?"
        
        The young woman's jaw drops, and for a moment you fear her eyes might crawl out of her socket. "Oh no, that's right, isn't it?" she murmurs. "I only thought—it should be a [i]happy[/i] event, because their loved ones are finally joined with the sky, but surely not everyone—oh, [i]no[/i]—"

        "I'm sure they'll understand," you say almost instinctively, taken off guard by the strength of her reaction. "You're just trying to help, after all. But it might be good to keep in mind for future reference, you know?"
        
        The woman swallows a gulp before nodding. "Yes, of course. Thank…thank you for telling me!" she says, bowing low and quick. "Madam Junne will never let me hear the end of this, I'm sure…but oh, I should stop rambling! I don't even know whether you'll be sending light or not!"
        
        "I won't be participating, no," you say, shaking your head. "Just here to watch, if that's alright."
        
        The woman nods eagerly in response. "Right, of course. Those who have light to send will gather here on the grass, so onlookers are encouraged to go up to the tower," she says, trying to maintain a valiant front despite being obviously flustered. "I believe we still have free spots in all of the levels, but oh, the view will be best from up high! Come on, I'll take you where you need to go."
        
        She waves you forward, then, leading you to the base of the incline. She spends some time explaining the path to you the path upward—never mind that it's as straightforward as a path can get—and thanks you once more before going back out to the field, a solemn expression on her face.

*page_break

The air is colder at the top of the tower. A puff of white mist appears in the air before you as you exhale in quick breaths, your body strained by the long climb.

You used to have better stamina during the war. Always running from one checkpoint to the next, your honor guard a wall of shields and enchantments around you. Mana bursting from your fingertips, entire battalions laid low by a single spell.

You left much of that strength behind in the abyss, and you don't know if Senz and Tahlia's continued efforts will ever see you restored to your prime. Perhaps it is beyond them. Jove knows that you showed little care for your own well-being in those desperate years of fighting the war, at the head of cornered mice facing the power of ancients. You had fought every day as if it were your last—and often, they very nearly were—and it is your body that paid the price. Perhaps it had exacted a steeper price than you ever knew, and in the end, this is just your past catching up with you.

*choice
    #I'll not mourn that power if it goes. Not when it's claimed so many lives.
        *set emotional %+ 15
        In the heat of battle, the reckoning you visited upon your enemies had been so easy to justify.
        
        [i]Kill them, or they will kill you instead.[/i]
        
        [i]They must pay the price of their betrayal. Of their wanton slaughter, committed against those caught unawares.[/i]
        
        [i]You offered them the chance to surrender. Is it your fault that they refused?[/i]
        
        Rational thoughts, in all, though that makes them no less bloody. With a wave of your hand, you felled your enemies ten, twenty soldiers at a time. Watched as the light leave their eyes, forced yourself not to think about the family they leave behind. Would it be so bad if it was you who fell in their stead? Why do you get to decide whose life is worth preserving?
        
        These thoughts haunted you long after each battle drew to a close, followed your every footstep like ghosts. Your powers kept you dancing at the edge of death, demanding a terrible blood price in exchange. And in the end, it led you to the pyre all the same.
    #No use worrying about it now. I'll deal with this if it becomes a problem.
        *set emotional %- 15
        You're nothing if not adaptive. Despite the great variety of problems that whatever divine power rules over Arvanand has seen fit to lay in your path, you've been able to overcome it—by hook, by crook, or in one niche case, by resurrection. It will certainly be a problem if your body's deteriorated enough that you lose your capacity for magic entirely, but you've seen evidence promising the contrary. First, you know that you can cast magic [i]right now[/i], as proven by your stint in the woods with ${falco} and ${yusuha}. And second, no matter how remorseful she claims to feel, Tahlia would not have brought you back had you not still been a magical juggernaut worth the cost of her spell. Likely that means that you'll measure up to your old self in time, and perhaps even exceed ${them} entirely.
        
        And should push come to shove, it's not too late for you to pick up a sword. You've seen Leon in combat plenty of times before, as well as Eli before him. Surely you've picked up [i]some[/i] wisdom from fighting alongside them and adapting your own attacks to their rhythms. With any luck, you might be able to apply it to a blade of your own.
    #Whatever it is that's happening to me, I seem to be in good hands.
        *set optimistic %+ 15
        It's only natural to expect an act of resurrection—a miracle broaching the realm of the divine—to carry with it significant complications. But in all the world, Tahlia is the only person you know of who have managed the feat. She has at her behest a theurge divorced from the auspices of Jove, as well as ancient means of healing you can only surmise is a form of arcana. It remains to be seen what she truly means to do with you, but as far as the reforging and healing of your body goes, you seem to have lucked out to land in her care.
        
        And in any case, being alive and weakened is a definite step up from being [i]dead[/i]. You still vaguely remember that cold, impassive abyss, shifting in great, laborious waves as your fragments rise and fall within its depths. You lose more and more of the memory each day—and perhaps one day, you may not remember it at all. But even in that base and unthinking form, driven by pure instinct and feeling, you had chosen to live. Unknowing the form you would take on the other side, or circumstances you would be pressed into.
        
        You breathe in the night air, feeling its pleasant chill settle in your lungs. Indeed, you could do a lot worse than this.
    #Doubtless Tahlia already knows what to do with me, and is just biding her time.
        *set optimistic %- 15
        Had Tahlia truly been motivated solely by remorse for those who fell unjustly due to Sister's actions, then the Seat would be crawling with the countless victims of her senseless war. Brave men and women who fell in defense of their homeland after a strike right in the heart of their kingdom. Widows and orphans who starved out in the cold, their homes a burning wreckage soiled by the fires of war. A king whose heart is set on making amends, on bridging the rift created by his forefathers, that the peoples of Arvanand may shed the burdens of their past.
        
        And yet, you are the only person the priestess had elected to bring back. You, a mage whose veins course with the power of ancient entities, who could snuff out the life of a squadron without breaking a sweat. You, who are descended from Arcadia's noblest clan, one that counts ${yusuha}, ${falco}, and Tahlia herself among their numbers.
        
        You would be a fool to believe her choice to resurrect you to be a seeking of redemption. There is a place in her plans for someone like you, and you have a sneaking suspicion that she means to see it filled—by hook or by crook.

*page_break

The space around you begins to fill with more and more people, who buzz in excitement at the prospect of witnessing Departure from—if the young acolyte is to be believed—the best seats in the house. In such a joyous, uplifting atmosphere, it's easy to believe that Thulrum is what it presents itself to be. A refuge for the broken and downtrodden, where they may at last lay down their burdens and live. And yet, it is difficult to forget the bones upon which this paradise rests, and the bloody path forward its leadership may yet force it to walk.

*choice
    #There must be a better way. Julius was determined to find it—and so was Leon.
        *set optimistic %+ 15
        You still remember the day your world turned upside down, when Sister had driven her talons into poor King Julius's throat, killing with him his long-held dreams of reconciliation. Or so the tale would have gone, had his brother not seized the kingdom back from Sister's clutches, and stoked the fire of his ideals anew.
        
        You know better than anyone that Leon cherishes his brother's dreams a great deal, and yearns to do right by his legacy. He saw firsthand the suffering undergone by the people of Merdel Village, risked his own life to break the plague visited upon them by Parami nobles. You had so little time to experience Param under his rule, and you've little doubt that he's now still dealing with the echoes of war—not to mention the aftermath of your execution. But despite everything, you don't doubt that his is a noble and compassionate soul. That he will prove an invaluable ally in forging a path forward to peace.
        
        You harbor no illusions that it will be easy. Many Arcadians—perhaps Tahlia herself among them—will rightfully seek vengeance against the endless list of corrupt Parami nobles and those who act under their orders. Leon may be forced to defend them to prevent a complete collapse of an already-destabilized Param, and in so doing be cast as an abettor to their crimes. Any step taken towards reconciliation carries the risk of plunging the realm deeper into chaos, to spark once more the terrible fires of war.
        
        And still, you cannot help but to dream. That one day Arvanand may lay down the burdens of its past, and at last know the mercy of a lasting peace.
    #Freedom cannot be seized through bloodless means. Thulrum does only what it must.
        Bardsongs have long since extolled the virtues of peaceful reconciliation, brought about through dialogue and diplomacy. But in the end, such fanciful ideas are not long for the real world, so fraught with vengeance and hatred, so haunted by the specters of war. In the realm of the bards, these ideals never had to contend with lethargic traditions and cruel nobles, or a society so used to the existence of an oppressed class that it would all but collapse in their absence. In the face of such dire conditions, what recourse exists for Arcadians but to pick up the sword?
        
        King Julius's dreams had been admirable; this, you do not deny. Still he was but a man afraid of rocking the boat, unable to uproot the corruption running rampant in his own kingdom. He offered olive branches and restitutions from his own coffers, but can do little to truly break the shackling of Arcadians. You understand his efforts to be beleaguered, that every proposal of redress was all but dead on arrival in the Parami noble council. But how can you blame Arcadians for refusing to be content with incremental changes across generations, when every day they die in scores under the yoke of oppression?
        
        Even knowing the terrible blood price of their war, even knowing that their efforts—directly or otherwise—claimed your own life, you cannot find it in you to blame them. Not when you know all too well the painful reality they face, and the terrible choices they must make to break away from it.
    #I can make no judgments on Thulrum's morality. My own hands are steeped in blood.
        You understand better than most the fragility of human life. You had bartered your own convictions—that your cause is just, and would lead to a better tomorrow—with the lives of countless Salantir soldiers, allowed their blood to soak the earth from Kantena to Sienan. The righteousness of your fight shone bright like a sun wherever the war led you, its rays blinding you to the slaughter. Again and again you had rained judgment upon your foes with reckless, callous abandon. As if no parent had wept when they beheld them the first time, feeling their tiny heartbeats pounding against their chest. As if no child would be cast out into the cold for lack of money, now that their guardian had fallen victim to the blood-soaked mage of the Parami resistance.
        
        You had seen honor in the carnage, once. You fought in defense of a land beleaguered by foreign invaders. Against a madwoman, a known slaughterer, who would plunge the whole of Arvanand into endless chaos were she not stopped in her tracks. It was a natural conclusion to come to: of course you would fight. What else would there be to do? Would you have the Parami fall upon their own swords, when it's plain that injustice had been visited upon them, and they had every justification to put things to rights?
        
        By swearing yourself to their cause, you had affirmed the Parami's right of resistance. It seems unjust, then, for you to deny the Arcadians theirs. You beheld thousands of Parami corpses and swore that their deaths will not be in vain. What have you to say for the countless Arcadians brutalized by Param and Salantira over the course of centuries?
    #My loyalty has always been with Param, and there it will ever remain.
        You are not blind to the plight of the Arcadians, or the righteous bones of their cause. But just as they ought be allowed to fight in defense of their people, so too should you have leave to fight for those you hold dear. You had spent years in the front lines of the Parami-Salantir war, watching your sworn siblings fall victim to Sister's machinations, be forced to watch as their blood stained the earth scarlet. You had borne the guilt of walking out of skirmishes carrying bodies two and three at a time. Green soldiers still wet behind the ears, who nevertheless threw themselves into the line of fire to save you. [i]You[/i], the light of hope who would see Param safely through to the other side. Who would defend their beloved nation, their families, to the bitter end.
        
        You do not have it in you to betray their faith, to dishonor their sacrifice. They believed in that vision of Param, noble and knightly, fighting tirelessly in the name of justice. And for all that in the end they had tied you to the pyre, you know that they do so with heavy hearts, believing there to be no alternatives. Leon, Saine, Ilya—they have always been good of heart, strong of will. The sort of people who can guide Param, and indeed Arvanand, to a better future. And you would be glad to one day fight in defense of their dreams once more.
    #Hatred runs deep on either side. I don't know whether a path to peace exists.
        *set optimistic %- 15
        It is the unfortunate nature of humans to be hypocrites. Wrongs committed against them are the height of villainy, senseless and brutal, while their own transgressions are justified, sometimes even noble.
        
        It is justice to lift one's blade in the name of a kindly king who dreamed only of peace. It is justice to seek to strike back against the snakes who invaded the kingdom at its heart, who slew knights before they could so much as draw their blades.
        
        It is justice to seek to break free from the yoke of oppression, through the only means one's oppressors have left available. It is justice to seek the death of a dithering king wringing his hands, play-acting at savior as hundreds continue to die unjustly at his people's hands.
        
        And what is left behind when the smoke clears, and the swords and pitchforks are finally laid to rest? Mounds of bodies on either side, leaving behind grieving mothers and orphaned children, nursing a burning desire for vengeance in their hearts. One that can only be slaked by the blood of their loved ones' murderers.
        
        And so the cycle begins anew, and true peace hovers more distantly still in the horizon.
        
*page_break

You heave a long sigh, letting the thoughts stew over in your mind as you gaze out onto the open plains below. The knoll has grown dense with people now. Thousands of them claiming their spots, pouches in hand, flickering lanterns set on the ground. It helps put things in perspective. So many have lost a loved one over the course of a mere year. A disproportionately high amount, as compared to Thulrum's fledgling population. Old age can only claim so many at a time. The specters left behind by a lifetime's worth of oppression knows little of such limitations.

Out near the center of the field, a woman in priestly garbs calls out to the senders of light. Her voice must have been very loud, for the din of it carries—albeit at the volume of a passing breeze—to where you stand, at the top of the tower. It's beyond you to make sense of her words from this distance, but it must have been some sort of emotional address, perhaps religious in nature, for the crowd around her listens with rapt attention.

A solemn air pervades the landscape at the tail end of her speech, and all around you the other onlookers speak in hushed tones that the time has finally come. The priestess spreads out her arms on either side of her, and all round the gathering's perimeter, other Ishavak priests—twenty or thirty strong, by your estimation—mirror her pose in turn. Trails of mana begin to percolate their form, and in a display that absolutely stuns you, a single magic circle expands to cover the entire breadth of the knoll, with the ground upon which the priests stand becoming points of origin. The runes bleed into one another in an intricate tapestry, among them many esoteric combinations who you yourself have barely ever used, culminating in a whole whose meaning escapes you recognition.

Remarkably, the lines of the spell appears to bend and adjust so that they run through every lantern which touches upon the grass, and yet fails to lose the spell's intended effect. The air thrums with the song of mana melding into one another, and with a brilliant flash of light the spell comes alive.

*page_break

Taking that as a signal, the mourners on the knoll slide their lanterns' top side open and feed the ashes in their pouch directly into the flame. The Everfires flicker into a hundred different colors as they gobble the ashes, interacting with the spell circle at their base to unleash plumes of colorful mist into the sky.

It is a breathtaking sight. The mist lifts upwards in a chorus, thick and dense, like smoke billowing from a thousand infernos. They fill the span of the sky with a languid haze, hues twisting and mixing with each other as they blot out the night sky, creating translucent clouds shot through with a hundred different colors. You watch in awe as they stretch across the sky, retaining their color even as they spread and thin out, veiling the stars at the edge of your vision.

And it is there that they meet with another, alien hue, one that you [i]know[/i] does not belong the moment you catch sight of it.

You turn your head towards it with furrowed brows: thick gray plumes and orange light, the brilliance of its shine piercing through the colorful clouds.

It takes a moment for you to recognize what it is.

And it takes another for the screaming to begin.

*page_break
*goto_scene Checkpoint_6-3