*comment Chapter 5 - Golden Sun
*image header_c5.png center Chapter 5, Golden Sun. Even through scars and searing heat, we burn.
*page_break

*set lsword +10
*set lstrength +10
*set lendurance +10
*set sdagger +10
*set sblink +15
*set sspeed +10
*set sperception +5
*set itheurgy +5
*set ienchantment +10
*set ialchemy +5

"It's almost over, ${fname}," Ilya says, sweat matting her white hair. "Bear with it a little longer."

It is always the same reassurances each time, not that Ilya needs the reminder. The healer's squad of enchanters sit in a ring around you, pouring mana into the intricate, concentric spell circles upon which you sit. The runes hum as they pulsate, their power flickering to life and  dimming into repose; ${phant1}'s power trembles and lurches beneath your skin, defiant against their call. Ilya speaks as if in prayer. "Just a little more. Breathe, ${fname}."
*fake_choice
    #Inhale.

${phant1}'s visage flashes in your mind as you close your eyes,
*if (phant1 = "Satiel")
    *set phantvar 1
    blinding white eyes solemn as concentrated light bends the air around him. His aura is overwhelming, the ring of his
*elseif (phant1 = "Airas")
    *set phantvar 2
    deadly red eyes shining as the toxic mist swells and bends around them. Their aura is overwhelming, the ring of their 
*elseif (phant1 = "Gweila")
    *set phantvar 3
    the knife-slit of his eyes shining as the acrid green smoke swells and bends around him. His aura is overwhelming, the ring of his 
*else
    *set phantvar 4
    her black lips downturned as the odious mist bends the air around her. Her aura is overwhelming, the ring of her 
power an august death knell in your skull.

[i]What do we call it then, if not a curse?[/i] Eli had said, shadows dancing across ${ehis} face in the dying light. $!{ehis} voice is only an echo now, a pale imitation, but you feel the urgent cadence to ${ehis} voice as if ${ehe}'d come alive once more. [i]What good could this carnage buy? ${fname}, what could be worth the price?[/i]

You remember the sag of ${ehis} posture, the blood on ${ehis} hands where the light is dancing still. $!{ehis} face twists in anguish, and it occurs to you that for all that ${ehe} is older and wiser, [i]Eli is still a child[/i]; yet ${ehe} stands bowing over the mage's body, a clumsy, indolent man whose eyes had twinkled when he smiled, when he snuck sweets for you into the study. Eli's frame shakes as ${ehe} sobs into ${ehis} scarf, smeared red where ${ehis} fingers trail across the fabric, and it is a breath until you close the distance as you—

*fake_choice
    #Exhale.

The black of Eli's hair morphs into chestnut-brown, into a boy not much older than ${ehe} was, too young to die as ${ehe} did.

You had let ${phant1} burn to the surface then, 
*if (phant1 = "Satiel")
    scathing-white and violent as he
*elseif (phant1 = "Airas")
    tempestuous and violent as they
*elseif (phant1 = "Gweila")
    lurid green and violent as he 
*else
    scathing-black and violent as she 
mowed down the knights. You paid no mind to the recoil blooming in your system, because the mana in your veins are singing [i]what could be worse, what could be worse than to lose another[/i]—it is a song too familiar to ignore, and so you whirl on Eli's ghost, tell ${ehim} [i]this is it, this is the good that carnage buys[/i]; that you had lost everything when you lost ${ehim}, so you'll be damned if you—

*fake_choice
    #Inhale.

Slowly, painfully, you suppress ${phant1title}'s aspect even as it sears against your veins; you pull it taut like a leash, dousing, drowning it in mana of your own. You feel remarkably like water at a goblet's brim: tense to the point of vibration, so close to a free fall. The @{phantvar light|mist|smoke|mist} seethes and hisses, indignant at its repression as it [i]beat beat beats[/i] underneath your skin—

And then the circuit completes and the enchantment settles, stout and immovable, like a dam over a coursing river.

Ilya sags to the ground. "It is done."

*fake_choice
    #Exhale.

"That was close." The paladin behind you hoists himself up, straw-colored hair falling in clumps around his freckled face. His magical talents are unremarkable, especially when compared to his formidable swordplay. But Ilya had taken one look at him enchanting his blade mid-combat, the ensorcelled steel burning through Salantir armor; she anointed him straightaway as part of your personal brigade.

It's almost laughable, really, to be regarded as the cornerstone of the Sun Prince's rebellion, and yet ending up collapsed and gasping near the end of each battle. More disgraceful still that your lifeline is a squad of mages still wet behind the ears, paper cuts on their fingers from plowing through the Fae Records in a week.

And yet there is no denying the method's efficacy: Glyphs of Magesong to supplement your mana, enough for it to stand its ground against the flood of ${phant1}'s power, interspersed with Glyphs of Magebane to quell the excesses. Ilya had tried by herself, at first, but for all that she is a skilled enchantress ${phant1} is grand and terrible, and by the end Ilya'd end up no better for wear than you. So it was that she assembled a squad to help her tend to your [i]needs[/i], among which the fresh-faced Gael was the newest recruit.

The paladin immediately draws his sword once more, turning south to where the battle is thickest. "Your @{phantvar Reckoning Light|Venom Dance|Shaman's Elegy|Plaguehand} really did a number on them," Gael observes matter-of-factly, rearing into a charge. "The Sun Prince is breaking their vanguard."

*page_break

You follow his gaze and see that he speaks truth.

Leon's figure is visible in the distance as he chases down the Salantir archmage,
*if (phant1 = "Satiel")
    her robe tattered where Satiel's blast had grazed her.
*elseif (phant1 = "Airas")
    her skin boiling, hives from when Airas's poison had seeped into her skin.
*elseif (phant1 = "Gweila")
    her robe tattered from where the mighty ${ultima2} had grazed her.
*else
    valiantly fighting through the pain of her decay, skin boiling where Nyx's touch had grazed her.
The dusk light refracts as she weaves a gout of green flame, the spell hissing with smoke; she whirls on her pursuer and [i]flings[/i]—

In a second Leon is underneath her, sliding into place with a practiced roll, his limbs dancing around the flames. Twice, quickly, the blade's hilt catches her in the abdomen, and even as she wheezes Leon forcefully rams her down, merciless as he brings his blade to bear. The mage screams when she goes down, when the prince pins her to the ground, wild-eyed as the plea for mercy burns her throat.

She does not scream for long.

*fake_choice
    #It's a harrowing sight. War takes and takes from us all.
    #I feel vivid, full-bodied relief. One step closer to the end.
    #I can only convince myself that the peace we purchase will be worth it.

The deputy watches as his superior's blood paints the earth, trembling as he bellows the orders to fall back. His soldiers race to obey him, themselves run ragged and outmatched, rushing in droves to the safety of the keep. The rebellion is galvanized anew as they give pursuit, their blades singing, finding purchase in the retreating knights' backs; Leon is right at the head of the charge, his green eyes gleaming as it catches the dying light.

"Give chase!" the Sun Prince roars as his blade is swung overhead, wild and mad and rampant, knights falling like puppets around him. He is twenty, thirty paces from the gate when Saine blinks into the air in front of him, bodily charging his brother yelling [i]stop, stop, your knights are dying and we need to regroup[/i].

Leon grits his teeth, seething with fury at the enemies slipping through his fingers. But he heeds the younger's counsel, fist balled around his blade as he watches the gate—[i]where they had taken the saintess, where they had strung his brother by his neck[/i]—slam down against the packed earth.

There is silence, for a while, pregnant and deafening. "Regroup," the prince calls out at last. "See that our wounded are treated."

*page_break And so you do.
*label rainclears

It is near midnight when the rain clears, the air thick with the scent of damp earth and bruised grass. You feel the water soak into your bones, your mana quietly simmering against the low timber of the dying drizzle. Finally you feel at home in your own body, alone as you are in a clearing fifteen minutes from the camp.

You brace yourself for the eventuality that ${phant1}'s alien energy will come coursing through your body once more tomorrow. $!{phant1title} is a cruel bargainer, and the price of @{phantvar his|their|his|her} power has been severe. You are propelled now by adrenaline as your mana ducts stretch and strain to bear the vicious load, pacified only by your allies' Glyphs and these nighttime meditations. But you know there will be lasting consequences, once the damage finds time to settle, and the breadth of its impact will be unknowable until it fully manifests.

*choice
    #The thought fills me with piercing dread.
        *set emotional %+ 15
        *set preemotional %+ 15
        You have come too far, done too much as a mage just to lose it all in one fell swoop. Regardless, this
    #If it buys victory, there is little I won't tolerate.
        *set emotional %- 15
        *set preemotional %- 15
        You have come too far, bore too great a cost in fighting this war just to stop now. This
    #I'm sure everything will work out. I'll cross that bridge when I get to it.
        *set optimistic %+ 15
        *set preoptimistic %+ 15
        After all, have you not made do so far with only a band of ragtag enchanters? There will be time enough to find a solution for your maladies when Param is peaceful once more. Besides, this
    #I expected as much. I've been lucky to even make it this far.
        *set optimistic %- 15
        *set preoptimistic %- 15
        Indeed. There is always a price attached to power, and scarcely any power is greater than ${phant1}'s. Besides, this
conflict is bigger than you, bigger than any one person—and there is no choice but to press forward when the bewitching lure of peace is all but within your grasp.

There is a sudden rustle in the leaves behind you, a touch too acute to be passing wind. You tense up immediately, fingers already dancing around a spell circle because [i]this wouldn't be your first ambush[/i]; enemies always take you as wounded and vulnerable in the winding down after combat, forgetting that for all that you're now known as ${phant1}'s host, before @{phantvar him|them|him|her} you were still royal retainer to the strongest swordsman in the land.

The air shrieks as @{specialvar the burst of ice begins forming in|hissing poison begins leaking from|the Glyph of Strength begins forming in|the gout of black mist begins to gather at} your palm—a minor spell to test the waters, though you are capable of so much more and unafraid to show it.

A beat, a tense second as you dare the assailant to spring forth. Instead they emerge from the tangled growth, languid and deliberate: a familiar figure, pale and willowy under her sable cloak.

"Ante," you call out tersely. "Come to spy on me again?"

"[i]Spy[/i] is a strong word, ${sirdame}. I am simply standing guard in case of an ambush."

A rather blatant lie, even for the spymaster. This is the third time in the campaign that you've caught her skulking about, watching you; you're not fool enough to believe there hasn't been times she escaped your notice. Ante, it appears, has decided the sin of being stepsibling to the enemy commander—no matter how star-crossed—is not one three years of loyalty could absolve.

*choice
    #I try to be sympathetic. It's good of her to be vigilant, at least.
        *set noble %+ 15
        *set prenoble %+ 15
        Ante perceives your understanding, nodding solemnly as if in gratitude. "So you understand, ${sirdame}: I'm simply doing my job."
        
        You shrug in assent, droplets falling off your 
        *if (hairlength = "bald")
            head
        *else
            ${haircolor} hair
        from the motion. "Sure, I get that. It's just wasted effort when you can expend it on the enemy."
        
        *goto anterelax
    #This is getting ridiculous; I've more than proven my loyalty.
        *set emotional %+ 15
        *set preemotional %+ 15
        Ante perceives your disbelief; she takes a step back in fear of what you might resort to. "Please understand. I'm simply doing my job, ${sirdame}."
        
        You stifle an incredulous laugh at that, droplets falling off your
        *if (hairlength = "bald")
            head
        *else
            ${haircolor} hair
        from the motion. "Your [i]job[/i]," you scoff, "is to observe the [i]enemy[/i]."
        
        "And if the enemy has a key?" Ante's gaze is sharp, her form taut as if ready for combat. "You have earned the trust of our commander, our prince, our best healer. Surely you understand, ${sirdame}, that [i]someone[/i] must be left to doubt."
        *goto angrychoice
    #She can observe me all she wants: I've got nothing to hide.
        *set emotional %- 15
        *set preemotional %+ 15
        Ante perceives your relentment, nodding solemnly as if in gratitude. "So you understand, ${sirdame}: I'm simply doing my job."
        
        You shrug nonchalantly, droplets falling off your 
        *if (hairlength = "bald")
            head
        *else
            ${haircolor} hair
        from the motion. "It doesn't bother me. It's just wasted effort when you can expend it on the enemy."
        *label anterelax
        
        "And if the enemy has a key?" Ante's gaze is sharp; for all that her body language has been deliberately relaxed, her guard is anything but down. "You have earned the trust of our commander, our prince, our best healer. Surely you understand, ${sirdame}, that [i]someone[/i] must be left to doubt."
        *choice
            #"That's fine. Do as you like."
                *goto doasyou
            #"You sure are persistent. Careful that you don't fall for me!"
                *set charming %+ 15
                *set precharming %+ 15
                Ante goes very, very still, though you can spot the ghost of a twitch on her right eyebrow. She valiantly reins it in as she dips into a curt bow.
                *label iampleased
                "I am pleased that you understand, ${sirdame},"
                *goto makestoleap
            #You have nothing further to say to her. Quietly turn away.
                *set charming %- 15
                *set precharming %- 15
                Ante takes your cold shoulder in stride, quickly dipping into a curt bow.
                *goto iampleased
    #Maybe she'll need to be hit by this spell to realize who she's dealing with.
        *set noble %- 15
        *set prenoble %- 15
        Ante perceives your aggression, sees the risk for what it is, and takes a step back. "Please understand. I'm simply doing my job, ${sirdame}."
        
        You inch your spell hand forward, droplets falling off your 
        *if (hairlength = "bald")
            head
        *else
            ${haircolor} hair
        from the motion."Your [i]job[/i]," you spit, "is to observe the [i]enemy[/i]."
        
        "And if the enemy has a key?" Ante's gaze is sharp, alternating between you and the still-forming spell. "You have earned the trust of our commander, our prince, our best healer. Surely you understand, ${sirdame}, that [i]someone[/i] must be left to doubt."
        
        *label angrychoice
        *choice
            #"Fine. Do as you like."
                *label doasyou
                *set emotional %- 15
                *set preemotional %- 15
                Ante gives you a curt bow.
                *label domyduty
                "Then I will do my duty, ${sirdame}," 
                *label makestoleap
                she says, making to leap away. "You will not detect me again. This, at least, I can promise you."
                *goto rushofwind
            #"You are trying my patience, Ante! See what happens when you cross me again."
                *set emotional %+ 15
                *set preemotional %+ 15
                *label mustdo
                "I must do my duty, ${sirdame}, whatever the consequences may be to me," she says, making to leap away. "But
                *label nogood
                I'm of no good to Param dead—so you will not detect me again. This, at least, I can promise you."
                *goto rushofwind
            *if (((specialvar = 1) or (specialvar = 2)) or (specialvar = 4)) #Enough is enough. I release the spell.
                *set noble %- 15
                *set prenoble %- 15
                *achieve attackante
                Ante blanches as your spell bounds forward; she leaps to the side with a practiced nimbleness, but your spell homes in on her and catches her in the thigh. The spymaster winces as the
                *if (specialvar = 1)
                    icicle draws blood, painting its tip red as it shatters under her.
                *elseif (specialvar = 2)
                    *set poisonkiss true
                    *set acounter +1
                    poison blisters her skin, leaving a hissing lesion as it dissipates into air.
                *else
                    *set rancor true
                    *set scounter +1
                    mist wraps thick around her skin, leaving a hissing lesion as it dissipates into air.
                A glancing blow, by all measures. But it drives the point home.
                
                "Try me again, Ante," you hiss, "And you [i]will[/i] be sorry."
                
                "I see," she notes dourly, making to leap away.
                *goto domyduty2
            *if (specialvar = 3) #Enough is enough. I activate the spell.
                *set noble %- 15
                *set prenoble %- 15
                *set glyphofstrength true
                *set ecounter +1
                It is the work of a single second to bring the Glyph to completion, to have it drape strength over your form like a coat. Ante blanches as you bound forward, propelled by the Glyph's power; she leaps to the side with a practiced nimbleness, but you'd already pivoted
                *if (injury = "brokenknee")
                    on your good leg to
                *else
                    to
                catch her from her blind spot. The punch connects with her navel, once, hard, and you feel the muscle underneath give way as Ante slips away once more.
                
                A glancing blow, by all measures. But it drives the point home.
                
                "Try me again, Ante," you hiss, "And you [i]will[/i] be sorry."
                    
                "I see," she notes dourly, still reeling from the impact but already making to leap away.
                *label domyduty2
                "I must do my duty, ${sirdame}, whatever the consequences may be to me. But
                *goto nogood
