*comment Chapter 1 - New Leaf
*image header_c1.png center Chapter One, New Leaf. The gentle winds whisper of change.
*page_break

"Thank you," the innkeep breathes, her voice hoarse. "For the first good sleep I'll have in weeks."

The heavyset woman, likely in her fifties, places a small pouch of coins on the table. There’s a slump to her posture, puffiness around the eyes, grease in her hair that she hasn't washed out. Even if you hadn't heard her muffled sobs through the thin walls at night, you'd still be able to tell she's been spending her nights in tears.

Losing one's son to bandits tends to do that to a mother. You've seen too many of them on the road, and you can only hope the swift end you brought upon his murderers can help her cope with the grief.

The pouch falls over from its own weight, spilling silver coins onto the wooden table. Less than bandit exterminations normally go for, but far more than a haggard, grieving innkeep ought be able to afford.

*choice
    #"It's gonna be tough work running this place alone, ma'am. You should keep the money."
        *set noble %+15
        *set prenoble %+ 15
        *temp innfavor true
        She looks up at you, startled and almost angry, but stills at the sight of the empty inn. Her teeth bite down on her lower lip as she looks down in shame.

        "You done give my son his peace, and I can't even give you some change." She spends some time looking at her lap before standing up, sniffling. "Stay the night, at least. I'll fix you a hot meal. And…thank you."

        You give her a faint smile and nod as she moves out of sight.

        Leaning back against the chair, you will yourself to feel no regrets over the decision. This will likely mean several nights spent making camp on the Esteram Forest, sleeping on cold, uneven ground and hunting beasts for meat and coin. Not exactly how you wanted to spend your week, but you'll be fine. You're not sure you could say the same of the innkeep.
        *goto inn1

    #"Thank you. May he find peace in Jove's embrace."
        *set noble %-15
        *set prenoble %- 15
        *temp innfavor false
        You nod at the innkeep solemnly and take the payment you are owed. It feels heavy in your pocket, heavier than it should—but a contract is a contract, and reckless generosity won't fill your stomach or pay for your ale.

        "May he find peace," she echoes, glazed eyes gazing out into the rainy night. You don't comment on her pointed exclusion of the deity's name. "Feel free to stay the night. This is a storm brewing, and I've got nothing but empty rooms anyhow. Help yourself."

        She rises and moves into the kitchen, presumably to fix some dinner for you both. You resolve to pay for the room and food, at least. The inn had shut down to allow her space to grieve, and now she must get it back up and running with the only help she had around now six feet under.
        *goto inn1

*label inn1
*page_break You head upstairs.

You push past the door of your modest accommodations, stowing away your belongings and stripping out of your blood-soaked clothes. You were lucky in this particular hunt—the bandit foursome were asleep when you found them, and despite being outnumbered you sustained no wounds that a couple bottles of potions and a nice long bath couldn't undo.

You fill out the large wooden tub in the center of the room with water, sprinkling in a generous helping of cleansing potion. The bath soon blooms with a generous lather, and you begin the tedious process of washing out the grime you've accumulated over the past few days.

Starting from the top, you work out the tangles of your…


*choice
  #long…
    *set hairlength "long"
    *goto hairdone
  #shoulder-length…
    *set hairlength "shoulder-length"
    *goto hairdone
  #bobbed…
    *set hairlength "bobbed"
    *goto hairdone
  #short…
    *set hairlength "short"
    *goto hairdone
  #What tangles? I'm buzzed!
    *set hairlength "buzzed"
    *goto buzzhairdone
  #What tangles? I'm bald!
    *set hairlength "bald"
    *goto baldhairdone


*label hairdone
Starting from the top, you work out the tangles of your ${hairlength}...

*choice
  #black…
    *set haircolor "black"
    *goto colordone
  #brown…
    *set haircolor "brown"
    *goto colordone
  #blond…
    *set haircolor "blond"
    *goto colordone
  #ginger…
    *set haircolor "ginger"
    *goto colordone
  #red...
    *set haircolor "red"
    *goto colordone
  #auburn...
    *set haircolor "auburn"
    *goto colordone
  #gray…
    *set haircolor "gray"
    *goto colordone
  #white…
    *set haircolor "white"
    *goto colordone

*label buzzhairdone
Oh, of course! You have at the gritty surface of your head, slowly but surely scrubbing out the sticky stains of dried blood from your…
*choice
  #black…
    *set haircolor "black"
  #brown…
    *set haircolor "brown"
  #blond…
    *set haircolor "blond"
  #ginger…
    *set haircolor "ginger"
  #red...
    *set haircolor "red"
  #auburn...
    *set haircolor "auburn"
  #gray…
    *set haircolor "gray"
  #white…
    *set haircolor "white"

You scrub out the sticky stains of dried blood from your ${haircolor} hair. The day-old spots was harder to remove than you had initially thought, but a bit of persistence and magical lather did the trick.
*goto eyechoice

*label baldhairdone
Oh, of course! You have at the smooth surface of your head, slowly but surely scrubbing out the sticky stains of dried blood scattered throughout.
*goto eyechoice