*label rushofwind

And with a rush of wind and rustling leaves, she is gone.

*page_break

The moon hangs high in the sky by the time you slip out of your soggy clothes, swapping it for your coarse but well-fitting nightclothes. You toss and turn on your bedding that night, attempting to rest and ready yourself for the battle ahead. And yet between your mind's meditative buzz and the cold remnants of rainwater still clinging to your bones, you find that sleep has become an elusive ghost.

And so you walk. Aimlessly, thoughtlessly, you meander between tents until you chance upon a rock face just beyond the camp borders.

The cliff plays host to a carpet of underbrush, painted blue-green by the glimmering moon, sighing with the wind. Wet blades of grass give way underfoot as you tread the path to the cliff's edge, drinking in the moonlight like ambrosia. Sienan Keep rises from the horizon, stretching to the sky with its sturdy ramparts and majestic spires; you can't shake the feeling that those very same structures will be painted scarlet come tomorrow morning.

"Can't sleep?"

The voice jolts you out of your reverie, and you turn around to find…
*choice
    #The Sun Prince in a loose-fitting tunic, looking so much like the kindly adventurer you had met all those years ago.
        *goto leonsection
    #The saintess-in-training, hair a shining beacon under the moonlight, come to make good on the promise she made her mentor.
        *goto ilyasection
    #The younger royal, green eyes holding your gaze as he inches towards you, quiet as the night.
        *goto sainesection

*label ilyasection
Ilya's resolve is plain in the set of her jaw, her blue-eyed gaze determined as she trains them on the castle. "I can't sleep either, you know. I keep thinking…this is really it, ${fname}. The last stretch," she says, trailing a hand through her white hair. "The saintess is in there, somewhere. It's been two long years…I hope she's okay."
*choice
    #"Mireil said she needed the saintess alive. We'll be able to save her, you'll see."
        *set optimistic %+ 15
        *set preoptimistic %+ 15
        "I hope you're right, ${fname}," Ilya sighs. "I haven't stopped thinking about the night we left her. It was the hardest thing I've ever done in my life."
        
        "It was rough," you agree. "But that decision is what allowed us to come back here, to come back for her. The war is nearly won, Ilya, and by this time tomorrow the saintess will be with us."
        
        The healer nods at that, as if willing herself to be convinced. "We have to make it happen. The saintess is too kind, too pious a woman to die at Mireil's hands."
        
        "We're in agreement, then,"
        *label yousay
        you say. Ilya had been near inconsolable, those first few months; you suppose you should be grateful that she's tempered her despair into zeal. "But what of you, Ilya? What are your plans after the war?"
    #"A lot can happen in two years, Ilya. I wouldn't hold my breath."
        *set optimistic %- 15
        *set preoptimistic %- 15
        The healer laughs mirthlessly. "You don't beat around the bush, do you? Not that I can judge you for it, when I've been thinking the same thing myself."
        
        "Reckless optimism tends to disappoint. It's a good thing to temper your expectations."
        
        The healer nods at that, her smile conflicted. "And yet I can't [i]not[/i] nurse this hope, ${fname}. The hope that she's alive, and that she'll return to us safe and sound
        *label saintesskind
        She is too kind, too pious a woman to die at Mireil's hands."
        
        "We're in agreement there, at least,"
        *goto yousay
    #"We'll know when we find her. Keep your head in the fight, Ilya."
        *set emotional %- 15
        *set preemotional %- 15
        The healer laughs mirthlessly. "Focused as always, ${fname}. I still have much to learn from you, it seems."
        
        "A rare occasion, when usually you're the one keeping us grounded."
        
        "Touche," she chuckles. "It's just that she's within arm's reach now, ${fname}. I can't [i]not[/i] think about her, not when she's so close.
        *goto saintesskind

Ilya's eyes widen at the question, her eyebrows twisting in bewilderment. "I'm…not sure. I think I found it disrespectful, ${fname}, to have plans for myself when the saintess's future is still so uncertain. So, um, I haven't really thought about it," she admits, shuffling her feet.
*if (ilyahouse)
    "Although…my brother became of age just last month, so he'll be able to succeed my father's title. My house is saved, ${fname}. It feels surreal, and I don't quite know what to make of this freedom."
*else
    "Did you know I was training to become the saintess? It was the only way for me to inherit my father's title, though now my brother is old enough to succeed it in my stead. With my house saved, I finally have some freedom, ${fname}. I don't quite know what to make of it."

*choice
    *disable_reuse #"Do you still dream of being the saintess?"
        *set ilyasaint true
        "It's strange," she ponders, looking out onto the horizon. "I had thought it was just a stepping stone, a means for me to save my family. But I think I can do a lot of good from the position, you know? I have the best example to follow, after all."
        
        "You really look up to the saintess, huh?"
        
        Ilya chuckles at that, the sound resonant against the sighing wind. "Of course. There's a lot to admire about her. She's a powerful theurge, an able bureaucrat, and genuinely cares for the people—of the Jovian faith or otherwise. It's a lot to live up to."
        *choice
            #"I'm sure you'll do fantastic. Believe in yourself a little more, Ilya."
                *set optimistic %+ 15
                *set preoptimistic %+ 15
                *set rilya %+ 10
                Ilya closes her eyes, the ghost of a blush dusting her cheeks. "It'll be a long time before I'm fit for the mantle, ${fname}. But I'm glad you have such a high opinion of me."
                
                "Is my opinion too high, or yours too low? I don't think you understand the impact you have on this army, Ilya."
                
                "Now I [i]know[/i] you're just trying to get on my good side, ${fname}." There's a high lilt to her chuckle, sorrow in her eyes. "I do alright as a healer, but there's been so much…no, never mind that. I'll take your word for it, ${fname}—here's hoping I can live up to that faith."
            #"Are you sure you're ready for that kind of commitment?"
                *set optimistic %- 15
                *set preoptimistic %- 15
                Ilya closes her eyes, humming softly as she does. "Truthfully, I don't really know, ${fname}. It will certainly be a long time before I'm fit for the mantle, but objectively speaking, I don't think anyone could grow into the role better than me. It will be difficult, but I have to try."
                *choice
                    #"Well, as long as you're determined."
                        *set charming %- 5
                        *set precharming %- 5
                        *set emotional %- 5
                        *set preemotional %- 5
                        Ilya glances sideways at you, chuckling lightly. "You know I've never been one for half-measures, ${fname}."
                    #"Anything I can do to help, you just let me know, alright?"
                        *set charming %+ 5
                        *set precharming %+ 5
                        *set emotional %+ 5
                        *set preemotional %+ 5
                        *set rilya %+ 10
                        Ilya's smile is serene in the waning light. "Thank you," she says softly.
    *disable_reuse #"If being saintess wasn't on the table, what would you do instead?"
        "It is a strange feeling, ${fname}, to be a free woman. I've been resigned to my fate for so long, and now the choices before me are…paralyzing."
        
        *choice
            #"Ilya de Alviar, indecisive? I never thought I'd see the day."
                *set charming %+ 15
                *set precharming %+ 15
                *set rilya %+ 10
                The healer thwacks you on the arm. "I've certainly fallen far, to make confidants out of knaves like you. I should've known you'd enjoy watching me squirm."
                
                You laugh openly, raising an arm in self-defense. "You like that about me."
                
                "I like [i]nothing[/i] about you."
                
                "Liar," you accuse. Ilya gives you another thwack for good measure, chuckling good-naturedly.
            #"You don't have to decide on anything yet. Choice is an uncertain luxury right now."
                *set optimistic %- 15
                *set preoptimistic %- 15
                *set rilya %+ 5
                "True enough," the healer concedes. "I suppose these are the kinds of things we can only plan about when the war is truly over."
                
                You nod in agreement. "We'll have to focus on tomorrow's battle, but lets revisit the topic in better times."
                
                Her grin is slight, but sincere. "I'll hold you to that."
            #There's nothing I can really say to that. Just nod in response.
                *set charming %- 15
                *set precharming %- 15
                *set rilya %+ 5
                Ilya laughs at your confusion, her hair falling out of place around her shoulders. "Sorry, I don't know what kind of response I was expecting. Though I suppose it doesn't really matter—it's all hypothetical, anyway."
                
                "Hypothetical?"
                
                "Mm. Aside from the whole White Fangs business…I've never really been the adventurous sort. I might stick to the path of becoming saintess just because it's familiar territory, safe. And maybe that's enough for me."
    *selectable_if (ilyahouse) #"And what does this mean for your arrangement with Kavan?"
        The healer's blue eyes glint with something you can't quite pin down. "It will fall through, of course," she says, slowly, deliberately. "With any luck, he's had time to phase out his feelings for me, now that he's busy managing the wartime logistics back in Kantena."
        
        *if (charming > 50)
            "Oh, is that where he ended up? How curious, for you to be on opposite ends of the war effort."
            
            "I don't know what you're insinuating," she says airily, though you don't buy for a second that she had no part in engineering this outcome. "It was Leon's decision, after all. Everything else are just…convenient side-effects."
        *else
            You don't think for a second that it's mere coincidence the boy ended up on the opposite end of the war effort—and judging from the mischievous quirk to her lips, she doesn't expect you to.
            
        Ilya shoots you an expectant look, her gaze electric as it holds your own.
        *if (ilyafwb = false)
            *choice
                #Kiss her.
                    *label ilyakiss
                    *set ilyarom true
                    *achieve ilyarom
                    *set rilya %+ 20
                    Ilya meets you halfway, smelling of rainwater and lavender as her lips lock against yours, her white hair silken smooth where it brushes against your cheek. It's quiet, at first, chaste, but when your hand rests upon her back you can feel her breath hitch; and then the healer's hands are around your jaw and she leans into the kiss with a hungry sort of passion. There's no explosion, no fireworks that people often spoke about; it feels instead as if you've been plunged into ocean blue, as blue as her eyes, at once roaring and serene—you never want to come up for air.

                    "So long," she says after the first parting, her breath warm as it paints white in the night air. "So long, I've waited for this."
                    *choice
                        #"And whose fault was that, hm?"
                            *set charming %+ 15
                            *set precharming %+ 15
                            "Mine," she breathes, giggling against your embrace. "It's my fault, and I was a fool, and—do we really need to go through the whole thing? Or can we just skip to the part where you kiss me again?"

                            "I [i]do[/i] rather like that part."

                            Her laugh is bright as she presses her lips against your chin. "What a lukewarm word, like," she says quietly, her teeth ghosting softly against your skin. "I think I can do better than [i]like[/i]."

                            Her eyes gleam like sapphires in the moonlight, mesmerizing even as the taunt forms on the tip of your tongue. "Prove it."

                            Her breath is warm against your cheek. "I think I will." 

                            That night you find out, that in true Jovian fashion, there is nothing Ilya does better than making good on her word.
                            *goto endnightscene
                        #Say nothing; lean in for a second kiss.
                            *set charming %- 15
                            *set precharming %- 15
                            Ilya falls into your arms as you lean in for seconds, her hands snaking around your waist to pull you in closer. The kiss is immediately assertive, the second time around—assured in its familiar territory, comfortable as a hearth's embrace. Through the peek of your lids all you can see is glimmering white, stardust and moonlight spun into strands, and you can't help but to think how [i]lucky[/i] you are, to hold the night sky in your hands.

                            "Don't stop," Ilya chides, when you break apart. "We've got two years of catching up to do, so don't you [i]dare[/i] stop."

                            There's no way to tell her as much, when your lips are so preoccupied, but you find you're all too happy to oblige.
                            *goto endnightscene
                        
                #"Ilya...I think my feelings have changed."
                    *set rilya %- 10
                    *set ilyarom false
                    The healer schools her expression into one of careful neutrality. It is a valiant effort, but you've fought by her side for four years now—you can spot the droop to her eyelid, the tense quirk to her lips that speak of dejection. "Ah," she says, casting her gaze out onto the horizon. "You don't have to tell me, but…can I know why?"
                    *choice
                        #"Four years was a long time. I just don't feel the same anymore."
                            Ilya smiles wistfully, her hand balling up into a fist beside her. "Damn," she says under her breath, and you feel your eyes widen in surprise—this is the first you've ever heard her swear. "Damn
                            *label mycircum
                            my circumstance, to make me let
                            *label youslip
                            you slip away like this."
                            *label fakechoice
                            *fake_choice
                                #"I'm sorry, Ilya."
                                #"I hope we can still be friends."
                                #"Maybe sometime in the future, we can revisit this possibility."
                            Ilya's breath catches as you open your mouth, and she quickly holds a hand up to instruct your silence. "Please, don't…don't say anything further. I'm barely holding myself together, ${fname}—I don't think I could take it."
                            
                            You assent to her request, letting silence drape over you both as Ilya expertly reins herself in. "It is too bad that things turned out this way," she says at last, and when you whirl on her the healer had phased the dew out of her eyes. "But we are still comrades before we are anything else. It will take some time, but I think we can go back to that again, ${fname}. Friends, even."
                            
                            The healer turns away, then, her smiling facade slipping back on like a mask. "Well, thank you for the chat, ${fname}. In some ways, I suppose this gave me the closure I needed. And with one final, wistful glance in your direction, Ilya disappears into the night.
                            *goto endnightscene
                        
                        #"I just don't think I'm in a good place for romance."
                            Ilya smiles wistfully, her hand balling up into a fist beside her. "I see," she says under her breath, shaky as you've never heard her before. "I can understand that, ${fname}, but…damn this blasted war. Damn [i]me[/i], for letting
                            *goto youslip
                    
                        #"I'd rather not say."
                            Ilya smiles wistfully, her hand balling up into a fist beside her. "Of course, I—I won't force you, not when I made you wait for four years. This is just what I deserve," she says at length. "But…damn
                            *goto mycircum
                    
                #"I don't think I'm up for romance anymore, Ilya. But if you want something simpler..."
                    The healer schools her expression into one of careful neutrality. It's a valiant effort, but you've fought by her side for four years now—you can spot the droop to her eyelid, the tense quirk to her lips that speak of dejection. "Ah," she says, casting her gaze out onto the horizon. "You no longer want…a relationship, you mean. You don't have to tell me, but…can I know why?"
                    *set rilya %- 10
                    The healer schools her expression into one of careful neutrality. It is a valiant effort, but you've fought by her side for four years now—you can spot the droop to her eyelid, the tense quirk to her lips that speak of dejection. "Ah," she says, casting her gaze out onto the horizon. "You don't have to tell me, but…can I know why?"
                    *choice
                        #"Four years was a long time. I just don't feel the same anymore."
                            Ilya smiles wistfully, her hand balling up into a fist beside her. "Damn," she says under her breath, and you feel your eyes widen in surprise—this is the first you've ever heard her swear. "Damn
                            *label mycircum2
                            my circumstance, to make me let
                            *label youslip2
                            you slip away like this."
                            
                            "Ilya…"
                            
                            "I…I'm sorry, ${fname}. I don't think—the kind of relationship you're looking for, I don't think I can do it. Not right now, at any rate."
                            *goto fakechoice             
                        #"I just don't think I'm in a good place for romance, emotionally."
                            Ilya smiles wistfully, her hand balling up into a fist beside her. "I see," she says under her breath, shaky as you've never heard her before. "I can understand that, ${fname}, but…damn this blasted war. Damn [i]me[/i], for letting
                            *goto youslip2
                    
                        #"I'd rather not say."
                            Ilya smiles wistfully, her hand balling up into a fist beside her. "Of course, I—I won't force you, not when I made you wait for four years. This is just what I deserve," she says at length. "But…damn
                            *goto mycircum2
            
        *else
            *choice
                #Kiss her.
                    *set ilyarom true
                    *achieve ilyarom
                    *goto ilyakiss
                #"I don't think I want that kind of relationship anymore, Ilya."
                    *set ilyafwb false
                    The healer schools her expression into one of careful neutrality. "Ah," she manages, after a beat of silence. "You realize there are two different implications for your words, right? Either we go back to being friends—perfectly rational, if somewhat disappointing—or you're looking for something [i]more.[/i] So," she says, leaning towards you with a strange glimmer in her eyes. "Which is it, ${fname}?"
                    *choice
                        #"More. I want something more, Ilya."
                            Her smile is easy and bright. "I think that could be arranged," she laughs, leaning her forehead against yours. "There will be time enough to find where we stand, after this is all over. I think it's a bit too hefty a discussion when we're right on the enemy's doorstep, don't you?"
                            
                            Ilya brushes her fingers against your cheek, once, softy, and turns around to leave. "Stay alive tomorrow—we'll have [i]much[/i] to discuss after the battle." And with a flit of her white hair, Ilya disappears into the night.
                            *goto endnightscene
                        #"I think we're better off as friends."
                            *set ilyarom false
                            The corner of her lips pull taut at the words, but before long the familiar, smiling facade—the one she wears around nobles, [i]never around you[/i]—falls back into place, quick and practiced. "I see. That's too bad," she says with a nonchalant shrug. "I hope this doesn't make things awkward between us, ${fname}. I'd hate for us to go through all these…[i]phases[/i], and end right back at square one."
                            
                            Ilya's slender fingers brush through her hair, and it trails behind her as she turns around to leave. "Stay alive tomorrow," she says at length, before disappearing into the night.
                            *goto endnightscene
                           
    #Say nothing more. Just take in the cool night air and relax.
        *set ilyarom false
        *set ilyafwb false
        The both of you fall into a companionable silence, Ilya's breath slow and steady as she looks out onto the horizon. There's something wistful in her gaze, but that determined set to her jaw never quite fades.
        
        It is a while before Ilya speaks again. "Well, thank you for the chat, ${fname}. I think I'm about ready to brute-force my way through insomnia," she
        *label laughtight
        laughs, tightening her cloak around her. "I recommend you do the same. We've got a big day ahead, and you're the army's main piece. We need you well-rested, or the rebellion will pay for it."
        
        The healer gives you a smile as she turns around, and with a flutter of her cloak she disappears into the night.
        *goto endnightscene
 
*page_break
"Well, thank you for the chat, ${fname}. I think I'm about ready to brute-force my way through insomnia," she
*goto laughtight
    
    
*label sainesection
*set ilyarom false
Saine shivers in from the cold air, pulling his coat closer as he stands next to you. "It's really cold tonight," he remarks, gaze firmly set on the keep. "But we're finally at the last stretch…this time tomorrow, for better or worse, everything will be over."
*choice
    #"It'll be for the better, you'll see."
        *set optimistic %+ 15
        *set preoptimistic %+ 15
        "I bet it will, as long as you're around," he says, grinning. He shifts on his feet, his attention back on the castle. "I
        *goto liferoad
    #"You holding up alright, Saine?"
        *set charming %+ 15
        *set precharming %+ 15
        "Fine, I'm fine," he says, brushing your concern away with a strained cheer. "It's just…I
        *goto liferoad
    #Say nothing. Just thaum a small fire to keep him warm.
        *set charming %- 15
        *set precharming %- 15
        The flame ignites in your palm with a soft crackle. Saine smiles at the gesture, leaning closer to you to bask in the warmth. "Thanks, ${fname}. This helps, but I
        *label liferoad
        can't wait to get back to Sienan. I don't think I'm cut out for a life on the road."
        
        You ponder that. "You seemed happy enough, back in the White Fangs."
        
        "I did, didn't I? Guess it took a whole war to finally give me some perspective," he says, grinning—it doesn't quite reach his eyes. "I'm starting to get it, I think. This whole…noblesse oblige thing Julius always harped on about. You've seen it, haven't you? People [i]light up[/i] at the mention of his name, ${fname}. A whole country ready to throw their lives away in honor of him. To be king for two years, and leave such a towering legacy…I almost feel ashamed with the way I've been acting.
        
        "I'm going to do better, ${fname}," he says finally, drawing his back a little straighter. "All his life, Julius fought for a better Param—and he died for it, too. I'm going to pick up right where he left off…whatever the cost."
        
        *if (saineace)
            You think back to the balcony in Sienan castle, to the conversation you had with Saine two years ago. The cost he's referring to becomes painfully clear: a life as an ambassador, away from the continent he loved so much, a surrender to a loveless marriage. Saine is not yet twenty, yet he has chosen to shoulder a truly sinister burden.
            *choice
                #My heart hurts for him. I will never truly understand what he's going through.
                    *set emotional %+ 15
                    *set preemotional %+ 15
                    *goto saysomething
                #Saine has really done a lot of growing up. His courage is inspirational.
                    *set emotional %- 15
                    *set preemotional %- 15
                    *goto saysomething
                #I can't help but feel devastated on his behalf, especially since I share his struggles.
                    *set aroace true
                    *goto difference
        *else
            
            "And what cost exactly are you talking about?"
            
            Saine falters, for a moment, before the resolve returns to his eyes. "Before this war happened, Julius was going to ship me off to Thayle, did you know?"
            
            It's something the deceased king mentioned in passing, and so much has happened since then. But you do recall him saying something to that effect: you tell Saine as much. "He wanted to have me married, ${fname}. To solidify an alliance—a good thing for Param, when you think about the geopolitics of it, but a piss-poor deal for me. Me, who can't love anyone. Not in that way."
            *choice
                #I feel my brows raise in surprise. I had never known this about him.
                    *goto saysomething
                #I note the information and move on.
                    *goto saysomething
                #Somewhere deep within me, I had always suspected this was the case.
                    *goto saysomething
                #I can't help but feel devastated on his behalf, especially since I share his struggles.
                    *set aroace true
                    *label difference
                    The difference between you two, of course, is that any marital obligations you once had have long since been shed, alongside all the other trappings of your nobility. But even experiencing what you have through the lens of a baseborn mage has been as difficult as it is lonely. Everywhere you went, the notion of love and consummation had always been treated as a given, and you had grown increasingly certain that no one would ever understand what it's like, to live as you do.
                    
                    And yet here Saine is, a sliver of a child forced into a role too large and cruel for his young shoulders. A boy who had taken his ordeal in stride, despite it all, one who talks of sacrifice as if he had everything left to give.
                    *choice
                        #I'm hugging him before I realize it.
                            *set emotional %+ 15
                            *set preemotional %+ 15
                            *set rsaine %+ 20
                            Saine splutters something intelligible as you seize him in your arms, though before long he's leaning into the hug out of sheer instinct. "${fname}…?"
                            
                            "Sorry, I just—I never thought I'd meet another," you manage through shuddering breaths. "Another person like me."
                            
                            You feel the prince tense up against you. "You mean…?"
                            
                            "I know what you're going through right now. I know…how hard it must be. You've been so strong, Saine, and I—I'm so proud of you."
                            
                            As soon as the words leave your mouth, the young prince all but crumples in your embrace. Like a dam breaking, his tears come out in steady, unmeasured streams, painting wet spots on your tunic as they barrel down his cheeks. You hold Saine tightly, wordlessly, even as he shakes, even as he gasps his breaths, and watch the stars gleam in the distance through tears of your own.
                        #I tell him the truth: that he's not alone.
                            *set rsaine %+ 20
                            "I understand, Saine," you try, carefully neutral.
                            
                            The prince whips his head in your direction, caution and uncertainty brewing in those green eyes. "You do?"
                            
                            "Mm. I've always felt the same way, after all," you say, trying for a reassuring smile. "Of course, you and I are very different people, but—"
                            
                            Your next words promptly die in your throat as Saine bodily whirls on you, his hands trembling as they seize yours in his own. "You—you're not messing with me, are you? It wouldn't be funny, ${fname}, and even if it's you, I—"
                            
                            "No, of course not," you say, looking him squarely in the eyes, hoping the determination you feel swelling up in your chest carries through. "I would never do that to you. I—I know how hard it must be, to bear all of this on your own. You've been so strong, Saine, and I—I'm so proud of you.
                            
                            As soon as the words leave your mouth, the young prince all but crumples into himself. Like a dam breaking, his tears come out in steady, unmeasured streams, leaking through the gaps of his fingers as they barrel down his cheeks. You reach out an arm behind the rogue in a bid to comfort him, painting circles in the small of his back. All the while, you gaze in silence towards the stars gleaming in the distance, and if you feel something beginning to prick at the edge of your own eyes, Saine remains none the wiser.
                            *goto sainecalm
                        #I say nothing. We have this in common, but our experiences must be incredibly different.
                            *goto saysomething
            *label sainecalm
            *achieve saineace
            *page_break
            It would be a long while before the prince would manage to bring himself together once more, sniffling the last of his sobs into his sleeves. "I'm sorry you had to see that," he croaks. "That wasn't very princely of me."
            
            "Don't worry about it," you try, giving him what you hope is a reassuring smile.
            
            Saine returns the gesture with a smile of his own, soft and wistful, before turning his gaze on the horizon. "I guess I chose the right person to confide in," he says, almost mirthful. "No one would understand better than you, after all. So tell me, ${fname}. Tell me what I need to hear: that I'm making the right call."
            *goto sainechoice
            *label saysomething
            
            "${fname}?" Saine asks, his breath painting white clouds against the night air. "Say something."
            *label sainechoice
            *choice
                #"No one should be held to such an expectation. Your life is your own, Saine."
                    *set rsaine %+ 20
                    Saine shifts his stance, his gaze downcast. "But it doesn't have to be. If I can make a difference, [i]save lives[/i] by doing this, why shouldn't I? Why is it less important if [i]they[/i] suffer than if I do?"
                    
                    "Because there are other ways to cement alliances," you try. "Ones that do not cause you such misery. Leon will be a good king, one that doesn't have to trade his brother's happiness for Param's."
                    
                    The younger sniffs, and you don't think it's from the cold air. "But I could help him," he says weakly.
                    
                    "You can, but is it worth the price? You said it yourself: your brother lived by this principle, and it cost him his life. Saine, what if it costs you yours?" You turn to face the prince, a child by all measures—far too young for such burdens. "Don't throw your happiness away like this. You're a good person, and you've done much for Param. You've done [i]enough[/i], Saine."
                    
                    The prince drops to the ground with a soft thud, fully weeping now as he turns his head away. "You always know just what to say, don't you?" he says, sniffling into his sleeve. "I…thank you, ${fname}. Really, I needed to hear that."
                
                    You join him on the ground, the blades of grass ticklish against your bare leg. A companionable silence falls over you, and though no further words are exchanged that night, there is no mistaking the expression on Saine's face. As the moonlight glides and casts shadows across his features, the prince looks as he hasn't looked in years: radiant, and at peace.
                    *goto endnightscene
                #"You'll be able to do a lot of good. I'm rooting for you."
                    *set rsaine %+ 10
                    Saine nods at your words, the smile on his face melancholic. "Too bad Julius isn't around to see, huh? He would've been over the moon."
                    
                    "I only knew him for a short while, but he was the sort of person that was easy to understand," you say, closing your eyes in remembrance. "And I think he'd have been proud of you, you know. You and Leon both."
                    
                    "I think I can agree," Saine sighs, the night breeze blowing against his hair. "It…feels good, to pick up where he left off. His body is lost to us, Mireil made sure of that—but I think he'd have been pleased to know his ideals lived on. So I'll be sure to do him proud."
                    
                    A companionable silence falls over you both, after that, and it is a while until Saine rises to excuse himself.
                    
                    "Thanks for the talk, ${fname}. I needed…courage, to be sure of this decision. I think having this talk helped."
                    
                    *label finalconflicted
                    And with a final, conflicted smile over his shoulder, Saine disappears into the night.
                    *goto endnightscene
                #"Don't pressure yourself too much: you've done plenty already."
                    *set rsaine %+ 10
                    Saine shifts his stance, the smile on is face melancholic. "I wish that was the case. Julius had shouldered all the burden himself, when he was alive. Now, Leon leads an army and makes all the hard calls. I just stab whoever he tells me to."
                    
                    "Leon wouldn't be able to do what he does without your support. You've done a lot for him, Saine, and I [i]know[/i] he's told you as much."
                    
                    Saine sighs against the night breeze. "But I could do more," he half-whispers.
                    
                    "But should you? You said it yourself: your brother lived by this principle, and it cost him his life. Saine, what if it costs you yours?" You turn to face the prince, a child by all measures, trapped under the legacy of his dead brother. Looking so uncertain, so forlorn that it hurts your heart to stare him in the face. "Consider your options carefully, Saine. Do what you feel you must, but don't forget that you deserve kindness, too."
                    
                    The prince takes sudden interest in his feet, shuffling them lightly against the grass. "Damn it, ${fname}. I was already set on my decision, but you really do know how to make a guy doubt, huh?"
                    
                    You shrug. "It's a good thing, to think twice before signing away your freedom."
                    
                    "Can't argue with that," he says, chuckling mirthlessly.
                    
                    A companionable silence falls over you both, after that, and it is a while until Saine rises to excuse himself. "Thanks for the talk ${fname}. I think you're right—that I was rushing the decision, I mean. I'll think it over again."
                    *goto finalconflicted
                    