*label colordone
Starting from the top, you work out the tangles of your ${hairlength} ${haircolor} hair.

The clots of dried blood were difficult to rinse out, but a bit of persistence and magical lather did the trick.
*goto eyechoice


*label eyechoice
You look at your reflection in the pool of water as you rinse your face of oil and impurities. Staring back at you were a pair of…
*choice
  #black…
    *set eyecolor "black"
  #brown…
    *set eyecolor "brown"
  #blue…
    *set eyecolor "blue"
  #green…
    *set eyecolor "green"
  #gray…
    *set eyecolor "gray"
  #hazel…
    *set eyecolor "hazel"
  #violet...
    *set eyecolor "violet"
  #golden...
    *set eyecolor "golden"
  #red…
    *set eyecolor "red"

Staring back at you are a pair of ${eyecolor} eyes, pulsing with a dim magical glow in the poorly-lit room.

It's time to finish up. Gathering up all that remains of the lather, you scrub away at the layers of grime covering your…

*choice
  #mahogany…
    *set skintone "mahogany"
  #dark brown...
    *set skintone "dark brown"
  #warm brown...
    *set skintone "warm brown"
  #olive…
    *set skintone "olive"
  #tan…
    *set skintone "tan"
  #light…
    *set skintone "light"
  #pale…
    *set skintone "pale"

You scrub away the layers of grime covering your ${skintone} skin. The sweat and dirt melts easily against the lather, pooling into a brown-black puddle at the bottom of the basin.

Rising up from the bath, you take a moment to inspect the entirety of your…
*choice
  #average…
    *set build "average"
  #gangly…
    *set build "gangly"
  #stout…
    *set build "stout"
  #curvaceous...
    *set build "curvaceous"
  #muscular…
    *set build "muscular"
  #lean…
    *set build "lean"
  #slender...
    *set build "slender"
  #heavyset…
    *set build "heavyset"

*set appearanceset true
*set gender "nonbinary"

You take a moment to inspect the entirety of your ${build} body. Satisfied with the state of hygiene you've achieved, you exit the room and slip into your nightclothes.

The innkeep knocks on your door, later that night, and hands you a bowl of vegetable stew. It is a simple dish, but warm and well-seasoned. Certainly better than anything else you've eaten the past week. You finish your meal and tuck in for the night. Tomorrow, your journey begins anew.

*page_break Sleep overtakes you.

[i][b]It burns.[/b][/i]

[i]Red-hot fire sears like molten daggers in your veins as the circle crackles to life around you. You open your mouth to scream, to beg for mercy, but your throat finds only air. Markings materialize all over your small, fragile body, each brand burning through flesh to carve itself upon your skin. You writhe and spasm against the linoleum floor. Your tormentor does not care.[/i]

Kill me[i], you plead with your eyes. [/i]Kill me, please.

[i]A sneer, a new spell cast. Magical smoke billows around you, purple, thick as poison. You feel your head splitting open, and your fingers are claws upon your temple—anything, anything to distract from the pain—[/i]

[i]Eyes rolling, you slip once into the dark's embrace, and are yanked back; your skin boils, twists upon itself—[/i]

*page_break [i]And it stops.[/i]

[i]"Disappointing." He spits, and is gone.[/i]

[i]Like a dam breaking, your tears flow freely at last, your muscles still throbbing from the torturous pain. Each sob wracks your body and rips through your insides anew.[/i]

[i]A warm hand against your temple. "There, there. It's over..."[/i]

*label choosename
*choice
  #...Agria.
    Does Sister call you Agria?
    *choice
      #Yes.
        *set fname "Agria"
        *goto nameset
      #No, that's not it.
        *goto nameq
  #...Alexis.
    Does Sister call you Alexis?
    *choice
      #Yes.
        *set fname "Alexis"
        *goto nameset
      #No, that's not it.
        *goto nameq
  #...Cethann.
    Does Sister call you Cethann?
    *choice
      #Yes.
        *set fname "Cethann"
        *goto nameset
      #No, that's not it.
        *goto nameq
  #...Ein.
    Does Sister call you Ein?
    *choice
      #Yes.
        *set fname "Ein"
        *goto nameset
      #No, that's not it.
        *goto nameq
  #...Fey.
    Does Sister call you Fey?
    *choice
      #Yes.
        *set fname "Fey"
        *goto nameset
      #No, that's not it.
        *goto nameq
  #...Hel.
    Does Sister call you Hel?
    *choice
      #Yes.
        *set fname "Hel"
        *goto nameset
      #No, that's not it.
        *goto nameq
  #...Innes.
    Does Sister call you Innes?
    *choice
      #Yes.
        *set fname "Innes"
        *goto nameset
      #No, that's not it.
        *goto nameq
  #...Leith.
    Does Sister call you Leith?
    *choice
      #Yes.
        *set fname "Leith"
        *goto nameset
      #No, that's not it.
        *goto nameq
  #...Rune.
    Does Sister call you Rune?
    *choice
      #Yes.
        *set fname "Rune"
        *goto nameset
      #No, that's not it.
        *goto nameq
  #...Sevan.
    Does Sister call you Sevan?
    *choice
      #Yes.
        *set fname "Sevan"
        *goto nameset
      #No, that's not it.
        *goto nameq
  #...Yuval.
    Does Sister call you Yuval?
    *choice
      #Yes.
        *set fname "Yuval"
        *goto nameset
      #No, that's not it.
        *goto nameq
  #...something else.
    *label inputname
    What does Sister call you?
    *input_text fname
    She calls you $!{fname}?
    *choice
      #Yes.
        *set fname "$!{fname}"
        *goto nameset
      #No, she calls me something else.
        *goto inputname