*label leonsection
Leon's smile is melancholic as he makes his way towards you, setting himself down with a soft thud. "I don't blame you," he says, motioning for you to join him on the grass. "It's a big day ahead."

You take a seat next to him, the night breeze a cool caress over your skin. Leon shifts beside you, his gaze distant.
*choice
    #"It's a rare night when you're not snoring in your tent.What's on your mind?"
        *set charming %+ 15
        *set precharming %+ 15
        "Nothing. Everything." The prince sighs, hugging his knees as he does. "Sorry, it's just…I'm scared, to tell you the truth.
        *goto wemarch
    #"You can talk to me about anything, Leon. You know that, right?"
        *set noble %+ 15
        *set prenoble %+ 15
        "I'm fine. Really." A silent beat, and then the prince sighs, hugging his knees as he does. "Sorry, you deserve better than false bravado. I'm…scared, to tell you the truth.
        *goto wemarch
    #"It'll turn out well tomorrow. You'll see."
        *set optimistic %+ 15
        *set preoptimistic %+ 15
        "I wish I could share your confidence," the prince sighs, hugging his knees as he does. "I hate to admit it, but I'm…scared.
        *goto wemarch

*label wemarch
Tomorrow we march on Sienan Keep, against whatever Mireil has in store for us. And...there are so many unknowns, ${fname}—too many."
        
"We knew this going in," you try. "Everyone in this army does."
        
"I know. Everyone has rallied around Julius's name, and I couldn't be more thankful, but…what if I lead them to their deaths?" The prince pauses, chancing a look on your face, his green eyes percolating with fear you'd thought the war had long since ironed out. "${fname}, what if I lead you to yours?"

*choice
    #"Then I die for your cause, and gladly."
        *set optimistic %- 15
        *set preoptimistic %- 15
        Leon looks at you for the first time tonight. It's hard to miss the grim set to his features. "Why?"
        *choice
            #"Because the cause is mine, too."
                *set rleon %+ 20
                "You seem to have forgotten, Leon—you're a leader, not an enslaver, and this cause is not yours alone. You don't get a monopoly on it, or the burdens it entails—all of us here share your vision, down to the last man." 

                "That may be so," the blond concedes, "But in the end it is [i]my[/i] crown, [i]my[/i] throne we are fighting for. And no matter how well tomorrow goes, the Keep will still be painted crimson with the blood of innocents."

                "Then that will be a debt incurred. Pay for it well with a just and compassionate rulership. [i]That's[/i] the crown, the future they are fighting for," you pause, carefully considering your next words. "You...aren't wrong, Leon. Tomorrow when we march on the Keep, many of us will lay dead on its floor before victory is won. But you risk your life too, same as any knight or peasant in that camp. You will brave the front lines, and after that, the crown. No sacrifice is greater than yours—do not forget that."
                *goto leonrelcheck
            #"Because I trust you, Leon. Unequivocally."
                *set rleon %+ 20
                "I don't deserve such faith." His voice is a whisper, eyes downcast.

                "You don't get to tell me where my faith ought to go," you tell him, solemn. "You are honest, compassionate, strong—all the qualities to make a good king, and I'm not the only one who sees it." You gesture in the direction of the camp—a massive, sprawling structure housing thousands, all with far more zeal and morale than their situation ought to rightly account for.

                "Then why has it turned out like this? Three thousand of our dead lie between here and Kantena!"
        
                "Any leader with half your mettle would've had us all join them before we ever see Sienan," you say slowly, carefully ruminating on every word. "It's been a hard road coming here, and it'll be a hard road moving forward—it's easy to lose perspective. But we would not be here for any other claimant, Leon. We are here because you, and you alone are [i]worthy[/i]."
                *goto leonrelcheck
    #"Actually, you'll find I'm rather good at avoiding death."
        *set charming %+ 15
        *set precharming %+ 15
        Leon looks at you despairingly. "This is no time for your jokes, ${fname}."
        *choice
            #"I'm not joking, though?"
                *set rleon %+ 20
                "You've seen what I can do, Leon. I've come too far and grown too much to fall for Mireil's tired old tricks."

                "How can you be sure?" He pulls his knees to his chest, and for a moment the seasoned warrior-prince falls away, leaving only a scared boy in his wake. "You've lost your most important person to her before. How can I be sure that I won't lose mine?"
                *goto leonrelcheck2
            #"Alright, but you need to loosen up."
                *set rleon %+ 20
                "Tomorrow will go well, you'll see," you say, attempting the most reassuring smile you could pull off. "We'll stop my crazy sister, and you'll sit on the throne, where you're meant to be."
           
                "How can you be sure?" He pulls his knees to his chest, and for a moment the seasoned warrior-prince falls away, leaving only a scared boy in his wake. "You've lost your most important person to her before. How can I be sure that I won't lose mine?"
                *goto leonrelcheck2

*label leonrelcheck
*page_break
*if (rleon > 64)
    "${fname}…"

    There is a magnetic quietness to his tone; you jerk your head to look at him, operating on pure instinct. The prince trains his own gaze at you, a novel medley of expressions made plain on his face—gratitude, admiration, and—longing? Under the vast carpet of starlight, his eyes seem to gleam like emeralds.

    The air is electric.
                
    "${fname}, I...I have never felt this way before, about anyone," he says. There is a high-pitched slur to his words, but he presses on earnestly. "I care about you. As more than just a comrade, more than just a friend. Before we go into battle tomorrow, I—I have to know. If you...feel the same way."
    *goto leonconfess
*elseif (rleon > 50)
    "${fname}...Thank you," he does not say as much as he whispers, gaze on something far away. "You're a true friend. Thank you for believing in this cause—in [i]me[/i]. I am honored to fight by your side."
    
    You find there is little you can say to Leon's earnest declaration, so you nod your acknowledgment as the prince fixes his gaze on the horizon.
    
    The conversation soon turns towards the oncoming battle and your plans for the future, and the night passes in a companionable haze.
    *goto endnightscene
*else
    "${fname}...Thank you," he does not say as much as he whispers, gaze on something far away. "I know we haven't always agreed on everything, but I'd still trust you with my life, ${fname}. You're a good person, and a hell of a fighter. I'm glad you're on our side."

    You find there is little you can say to Leon's earnest declaration, so you nod your acknowledgment as the prince fixes his gaze on the horizon.
    
    The conversation soon turns towards the oncoming battle and your plans for the future, and the night passes in a companionable haze.
    *goto endnightscene
*label leonrelcheck2
*if (rleon > 64)
    
    There is a magnetic quietness to his tone; you jerk your head to look at him, operating on pure instinct.
                
    "${fname}, I…" The prince bites down on his lips in solemn contemplation; for a second, he fixes his gaze on the blades of grass between his feet, and then he steels himself and looks you in the eye. "I have never felt this way before, about anyone. The mere thought of losing you—of you not being here, by my side…it terrifies me. More than I can express."

    "Leon, what are you say—"
    
    "I care about you," he says, gripping your hands in his own. There is a high-pitched slur to his words, but his gaze is steady as he presses on earnestly. "As more than just a comrade, more than just a friend. When the battle is joined tomorrow, there is no guarantee both of us will make it out alive, so I—I don't want anything to be left unsaid. I have to know, ${fname}. If you…feel the same way."
    *goto leonconfess
*elseif (rleon > 50)

    The Sun Prince holds your gaze in his own, and under the starlight you can see for the first time the tired lines of his face, the way his broad shoulders sag with the weight of his station. "I have lost so much in this blasted war, ${fname}; I'll be damned if I lose you, too. I'll make sure it doesn't come to pass."
    
    You find there is little you can say to Leon's earnest declaration, so you nod your acknowledgment as the prince fixes his gaze on the horizon.
    
    The conversation soon turns towards the oncoming battle and your plans for the future, and the night passes in a companionable haze.
    *goto endnightscene
*else
    
    The Sun Prince holds your gaze in his own, and under the starlight you can see for the first time the tired lines of his face, the way his broad shoulders sag with the weight of his station. "We haven't always seen eye-to-eye on everything, ${fname}—I know that. But everything you've done for Param…to repay you with death—I would never forgive myself. I'll make sure it doesn't come to pass."
    
    You find there is little you can say to Leon's earnest declaration, so you nod your acknowledgment as the prince fixes his gaze on the horizon.
    
    The conversation soon turns towards the oncoming battle and your plans for the future, and the night passes in a companionable haze.
    *goto endnightscene

*label leonconfess
*choice
    #Kiss him.
        *set rleon %+ 20
        *set leonrom true
        *set ilyarom false
        *achieve leonrom
        In a single swift motion, you lean and the distance between you closes, Leon flinching as your lips lock against his. The blond is statue-still at first, but in a second his hand is in your hair and he's returning the kiss, leaning in with a desperate sort of hunger.
            
        The lack of experience shows on both sides—the kiss is largely a clumsy affair, with teeth gnashing against lips and his grip a bit too tight for comfort around your chin. But some way, somehow, everything feels impossibly, improbably [i]right[/i]—like missing shards of glasswork slotting themselves into place. The interaction must've been brief—ten seconds, perhaps—but in your head time seemed to stretch infinitely, and when you pull away the both of you are gasping for air.

        "Wow, um," Leon says, still winded and breathless. Even in the low light you can make out the vivid red blush dusting his cheeks—and judging from the foreign, itchy flare you feel creeping up your face, you daresay your own expression mirrors his. "Can I take that as a yes?"

        *choice
            #"Yeah you can, you big oaf."
                  *set charming %+ 15
                  *set precharming %+ 15
                  "I find it a little hard to feel insulted right now," he says, smiling that lopsided grin of his that lights up his whole face.

                  "Yeah? Then I guess this is as good a time as any to tell you—you can't kiss for [i]shit[/i]."

                  His laugh is easy and bright. "You should help me practice, then, shouldn't you?"

                  "If I must," you laugh as he leans in for seconds. You're very pleased to find that the prince is a [i]very[/i] quick learner.
                  *goto endnightscene
            #Say nothing, just kiss him again.
                  *set charming %- 15
                  *set precharming %- 15
                  You forgo words in favor of a second round, the raging storm of emotions within you pouring out like a tidal wave against Leon's lips. A laugh escapes the blond's mouth, joyous and clear as a bell, as he leans into the kiss a second time.
                  
                  "Does this answer your question?" you ask in the end, forehead pressing against his.

                  "No, I didn't quite catch that," he says, smiling that dimpled grin of his that lights up his whole face. "Maybe you should tell me again."

                  And you do. A third time, a fourth, and soon you realize you've lost both count and care as the prince's lips claim yours once more.
                  *goto endnightscene
    #"I need more time."
        Leon tries his best, but there's no hiding the crestfallen look that graces his features. "Of course," he manages, valiantly schooling his expression. "But ah, I'm willing to...work on myself, on whatever's making you unsure, if you'll tell me." He offers, before covering his own mouth, mortified. "Wait, I'm sorry, you don't have to tell me! That is, I didn't mean to pressure you! Jove, I should probably stop talking, huh..."

        You watch as Leon continues to stumble over his words, a deep red shade dusting his cheeks. You will need to step in now, before the prince embarrasses himself to death.
        *choice
            #"For the record, I do feel the same. But..."
                Leon looks up at you, at once timid and expectant.
                *choice
                    #"I'm just not sure I could handle all that...comes with you."
                        The prince's face immediately blooms into a relieved smile. "I'm...glad. That you like me for me, I mean. And that you're giving this whole royalty thing a good think," he says, bashfully scratching at his cheek. 
                        *goto leonunderstand
                    #"I have some...issues to work through, before I can commit to something like this."
                        The prince nods thoughtfully, seeming to try his best to keep his smile even.
                        *goto leonunderstand
                    #"I've never thought of you that way, and I need time to sort myself out."
                        The prince's face immediately takes on a new expression—something like relief, you think, but not quite. "I'm...glad. That you're giving me a chance, I mean," he says, bashfully scratching at his cheek.
                        *goto leonunderstand
                    #"I'd rather not say right now. I'm sorry."
                        "No, of course." He gives you a warm smile, and you almost believe it. "If it's you...this much, I don't mind at all. I'll wait as long as you need."

                        "Thank you," you whisper, averting your gaze.

                        "Just...if it's okay with you, can you stay here tonight? I could still use the company," he grins.

                        You nod, obliging him, and he seems to phase into his regular self with ease. The conversation soon turns towards the oncoming battle and your plans for the future, and the night passes in a companionable haze.
                        *goto endnightscene
    #"I'm sorry."
        Leon is quick to turn away, but you could still see his expression in that split second before he does—the prince looked absolutely crestfallen. "I see," he manages, after a while. "If...if you don't mind, may I ask why?" He asks, before covering his own mouth, mortified. "Wait, I'm sorry, you don't have to tell me! That is, I didn't mean to pressure you! Jove, I should probably stop talking, huh..."

        The poor prince looks about ready to jump off the hill you're both sat on, his cheeks dusted with a vivid shade of red. You will need to answer now, before he does just that.
        *choice
            #"I simply don't swing that way."
                *goto leonstills
            #"I simply don't swing that way. Or any way, really."
                *goto leonstills
            #"I value your friendship too much to risk it like that."
                *goto leonfriend
            #"I just don't feel that way about you. I'm sorry."
                *goto leonhonest

*label leonunderstand
"I understand, ${fname}. If it's you, this much...I don't mind at all. I'll wait as long as you need."

"Thank you," you whisper, averting your gaze.

"Just...if it's okay with you, can you stay here tonight? I could still use the company," he grins.

You nod, obliging him, and he seems to phase into his regular self with ease. The conversation soon turns towards the oncoming battle and your plans for the future, and the night passes in a companionable haze.
*goto endnightscene

*label leonstills
Leon stills beside you at the answer. "Oh," he says, after a while. "Leave it to me to fall for someone I can't have," he attempts a humorous grin—neither of you buy it. "I hope this doesn't change anything between us. I'll...get over you, I swear it. Until then, please bear with me."

Meeting his gaze once more, you give him what you hope is a reassuring nod. An awkward sort of silence descends upon you both, and before long Leon excuses himself.

"Good night," he says, in the end, with a smile that doesn't quite reach his eyes.
*goto endnightscene

*label leonfriend
Leon stills beside you at the answer. "Oh," he says, after a while. "I'm...glad, I think. Certainly, you've been nothing but a true friend to me," he attempts an easygoing grin—neither of you buy it. "Then I hope this doesn't change anything between us. I'll...get over you, I swear it. Until then, please bear with me."

Meeting his gaze once more, you give him what you hope is a reassuring nod. An awkward sort of silence descends upon you both, and before long Leon excuses himself.

"Good night," he says, in the end, with a smile that doesn't quite reach his eyes.
*goto endnightscene

*label leonhonest
Leon closes his eyes mournfully as the words leave your lips. "I see. Thank you for being honest with me." he says, after a while. "I hope this doesn't change anything between us. I'll...get over you, I swear it. Until then, please bear with me."

Meeting his gaze once more, you give him what you hope is a reassuring nod. An awkward sort of silence descends upon you both, and before long Leon excuses himself.

"Good night," he says, in the end, with a smile that doesn't quite reach his eyes.
*goto endnightscene

*label endnightscene
*page_break

The sun still hangs low on the horizon when Leon marches the army out once more.

It is difficult not to notice the exceptional vigor lining the face of every man and woman, knights and mages and peasants come to claim victory and restore their lost kingdom. Many of their comrades lay dead and buried along the campaign trail, and they may very well share such a fate before the day is out.

Yet they look towards the Sun Prince leading them, his silver armor glinting in the morning sun, and find their spirits alighting anew. Where his blade points, enemies fall; Param's victory is assured.

*page_break

The first test to their resolve, as expected, was at the gates of Sienan Keep. The limestone masonry is as sturdy as you remember it, the battlements armed to the teeth: arrows and magefire come hurling down like a rainstorm, endless and deadly.

The soldiers do what they can against the assault, shields raised in warding, mages working feverishly to strike the projectiles as they come. Yet the siege proceeds at a painfully sluggish pace, owing largely to the keep's newly-erected gate. It glimmers with the harsh sheen of enchanted metal, and though the gate groans against the battering ram, it soon becomes clear that casualties will pile without your interference.

Blessedly, Sister's arcane wall is nowhere to be seen; not that it would have stopped you, when you've had a full two years to prepare countermeasures against it. Yet it's heartening all the same to not have to call on @{phantvar Satiel|Airas|Gweila|Nyx} so early in the battle.

But how will you deal with the enchanted gate?

*label gatechoice
*choice
    *selectable_if (alchemy > 65) #I prepared a vial of Rust Elixir for this exact scenario.
        *set prestige +5
        *set rustelixir true
        *set acounter +1
        *achieve bustgate
        At your will, the vial autonomously floats out of the folds of your cloak, crashing against the battering ram's warhead and coating it in a mystical amber sheen. Each time the warhead crashes against the gate, powdery red corrosions spread out on the enchanted metal;
        *label beforelong
        before long the gate gives into the relentless assault, shrieking as it careens by its hinges
        *label andclatter
        and clatters uselessly onto the palace grounds.
        
        "Charge!" Leon bellows at the army's forefront, his blade nimble as it glides over enemy throats and cuts them down like ribbons. Behind him
        *goto galvanized
    *selectable_if (spiritism > 75) #I can open multiple spirit gates to let the soldiers bypass the gate entirely.
        *set prestige +5
        *set spiritgate true
        *set scounter +1
        *achieve bustgate
        It's a daring move, and one that places incredible strain on you: you have to sustain multiple gates at once, to prevent the soldiers from getting flanked and cornered when they step out on the other side of the wall. But your mastery over the art is formidable indeed, and though fatigue sinks its teeth into your bones, the portals hold strong and steady. The last of the soldiers step through and you follow suit behind her, emerging on the other side to the sight of two armies locked in fierce combat.
        
        "Charge!" Leon bellows in the thick of the battle, his blade nimble as it glides over enemy throats and cuts them down like ribbons. Around him
        *label galvanized
        his army follows suit, galvanized by the valor of their Sun Prince, spearheads painted red as they find purchase in Salantir flesh. The air is thick with clanging metal and the scent of blood, but even at a glance it's clear that the Salantir are on the backfoot; the enemy commander sounds a call to fall back into the keep, and the rebellion makes them bleed for every inch of the retreat.
    *selectable_if (learning > 60) #I've seen this metal in a tome before...
        *choice
            *selectable_if (thaum > 74) #...and I know it melts under extreme temperatures. Cast Sunflame.
                *set prestige +5
                *set sunflame true
                *set tcounter +1
                *achieve bustgate
                It's an advanced thaum spell, just a tier beneath Skywrath, and so it's no surprise that in the whole of the Sun Prince's army, you are the only mage capable of casting it. At your will, the castle gate combusts instantaneously into a raging inferno, its flames a deadly orange as it bends and melts the metal underneath. The battering ram finds more leverage against the malleable steel, and
                *goto beforelong
            *selectable_if (thaum > 74) #...and I could Sunflame, but I think there's a better way.
                For all that Sunflame is a powerful spell, it's also incredibly taxing on the caster's stamina. The battle has only just begun, and it might be prudent to conserve as much stamina as you can.

                How will you proceed?
                *goto gatechoice
            *selectable_if (thaum <= 74) #...though nothing in my repertoire can exploit its weaknesses well.
                It would've been a surefire way to get the army through, but certainly not the only one. How will you proceed?
                *goto gatechoice
    #I need to conserve my strength. I help ward attacks from the battlements..
        And so you do. It is tedious work to thaum arrows into ash and cast minor defense enchantments, but most disheartening of all is the way that—despite your best efforts—around you knights still fall to the relentless volley of attacks. It is an expected cost in a battle of attrition such as this, though the thought is small comfort when so many of your comrades meet their demise, the earth turning scarlet as it drinks their blood.
        
        It is a forbiddingly long time until the gate gives into the relentless assault, its metal hinges shrieking as it careens
        *goto andclatter
*page_break
The chase takes you deep inside the keep, and the battle is joined anew in the royal atrium, where reinforcements spill out from adjoining corridors. It is here that Salantira's elites join the combat in earnest: chaos unfolds around you as the renowned Osirian thaumaturges enter the fray, ice and fire and lightning strewn about haphazardly under the hall's high ceilings.

Yet under the influence of Ilya's enchantments @{specialvar and supported by your thaum,|and supported by your volleys of Everblaze,|as well as your own,|and supported by your Visions of the Damned,} the rebellion manages to keep the tide in its favor. Though the archmages are powerful on their own they are few and far between, and as the Parami swarm around them they fall as easily as any common squire.

*page_break The air shifts.

Suddenly, inexplicably, weapons clatter to the ground as the rebellion soldiers tremble and claw at their own heads, the expression on their face one of pure terror. You frantically search about the room as they bodily throw themselves on the ground, thoroughly confused when you feel no such impulse yourself. Surprisingly, even Ilya—herself a mage of no low caliber—is doubled over by the grand staircase, her white hair trailing along the ceramic steps. To affect even her, whoever is performing this sorcery must be a formidable mage.

The Salantir seize the momentum to mount a counteroffensive, much like yourself entirely unaffected by the curse. Dodging a stream of stray magefire, your eyes dart around the room in search of the curse's caster, and some sort of nexus—for both must be here in this very hall, for the impact to be so severe. Eventually, you catch sight of…

*temp terrorbane1 false
*temp terrorbane2 false

*choice
    *selectable_if (learning > 60) #...a dark-cloaked mage bearing a familiar artifact—one you've seen in a tome before.
        *set prestige +5
        *set terrorbane1 true
        Your eyes widen as they land upon the glass orb, percolating with swirls of languid black mist. You recognize it immediately as the Dread Soul, an artifact fashioned by Salantira with knowledge gleaned from Arcadian lore. A difficult piece to craft, and more difficult still to wield, but a look about the room would tell you that the mage bearing it has managed both.
        *label encounter
        
        You'll need to dispatch it quickly, if the rebellion is to survive the encounter. How will you deal with the mage?
        *goto dreadattack
    *selectable_if (deacon) #...a dark-cloaked mage bearing a familar artifact—one of Deacon Thomas's favorites, in fact.
        *set prestige +5
        *set terrorbane1 true
        Your eyes widen as they land upon the glass orb, percolating with swirls of languid black mist. You recognize it immediately as the Dread Soul, an artifact that even the good Deacon sought and was unable to acquire. A relic fashioned by Salantira with knowledge gleaned from Arcadian Lore, the Dread Soul is capable of instilling mass terror so severe that it can bring an army to its knees—as the rebellion currently demonstrates.
        *goto encounter
    #...Saine, fighting to remain lucid. His sharp eye may be helpful in this situation.
        Saine groans as he pulls himself up, breath heavy with exertion as his mind fights against the curse's influence. You help him to his feet, letting the rogue sling his arm around your shoulder. "Saine," you whisper to him urgently. "I need your help. The curse's caster must be in this hall somewhere, but I can't find them? Can you help me?"
        
        The prince takes a shuddering breath, his eyes closed and brows furrowed. It seems he is not yet fully out of the curse's grasp.
        *choice
            *selectable_if (enchantment > 60) #I cast a Glyph of Dispel to wake him from the curse.
                *set prestige +3
                *set glyphofdispel true
                *set ecounter +1
                *set terrorbane1 true
                It would be impossible to counteract the curse's impact on a large scale, but with Saine as the lone target the enchantment poses no problems for you. Your Glyph brings him out of the trance, and clarity quickly returns to his green eyes.
                *label wheeze
                "${fname}," he wheezes, trying to regain his bearings.
                
                "Saine, quickly," you mutter urgently as around you the rebellion army is one-sidedly battered by the Salantir. "I need you to find an active curse-caster. They should be removed from the thick of the fighting, performing verbal incantations—and possibly, holding some sort of artifact. Can you spot anyone like that?"
                
                Saine's body remains weak in your arms, but his eyes are already lucid, scanning the room's every nook and cranny for possible culprits. It is the work of ten or twenty seconds before he points a trembling finger towards the hall's east, where a mage in pitch-black robes is furiously chanting over an orb-like artifact. "There," he breathes, weaning himself off your support to stand on his own. "I'll be fine, I just need some time to recover. Go, ${fname}—quickly."
                
                You don't wait for him to tell you twice.
                *goto dreadattack                
            *selectable_if (alchemy > 60) #I feed him a Draught of Clarity, a potion designed to counteract mental maladies.
                *set prestige +3
                *set draughtofclarity true
                *set acounter +1
                *set terrorbane1 true
                You only have a single flask of it on your person, enough for perhaps one or two doses. Thankfully, that's all you need: you force Saine's mouth open and pour the draught down his throat; the prince retches from the bitter concoction, but clarity soon returns to his green eyes.
                *goto wheeze
            *selectable_if (charisma >= 50) #I muster all the persuasiveness I can gather to shake him out of his reverie.
                *set prestige +2
                *set terrorbane1 true
                "Saine, listen to me," you mutter urgently. "Everyone is in danger right now, and you're our only hope. I promise you there's nothing to fear, as long as you wake up and help me. So please—I'm begging you, Saine, [i]wake up[/i]."
                
                Saine's head lolls slightly against your shoulder, but his brows furrow in focus and clarity slowly returns
                *label greeneyes
                to his green eyes. "${fname}," he wheezes, trying to regain his bearings.
                *goto wheeze
            #I wait for him to come around. I know he can do this.
                You wait for Saine to come to, slinging spells against the attacking Salantir in the meantime. And yet despite your best efforts, much of the defenseless rebellion is slaughtered before you. Dread quietly settles in the pit of your stomach, but soon Saine stirs against your shoulder, brows furrowing in focus and clarity returning
                *goto greeneyes