*label nameq  
What does Sister call you?
*goto choosename


*label nameset
[i]A warm hand against your temple. "There, there. It's over, ${fname}."[/i]

[i]"S-sister," you manage through your teeth. "It h-hurts."[/i]

[i]Her eyes are rubies against the magic circle's glow, her own markings an angry crimson on her milky skin. "I know. I know, it will get better."[/i]

[i]You point at her runes, the ebbing glow hypnotic. "Y-you," a groan, a sob, "hurt."[/i]

[i]She smiles, almost serenely, but you catch the quiver in her lips, her eyes narrowing imperceptibly. "I am okay."[/i]

[i]You nails dig into the skin of her arm. "Eli. Is Eli here?"[/i]

[i]Sister shakes her head.[/i]
*choice
    #"The doctor took him away."
        *set geli "male"
        *set elias "Elias"
        *set ehe "he"
        *set ehim "him"
        *set ehis "his"
        *set etheirs "his"
        *set ehes "he's"
        *set evar 1
    #"The doctor took her away."
        *set geli "female"
        *set elias "Eliana"
        *set ehe "she"
        *set ehim "her"
        *set ehis "her"
        *set etheirs "hers"
        *set ehes "she's"
        *set evar 2
[i]"$!{ehe} won't be back for some time. No healing, not now."[/i]

[i]A new wave of pain erupts, setting your insides on fire once more. You clench your teeth to stop yourself from heaving. "S-sister! A-ack!"[/i]

[i]"I'll make it go away," she whispers, and her markings blaze to life. She winces, black hair matted with sweat falling over her face, and mutters a spell. "Sleep, ${fname}."[/i]

[i]The last thing you remember are her eyes, red as blood, and her gentle palm over your eyes.[/i]

*page_break [i]You fall.[/i]

You jerk awake in an empty room—[i]soft, clean sheets, thank Jove[/i]—rather than the cold hard flooring of your memories. Sweat beads down your forehead in bullets as you will for the panic to settle. You're in [i]Param[/i], not Salantira, and you are not the helpless little child you were nine years ago. No one will harm you now. No one [i]can[/i].

Almost on instinct, you roll up the sleeves of your nightshirt. The markings are barely visible nowadays, a dull, imperceptible overlay just a shade lighter than your skin. Your fingers trail along their length, from the slender patterns snaking along your forearm to the complex, layered runes covering your shoulders.

Your heart sinks with dread as your hand sweeps across the telltale friction of fraying seals. This is bad—you had planned to make for Sienan, next, but that's some three months of travel and the highway is nothing if not dangerous. You're bound to use your magic, at some point, and thinking about the strain it would put on your weakened seals gives you a headache.

*page_break

There's no two ways about it. You have to stay in this town until the seals repair themselves—that's one whole year, if you're lucky. You restrain the urge to bang your head against the bedpost. There's no place for you to stay in this neck of the woods, no guild or magic workshop that can help get you set up with some income as you wait your seals out. No one you could ask for help, either...

[i]Hold on[/i], you think with a sudden clarity. [i]That might not be entirely accurate[/i].

You [i]do[/i] know someone in this town. Someone who conveniently has a lot of rooms to spare…and, given recent events, might be predisposed to help you out a bit as you regain your footing.

You eye the rising sun out on the horizon and swallow. It seems your next step is clear.

*page_break

"So that's how it is," you sigh pitifully, closing out your hastily-woven tale. "I'll have to stay in this town for the next twelve months."

The innkeep looks at you dubiously. The eye bags enhance the effect, you note. "Aye, I do hear mages need to rest for long if their magic goes haywire. But a year?"

Well, she's got you there. Recovery from mana exhaustion is typically a week-long affair, if even that.