*label dreadattack
*choice
    #I move swiftly across the room, thinking of possible countermeasures while I do.
        You weave past the chaos and din of the battle, handily dispatching a couple of soldiers as you make a beeline for the mage. You get close enough to make out the artifact he's holding,
        *label instantanima
        and in an instant you're able to feel its magical anima, overwhelming as it radiates in waves. If you weren't sure of it before, you certainly are now: this is the curse's nexus, in the flesh.
        *choice
            *if (temp1 = "intrigue") #I already have my dagger out, don't I? I drive it cleanly through his heart.
                *set prestige +5
                *set terrorbane2 true
                And so you do. It takes ten seconds to close the distance between you, and less than one for the dagger to find purchase in his heart. His eyes widen in shock as he beholds the face of his killer, arms falling limp by his side as he draws one last, shuddering breath.
                                
                The artifact clatters uselessly against the stone floor.
                *goto breakcurse
            *selectable_if (enchantment > 70) #I can overload the nexus by piling my own enchantments on top of the caster's.
                *set prestige +5
                *set glyphofterror true
                *set ecounter +1
                *set terrorbane2 true
                The spell circle blooms in your hand as you cast your own Glyph of Terror—doubtlessly the spell being used to overwhelm the rebellion army—and direct its anima towards the artifact. The mage shifts uncomfortably as the artifact shakes and vibrates in his hands; he looks around for any possible signs of interference, but when his eyes lock with yours it is already too late. The artifact shatters in his hands, its pieces clattering uselessly on the ground.
                                
                The mage's eyes widen to a nearly inexplicable degree, and immediately he turns around and fades into the crowd. You let him do so, feeling a bit winded yourself. You have, after all, succeeded in averting the battle's most imminent crisis.
                *goto breakcurse
            #Let's do this the old-fashioned way: good old Morana's Wail.
                *set moranaswail true
                *set tcounter +1
                The spell circle blooms in your hand as you dart towards the mage, the air chilling from the spell as you bring it to bear. But the mage picks up on your sudden charge; he runs directly into a crowd of Parami soldiers, the dread in his eyes clearly hoping that you'll terminate the spell for fear of friendly fire.
                                    
                And yet you couldn't, even if you wanted to: the spell is fully primed and lurches forward of its own accord, tearing through several of your defenseless allies as it bounds towards the mage. You wince at the collateral damage,
                *if (thaum > 60)
                    *set prestige +3
                    but the spell does as it's supposed to: when the cold mist clears, the mage's body lies broken on the floor, his artifact cracked and broken beside him.
                    *goto breakcurse
                *else
                    *set prestige -3
                    and the grimace sets deeper still when the cold mist clears: your allies lie wounded on the palace floor, and the mage is nowhere to be seen.
                    *goto ilyacurse
            #A well-placed Fist of the Dark Lord should do the trick.
                *set fistofthedarklord true
                *set scounter +1
                The spell circle blooms in your hand as you dart towards the mage, the air chilling from the spell as you bring it to bear. But the mage picks up on your sudden charge; he runs directly into a crowd of Parami soldiers, the dread in his eyes clearly hoping that you'll terminate the spell for fear of friendly fire.
                                    
                And yet you couldn't, even if you wanted to: the spell is fully primed and lurches forward of its own accord, tearing through several of your defenseless allies as it bounds towards the mage. You wince at the collateral damage,
                *if (spiritism > 60)
                    *set prestige +3
                    but the spell does as it's supposed to: when the black mist clears, the mage's body lies broken on the floor, his artifact cracked and broken beside him.
                    *goto breakcurse
                *else
                    *set prestige -3
                    and the grimace sets deeper still when the black mist clears: your allies lie wounded on the palace floor, and the mage is nowhere to be seen.
                    *goto ilyacurse
    *selectable_if (intrigue > 74) #I move stealthily towards the mage, dagger already slipped out of my doublet.
        *set temp1 "intrigue"
        *set prestige +5
        *set terrorbane1 true
        You are no Saine, admittedly, but you make do with the cloak-and-dagger skills you've picked up during your travels. Lightly do your feet glide across the palace floor, weaving through the chaos and din of combat with silence and grace. You get close enough to the mage to make out the artifact he's holding,
        *goto instantanima
*label ilyacurse
*page_break

You fight the bile quickly rising in your throat as your eyes dart around the room, searching for the familiar flutter of black robes. Forcibly you throw yourself into the thick of the fighting, untangling yourself from the Salantir even as they cut down your allies, because this is it, everything will be over unless you can [i]find the bastard again[/i]—

A shriek pierces the air, followed by the sound of glass shattering. Your head swivels eastward and you find your quarry dead on the palace floor, Ilya standing over his body and blood running down her face. "That should do it," she wheezes, her enchantment evaporating into air.

*label breakcurse
*page_break The curse is broken.
*if ((terrorbane1) and (terrorbane2))
    *achieve terrorbane

It takes some time for the soldiers to truly regain their bearings, but even through the daze they fight tooth and nail to regain advantage. They successfully corner the Salantir against the grand staircase, the panic-stricken fighters properly outnumbered and quickly losing ground. You grimly acknowledge the retreat orders as it rings out from the top floor, watching as the Salantir file into the throne room to make their final stand.

You follow Leon and his rebellion as they give chase.

*page_break

The Sun Prince pauses at the doors of the throne room, snarling as he beholds a familiar woman: the one who murdered his brother in cold blood, whose face has been vengefully seared into his mind for the past two years. She regards him with an amused twinkle in her eyes, rising indolently from her throne as the Salantir form a barricade around her.

"I suppose congratulations are in order," she titters, flipping her hair over her shoulder. "You've finally managed to make it back, young prince! Poor Julius would have been [i]so[/i] proud."

"Keep his name out of your mouth, witch," Leon spits. There's an uncharacteristic tremble to his blade, his knuckles white where it grips the golden hilt. "He died a dignified death, in pursuit of peace. [i]You[/i]," he says, raising his blade high, "will die like a [i]dog[/i]. Charge!"

Sister cackles as the battle is joined once more, the air around her twisting as her spell circles manifest. It is a breath before a gash in space swallows her whole, another before you hear her whisper, low and sinister, [i]right next to you[/i]—

"Your friends wouldn't mind if I borrow you for a bit, would they?" she drawls, her arms wrapped around your shoulder. "I think we're due for a little [i]reunion[/i]."

You hear Ilya shout in your general direction, Saine panicked as he blinks in front of you, reaching his arm out. Your fingers ghost against his, once, quickly, but Sister's grip is steady around your neck and she [i]pulls[/i]. Adrenaline rushes to your brain, your feet scraping against the coarse carpet as you fall backwards: past the portal, and into the darkness.

*page_break

The world spins into focus as the portal spits you back out.

You bodily jerk yourself away from Sister the moment your feet find solid ground, the mage laughing freely as she careens and lets you go. "Welcome, ${fname}, to the Sanctum of Jove."

The Sanctum in question is a narrow but high-ceilinged space, decorated with rows of gold-trimmed pillars and ornate murals of celestial beings. Light penetrates into the room through a row of stained glass windows, refracting as it does into a kaleidoscope of colors. You note the shape of the ceiling, arching conically into a high steeple, and realize that Sister speaks truth: this can only be the Sanctum of Jove, a holy space in Sienan Keep's highest spire. It is sacrilege for you to set foot here, a space reserved for royalty, though you're sure a pardon could be arranged when you've been dragged here unwillingly by a murderous invader.

"Now, now, there's no need to glower." Sister walks languidly towards one of the windows, the filtered light painting her form shades of red and blue. "Now that your little [i]allies[/i] are out of the way, we should have nice, civil chat, don't you think?"

*label sisterz
*temp phanta ""
*if (phant1 = "Satiel")
    *set phanta "Satiels"
*elseif (phant1 = "Airas")
    *set phanta "Airases"
*elseif (phant1 = "Gweila")
    *set phanta "Gweilas"
*else
    *set phanta "Nyxes"
    
*temp triggerjoin false
*choice
    #That's fine by me. There are plenty of questions I want answered.
        "You always were the curious sort," she drawls, hand pressed against the window. "Go on, then. Ask of me what you will."
        *label sisterq
        *choice
            *disable_reuse #"Why did you do this?"
                "The invasion, you mean." It is not a question, so you do not answer. "Haven't I made my motivations plain, dear @{pronvar brother|sister|sibling}? Arcadia was the host of magic powerful enough to shake the world's foundation, a center of learning so far beyond these [i]ercei's[/i] grasp. And yet a whisper from the Church had Param and Salantira both level it to the ground.
                
                "Now even as these [i]ercei[/i] dance upon stolen land, the noble Arcadians are marginalized, the labor of their ancestors stolen from them! Does it not make you sick to your stomach? Is it not cause enough for vengeance?"
                
                "The Arcadians were en route to betterment, under King Julius," you argue. "Many now fight under his brother's banner. You still claim that this is all for them?"
                
                "[i]Them?[/i]" Sister hisses, slow and vicious. "No, not them. [i]Us.[/i]"
                *choice
                    *disable_reuse #"What do you mean by [i]us[/i]?"
                        Sister rolls her eyes. "Have you lost your capacity for basic Arvanian, too? You," she says, her black-lacquered nail pointed at you. "And me. We are [i]Arcadians[/i]."
                        *choice
                            #She must be lying. I'm [i]Salantir[/i]; I've got the noble blood to show for it!
                                *set emotional %+ 15
                                *set preemotional %+ 15
                                Sister takes in your disbelief with something like resignment. "Of course this is how it's going to be," she sighs. "Oh well. You don't have to believe me. It makes no difference
                                *label whenyou
                                when you'll die here either way."
                                *goto sisterq
                            #Of course I'm Arcadian. You can't forge deals with phantasma on research alone.
                                *set emotional %- 15
                                *set preemotional %- 15
                                Sister's brows arch in mild surprise as she notes your acceptance. "Hm. Maybe I've underestimated you, ${fname}. Though this changes nothing—you will still die here, by my hand."
                                *goto sisterq
                            #It doesn't matter. I have no loyalty to my past, only my present.
                                Sister takes in your nonchalance with something like resignment. "You always were so very shortsighted," she sighs. "Oh well. It's not like this will make any difference,
                                *goto whenyou
                     
            *disable_reuse #"Do you really think you have any chance of winning?"
                *set triggerjoin true
                Sister's smile is all teeth. "Should you be saying that, when that phantasma of yours is eating you alive? I am a master at my art, ${fname}. Don't look down on me when you can barely keep your powers under control."
                *choice
                    *disable_reuse #"I'm not the same mage I was two years ago."
                        Her smile glints like a dagger. "Neither am I."
                        *goto sisterq
                    *disable_reuse #"Even if you defeat me, your army is cornered."
                        "So what? That useless rabble have served their purpose," she says derisively. "As long as [i]you're[/i] removed from the picture, Arcadia's revival is assured."
                        *goto sisterq
                    *disable_reuse *if (triggerjoin) #"And if I told you I'd rather join you?"
                        Sister scoffs, incredulous. "Then you must take me for a fool. Did you not spend two years decimating my armies, ${fname}? Pawns they may be, but it saddens me still when my toys are so cruelly ripped apart. You're going to pay for that, of course."
                        *goto sisterq
                
            *disable_reuse #"Is Eli still alive?"
                You knew it was a stupid question, that you saw ${ehis} body burst into light before your very eyes; and yet in your dreams ${ehe}'d always be so vivid and alive—no limp body tattooed with seals, or warm brown eyes glassy from death's embrace—and foolishly, desperately, you had allowed yourself to [i]hope[/i].
                
                Sister's gaze on you is severe, incredulous. "A farce of a question," she chides. "$!{ehe} is dead, as surely as Julius is dead. Surely you're not foolish enough to believe otherwise."
                
                You close your eyes in solemn acceptance, the hope you held in your heart fizzling out like a dying ember.
                *goto sisterq
                
            #Time for talking is over. I immediately launch into an attack stance.
                Sister perks up when she feels your mana levels spike, detaching herself from the window and mirroring your stance with her own.
                *goto talonscome
    #There's nothing to discuss. Immediately attack her.
        *achieve attacksister
        Sister sighs as she feels your mana levels spike, but she meets your aggression and dutifully leans forward into an attack stance.
        *label talonscome
        Her talons come out, deadly and burning, and around her the air shifts under the weight of her magic, bending as the portal opens and swallows her whole once more.
        
        Instinct tells you that she'll reappear behind you, claws outstretched and heading for your jugular; instead, the void opens [i]underneath your feet[/i], forcing you into a stumble as Sister rises, swiping at your chest—
        *choice
            *selectable_if (intrigue > 74) #But I dodge her easily, rolling away from the blow.
                *set prestige +3
                Her gaze was transfixed on your feet before the attack—it is child's play to predict her next move.
                
                You lean back against Sister's assault as the talons burn through the air where your torso once was, rolling backwards into a practiced tumble and landing back on your feet. Few mages are capable of such acrobatics, but the Deacon's training saw to it that you were the exception rather than the rule.
                
                *label scowlsuccess
                Sister scowls at your successful maneuver. "Well done,"
                *label begrudging
                she says begrudgingly. "Ready for seconds?"
            *selectable_if (spiritism > 60) #I cast the Spirit Cloak I've been preparing.
                *set prestige +3
                *set spiritcloak true
                *set scounter +1
                The spell grants you temporary incorporeality, which ought to allow you to phase through Sister's attack unscathed.
                
                It's a risky move, as the spell is only active for a narrow window of time, but your timing was precise and the claws phase through your torso harmlessly. You use the opportunity to roll forward into a tumble, landing back on your feet two paces
                *if (injury = "brokenknee")
                    away. You grimace as your injured knee strains and nearly buckles under the weight, but you grit your teeth and remain upright, shifting into a fighting stance once more.
                *else
                    away and leaning forward into a fighting stance.
                
                *goto scowlsuccess
            *selectable_if (alchemy > 70) #I allow the attack to connect, reaching for the fast-acting potion stashed in my robe.
                *set prestige +3
                *set draughtofquickrecovery true
                *set acounter +1
                You grimace as the claws sear against your torso, tasting blood as your teeth bite down on your lower lip.
                *if (injury != "brokenknee")
                    Using the attack's momentum you roll backwards into a tumble, landing back on your feet as you bite the vial's cork and spit 
                    *label itout
                    it onto the floor. The blue liquid smokes as it spills from the vial and splashes across your wound, and the effect is instantaneous: the broken skin absorbs the potion hungrily, and it is two or three seconds before the wound is sealed, leaving you no worse for wear.
                *else
                    Using the attack's momentum you roll backwards into a tumble, grimacing as your injured knee strains under your own weight. But you grit your teeth and persevere through the pain, biting the vial's cork and spitting
                    *goto itout
                
                Sister scowls as she sees her assault undone. "Not bad,"
                *goto begrudging
            #I allow the attack to connect, because there's nothing I can do.
                You grimace as the claws sear against your torso, tasting blood as your teeth bite down on your lower lip. Using the attack's momentum you roll backwards into a tumble, landing back on
                *if (injury = "brokenknee")
                    your feet and grimacing as pain sears through both your chest and your injured knee. 
                *else
                    your feet as you clutch at your chest in pain.
                
                Sister preens at her successful assault, licking the blood painting her talons. "Tasty," she sneers. "Ready for seconds?"

"I am," you reply, feeling the foreign mana seeping, flooding through your body. Being put through Sister's portal had driven your mana circuits out of sorts, but the stage is now set for ${phant1} to make @{phantvar his|their|his|her} appearance. And given what it will cost you, you intend to put
@{phantvar his|their|his|her} powers to [i]very[/i] good use.

*page_break

${phant1}'s power roars as it comes to the surface, heavy and ancient and beating like a war drum. Sister leaps backward as she pours mana into the air, twin spell circles emerging in front of her. At her command they twist into Morana's Wail and Clay Cannon, bounding forward in quick succession with a velocity that promises death.

*choice
    *selectable_if (phant1 = "Satiel") #Call on Satiel
        *set holyaegis true
        Satiel stirs in your mind's eye as he senses imminent danger, scoffing when he identifies the threat.
        
        [i]Holy Aegis[/i], his voice booms in your head, and at once light dances at the tips of your fingers, twisting and curling into a spherical shield of blinding light. You feel the strain in your mana as Sister's projectiles connect, and yet the barrier holds strong: icicles and earthen cannonballs both disintegrate as they collide with Satiel's power, and when the shield is dispelled you stand fully unscathed.
        *goto dustclear1
    
    *selectable_if (phant1 = "Airas") #Call on Airas
        *set arcoferasure true
        Airas stirs in your mind's eye as they sense imminent danger, scoffing when they identify the threat.
        
        [i]Arc of Erasure[/i], their voice drawls lazily in your head, and at once their power manifests against the incoming projectiles. Icicles and earthen cannonballs both lose their constitution as they lurch towards you, their composition flaking out of existence at Airas's command. When you can no longer feel the ancient hum of the Beckoning Hand's power singing in your veins, both of Sister's projectiles have wholly disintegrated into air.
        *goto dustclear1

    *selectable_if (phant1 = "Gweila") #Call on Gweila
        *set songofalacrity true
        Gweila stirs in your mind's eye as he senses imminent danger, features twisting into reckless glee when he identifies the threat.
        
        [i]Song of Alacrity[/i], his voice cackles in your head, and at once his power settles upon your entire body like a coat. Immediately you are besieged by a sensation of weightlessness, and as if of their own accord your feet glide across the 
        *if (injury = "brokenknee")
            floor, limp and all,
        *else
            floor
        in automatic, instinctual movements. The projectiles wheeze past you harmlessly as you dance and weave around their arc, and when you hear the sound of their impact against the sanctum wall you're still standing, perfectly unscathed.
        *goto dustclear1

    *selectable_if (phant1 = "Nyx") #Call on Nyx
        *set danceofthedead true
        Nyx stirs in your mind's eye as she senses imminent danger, her black lips curling into a sinister smile when she identifies the threat.
        
        [i]Dance of the Dead[/i], her voice whispers in your head, and at once a thick black mist materializes in front of you, spitting out undead by the dozens. The cold bodies pile themselves atop one another, glassy eyes rolling as they climb and claw over their brethren and lumber towards the projectiles.
        
        Many are decapitated and maimed when the attack connects, but whatever appendages remain continue to flail against icicles and earthen cannonballs both. When the spells are dispersed, the undead meatshield still maintains half its original number, groaning in wait of their next order.
        *goto dustclear2

*label dustclear1

But when the dust clears,
*goto sisterno

*label dustclear2

The dust clears, and
*label sisterno
Sister is nowhere to be seen.

*page_break

"Miss me?"

Sister leans into a lunge even as she whispers beside you, and it is only adrenaline from the previous attack that lets you dodge the fatal slash she aims to your throat. You leap backward with the momentum, pivoting on your
*if (injury = "brokenknee")
    good
*else
    right
leg and instinctively reach for the first spell that comes to mind:

*choice
    *selectable_if (thaum > 49) #Morana's Wail
        *set moranaswail true
        *set tcounter +1
        *set thaum %+ 10
        The spell manifests with a chill, glimmering ice flakes consolidating into icicles that launch themselves towards Sister at high speed.
        *label quickcasting
        Your quick casting catches the older mage off guard as she fights against her attack's inertia, the impetus throwing her right into the path of your deadly spell. Her eyes widen as the attack hurtles mercilessly in her direction; it is all she could manage to draw her claws in front of her torso, letting the burning talons blunt what would otherwise be a direct hit.
        *goto nonsubj
    *selectable_if (thaum > 75) #Sunflame
        *set thaum %+ 10
        *set sunflame true
        *set tcounter +1
        Sister's eyes widen as she recognizes your incantation, but the older mage is still fighting against her attack's inertia, the impetus landing her too far to prevent you from casting the spell. The runes complete their circuit around your fingertips, and in a second the air around Sister shimmers before it [i]combusts[/i]. The mage wails as she casts a Glyph of Resistance on herself, allowing her to escape the worst of the damage though her skin still burns and smokes from the assault.
        *goto nonsubj
    *selectable_if (alchemy > 49) #Clay Cannon
        *set alchemy %+ 10
        *set claycannon true
        *set acounter +1
        You thank your lucky stars as you feel the alchemic mounds in your robe's inner pockets. The spell circle blooms to life at your command, the clay exploding in size as it passes through the circle
        *label andfires
        and fires towards Sister at high speed.
        *goto quickcasting
    *selectable_if (spiritism > 49) #Fist of the Dark Lord
        *set spiritism %+ 10
        *set fistofthedarklord true
        *set scounter +1
        The portal manifests with an arcane chill, shrieking as the otherworldly bludgeon emerge from its depths
        *goto andfires
    *selectable_if (enchantment > 49) #Glyph of Subjugation
        *set enchantment %+ 10
        *set glyphofsubjugation true
        *set ecounter +1
        Sister's eyes widen as she recognizes your incantation, but the older mage is still fighting against her attack's inertia, the impetus landing her too far to prevent you from casting the spell. The runes complete their circuit around your fingertips, and in a second the ground beneath Sister shimmers before it [i]shines[/i]. Sister screams in anguish while her consciousness is overridden and confined into the depths of her mind.
        *goto subjugate
    
*label subjugate

Sister stills as the spell reaches completion, making for an eerie sight when moments ago she had moved quicker than your eyes could follow. The order is a simple one, and it leaves your lips quickly, easily. It is a second before Sister's talons are pointed at herself, poised to stab deep into her abdomen and end her reign of terror once and for all.

Just as you're about to let out the breath you'd been holding in, Sister's mana spikes once again as she overpowers part of your spell; though the talons descend upon her still, their trajectory went askew—in the end, the older winds up with an arm injury in lieu of a fatal wound.

Sister smiles as she dispels the remnants of your influence,
*goto commendation

*label nonsubj

Sister is still smiling as she reels from your attack,
*label commendation
commendation ready at the tip of her tongue. "Well done, ${fname}. Good to see you're not [i]completely[/i] helpless without your phantasma. But playtime," she says, her mana levels spiking dangerously, "is over."

Sister reaches out both her arms towards the ceiling, her pitch-black mana angry and crackling as it swirls around her. An arcane gale churns about the room, setting both your robes and Sister's to flutter, the flooring underneath her feet depressing under the weight of her spell. A chasm forms in the air, a sphere of dark matter reverberating with violent magic, and it grows and grows until it's big enough to swallow you thrice over. Sister's eyes are blood-red, luminous with exhilaration as she declares: "Worldscar."

And she throws. [i]She throws the portal.[/i]

*page_break

Instantly, instinctively, you call upon ${phant1} once more, the ancient force quick to acquiesce as @{phantvar his|their|his|her} power hums in your bloodstream. There is no time for second-guessing with danger so imminent, no opportunity to assess the cost of your invocation.

And so you let @{phantvar the High Intercessor|the Beckoning Hand|the Clear-Sighted|the Condemned} 
dominate the flow of your mana; you play vessel to this foreign might, this [i]phantasma[/i], and feel your mana ducts fry as 
@{phantvar his|their|his|her} full power is made manifest.

*temp breakwall false
*if (phant1 = "Satiel")
    *set breakwall true
    *page_break "Great Intercession."
    *set greatintercession true
    The sensation flooding through your system is undescribable; you feel as if you've ascended to a higher plane of existence, like Sister's mass of dark energy is naught but an insignificant fly buzzing at the table of a god. You stare her spell down even as it sails towards you at an alarming speed. Satiel's mana seeps out from your pores, setting the air to glimmer, ignite, [i]burst[/i]; in an instant it consolidates into a host of consecrated light, matching the Worldscar in size but roaring with a different, [i]stronger[/i] kind of might. The spell hums as it bounds forward, slabs of stone flooring lifting where it grazes them, meeting the dark mass of energy and [i]swallowing it whole[/i].
    
    Sister is wide-eyed as she throws herself to the side, yet she is still caught in the spell's impact as it arcs past her and takes out an entire sanctum wall. Power hums heavy in your veins as Sister is slammed against a golden pillar, and when she sinks to the ground she is fully battered and barely lucid.
*elseif (phant1 = "Airas")
    *set breakwall true
    *page_break "Arc of Inception."
    *set arcofinception true
    The sensation flooding through your system is undescribable; you feel as if you've ascended to a higher plane of existence, like Sister's mass of dark energy is naught but an insignificant fly buzzing at the table of a god. You stare her spell down even as it sails towards you at an alarming speed. Airas's mana seeps out from your pores, lurching towards the dark mass and engulfing it whole; in an instant the spell bursts out of existence before reforming again, whirling thick and heavy as it veers—[i]towards Sister[/i].
    
    Sister is wide-eyed as she throws herself to the side, yet she is still caught in the spell's impact as it arcs past her and takes out an entire sanctum wall. Power hums heavy in your veins as Sister is slammed against a golden pillar, and when she sinks to the ground she is fully battered and barely lucid.
*elseif (phant1 = "Gweila")
    *page_break "Avatar."
    *set avatar true
    The sensation flooding through your system is undescribable; you feel as if you've ascended to a higher plane of existence, like Sister's mass of dark energy is naught but an insignificant fly buzzing at the table of a god. You stare her spell down even as it sails towards you at an alarming speed—but for all that it comes lumbering and deadly, it does not strike you so much as you strike [i]it[/i], the host of dark matter splintering away from your form as if cleft by a divine axe.
    
    You do not give time for Sister to react to her failure. Immediately you bound forward as if propelled by an explosion, and when your fist connects against her abdomen—once, twice, four times, six—you feel her ribs give way under the force, blood spilling profusely from her gaping mouth. Her broken form hurtles across the room, smashing against a golden pillar, and when she sinks to the ground she is fully battered and barely lucid.
*else
    *page_break "Soultaker."
    *set soultaker true
    The sensation flooding through your system is undescribable; you feel as if you've ascended to a higher plane of existence, like Sister's mass of dark energy is naught but an insignificant fly buzzing at the table of a god. You stare her spell down even as it sails towards you at an alarming speed, because Nyx's power is already in the air, [i]already behind Sister[/i] as the mist takes her hostage, thick and black and virulent. Sister clasps at her throat as she feels her soul leave her body, frothing at the mouth and losing control over her spell.
    
    Her body is tossed to the side and her spell follows suit, arcing sideways from you and taking an entire sanctum wall with it on its way out. Power hums heavy in your veins as Sister is slammed against a golden pillar, and when she sinks to the ground she is fully battered and barely lucid.
*page_break

You take a shuddering breath as ${phant1}'s power leaves you, barely upright when you approach the black-haired mage. The terror that has haunted you all your life, now laying powerless and broken, within an inch of her life.