*choice
    #Be frank with her, sticking as close to the truth as you can.
        *set charming %-15
        *set precharming %- 15
        "I have an illness."

        "Do you now."

        "I've had it for a long time." You pause for a bit, wondering how to avoid mentioning the seals; you settle on a little white lie. "If I overuse my mana, my magical ducts shortcircuit. They become damaged, instead of strained. The recovery is a lot longer, then."
    
        *if (innfavor)
            There's something soft in her gaze as she regards you. You daresay she almost looks…protective?
            
            "Well, what the heck. You're a good kid, and you done right by me. Stay as long as you like, no charge."

            "Oh. That's...generous. But you're in a tight spot too."

            "I imagine yours is a bit tighter, after doing a job and not taking the pay."

            She's got you there, but you've thought about this eventuality. "I talked to the crier this morning, he said Leaf End is always hiring in places. I could—"

            "Then work here, if you must," she huffs, holding a hand up. "I could use someone to wait tables and run errands. My knees ain't what they used to be."
      
            You are stunned by the proposition, for a beat. But if you tally up the weekly cost of room and board, and run that against the average wage of a gofer...it's still generous to your end of the bargain, but not by too much. 
            *goto contconvo
        *else
            She holds your gaze for a while. It's clear that she doesn't completely buy it. "You don't got a bounty on you?"

            "No, ma'am," you quickly reassure her. [i]Not in this country, anyhow.[/i] "And the coins you paid me could put me up for a bit—I just need to be sure you won't throw me out if I take a while to get set up."

            She nods thoughtfully. "That could cover the first month easy, meals and all."

            "Right. And I talked to the crier yesterday, he said Leaf End is always hiring in places. I'm sure I could—"

            "Well, he ain't wrong. I'm hiring, for one," she cuts in. "A lot of work goes into an inn, and I ain't as young as I used to be. My husband used to do the errands and the heavy lifting, then my son. 'Course, both of them are dead and buried now."

            There's something distant in her eyes as she trails off. The silence is palpable, but short-lived.

            "Half of yesterday's pouch," she offers. "I'll need that much to get the place back up and running. Beyond that, just wait tables and run errands for me, and you can stay as long as you like."
            *goto contconvo  

    #Try to get in her good graces. Say you've grown attached to the town.
        *set charming %+15
        *set precharming %+ 15
        "Well, it's not just the mana," you lie, trying to appear sheepish. "I've been looking to take a break from adventuring for a while, and this town looks to be the perfect place for that."

        "Does it now. And just what about Leaf End done caught your attention?"

        "It's, ah, quaint. Lots of wind, and I rather like the quiet."

        She snorts, almost inaudibly. "The quiet, huh?"

        You nod sheepishly, nervously awaiting her verdict.
        *page_break

        *if innfavor = true
            "You can keep your secret, so loosen up, whelp," she huffs, almost amused. "You're a good kid, and you done pay me already with the coins you returned. Stay as long as you like."

            "Huh? Wait, that barely covers a month, not a year!"

            "Aye, then the rest will come from the peace you gave my son. That's worth more than a wee coin pouch, I reckon."
            
            "Oh. That's...generous. But you're in a tight spot too."

            "I imagine yours is a bit tighter, after doing a job and not taking the pay."

            She's got you there, but you've thought about this eventuality. "I talked to the crier this morning, he said Leaf End is always hiring in places. I could—"

            "Then work here, if you must," she huffs, holding a hand up. "I could use someone to wait tables and run errands. My knees ain't what they used to be."
      
            You are stunned by the proposition, for a beat. But if you tally up the weekly cost of room and board, and run that against the average wage of a gopher...it's still generous to your end of the bargain, but not by too much.
        *else
            "You're a couple decades too young to be pulling a fast one on me, whelp. I know you're keeping a secret," she huffs. "But I don't forget that you done give my son his peace. So long as there ain't a bounty on your head…"

            "Absolutely not, ma'am," you quickly reassure her. [i]Not in this country, anyhow.[/i] "And the coins you paid me could put me up for a bit—I just need to be sure you won't throw me out if I take a while to get set up."

            She nods thoughtfully. "That could cover the first month easy, meals and all."

            "Right. And I talked to the crier yesterday, he said Leaf End is always hiring in places. I'm sure I could—"

            "Well, he ain't wrong. I'm hiring, for one," she cuts in. "A lot of work goes into an inn, and I ain't as young as I used to be. My husband used to do the errands and the heavy lifting, then my son. 'Course, both of them are dead and buried now."

            There's something distant in her eyes as she trails off. The silence is palpable, but short-lived.

            "Half of yesterday's pouch," she offers. "I'll need that much to get the place back up and running. Beyond that, just wait tables and run errands for me, and you can stay as long as you like."
*label contconvo

"That…sounds perfect. Yes, I'll take you up on that."

"Well, then. Glad that's settled." She rises from her chair, dusting her apron off. "The inn will have to reopen within the week, if we've any hope of staying afloat. Take the day if you're still feelin' those wounds, but be down here tomorrow mornin', bright and early, you hear?"

*if charming >= 50
    "You got it, ma'am," you say, grinning wide and holding your hand out. She looks at you the way one might look at a dog chasing its own tail, but shakes on it all the same.

    "That's Aunt Bess to you, now. Everyone 'round here calls me that. Pleasure to be workin' with you, whelp."
*else
    You nod in affirmation, satisfied with the arrangement, and hold out your hand. She gives you a curious look, but shakes on it all the same.

    "Call me Aunt Bess, from here on out. Everyone 'round here does. Pleasure to be workin' with you, whelp."

*page_break

As promised, Aunt Bess starts putting you to work the very next day. You run around town from the early hours in the morning, placing orders and purchasing stock for the pantry. In the process, you notice that Aunt Bess seems to be a very well-liked figure in town; whenever you let slip her name or the Bellgrove Inn in conversation, you end up with an extra bag of flour ("On the house, for the grievin' ma. Take good care of her, will you?") or shopkeeps that empathetically insist you only pay for the goods when the inn hits better times.

In the end, you were saddled with far more produce and cleaning supplies than the inn's funds rightly ought to have accounted for. Though your back and arms suffer for it, seeing the town rally around Aunt Bess makes the entire ordeal rather fulfilling.
*page_break

The inn opens its doors after two days of preparation and steadily builds back up to its former patronage. Before the season is out, the rooms are all too often booked out and the lower floor had all but become a tavern. Aunt Bess began regaining some of her color and humor, in those first few weeks. You think the rowdy patrons and the workload did her some good.

Your life steadily settles into a routine—nights working the floor of the makeshift tavern, and twice or thrice a week you'd run around town on a restock run. That leaves you with quite a bit of free time—time you'd typically spend practicing magic, but you don't want to push your luck with the seals. You do a bit of light practice every now and again, but before long it is apparent that finding a new pastime would be prudent.

And so you do.

*choice
    #I joined a performance group.
        *set charisma 75
        *set profession "charisma"
        *achieve charismaleaf
        Sofiya and Rean were a performing duo when they first came to Leaf End. Sofiya would dance for tips to the music Rean strummed on his lute, and they would go wherever crowds could be found. Bellgrove Inn happened to be their venue of choice one night; as the kitchen closed and you doled out the last of the ale, the pair asked for volunteers to help them make merry well into the night.

        It was a surprisingly popular offer. Drunken travelers took turns butchering bardic classics to the laughter of the crowd, while the younger women gyrated themselves rather scandalously to the music, egged on by Rean's roguish charm.

        "Let's hear it for our barkeep!" Sofiya yelled, and suddenly she is beside you and pulling you to the center of attention. "Come on then, don't be shy. We'll back you up." Behind her, Rean gave you a thumbs up.

        Put on the spot, your first instinct was to...
        *choice
            #...sing. What I lack in training, I make up for in raw talent.
                *temp singdance "sing"
                It was an old bardic classic, one you knew like the back of your hand. Rean was quick on the uptake, seemingly energized by the first singer of the night to actually hit the notes. Sofiya laughed and sprang to action beside you, skirt swaying and feet tapping away, and with renewed vigor the crowd sang along to the song until the very last note.
            #....dance. After all, ballroom steps and combat stances share a surprising amount in common.
                *temp singdance "dance"
                You whisper the name of a duet routine to the pair, and they seem startled for a bit, before agreeing with wide smiles. Rean launched into a familiar staccato melody while Sofiya leaped into action, leaning close to you as her skirt hikes up scandalously with each of her elaborate leg movements. Your hands were on her hips, and hers in the tangle of your hair, and you both hit the beats in perfect unison. The crowd hooted and hollered at the suggestive performance, and they clapped along to the rhythm until the very last note.
        *page_break
        Sofiya and Rean approached you after the inn cleared, asking you to perform with them for the duration of their stay. You agreed to join them whenever the inn could spare you.

        Though your
        *if (singdance = "sing")
            singing was relatively on par with Rean's,
        *else
            dancing was relatively on par with Sofiya's,
        you soon learned that the more important skill for a performer to have was [i]presence[/i]. Sofiya and Rean were both masters at captivating their audience—from friendly banter to making the right expressions, they commanded attention whenever they took the stage. And by the time you parted ways some two months later, these skills had come to you as naturally as breathing.
    
        *page_break
        Several days after their departure, you caught Aunt Bess as she cooked in the kitchen, humming and gyrating her hips in a move that looked suspiciously reminiscent of Sofiya's trademark jig. You dropped the batch of produce you'd been carrying to give her a hearty round of applause; she turned a dangerous shade of red before chasing you out with a frying pan.
        *goto timelapse
    #I frequented the local book shop and devoured half of their collection.
        *set learning 75
        *set profession "learning"
        *achieve learningleaf
        It was not a particularly big shop, admittedly. Still, their collection was much more than you'd expected to find in a backwater town like Leaf End, with a sizable chunk of its population illiterate. The shopkeep was a little old lady with a kind smile and horrible eyesight; she welcomed your frequent company, letting you raid her shelves even on days when you didn't purchase anything.

        The time you spent in that quaint little book shop were perhaps the most peaceful days of your life, and certainly among the most instructive. You learned that the shopkeep was something of an established academic in her heyday, having graduated from a famed institute in the big city and spending decades as the personal scholar of a marquess. When she wasn't dozing off on the shop counter, she'd be all too happy to entertain your queries on Parami history and debate you on the finer points of deontology.

        She [i]did[/i] tend to get carried away in her lectures once she got started, but if she had noticed you mentally checking out in the middle of her tirades, she never did say anything of it.
        *page_break
        At the inn, your new pastime appeared to have piqued Aunt Bess's interest, and so you offered to teach her the alphabet. She was a quick learner at first, but after a week spent being stuck on the (infamously difficult) Parami quad-vowels, she haughtily declared the whole issue a waste of her time and stalked away, huffing.

        Yet on certain nights you'd be awakened by the sound of her rifling through your bookshelves, in a manner only she could think of as sneaky. You chuckled to yourself under the sheets as she walked away with her new acquisition, victorious.
        *goto timelapse
    #I became a local informant for a visiting spymaster.
        *set profession "intrigue"
        *set intrigue 75
        *set deacon true
        *achieve intrigueleaf
        Deacon Thomas, he had called himself, though you got the distinct impression that he was no man of Jove's.

        Your work for him involved sniffing rumors and running messages to nearby locales, often taking you out of Leaf End for days at a time. Thankfully, he paid plenty enough for you to hire some of the town's youth to cover for you at the inn every now and again.

        Through the months of skulking about you did for the good Deacon, you picked up quite a bit of the trade. Your steps were now quiet as the night, and lies would roll off your tongue fluid as water. You considered the experience instructive. Certainly a mage in your situation could do with a little bit of cloaks and daggers.

        Aunt Bess wasn't too happy with the arrangement, though. She'd often complain that your seasonal replacements were slow and clumsy at their work, saying the Deacon cheated her out of the only good errand-runner in town. You'd only laugh at her dramatics, and if your soup was a touch too salty every time you came back from a mission, you said nothing of it.
        *goto timelapse