*temp mcline 0
*choice
    #"This is the end of the line, Sister."
        *set mcline 1
    #"Was it all worth it, in the end?"
        *set mcline 2
    #"This one is for Eli."
        *set mcline 3
    #"I wish it didn't have to turn out this way."
        *set mcline 4
    #"Finally...finally, I'll be free."
        *set mcline 5

*label sisterarc
*comment ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ SISTER FLASHBACK SECTION~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
*comment MC is 2
[i]She is seven when Father brings ${them} home, a wisp of a child with swollen cheeks and startling ${eyecolor} eyes.[/i]

[i]"Another one, Father?" she asks, and when he turns the man looks as he always does, scowling, severe.[/i]

[i]"This one is different, brat. Pure talent, untainted—a true Mateus."[/i]

Mateus. [i]The name rings like a siren call in her head, the elusive mirage that always curled on the tip of Father's tongue. And here it is, in the flesh, with its carefree smile and chubby hands that grab at her hair.[/i]

[i]"Prepare the ritual. We will begin immediately," he orders, curt as ever. She nods her head and moves to obey him.[/i]

[i]The little thing cries when Father begins, when the incisions are made and the runes set aglow. For all that ${they} @{plural are|is}[/i]
[i]heritor to some lofty legacy, ${they} @{plural bleed|bleeds} and[/i]
[i]@{plural weep|weeps} as easily as any child.[/i]

[i]"I thought you'd be stronger," she says when Father finishes, when ${their} tears streak across ${skintone} skin.

[i]She watches ${them} all night.[/i][/i]
*page_break
*comment MC is 7
[i]She is twelve when the woman perches by the windowsill, her pale gold locks gleaming against the light of the moon.[/i]

[i]"So talented, for one of the Roumen," the woman breathes, and for a moment the girl is transfixed by her ethereal beauty, the languid drawl of her voice. "But what has been done to you? For[/i] ercei [i]hands to tamper with Arcadian blood…revolting."[/i]

[i]She snaps out of her trance, then, moves out of her covers and feels magic burn to the surface. It shoots from her fingers, bright orange and violent, but when it grazes the woman's skin the flames twist into nothing.[/i]

[i]"I can help you, child," the woman whispers then, her slender fingers around the girl's jaw, blood-red eyes a mirror of her own. "But you must talk to me."[/i]

[i]Her lips make to obey the command, bewitched by her words, but the arcane collar tightens against her neck and it is all she could do to wheeze. The older notes her desperation, the way her nails dig into the skin of her neck, and at once she wraps her arms around the girl.[/i]

[i]"What a cruel trick. You've suffered too much, you poor child," she's saying, and the warmth of her embrace is at once foreign and familiar—she almost wants to cry. The woman's fingers trail across her nape and she can feel the collar break, dissipating into air. "There we are. Now tell me everything, child. Everything he's done to you."[/i]

[i]She does, and the woman listens. She listens even as her words jumble and trip over themselves; she listens even when the tears come, slow, and sparse.[/i]
*page_break
*comment MC is 11 when they escape
*comment MC is 15
[i]She is twenty-one when the court calls her Royal Mage, when she has the duke firmly under her thrall.[/i]

[i]It was child's play to see her father dead, once the collar was broken. Easier still to guide the duke to her @{pronvar brother|sister|sibilng}, to slip the drug into his tea once he let his guard down.[/i]

[i]"You'll help me, won't you, Duke?" she's saying, and the man nods obediently, eyes glazed over as he hangs onto her every word. "Very good. There is much you must do before Salantira's sins are fully repaid…"[/i]

[i]She thinks of Eli, ever soft-hearted, at the edge of madness as ${ehe} took ${ehis} tutor's life. She thinks of her @{pronvar brother|sister|sibling}, so young and innocent—in spite of[/i]
[i]@{pronvar his|her|their} power, the lofty call of[/i]
[i]@{pronvar his|her|their}  blood.[/i]

[i]"…so you'd better get to work, hm?"[/i]

*page_break
*comment present time, MC is 23
[i]She is twenty-nine when her @{pronvar brother|sister|sibilng} returns, having grown into[/i]
[i]${their} powers, a darkness in ${their} eyes she did not think ${them} capable of.[/i]

[i]She watches quietly as the world spins and swims in her vision, as the younger approaches and holds her gaze in his own. She should've known better than to attempt to fight a Mateus, should've listened to her mentor when she said[/i] come back,
${they}
@{plural are|is} too strong for you and you've done enough.

[i]She did not listen; how could she? She had worked so hard to overcome the limits of her bloodline—too hard to believe that for all that she's sold to the devil, all the hours she spent poring over yellowed tomes and buckling under ancient spells, she still couldn't measure up to ${them}.[/i]

[i]Her @{pronvar brother|sister|sibilng}, her unwitting tormentor—and soon, her executioner.[/i]

Stop it, [i]she wants to say.[/i] Don't you dare look down on me. [i]But she is at the end of her lifeline, and there's still one last thing she must do; and so despite the anger burning inside her, white-hot and blinding, she forces herself to quiet, to listen as[/i]
[i]the words leave ${their} lips:[/i]

*if (mcline = 1)
    
    "This is the end of the line, Sister."
    *page_break
    Sister chuckles even as her vision clouds, the action setting her wounded form to shudder. "So it is," she says, hoarse, defeated. "I suppose I should congratulate you."
    *label congratulate
    *choice
        #"Congratulate me, then, so I can kill you and be done with it."
            *set emotional %- 15
            *set preemotional %- 15
            "You've grown so cruel while I wasn't looking," she manages, wheezing all the while. "But you see…you're not done with me just yet."
        #"We've really done it. Param will know peace."
            *set optimistic %+ 15
            *set preoptimistic %+ 15
            "You sound so much like that Julius, you know," she manages, wheezing all the while. "Pity for you, ${fname}—you're not done with me just yet."
        #"We will never fully recover from the horrors you've inflicted."
            *set optimistic %- 15
            *set preoptimistic %- 15
            "What's this? Already thinking of recovery, are we?" she wheezes as much as she laughs, and the sound rings bitter in your ears. "It's not smart to count me out just yet."
        #"So many people suffered because of you. Too many."
            *set emotional %+ 15
            *set preemotional %+ 15
            "What's this? Eli had rubbed off on you before ${ehe} went and died, it seems," she wheezes as much as she laughs, and the sound rings bitter in your ears. "But you see, ${fname}…it's not smart to count me out just yet."
    *goto afterdialogue
*elseif (mcline = 2)
    
    "Was it all worth it, in the end?"
    *page_break
    Sister chuckles even as her vision clouds, the action setting her wounded form to shudder. "There is no question of [i]worth[/i], ${fname}. I only saw what had to be done, and did it. You did the same—the difference is that you came out on top. I suppose I should congratulate you."
    *goto congratulate
*elseif (mcline = 3)
    
    "This one is for Eli."
    *page_break
    Sister chuckles even as her vision clouds, the action setting her wounded form to shudder. "Has it been nine years, ten? And ${ehe} still haunts you so? Perhaps this little vengeance of yours can dispel ${ehis} ghost—I suppose I should congratulate you."
    *goto congratulate
*elseif (mcline = 4)
    
    "I wish it didn't have to turn out this way."
    *page_break
    Sister chuckles even as her vision clouds, the action setting her wounded form to shudder. "And yet this is the way it must be. You made your choice when you left with Eli, and I made mine long before. We were bound to stand on opposite ends, and you managed to come out on top. I suppose I should congratulate you."
    *goto congratulate
*else
    
    "Finally...finally, I'll be free."
    *page_break
    Sister chuckles even as her vision clouds, the action setting her wounded form to shudder. "You did well to escape my grasp for nine years, ${fname}. Better still to come out on top—I suppose I should congratulate you."
    *goto congratulate
*label afterdialogue

Immediately, a massive spell circle materializes underneath your feet, pulsing with Sister's pitch-black mana. It stretches out beyond the confines of the Sanctum, beyond where you can see, and it is with a slow, sinking sense of horror that realization dawns upon you.

The runic arrangement that spans the entire room is only the innermost ring of the glyph, perhaps only a twentieth of the full spell. The size alone gives you pause—constructing and powering such sorcery should've rendered its caster fully catatonic. But most alarming of all are the runes Sister has written in the arcane script, carefully arranged in neat concentric rings: gather, time, [i]detonation.[/i]

Sister gazes up at you through half-lidded eyes, her lips curled into a conceited smirk. "Three months. In three months' time, the spell will be fully primed and detonate; it will take all of Sienan with it."

*choice
    #"How could you do this?"
        *set emotional %+ 15
        *set preemotional %+ 15
        "Are you really surprised, ${fname}? I've hardly been a saint thus far," she chuckles.
        
        "But to do something like this, just for the sake of it…you're absolutely [i]inhuman[/i]."
        
        Sister's eyes widen in a moment of lucidity, and with a strength you didn't know she had she bodily jerks forward, her hand a vicegrip around your neck. "That's right, ${fname}. I'm a damn monster, so you had better remember me well," she hisses, her voice rasping from the strain, nails digging into your skin. "And like the monster I am, I'll leave you one last thing to remember me by."
        *goto conjurethaum
    #"This changes nothing. Three months is plenty of time for me to dispel your magic."
        *set emotional %- 15
        *set preemotional %- 15
        "I spent two years building this curse, ${fname}. You think you can undo it so easily?"
        
        "You sorely underestimate Parami mages, Sister. I'll have plenty of help."
        
        Sister's eyes widen in a moment of lucidity, and with a strength you didn't know she had she bodily jerks forward, her hand a vicegrip around your neck. "We can't have that, can we?" she hisses, her voice rasping from the strain, nails digging into your skin. "Fight my curse fair and square, ${fname}. By. Your. Self."
        
        *label conjurethaum
        You conjure thaum against her in reflex, slamming her once more against the pillar, but realize with sinking dread that you are too late. You feel the arcane collar blossom against your neck, a sensation you haven't felt in a lifetime—not since Thaubal Altinier's death.
        
        "What a convenient tool…Father left me," she preens, even as she's sagging to the floor, even as her lids close upon themselves. "Now then…show me…a good performance…"
        
        And with a final, gasping breath, Sister's form goes slack on the marble floor.
        *goto aftersister
    #"I'll make sure everyone evacuates the city. Everything else can be rebuilt."
        *set noble %+ 15
        *set prenoble %+ 15
        "What's this? You won't even attempt to best me?"
        
        "I have no desire to compete with a dead woman, Sister. Parami lives are more important."
        
        Sister's eyes widen in a moment of lucidity, and with a strength you didn't know she had she bodily jerks forward, her hand a vicegrip around your neck. "You disappoint me, ${fname}," she hisses, her voice rasping from the strain, nails digging into your skin. "Then I suppose I'll have to force your hand, won't I?"
        
        *goto conjurethaum
    #Why give her gloating an audience? I have to tell Leon about this, immediately.
        *set noble %- 15
        *set prenoble %- 15
        "You're far too cold to your dear Sister, don't you think? Have some respect for my final act, ${fname}."
        
        "There will be audience enough for your platitudes in hell. I've got other things to attend to."
        
        Sister's eyes widen in a moment of lucidity, and with a strength you didn't know she had she bodily jerks forward, her hand a vicegrip around your neck. "You know I'm the jealous type, don't you, ${fname}?" she hisses, her voice rasping from the strain, nails digging into your skin. "So I'll [i]make[/i] you pay attention to me."
        
        *goto conjurethaum
*label aftersister
*page_break
*achieve defeatsister
Leon bursts in through the door, then, his cadre of elite knights trailing behind him, with Saine bringing up the rear. "${fname}, are you al—" The prince's words come to a grinding halt, his jaw dropping as he takes in the sight of the room.
*if (breakwall)
    You follow his gaze east, towards the sanctum wall that ${phant1} took out, and watch as the prince swallows a nervous gulp.
*else
    You follow his gaze behind you, towards the clobbered pillar where ${phant1} made @{phantvar his|their|his|her} mark, and watch as the prince swallows a nervous gulp. 

"Ah, that is—I'm glad to see you alive," the prince says, making his way towards you. "Ilya is downstairs, tending to the wounded. We'll need to get you to her, judging by the look of you—"

"Brother, wait," Saine mutters behind him. "${fname}, just where is…?"

You move aside in anticipation of his next words, your form giving way to Sister's crumpled corpse. Some of the knights rear back in a horrified reflex; you could hardly blame them. So many of their comrades laid down their lives in the war, and here was the woman responsible for their deaths, sprawled out like a scarecrow on the marble floor.

Saine was the first to speak again. "Is she…?"

You nod in confirmation. "Dead."

*page_break

A hushed silence falls across the room, then, the knights turning towards each other with disbelief etched plain onto their features. "Is it…really over?" you hear a brown-haired paladin whisper, her brows furrowed in skepticism.

"It's over," Saine confirms, quiet as an oath, as if the truth might break if he wasn't careful with it. And then that green-eyed gaze look up to hold your own, and through a grin that spans nearly his entire face the younger repeats the words, loud and assured: "It's over!"

*page_break

The tension shatters like glass, then, the knights clapping each other on the back and weeping openly against their gauntlets. Immediately they speak of their families, daughters who feared fathers coming home as corpses, lovers who tied knots against wiry trees and bent their knees in prayer. They speak of farmsteads and warm meals and lives worth living, and as you look around the room it is as if in ten seconds everyone had aged years in reverse.

[i]Home[/i], they breathe, careful, reverential. It had been a long war, a terrible war, and though blood had been shed in countless measures they think of the peace it bought in its stead and can't help but to smile. [i]Home.[/i]

Saine crashes against your torso, then, his arms wrapped tight around your waist as his tears begin in earnest. Leon follows suit behind him, still shaking his head in disbelief, but he throws his arms around you all the same and laughs at his brother's crying—as if he wasn't on the edge of tears himself.

When he parts from the hug the Sun Prince is smiling broadly; he speaks happily of a brother avenged and a kingdom won, blissfully unaware of the acute dread slowly sinking in the pit of your gut.
*page_break
*set memorypoint "complete_victory"
*goto_scene Junction