*label timelapse

And just like that, your life in Leaf End falls into a quiet rhythm, and time flies by in the blink of an eye.

Spring gives way to summer.

*page_break

"Set it down by the kitchen counter, there's a good 'un."

*if (charming >= 50)
    You fall into a heap on the floor with a dramatic sigh. "This is the eleventh sack today. You're killing me here."

    A snort, but not without mirth. "Earn your keep now. There's one more trip to make."

    "Don't you have anything less...hands-on I could do? Accounting? Baking? I make a mean meat pie."

    "Better than mine?"

    "...No."

    "Off you go, then."

    "This is slavery," you sniff, and she laughs after you as you leave.
*else
    You glare at her pointedly, sweat beading down your face. "This is the eleventh sack today. You're enjoying this."

    "I don't know what you're insinuating, whelp. I'm just a poor old lady with a bad back."

    "Not an excuse for this...torture. And exploitation. I could get you hanged, you know."

    "Ha! Ain't we dramatic today."

    "No sympathy, no remorse? You must be the devil herself."

    "Of course, [i]dear[/i]. Next sack of potatoes, please."

    "This is slavery," you hiss, and she laughs after you as you leave.

Summer gives way to fall.
*page_break 
"I haven't put on weight, have I?"

*if charming >= 50
    "You look lovely."

    "That ain't an answer, whelp."

    You look up from the tome and offer her your most blinding smile. "You look lovely, [i]hag[/i]."
*else
    "Mm."

    "Oi! I asked a question, whelp."

    You look up from the tome and smirk, as insufferably as possible. "I don't answer to demons, [i]hag[/i]."

The skillet very narrowly misses your head.

Fall gives way to winter.

*page_break

*if (charming >= 50)
    "You're like night and day, you know."

    "Huh?"

    "You and my son."
*else
    "You remind me of him, you know."

    "Huh?

    "My son."

"Oh."

*if charming >= 50
    "He was the quiet sort. 
*else
    "He was the quiet sort, like you.
Got it from his dad, I reckon. I kept telling him to get out more, find some friends his own age, go traveling. He'd only snort and go to chop firewood in the back. Said I acted all tough but he knew I'd get lonely."

*if charming >= 50
    "He sounds like an amazing guy."
*else
    You say nothing, but make sure to look her in the eyes to let her know she has your attention. 

She is silent, for a beat, and when she speaks again her voice has grown hoarse.

"Ha...he was a fool of a boy, to get between that dagger and me. I'm goin' on sixty, and I've got a bad heart, one foot in the grave already. He had his whole life left to live, a girl he fancied. Why should he be the one to kick the bucket?"

A choke, a sob, and the dam breaks. "Why s-should he?"

This being the first time you've seen her cry since your first night at the inn, the sight catches you terribly off-guard. 
*if charming >=50
    For the first time in a long time, you find that you have nothing to say. Tentatively, you step around the table and give her a hug, and she trembles like a leaf in your arms until the early hours of the morning.
*else
    You rack your brain for comforting words, but come up empty. For the first time in a long time, you wish you were better at conversation. As it is, you tentatively step around the table to give her a hug, and she trembles like a leaf until the early hours of the morning.

Winter gives way to spring.

*page_break

"So this is it, huh."

Aunt Bess stands in the inn's doorway, arms crossed and eyes hard.

"There, Aunt Bess, don't be sad. You'll come 'round again, won't you, ${fname}?"

The reassurance came from Kadan, the nice young man you scouted from a town over—your replacement, as you'll officially no longer reside in Leaf End as of today. You nod non-committally and look Aunt Bess in the eye.

*choice
    #I try to lighten the mood as I say my goodbyes.
        *set charming %+15
        *set precharming %+ 15
        "I'll be leaving now, Aunt Bess," you say, taking hold of her hands. "Take your medicine regularly, alright? You're absolutely intolerable when your migraine's coming on. You'll drive away all the patrons again, and Kadan too for good measure."

        She chuckles, sounding resigned. "You always did have such a mouth on you. The way you speak to me, you'd think [i]I[/i] was the one squatting in [i]your[/i] inn."

        "S-Squatting!" you say, holding a hand over your heart in mock offense. "I resent that. I pulled my own weight, you know. You really did put me through hell this past year."

        "You always were the dramatic sort. I'll miss that."

        A beat of silence. "I'll miss you too, you old bat."

        "You'd better, with what I'm about to give you," she grins, and hands you a stack of thick, leather-bound books.
        *goto besstome
    #I knew I'd have trouble with words today, so I've prepared a gift in advance.
        *set charming %-15
        *set precharming %- 15
        You pull it out from your travel sack: 
        *if charisma = 75
            a delicately painted lute, with an inscription on its back. [i]From ${fname}, Sofiya, and Rean: to the best innkeep in Param.[/i]

            "Something to remember us by."

            She huffs, dew forming on her eyes. "When you left on your 'urgent business' last month...?"

            "Mm. I heard they were passing by Tyebrook. That's the same lute Rean played here, last year."
        *elseif learning = 75
            a worn, leatherbound storybook—Theseus the Brave, the first book she had ever borrowed on those midnight raids, all those months ago.

            "Something to remember me by."

            She huffs, dew forming on her eyes. "You knew all along, huh, brat."

            "Mm. You're not exactly subtle, rifling through my shelves every other night."
        *else
            an enchanted snowglobe, the floating crystals within shimmering in brilliant hues. Kadan's jaw all but drops, and you preen a little at the appreciation. It's little more than a trinket, but even nobles covet one of these. If the inn were ever to fall upon hard times, this would make for a fantastic safety net.

            "Something to remember me by."

            She huffs, dew forming on her eyes. "You stole this, didn't you."

            "Earned it," you grin, reassuring her. "It was the Deacon's, once. I asked for it as payment for the last mission."
    #My words die in my throat. I'm trying really hard not to cry.
        *set emotional %+ 15
        *set preemotional %+ 15
        Aunt Bess's lips quirk up into a knowing smile as she sees you struggle for words. "Don't go crying on me, now.
        *if (intrigue = 75)
            I know that damn deacon taught you better than that."
        *elseif (intrigue = 75)
            I knew hanging around that old bookworm would've made you soft."
        *else
            I should've known that crybaby Sofiya would rub off on you."
        
        You breathe through your mouth, slow and deliberate, willing the sting in your eyes to go away. "Sorry, Aunt Bess. I really thought I could hold it in today."
        
        "You always were the dramatic sort," she says, not unkindly. "I'll miss that."
        
        Your head is in your hands now, and the words are muffled where your lips brush against the palms. "I'll miss you too."
        
        "You'd better, with what I'm about to give you."
        *goto besstome
    #I thank her cordially and make ready to leave. It's been nice while it lasted.
        *set emotional %- 15
        *set preemotional %- 15
        Aunt Bess chortles at your demeanor, shaking her head. "Can't pretend to be sappy for one day, brat? The way you treat me, you'd think [i]I[/i] was the one squatting in [i]your[/i] inn."

        "Squatting," you say, drawing out the vowels for dramatic effect. "I resent that. I pulled my own weight, you know. You really did put me through hell this past year."

        "You always were the dramatic sort. I'll miss that."

        A beat of silence. "Thanks for everything, Aunt Bess."

        "You had better be grateful, brat, with what I'm about to give you," she grins, handing you a stack of thick, leather-bound books.
        *goto besstome
    
"Ha...well, thank you. It's thoughtful. I didn't know you had it in you."

"Nothing but the best for Aunt Bess."

"And nothing but the best for my brat, either," she says, handing you a stack of thick, leather-bound books.

Your eyes widen at the sight of the rare manuscripts. They are precious tomes, one and all, and in due time you'll no doubt be able to extract valuable knowledge from each one. But at present, the one that piques your interest the most is...

*label besstome
*choice
  #Old Saarta's Compendium of Magicked Materials, Vol. VIII
    Old Saarta is said to be the greatest alchemist to ever live. He crafted potions that are still in use today, despite the man himself having croaked for some fifty years now. His series of compendiums remains the gold standard of academic insight into the field of alchemy, but the later, more complex volumes are seldom seen outside the halls of royal academies and private noble collections. For a copy to find its way to Leaf End...Aunt Bess must have strained herself.

    You've browsed through the earlier volumes of Saarta's Compendium, and it was still a challenge to process the various detailed instructions on brewing concoctions and synthesizing magical materials. Alchemy is a tremendously flexible art, capable of performing magical feats of all persuasions. However, its unfortunate reliance on material availability presents a constraint rarely encountered in other schools of magic.

    It is apparent to you that studying this tome will be a tremendous struggle to those without advanced knowledge in alchemy. Are you one such mage?
    *choice
      #Yes, alchemy is my specialty.
        *set specialtyset true
        *set specialty "Alchemy"
        *set alchemy %+50
        *set specialvar 2
        *goto tome1
      #No, I'm best at something else.
        *goto tome2

  #The Fourth Hieron Grimoire
    Every two years, the greatest thaumers in Param would converge in the city of Hieron, isolating themselves in the local magic tower to exchange ideas and push the boundaries of the art. The product of these discussions are poured into revolutionary tomes that became known as the Hieron Grimoires. The Sixth Grimoire had actually been produced earlier this year, but the tomes are so in-demand that even finding this old, twice-outdated version is an incredible feat on Aunt Bess' part.

    You've heard a fellow mage sing this particular tome's praises when it first came out: it is chock-full of instructions on increasing magical firepower and streamlining mana usage. These are invaluable techniques for any thaumer worth their salt, whose trade is to subdue their opponents with an onslaught of elemental attacks. It is a straightforward and powerful school of magic, though it seldom sees any use outside of the battlefield.

    Though the techniques detailed within are universally fascinating for the magical mind, they are far too specific to be immediately useful for anyone but the most adept of thaumers. Do you consider yourself one such?
    *choice
      #Yes, thaum is my specialty.
        *set specialtyset true
        *set specialty "Thaum"
        *set thaum %+50
        *set specialvar 1
        *goto tome1
      #No, I'm best at something else.
        *goto tome2
  #The Fae Records
    The Tome of Fairies, the most widespread text on the art of enchanting, was derived from the personal journals of one Dame Monahan, an imperial enchantress of the oversea Gespenst Empire. Her feats were so renowned and remarkable that it is said she carries fae blood in her veins, a claim that the woman herself had never denied. The Fae Records is a direct translation of her journal in its complete form, without the watering-down and simplification that the Tome of Fairies engage in.

    Though the Dame's script sometimes diverge into commentaries on the Empire's elaborate court life and her palpable disdain of the imperial bureaucracy, most of her accounts hold legible insights into the nature of blessings and curses alike. To the amateur's eye, they might too often seem like the ramblings of an old woman approaching senility. Any good enchanter, though, would know how to craft them into potent buffs and curses that could turn the tides of entire battles. Do you think yourself capable of such a feat?
    *choice
      #Yes, enchantment is my specialty.
        *set specialtyset true
        *set specialty "Enchantment"
        *set enchantment %+50
        *set specialvar 3
        *goto tome1
      #No, I'm best at something else.
        *goto tome2
  #Book of the Hollow
    As recently as fifteen years ago, any shop that stocked this tome would have been burned to the ground by church-sanctioned inquisitions. It was inevitable that practitioners would come to blows with religious authorities, spiritism being what it is, but even back then many found command over the deceased and otherworldly worthy of that risk.

    It was the Count of Polerien,    a Salantir noble, who first codified the specific sect of spiritism that allowed collaboration with the netherworld—rather than subjugation thereof—to which the church begrudgingly withdrew their opposition. It is a largely underdeveloped art, however, and pales in comparison to the magic contained in old tomes like this.

    Without proper understanding on how to navigate communication with the netherworld, usage of this tome would brand you a [i]necromancer[/i] rather than a spiritist, and you would likely be hunted down on the spot. Do you have what it takes to avoid such a fate?
    *choice
      #Yes, spiritism is my specialty.
        *set specialtyset true
        *set specialty "Spiritism"
        *set spiritism %+50
        *set specialvar 4
        *goto tome1
      #No, I'm best at something else.
        *goto tome2
*label tome2
Is that so? Which tome, then, best represents your specialty?
*goto besstome

*label tome1
Of course. You have a rare gift in the art, seldom seen even amongst your magical peers.

You take the stack from her, carefully storing them in your travel sack. They're quite cumbersome to carry around, but the absolute treasure trove of knowledge they contain is definitely worth the sacrifice.

"You have me at a disadvantage, Aunt Bess. I don't know how to thank you."

She laughs heartily, satisfied with the reaction she got. "Just be careful out there, you hear? I've already buried my husband and my kid. If I find I'll have to bury...

*choice
  #...another son...
    *set gender "male"
    *set them "him"
    *set their "his"
    *set they "he"
    *set theirs "his"
    *set theyre "he's"
    *set themselves "himself"
    *set pronvar 1
    *set sirdame "my lord"
    "If I find I'll have to bury another son, I'll kill you myself."
  #...a daughter, too...
    *set gender "female"
    *set them "her"
    *set their "her"
    *set they "she"
    *set theirs "hers"
    *set theyre "she's"
    *set themselves "herself"
    *set pronvar 2
    *set sirdame "my lady"
    "If I find I'll have to bury another daughter, too, I'll kill you myself."
  #...another brat...
    *set gender "nonbinary"
    *set them "them"
    *set their "their"
    *set they "they"
    *set theirs "theirs"
    *set theyre "they're"
    *set themselves "themselves"
    *set plural true
    *set pronvar 3
    *set sirdame "Retainer"
    "If I find I'll have to bury another brat, I'll kill you myself."

You chuckle under your breath. "I'll be careful. I promise."

You hug her for the last time, and say a final goodbye to the Bellgrove Inn.
*achieve leafend
*page_break
*set memorypoint "complete_inn"
*goto_scene Junction