*comment Chapter 3 - Weeping Twilight
*image header_c3.png center Chapter Three, Sickle Moon. Pale death waxes and wanes against the night sky.
*page_break

The burning midday sun beats down relentlessly on your exhausted body, and you realize too late that a black robe probably wasn't the best choice of outfit for today. Between the merciless heat, the fatigue setting in your bones, and the attentive eyes of an expectant crowd, you find your senses to be wholly overwhelmed.

Of course, there's also the matter of the master swordsman charging at you. The velocity of his assault promises nothing but pain.
*page_break
"Hah! Hah! Hiyah!"

Leon continues his relentless assault, kicking up a storm of dust as he does and using it to his advantage. Between his agile, powerful blows and your clouded vision, you can tell you're losing ground quickly.

If you're to mount a counteroffensive, now is the time to do it.
*temp choices true
*if (thaum > 60)
    *set choices true
*elseif (enchantment > 60)
    *set choices true
*else
    *set choices false

*choice
    *selectable_if (thaum > 60) #Cast an explosive spell to blow him away.
        *set thaum %+ 10
        *set flametongue true
        *set tcounter +1
        Avoiding a strike of Leon's blade, you trigger the spell circle before it completes. Your mana all but hemorrhages into the air around you, but the spell achieves its intended effect. Leon raises his blade against the brunt of the spell, and the holy steel soaks it like water. It is a splinter attack that catches Leon on the torso, and you count it a small victory that the small explosion sends him reeling.

        The swordsman regains his footing in a second, breastplate noticeably singed but otherwise unharmed. "That was good, but can you keep it up?"
    *selectable_if (enchantment > 60) #Cast a defensive buff on yourself.
        *set enchantment %+ 10
        *set glyphofprotection true
        *set ecounter +1
        Avoiding a strike of Leon's blade, you trigger the spell circle before it completes. Your mana all but hemorrhages into the air around you, but the spell achieves its intended effect. The Glyph of Protection settles against you like a second skin, a sturdy failsafe that's gotten you out of plenty of close calls before. Leon is undoubtedly a skilled swordsman, but you've sparred against him before, and not even he can—

        Leon's blow catches you from the side and sends you reeling backwards. As you're left bowing from the impact and gasping for breath, you notice that the Glyph is all but torn to pieces.

        That sword is trouble. "Wow, this blade is better than I remember," the prince remarks, grinning.
    *if ((choices = false) or (spiritism > 60)) #Summon some spirits to distract him.
        *set spiritism %+ 10
        *set visionsofthedamned true
        *set scounter +1
        Avoiding a strike of Leon's blade, you trigger the spell circle before it completes. Your mana all but hemorrhages into the air around you, but the spell achieves its intended effect. A portal opens between you and Leon, and out pours several ghastly spectres. The ghastly beings wail as they launch themselves, flying at high velocity in Leon's direction—

        And the prince dispels them with three swipes of his blade. Perhaps summoning spirits wasn't the best option against a holy sword, you think in hindsight. "Come on, ${fname}, you should know better than that," he laughs. "Here I come!"
*page_break
Leon charges in for a second pass, and he comes too quickly for you to form a proper magic circle. You try anyway in a desperate bid for self-defense, but Leon slams the flat side of his blade against your torso. The attack knocks the wind out of you, and sends you sprawling onto the hard ground.

"Yield," he says, the blade pointed at your throat.
*choice
    #Do as he says.
        "I yield."
        *page_break
    #Attempt to reverse the situation by throwing some sand into his eyes.
        *set noble %- 15
        *set prenoble %- 15
        Nothing fancy, but you can think of no other alternative else in this situation.

        Unfortunately, Leon notices your gambit just in time, and he jerks his head just enough to save his right eye from the attack. He winces in pain as some of the particles enter his left eye socket, but in a remarkable show of self-control he does not budge a single inch.

        "Playing a little dirty, aren't you?" Leon groans under his breath, his one-eyed gaze intense enough to match the sun's glare. He pushes the blade against your jugular, the blessed steel cold to the touch. "[i]Yield[/i]."
        *page_break "I yield."

*achieve retainer
Leon grins as he sheathes the blade, hand swiping at the beads of sweat rolling down his face. You grip the hand he holds outs and he hoists you to your feet. "Well fought, ${fname}. You definitely would've done me in if it weren't for this blade."

"Well fought, indeed," hums an amused voice from behind you. King Julius approaches you with a warm smile, the procession of guards around him sturdy as fortress walls. His cascade of golden hair matches Leon's, though the tired lines of his face and the slack of his posture speak of a wholly different lifestyle. "I daresay you've more than proved your worth. Ignis?"

"Yes, Your Majesty," replies the greying knight at his side—you recognize him as Ignis, Captain of the Royal Guards. "The challenger lasted 21 minutes and 35 seconds against the Blade of Trials—well over the 10-minute requirement."

"And the longest anyone has lasted in 20 years, if memory serves," the King adds. "Congratulations, Brother. You've found a true gem."

Leon nods happily, slinging his arm around your shoulders. "I've finally got a retainer, then. I thought this day would never come."
*page_break
*set settinghistory true
It's not a very bright tradition, if you do say so yourself. Few knights would be able to keep up with Leon in a normal fight, but equipped with the consecrated blade, a treasured relic of the Holy Kingdom, he becomes a veritable monster. It's a small wonder he's gone without a retainer for so long.

The king utters a few whispered words to Ignis, and soon whirls on his heels towards you. "I bid you welcome to the knighthood, ${fname}. A formal ceremony will be held in a fortnight's time, though the title of royal retainer is effective immediately. You will receive a generous monthly stipend and be quartered on the castle's lower apartments. As for your tasks—that will all be up to Leon."

The prince grins. "My brother will have me run around the continent, I'm sure. The work won't be much different from what we did with the White Fangs—it'll be just like old times."

"Yes, I suppose your little excursion will serve as useful experience," the king chuckles. "But there will be time enough to discuss that later. I plan on keeping you in the capital until the banquet, at least."

You swallow nervously at the King's words. The banquet in question had been planned for a long time now, and as a close friend of the royalty (and now a royal retainer besides), you are bound by Parami customs to attend. Ilya had laughed at your trepidation for going to the event, and taken it upon herself to instruct you extensively on the finer points of Arvanand history and Parami court life. Not much you don't already know, though you had to keep that fact from Ilya lest she inquires into your past.

(The View World History and View World Religion options have been added to the stats screen.)
*page_break

Alas, were that the issue was simply your lack of knowledge on Imperial luxury imports or the correct steps to a waltz. What you truly dread are the banquet's attendees—it is held in honor of the [i]Salantir[/i], with many of their state dignitaries attending. Although it's been a great many years since your absconsion from the Grand Duchy, the thought of sharing a space with them still makes your skin crawl.

"Before you go, ${fname}," the King says, interrupting your reverie. "I would have you walk with me."

*if (charming > 50)
    "Huh?" You sputter at the request, drawing an irritated glance from Ignis. "I mean, of course, Your Majesty," you say hesitantly.
*else
    You give him an incredulous stare at the request, before an irritated glance from Ignis forces you to correct your visage. "Of course, Your Majesty," you say hesitantly.

Leon shrugs at the exchange, and addresses you as he walks away. "I'll see you later, then, ${fname}. I'll see if I can bother Saine for a bit. Come find us after you're done!"

*page_break And he goes.

King Julius leads you down the hallways of Sienan Keep, a grand structure with sensible, workmanlike masonry and a bevy of defensive structures. Built at a time when the continent of Arvanand was embroiled in endless war, the castle's militaristic influences hold strong even to this day, though it has not seen war in several centuries.

The sun beats down mercilessly through the gaps of the hallway's pillars, and you feel yourself sweat under your robes. The king marches on solemnly; the silence is almost oppressive.
*label kinghub

*temp q1 0
*temp q2 0
*temp q3 0
*temp q4 0
*label expohub
*goto tabb
    *label tabb
    *choice
        *selectable_if (q1 = 0) #"You wished to speak to me, Your Majesty?"
            *set q1 1
            The Majesty in question grunts by way of confirmation. Somehow he still makes the gesture seem lordly. "Truth be told, you perplex me, ${fname}. You are the most qualified retainer that Param has seen in a long time. And a magic-wielder besides—a rare asset here in a kingdom of knights. You 
            *if (charming > 50)
                are courteous and friendly, if overbearingly so, 
            *else
                observe decorum perfectly, if quietly, 
            and have earned the complete trust of both my brothers in scarce more than a year. By all accounts, your recruitment is a blessing for this kingdom." 
            
            The king peers sideways towards you, his deep jade eyes colored with distrust. "And yet when I ask my brothers of your origins, they seem to know curious little. A vagrant with no family to speak of, a disinclination to speak of ${their} past, an aptitude for magic that rivals those of our best archmages? There is a limit to presumption of good faith, ${fname}, and I fear you have exhausted mine."

            As the king continues his tirade, you think to yourself…
            *choice
                    #...that these are fair concerns. The king is right to look out for his brothers.
                        *set noble %+ 15
                        *set prenoble %+ 15
                        You nod thoughtfully as the king airs his misgivings, a gesture that seems to mollify him somewhat.

                        "I'm glad that you seem to understand me, ${fname}. I'd like to respect your wish to keep secrets, 
                        *label stationbid
                        but my station bids me do otherwise. So I ask you: who are you truly? Where do you come from, and what are your intentions for Param?"
                        *choice
                            #I try to persuade him that you mean no harm.
                                *set charisma %+ 10
                                "I maintain that I can't speak of my past, Your Majesty, even if I wanted to," you begin, head bowed down in carefully engineered regret. "But if I had known all along who the princes were and had designs against them, I would have carried them out in Calinger, away from your watchful eyes." You make a show of glancing backwards at the procession of royal guards behind you before continuing your spiel. "It is the foolish assassin who waits a year to strike at ${their} prey, and follow them to the continent's most fortified castle besides."

                                The king considers your statement, seeming mildly pacified. "This is not a good enough answer, ${fname}, and I will extract a proper one from you yet," he decrees judiciously. 
                                *goto brothersnaive
                            #I can exploit the king's own laws to delay his interrogation.
                                *set learning %+ 10
                                You bow deeply to the king, an advance apology on the act of impudence you are about to commit. "Article 27 of the Tower Accords: sufferers of undocumented magical maladies are allowed to keep their silence on its impacts, pending a diagnosis by Church-sanctioned theurges." You bow once more for good measure. "I am sorry, Your Majesty, but please let me keep my silence."

                                The king seems taken aback by your brazen quoting of the law, but his lips quirk up with a grudging sort of respect. "A clever use of the loophole in my own reforms," he sniffs. "I will see that law reviewed, ${fname}. I hope that…[i]others[/i] impacted by these maladies do not suffer for it, just for you to buy some time.

                                "Then that will be all, I think.
                                *goto speakagain
                            #Tell an elaborate lie of a mage that rescued you after bandits ravaged your village.
                                *set intrigue %+ 10
                                It is close enough to the truth, you decide, the lie diving from your tongue with ease. "He taught me the workings of magic and how to defend myself—but his methods were inhumane, and I carry that trauma still to this day." You picture the Salantir researcher, his cruel dagger carving wounds into your skin, and find that your voice carries a genuine tremble. "This is the most I can tell you, Your Majesty. Please, I can speak no more on the subject."

                                The King looks at you sympathetically. "I am sorry to have inquired, ${fname}." He shifts on the balls of his feet, hesitates, then presses on. "And yet I must tell you I still find your explanation wanting. 
                                *label brothersnaive
                                My brothers are good-hearted and trusting, to the point of being naive. It is not a bad quality, and certainly one I would like them to keep—you understand, then, why I must play the wary guardian.

                                "But that is enough for one day, I think.
                                *label speakagain
                                We will speak of this again later, but you may consider the matter dropped for now. You have a banquet to prepare for, after all."
                                *goto afterconcern

                    #...that this is a waste of your time. His distrust is unwarranted.
                        *set noble %- 15
                        *set prenoble %- 15
                        Despite your rising annoyance, you carefully school your expression into one of neutrality. Parami policies on lèse-majesté are rather severe, after all.

                        The King observes you, hawk-eyed to the point of intimidating. "I'd like to respect your wish to keep secrets, ${fname}, 
                        *goto stationbid
            *label afterconcern
            *page_break
            The king hastens his steps and makes to leave. You realize that if you have any questions you'd like to ask him, there is no time to do so but now.
            *choice
                #Ask him another question.
                    *if ((q2 = 0) or ((q3 = 0) or (q4 = 0)))
                        *if (charming > 50)
                            "Your Majesty, if I may…? I'd like to ask you a question. If, um, it pleases you."
                        *else
                            "Your Majesty, please wait. I'd like to ask you a question, if you'll allow me."

                        King Julius turns towards you. "Yes?"
                        *goto expohub
                    *else
                        "I apologize, ${fname}—I don't think I can spare the time. But you are a part of Sienan Keep now—I'm certain we can find time for your queries some other time." With a small incline of his head, the king moves forward with his knights in tow and disappear around the corner.
                        *goto kingdone
                #Let the king leave.
                    And so he does.
                    *goto kingdone
                
        *selectable_if (q2 = 0) #"Can you tell me more about the upcoming banquet?"
            *set q2 1
            The king cocks his head slightly at your question. "I suppose it can be disconcerting to walk into your first royal banquet, far away though it might be. Fine then, ${fname}, I'll indulge you.
            
            "The banquet is to be held in just shy of a fortnight's time. Its purpose is to cement the Arcadian Accords, an edict that will see to the emancipation of Arcadians. You know of them, I presume?" [i]All too well[/i], you don't say—you simply nod, and King Julius presses onwards. "You know, then, of the fall of their state many centuries ago, and how starkly their lives differ under Parami and Salantir rule. In Salantira, they have been granted civil rights equal to that of the native population for more than a century; yet here in Param, my forebears saw it fit to enslave them and deny them basic decencies."
            
            Behind you, armor clangs as Ignis shifts his posture. "In his waning years, your father made the slavery of Arcadians illegal, Your Majesty."
            
            "And yet he did not recognize that liberty alone makes a poor salve in the face of generational poverty," the king spits, chastening his guard captain into silence. "But I digress. The Accords will be our attempt to bridge the chasm that separates us with the Arcadians. Special economic zones, aid from royal coffers, construction of schools—hardly enough to reverse the damage we've inflicted upon them, but perhaps it can serve as a start."
            
            You nod thoughtfully. Such an altruistic attitude is unheard of among royalty, but the king looks adamant. "And how does Salantira fit into all this?"
            
            "Financial aid, and in no small measure. The Duchy has plead with Param to terminate Arcadian oppression for generations. Their efforts fell on deaf ears thus far, and so I will make sure to listen. This banquet will be the first step."
            *label finishspiel
            
            King Julius finishes his spiel, and regards you once more. "Is there anything else?"
            *goto expohub
        
        *selectable_if (q3 = 0) #"Why did you let the princes form the White Fangs?"
            *set q3 1
            King Julius laughs at that, the sound novel to your ears. "The first time I've heard of your White Fangs was the day it marched into my court. I did not [i]let[/i] them do anything, ${fname}. They left of their own accord, and I was unable to stop them."
            
            "Why did they leave, Your Majesty?"
            
            "Parami succession is traditionally a bloody affair, did you know? Always some aristocrat pitting us against one another, with their plots and daggers and poison, whatever they can use to grab a bigger slice of power," the king explains, disgust plain in his tone. "Both my brothers escaped the night of our father's funeral. Take the throne in peace, they told me, before whisking Ilya away with them to Jove knows where. I was grateful for the gesture at first. Little did I know they would abandon their duties and traipse over the countryside for three whole years." The king pinches his nose, his expression longsuffering. "But they are back now, I suppose. And I intend to work them to the bone."
            *goto finishspiel
            
        *selectable_if (q4 = 0) #"What sorts of missions will you be sending the princes on?"
            *set q4 1
            "Leomar—Leon to you, I suppose—is a terrible statesman, but you've seen for yourself his skills with a blade. He will lead an order of knights to combat disturbances around Param. It does the Crown good to have people see a royal fighting crime on the front lines." King Julius's voice trails, and he looks thoughtfully into the distance. "As for Iver, his case is a bit more difficult. His post is overseas in the Kingdom of Thayle, to serve as a diplomat and observe Imperial movements. But he has been insistent in the dereliction of his royal duties…I will see him go yet, one way or the other."
            *goto finishspiel
        
        *if ((q1 = 1) and ((q2 = 0) and ((q3 = 0) and (q4 = 0)))) #"Never mind, Your Majesty. Forgive me for taking up your time."
            The king gives you a curious stare, but decides against saying anything. 
            *label hallwaycorner
            He turns the hallway corner, and is gone.
            *goto kingdone
        
        *if ((q1 = 1) and ((q2 = 1) or ((q3 = 1) or (q4 = 1)))) #"That's all I wanted to ask, Your Majesty. Thank you for your time."
            The king nods wordlessly. 
            *goto hallwaycorner
        
*label kingdone
*page_break
After the king departs, you accost a palace servant as she walks by to inquire after Leon and Saine's whereabouts. She obediently informs you that the princes could be found in the royal study, roughly a five minute walk from the hallway you're standing in. You thank her for the information, and with her directions in mind you find the study in question with little trouble.

You pass through the polished wood door to enter a wide, high-ceilinged space that smells markedly of mildew and old tomes. The room is cleaved into two distinct halves—on your left is a pair of mahogany desks surrounded on all sides by towering shelves filled with thick, leatherbound manuscripts. On the other side of the room is an elevated platform covered with a lavish fur carpet, its entire surface littered with throw pillows and plush cushions. Sunlight peeks through the room's velvet draperies in narrow beams, casting a gentle magenta haze over the entire study.

"I hope Julius didn't chew your ear off."

*page_break

You turn your head to regard Leon where he's perched on the elevated platform, and feel an eyebrow rise of its own volition. The cushions on that side of the room had clearly been intended to serve as seating of some sort, but the blond had instead thrown them together into a pillow fort to bury himself under. He drops the impressive-looking tome he'd been nursing and beckons for you to join him. "That spar must've tired you out, right? This is the best spot in the castle to catch a break."

"I shouldn't be surprised, really," Saine scoffs from where he's seated across the room. An array of books and paperwork are scattered on the desk before him, and there are bags under his eyes that imply a general lack of sleep. "I thought you might've turned over a new leaf after the whole White Fangs business, but you picked up that book just in case Julius walked in, didn't you?"

"Saaaaaine," Leon complains, his voice laced with mock distress. "We just got back here, you know. Aren't I entitled to some grace time?"

"That's grace [i]period[/i], brother," the younger prince responds, sighing. "And we've been here for over a week! Lord Brother has been really lax with you, but I think his patience might be running thin."

"He's too proud to show it, but I bet he's just happy to have us back. I've got plenty of time before he starts breathing down my neck," Leon says, grinning confidently. "${fname}, what are you waiting for? Get here already."

*choice
    #A break sounds nice—Leon and the king have run me ragged this morning, after all.
        *set rleon %+ 10
        Leon beams up at you as he scoots over to one side, making room under his cushion fortress. As expected, the plush material feels cool and soft against your skin, and you nod your head in concession to the blond prince—that his velvety burrow is, indeed, as cozy as he claims it to be.
        
        "Saine," Leon calls out beside you. "You haven't so much as glanced away from that book since I walked in. Come on, a little nap won't kill you!"
        
        The younger prince replies with an uncertain gaze. "I really shouldn't," he says, his tone absent of conviction.
        
        *choice
            #"Come on, Saine. Just a little while—I promise."
                The rogue holds your gaze for a long moment, and eventually relents with a sigh. "Fine," he says at last, and for all that he makes a show of acting resigned, his steps are a hair too giddy for you to believe the fiction. "Just a little while."
                
                He curls up on the floor beside you, and protests half-heartedly when Leon ruffles through his hair. "Of course you'd only listen to ${fname}. What did I expect?"
                
                "Nothing good ever comes out of taking your advice, brother. And I said I was going to rest, not play audience for your nagging."
                
                "You'll have to excuse him, ${fname}," Leon says at length, withdrawing his hand in mock offense. "He gets this way whenever he's spent too long buried in paperwork. He'll be a lot less cute while we're in Sienan, I'm afraid."
                
                "And just as well," Saine counters. "Maybe you'll start taking your work seriously now that there's no one to bug."
                
                The older prince only laughs at the jab. "That's the sleep deprivation talking, so I'll let it slide this time. Get plenty of rest, alright? I'm sure Julius will start pulling on your hair before long—can't have you ready to keel over when that happens."
                
                There's a final grunt in the affirmative as Saine rolls under the cushions and lays his head against Leon's stomach, eliciting a laugh from the older brother. You find that your own hand reaches out almost instinctively to pat the brunette's head, and he leans easily into the touch as he closes his eyes.
                
                Buoyed by the gentle breeze sighing through the curtains and the princes' steady breaths as they fall asleep beside you, you let the world gently fade to black.
            #"Leave him be, Leon. Not everyone can afford to slack off like you."
                "I've been pulling my weight!" Leon says, laughing. "I'm not booksmart the way that Saine is, but I've been shaping up the knights for the past few weeks."
                
                "Struck the fear of Jove into them, more like," Saine parries easily. "The royal chaplain threatened to retire if we send a single more recruit his way. You really need to practice restraint, brother."
                
                "So am I doing too much or too little? I suppose I'll never wrap my hand around this whole prince business."
                
                Saine scrunches his nose in mock contempt. "I'm saying you need to practice [i]moderation[/i]. Combat training is fine and all, but if you don't learn to properly observe decorum, it's only a matter of time before the incident with Lady de Doravas repeats—"
                
                "S-Saine!"
                
                "Alright, alright, no need to yell," the rogue responds, smirking. "I'll just have to tell ${fname} about it when you're out of earshot."
        
                Time passes quietly in the study after that, with Saine going back to his work and Leon lazily flipping through the pages of his book. Cocooned in the sounds of rustling paper and Leon's steady breaths as he slowly falls asleep beside you, you let the world gently fade to black.
    #If I'm already in the study, I might as well brush up on current affairs.
        *set rsaine %+ 10
        You shoot Leon an apologetic glance as you take the seat opposite his younger brother. "I haven't really gotten the chance to get properly acquainted with Parami politics," you remark, ignoring the offended noise Leon makes from across the room. "What would you recommend for me to get started with?"
        
        The younger prince browses the books strewn out before him and extracts a brown-cover manuscript from the pile. "Catch, ${fname}," he says, throwing the book in your direction. You catch it handily. "That's the steward's records. He's made a note of all of the kingdom's major events in recent times, though you'll have to contact Ante's unit to get to the juicier bits."
        
        "I don't get it," Leon whimpers sullenly. "Everything moves so quickly around here. It's like none of you ever come up for air."
        
        "Be grateful that ${fname} is doing this, brother. Having a well-read retainer is to your benefit, you know? Maybe with ${them} around there won't be a repeat of the incident you had with Lady Dor—"
        
        "S-Saine!"
        
        "Alright, alright, no need to yell," the rogue responds, smirking. "I'll just have to tell ${fname} about it when you're out of earshot."
        
        Time passes quietly in the study after that, with Saine going back to his work and Leon lazily flipping through the pages of his book. Cocooned in the sounds of rustling paper and Leon's steady breaths as he slowly falls asleep beside you, you let the world gently fade to black.
*page_break
Your peace would be remarkably short-lived, as it turns out.

The sun is still high on the horizon when Saine shakes you awake, muttering under his breath about a summons from the king. You and Leon both obediently follow after the young prince as he power walks through the hallways, your mind still submerged in the lingering remnants of sleep.

During your days on the run, such a blatant lack of vigilance would have been an unthinkable act. But you are in perhaps the safest haven in all of Arvanand, and sleep had come to you easily, the way it hadn't in years. Privately, you feel ill at ease with how much you've lowered your own guard. You're much too used to the habit of looking over your shoulder and jumping at shadows, always wary that your past would catch up with you—so much so that simple idleness feels like a foreign sort of kindness, the kind you did not deserve.

A sideways glance tells you, at least, that Leon is in far worse shape, barely lucid as he ambles down the halls. You quietly take comfort in that small victory as Saine leads you through a pair of ornate doors and into the throne room.
*page_break
"Leomar, Iver—welcome. I apologize for the sudden call."

The king looks down on you from his perch on the throne, and you hastily dip into a low @{pronvar bow|curtsy|bow}. The princes simply nod their heads in acknowledgment of their brother's presence, as is dictated by Parami decorum.

*fake_choice
    #The reminder of how different our stations are is sobering.
        Even after all this time, It still catches you off guard sometimes that you're rubbing elbows with royalty. It's hard to ignore the touch of dread that curls in the pit of your stomach, as well. The last time you had gotten involved with someone so high up in the world, you nearly lost your life for it.
    #I'm mostly fascinated by how different Parami royal customs are.
        Back in Salantira, even the Grand Duke's mother had to curtsy to him. You suppose they are proper reflections of both of the nations' cultures. The Salantir are often a formal, stilted lot, with singular opinions on rank and respect; speaking out of turn to your betters could be grounds for imprisonment. In Param, meanwhile, such exercises of power would be universally derided as an act of tyranny.
    #I'm much more curious about why the king has called us here.
        Of particular concern is that he has summoned [i]you[/i]—a soon-to-be retainer to his brother, meaning that whatever this missive concerns would present considerable risk to Leon's safety.

"You've arrived," says a familiar voice behind you. You turn to regard Ilya as she walks into the throne room and @{pronvar curtsies to the king|gives the king a curtsy of her own|curtsies to the king}.

"So have you, for once," Leon says with a grin. "The saintess finally let you out of her grip?"

[i]Saintess[/i]. It's a word you've only ever heard before from the Jovian faithful, and always laced with ample admiration. Her name is scarcely mentioned in towns like Leaf End, where life is often too difficult to allow for faith in a benevolent god—but the deeper into Param one goes, so too does her influence grow, like the rings of an ancient tree. In Calinger, weeks of travel from the capital, she commands more admiration than the local folk heroes; in Sienan, where the Church's influence is strongest, it's as if she is Jove reborn.

Whatever one's opinion on the three-faced God is, the saintess herself is almost universally held in high esteem. She is considered the most potent theurge in all of Arvanand, and her unerringly noble spirit makes her beloved by the masses, even independent of their love of Jove.

"Funny you should say that," Ilya responds easily. "I'm actually here at her request—and so are you."

*page_break

"Lady de Alviar is correct," the king sighs. "The saintess has alerted us to an alarming problem. One that will need to be dealt with posthaste."

"We figured as much, given how adamant you've been on keeping us in Sienan thus far, Lord Brother," Saine notes matter-of-factly. "Am I right to assume that this has something to do with…?"

"That's correct, Iver. The Silcur Barony has been hit with a particularly severe case of the moonvein plague. The local lord has petitioned the Church for immediate aid, and the saintess has seen fit to send Lady de Alviar to handle the case." The king gestures towards Leon with a wave of his hand, and Ignis leaves his side to hand the blond a scroll bound with golden thread. "This is a royal missive for you to accompany the Lady, as per her request. You are expected to leave at dawn tomorrow—given how time-sensitive the mission is, speed is of utmost importance."

"Understood, Lord Brother," Saine answers dutifully. "We will make the necessary preparations immediately."

The king nods in approval, before turning his gaze on you. "Leomar and Iver are already familiar with the situation. I understand this is your first time in Central Param, ${fname}—if you have any questions on the mission, you may direct them to Lady de Alviar."

"Yes, Your Majesty," you find yourself saying.

"Then—Leomar Nantael de Param, Iver Norsaine de Param, and Ilya Magritte de Alviar—on the honor of the Parami nobility, I bid you return to me with good news."

"By your leave," Leon says with a final incline of his head, before turning around to leave the throne room. You fall into step behind him with Saine and Ilya, and soberly note that it already feels like the White Fangs have reconvened once more.

*page_break

"Saine and I will handle the logistics," Leon says once you've closed the door behind you. "It'll be to the kitchen first, and then to the stables—${fname}, can you ride?"

*temp ridewith ""
*choice
    *if (intrigue > 49) #"Sure, I know my way around a horse."
        *set canride true
        "Great, then we'll find you one of the sturdier mounts," Leon notes with a nod. "Would you be okay with Ilya riding with you? She's never really ridden a horse before, so—"
        
        "I [i]have[/i]."
        
        "She's never ridden [i]over long distances[/i] before," Leon corrects graciously. "Mine and Saine's horses are on the older side, so they're not really the best pick for this…"
        *label ridechoice
        *choice
            *disable_reuse #"Wouldn't it be better for you to ride a younger mount, then?"
                Leon answers you with a tight-lipped smile. "You'll have to forgive us, ${fname}," he says sheepishly. "It's not as if there aren't stronger mounts to choose from, but Steyer and Scout have been with us since boyhood. We haven't seen them in so long, and we—well, I suppose we're a little sentimental."
                
                Ilya frowns at his reasoning. "Even if it means you'll be subjecting them to more burden than they can safely handle?" 
                
                "They may be older, but they're war steeds all the same," Saine answers. "The trip will tire them out a little easier, but they're more than well enough to make it to Silcur and back."
                *goto ridechoice
            #"Ilya can ride with me."
                *set ridewith "ilya"
                "I'm sure Steyer and Scout will appreciate it," Leon remarks, smiling. "It's been years since they had to carry anyone, too—not a good idea to immediately saddle them with a heavier load."
                *goto load
            #"I'd prefer to go alone, actually."
                *set ridewith "alone"
                "Then I'll be counting on you, Saine," Ilya says, nodding at the younger prince. "Scout is quite the gentle one, if I remember correctly."
                
                Leon hums his approval. "That she is. And she's younger than Steyer, too, so she'll handle the extra load a little better."
                *goto load
    *if (intrigue > 49) #"I'm a bit out of practice, but I should be okay."
        *set canride true
        *set ridewith "alone"
        "Then we'll find you one of the more docile mounts," Leon says. "Would you be okay with Ilya riding with you? She's never really ridden a horse before, so—"
        
        "I [i]have[/i]."
        
        "She's never ridden [i]over long distances[/i] before," Leon corrects graciously. "Scout and Steyer here are on the older side, so they're not really the best pick for this…"
        *goto ridechoice
    *if (intrigue > 49) #"I've never been on horseback before."
        *set canride true
        *set ridewith "leon"
        Leon nods thoughtfully at your answer. "That's fine, ${fname}—neither can Ilya," he hums. "Then you'll ride with me, and Ilya with Saine; Steyer is a little more docile, so he's a better fit for a first-time rider. Scout can take Saine and Ilya in the meantime. We'll double-check with the stablemaster to make sure that they can handle the extra load."
        *goto load
    *if (intrigue < 50) #"Actually, with my bad knee..."
        *set ridewith "leon"
        Leon hisses at his own mistake. "Ah, of course. I'm sorry, ${fname}—I don't know where my mind was," he says, ruffling through his hair. "Then you'll ride with me, and Ilya with Saine; my Steyer is a little more docile, so he'll probably be a better fit for you. Scout can take Saine and Ilya in the meantime. We'll double-check with the stablemaster to make sure that they can handle the extra load."
*label load

"[i]Load[/i]," Ilya repeats slowly. "I say this as a friend, [i]Your Highness[/i], but you really need to work on your decorum. No wonder Lady de Doravas wouldn't stop going on about—"

"Alright, then, we've got places to be," Leon interrupts, his tone laced with panic. "Saine, let's get going—our supplies aren't going to pack themselves."

For a moment Ilya looks tempted to pursue the point, but she mercifully decides to drop the issue. "And neither will ours, unfortunately," she sighs, to Leon's immediate relief. "We'll need to stock up on medicinal herbs while we have the capital's resources. ${fname}, I'll brief you on Silcur along the way."

*choice
    #"And on Lady de Doravas, I hope?"
        *set charming %+ 15
        *set precharming %+ 15
        Leon stares at you in open horror. "Please. Not a word about that woman."
        
        "Sorry, ${fname}—I'm oathbound to obey to the wishes of royalty," she says, giggling. "Now Saine, on the other hand…"
        
        "It's a long way to Silcur," Saine remarks. "I'm sure we could find the time."
        
        "Damn it all," Leon mutters under his breath. "I suppose I'm doomed either way, then…but we really should get ready for now. We'll need to get everything done quickly if we want to be well-rested for the trip."
        
        Saine nods in agreement. "We'll meet at the castle gates tomorrow at dawn. We'll take breaks as necessary, but it'd be best for us to arrive as quickly as possible. Godspeed, everyone."
        
        And with a final exchange of goodbyes, you part ways and head for your respective destinations.
        *goto silcurbrief
    #"I understand. Lead the way, Ilya."
        *set charming %- 15
        *set precharming %- 15
        Leon shoots you a grateful look. "I knew you'd get it, ${fname}—we'll need to get everything done quickly if we want to be well-rested for the trip."
        
        "We'll meet at the castle gates tomorrow at dawn," Saine says. "We'll take breaks as necessary, but it'd be best for us to arrive as quickly as possible. Godspeed, everyone."
        
        And with a final exchange of goodbyes, you part ways and head for your respective destinations.
        *goto silcurbrief

*label silcurbrief
*page_break
The sun is blinding when your eyes first catch a glimpse of it.

It is the cusp of afternoon, and there is an unmistakable orange sheen pulling at the edges of the clouds. It's been weeks since you first arrived at the Keep, and you haven't left the compound since. After spending so long shielded from the sun's glare by stone walls and paneled glass, even even the dimming light seems harsh by comparison.

Ilya seems to share your concern, pulling up the hood of her commoner's cloak—summer never did agree with her complexion,
*if (skintone = "pale")
    just as it had never agreed with yours.
*elseif (skintone = "light")
    even less than it had ever agreed with yours.
*else
    and she's always been openly envious of how well yours fare against hot weather.

"We've gathered up everything we needed from the royal storehouse," Ilya muses as she falls into step beside you. "We'll need to make stops at a couple of magic shops, and see if the florist has any grassvane in stock."

"And if they don't?"

"The road to Silcur takes us through Param's main trade artery—I'm sure we'll be able to find some along the way," she says.

You can't help but to think that she looks completely at home as she leads you through the throngs of people milling about Sienan's main street. Back in the Keep, Saine had informed you that Ilya is the eldest daughter of the House de Alviar, as noble a Parami bloodline as they come—but looking at her weaving past the bustle of the city with expert ease, you would not have thought to doubt that she was just an uncommonly pretty bar wench.

"Sorry that we pulled you into this mess, ${fname}," she says, pulling you out of your reverie. "I'm sure you feel a little disoriented—if you have any questions, I'd be happy to answer."

*temp moonveinexpo1 false
*temp moonveinexpo2 false
*temp moonveinexpo3 false
*temp mooncounter 0
*label moonveinexpo
*choice
    *disable_reuse #"Tell me more about this moonvein plague."
        *set moonveinexpo1 true
        *set mooncounter +1
        "It's a rare and awful disease, and one that we have yet to really understand," Ilya says, gazing into the distance. "What we do know is this: it starts with rashes and welts on the surface of the skin, easily confused with common allergies or bug bites. By the second week, the afflicted will undergo bouts of high fever and frequent vomiting. And by the third, the illness will have progressed to its last stage, which turns the victim's bloodstream white—hence the name [i]moonvein[/i]."
        
        *if (learning > 60)
            *set rilya %+ 10
            You can't help but to heave an anxious sigh. Human anatomy is far from your area of focus, but you have perused a couple of the tomes in your time, if only to pass time in Leaf End. Red-tinged blood is necessary for the human body's ability to bind life force from its environment—to have that function compromised could only result in…
            
            "So you understand," Ilya sniffs. "If left untreated, the last phase of moonvein has a perfect fatality rate."
        *else
            Something thick begins to form at the base of your throat.
            *if (charming > 50)
                "That doesn't sound like a terribly fun time."
                
                "That would be because it's [i]not,[/i]" Ilya sniffs. "If left untreated, the last phase of moonvein has a perfect fatality rate."
            *else
                "Go on, Ilya."
                
                "We have our work cut out for us, ${fname}," Ilya says solemnly. "If left untreated, the last phase of moonvein has a perfect fatality rate."
        *goto moonveinexpo

    *disable_reuse *if (moonveinexpo1) #"Then how do you treat the disease?"
        *set mooncounter +1
        "It's inefficient, but repeated healing of the victim's body until the illness runs its course has proven somewhat efficacious," Ilya says. "Theurgy moreso than alchemic potions, though the latter can still help in a pinch. That's why it's vital for a skilled theurge to go; I could safely handle healing of that scale for maybe two or three patients at a time."
        
        You can easily pick up on the unease in her tone. "But that's not what we're up against, is it?"
        
        Ilya answers with a thin-lipped smile. "It's called a plague for a reason, ${fname}."
        *goto moonveinexpo

    *disable_reuse #"Why have you specifically been picked out for the mission?"
        *set mooncounter +1
        *set moonveinexpo2 true
        "We're dealing with the borders of theurgic knowledge here, ${fname}. Moonvein is a disease that only started to appear around three years ago—otherwise, I'm sure a mage of your caliber would've at least heard of it before." Ilya bites at the corner of her lips and casts her gaze on the ground. "Our mission is not simply to heal the people of Silcur using tried and true methods. We must discover a cure—one that could be replicated should the need ever arise in the future."
        
        You ponder her explanation for her moment. "But you told me that the disease first surfaced three years ago—if the cure still hasn't been discovered yet, does that mean…?"
        
        Ilya gazes at you out of the corner of her eyes. "That everyone who caught it had died? They very well could have," she says. "But they didn't—because of the Plague Doctor."
        
        You stop in your tracks. "Because of [i]who[/i]?"
        
        "That's the question we're all asking, too. The Doctor is a theurge who went from village to village, anywhere the plague had touched, and eradicated it single-handedly. Their theurgy must have been on par with mine—if not with the saintess—and their identity still baffles us to this day."
        
        [i]Baffling[/i] must be a hell of an understatement, you think to yourself. Access to the art of theurgy is aggressively managed by the Church, and one must become a devoted acolyte to even have a shot at learning. To have such an advanced caster pilfer their art and use it without their sanction must have sowed a great deal of chaos and distrust within the Church.
        
        "Regardless, it is evident now that the plague is no passing illness," Ilya says with a dismissive wave of her hand. "We will need to understand its nature and discover means of curing it—or preventing it altogether. It's been determined that I am the cleric best-suited for the job."
        *goto moonveinexpo

    *disable_reuse *if (moonveinexpo2) #"This seems like a terribly large job for a single healer."
        *set mooncounter +1
        "The saintess should be sending more," you remark.
        
        "Jove knows she would have, if she could," Ilya says. "But Silcur isn't the only place in Param needing the attention of the Church, ${fname}. Disease and injuries are everywhere, and we are oathbound to help as many as we can."
        
        You ponder the statement for a while. "But the saintess—the most powerful theurge in Arvanand—is to remain in the capital?"
        
        Ilya shrugs and bites down a smile. "Sometimes platitudes can save more lives than a full day of theurgy. And there's no denying that the saintess is a gifted speaker."
        *goto moonveinexpo

    *disable_reuse #"How will the princes and I be useful in this mission?"
        *set mooncounter +1
        "You're a mage, ${fname}—that in itself should suffice as an answer," Ilya says with a laugh. "Have you forgotten that you're the reason I'm still here to begin with? There's not a lot that we understand about this disease yet, but I'm sure you'll find a way to make yourself useful."
        
        You nod your head by way of concession. "And Leon and Saine?"
        
        The healer's expression takes a grim turn. "There is…something odd about this iteration of moonvein, ${fname}. It's a deadly disease, by all accounts, but contagiousness had always been mercifully low…it was the case that the word [i]plague[/i] was used rather generously," she says at length. "Not anymore. Missives coming out of Silcur report case numbers well beyond the first wave three years ago."
        
        The implication is easy enough to glean. "You suspect foul play, then."
        
        Ilya nods hesitantly. "I hope to be wrong, ${fname}, but even the saintess shares my suspicions," she says. "It's difficult not to notice how disproportionately moonvein affected Arcadian populations, even three years ago. We had chalked it up to a quirk of geography, and even considered that their lower living standards might have had something to do with it—but for the illness to hit this severely, deep in former Arcadian lands…well."
        
        "It's definitely something to look into," you agree easily. "Then the princes are to play bodyguards?"
        
        "And executioners," the healer says darkly. "If it comes down to it."
        *goto moonveinexpo

    *disable_reuse #"Tell me more about Silcur."
        *set moonveinexpo3 true
        *set mooncounter +1
        "It's a barony in Western Param, situated in former Arcadia territory," Ilya explains. "Its location is about as far south as fertile land goes before the Yied Desert turns it barren, which means that it functionally serves as the region's breadbasket. It's also the southernmost outpost of Param's main trade artery, and its proximity to the desert mines makes the barony far richer than its surrounding territories."
        
        You feel your eyebrows furrow of their own accord. After all, if what Ilya's telling you is true, then the so-called barony is rich, fertile, and strategically located besides. Such an important territory is more commonly awarded to a marquess, or perhaps an uncommonly meritable count—that a [i]baron[/i] was granted custodianship of it is nothing short of baffling.
        
        To her credit, Ilya quickly picks up on your bewilderment. "I know what you're thinking—but the de Silcur lineage far outstrips their current station," she explains. "Depending on who you ask, it can even be considered more prestigious than my own. The baron traces his heritage all the way back to the kingdom's founding, and some of the most decorated officers of the Arcadian conquest came from his house. So great were his ancestors' contributions that they were awarded the prosperous Silcur territory after Arcadia was annexed, in addition to their original holding in southern Param."
        
        "To become a barony in so short a time…that's a hell of a fall from grace," you say, because it is. After all, the ability to possess multiple landed titles at once is a privilege granted only to dukes and marquesses. "What happened to them?"
        
        "They were…heavily penalized, a couple of generations ago. The house went by another name then, because Silcur was only a secondary holding; their primary one was Icharea, which has now been absorbed by the surrounding lands. But the Marquess de Icharea, the current baron's great grandfather—he was the instigator of the Icharea Massacre."
        *goto moonveinexpo

    *disable_reuse *if (moonveinexpo3) #"Tell me more about the Icharea Massacre."
        *set mooncounter +1
        "It was a terrible affair, ${fname}. Arcadian oppression was still at large in Param at that time, but the last Marquess de Icharea took it to the furthest extreme. Arcadian slaves under him were made to live and work in inhumane conditions, and many perished under his orders in the Yied Mines." Ilya heaves a heavy sigh and runs a hand through her hair before continuing. "But the worst act of all came at the end of his rule. He gathered up the least productive Arcadian slaves in Silcur—many of them old, infirm, [i]children[/i]—and had them taken to his estate in Icharea. What happened next…is self-explanatory, I think.
        
        "In any case, it was a level of brutality that not even the king back then could stomach. He seized most of the marquess's assets after the massacre came to light, and left him only with the house's current territory in Silcur," she says. "And for all that it's a rich and fertile land, the baron hardly enjoys any of it—as part of their punishment, the house must pay most of the wealth they accumulate to the crown, to power Arcadian restitution programs."
        *goto moonveinexpo
    
    *if (mooncounter > 0) #"That's all I wanted to ask. Thank you, Ilya."
        *if (mooncounter = 7)
            Ilya nods at you with a wan smile. "Alright, ${fname}. If you think of anything else you want to ask, feel free to ask me on the road," she says, before jerking her chin towards a modest shop at the end of the street. "For now, we've arrived at our first stop. Let's get us some herbs, alright?"
        *else
            Ilya nods at you with a wan smile. "Alright, ${fname}. There's still other details about the mission that we'll need to discuss, but time enough for that on the road," she says, before jerking her chin towards a modest shop at the end of the street. "For now, we've arrived at our first stop. Let's get us some herbs, alright?"
            
        You nod in affirmation, and together the both of you close the distance. There's a bell that jingles above the door as Ilya pushes it open, and a kindly old man that smiles up at you from behind the counter. Something warm and familiar settles in the cavity of your chest as coin and herbs exchange hands, and just like that you fall into the steady rhythm of mission preparations once more.
        *page_break Just like old times.
        *goto postmoonvein

    *if (mooncounter = 0) #"There's no need for a briefing. I'll just do as I'm told."
        Ilya frowns at your words. "We'll be dealing with a time-sensitive crisis in Silcur, ${fname}, and every decision we make could save a life. We'll need your input as well as your expertise—it'd be best for you to know the lay of the land." There is silence for a brief moment, and then Ilya turns in your direction with a wan smile. "But I suppose there is time enough for that on the road. For now, we can just focus on gathering the ingredients we need. Speaking of which: here's our first stop."
        
        Ilya halts her steps in front of a modest shop at the end of the street, surrounded on all sides by an impressive herb garden. There's a bell that jingles above the door as Ilya pushes it open, and a kindly old man that smiles up at you from behind the counter. Something warm and familiar settles in the cavity of your chest as coin and herbs exchange hands, and just like that you fall into the steady rhythm of mission preparations once more.
        *page_break Just like old times.
        *goto postmoonvein
    
*label postmoonvein
It was remarkably easy to tell when you've crossed into Silcur proper.

The Parami west has always been one of the its less developed regions, owing to the fact that Parami commerce is largely concentrated along its central axis. Along your path to Silcur, you had passed little else beyond hamlets attached to an 'outpost'—small makeshift markets where locals fed ores and ranch products into the trade stream. The roads were narrow and ill-paved, and inns were so few and far between that you had been forced to spend a couple of nights under the open sky.

But at some point the roads had opened up, and the outposts you'd passed began to look the part: lively markets and hardwood caravans, merchants hawking their wares at volumes fit to shake the heavens. Silcur's outpost was the busiest of all, all clangor and chaos despite the sun being freshly risen on the horizon. The town proper seems almost quaint by comparison, rows of single-story houses nestled along gently curving streets.

Your horses clop along the central road at an easy pace, seemingly grateful to have found even footing after such a long journey. In the distance, the de Silcur mansion fades into view: a clean and sturdy building with a well-trimmed if modest courtyard.

A sturdy-looking guard at the mansion gates eyes you with caution and hostility, and when Leon guides his horse into the entrance he is halted by the business end of his spear.

"The baron is not receiving visitors at this time," he grouses. "Turn around and leave."

*choice
    #I try to talk him into letting us in.
        *set charming %+ 15
        *set precharming %+ 15
        "Whoa, no need to get all worked up there," you say, holding both your hands up. "We're here at the baron's request."
        
        The guard narrows his eyes. "I don't think you heard me," he scoffs, his lance inching closer to Leon's chest. "[i]Leave.[/i] I won't say it a third time."
        
        Leon heaves a weary sigh before making a grab at the spearhead, the leather of his travel gloves chafing against the cold iron. The guard recoils in surprise, and tries to pull his armament away—to no avail, as Leon yanks it from his grip and tosses it edgewise onto the ground.
        
        "This is a blatant disregard of the decorum owed to nobility," Ilya chides
        *if (ridewith = "ilya")
            behind you.
        *else
            from where she's seated behind Saine.
        "The baron would do well to seek more courteous guards for his estate."
        
        *goto leonnods
    #I motion for Leon to give him the king's missive.
        *set charming %- 15
        *set precharming %- 15
        Leon nods and reaches for the parchment stuffed into his doublet, but before he could pull it out the guard hisses and moves forward, his lance grazing the skin of Leon's collarbone. "I don't think you heard me," he scoffs. "[i]Leave.[/i] I won't say it a third time."
        
        Leon heaves a weary sigh before making a grab at the spearhead, the leather of his travel gloves chafing against the cold iron. The guard recoils in surprise, and tries to pull his armament away—to no avail, as Leon yanks it from his grip and tosses it edgewise onto the ground.
        
        "This is a blatant disregard of decorum owed to nobility," Ilya chides
        *if (ridewith = "ilya")
            behind you.
        *else
            from where she's seated behind Saine.
        "The baron would do well to seek more courteous guards for his estate."
        
        *goto leonnods
    #What an annoyance. I'll teach him a lesson he won't soon forget.
        *set noble %- 15
        *set prenoble %- 15
        The spell circle curls around your fingertips almost languidly, and
        *if (thaum > enchantment)
            *set thunderstrike true
            with a breath and a burst of mana you thaum a smattering of thunder into existence. The blast catches the guard on the forearm, and with a yelp he leans back and falls onto the ground, his spear clattering uselessly by his side.
            
            "If we had any ill intent against the baron, you'd be dead by now," you say shortly. "I suggest you bring our arrival to the baron's attention. Otherwise," you say, your gaze flitting quickly over his neck, "we will be forced to catch it some other way."
            
            The guard swallows a big gulp under your imperious gaze, before scrambling to boost himself onto his feet. "Right away," he mutters under his breath, already beating a panicked retreat.
        *else
            *set glyphofsubjugation true
            with a chant and a burst of mana you will the Glyph of Subjugation into existence. The guard's eyes widen as he feels the spell rapidly sinking into his skin, but by the time he fully realizes what was happening to him, it was already far too late. He's been made a puppet to your whims, and with a wave of your hand he loosens his grip on his weapon and watches it clatter uselessly onto the ground.

            "If we had any ill intent against the baron, you'd be dead by now," you say shortly. "I suggest you bring our arrival to the baron's attention. Otherwise," you say, your gaze flitting quickly over his neck, "we will be forced to catch it some other way."
            
            The guard grasps at his throat when you release the Glyph's hold on him, eyes bulging as he stares at you in open horror. "Right away," he manages eventually, before beating the quickest retreat you've ever seen.
            
        "Feeling a little on edge, are we, ${fname}?" Leon says, grinning as he watches the guard's retreating back. "Not that I blame you…it's been a long journey, and this was a hell of a welcome."

        Saine scoffs at his brother's words. "You can say that again," he says amusedly, foot digging a spur into his mount and guiding him to a trot. "At any rate, there's no reason for us to hang around here any longer. We've got a baron to meet."
        *goto meetbaron
    #Given all we've heard about the barony's struggles, outbursts like this ought be easily excused.
        *set noble %+ 15
        *set prenoble %+ 15
        "Peace," you say gently, holding both hands up in a bid to deescalate the situation. "We are envoys sent by His Majesty the King, upon the baron's request. We mean you no harm."
        
        The guard quirks one corner of his lip up in contempt. "You lot have a lot of nerve, trying that old trick again so soon," he sneers. "I may be one guard, but the baron's knights are some of Param's finest. You'd do well to leave now before you regret it."
        
        Leon heaves a weary sigh before making a grab at the spearhead, the leather of his travel gloves chafing against the cold iron. The guard recoils in surprise, and tries to pull his armament away—to no avail, as Leon yanks it from his grip and tosses it edgewise onto the ground.
        
        "The baron has some nerve, to request help so desperately and have his people greet us this way," Ilya sniffs
        *if (ridewith = "ilya")
            behind you.
        *else
            from where she's seated behind Saine.
        "If there weren't innocent lives on the line, I'd be tempted to see how well you'd fare against moonvein without a theurge."
        
        *goto leonnods

*label leonnods
Leon nods his agreement before producing a piece of parchment from his doublet. "A royal missive from the King of Param," he explains shortly. It appears the long trip has taken its toll even on the normally exuberant prince. "Turn us away again and it's your baron who'll be paying the price."
        
"But not before he makes you pay yours," Saine mutters.

The guard hesitantly takes the parchment from Leon and scans its contents. You can identify the exact moment his eyes land on the royal seal, and in an instant his entire demeanor shifts into one of subservience. "My apologies," he says quietly, widened gaze shifting onto Ilya. "I hadn't realized that someone so honorable had been sent to assist us. I beg you forgive us this transgression, Lady de Alviar."

You quietly resist the urge to laugh. It is [i]Leon[/i] he had pointed his lance at, and the one he should truly be concerned about; threatening royalty with bodily harm is tantamount to treason, and you have no doubt that the guard would be groveling for mercy had the princes not insisted on masking their own identities.
        
"So long as you understand," Ilya says coolly, though there is an amused quirk to the edge of her lips that mirrors your own. "Given how urgent the matter at hand is, we do not plan to linger around here for long. Please open the gates and call for the baron immediately."
        
The guard dips his head and refuses to meet her gaze. "Right away," he mutters under his breath, already turning around to beat a panicked retreat.

The four of you watch as the guard ambles over to the mansion, for a while, until Saine eventually breaks out of his reverie and guides his mount into the courtyard. "No sense hanging around here," he says with a shrug. "We've got a baron to meet."

*label meetbaron
*page_break

"I apologize for the trouble at the gates, Lady de Alviar. Times have been terribly unkind for us."

The baron shifts uncomfortably in his seat, though he meets Ilya's gaze with a firm resolution. He is much younger than you had expected, perhaps on the wrong side of twenty, though the bags under his eyes age him up quite a bit. Sizing him up head-to-toe, you can't help but to think he's a bit unimpressive: from his mousy brown hair and his ill-fitting slacks, to the placid skin that looks like he's never spent a single day in the sun.

He takes a sip of his tea and leans back against the sofa, appearing to contemplate his words. "There have been a number of attempts on my life over the past couple of weeks, and I've lost two good knights to the assaults," he confesses eventually, a hand fiddling idly with the handle of his cup. It's an ornate piece of ceramic, the kind normally only capital nobles are privy to—a shadow of the house's former glory. The lion and the snake, entwined as one—you have to wonder how House de Icharea saw itself, during its heyday. "You understand, then, why my guard had become a little jittery."

"[i]Jittery[/i] is not the word for it, Baron. He pointed his lance at my escort's [i]jugular[/i], without hearing out even a word he said," Ilya says shortly. "But we are willing to let this slide, if only because we have more important matters to attend to."

The baron's smile is wan, thin-lipped. "I'm grateful for your discretion, my lady."

*temp village false
*temp someinfo false
*label baronexpo
*choice
    *disable_reuse #Inquire about the assassination attempt.
        *set someinfo true
        Ilya beats you to the question. "You say you've been plagued by assassins of late?"
        
        "Unfortunately," the baron replies with a sigh. "We have precious little information on the assailants—they're a slippery lot, and the ones we did manage to capture are as tight-lipped as they come. We have our suspicions as to who they might be, but nothing concrete." The baron briefly purses his lips, before quickly shaking his head. "But that matter is mine to look into. There is the matter of the plague to focus on instead. My people have suffered for too long."
        *goto baronexpo
    *disable_reuse #Ask about the moonvein plague.
        *set village true
        *set someinfo true
        "Tell us what you know of the plague," you say. "We'll need all the information we can get before we start handling the case."
        
        The baron is silent for a moment, and when he speaks his voice is oddly subdued. "It is exactly the same as it was three years ago, though the amount is like nothing we've ever seen before. I've spent a fortune on hiring alchemists and doctors, but any benefit they could provide has been marginal. I came to the conclusion that theurgy would be our last hope, and that was when I petitioned the church."
        
        Saine leans forward in his seat, green eyes fixated on the baron's face. "Your city seems well enough, Your Lordship," he says at length. "The market is bustling, and the trade stream unimpeded. Pretty curious, for a town plagued by moonvein."

        The baron shakes his head. "The town is not the area of concern, Sir Saine. It is instead Merdel Village, located slightly north of here, the only other settlement under de Silcur stewardship. Given how severe the contagion had become, we had no choice but to impose a quarantine on it."
        
        Ilya closes her eyes and heaves a deep sigh. "A harsh call, but the only one you can make in this situation," she says. "You made the right choice, my lord."
        *goto baronexpo
    *disable_reuse *if (village) #Ask about the village of Merdel.
        *set someinfo true
        "Tell us more about this quarantined village."
        
        There is a look of unease that crosses the baron's features, but it is gone as quickly as it had appeared. "The village was established only a couple of generations ago, at the tail end of my grandfather's rule. That is, after the Icharea Massacre," the baron says, not meeting your gaze. "Many of the Arcadians wanted nothing to do with the town of Silcur—understandably so, of course—and moved upriver to found a village open only to their own kind. They self-sustain through farming and fishing, though they do engage in trade with us from time to time."
        
        Ilya contemplates the information with a grim set to her jaw. "Then it is again Arcadians who bear the brunt of moonvein's carnage."
        
        Silence, and then a nod from the baron. "I'm afraid so."
        *goto baronexpo
    *if (someinfo) #"That's all the information we need, Baron. We'd best get going."
        *goto postbaron

*label postbaron
Baron de Silcur nods his approval. "I'm grateful for your swiftness," he says, before turning around to regard the knight standing behind him. "Sir Joran, you are to take your retinue and escort the lady and her companions to their—"

"There's no need for that," Leon interrupts, shaking his head. "Sending a platoon to a dying village hardly seems appropriate."

"Sir…Leon, was it?" The baron motions for his knight to come forward as he shifts his attention towards the prince. "I'm afraid my decision to quarantine Merdel Village was…ill-received, to say the least. I cannot guarantee that the lady will be safe from the villagers' ill-conceived wrath, knowing that I sent for her—and so I must insist on the inclusion of Sir Joran's squad."

You can spot the tension in the set of Leon's jaw, if only because you knew to look for it. "We can more than handle ourselves, Baron. The king wouldn't have left Lady Ilya in our care if we were incompetent." The prince turns to you, then, and jerks his chin in the baron's direction. "Tell him, ${fname}."

*choice
    #"Please indulge him, Baron. He's a nightmare to work with when he's sulking."
        *set charming %+ 15
        *set precharming %+ 15
        Ilya is quick to follow your lead. "Let him have his way and spare us all," she urges, ignoring the offended look Leon shoots you both.
        
        The baron holds his silence for a while, insistent, but eventually relents with a sigh. "Very well, my lady. I suppose you know your retainers best," he says. "Sir Joran's unit will remain at your disposal for the duration of your stay in Silcur. Send for him, my lady, and he will come running."
        
        "I understand, Baron," Ilya answers, smiling. "Thank you for your generosity."
    #"You are much too stubborn for one who's been groveling for our help."
        *set charming %- 15
        *set precharming %- 15
        Sir Joran has his sword unsheathed in less than a second. "Govern your tongue! You are speaking to nobility!"
        
        "Peace, Sir Joran," the baron says, gently pushing his knight's sword away. "@{pronvar Sir|Madam|The honorable} ${fname} has the right of it."
        
        "But Your Lordship—"
        
        The baron holds up a hand to silence his knight, and though he seemed to fume at the order the larger man reluctantly sheathes his blade once more. "I petitioned you for aid, and you've been gracious enough to provide it," he says sagely. "I shall not interfere with how you wish to handle this case. That being said, Sir Joran's unit will remain at your disposal for the duration of your stay in Silcur. Send for him, my lady, and he will come running."
        
        "I understand, Baron," Ilya answers, smiling. "Thank you for your generosity."
    #"They are ailing and in need, and you would bring an army to their doorstep?"
        *set noble %+ 15
        *set prenoble %+ 15
        The baron's eyes widen in surprise. "I…I suppose you are correct," he relents, after a moment of consideration. "It places me ill at ease to send the lady off with so few guards with her…but you raise a compelling point, @{pronvar Sir|Madam|The honorable} ${fname}."
        
        "We appreciate your generosity all the same, Baron," Ilya says. "But my retainers are highly skilled. There's no need to worry about my safety."
        
        "Then I shall take your word for it, my lady," the baron says with a slight bow. "All the same, Sir Joran's unit will remain at your disposal for the duration of your stay in Silcur. Send for him, my lady, and he will come running."
        
        "I understand," Ilya answers sweetly. "I'll keep that in mind."
        
*page_break
The baron makes an offer just before you leave for you to take the day to rest and recuperate from the journey. Although the promise of warm food and proper bedding is all too tempting, you know the delay would be much too costly for Merdel Village—and so you politely decline his offer. He then instructs Sir Joran to accompany you to the edge of town, and while keeping the directions he gave you in mind it is not long before the village comes into view.

Cold dread curls around the pit of your stomach as your party approaches the settlement. Even from a distance, Merdel Village seems unmistakably like a place that had been touched by the plague: from the villagers hobbling back and forth between homes, an expression of panic etched onto their faces, to the open, shallow graves carved onto the grounds outside of town—everything about the village screams of grief and death.

*choice
    #My heart hurts for these people. It's difficult even just to witness this carnage.
        *set emotional %+ 15
        *set preemotional %+ 15
        You can't even begin to comprehend the depth of the sorrow they must feel. To have their loved ones die around them in droves, knowing full well that they too could be next.
    #Succumbing to emotions will only cloud our judgment. We must focus on the objective.
        *set emotional %- 15
        *set preemotional %- 15
        The situation before you is horrifying, but being fixated on that will only cloud your judgment. The best calls can often be the hardest ones to make—you must never lose sight of the bigger picture.
    #I feel overwhelmed. Do we really have what it takes to see this through? 
        *set optimistic %- 15
        *set preoptimistic %- 15
        Theurge or not, Ilya is just one person, and what assistance you can offer as an offensive mage is likely to be meager. To say nothing of the princes, who are far more comfortable ending lives rather than saving them. Your odds of success seem more and more daunting by the second.
    #I have faith in Ilya's judgment and capabilities. We [i]will[/i] succeed in our task.
        *set optimistic %+ 15
        *set preoptimistic %+ 15
        You've seen Ilya's work firsthand, after all, and it would not surprise you one bit to learn that the healer's capabilities is second only to the saintess herself. If anyone could get Merdel out of its current predicament, it's her.

You dismount your horses and tie them to a post near the village gate, all the while feeling the weight of a hundred weary, cautious eyes on you. Ilya produces four bottles of tonic from her travel sack—Draughts of Resilience, courtesy of the royal storehouse. Among the most difficult of alchemic potions to concoct, and the only one proven to protect one from contracting moonvein. You all down the potion in one gulp, and with a final, reaffirming look at one another your party makes its way into the village.

*page_break

As it turns out, you don't make it very far inside.

You are accosted not ten steps from the entrance by a man with soot-black hair and deeply tanned skin, one hand rested on the hilt of his sheathed blade. When he speaks, his voice is hoarse and weary. "What business do you have with Merdel Village?"

Ilya steps forward, her stance and expression carefully neutral. "My name is Ilya, a wandering priestess," she says, the lie you had agreed upon rolling easily off her tongue. After all, if it is the case that Merdel has no love lost for the Baron de Silcur, it would be better for you to conceal your alignment with him. "My escorts and I had caught wind that a moonvein plague is brewing in this village. With your permission, I seek to render what services I could as a theurge."

A conflicting brew of emotions flash through the man's features. "It's…true that we need help," he admits with some difficulty. "But I'm sure you understand—it's hard for us to accept handouts from the Jovian Church."

Ilya schools her tone into one of sympathy. "Your animosity towards the Church is reasonable, given the history of its behavior towards Arcadians," she allows. "But I've come here not at the bidding of the Church, but rather that of my own conscience. A theurge must always help others, if they are able; and though I don't know yet how much I'll be able to do against moonvein, I would be remiss not to at least try."

The man considers her words, for a while, and eventually relents with a sigh. "Then we welcome your aid, priestess. My name is Barza, eldest son of the village head," he says, before catching himself. "Although I suppose I am the acting head now, given that my father…no matter. Please let me know if I can be of service, priestess. Anything that can help save the people of our village."

*choice
    #Good. I'm glad he can be made to see reason.
        *set emotional %- 15
        You're here to help, and your capacity to do so is reliant on the locals' cooperation. Such an agreeable start only serves to improve your odds of success.
    #So he's lost his father to this plague. My heart aches for him.
        *set noble %+ 15
        To have gone through such a harrowing affair and not even have the time to grieve—you can't imagine what it's like. You can only hope he will get the rest he deserves before long.
    #I feel the pressure mounting. We can't repay such hope with failure.
        *set emotional %+ 15
        You are not ignorant to the flicker of hope that had sparked in Barza's eyes. Desperation is plainly written in every crease of his features—he sees you as the village's only hope. You swallow a nervous gulp as the group strides forward.

Barza takes you to a building near the village's center, a large mud-brick house that had once belonged to the village alchemist before she succumbed to the plague. Passing through the house's wooden door, you are immediately besieged by the stench of putrefaction and death, the scent so heady and dizzying that you have to lean on the door jamb for support.

A quick scan through the room alerts you to the true gravity of the situation. A number of beds are strewn haphazardly about the room, all of which contains patients in various stages of moonvein decay.

Immediately to your right is the body of one recently passed, the white sheet of their bedding pulled all the way up to cover their head.

Lying opposite of them is a young man with pallor so severe that you know he has been marked for death.

Near the edge of the room, a middle-aged woman stares at the ceiling listlessly, as if waiting for the axe to fall. A younger woman—presumably her daughter—peers at her helplessly through the house's windows, the sound of her sobs piercing in the deathly silence.

It is a while before any of you can find the strength to speak. "Thank you for showing us the way, Barza," Ilya says finally, her voice barely a whisper. "We will do everything we can."

*page_break

Ilya wastes no time in getting to work, immediately marching towards the patient closest to her and working her theurgy. She pulls away mere moments later, her expression thoroughly dejected. "He's too far gone," Ilya says, quietly enough that only you can hear her. "I've done what I can to make his last moments less painful, but I must prioritize those with the best odds of survival."

"Godspeed, Ilya. I don't envy your position, but you're doing necessary work," Leon says. "Saine and I will do what we can to learn more about this plague's spread, as you instructed. So don't worry about anything other than saving these people's lives."

Saine's nod is enthusiastic, his feet already pointed towards the exit. You can't help but to sense the undercurrent of panic and discomfort in his body language—not that you blame him for it, things being how they are. "We'll try to find a pattern in the cases," he says, his voice admirably stable.

"We [i]will[/i] find a pattern in the cases," Leon corrects. "You can count on us."

Ilya somehow manages a smile. "And I do," Ilya says. "You remember what to look for, right?"

Saine nods on his brother's behalf. "We have three possibilities to analyze. The first is that the plague spreads through close contact, like the Phryge disease. We'll need to investigate if any pattern emerges from patients meeting one another. The second is contaminated water, like the one that causes scarfever. There's only two water sources in the village, so that's easy enough to map out. And lastly—"

"Insects, like the red plague," Leon finishes, steering his brother towards the exit. "We remember everything, Ilya."

"Then good luck," Ilya says. "I'll be awaiting the good news."

And with that, the princes leave the building, and Ilya continues her work. Knowing that the villagers' lives hang in the balance, you move quickly to follow her lead.

*label bookmark1

*temp plaguemethod ""
*label plaguechoice
*choice
    *selectable_if (alchemy >= 50) #I use the late alchemist's cauldron to synthesize draughts for Ilya's use.
        *set alchemy %+ 15
        *set acounter +1
        *set draughtofquickrecovery true
        *set manarecoverypotion true
        *set plaguemethod "alchemy"
        You lift up the travel sack you had brought with you from Sienan and dump its contents onto the alchemist's table, all the while scanning through the recipes in your head. Draughts of Quick Recovery for the patients, and Mana Recovery Potions for Ilya—hardly the most inspiring weapons with which to combat a plague, but it's the best you can do.
        
        The cauldron is lit with a simple burst of theurgy, and the water brought to boiling. You roll up your sleeves and get to work.
        *goto nonresiliencepath
    *selectable_if (enchantment >= 50) #I use enchantment magic to assist Ilya in healing the patients.
        *set enchantment %+ 15
        *set ecounter +1
        *set glyphofimmunity true
        *set plaguemethod "enchantment"
        There's a lot to be nervous about when using Glyphs of Immunity as a means of treatment, but you're a skilled enchanter assisting an
        *if (enchantment < 76)
            even more skilled
        *else
            equally skilled
        theurge—if nothing else, no one has better odds at making this gambit work than the two of you.
        
        Mana bleeds from your fingers and twists into spell circles. Beside you Ilya straightens her back and begins casting spells of her own, and just like that the two of you get straight to work.
        *goto nonresiliencepath
    *selectable_if (learning >= 50) #I use my knowledge of good medical practices to the patients' benefit.
        *set learning %+ 15
        *set plaguemethod "learning"
        The breadth of your knowledge on the topic is hardly expert—what with a good portion of it having been haphazardly compiled just before leaving Sienan—but the royal library is rich and vast, and you are nothing if not a quick learner. You quickly scan through the nuggets of wisdom in your head—how boiling grassvane twice makes it easier to keep down, or how bloodletting in moderation can increase the effects of theurgy—and move quickly to begin their application.
        
        Ilya recognizes your efforts as things she would have done herself, and makes it known that she appreciates the extra pair of hands. She rolls up her sleeves and begins casting her theurgy with undivided focus, and just like that the two of you lose yourselves in the rhythm of work.
        *page_break
        *goto nonresiliencepath
    *disable_reuse *selectable_if (alchemy > 70) #I let Ilya handle the patients while I brew more draughts of resilience.
        *set plaguemethod "nothing"
        The potion does precious little for ones already inflicted, but there are plenty of those still whole and healthy in Merdel Village. According to accounts from the plague's first iteration three years ago, the draught's effects will see them through the week unscathed.
        
        You relay your plan to Ilya, and instantly her brows furrow in worry. "I get what you're saying, ${fname}, but…" She scans the room with hesitant eyes, and you can almost see her counting the number of patients in her head. "Stopping the spread of the plague is important, but the village's population numbers well in the hundreds, while we only brought so much ingredients with us. And try as I might, ${fname}, more people here [i]will[/i] die if I don't have you helping me."
        *choice
            #"We can't focus on the short-term. We'll purchase ingredients from Silcur as the need arises."
                *set rilya %- 10
                The healer purses her lips, clearly unconvinced. "I don't like this, but you're the alchemist," she says with a resigned sigh. "I'll have to make do without your help, then. Godspeed, ${fname}."
                *goto resiliencepath
            #"You're right. It would be best to focus our efforts on saving those already afflicted."
                The healer's relief is palpable. "I'm glad, ${fname}. For these people and my sanity both."
                *goto plaguechoice

*label nonresiliencepath
*page_break
It isn't long before you began to lose hope.

Of course, you knew from the outset that plenty of patients would die despite your best efforts. But it is another thing entirely to witness their eyes suddenly lose their luster, or feel their bodies go slack in your grasp,
*if (plaguemethod = "learning")
    lips still stained by the green of grassvane.
*elseif (plaguemethod = "alchemy")
    lips still slick with the liquid of your potion.
*else
    *comment (plaguemethod = "enchantment")
    your Glyphs still burning through their bloodstream.
And yet you cannot allow yourself even a moment to grieve their passing, because
*if (plaguemethod = "alchemy")
    there are ingredients to fetch and potions to pour, and you feel the weight of hundreds of lives on your shoulders with every stir of the cauldron.
*else
    *comment (plaguemethod = "enchantment" / "learning")
    another body awaits your treatment, the life that it holds ebbing and waning before your very eyes.

*if (plaguemethod = "alchemy")
    You hear Barza call out encouraging words to the ghastly-pale man you had seen earlier, an orphan who he had taken under his wing.
*else
    *comment (plaguemethod = "enchantment" / "learning")
    Barza tells you that the ghastly-pale man is his apprentice, an orphan by the name of Thais.
He came to the village ten years ago, after the 'accidental arson' of his family home, and has since become one of Merdel's best swordsmen. Ilya makes a shallow cut in his forearm, watches it bleed white, and shakes her head. Barza nods his head grimly and prepares the hearse.

*if (plaguemethod = "alchemy")
    Later, as you bring a new batch of potions to boil, you spy an elderly man out of the corner of your eye. He holds up a skeletal hand as Ilya approaches, refusing treatment through gesture where his voice fails him. He points instead to the bed at the corner of the room, which Barza explains contains his granddaughter. You duly note the way Ilya and Barza both hold their silence on the fact that she is already dead.
*else
    *comment (plaguemethod = "enchantment" / "learning")
    An elderly man holds up a skeletal hand as you approach, refusing treatment through gesture where his voice fails him. He points instead to the bed at the corner of the room, which Barza explains contains his granddaughter. You don't have the heart to tell him that she is already dead.

*if (plaguemethod = "alchemy")
    The woman by the window introduces herself as Leis. Ilya talks to her to keep her lucid while she feeds her drops of your potion, and Leis speaks freely of her beloved husband, who works out in Calinger, and the lovely daughter they've raised together. With your potion assisting Ilya's feverish care, the healer somehow manages to pull Leis out of the critical stage.
*else
    *comment (plaguemethod = "enchantment" / "learning")
    The woman by the window introduces herself as Leis. Ilya talks to her to keep her lucid as you try to treat her illness, and she speaks freely of her beloved husband, who works out in Calinger, and the lovely daughter they've raised together. With your combined efforts, you somehow manage to pull her out of the critical stage.

Her daughter watches her fall asleep and mistakes it for the worst; the anguished wail she lets out rattles you to your very core.

At the cusp of dusk, Ilya turns to you with trembling hands and barely-held tears. "We can't keep going like this," she says, her voice hoarse with exhaustion. "We can't save everyone, or we'll collapse along with them. We have to," a gulp, an averted gaze, "Let some of them go."

You drink in the sight of the room, afoul with the stench of death and decay, and know that there is wisdom in the healer's words. If you are to maximize your impact here, you will have to start prioritizing.

The question is, how?
*goto yousavewho

*label resiliencepath
*page_break
It isn't long before your resolve begins to waver.

Ilya's fear, it turns out, is well-founded. Talented though she is, Ilya is but a single theurge in a sea of death, and all alone her efforts are like a dinghy struggling to stay afloat in a storm. You mix the draughts amidst the din of pained groans and leaden death, hands rifling through ingredients and potions deftly poured into flasks. And though you try your best to focus on the task at hand, it becomes increasingly difficult to do so as the consequences of your actions begin to manifest around you.

You hear Barza call out encouraging words to the ghastly-pale man you had seen earlier, an orphan who he had taken under his wing. He came to the village ten years ago, after the 'accidental arson' of his family home, and has since become one of Merdel's best swordsmen. Ilya makes a shallow cut in his forearm, watches it bleed white, and shakes her head. Barza nods his head grimly and prepares the hearse.

Later, as you bring a new batch of potions to boil, you spy an elderly man out of the corner of your eye. He holds up a skeletal hand as Ilya approaches, refusing treatment through gesture where his voice fails him. He points instead to the bed at the corner of the room, which Barza explains contains his granddaughter. You duly note the way Ilya and Barza both hold their silence on the fact that she is already dead.

The woman by the window introduces herself as Leis. Ilya talks to her to keep her lucid while she works her theurgy, and Leis speaks freely of her beloved husband, who works out in Calinger, and the lovely daughter they've raised together. You do your best to ignore the way her voice weakens with each passing minute, even under Ilya's feverish care. When her form finally falls slack in the healer's arms, Leis's daughter claws at the windows until her fingers bleed red, the anguished wail that she lets out rattling you to your very core.

At the cusp of dusk, Ilya turns to you with trembling hands and barely-held tears. "I can't keep going like this," she says, her voice hoarse with exhaustion. "I can't save everyone, or I'll collapse along with them. I'll have to," a gulp, an averted gaze, "Let some of them go."

You drink in the sight of the room, afoul with the stench of death and decay, and know that there is wisdom in the healer's words. If she is to maximize the impact of her theurgy, she will have to start prioritizing.

The question is, how?
*goto ilyasaveswho

*label yousavewho
*choice
    #We prioritize the old and infirm. Their chances are low, but we have to [i]try[/i].
        *set noble %+ 15
        *set prenoble %+ 15
        Who can rest easy at night, knowing that they've willingly doomed others to a certain death?
        
        It's a hell of a question to pose, especially knowing that you may very well have sealed the fate of others, ones who stood a better chance—but what else is there to say? Plague-breaking is a thankless business, and it's your conscience that is paying the price.
        
        You relay your opinion to Ilya, and she agrees to it with no resistance. If you didn't know better, you'd think the healer was all too grateful that the decision had been taken out of her hands.
        *goto savetheold
    #We prioritize the old and infirm. The village's recovery will hinge upon its leadership's survival.
        *set noble %- 15
        *set prenoble %- 15
        After all, the aftermath of a plague is often just as deadly as the plague itself. With no captain at its helm, how can the lost ship right its course?
        
        It's an almost laughable act, to weigh the lives of others as if they were pieces on a chessboard. The simple thought of it makes you grind your teeth together—but what else is there to do? Plague-breaking is a thankless business, and it's your conscience that is paying the price.
        
        You relay your opinion to Ilya, and she agrees to it with no resistance. If you didn't know better, you'd think the healer was all too grateful that the decision had been taken out of her hands.
        *goto savetheold
    #We prioritize the young and able-bodied. They'll be needed workforce in Merdel's path to recovery.
        *set noble %- 15
        *set prenoble %- 15
        After all, the aftermath of a plague is often just as deadly as the plague itself. With no one to till the fields and fend off bandits, how would Merdel survive?
        
        It's an almost laughable act, to weigh the lives of others as if they were pieces on a chessboard. The simple thought of it makes you grind your teeth together—but what else is there to do? Plague-breaking is a thankless business, and it's your conscience that is paying the price.
        
        You relay your opinion to Ilya, and she agrees to it with no resistance. If you didn't know better, you'd think the healer was all too grateful that the decision had been taken out of her hands.
        *goto savetheyoung
    #We prioritize the young and able-bodied. They still have their whole lives left to live.
        *set noble %+ 15
        *set prenoble %+ 15
        At least the elderly had already led long lives, if not necessarily full ones.
        
        It's a hell of a silver lining, and you grit your teeth at the simple thought of it—but what else is there to say? Plague-breaking is a thankless business, and it's your conscience that is paying the price.
        
        You relay your opinion to Ilya, and she agrees to it with no resistance. If you didn't know better, you'd think the healer was all too grateful that the decision had been taken out of her hands.
        *goto savetheyoung
    *selectable_if ((plaguemethod = "alchemy") or (plaguemethod = "enchantment")) #Screw that. I'm going to save everyone, and damn the consequences.
        *set noble %+ 25
        *set prenoble %+ 25
        Ilya balks at the statement, her expression at once turning indignant. "I won't let you," she seethes, her grip iron-strong around your arms. "You're going to get yourself killed, ${fname}, and I'll be damned if I just stand by and watch you do it."
        
        You shake yourself free of her grasp and mumble a half-hearted apology, already moving to make good on your promise. There are
        *if (plaguemethod = "alchemy")
            potions to brew
        *else
            *comment (plaguemethod = "enchantment")
            glyphs to cast
        and people to save, and not even Ilya's well-meaning concern can stand in your way.
        *page_break
        *if (plaguemethod = "alchemy")
            *goto saveallalc
        *else
            *comment (plaguemethod = "enchantment)
            *goto saveallenc

*label ilyasaveswho
*choice
    #She should prioritize the old and infirm. Their chances are low, but she ought to at least [i]try[/i.
        *set noble %+ 15
        *set prenoble %+ 15
        You've always known Ilya to be the sensible, practical sort; but who can rest easy at night, knowing that they've willingly doomed others to a certain death? It's a hell of a question to pose, especially knowing that she may very well seal the fate of others in the process, ones who stand a better chance—but what else is there to say? Plague-breaking is a thankless business, and Ilya is already bearing the brunt of the work—it's the least you can do, to bear most of the guilt.
        
        You relay your opinion to Ilya, and she agrees to it with no resistance. If you didn't know better, you'd think the healer was all too grateful that the decision had been taken out of her hands.
        *goto ilyasavetheold
    #She should prioritize the old and infirm. The village's recovery will hinge upon its leadership's survival.
        *set noble %- 15
        *set prenoble %- 15
        After all, the aftermath of a plague is often just as deadly as the plague itself. With no captain at its helm, how can the lost ship right its course?
        
        It's an almost laughable act, to weigh the lives of others as if they were pieces on a chessboard. The simple thought of it makes you grind your teeth together—but what else is there to do? Plague-breaking is a thankless business, and Ilya is already bearing the brunt of the work—it's the least you can do, to bear most of the guilt.
        
        You relay your opinion to Ilya, and she agrees to it with no resistance. If you didn't know better, you'd think the healer was all too grateful that the decision had been taken out of her hands.
        *goto ilyasavetheold
    #She should prioritize the young and able-bodied. They'll be needed workforce in Merdel's path to recovery.
        *set noble %- 15
        *set prenoble %- 15
        After all, the aftermath of a plague is often just as deadly as the plague itself. With no one to till the fields and fend off bandits, how would Merdel survive?
        
        It's an almost laughable act, to weigh the lives of others as if they were pieces on a chessboard. The simple thought of it makes you grind your teeth together—but what else is there to do? Plague-breaking is a thankless business, and Ilya is already bearing the brunt of the work—it's the least you can do, to bear most of guilt.
        
        You relay your opinion to Ilya, and she agrees to it with no resistance. If you didn't know better, you'd think the healer was all too grateful that the decision had been taken out of her hands.
        *goto ilyasavetheyoung
    #She should prioritize the young and able-bodied. They still have their whole lives left to live.
        *set noble %+ 15
        *set prenoble %+ 15
        At least the elderly had already led long lives, if not necessarily full ones. It's a hell of a silver lining, and you grit your teeth at the simple thought of it—but what else is there to say? Plague-breaking is a thankless business, and Ilya is already bearing the brunt of the work—it's the least you can do, to bear most of guilt.
        
        You relay your opinion to Ilya, and she agrees to it with no resistance. If you didn't know better, you'd think the healer was all too grateful that the decision had been taken out of her hands.
        *goto ilyasavetheyoung

*label savetheold

*if (plaguemethod = "alchemy")
    You spend the rest of the day slaving away at the cauldron, burning through ingredients and pouring potions into bottles at a quick, steady pace. Ilya fetches the draughts as the need arises, and combined with her theurgy your efforts begin to make dents against the relentless wave of death and decay.
    *if (alchemy > 64)
        *set prestige +5
        *goto saveoldgood
    *else
        *set prestige +1
        *goto saveoldbad
*elseif (plaguemethod = "enchantment")
    You immediately get to work, approaching the nearest elderly patient with incantations already recited in your head. You forge the glyphs with careful bursts of mana, conscious of the long road ahead that you've still yet to tread. Ilya falls into step beside you, a similar expression of focus etched onto her features, and together your combined efforts begin to make dents against the relentless wave of death and decay.
    *if (enchantment > 64)
        *set prestige +5
        *goto saveoldgood
    *else
        *set prestige +1
        *goto saveoldbad
*else
    *comment (plaguemethod = "learning')
    You immediately get to work, soothing the nearest elderly patient and making a shallow cut in her forearm. You allow yourself a relieved breath when her blood flows red against your palm, reach for the goblet of distilled grassvane you've prepared, and feed her the concoction in slow, gentle drops. Ilya falls into step beside you, the flare of her mana soothing against the stale, musty air, and together your combined efforts begin to make dents against the relentless wave of death and decay.
    *if (learning > 64)
        *set prestige +5
        *goto saveoldgood
    *else
        *set prestige +1
        *goto saveoldbad

*label saveoldgood

Night falls on Merdel Village.
*page_break
The decision to deny aid to so many patients had been a difficult one to make, but you're able to take some comfort in the fruits that it bears.

There had been ten elderly patients struggling to stay alive when you had first begun the treatment. Although four of them have since passed away despite your best efforts, there were still more left alive by the end of the ordeal than you had any right to expect.

You try not too think too hard about the number of younger patients whose conditions had suddenly taken a turn for the worst. Instinctively, you know that they likely could have been saved had you spared the time to treat them, but there is no use wondering about could-have-beens where Barza's hearse has already arrived at your doorstep.

You and Ilya both have made your beds, and there is nothing you can do but to sleep in it.

And sleep in it you do.
*page_break
*goto neutralwake

*label saveoldbad

Night falls on Merdel Village.
*page_break

The decision to deny aid to so many patients had been a difficult one to make. But you imagine it will be an even more difficult one to live with, given the carnage that it had resulted in.

For all that you had given it your best shot, there is no denying that the task of saving the most vulnerable of the villagers is beyond your meager abilities as
*if (plaguemethod ="alchemy")
    an alchemist.
*elseif (plaguemethod = "enchantment")
    an enchanter
*else
    a medical advisor.
There had been ten elderly patients struggling to stay alive when you had first begun the treatment, and nearly all of them have since passed away. The two that remains have thankfully entered a state of relative stability, though it is difficult for you to take pride in that—not when it was Ilya's theurgy that had done most of the legwork.

Furthermore, it is difficult not to think about the number of younger patients whose conditions had suddenly taken a turn for the worst. Instinctively, you know that they likely could have been saved had you spared the time to treat them, and that such a task would perhaps be a more suitable match for your meager talents. Instead, now the young and old alike lie motionless in their beds, pain and anguish etched onto their features, even in death.

Regardless, the deed is done, and Barza's hearse has arrived at your doorstep. There is nothing left to do but to rest, and pray that fortune favors you when the sun rises once more tomorrow.

You have made your bed, and there is nothing you can do but to sleep in it.

And sleep in it you do.
*page_break
*goto neutralwake

*label savetheyoung
*set prestige +3
*if (plaguemethod = "alchemy")
    You spend the rest of the day slaving away at the cauldron, burning through ingredients and pouring potions into bottles at a quick, steady pace. Ilya fetches the draughts as the need arises, and combined with her theurgy your efforts begin to make dents against the relentless wave of death and decay.
    *goto savetheyoung2
*elseif (plaguemethod = "enchantment")
    You immediately get to work, approaching the nearest patient with incantations already recited in your head. You forge the glyphs with careful bursts of mana, conscious of the long road ahead that you've still yet to tread. Ilya falls into step beside you, a similar expression of focus etched onto her features, and together your combined efforts begin to make dents against the relentless wave of death and decay.
    *goto savetheyoung2
*else
    *comment (plaguemethod = "learning')
    You immediately get to work, soothing the nearest patient and making a shallow cut in her forearm. You allow yourself a relieved breath when her blood flows red against your palm, reach for the goblet of distilled grassvane you've prepared, and feed her the concoction in slow, gentle drops. Ilya falls into step beside you, the flare of her mana soothing against the stale, musty air, and together your combined efforts begin to make dents against the relentless wave of death and decay.
    *goto savetheyoung2

*label savetheyoung2

Night falls on Merdel Village.
*page_break

The decision to deny aid to so many patients had been a difficult one to make, but you're able to take some comfort in the fruits that it bears.

There had been eight younger patients struggling to stay alive when you had first begun the treatment. Although one of them have since passed away despite it all, there is no denying that your efforts had resulted in nothing short of a miracle.

You try not too think too hard about the slew of older patients who had succumbed to their illnesses, without your treatment to improve their odds. Ilya does the rounds before you turn in for the night, cutting small gashes into the skin of their forearms. She watches them bleed onto the wooden floor, one after the other, drops white as starlight.

She turns away from you each time, the sound of her heavy breathing clear as a funeral bell in the stagnant air. You need not see her face yourself to know the expression she must wear.

Barza arrives at your doorstep with his hearse, and you know then that the time for could-have-beens is up. You and Ilya both have made your beds, and there is nothing you can do but to sleep in it.

And sleep in it you do.
*page_break
*goto neutralwake

*label ilyasavetheold

Night falls on Merdel Village.
*page_break

The decision to deny aid to so many patients had been a difficult one to make. But you imagine it will be an even more difficult one to live with, given the carnage that it had resulted in.

For all that Ilya had given it her best shot, it is apparent that the task of saving the most vulnerable of the villagers is beyond what can be expected of a lone theurge, no matter how talented she may be. There had been ten elderly patients struggling to stay alive when Ilya had first begun the treatment, and nearly all of them have since passed away. The one that remains have thankfully entered a state of relative stability—though judging by the soft, muffled sobs escaping Ilya's lips, it is difficult for the healer to take any pride in that.

Furthermore, it is difficult not to think about the number of younger patients whose conditions had suddenly taken a turn for the worst. Instinctively, you know that they likely could have been saved had Ilya spared the time to treat them, and that such a task would perhaps be more suitable given your limited resources. Instead, now the young and old alike lie motionless in their beds, pain and anguish etched onto their features, even in death.

Regardless, the deed is done, and Barza's hearse has arrived at your doorstep. There is nothing left to do but to rest, and pray that fortune favors you when the sun rises once more tomorrow.

You and Ilya both have made your beds, and there is nothing you can do but to sleep in it.

And sleep in it you do.
*page_break
*goto neutralwake

*label ilyasavetheyoung

Night falls on Merdel Village.
*page_break
The decision to deny aid to so many patients had been a difficult one, and you think it for the best that you'd been the one to make it. The burden you've asked Ilya to shoulder is tremendous, and your lifting what weight you can off her conscience is a kindness that she only deserves.

There had been eight younger patients struggling to stay alive when Ilya had first begun her treatment. Four of them have since passed away despite her best efforts, and of the four that remains one is still in a critical stage.

There is also the matter of the older patients, most of whom had succumbed to their illnesses without Ilya's healing to improve their odds. Ilya does the rounds before she turns in for the night, cutting small gashes into the skin of their forearms. She watches them bleed onto the wooden floor, one after the other, drops white as starlight.

She turns away from you each time, the sound of her heavy breathing clear as a funeral bell in the stagnant air. You need not see her face yourself to know the expression she must wear.

Barza arrives at the doorstep with his hearse, and Ilya hurriedly composes herself once more. She greets him with a peerless mask of confidence, and Barza kindly ignores the way her hands tremble in the hot, dry night.

You and Ilya both have made your beds, and there is nothing you can do but to sleep in it.

And sleep in it you do.
*page_break
*goto neutralwake

*label saveallalc
Ilya watches you despairingly as you slave away at the cauldron for the rest of the day, burning through ingredients and pouring potions into bottles like a @{pronvar madman|madwoman|madperson}. She stares at you for a long while, irate, disbelieving, until the groan of a patient shakes her out of her anger and sets her to work once more.

The sun sets to reveal a glimmering black sky, the moon a deathly sickle against the canvas of night.
*fake_choice
    #I refuse to rest.

Your fingers chafe and bleed from the strain of your efforts, wrists singed where the cauldron fire had licked.
*fake_choice
    #I refuse to rest.

Ilya pulls at your elbow and demands for you to stop, her own knees nearly buckling under the weight of exhaustion.
*fake_choice
    #I refuse to rest.

When the sun is risen once more, there are no more ingredients for you to reach for, and no mana left to spend. You spy Ilya out the corner of your eye—the healer is crumpled on the floor, but is already waking up a mere two hours into her sleep.

You give her what smile you can manage, gesturing to the full deck of potions laid out beside you, and feel your vision gently fading to black.
*if (alchemy > 80)
    *set prestige +8
    *goto bigsuccessalc
*else
    *goto bigfailalc

*label saveallenc
Ilya watches you despairingly as you summon a glyph and immediately begin treating the next patient. You feel your mana ducts crackle angrily at the strain of the effort, already spent from a full day of casting. But you power through their resistance through sheer force of will, and even as your head spins and your vision goes blurry, you cast on.

Ilya can do nothing but stare at you for a long while, irate, disbelieving, until the groan of a patient shakes her out of her anger and sets her to work alongside you once more.

The sun sets to reveal a glimmering black sky, the moon a deathly sickle against the canvas of night.
*fake_choice
    #I refuse to rest.

Your temple throbs and rages and begs for you to rest. Your hands tremble as the ducts underneath scrape for the last vestiges of your mana.
*fake_choice
    #I refuse to rest.

Ilya pulls at your elbow and demands for you to stop, her own knees nearly buckling under the weight of exhaustion.
*fake_choice
    #I refuse to rest.

When the sun is risen once more, there are no tricks up your sleeve that you have yet to try, no more mana left to spend.

You spy Ilya out the corner of your eye—the healer is crumpled on the floor, her consciousness having left her mere minutes ago. You gingerly try to reach down towards her, intending to guide her to one of the empty beds.

You instead feel your feet give out, as if a rug had been pulled out from under you. Darkness claims your vision before you could feel your body hit the floor.
*page_break
…
*page_break
*if (enchantment > 80)
    *set prestige +8
    *goto bigsuccessenc
*else
    *goto bigfailenc

*comment inefficient coding here. streamline it by the next update.......if you dare
*comment (if youre a codediver and youre seeing this no you didnt)

*label bigsuccessalc
The first thing you see when you open your eyes is the orange rays of sunset as they filter through the windows. The next is a head of familiar white hair, and blue eyes holding concern and relief in equal measure.

"You're finally awake," Ilya says from where she's seated at your bedside. There's an uncharacteristic slouch to the healer's posture, accompanied by the kind of eyebags she would usually be in a rush to remedy.

*choice
    #I wasn't the only one to collapse. I ask her how she's holding up.
        *set noble %+ 15
        *set prenoble %+ 15
        "I'm fine, don't worry," you say, holding a hand up to refuse her. "I wasn't the one who had to cast theurgy on a colleague after having just collapsed myself."
        
        Ilya scoffs at that. "And [i]I[/i] wasn't the one who was on the verge of mana exhaustion for the, oh, [i]eleventh time[/i] this year," she says testily. "You really need to get that hero complex under control. It's going to kill you one of these days."
        
        *if (charming > 50)
            "Not while I have you around," you say, giving the healer a wink for good measure.
        *else
            "I'll try not to be so reckless in the future," you allow, if only to appease her.
        You take a proper gaze around the room, then, and note that you've been moved to the house's master bedroom, separated from the village's makeshift sickbay by a rickety wooden door. You purse your lips as the day's events come rushing back, and hesitantly pose the question to Ilya. "How are the…?"
        *goto postbigsuc
    #It's rare to see Ilya so haggard. On reflex, I try to lighten the mood.
        *set charming %+ 15
        *set precharming %+ 15
        "You look awful, Ilya. Want me to brew a potion for those eyebags?"
        
        Ilya scoffs at the offer. "It goes without saying that we have other things to be worrying about," she says. "Besides, I've seen you try your hand at glamor before, and the results…well. I wouldn't wish it on my worst enemy."
        
        "I take offense to that, just so we're clear," you quip, before casting a proper gaze around the room. It appears you've been moved to the house's master bedroom, separated from the village's makeshift sickbay by a rickety wooden door. You purse your lips as the day's events come rushing back, and hesitantly pose the question to Ilya. "How are the…?"
        *goto postbigsuc
    #There's no sense in wasting time with pleasantries. I inquire about the villagers' fate.
        *set charming %- 15
        *set precharming %- 15
        You gingerly push yourself up on the bed, and Ilya moves forward in an offer to help. You hold a hand up to refuse her, instead leaning on the headboard for support. When you speak, your voice comes out hoarse and scratchy. "The villagers…?"
        *goto postbigsuc

*label neutralwake
You awaken at the break of dawn, not because you are well-rested, but because the day's carnage had followed you into your dreams.

You shake your head violently in a bid to expel the nightmares, even as you pull away from the mattress. The specters linger in the air around you, catapulting jeers and pleas for salvation in turns, their cries a funeral bell in your head as you stumble out of the room.

Pushing through the door jambs, your gaze immediately lands upon your companions, huddled together around a small table. They look up as you approach, their faces silent mirrors of your own—sickly complexions and weary eyes, hair unkempt from a night that refused to grant them rest.

"How are you feeling?" Ilya asks after you've found your seat. It is almost laughable that she would ask the question, when you know you couldn't have looked any worse than her. "Tell me if anything feels strange, ${fname}. You went through a lot yesterday."

*choice
    #I'm not the only one pushed to brink. She had better conserve her mana.
        *set noble %+ 15
        *set prenoble %+ 15
        "I'm fine, don't worry. I wasn't the one doing most of the legwork," you say, leveling an even stare at the healer. "That would be you, Ilya. You should still be resting right now, given how much mana you expended."
        
        She gives you a lopsided smile and a noncommittal nod. You know as well as she does that sleep does not come easy with the scent of death hanging so thickly in the air. "I'll give it another try in an hour or so," she lies easily, before jerking her head in the princes' direction. "We have more important matters to discuss right now."
    #The atmosphere is awfully tense—my first reflex is to try and lighten the mood.
        *set charming %+ 15
        *set precharming %+ 15
        "You look awful, Ilya. Fancy a little glamour for those eyebags?"
        
        The healer scoffs at the offer. "It goes without saying that we have other things to be worrying about," she says. "Besides, I've seen you try your hand at glamor before, and the results…well. I wouldn't wish it on my worst enemy."
        
        "I take offense to that, just so we're clear," you quip, even knowing that she has the right of it. You turn your gaze towards the princes then, and Leon answers you with a tight-lipped grin. "Though I suppose we have more important matters to discuss right now."
    #There's no sense in wasting time with pleasantries. We have business to attend to.
        *set charming %- 15
        *set precharming %- 15
        "Don't worry about me," you say evenly, already turning in the princes' direction. "We have more important matters to discuss right now."

Saine nods solemnly and moves to close the door behind him, casting one last gaze upon the patients still drifting in and out of fitful sleep. When he speaks, his tone is low and quiet, as if in fear that someone might be listening in. "I'm sorry," he says, not quite looking you in the eyes. "You and Ilya worked so hard, but Brother and I have made no progress on our end."

You can feel the faint hope you had nursed in your heart quietly fizzling out, like candle in a rainstorm. "Tell me."

"There is no method to this plague's madness, no matter how much we try to make sense of it," Leon scoffs, looking ready to tear his hair out. "We still don't know how it spreads—we only know that it [i]does[/i], and viciously at that."

Saine nods in affirmation. "We ruled out contaminated water early on. Merdel and Silcur share the same river as their water source, so it doesn't check out for the plague to only be limited to Merdel," he continues. "We ran a couple of tests using the potions from Sienan just in case, and so far nothing's come of that."

"The other possibilities are dead ends as well," Leon adds. "The plague affects those who have fully quarantined in their homes, and by all accounts it seems that insect extermination efforts have been as thorough as they are fruitless."

Ilya's gaze is downcast. "Then we're back at square one."
*goto squareone

*label bigsuccessenc
The first thing you see when you open your eyes is the orange rays of sunset as they filter through the windows. The next is a head of familiar white hair, and blue eyes holding concern and relief in equal measure.

"You're finally awake," Ilya says from where she's seated at your bedside. There's an uncharacteristic slouch to the healer's posture, accompanied by the kind of eyebags she would usually be in a rush to remedy.

*choice
    #I wasn't the only one to collapse. I ask her how she's holding up.
        *set noble %+ 15
        *set prenoble %+ 15
        "I'm fine, don't worry," you say, holding a hand up to refuse her. "I wasn't the one who had to cast theurgy on a colleague after having just collapsed myself."
        
        Ilya scoffs at that. "And [i]I[/i] wasn't the one who was on the verge of mana exhaustion for the, oh, [i]eleventh time[/i] this year," she says testily. "You really need to get that hero complex under control. It's going to kill you one of these days."
        
        *if (charming > 50)
            "Not while I have you around," you say, giving the healer a wink for good measure.
        *else
            "I'll try not to be so reckless in the future," you allow, if only to appease her.
        You take a proper gaze around the room, then, and note that you've been moved to the house's master bedroom, separated from the village's makeshift sickbay by a rickety wooden door. You purse your lips as the day's events come rushing back, and hesitantly pose the question to Ilya. "How are the…?"
    #It's rare to see Ilya so haggard. On reflex, I try to lighten the mood.
        *set charming %+ 15
        *set precharming %+ 15
        "You look awful, Ilya. Fancy a little glamour for those eyebags?"
        
        Ilya scoffs at the offer. "It goes without saying that we have other things to be worrying about," she says. "Besides, I've seen you try your hand at glamor before, and the results…well. I wouldn't wish it on my worst enemy."
        
        "I take offense to that, just so we're clear," you quip, before casting a proper gaze around the room. It appears you've been moved to the house's master bedroom, separated from the village's makeshift sickbay by a rickety wooden door. You purse your lips as the day's events come rushing back, and hesitantly pose the question to Ilya. "How are the…?"
    #There's no sense in wasting time with pleasantries. I inquire about the villagers' fate.
        *set charming %- 15
        *set precharming %- 15
        You gingerly push yourself up on the bed, and Ilya moves forward in an offer to help. You hold a hand up to refuse her, instead leaning on the headboard for support. When you speak, your voice comes out hoarse and scratchy. "The villagers…?"
*label postbigsuc

*achieve maxplague
The healer averts her gaze for a brief moment before meeting yours resolutely, as if forcing herself.  "I don't agree with what you put yourself through, ${fname}, but I can't deny that you did well," she says, allowing for a slight smile. "We managed to get most of the patients stable, at least for the time being. Although…"

You feel the relief swelling in your lungs suddenly being doused. "Although?"

"Leon and Saine came back this morning, and…well, I suppose it would be better for you to hear from them yourself." Ilya stands and dusts herself off, before offering you a hand. "I did what I could to patch you up. Here, can you stand?"

You obediently let the healer grasp your hand and yank you to your feet. There's a light throbbing somewhere in your cranium and a general soreness permeating your body; although, given what you put yourself through last night, you had expected it to feel much worse. Not that it matters, of course—Ilya would normally be the first person to tell you to rest when you need to. That she's already encouraging you to be up and about speaks volumes about how grave the situation must still be.

Ilya leads you past the bedroom's wooden door, and you find yourself in the sickbay once more. The number of patients still lingering on their mattresses have not declined much since when you first began your treatment yesterday—and for all that the number of lives still hanging in the balance terrifies you, there is indisputable relief swelling in your chest, seeing how many people yet remains.

You feel something slick underfoot as you step through the room, and refuse to look at what must be viscous white blood staining the floorboards. Instead, you focus your attention on a boy with chestnut-brown hair, who immediately bolts up from his seat when he sees you approach.
*goto meetprinces

*label bigfailalc
The first thing you see when you open your eyes are the orange rays of sunset as they filter through the windows. The next is a head of familiar white hair, and blue eyes holding concern and relief in equal measure.

"You're finally awake," Ilya says from where she's seated at your bedside. There's an uncharacteristic slouch to the healer's posture, as well as the kind of eyebags she would usually be in a rush to remedy.

*choice
    #I wasn't the only one to collapse. I ask her how she's holding up.
        *set noble %+ 15
        *set prenoble %+ 15
        "I'm fine, don't worry," you say, holding a hand up to refuse her. "I wasn't the one who had to cast theurgy on a colleague after having just collapsed myself."
        
        Ilya scoffs at that. "And [i]I[/i] wasn't the one who was on the verge of mana exhaustion for the, oh, [i]eleventh time[/i] this year," she says testily. "You really need to get that hero complex under control. It's going to kill you one of these days."
        
        *if (charming > 50)
            "Not while I have you around," you say, giving the healer a wink for good measure.
        *else
            "I'll try not to be so reckless in the future," you allow, if only to appease her.
        You take a proper gaze around the room, then, and note that you've been moved to the house's master bedroom, separated from the village's makeshift sickbay by a rickety wooden door. You purse your lips as the day's events come rushing back, and hesitantly pose the question to Ilya. "How are the…?"
        *goto postbigfail
    #It's rare to see Ilya so haggard. On reflex, I try and lighten the mood.
        *set charming %+ 15
        *set precharming %+ 15
        "You look awful, Ilya. Want me to brew a little potion for those eyebags?"
        
        Ilya scoffs at the offer. "It goes without saying that we have other things to be worrying about," she says. "Besides, I've seen you try your hand at glamor before, and the results…well. I wouldn't wish it on my worst enemy."
        
        "I take offense to that, just so we're clear," you quip, before casting a proper gaze around the room. It appears you've been moved to the house's master bedroom, separated from the village's makeshift sickbay by a rickety wooden door. You purse your lips as the day's events come rushing back, and hesitantly pose the question to Ilya. "How are the…?"
        *goto postbigfail
    #There's no sense in wasting time with pleasantries. I inquire about the villagers' fate.
        *set charming %- 15
        *set precharming %- 15
        You gingerly push yourself up on the bed, and Ilya moves forward in an offer to help. You hold a hand up to refuse her, instead leaning on the headboard for support. When you speak, your voice comes out hoarse and scratchy. "The villagers…?"
        *goto postbigfail

*label bigfailenc
The first thing you see when you open your eyes are the orange rays of sunset as they filter through the windows. The next is a head of familiar white hair, and blue eyes holding concern and relief in equal measure.

"You're finally awake," Ilya says from where she's seated at your bedside. There's an uncharacteristic slouch to the healer's posture, as well as the kind of eyebags she would usually be in a rush to remedy.

*choice
    #I wasn't the only one to collapse. I ask her how she's holding up.
        *set noble %+ 15
        *set prenoble %+ 15
        "I'm fine, don't worry," you say, holding a hand up to refuse her. "I wasn't the one who had to cast theurgy on a colleague after having just collapsed myself."
        
        Ilya scoffs at that. "And [i]I[/i] wasn't the one who was on the verge of mana exhaustion for the, oh, [i]eleventh time[/i] this year," she says testily. "You really need to get that hero complex under control. It's going to kill you one of these days."
        
        *if (charming > 50)
            "Not while I have you around," you say, giving the healer a wink for good measure.
        *else
            "I'll try not to be so reckless in the future," you allow, if only to appease her.
        You take a proper gaze around the room, then, and note that you've been moved to the house's master bedroom, separated from the village's makeshift sickbay by a rickety wooden door. You purse your lips as the day's events come rushing back, and hesitantly pose the question to Ilya. "How are the…?"
    #It's rare to see Ilya so haggard. On reflex, I try to lighten the mood.
        *set charming %+ 15
        *set precharming %+ 15
        "You look awful, Ilya. Want me to brew a little potion for those eyebags?"
        
        Ilya scoffs at the offer. "It goes without saying that we have other things to be worrying about," she says. "Besides, I've seen you try your hand at glamor before, and the results…well. I wouldn't wish it on my worst enemy."
        
        "I take offense to that, just so we're clear," you quip, before casting a proper gaze around the room. It appears you've been moved to the house's master bedroom, separated from the village's makeshift sickbay by a rickety wooden door. You purse your lips as the day's events come rushing back, and hesitantly pose the question to Ilya. "How are the…?"
    #There's no sense in wasting time with pleasantries. I inquire about the villagers' fate.
        *set charming %- 15
        *set precharming %- 15
        You gingerly push yourself up on the bed, and Ilya moves forward in an offer to help. You hold a hand up to refuse her, instead leaning on the headboard for support. When you speak, your voice comes out hoarse and scratchy. "The villagers…?"
*label postbigfail

The healer purses her lips and refuses to meet your gaze, and you can feel your heart immediately sinking.  "We tried our best, ${fname}," she says, in lieu of an answer.

The implication is clear. "Then they didn't make it."

"Some of them did. Our efforts were not in vain," she insists, though the tone of her voice carries no conviction. "We're dealing with something beyond the borders of human knowledge here, ${fname}…callous though it may be to say, a result like this is only to be expected."

There is a perfect silence that falls upon the room when Ilya's voice trails off, and you feel the weight of it on your shoulders, leaden and oppressive. You wonder for a moment if this is how the executioner feels, once the guilty is beheaded and the axe is lifted once more.

"Regardless, there is work yet to be done. Leon and Saine came back this morning, and…well, I suppose it would be better for you to hear from them yourself." Ilya stands and dusts herself off, before offering you a hand. "I did what I could to patch you up. Here, can you stand?"

You obediently let the healer grasp your hand and yank you to your feet. There's a light throbbing somewhere in your cranium and a general soreness permeating your body; although, given what you put yourself through last night, you had expected it to feel much worse. Not that it matters, of course—Ilya would normally be the first person to tell you to rest when you need to. That she's already encouraging you to be up and about speaks volumes about how grave the situation must still be.

Ilya leads you past the bedroom's wooden door, and you find yourself in the sickbay once more. There are precious few patients still lingering on the mattresses, and you try not to think too hard about how many people must have died in the time you were out. You feel something slick underfoot as you step through the room, and refuse to look at what must be viscous white blood staining the floorboards. Instead, you focus your attention on a boy with chestnut-brown hair, who immediately bolts up from his seat when he sees you approach.
*label meetprinces

"${fname}, you're up!"
*page_break

Saine immediately runs in your direction, his steps somehow still silent against the normally creaky floorboards. His brother follows behind him at a more leisurely pace, clearly mindful of the patients still drifting in and out of fitful sleep.

"Good to have you back," he says, his tone just above a whisper. "Though I wish we could've let you wake up to better news."

You swallow a gulp. "Tell me."

"There is no method to this plague's madness, no matter how much we try to make sense of it," the blond scoffs, looking ready to tear his hair out. "We still don't know how it spreads—we only know that it [i]does[/i], and viciously at that."

Saine nods in affirmation. "We ruled out contaminated water early on. Merdel and Silcur share the same river as their water source, so it doesn't check out for the plague to only be limited to Merdel," he continues. "We ran a couple of tests using the potions from Sienan just in case, and so far nothing's come of that."

"The other possibilities are dead ends as well," Leon adds. "The plague affects those who have fully quarantined in their homes, and by all accounts it seems that insect extermination efforts have been as thorough as they are fruitless."

Ilya's gaze is downcast. "Then we're back at square one."

*label squareone
*choice
    #I can feel my heart hammering in my chest. We can't go through yesterday again.
        *set emotional %+ 15
        *set preemotional %+ 15
        Your body may be mostly rested, but it'd be a lie to say that you're mentally prepared for another round of life-saving maneuvers. How many lives would you be able to save, before the strain claims your own in exchange?
        
        You feel Saine's gaze flicker over to you briefly, and wonder what it is that gave you away—the full-body shiver, or the grimace you must be wearing? Whatever it is that the younger prince sees, he sagely decides not to comment on it. A decision you're all too happy to mimic—you're in the thick of it now, and there's nothing you can do but press forward.
    #What else did we expect, sending a couple of mercenaries to map out an epidemic?
        *set optimistic %- 15
        *set preoptimistic %- 15
        You knew going in that your mission is hopelessly understaffed. For all that Ilya insists that all theurge missions are, given the art's supply-to-demand ratio, you should have been saddled with capable assistance—more capable, at least, than a pair of princes whose specialties lie in [i]killing[/i].
        
        Regardless, it's too late for such regrets. You're in the thick of it now, and there's nothing you can do but press forward.
    #No use stressing over it. These are the cards we've been dealt.
        *set emotional %- 15
        *set preemotional %- 15
        If nothing else, the lack of similarities with other diseases is useful information for you to know. That's a step closer to the truth—small though it may be.
    #I have faith, despite it all. We always manage to come out on top [i]somehow[/i]..
        *set optimistic %+ 15
        *set preoptimistic %+ 15
        Ilya is one of the best theurges in the land, and you're not too shabby of a mage yourself. There's sure to be a way out of this predicament somehow, especially with you two at the helm—the most important thing is for you not to lose hope.

"It's the same conclusion as the one drawn years ago, at the advent of the first plague," Ilya sighs. "We had attributed the lack of a pattern to faulty reports, given how chaotic the first wave had been. But to see the same thing repeated now…is baffling, to say the least. It defies everything we know about modern medicine."

You know that, of course, as well as anyone. Disease outbreaks are far from rare in the continent, and in the past entire cities had been decimated as one plague gave way to the next. Yet in all these cases, the catalyst for a widespread epidemic has consistently remained one of the three. 

"So what do we do now?" Saine asks, breaking the collective silence. "There's no way we can keep this up.
*if (plaguemethod = "nothing")
    Barza's already gone and distributed the draughts of resilience ${fname} brewed, and we don't have enough materials on hand for ${them} to make a second batch. And even if we do, if we keep going at our current pace—Ilya and ${fname} will be joining these patients before long."
*else
    We don't have enough draughts of resilience, for one, not to mention the amount of duress Ilya and ${fname} are bound to go through. If we keep doing what we've been doing, we'll be joining these patients before long."

"Then we go back to Sienan," Ilya says, resolute in a way that's almost convincing. "We will ask for the saintess to send a proper delegation of theurges, perhaps one that she will lead herself. We have sorely underestimated moonvein—I'll see to it that we don't make that mistake twice."

Leon's frown is deep and immediate, if resigned. "Then we're abandoning these people."

Ilya squares her shoulders, daring the prince to contradict her. "It doesn't sit well with me, either. But we have no leads, and our supplies are rapidly thinning—we can't do much here either way. It would be highly irresponsible for us to stay."

*choice
    #I object on instinct. We can't just leave these people here to die!
        *set noble %+ 15
        *set prenoble %+ 15
        *set emotional %+ 15
        *set preemotional %+ 15
        "We must not have exhausted all our options yet," you protest. "It will take the better part of a week for us to go to Sienan and back—I don't know if these villagers can last that long. We have to stay and help—"
        
        "I won't have any of it this time, ${fname}," the healer hisses, her eyes narrowing. "You're always so eager to throw your life away, and I'm done with just standing at the sidelines and watching you do it. I [i]will[/i] leave for Sienan tonight, and it doesn't matter if you're coming with me or not. See for yourself how you'll fare without a theurge."
        
        Saine takes the healer's hand in his own, gently rubbing at her palm in a bid to soothe her anger. "${fname} didn't mean it, Ilya. I'm sure ${they}'ll be willing to listen to reason—let's just give ${them} a minute."
        
        "We'll go back to Sienan tonight, ${fname}," Leon says evenly, though his gaze remains fixated on the ground. "I command it as your liege. Param is unkind to retainers who have opted to shirk their duties."
        
        You grit your teeth in frustration at the order. Even if you choose to defy it, there is precious little that you'll be able to do without the rest of the White Fangs' assistance. There is a flash of anger and desperation that ripples through you as you recall the villagers who had passed away in this very room, the distant wails that had pierced through the air as Barza broke the news to their families. You gaze around the chamber at the sleeping patients, sweating, fitful in their beds—and know that they and theirs have now been condemned to a similar fate.
        
        But what else is there to do? You are fighting against impossible odds, undermanned and under-equipped. Facing a deadly illness insubordinate to the principles of medicine, striking at its victims like bolts of thunder, vicious and irregular.
        *goto irregular
    #Ilya has the right of it. Our prospects are deeply uncertain, should we stay.
        *set noble %- 15
        *set prenoble %- 15
        *set emotional %- 15
        *set preemotional %- 15
        "We'll make the trip as quickly as we can," you say, echoing Ilya's sentiment. "Lives will be lost in the process, but we'll be returning with more decisive means to combat the plague with."
        
        "Good, then we're in agreement," Ilya acknowledges, her voice even despite the tumult of emotions in her gaze. "I better not hear any objections from you, Leon. ${fname} and I will be leaving for Sienan tonight, whether you like it or not. You're welcome to see for yourself how you'll fare against the plague without us."
        
        Leon shakes his head. "I would never ask that of you. Thank you for everything you've already done…I'll inform Barza on our next course of action."
        *goto leonfinal
    #The Church had miscalculated the issue's severity. The responsibility does not fall on us.
        *set noble %- 15
        *set prenoble %- 15
        *set emotional %- 15
        *set preemotional %- 15
        "We'll make the trip as quickly as we can," you say, echoing Ilya's sentiment. "What we've done here already goes above and beyond the call of duty."
        
        "Good, then we're in agreement," Ilya acknowledges, her voice even despite the tumult of emotions in her gaze. "I better not hear any objections from you, Leon. ${fname} and I will be leaving for Sienan tonight, whether you like it or not. You're welcome to see for yourself how you'll fare against the plague without us."
        
        Leon shakes his head. "I would never ask that of you. Thank you for everything you've already done…I'll inform Barza on our next course of action."
        *goto leonfinal
    #To see so much preventable death happen on account of the Church's reservation is infuriating.
        *set noble  %- 15
        *set prenoble %- 15
        *set emotional %+ 15
        *set preemotional %+ 15
        The Church had better be ready to own up to their mistakes.
        
        "We'll make the trip as quickly as we can," you say, echoing Ilya's sentiment. "But the Church made a mistake in sending such a small party for so monumental a task. They should be made to answer for their folly."
        
        Ilya turns to you in surprise, clearly not expecting the slight. "I understand your concern, ${fname}, but our theurges are already spread thin as is. Sending more people here necessarily means that elsewhere, others will suffer in their stead. Given the information we had, I think the saintess made the right call."
        
        "There is time enough for this later, once we're out of the woods," Saine interrupts softly, though you don't miss the hint of steel in his tone. "Whoever was at fault for this mistake, it has already been made. We need to focus on seeing it corrected."
        
        "Then we go back to Sienan tonight," Leon says evenly, though his gaze remains fixated on the ground. "Thank you for everything you've done, you two. I'll inform Barza on our next course of action."
        *goto leonfinal

*label leonfinal

There is a finality to Leon's tone that turns your stomach, knowing that the decision has now been made. Even knowing that you're making the right choice, there is a flash of guilt that ripples through you as you recall the villagers who had passed away in this very room, the distant wails that had pierced through the air as Barza broke the news to their families. You gaze around the chamber at the sleeping patients, sweating, fitful in their beds—and know that they and theirs have now been condemned to a similar fate.

But what else is there to do? You are fighting against impossible odds, undermanned and under-equipped. Facing a deadly illness insubordinate to the principles of medicine, striking at its victims like an archer's volley, vicious and irregular.

*label irregular
*page_break Irregular...?

The thought strikes you like a burst of lightning on a clear day.

[i]Irregularity[/i] as a term is far from foreign to you, as it is discussed at length in all magical tomes worth their salt. In every branch of magic, one of the biggest issues mages have to contend with is the art's volatile nature, for even the innocuous Boomerang Gale could backfire spectacularly if its spell circles are improperly cast. Advances in thaumaturgy have since been made that allowed even beginner mages to stabilize the spell and command it according to their will. And yet in the most powerful, high-level spells, such control often escapes even the most prodigious of spellcasters.

In particular, the phenomenon puts you to mind of the spell…

*choice
    #...Roving Thunder.
        *set thaum %+ 15
        Before Skywrath, there was Roving Thunder, named the crown jewel of all thaum spells for its destructive potential and ability to break entire armies. But such cosmic powers came at a terrible cost—there is only so much control its caster could exert over the spell's intricate framework, and it is inevitable that with every cast, some of its effects would veer towards allies and attack them instead.
        
        Studies done on the spell have since been greatly discouraged, and instructions on its casting expelled from the Hieron Grimoires. But the principle that governs it remains a universal constant—with Skywrath, with Morana's Wail, and even with Boomerang Gale, thaumers evoke their powers by playing a game of chance. They command the forces of the world with every flick of their fingertips, but their control is never truly complete.
        
        Because magic is a volatile art, and the greater its scale, the more irregular its behavior.
    #...Synthesis: Palmerra.
        *set alchemy %+ 15
        If one is a good alchemist, then it must follow that they are also a good experimenter. Of all the branches of magic, alchemy is the one art that consistently deals with uncharted territory, as the real-world constraints of time and materials often necessitate its practitioners to defy convention in their syntheses.
        
        For no alchemic substance is this truer than for Palmerra, a drug of Arcadian origin that calls for extracts of the now-extinct palmeri vine. But the drug's immense utility has seen alchemists far and wide tasked by their lords to create a substitute, and so they do. The few attempts that bore success universally bear a tremendous risk—namely, that the concoction may very well kill upon consumption.
        
        Because magic is a volatile art, and the more powerful its effects, the more irregular its behavior.
    #...Banecircle.
        *set enchantment %+ 15
        It is one thing to use magic in bending the elements, but it is another entirely to have command over existence itself.
        
        Such are the powers of Banecircle, the crowning jewel of all enchantment spells. It phases out reality in bursts, painting scars over shadows before spiriting away their hosts. Entire armies have buckled under its oppressive might, the rank and file scattering to the four winds as all around them their comrades phase away to dust.
        
        But such cosmic powers do not come at a cheap price. Even the enchanter that weaves Banecircle does not know how it will behave, or who will suffer its banishment. There are no glyphs whose boundaries it will accept, no commands it will obey—it exists and then it is gone, taking with it whatever it desires.
        
        Because magic is a volatile art, and the more powerful its effects, the more irregular its behavior.
    #...Gatebreaker.
        *set spiritism %+ 15
        The borders between the living and the dead are woven by the gods, but there are those who seek to trespass against the edict of divines. Such is the art of the spiritist, and of all the blasphemies at their employ, greatest of all is Gatebreaker: a terrible spell harnessing the power of violent ghouls to desiccate and dissolve in one fell swoop.
        
        And yet such cosmic powers do not come at a cheap price. Even the spiritist that summons the ghouls does not know how they will behave, or who will suffer their wrath. The spirits shun mercy and eschew command, barreling ever forward towards the first target they have in their sights, subjecting them to their all-encompassing might.
        
        Because magic is a volatile art, and the more powerful its effects, the more irregular its behavior.

It dawns on you then that you've been looking at this all wrong. Merdel Village's ordeal cannot be explained through medical means, because it is not medical in nature. No, the lack of a pattern implies something much more sinister is at work, and you feel dread clench around your heart as the thought begins to settle.

Moonvein is no malady.

It is a curse.

*page_break

It is remarkably easy to establish a plan of action, once the veil of mystery has been parted. Curses of moonvein's scale and duration are unheard of throughout the entirety of Arvanian history, and yet you can find no cause for you to panic—because all curses must obey the rules of enchantment, and chief among those rules is that enchantments can [i]always[/i] be dispelled.

The ways for you to do so are plain enough for
*if (enchantment > 60)
    an enchanter
*else
    a mage
of your caliber. Curses can only sustain themselves over long periods of time through the use of a nexus—devices infused with high-density magical energy, which can act as a substitute for the mana normally provided by an active caster. If the nexus goes, so does the curse—all you have to do is find it.

Your quest to do so has taken you to the front door of Barza's home. Ilya briefly raps against the door, and there is a shuffling noise inside as Barza rushes to answer. You duly note the man's haggard appearance as he opens the door, eyes bleary and hair sticking out in clumps. The sight of him takes Ilya by surprise, and the healer takes a hesitant step back before she clears her throat and dips  her head lightly. "Barza," she says cordially. "I hope the day finds you well."

The black-haired man's mouth pulls into a taut, unhappy line. "Is that a joke?" he says shortly. There is venom in his tone that catches you off guard, given how accommodating and polite he had been since you first arrived at the village. The man himself seems to realize it too, and he schools his grimace into an apologetic smile. "I'm sorry, I shouldn't be getting short with you. You and your paladins have been a true blessing for the people of Merdel, priestess. We are truly in your debt."

"We are only doing our duty," Ilya deflects easily. "And there are no need for apologies. I understand these are challenging times, Barza."

"I thank you for your consideration," Barza replies, dipping his head into a slight bow. "What can I do for you, priestess?"

"A bit of good news, first. The patients currently remaining in the sickbay have all stabilized, and we're positive that they'll make a full recovery given enough rest and medicine."

"Thank you for your efforts," Barza says with a wan smile. "Something tells me it's not the only thing you came to talk about, however."

Ilya nods, slow and cautious. "We'll be frank, Barza—it will be impossible for us to provide treatment indefinitely, given how much we're lacking in manpower and supplies," she says. "What we're doing now is mitigatory work. Unless we get to the root of the problem, Merdel will continue to be ravaged by moonvein, and all our efforts will have been in vain."

Barza turns his face away, his expression at once resigned and devastated. "I had feared that you would say as much. Then I assume you'll be heading back to the capital to petition the Church?"

"If it comes down to it, we will," Ilya agrees. "But there is a lead we'd like to pursue, one that could possibily end the epidemic before the week is out."

Barza's eyes widen in shock, and for a moment he looks at Ilya as if she is Isha reborn. You can identify the exact moment he schools his expectation into something milder, more cautious—but that glimmer of hope never quite leaves his eyes. "Then I am at your service, priestess. Anything I can do for you—simply name it, and I will see it done."

*page_break

At Ilya's request, Barza provisions your party with a rough map of Merdel Village. As the village's acting chief, he knows all two hundred and twenty villagers by name, as well as who amongst them had contracted moonvein over the past few weeks. He puts this knowledge to use in marking each of their households on the map, and it is not long before you notice that a pattern emerges.

Although curses of this magnitude are unheard of in the realm of magic, you are able to extrapolate its likely behavior from its smaller-scaled brethren. When applied to an area rather than a single target, enchantments are likelier to strike closer targets than they are far—and sure enough, the map Barza has drawn show a concentration of cases around a single landmark.

You point at the landmark in question, and Barza raises his eyebrows in surprise. "Merdel Cave?" he wonders aloud. "That's where the curse is centered?"

"Tell us more about this cave," you press.

Barza leans back in his seat, still shaking his head in disbelief. "[i]Cave[/i] is a bit of a misnomer. It's actually a sinkhole, created after the rockbed above it collapsed. There's a freshwater pool at its base, and we use it as a place of burial for the village's most honored." Barza looks up at you then, almost aggressive in his inquisition. "I was there just a few days ago, to put my father's body to rest. It's a place of great importance to us—you're saying someone's used it as a curse's haven?"

Ilya leans forward and reaches out a comforting hand, but Barza is quick to yank his arm away. "Nothing is certain yet," she tries. "And in any case, it's most important for us to—"

"The demon who did this will pay," Barza growls. "I swear it on my father's name."

*choice
    #His anger is a mirror of my own. This is the height of degeneracy.
        *set emotional %+ 15
        *set preemotional %+ 15
        "Whoever did this won't get away with it," you say. Barza looks up as the words leave your lips, searches your gaze as if on the lookout for platitudes—a fruitless effort, because you meant every word you said.
        
        Ilya straightens her back beside you. "Right now, there is no greater revenge than for us to break this curse," she says. "Will you guide us to the cave?"
        
        "I will," Barza agrees readily, galvanized by his righteous fury. He rises from his seat and motions towards the door, and all around you the White Fangs move to follow him. "This way, priestess."
    #He's losing sight of what's important. I remind him to focus on solving the plague.
        *set noble %- 15
        *set prenoble %- 15
        "That's all well and good, but first we need to get to the bottom of this curse," you say, and though Barza seethes at the slight, he sagely decides to keep his silence. "Will you guide us to the cave?"
        
        "I will," he agrees readily, despite the tension in his jaw. He rises from his seat and motions towards the door, and all around you the White Fangs move to follow him. "This way."
    #He's welcome to his outburst, if that's what he wants. He's served his purpose already.
        *set emotional %- 15
        *set preemotional %- 15
        "Right now, there is no greater revenge than for us to break this curse," Ilya says diplomatically. "Will you guide us to the cave?"
        
        "I will," Barza agrees readily, despite the fury still etched onto his features. He rises from his seat and motions towards the door, and all around you the White Fangs move to follow him. "This way, priestess."
    #The sight of him harrows me. I'll do everything I can to stop this plague.
        *set noble %+ 15
        *set prenoble %+ 15
        Ilya appears to echo your sentiments. "Right now, there is no greater revenge than for us to break this curse," she says. "Will you guide us to the cave?"
        
        "I will," Barza agrees readily, despite the fury still etched onto his features. He rises from his seat and motions towards the door, and all around you the White Fangs move to follow him. "This way, priestess."

*page_break

The path to Merdel Cave twists and turns like the body of a snake, weaving past treelines and brambles before opening up to a clearing with weathered limestone at its base. The sinkhole is easily identifiable even in the distance, an opening large enough for three people to pass through altogether. Moss crawls up the cavern's walls and finds purchase on the surrounding rocks, and you take care not to slip as you approach the cavity. "This is it," Barza says when you've reached your destination.

You kneel down at the sinkhole's edge and peer inside. Daylight filters in from the sun shining overhead, refracting off the underground pond's surface and illuminating the cave's rocky edges. You do your best to focus on the water's depths, your mana rippling through still water for any imprint the artifact may have left behind. And sure enough, you find it—the barest hint of magical anima, woven into the the pond in a way that signifies it had been years in the making.

*choice
    #The oddity is worth mentioning. I bring it up to Barza and the White Fangs.
        "That's strange," you remark, turning around to face the rest of your party. "How long has Merdel suffered from the plague, again?"

        It is Barza that answers your question. "It is nearly two weeks since the first case became known to us. Why do you ask?"

        "There is a faint trace of magic in there, but it looks to be several years old at least. If it's truly the curse's nexus, then the plague should have begun a long time ago."

        "It can't be," Leon hisses, disbelieving. "So we were mistaken after all?"
        
        "It's…quite possible,' you agree reluctantly. "But a lot of the elements surrounding this case have been unprecedented—a delayed curse would hardly be the most surprising thing we've had to contend with."
        
        "Regardless, this is the only lead we've got," Ilya adds, resolute. "We've gotten this far already; there's no sense for us to backtrack now."
        
        "Then I suppose we'll have to get to this artifact," Saine says. "The question is, how?"
    #Perhaps I'm reading things wrong. I shouldn't douse their optimism so close to the goal.
        "There's a trace of mana in there. Something magical is at the bottom, unquestionably."
        
        "Then we're on the right track," Saine remarks, his tone laced with relief. "I suppose we just have to get to this artifact, then. The question is, how?"

*label divechoice
*choice
    #We can have the pond bring it to us. I will cast Waterwyrm.
        A high-level thaum spell designed primarily for naval combat, Waterwyrm shapes a designated body of water into a mighty serpent, capable of punching through ship hulls and scattering their sails to the winds. But here, in a claustrophobic space with still water as its fuel, the serpent will be much weaker—just enough to reach for the bottom of the pond and bring the artifact back to you, without collapsing the cave in the process.
        
        Will you cast Waterwyrm?
        *choice
            *selectable_if (thaum > 65) #Yes, cast this spell.
                *set waterwyrm true
                "I might know a way," you say, already reaching for your mana reserves. "It's fortunate that they've chosen a pond of all places to hide the nexus. A Waterwyrm should do the trick."
                
                A look of recognition flashes across Ilya's features. "I see. I hadn't thought of such a solution, but it could certainly work," she mutters thoughtfully. "Although…it's asking for a lot, but would it be possible for you to bring it to the surface instead? The nexus is the best lead we have to finding out who's behind this curse, after all."
                
                "I can certainly try," you reply, hoping you don't come across as uncertain as you feel. Waterwyrm is an attack spell by nature, and for all that it can be coaxed to become forceful instead of destructive, the finesse required to pull it off is more than you've ever had to exert on a spell before.
                
                But if there's any thaumer out there who can manage the feat, it would be you.
                
                "Stand back," you say, the ancient words already forming at the tip of your tongue. Mana bleeds from your fingertips in rushing torrents, painting spell circle in the still surface of the pond. The water there glistens and bends under the weight of your powers, and before long something large and serpentine takes shape in its watery depths.
                
                Waterwyrm roils through the sinkhole like a plunging blade, single-minded in its ferocity as it makes its way down to the nexus. As you feel it approaching the pond's base, you pull back against the spell's power like the tightening of a leash, and nearly double over from the backlash it sends back. Stubbornly, persistently, you assert your dominance over it as a master would their raucous pupil, and though it resists for what feels like an eternity, the serpent eventually relents to your control.
                
                The nexus bounds upwards almost languidly, buoyed by the tamed beast. Saine reaches for the artifact as it drifts to the pond's edge, and holds it up for all of you to see.
                *goto truthroute
            #No, I'll do something else.
                *goto divechoice
    #Saine should be able to blink to the pond's base, with a little alchemic support.
        The support in question being, of course, a Mana Recovery Potion.
        
        It's a good thing that the potion is such a compact liquid. For someone of Saine's meager magical talents, half a gulp would be enough to restore his mana back to its original state. All he has to do is keep a full gulp in his mouth, and consume it sparingly as he makes the trip down. Unless the pond is far deeper than groundwater reserves usually are, he should be able to make the trip back and forth with plenty of mana to spare.
        
        Will you give him the Mana Recovery Potion?
        *choice
            *selectable_if (alchemy > 60) #Yes, I'll hand him the bottle.
                *set manarecoverypotion true
                "I might know a way," you say, and immediately the group collectively turns their gazes on you. "If Saine is up for it."
                
                The brown-haired boy raises an eyebrow in curiosity. "Me?" he asks, pointing a finger at himself.
                
                You nod by way of confirmation, reaching inside your cloak for the familiar glass bottle. You brandish it for the rogue to see, and his confusion only seemed to increase. "Is that…a Mana Recovery Potion?"
                
                "Yes, though this is a particularly high concentration variety," you affirm. "A single mouthful would be able to restore your mana twice, three times over."
                
                It is Ilya who now turns a curious stare in your direction. "But what function does it serve—ah," she says, catching herself mid-sentence. "Do you intend to make him blink to the pond's base?"
                
                *if (charming > 50)
                    "Got it in one. What do you say, Saine?"
                *else
                    You reply with a nod, your gaze still fixated on Saine. "Will you do it?"
                    
                "Of course," he says, managing a grin. "I'll be back before you know it."
                
                "Down the potion in halves," Ilya advises, concern written plain across her features. "If you haven't reached the bottom by the time you swallow the first gulp, come straight back up, okay?"
                
                "I'm not my brother," Saine says, in lieu of a proper answer. In a surprising show of tact for Barza's benefit, Leon keeps his protest to an inaudible grumble. "Don't worry about me."
                
                You hand the potion to him, and the rogue obediently empties the bottle into his mouth. His bloated cheeks make him look even younger than his sixteen years, and you try not to comment on the contrast it paints against the solemn look in his eyes.
                
                The prince sheds his cloak and dives, and the four of you wait with bated breaths in anticipation of his return.
                *page_break
                Mercifully, you do not have to wait long. Saine returns within two minutes, gasping for breath but otherwise unharmed. Leon pulls him out of the water and loses his footing on the slippery ground; both princes fall in a heap by the pond's side and nearly send the item back into the depths.
                
                Saine extracts himself from his brother, thanking him with a tone better suited for admonishment. Regardless, he picks the artifact up from the pond's edge and holds it up for all of you to see.
                *goto truthroute
            #No, because we've already consumed the stock we brought along with us from Sienan.
                *goto divechoice
    #I have no spare potions, but a Glyph of Magesong can achieve the same effect.
        The Glyph is simple enough to cast, if a little daunting given the spell's notoriously poor cost-to-benefit ratio. The true challenge will be tailoring it to affect a moving target, a feat even proficient enchanters are known to struggle with.
        *choice
            *selectable_if (enchantment > 60) #Luckily, I'm skilled enough as an enchanter to rise up to the challenge.
                *set glyphofmagesong true
                "I might know a way," you say, and immediately the group collectively turns their gazes on you. "If Saine is up for it."
                
                The brown-haired boy raises an eyebrow in curiosity. "Me?" he asks, pointing a finger at himself.
                
                "You," you confirm. "We'll need to rely on your blinking capabilities. We don't know how deep the pond goes—but it shouldn't be too different from a regular well, given that it's a groundwater pool. You should be able to be in and out in about a minute, given consistent blinking."
                
                Saine considers the proposal for a moment, looking wholly unconvinced. "I get that it's the best option we've got, but I can't exactly use the technique for that long—"
                
                "Because of mana limitations," you interject, and the young prince nods in affirmation. "That's where I come in."
                
                "A Glyph of Magesong," Ilya mutters thoughtfully, having connected the dots. "I see. But the spell will need to be continuously active while Saine is in motion…"
                
                "I can manage," you say. "Though if you feel the Glyph wearing off, Saine—you should come back up immediately."
                
                "I understand," the rogue replies with a grin. "I'll be back in no time."
                
                "Come back up at the first sign of trouble," Ilya advises, concern written plain across her features. "I mean it, Saine. I don't care how close to the bottom you think you are."
                
                "I'm not my brother," Saine says, in lieu of a proper answer. In a surprising show of tact for Barza's benefit, Leon keeps his protest to an inaudible grumble. "Don't worry about me."
                
                Having agreed on a course of action, you and Saine both make the necessary preparations. Before long, the spell is cast and the prince's cloak shed—he dives for the bottom of the pond, and the four of you wait in anxious silence for his return.
                *page_break
                Mercifully, everything goes without a hitch. It takes some expert mana control on your part, but your Glyph's hold on Saine's form never falters, even as he darts into the water's depths. Sure enough, the young prince returns to the surface within two minutes, gasping for breath but otherwise unharmed. Leon pulls him out of the water and loses his footing on the slippery ground; both princes fall in a heap by the pond's side and nearly send the item back into the depths.
                
                Saine extracts himself from his brother, thanking him with a tone better suited for admonishment. Regardless, he picks the artifact up from the pond's edge and holds it up for all of you to see.
                *goto truthroute
            #I'm not experienced enough in enchantment for such a risky move. We'll find another way.
                *goto divechoice
    #Attempting to retrieve it is risky. Better to just destroy this place, cave and all.
        Given how incensed Barza had been to find out that the cave had been defiled, he is likely to be resistant to this plan. After all, destroying the cave would necessitate the destruction of his predecessors' tombs, including the father he had laid to rest just a few days ago.
        *choice
            #It is either this or the plague's continuation. He will have to understand.
                The proposal feels bitter on your tongue, but you speak it all the same. "Given how deep groundwater reserves usually are, retrieving the artifact will be far too risky. It would be irresponsible to send anyone down there."
                
                "Then what do you suppose we do?" Leon asks, his head tilted in confusion. "We can't just leave the artifact be, can we? Not when we're so close."
                
                "We won't have to fetch the artifact to destroy it," you say evenly. You turn your gaze towards Barza then, and find that horror has already begun dawning on the black-haired man's face. "We can simply destroy the cave instead."
                
                Barza backs away from you, his entire form shaking as if he's staring an Elyssian beast in the maw. "No," he manages after a while, his voice barely above a whisper. "There must be another way."
                
                "We are sorry, Barza," Ilya says after a while, her eyes downcast. "We understand that these are hallowed grounds for your people. But this is for the good of the village—I'm sure your father and the others will understand."
                
                There is a long period of silence, punctuated only by the curses Barza mutters under his breath as he tries to keep himself together. You look up at his shaking form, face buried against his forearm, and struggle to connect him to the composed leader you had met at the village gate. It is a tremendous sacrifice you are asking him to make, especially given how much he has lost already. But there is no better path forward than this, and you're sure Barza knows it just as well as you do.
                
                "Very well," he says at last, utterly defeated. "If it will stop the plague…then I'll commit this act of blasphemy myself."
                *goto bombroute
            #There must be a better way—I'll think of something else.
                *goto divechoice

*label truthroute

*set silcurtruth true
A crystalline item of the deepest green, a tumultuous mist of foul magic percolating within. Beyond the shadow of a doubt, Saine has in his hands the moonvein nexus.

*choice
    #Finally. Finally, the villagers will find peace.
        *set noble %+ 15
        *set prenoble %+ 15
        You can still recall every body on every bed, every grimace twisted by the pain. You wouldn't wish such torture upon your worst enemy, and certainly not those innocent villagers. You can only be glad that the end of their suffering is in sight.
    #I can't help the hope already swelling in my chest. The curse will be broken.
        *set emotional %+ 15
        *set optimistic %+ 15
        *set preemotional %+ 15
        *set preoptimistic %+ 15
        The cause of this wretched plague is before you now. A glass orb, innocuous and fragile—so easy to break, to shatter—and then it will all be over.
    #This is nothing to get excited about. Our work is far from over.
        *set emotional %- 15
        *set preemotional %- 15
        You still have a culprit to find, after all. Without them in your custody, a second round of moonvein might as well be inevitable.
    #I'm wary of the aftermath. It feels like we're about to make a powerful enemy.
        *set emotional %+ 15
        *set optimistic %- 15
        *set preemotional %+ 15
        *set preoptimistic %- 15
        Who knows what else they'd be capable of? Is there any guarantee that you'll walk out of this ordeal in one piece?

Your reverie is interrupted by a sudden motion from your right, and before you could register the act Barza has snatched the nexus from Saine's grasp. The acting head watches the orb wide-eyed, his visage by turns surprised, angry, and—vindicated. "This insignia," he mutters, rubbing one finger across the embossed iron at the artifact's base. "So it really was him."

All around him, you and the rest of the White Fangs scramble forward to gaze at the symbol he has identified—and the sight of it stops you in your tracks.

It is instantly recognizable, brash in its design. You've seen it plastered on heraldic flags, sculpted on chestplates.

Carved onto the handle of a cup.

The lion and the snake, entwined as one.

The insignia of House de Icharea.

*page_break

A profound silence falls over your group as you make your way back to the village, Barza at the head of the pack and seething with a quiet fury. You spy his hand curling into a fist, tight enough to draw blood—and know then that if left to his own devices, the man would march into the de Silcur mansion and try to kill the baron himself.

*temp baronthoughts ""
*choice
    #And I'll be right there beside him. What the baron has done is unforgivable.
        *set emotional %+ 15
        *set preemotional %+ 15
        *set baronthoughts "mad"
        It is truly beyond you to imagine that someone could be so heartless. Whatever his motivations, whatever excuses he might summon once he is confronted with the evidence—nothing could absolve him of his guilt.
    #I'll reserve my judgment until more information comes to light.
        *set emotional %- 15
        *set preemotional %- 15
        *set baronthoughts "dudewhy"
        After all, if the baron truly is at fault, why would he leave behind so obvious a trail? It's obvious that there's more to the story, and haphazardly passing judgment is the last thing you should be doing right now.
        
        Not that you're all too eager to bring it up to Barza. The man looks to be at the edge of exploding—and rightfully so, in many ways. Were you in his position, it's unlikely that you would've been able to keep so cool a head.
    #The baron did not strike me as a callous murderer—we're still missing something here.
        *set optimistic %+ 15
        *set preoptimistic %+ 15
        *set baronthoughts "dudewhy"
        After all, if it was his intention to let Merdel Village fester in the plague—why petition the saintess for help? Param is the largest nation in Arvanand, and the king has no shortage of issues to divert him; how would he have caught wind of a frontier village's illness, were it not for the nobleman's plea?
        
        Something isn't adding up, though far be it from you to bring it up to Barza. The man looks to be at the edge of exploding—and rightfully so, in many ways. Were you in his position, it's unlikely that you would've been able to keep so cool a head.
    #Actually, I've been suspicious of him since the very beginning.
        *set optimistic %- 15
        *set preoptimistic %+ 15
        *set baronthoughts "dudewhy"
        It's difficult to miss how nervous and jittery he was. Clearly he had been hiding something, and that something may very well be that he had been the one to cause the epidemic all along.

It is Ilya who eventually breaks the silence, her tone careful and diplomatic. "We will need to tend to the village, first and foremost. I understand your anger, Barza, but it cannot take precedence over the work still left for us to do."

"I'm glad you found it [i]understandable[/i], priestess," Barza scoffs. "Our village has been ravaged, our ancestral grave defiled. This is not the first time my people have suffered under the rule of your kind, and it will not be the last. You will never understand."

"I don't deny it. I can't ever begin to grasp what you're going through," the healer responds, at once gentle and assertive. "But it doesn't take that much to see that you're intent on throwing your life away."

"The village still needs their acting head," Saine adds earnestly. "There are people to guide, recoveries to oversee. Please, you have to reconsider."

"And after that?" Barza snaps, his features twisted into a grimace. "After the bodies are buried, and you go back on your pilgrimage—what's to stop him from finishing the job?" 

"We'll stop him," Leon says. The prince had not spoken a single word since your group left the cave behind—and now that he has, there is an uncharacteristic chill to his tone that rings strangely in your ears. "You have my word. One way or another, we will see to it that justice is done."

Barza scoffs at the promise. "And why should I trust you—a paladin without so much as the armor to show for it?"

"He is no paladin," Ilya discloses, her eyes affixed firmly on the road ahead. "And we must apologize, Barza—we have not been forthcoming with you."

The older man whirls on her. "What?"

"What we're saying is that Sir Leon will have little trouble handling common knights," the priestess continues. "He is, after all, the most talented swordsman in all of Param, and received tutelage from the kingdom's most illustrious knights."

Barza turns an incredulous stare towards the blond, then, and Leon meets it with his own—steady and resolute. "What is the meaning of this?" he demands, grabbing the blond by the collar. "Who are you really?"

"I am Blessed Leomar, First Prince of the Kingdom of Param," Leon replies, unshaken by the aggression. He extracts the older man's hand from his neck, at once measured and forceful; Barza balks at the strength of his grip, stumbles backward in surprise. Leon keeps his gaze trained on him, the conviction in his tone unmistakable. "Upon my brother's honor, I swear it. The baron [i]will[/i] be brought to justice."

*page_break

There is a strange sort of tension in the air pervading the days that follow your return.

Barza shares no words with you that are not strictly necessary, though he has chosen to keep mum on your identities to the rest of the villagers. It is likely a practical choice, rather than a generous one—after all, Merdel Village has no love lost for Parami rule, and knowing that their saviors are no less than its pinnacle would be of no benefit to them. You and Ilya are glad for it. Though the plague is largely broken, recovery is its own ordeal—and there is enough on your plate as is.

Between full days spent working the sickbay floor and nights of fitful sleep, you never could have a proper conversation with Merdel's villagers. It is instead Leon and Saine who would tell you the tales of a village restored, of fathers and daughters and friends nursing hope in their eyes the way they hadn't in weeks.

*choice
    #Seeing our efforts bear fruit makes it easier to come to terms with everything.
        It would be impossible to call what had happened in Merdel Village anything short of a tragedy, but there is merit in hearing that it has not broken the villagers. Recovery will no doubt be a long, arduous effort—but that the people have a shot at it, at least, provides you no small amount of comfort.
        
        Through it all, Barza's hatred seethes in the background like an ever-present ghost. You catch him bleeding from the hands as he looks out the window, following the sun's trail towards the walls of Silcur. Hear him insisting to himself that he will see the baron's manor torn apart brick by brick—sounding so resolute that you dare not contradict him.
    #The dead still piles owing to our incompetence. We ought not celebrate atop their corpses.
        You hear the tales they do not tell you, as plainly as if they had been spoken. Of grieving widows, and orphans too young to have lost it all—Merdel Village has been devastated by this senseless curse, and their path to recovery will be long and painful.
        
        And your own limitations have played no small part in bringing about such tragedy.
        
        Adding to the grim mood is Barza's hatred, seething in the background like an ever-present ghost. You catch him bleeding from the hands as he looks out the window, following the sun's trail towards the walls of Silcur. Hear him insisting to himself that he will see the baron's manor torn apart brick by brick—sounding so resolute that you dare not contradict him.
    #I'm just glad it's over—for the villagers' sake, as well as for mine.
        The work that you do in the curse's aftermath feels almost like respite, after the torture of that first day. To not have the lives of others be dependent on every little choice you make feels like a greater blessing than you can put to words.

        Still, you put in your best efforts, and watch as it slowly begins to bear fruit. Through it all, Barza's hatred seethes in the background like an ever-present ghost. You catch him bleeding from the hands as he looks out the window, following the sun's trail towards the walls of Silcur. Hear him insisting to himself that he will see the baron's manor torn apart brick by brick—sounding so resolute that you dare not contradict him.

*page_break

Leon busies himself doing what work he can manage in place of the ill and deceased. The blond affects a convincing facade of earnest strength and good cheer, and the mourning villagers welcome his aid as one would the sun after days of storm. Barza does nothing to dispel the fiction, though it's difficult to miss the permanent tension in his jaw. He instead focuses his efforts on organizing burials and rehoming orphans, and privately you wonder how the man hasn't collapsed from grief and overwork.

It would be another week before the last of the patients is discharged, and the matter of the baron is brought up once more. Saine rides to Silcur and relays that the plague is broken; he returns with Sir Joran in tow, who beholds your handiwork with wonder and thanks you profusely on the baron's behalf.

"We are merely doing our duty, Sir Joran," Ilya parries easily, her smile a touch too taut to be genuine. The healer is barely upright after a week of strenuous work, but she hides it well enough that the awestruck knight does not notice. Barza takes note of the droop of her eyes and the slack in her stance—sees them mirrored in you, her stalwart companion—and looks away, a flicker of guilt passing through his features.

"But there are many things I wish to…[i]discuss[/i] with the baron," Ilya says, soldiering on. "For Merdel Village's sake, as well as Silcur's."

"Of course, my lady," the older knight replies reverently. "You and your paladins have done so much for us already. It is no less than our duty to hear out whatever concerns you may have."

Leon nods approvingly at the knight's words. "One more thing. I think it would be best for Barza to join us, as Merdel Village's acting head," he says. Barza regards him with a look of wan surprise, though he opts to keep his silence. A quick look at Sir Joran tells you that he's not the only one to find the offer startling. "He's the one who's led Merdel through the plague, after all. He has a right to be a part of our discussion."

"It trespasses upon the decorum owed to nobility," Sir Joran remarks, slightly apprehensive. "But the baron holds little regard for such things, as you've seen. I cannot give a certain answer yet, but I do not think he will mind."

"I see. Then please tell the baron that we will refuse to meet with him, should Barza be barred from entry," Leon says flatly.

"And that if Silcur faces a second plague for it, that the church will render him no aid," Saine adds.

Sir Joran visibly bristles at the open threat to his liege; it speaks highly of his restraint that he does not comment on it. "I will do as you ask," he declares. "I'm sure the baron will be happy to accommodate your request."

"Then we await the good news, Sir Joran," Ilya says, all smiles. "Jove go with you."

*page_break

"A lowborn headsman, at the table of nobles and royalty. Laughable," Barza remarks sharply, after the knight has departed. "Will you make me watch as you let the baron weasel away from his crimes?"

"I understand your distrust, Barza," Leon says, his voice carefully even. "But if we'd rather the baron slip away from justice, it would make more sense for us to leave you behind. When we told you the baron will be made to pay for his crimes, we meant every word of it."

"You are not the first person to promise this to us," Barza retorts. "And your kind always falls short when it counts. You've met one Parami noble, you've met them all—none of you can see past your own nose."

*choice
    #This schtick is getting old quickly. We've done nothing but help him and his village.
        *set noble %- 15
        *set prenoble %- 15
        After all, did you not just spend a week doing back-breaking work, all in order to save his people? Barza is severely misguided in directing his anger at you, especially when Merdel would have likely been wiped out without your assistance.
        
        And It appears you are not alone in thinking so.
        
        "Then stay behind, if that's what you prefer," Ilya snaps.
    #Barza is a grieving man at the end of his rope. This outcome is expected.
        *set emotional %- 15
        *set preemotional %- 15
        Given what Barza's had to put himself through over the past week, you had expected far worse of a pushback now that your identities have been disclosed. Let the man jeer all he wants; after all, a sharp word or two is of no consequence in the grand scheme of things.
        
        It appears, however, that Ilya is far more disillusioned by Barza's tantrum. "Then stay behind, if that's what you prefer," she snaps.
    #His words sting, given how much we've sweated and bled for Merdel Village.
        *set emotional %+ 15
        *set preemotional %+ 15
        After all, did you not just spend a week doing back-breaking work, all in order to save his people? His suspicion now feels like a spit upon your efforts, and it leaves a bitter sting in your heart to see Barza so callously disregard everything you've done for him.
        
        And It appears you are not alone in thinking so.
        
        "Then stay behind, if that's what you prefer," Ilya snaps.
    *if (baronthoughts = "mad") #We came into his village under deceptive pretenses. He has every right to be furious.
        *set noble %+ 15
        *set prenoble %+ 15
        Who can fault him, for charging you with accusations you've already shown a propensity for? Besides, Param is a cruel place for Arcadians, even in the here and now—their distrust of the country's gentry is as prudent as it is justified.
        
        It appears, however, that Ilya isn't quite as charitable in her views. "Then stay behind, if that's what you prefer," she snaps.
    *if (baronthoughts = "dudewhy") #We came into his village under deceptive pretenses. He has every right to be furious.
        *set noble %+ 15
        *set prenoble %+ 15
        Who can fault him, for charging you with accusations you've already shown a propensity for? Besides, Param is a cruel place for Arcadians, even in the here and now—their distrust of the country's gentry is as prudent as it is justified.
        
        It appears, however, that Ilya isn't quite as charitable in her views. "Then stay behind, if that's what you prefer," she snaps.

There is an uncharacteristic shortness to her tone, one that would normally be masked under layers of diplomatic facade. Saine and Leon both regard her with a look of mild surprise, which the healer promptly ignores; it is apparent that she's past the point of caring. "But think on it, at least—if nothing else, perhaps hearing the baron's reasons firsthand can help grant you a bit of closure. Otherwise, you may one day come to regret that everything you know of this plague came from the mouth of untrustworthy [i]nobles[/i]."

Barza scoffs at the healer's spiel, though the man looks slightly chastened under all his angry bluster. Ilya crosses her arms and waits for his reply; when it becomes apparent that he doesn't intend to give it, she sagely decides against pressing the issue. "We will depart for Silcur at sunset. Meet us at the village gate if you wish to come with us," she says. "In the meantime, ${fname} and I will need to rest for the day ahead. With or without your presence, we will see to it that this plague is stopped once and for all."

And with those final words, Ilya turns her back on Barza and makes for the sickbay once more.

"You'll have to excuse her for getting short with you," Saine says after a while, his gaze fixated on the healer's retreating figure. "This is the first time Ilya's had patients die in her care. Few things weigh quite as heavily on a healer's conscience."

"Mm," Barza replies, noncommittal. A conflicting brew of emotions pass through his features, and his anger seemed to be the tamest one of all—you'd hazard a guess that you'll be seeing the man again come sunset.

"Then we'll be preparing for the trip ahead." Leon is smiling faintly as he says the words, one hand rubbing at the back of his neck. "I hope you'll join us, Barza. Please get some rest in the meantime—you too, ${fname}. Me and Saine will get everything ready."

And with those final words, the four of you disperse to your respective destinations.

You know the path to the sickbay like the back of your hand by now, and your steps take you back to the familiar building within minutes. It feels almost bewildering to open the house's creaking door and behold the emptiness within. Just a few days ago, this place had been filled to the brim with ailing patients a stone's throw away from death. That they have now returned—to the embrace of family members, or to that of the earth—leaves you with a strange, hollow feeling at the pit of your chest.

Regardless, the matter is done, and you've performed admirably by anyone's standards. The only thing left to do is to confront the baron, and then everything will be over for good.

You take a deep breath and move through the room, weaving past now-empty beds and creaking floorboards. You crash on the bed with a palpable sense of release, knowing that the end is now within sight. A lone thought nests itself in our head as sleep begins to cloud your vision:

*if (baronthoughts = "mad")
    The baron will have hell to pay tonight.
*else
    *comment baronthoughts = "dudewhy"
    By hook or by crook, the truth will come to light tonight.
    
*page_break

When you reconvene at the village gate that evening, Barza is already standing by. His expression is a mask of pure impassiveness; he wordlessly acknowledges your arrival with a nod of his head, and proceeds to straddle his horse and point her towards the exit. One after the other, you and the White Fangs fall into line behind him, and together you ride to Silcur under the cold shadow of the moon.

*page_break

The manor comes into view a few hours later, the harsh slopes of its austere architecture seeming all the more sinister under the faint moonlight. A cursory gaze towards the grounds reveals that Sir Joran himself has taken to manning the gate. He stands tall and proud in his silver armor, and assumes a salute as he sees your party approach. Around him his retinue of knights does the same, their form as proper and sharp as the king's knights—and you know then that the task you have at hand is far from an easy one.

Saine had warned your party as much on the road to Silcur: that though the baron is now a rural lord, his family's illustrious history means that his knights count themselves among Param's best. They number only fifteen altogether, as that alone already wrings the baron's treasury dry in upkeeps; but the fact remains that they are elite fighters in their own right, and not ones you'd want to make an enemy of.

And yet if you wish to confront the baron, deliver the justice Leon had promised to Barza—then you must first remove his knights from the picture.

The question is, how?

*temp location ""

*choice
    *selectable_if (thaum > 65) #Sometimes it pays to be straightforward. If necessary, I'll use thaum to subdue them.
        *set thaum %+ 15
        *set location "hallway"
        Heavily outnumbered you may be, but the element of surprise should tip the balance heavily in your favor. Add to that the fact that you're fighting alongside some of the most capable warriors in Param, and you're beginning to feel sorry for the baron's knights and their poor odds.
        *goto thaumpath
    *selectable_if (enchantment > 65) #I'll use a Glyph to isolate the baron. The princes can deal with the rest.
        *set enchantment %+ 15
        *set glyphofsealing true
        *set location "sideroom"
        Elite knights they may be, but little good that will do them against high-caliber enchantments. Thankfully, mages are few and far between in Param, and the ones talented enough to outperform you are locked away in Sienan's mage tower. Without significant opposition, you should have plenty of time to interrogate the baron before the enchantment runs you dry of mana.
        *goto enchantmentpath
    *selectable_if (spiritism > 65) #Once we're inside, I'll use a Spirit Gate to isolate the baron from his guards.
        *set spiritism %+ 15
        *set spiritgate true
        *set location "woods"
        It's a daunting task, even for a spiritist of considerable merit like yourself. To open a spirit gate large and stable enough to transport six individuals in a single trip is difficult enough on its own. But the added pressure of the knights, who will do everything in their power to interrupt your casting and return the baron to safety—the thought of it alone is enough to set you on edge.
        
        Luckily, you're accompanied by incredibly capable fighters who will do their utmost to keep the heat off of you. And once the gambit has been completed, you should be able to interrogate the baron at leisure.
        *goto spiritismpath
    *selectable_if (alchemy > 65) #The neatest outcome would be a full confession. A truth serum should do the trick.
        *set alchemy %+ 15
        *set routelen true
        The White Fangs had regarded you with shock when you proposed the idea—not that you can blame them. The recipe for Routelen, a distilled drug capable of coercing those who consume it into telling the truth, has long been lost to the annals of history. The drug was purged from magical records alongside other drugs of Arcadian origin, the act carried out so thoroughly by Param and Salantira both that its existence is rarely known outside of esoteric circles.
        
        That you've come to learn the forbidden drug's recipe is the silver lining of your otherwise unenviable past. Luckily, your companions have seen fit to keep their inquiries to themselves, and quickly agreed on its usage despite its dubious legality.
        *goto alchemypath

*label alchemypath

Your party crosses into the baron's courtyard without event, and a knight is dispatched to guide you to the manor's stables. You dismount and tie the mares to the stable's posts, and the knight then escorts you inside the mansion. There is a subtle tenseness to your companions' forms, and you know it is because they are going over the plot in their heads. Your role in it all, though pivotal, ended when the cauldron fire is doused and the potion bottled. It is now up to the rest of the White Fangs to see the plan through.

"Welcome back to Silcur, Lady de Alviar," Baron de Silcur says as you enter his sitting room. The man's smile is beatific, his arms spread open in a welcoming gesture. "And of course, your paladins and Headsman Barza as well. We are richer for your presence."

"Thank you, Baron," Ilya replies sweetly, her head lowered slightly in keeping with Parami decorum. "It pleases me to see that you're in good health."

"You are too kind. Please, my lady, follow me to the dining hall. My chefs have expended their best effort in putting together a feast worthy of your deeds."

"Pah," Barza scoffs behind you. The act draws the attention of Sir Joran, who stands guard beside the baron; the knight-captain turns a sharp eye on Barza, his stance tensing like a drawn bowstring. Baron de Silcur peaceably places a hand on his knight's sword arm, and the man begrudgingly relents.

"What say you, my lady?" the baron continues, unfazed.

"It is a tempting offer, Baron," Ilya says, smiling mirthlessly. "But if we are to dine together, then I think it appropriate that my…[i]paladins[/i] are properly introduced to you."

The baron raises one eyebrow, perplexed. "Oh? I see—"

"First, the master mage who has provided invaluable assistance to me in Merdel Village," Ilya says, gesturing in your direction. "Allow me to introduce the Honorable ${fname}, Royal Retainer to Blessed Leomar, Prince of Param."

Baron de Silcur's eyes widen at the mention of your illustrious title, though to his credit he takes the information in stride. "I—that is—welcome, @{pronvar my lord|my lady|most honorable}. I am only sorry I have not been able to show you the proper courtesy you are owed."

*fake_choice
    #It feels nice to be treated with respect. The noble life definitely agrees with me.
    #I struggle to suppress a shudder. I could definitely do without such formality.
    #I don't feel one way or another about it. It's just a title.

Ilya gestures towards Saine next, who has kept a mostly low profile the entire time. "Secondly, this young man is Blessed Iver, Second Prince of Param," she continues. This time the baron makes no effort to mask his shock, his jaw falling open so quickly that you fear it might unhinge from his face. "And lastly, Prince Iver's brother: Blessed Leomar, First Prince of Param."

The baron takes a step back then, eyes wide and incredulous, before remembering himself and moving into a deep bow. All around him, his retinue of knights follow suit. "Your Highnesses. Forgive my impertinence—I have shown you a most discourteous—"

"Come now, Baron," Leon says jovially, motioning for the nobleman to rise. "We've come to celebrate the end of the plague, not to stand on ceremony. You said there was dinner waiting for us?"

"I—yes, Your Highness, you are most gracious," the baron says. "Then, if you would follow me…"

"One more thing," you say, producing a glass bottle from within your cloak. "I took the liberty of procuring a bottle of Kethiri wine on our way here. I understand it's a local specialty, and I was hoping it could be served during dinner?"

The baron eyes the bottle with faint surprise and little else, not knowing that an effective dose of truth serum has been mixed in with the liquid. Instead, he chose to take issue with the wine's supposed quality. "A fine choice, @{pronvar Sir|Madam|Most Honorable}, but many find the taste of Kethiri a little…acquired. I've already made arrangements for a bottle of Sienan Red—"

"Anything but that," Leon interrupts, scrunching his nose. "Capital wine never did sit right with me."

The baron regards him with a curious look, for a while, before nodding in assent. "Very well, Your Highness. Then if the good retainer could hand the bottle to my butler?"

A sturdy-looking, gray-haired man approaches you at the baron's bidding, and you obediently hand the bottle of wine to him. As his figure disappears beyond the dining hall doors, the baron smiles at you and turns to follow suit. "This way, Your Highnesses, if it pleases you."

*page_break

Before long, you are sat in the dining hall and digging into a generously portioned meal of braised chicken and greens. Saine and Ilya handily keep the baron occupied with talk of moonvein and current affairs, while Leon absentmindedly nods along from his seat at the table's head. From what you can glean of the conversation, the baron seems to be a learned and well-connected leader, never missing a step in the Sienan natives' dance of increasingly esoteric and frivolous topics.

It's a worrying realization, given what the baron's been implicated in—you can only hope that his is an isolated case rather than part of a bigger trend.

"At last, the wine," Leon says, reaching for his share of the Kethiri as soon as it is served. He lifts his goblet high, then, and all around him the rest of the dining party—bar Saine—follow suit. "To the end of the moonvein plague," the prince declares. "Once and for all."

There is a series of gulps around the room as the wine is downed. You can taste the strange, bitter edge of the truth serum mixed in with the drink, and a cursory glance at the baron tells you that he can taste it as well. His brows furrow ever so slightly, one part bewilderment, one part caution—but leveraging what suspicions he may have against a royal is the height of treason, and so he sagely decides to keep himself silent.

The truth serum has been consumed, and it only takes mere seconds for its effects to manifest. All that remains is to question the baron.

*page_break

"Now then," Leon leads, leaning with interest over the dining table. "Care to tell me what this is?"

The prince brings an item out of his coat, a plaque of gold-enameled iron engraved with a familiar symbol—the lion and the snake, insignia of the barony. It is all that remains of the nexus, after its glass orb had been shattered as a means of breaking the curse. And yet the most damning aspect of it remains whole and plain enough for you all to see, the baron included.

You and your group watch on as for the briefest of seconds, the baron's eyes flash with recognition—and then his bewilderment slips back on like a mask, and you know then that the man will be attempting deception.

Unfortunately for him, you've taken measures to prevent that.

"It's the Eye of Icharea—huh?" the baron splutters, reflexively jamming a hand against his own mouth. Despite his best efforts, his mumbles are still intelligible through the attempt. "It is the source of the moonvein plague, Your Highness."

"And how have you come across such information, Baron?"

"I planted the Eye in Merdel Cave myself," the baron admits, despite the horror dawning on his features. "I can explain."

*choice
    #We should let him. The baron deserves the chance to defend himself.
        *set noble %+ 15
        *set prenoble %+ 15
        After all, does he not have the truth serum flowing through his bloodstream? You only stand to gain from learning the truth behind Merdel Village's ordeal, and right now, truth is all that the baron is capable of.
    #He massacred innocents. Were it up to me, the baron would be dead by now.
        *set noble %- 15
        *set prenoble %- 15
        Your fingers are itching to draw a spell circle right there and then, to draw up a spell that would separate the baron's head from his body. And yet you know that such brutality, however justified, will draw no shortage of ire from your companions, and more importantly, your lord.
        
        Perhaps accepting the position of retainer was a mistake after all.
    #I'm only relieved that we've successfully acquired the baron's admission. The end is in sight.
        *set optimistic %+ 15
        *set preoptimistic %+ 15
        Justice for Barza's people, and the end of a long and arduous journey for you and the White Fangs. It feels almost surreal to be on the cusp of it, that the curse and perpetrator both have been identified.
    #I keep my eyes on the knights. They may leap at us at any moment.
        *set optimistic %- 15
        *set preoptimistic %- 15
        Luckily enough, there are only a few knights stationed within the dining room proper, with most of them more concerned with potential intruders than they are with invited guests. That gives you a preemptive strike advantage against the rest of the barony's knights—though it certainly doesn't hurt to be vigilant.

"And explain you will," Leon sneers, imperious. "But make no mistake, such a hefty crime warrants and equally brutal punishment. I hope you've prepared yourself, Baron."

The baron is silent, for a long while, his gaze fixated on the floor. "So it's come to this," he says under his breath. "Then you leave me with no other choice. Knights of de Silcur, seize them!"

Sir Joran turns to regard his lord, incredulous. "But Your Lordship, we cannot raise our blades against—"

"I will handle the matter. Just do as I say—and capture them alive," the baron hisses. "Go, man, go!"

*page_break
*set claycannon true
The guards fall upon your party like a mighty storm, their blades unsheathed in fluid motion and their forms charging at you with reckless abandon. Leon meets the vanguard with his sword, parrying the strike with expert ease and kneeing the knight's gut in the chink of his armor. The prince tramples his head in a bid to knock him out, and rapidly twists into a slash that catches another knight under his breastplate. Immediately the entire retinue's attention is on him, the whirling storm of swordplay headed straight for their lord, and it leaves your party with plenty of room with which to isolate the dining hall from the rest of the knights.

For his part, Saine blinks directly towards the dining hall's entrance and positions himself as the first line of defense. He uses the chokehold to his advantage, launching poisoned daggers and cheap strikes in quick succession as the knights try to barrel past him. What little guards manage the feat are met by the sharp edge of Barza's blade and the bludgeoning strength of your Clay Cannons, and one by one their knees buckle under the weight of your combined assault. With Ilya holding up the rear and furiously casting enchantments on your whole party, it is only a matter of time before the entire order falls unconscious at your feet.

The baron watches contemptuously as the last of his knights crash hard against the marble floor. "Damn it all," he curses under his breath, nursing a wound in his abdomen where one of Saine's knives had grazed him. "This wasn't supposed to happen."

*choice
    #"You've been a very bad man, Baron. You know what's coming next, right?"
        *set charming %+ 15
        *set precharming %+ 15
        "Bodily harm to royalty," Saine says, swiping blood from a cut on his cheek. "The punishment for such a crime is hardly ambiguous."
        
        "I'm not usually given to violent retribution, but you've done yourself no favors here, Baron," Leon says.
    #"This is the end of the line. Give it up."
        *set charming %- 15
        *set precharming %- 15
        "Not that you really have a choice," Saine shrugs. "You've got truth serum running through your veins, after all. We'll get the truth out of you one way or another."
    #"There was no need for all this. His Highnesses may have yet shown you mercy."
        *set noble %+ 15
        *set prenoble %+ 15
        "I have no affinity for violent punishments," Leon agrees. "But I fear your little gambit have put me in a rather foul mood."
    #"You better kill this man, Leon, or I'll do him in myself."
        *set noble %- 15
        *set prenoble %- 15
        "I'm not usually given to such a violent punishment, but you've done yourself no favors here, Baron," Leon says. "We will hear you out, if only not to waste the hard work my retainer's put into ${their} truth serum."       

Saine gazes down on the nobleman, eyes hard. "I sincerely hope we won't have to separate your head from your neck."

"Ha! I would welcome your mercy," the baron croaks through gritted teeth. "But you should know that everything I've done is for the good of Merdel Village."
        
Before you can register the act, Barza leaps forward and plants his foot on the side of the baron's head. The assault slams the nobleman flat against the floor, and there is bloodstain on the
*if (location = "hallway")
    marble
*elseif (location = "woods")
    dark earth
*else
    *comment (location = "sideroom" / "dininghall")
    carpet
when he pulls away. "Say that again, you bastard!" Barza hisses, even as Leon and Saine pull him away. "Say that you murdered us for our own good!"
        
"Peace, Barza," Leon urges through his teeth, his arms locked under the headsman's shoulders. "Let the baron say his piece."

It takes a while for Barza and the baron both to regain their composures, though Leon's hold on Barza is never relaxed. "I didn't want this to happen," the baron says after a while, with no small amount of ire. "I've only ever done my best for Merdel Village."
        
"Our patience is running thin, Baron," Saine growls. "Tell us everything, if you value your life."
        
The baron sniffs at the offer, looking wholly unconvinced of his prospects, but relents with a resigned sigh. "Ask of me what you will."
*temp askcounter 0

*temp inheritance false
*temp faithlords false
*label barontale
*choice
    *disable_reuse #"Why have you committed this act?"
        *set inheritance true
        *set askcounter +1
        "Where do I begin?" the baron asks, sighing. "I suppose it begins with my accursed lineage. I am heir to a house of reprobates. My father and his father before him were staunch believers in the Church's old doctrines—they have no love for the Arcadian people. They are hardly alone in that matter, but as you know, my grandfather was willing to make do more than most with his grudge."
        
        Leon nods his head in understanding. "Your grandfather would be…?"
        
        "The Marquess de Icharea, yes. The orchestrator of the Icharea Massacre," he confirms. "In my father's case, however, his means of purveying punishment to Arcadians were considerably more limited. He had to resort to more covert methods, chief among which was the curse of moonvein."
        
        "We didn't ask for your damn family tree," Barza snaps. "[i]You,[/i] Leyran. Why did you do this?"
        
        You raise an eyebrow at that exchange—not even Sir Joran has ever addressed his liege with his first name, after all. And yet the baron remains unfazed, instead looking the headsman in the eye. "My father would only name me as heir if I committed to his dirty work," he says flatly. "Otherwise, the position would have fallen to my uncle, whose fervor against Arcadia outstrips even my father. And so when my father ordered me to have the nexus fashioned, I did as he asked. And once my name had been written in the will…"
        
        "The former baron passed of a mysterious illness, some time ago," Ilya remarks quietly.
        
        A knife-slit of a smile. "That he did. Jove keep him."
        *goto barontale
    *disable_reuse *if (inheritance) #"So you did it for the sake of your inheritance?"
        *set askcounter +1
        "Yes, I will admit to that much, though even then my motivations aren't entirely selfish. I graduated top of my class from Sienan Academy, and I've been putting it to good use in managing Silcur. You will notice that this region has seen more growth in merchant traffic under my short stewardship compared to all of my father's lifetime."
        
        "I can attest to that," Barza admits grudgingly. "The reparations paid to Merdel have increased substantially since he inherited the estate."
        
        "So you see, I am the most qualified person for my position. My uncle is an incompetent drunkard on top of his prejudice—I do not believe Merdel Village would have survived under his rule."
        *goto barontale
    *disable_reuse *if (inheritance) #"Do you and Barza know each other?"
        *set askcounter +1
        "We are—were—friends, once upon a time," the baron says, and Barza looks away in disgust. "Though I'm sure our headsman is loathe to admit it."
        
        Leon peers down on the baron, perplexed. "How did a baron's son come to be friends with an Arcadian village boy?"
        
        "I had a foolish habit in my youth—I would frequently run away from the manor to go out and see the people with my own eyes," the baron explains. "I frequently visited Merdel Village under the guise of being a merchant's son, and rendered them what help I could in my limited capacity in that time."
        
        "You got us through the drought ten years ago," Barza says under his breath. "I would have never thought you capable of doing something like this."
        
        "I derive no pleasure from the choices I have made, Barza. But I don't see what else I could have done, for your benefit or for mine," the baron says, wistful. "In any case—that habit of mine was a mistake. My father was incensed at my decision to divert his resources to Merdel, as you might imagine. He threatened to have me deposed as his heir, and so I've been forced to spend a decade…proving myself. As it were."
        *goto barontale
    *disable_reuse #"Tell us more about the nexus."
        *set faithlords true
        *set askcounter +1
        "What is there to say? I am no mage, @{pronvar Sir|Madam|Most Honorable}—I can shed no light on it that you wouldn't be able to infer yourself. Perhaps only that I hired an enchanter to halt the curse before I dumped it into Merdel Cave. Of course, that went so swell for me, didn't it?"
        
        The dots connect in your head. "Then this is why the curse was delayed—a botched counter-enchantment."
        
        "I should have known better than to attempt such a gambit, really. What can a common enchanter do against such a powerful artifact?"
        
        "Then tell us how you acquired it," Ilya presses instead. "The Church has no records of a curse like moonvein. Who was it that devised such a brutal enchantment?"
        
        "That will be the Order of the Broken Flame, priestess. Though I daresay that's not a name you've ever heard before."
        *goto barontale
    *disable_reuse *if (faithlords) #"Order of the Broken Flame?"
        *set askcounter +1
        "Zealots of the old doctrine, with a singular focus on eradicating Arcadians," the baron says.
        
        Ilya's features twist into a grimace, and the healer steps back reflexively. "Impossible. The saintess herself has denounced the doctrine and supported Arcadian emancipation."
        
        "Then I imagine the Order brands her a heretic as well," the baron replies bitterly. "Everyone likes to speak of the Arcadians and how much they lost in the war, but our own nation also sustained no shortage of losses. Difficult work, quelling old hatreds, even when ordered of you by Jove's mouthpiece.
        
        "But I've digressed," he continues, sighing. "You wanted to know about the Order, but I'm afraid I know precious little. They operate in total secrecy, and are unafraid in taking extreme measures to ensure their secrets are kept."
        
        "You can't expect us to believe that," Barza hisses.
        
        The baron smirks. "Did the retainer not drug me with ${their} little truth serum? I would have no recourse to lie to you now, Barza, even if I wished to."
        
        Barza's anger is far from allayed. "But you made direct contact with them! Even had them carve your house's insignia onto the nexus, like a fool."
        
        "A little safety net for them to tie my cause to theirs. They don't trust me very much, you see, and made the correct decision of isolating me from most of the group's affairs."
        
        "So that's it, then? You want us to chase after some bogeyman you dreamed up, instead of taking responsibility for your actions?"
        
        "Believe what you will. I have nothing to lose, Barza. Even if the princes decide to spare my life, and bring me to the capital in chains—mark my word, the Order will find ways to silence me once and for all. I'm a dead man either way." The baron falls silent for a while, then, appearing to contemplate his words. "The best I can tell you is this: taking into account the feats they've managed to accomplish and the resources they have at their disposal, it is nearly certain that they count high-ranking nobles amongst their numbers. Were I you, Your Highness, I would take a closer look at the dukes and marquesses of the realm."
        
        "Your…concern has been received, Baron." Leon says, hesitant. "Though I have to admit—were it not for the serum, I'd be hard-pressed to believe a single word that came out of your mouth."
        
        "How lucky for me, then, that you brought your retainer with you."
        *goto barontale
    *if (askcounter = 5) #That will be all, Baron."
        "Very well. Then I suppose this begs the question—what will you do with me?"
        *goto aftergrill
    *if (askcounter < 5) #	(Skip the rest of the explanation. The game will treat you as if you have heard the answers to all the questions.)
        "If that is everything, Your Highness, then I guess this begs the question—what will you do with me?"
        *goto aftergrill


*label spiritismpath
Your party crosses into the baron's courtyard without event, and a knight is dispatched to guide you to the manor's stables. You dismount and tie the mares to the stable's posts, and the knight then escorts you inside the mansion. There is a subtle tenseness to your companions' forms, and you know it is because they are preparing the assault that will isolate the baron from his men. Yours will be the most pivotal role of all, and it is more difficult than you thought it would be to will your fraying nerves to settle. The spirit gate must be quickly cast and stable besides—otherwise, this gambit will be doomed to fail.

"Welcome back to Silcur, Lady de Alviar," Baron de Silcur says as you enter his sitting room. The man's smile is beatific, his arms spread open in a welcoming gesture. "And of course, your paladins and Headsman Barza as well. We are richer for your presence."

"Thank you, Baron," Ilya replies sweetly, her head lowered slightly in keeping with Parami decorum. "It pleases me to see that you're in good health."

"You are too kind. Please, my lady, follow me to the dining hall. My chefs have expended their best effort in putting together a feast worthy—"

He never gets to finish his sentence, interrupted by a rapid, jerking shift in Leon's stance—the signal that your party has agreed upon. All at once, your party leap into action.

*page_break

Leon leads the charge, his blade swinging into wild arcs that catch the unarmed knights by surprise. Barza is hot on his heels, proving himself to be a competent swordsman as he bashes Leon's would-be counterattackers into submission. Saine is quick to seize the momentum to his favor, nimbly weaving past the enemies in a rapid series of blinks, before making a grab for the baron and forcibly yanking him in your direction.

You and Ilya both are ready to receive him. Ilya's Glyph of Magesong burns brightly with the glow of her mana, and you feel the spell's effects rushing like rivers through your veins. It is almost too easy for you to tear the spectral gash in the air, commanding it to grow wider, take you [i]farther[/i]—and though you feel the spell's burden like a boulder upon your shoulders, you demand it keep itself steady and the spell obeys.

Saine barrels through the portal with the baron in tow, and Ilya is quick to follow after him. At your instruction, Barza deals one last blow before staging a rapid retreat, heading directly for the spirit gate while Leon covers his exit. For his part, the prince unleashes a series of thrusting strikes that forces his opponents backwards, before lifting you up bodily and diving for the portal himself.

The ghost of a blade scratches your arm as the knights land a pursuing blow, but soon you cross into the portal and the knights' forms fade into a mist of purple. The spirit gate closes on them with a spectral screech, and you know then that the plan has been a resounding success.

*page_break

When you and Leon come out the other end, it is in the woods just outside of Silcur. Your eyes are immediately drawn towards the baron's figure, leaning against the base of a tree and seething with anger. "What is the meaning of this?" he demands.

*goto spokento


*label enchantmentpath
Your party crosses into the baron's courtyard without event, and a knight is dispatched to guide you to the manor's stables. You dismount and tie the mares to the stable's posts, and the knight then escorts you inside the mansion. There is a subtle tenseness to your companions' forms, and you know it is because they are preparing the assault that will isolate the baron from his men. Your role in it all, though pivotal, requires little more than a flick of the wrist once the doors are closed—it is on Leon, Saine, and Barza's performances upon which the gambit's success hinge.

"Welcome back to Silcur, Lady de Alviar," Baron de Silcur says as you enter his sitting room. The man's smile is beatific, his arms spread open in a welcoming gesture. "And of course, your paladins and Headsman Barza as well. We are richer for your presence."

"Thank you, Baron," Ilya replies sweetly, her head lowered slightly in keeping with Parami decorum. "It pleases me to see that you're in good health."

"You are too kind. Please, my lady, follow me to the dining hall. My chefs have expended their best effort in putting together a feast worthy—"

He never gets to finish his sentence, interrupted by a rapid, jerking shift in Leon's stance—the signal that your party has agreed upon. All at once, your party leap into action.

Leon leads the charge, his blade swinging into wild arcs that catch the unarmed knights by surprise. Barza is hot on his heels, proving himself to be a competent swordsman as he bashes Leon's would-be counterattackers into submission. Saine is quick to seize the momentum to his favor, nimbly weaving past the enemies in a rapid series of blinks, before making a grab for the baron and forcibly yanking him towards an open side room.

You and Ilya are already waiting at its entrance, battle enchantments sailing through the air like arrows—the Glyphs settle on Barza and Leon's forms like coats, and under their influence the pair manage to break through the baron's knights and join you by the entrance. As one the four of you barrel after Saine's retreating form and slam the door shut; you let the Glyph of Sealing manifest into the air and settle over the door. A mere heartbeat later, the lock is affixed—and you know then that you're out of the woods.

The baron coughs into his arm when Saine lets him down, clearly winded from the rogue's rough handling. "What is the meaning of this?" he demands.

*label spokento
*choice
    #"You will speak when spoken to, Baron. Lest we renege on hearing you out."
        *set noble %- 15
        *set prenoble %- 15
        Baron de Silcur looks up at you then, as angry as he is bewildered. "This is unacceptable treatment. Even if it's your people, Lady Ilya, my knights will make sure that King Julius hears of—"
        *goto brotherout
    #"Making demands, are we? Rather bold for a criminal of your ilk."
        *set charming %+ 15
        *set precharming %+ 15
        Baron de Silcur looks up at you then, as angry as he is bewildered. "I do not deserve such censure, [i]paladin[/i]," he spits. "This is unacceptable treatment. Even if it's your people, Lady Ilya, my knights will make sure that King Julius hears of—"
        *goto brotherout
    #"There's a good reason for this, but we're going to need you to calm down."
        *set noble %+ 15
        *set prenoble %+ 15
        Baron de Silcur looks up at you then, cautious and bewildered. "What reason can there be for such treatment?" he scoffs. "This is unacceptable. Even if it's your people, Lady Ilya, my knights will make sure that King Julius hears of—"
        *goto brotherout
    #It's not really my place to speak. I let the nobles handle this.
        *set charming %- 15
        *set precharming %- 15
        "Quiet your fury, my lord," Ilya orders. "It will only serve to further worsen your situation."
        
        "You would presume to tell me what to do! Did your men not just assault me under my own roof, Lady Ilya?" the baron demands, seething with anger. "This is unacceptable. Even if it's your people, Lady Ilya, my knights will make sure that King Julius hears of—"
        *goto brotherout

*label brotherout
"Keep my brother's name out of your mouth," Saine scoffs, spitting the words with distaste.
        
The baron's head whips around so quickly that you fear for his neck. "You—?"
        
"Allow me to introduce Blessed Iver, Second Prince of Param," Ilya says evenly, and then, after gesturing in your and Leon's direction, "His brother, Blessed Leon, First Prince of Param. And finally, the Honorable ${fname}, retainer to the First Prince."
        
"And of course, you know me, don't you?" Barza sneers. "And what you've done to my people."
        
A lengthy, stunned silence from the baron follows the accusation, though the baron eventually manages to gather his composure. "I bid you all welcome to Silcur once more," he murmurs.

"Let's not beat around the bush," the prince says, reaching into his cloak and producing a familiar item. A plaque of gold-enameled iron engraved with a familiar symbol—the lion and the snake, insignia of the barony.
        
It is all that remains of the nexus, after its glass orb had been shattered as a means of breaking the curse. And yet the most damning aspect of it remains whole and plain enough for you all to see, the baron included.
        
You and your group watch on as for the briefest of seconds, the baron's eyes flash with recognition—and then his bewilderment slips back on like a mask, and you know then that the night is about to become much longer.

"How curious, Your Highness," the baron says, having regained control of himself. "What is it that you hold in your hand? And why does it bear the insignia of House de Icharea?"
*goto longweek

*label thaumpath

Your party crosses into the baron's courtyard without event, and a knight is dispatched to guide you to the manor's stables. You dismount and tie the mares to the stable's posts, and the knight then escorts you inside the mansion. You walk silently at the back of the pack, discreetly setting up as many spell circles as you possibly can. There may be hope yet that the baron will acquiesce to a more diplomatic solution; but if the accusations leveled against him make him less agreeable, then you will be prepared.

"Welcome back to Silcur, Lady de Alviar," Baron de Silcur says as you enter his sitting room. The man's smile is beatific, his arms spread open in a welcoming gesture. "And of course, your paladins and Headsman Barza as well. We are richer for your presence."

"Thank you, Baron," Ilya replies sweetly, her head lowered slightly in keeping with Parami decorum. "It pleases me to see that you're in good health."

"You are too kind. Please, my lady, follow me to the dining hall. My chefs have expended their best effort in putting together a feast worthy of your deeds."

"Pah," Barza scoffs behind you. The act draws the attention of Sir Joran, who stands guard beside the baron; the knight-captain turns a sharp eye on Barza, his stance tensing like a drawn bowstring. Baron de Silcur peaceably places a hand on his knight's sword arm, and the man begrudgingly relents.

"What say you, my lady?" the baron continues, unfazed.

"It is a tempting offer, Baron," Ilya says, smiling mirthlessly. "But if we are to dine together, then I think it appropriate that my…[i]paladins[/i] are properly introduced to you."

The baron raises one eyebrow, perplexed. "Oh? I see—"

"First, the master mage who has provided invaluable assistance to me in Merdel Village," Ilya says, gesturing in your direction. ""Allow me to introduce the Honorable ${fname}, Royal Retainer to Blessed Leomar, Prince of Param."

Baron de Silcur's eyes widen at the mention of your illustrious title, though to his credit he takes the information in stride. "I—that is—welcome, @{pronvar my lord|my lady|most honorable}. "I am only sorry I have not been able to show you the proper courtesy you are owed."

*fake_choice
    #It feels nice to be treated with respect. The noble life definitely agrees with me.
    #I struggle to suppress a shudder. I could definitely do without such formality.
    #I don't feel one way or another about it. It's just a title.

Ilya gestures towards Saine next, who has kept mostly a low profile the entire time. "Secondly, this young man is Blessed Iver, Second Prince of Param," she continues. This time the baron makes no effort to mask his shock, his jaw falling open so quickly that you fear it might unhinge from his face. "And lastly, Prince Iver's brother: Blessed Leomar, First Prince of Param."

The baron takes a step back then, eyes wide and incredulous, before remembering himself and moving into a deep bow. All around him, his retinue of knights follow suit. "Your Highnesses. Forgive my impertinence—I have shown you a most discourteous—"

"Rise, Baron," Saine orders flatly, and the baron rushes to obey him. "If we wished for you to act on ceremony, then we'd have told you who we were from the beginning."

The baron's shoulders sink in relief. "I see. You are most gracious, Your Highness," he says. "But if that's the case, then why have you revealed…?"

"There is a very good reason," Leon answers. He steps forward to meet the baron then, his figure tall and imposing, every bit the royal he had revealed himself to be. The baron all but shrinks into himself. "Care to tell me what this is?"

Leon brings an item out of his coat, a plaque of gold-enameled iron engraved with a familiar symbol—the lion and the snake, insignia of the barony. It is all that remains of the nexus, after its glass orb had been shattered as a means of breaking the curse. And yet the most damning aspect of it remains whole and plain enough for you all to see, the baron included.

You and your group watch on as for the briefest of seconds, the baron's eyes flash with recognition—and then his bewilderment slips back on like a mask, and you know then that the night is about to become much longer.

"How curious, Your Highness," the baron says. "What is it that you hold in your hand? And why does it bear the insignia of House de Icharea?"

*label longweek
*choice
    #I'm losing my patience. I outright accuse him of murdering the villagers.
        *set emotional %+ 15
        *set preemotional %+ 15
        "There is no use playing dumb, Baron," you growl, feeling your mana roil and screech underneath your skin. "You placed a curse upon Merdel Village using this artifact."
        *if (location = "woods")
            *goto woodsprepos
        *else
            *goto preposterous
    #The baron should be allowed the chance to explain himself. I keep my silence.
        *set noble %+ 15
        *set prenoble %+ 15
        It appears that Barza does not share your forebearance.
        
        "We have no time for your games," the headsman growls, his voice low and threatening. "You know full well what this is. You used it to murder my people!"
        *if (location = "woods")
            *goto woodsprepos
        *else
            *goto preposterous
    #I have no interest in speaking out of turn. I'll let Leon handle this one.
        *set charming %- 15
        *set precharming %- 15
        It turns out that Barza would beat him to the punch.
        
        "We have no time for your games," the headsman growls, his voice low and threatening. "You know full well what this is. You used it to murder my people!"
        *if (location = "woods")
            *goto woodsprepos
        *else
            *goto preposterous

*label woodsprepos

"Preposterous," the baron replies, barely audible. His shock is a tad too overblown to be genuine, though find it is difficult not to respect his commitment to the act. "I have no ill will towards Merdel Village—what would I have to gain—"

"This plaque is Satyran gold, Baron," Saine says firmly, interrupting the baron's offended spiel. "One of the rarest metals in the known world. Its distribution and ownership is limited to a select few noble houses…"

"…including House de Icharea, before it fell from grace," Ilya finishes. "I hope you don't intend to pin the blame elsewhere, when the nearest house allowed to handle it is my own House de Alviar, leagues away from Silcur."

"I would never suggest such a thing," the baron replies, gritting his teeth. "But the fact remains that I have never seen—and matter fact, I think it likely that—"

"Enough, Baron," Leon orders, his voice booming throughout the room. "You will tell us the truth, before we retract our goodwill."

"It is in your best interest to do so," Saine adds. "Otherwise, we'll be forced to report your dismissal of royal inquiry as an act of treason. I trust you are aware that the you must pay with such an affront with your life."

The baron is silent, for a long while, his gaze fixated on the floor. "So it's come to this," he says under his breath. "Damn it all…this wasn't supposed to happen."
*goto badmanbaron

*label preposterous

"Preposterous," the baron replies, barely audible. His shock is a tad too overblown to be genuine, though find it is difficult not to respect his commitment to the act. "I have no ill will towards Merdel Village—what would I have to gain—"

"This plaque is Satyran gold, Baron," Saine says firmly, interrupting the baron's offended spiel. "One of the rarest metals in the known world. Its distribution and ownership is limited to a select few noble houses…"

"…including House de Icharea, before it fell from grace," Ilya finishes. "I hope you don't intend to pin the blame elsewhere, when the nearest house allowed to handle it is my own House de Alviar, leagues away from Silcur."

"I would never suggest such a thing," the baron replies, gritting his teeth. "But the fact remains that I have never seen—and matter fact, I think it likely that—"

"Enough, Baron," Leon orders, his voice booming throughout the room. "You will tell us the truth, before we retract our goodwill."

"It is in your best interest to do so," Saine adds. "Otherwise, we'll be forced to report your dismissal of royal inquiry as an act of treason. I trust you are aware that the you must pay with such an affront with your life."

The baron is silent, for a long while, his gaze fixated on the floor. "So it's come to this," he says under his breath. "Then you leave me with no other choice. Knights of de Silcur, seize them!"

Sir Joran turns to regard his lord, incredulous. "But Your Lordship, we cannot raise our blades against—"

"I will handle the matter. Just do as I say—and capture them alive," the baron hisses. "Go, man, go!"

*page_break
*set moranaswail true
The knights fall upon your party like a mighty storm, their blades unsheathed in fluid motion and their forms charging at you with reckless abandon. Leon meets the vanguard with his sword, parrying the strike with expert ease and kneeing the knight's gut in the chink of his armor. The prince tramples his head in a bid to knock him out, and rapidly twists into a slash that catches another knight under his breastplate. Immediately the entire retinue's attention is on him, the whirling storm of swordplay headed straight for their lord, and it leaves your party with plenty of room with which to mount a counterassault.

For his part, Saine blinks directly towards the baron and attempts to take him hostage, and when his assault is repelled by Sir Joran he instead engages the knight-captain in direct combat. Beside you, Barza has leapt into a combat stance of his own, his sword pulled from its hidden sheathe beneath the headsman's cloak. He positions himself close to you and Ilya and engages the knights that manage to slip past Leon, his wide-arced slashes concerned more with pushing them back than decisively defeating them.

All for your benefit, of course, and you have no plans to disappoint him. You feel your long-stored mana crest in waves towards your fingertips and manifest into a frigid blast of air, amidst which Morana's Wail leaps out like a charging wolf. The spell weaves past your allies and rams instead against the knights, spoiling their balance and slamming them headfirst against the manor's walls. Your relentless flurry of attacks is redoubled as you feel Ilya's mana begins to seep into your bones, and though a blade or two would strike you mid-cast despite Barza's best efforts, you feel the wound healing before the pain could truly set in.

In the end, the knights find themselves sorely outmatched by the combined might of your assault. Only the baron remains conscious at the end of it all, and he looks up at your party with contempt from where he's perched on the floor.

"Damn it all," he curses under his breath, nursing a wound in his abdomen where an ice shard had grazed him. "This wasn't supposed to happen."

*label badmanbaron
*choice
    #"You've been a very bad man, Baron. You know what's coming next, right?"
        *set charming %+ 15
        *set precharming %+ 15
        "Bodily harm to royalty," Saine says, swiping blood from a cut on his cheek. "The punishment for such a crime is hardly ambiguous."
        
        "I'm not usually given to such a violent punishment, but you've done yourself no favors here, Baron," Leon says.
    #"This is the end of the line. Give it up."
        *set charming %- 15
        *set precharming %- 15
        "Do as ${they} @{plural say|says}, Baron, or else you may find that our mercy is quick to run out," Leon says.
    #"Tell us the truth now, and your life may yet be spared."
        *set noble %+ 15
        *set prenoble %+ 15
        "I have no affinity for violent punishments, but that may just change if you continue this act, Baron," Leon says.
    #"You better kill this man, Leon, or I'll do him in myself."
        *set noble %- 15
        *set prenoble %- 15
        "I'm not usually given to such a violent punishment, but you've done yourself no favors here, Baron," Leon says.
"I'll not say it again. Tell us the truth, before I let my retainer separate your head from your neck."
        
"Ha! I would welcome your mercy," the baron croaks through gritted teeth. "But you should know that everything I've done is for the good of Merdel Village."
        
Before you can register the act, Barza leaps forward and plants his foot on the side of the baron's head. The assault slams the baron's head flat against the floor, and there is bloodstain on the
*if (location = "hallway")
    marble
*elseif (location = "woods")
    dark earth
*else
    *comment (location = "sideroom")
    carpet
when he pulls away. "Say that again, you bastard!" Barza hisses, even as Leon and Saine pull him away. "Say that you murdered us for our own good!"
        
"Peace, Barza," Leon urges through his teeth, his arms locked under the headsman's shoulders. "Let the baron say his piece."
        
It takes a while for Barza and the baron both to regain their composures, though Leon's hold on Barza is never relaxed. "I didn't want this to happen," the baron says after a while, with no small amount of ire. "I've only ever done my best for Merdel Village."
        
"Our patience is running thin, Baron," Saine growls. "Tell us everything, if you value your life."
        
The baron sniffs at the offer, looking wholly unconvinced of his prospects, but relents with a resigned sigh. "Ask of me what you will."
*temp askcounter 0

*temp inheritance false
*temp faithlords false
*label barontale2
*choice
    *disable_reuse #"Why have you committed this act?"
        *set inheritance true
        *set askcounter +1
        "Where do I begin?" the baron asks, sighing. "I suppose it begins with my accursed lineage. I am heir to a house of reprobates. My father and his father before him were staunch believers in the Church's old doctrines—they have no love for the Arcadian people. They are hardly alone in that matter, but as you know, my grandfather was willing to do more than most with his grudge."
        
        Leon nods his head in understanding. "Your grandfather would be…?"
        
        "The Marquess de Icharea, yes. The orchestrator of the Icharea Massacre," he confirms. "In my father's case, however, his means of purveying punishment to Arcadians were considerably more limited. He had to resort to more covert methods, chief among which was the curse of moonvein."
        
        "We didn't ask for your damn family tree," Barza snaps. "[i]You,[/i] Leyran. Why did you do this?"
        
        You raise an eyebrow at that exchange—not even Sir Joran has ever addressed his liege with his first name, after all. And yet the baron remains unfazed, instead looking the headsman in the eye. "My father would only name me as heir if I committed to his dirty work," he says flatly. "Otherwise, the position would have fallen to my uncle, whose fervor against Arcadia outstrips even my father. And so when my father ordered me to have the nexus fashioned, I did as he asked. And once my name had been written in the will…"
        
        "The former baron passed of a mysterious illness, some time ago," Ilya remarks quietly.
        
        A knife-slit of a smile. "That he did. Jove keep him."
        *goto barontale2
    *disable_reuse *if (inheritance) #"So you did it for the sake of your inheritance?"
        *set askcounter +1
        "Yes, I will admit to that much, though even then my motivations aren't entirely selfish. I graduated top of my class from Sienan Academy, and I've been putting it to good use in managing Silcur. You will notice that this region has seen more growth in merchant traffic under my short stewardship compared to all of my father's lifetime."
        
        "He's telling the truth," Barza admits grudgingly. "The reparations paid to Merdel have increased substantially since he inherited the estate."
        
        "So you see, I am the most qualified person for my position. My uncle is an incompetent drunkard on top of his prejudice—I do not believe Merdel Village would have survived under his rule."
        *goto barontale2
    *disable_reuse *if (inheritance) #"Do you and Barza know each other?"
        *set askcounter +1
        "We are—were—friends, once upon a time," the baron says, and Barza looks away in disgust. "Though I'm sure our headsman is loathe to admit it."
        
        Leon peers down on the baron, perplexed. "How did a baron's son come to be friends with an Arcadian village boy?"
        
        "I had a foolish habit in my youth—I would frequently run away from the manor to go out and see the people with my own eyes," the baron explains. "I frequently visited Merdel Village under the guise of being a merchant's son, and rendered them what help I could in my limited capacity in that time."
        
        "You got us through the drought ten years ago," Barza says under his breath. "I would have never thought you capable of doing something like this."
        
        "I derive no pleasure from the choices I have made, Barza. But I don't see what else I could have done, for your benefit or for mine," the baron says, wistful. "In any case—that habit of mine was a mistake. My father was incensed at my decision to divert his resources to Merdel, as you might imagine. He threatened to have me deposed as his heir, and so I've been forced to spend a decade…proving myself. As it were."
        *goto barontale2
    *disable_reuse #"Tell us more about the nexus."
        *set faithlords true
        *set askcounter +1
        "What is there to say? I am no mage, @{pronvar Sir|Madam|Most Honorable}—I can shed no light on it that you wouldn't be able to infer yourself. Perhaps only that I hired an enchanter to halt the curse before I dumped it into Merdel Cave. Of course, that went so swell for me, didn't it?"
        
        The dots connect in your head. "Then this is why the curse was delayed—a botched counter-enchantment."
        
        "I should have known better than to attempt such a gambit, really. What can a common enchanter do against such a powerful artifact?"
        
        "Then tell us how you acquired it," Ilya presses instead. "The Church has no records of a curse like moonvein. Who was it that devised such a brutal enchantment?"
        
        "That will be the Order of the Broken Flame, priestess. Though I daresay that's not a name you've ever heard before."
        *goto barontale2
    *disable_reuse *if (faithlords) #"Order of the Broken Flame?"
        *set askcounter +1
        *achieve brokenflame
        "Zealots of the old doctrine, with a singular focus on eradicating Arcadians," the baron says.
        
        Ilya's features twist into a grimace, and the healer steps back reflexively. "Impossible. The saintess herself has denounced the doctrine and supported Arcadian emancipation."
        
        "Then I imagine the Order brands her a heretic as well," the baron replies bitterly. "Everyone likes to speak of the Arcadians and how much they lost in the war, but our own nation also sustained no shortage of losses. Difficult work, quelling old hatreds, even when ordered of you by Jove's mouthpiece.
        
        "But I've digressed," he continues, sighing. "You wanted to know about the Order, but I'm afraid I know precious little. They operate in total secrecy, and are unafraid in taking extreme measures to ensure their secrets are kept."
        
        "You can't expect us to believe that," Barza hisses. "You've already made direct contact with them! Even had them carve your house's insignia onto the nexus, like a fool."
        
        The baron smirks. "A little safety net for them to tie my cause to theirs. They don't trust me very much, you see, and made the correct decision of isolating me from most of the group's affairs."
        
        "So that's it, then? You want us to chase after some bogeyman you dreamed up, instead of taking responsibility for your actions?"
        
        "Believe what you will. I have nothing to lose, Barza. Even if the princes decide to spare my life, and bring me to the capital in chains—mark my word, the Order will find ways to silence me once and for all. I'm a dead man either way." The baron falls silent for a while, then, appearing to contemplate his words. "The best I can tell you is this: taking into account the feats they've managed to accomplish and the resources they have at their disposal, it is nearly certain that they count high-ranking nobles amongst their numbers. Were I you, Your Highness, I would take a closer look at the dukes and marquesses of the realm."
        
        "Your…concern has been received, Baron." Leon says, hesitant. "For your sake as well as mine, I hope you are telling the truth."
    *if (askcounter = 5) #That will be all, Baron."
        "Very well. Then I suppose this begs the question—what will you do with me?"
        *goto aftergrill
    *if (askcounter < 5) #	(Skip the rest of the explanation. The game will treat you as if you have heard the answers to all the questions.)
        "If that is everything, Your Highness, then I guess this begs the question—what will you do with me?"
        *goto aftergrill

*label aftergrill
*achieve yesbaron
Leon turns his gaze on Barza, whose grimace looks far more conflicted than it had been, before the baron's explanation. "You're the affected party here, Barza. If you decide that the baron's life should be spared, then that's will do. Otherwise…"

"Damn you, Leyran," Barza growls. "Always up on your high horse, thinking you know better than anyone else."

The headsman casts his gaze aside, then, unwilling to so much as behold his former friend—your eyes meet his as his gaze wanders, and for a brief moment he looks as if he is seeking your advice.

*choice
    #I advocate for him to kill the baron. A massacre by any other name...
        *set noble %- 15
        *set prenoble %- 15
        *set rleon %- 10
        *set rilya %+ 15
        *set baronalive false
        …is just as cruel. And he must pay the consequences of his horrendous acts in full.
        
        "The baron can dream up as many justifications as he wants," you say evenly. "The fact remains that he sent these villagers to their deaths. Blood must be repaid in blood."
        
        Leon turns to look at you, distressed. "${fname}…"
        
        "I find myself in agreement," Ilya declares, her arms crossed in front of her chest. "The baron tells a convincing tale, but in the end his hands are steeped in blood. Who can say whether this is where the carnage stops, if we leave him be?"
        
        "You don't need to do it, if you don't want to. I can do the deed for you." Saine had made the offer to Barza almost impassively, and it strikes you then that for all that the boy is young and affable, he is a trained assassin all the same.
        
        "No," Barza says, barely audible at first, and then he repeats it more resolutely. "No. I'll do it myself."
        
        "I must say, it's quite eerie to hear my execution be advocated for so fervently—right in front of me, no less," the baron sniffs. His expression is carefully engineered to appear unaffected, but there is the ghost of a tremor in his voice that betrays his facade. "Well then, Barza. I trust you'll make it quick? For old times' sake."
        
        Barza lifts his sword wordlessly and points it at the lord's neck. A moment's pause, a flicker of hesitation, and then the headsman steels himself and brings plunges his blade into his old friend's heart. He utters nothing more than a single, lonely word as he brings his blade down, his voice small and trembling like a wounded deer, choked up as if it had been submerged in water.
        
        "Farewell," he had said.
        
        You wonder if the baron had heard him, in the end.
        *page_break
        *goto deadbaron
    #I suggest that he spare the baron. In some ways, he's also a victim here.
        *set noble %+ 15
        *set prenoble %+ 15
        *set rilya %- 10
        *set rleon %+ 15
        *set baronalive true
        "I think the baron is deserving of your mercy, if you are willing to give it," you say evenly. "He made do with the situation he had. I don't think he should die for it."
        
        Ilya sighs beside you, longsuffering.
        *if (noble > 50)
            "Always so soft-hearted, ${fname}," she scolds.
        *else
            "Odd that you'd pick now of all times to be so soft-hearted," she groans.
        "The baron spins a convincing tale, but in the end his hands are steeped in blood. Who can say whether this is where the slaughter stops, if we leave him be?"
        
        "We won't be leaving him be," Leon counters. "If Barza decides to spare him, then we'll take him to the royal dungeon in Sienan. He'll be made to pay for his crimes there."
        
        "Swell," the baron scoffs. "How merciful of you, Your Highness."
        
        "Of course, the length of time that he will be kept there is also Barza's call to make." The prince turns towards Barza, then, and regards him with a hopeful expression. You're sure it was done unconsciously, but Barza seems to be affected all the same by the weight of Leon's expectations. "What say you?"
        
        The black-haired man remains silent, for a while, but eventually relents. "Very well, Your Highness. This seems to be a reasonable course of action."
        
        "Thank you, Barza," the prince beams, as if it is his life that the headsman had spared. "You can rest assured that the baron will receive no special treatment under our watch. He will face justice—on my honor, I swear it."
        
        Barza looks the prince squarely in the eyes at that, appearing to search his features for any signs of deception. But Leon is nothing if not earnest and charismatic, and the black-haired man soon finds that his fears have been allayed. "I...will hold you to that, Your Highness."
        *page_break
        *goto livebaron
    #I refuse to say anything. The baron's fate is no concern of mine.
        *set emotional %- 15
        *set preemotional %- 15
        *set baronalive true
        Leon is all too happy to make his recommendations in your stead.
        *label baronhorrible
        "What the baron did was horrible, Barza, but I think he deserves what mercy you can spare," he advises. "He called us here himself despite the risks it poses to his secret…"
        
        "He did so to assuage his own guilt," Ilya cuts in. "Don't mistake him satisfying his conscience for generosity. And in the end, his hands are still steeped in the blood of innocents. Who can say whether this is where the slaughter stops, if we leave him be?"
        
        "We won't be leaving him be," Leon counters. "If Barza decides to spare him, then we'll take him to the royal dungeon in Sienan. He'll be made to pay for his crimes there."
        
        "Swell," the baron scoffs. "How merciful of you, Your Highness."
        
        "Of course, the length of time that he will be kept there is also Barza's call to make." The prince turns towards Barza, then, and regards him with a hopeful expression. You're sure it was done unconsciously, but Barza seems to be affected all the same by the weight of Leon's expectations. "What say you?"
        
        The black-haired man remains silent, for a while, but eventually relents. "Very well, Your Highness. This seems to be a reasonable course of action."
        
        "Thank you, Barza," the prince beams, as if it is his life that the headsman had spared. "You can rest assured that the baron will receive no special treatment under our watch. He will face justice—on my honor, I swear it."
        
        Barza looks the prince squarely in the eyes at that, appearing to search his features for any signs of deception. But Leon is nothing if not earnest and charismatic, and the black-haired man soon finds that his fears have been allayed. "I...will hold you to that, Your Highness."
        *page_break
        *goto livebaron
    #I refuse to say anything. This should be Barza's call to make.
        *set noble %+ 15
        *set prenoble %+ 15
        *set baronalive true
        Leon does not appear to share your reservations, and is all too happy to make his recommendations in your stead.
        *goto baronhorrible

*label deadbaron
*if (location = "woods")
    Your party absconds into the night before the baron's men could mount a proper pursuit, having left the baron's body in an open clearing for his men to find. Leon promises to enlist the help of a nearby count to repel the knights from Merdel, should they attempt to seek vengeance for their deceased lord. And so although you part ways from Barza with some worry for that eventuality, Leon's assurances that the reinforcements will make it back in time are convincing enough to put your mind at ease.

    Skirting around the edge of town, your party acquires a pair of horses from a group of passing adventurers. They happily accept Leon's generous payment and surrenders their steeds, and before long the four of you find yourselves heading back into the Parami trade artery.
    *goto lastglance
*else
    Your party absconds into the night before the baron's men could regain their consciousness and mount a pursuit. Leon promises to enlist the help of a nearby count to repel the knights from Merdel, should they attempt to seek vengeance for their deceased lord. And so although you part ways from Barza with some worry for that eventuality, Leon's assurances that the reinforcements will make it back in time are convincing enough to put your mind at ease.
    
    You find Steyer and Scout where you had left them, blissfully ignorant as they help themselves to the baron's stock of horse feed. And yet they are intelligent, sensitive creatures, and when they perceive the tension and urgency with which your group carry yourselves, they are at once alert and ready to race back to Sienan.
    *goto lastglance

*label livebaron
*if (location = "woods")
    Your party returns with the baron in tow to his manor, and the knights besiege you with their weapons brandished not a second after your arrival. The baron orders for his men to stand down and clear your path back to the stables, and though they are visibly perplexed at the unexpected command, they obey it all the same.

    Steyer and Scout are right where you had left them, blissfully ignorant of the chaos that had transpired within the manor. The baron is allowed to ride on his own steed—after Saine has made a number of illustrative threats of what will happen to him should he attempt an escape—and obediently follows along as you make your way back to Sienan.
    *goto lastglance
*else
    Your party absconds into the night before the baron's men could regain their consciousness and complicate matters. Leon promises to enlist the help of a nearby count to repel the knights from Merdel, should they attempt to pin the blame of their lord's disappearance on Merdel Village. And so although you part ways from Barza with some worry for that eventuality, Leon's assurances that the reinforcements will make it back in time are convincing enough to put your mind at ease.
    
    Steyer and Scout are right where you had left them, blissfully ignorant of the chaos that had transpired within the manor. The baron is allowed to ride on his own steed—after Saine has made a number of illustrative threats of what will happen to him should he attempt an escape—and obediently follows along as you make your way back to Sienan.
    *goto lastglance

*label lastglance

You cast one last glance in Merdel village's direction as you depart the town, the straw of its thatched roofs nearly swallowed up by the distant horizon. You reflect back on the week that you had spent there—on the lives both lost and saved, families ravaged by a callous curse, a sacred grave unspeakably desecrated. A murderous noble
*if (baronalive = false)
    now put to the sword himself.
*else
    who will get to keep his head, despite the gravity of his acts.
    
(By all accounts, Arcadians have long since been liberated from the chains of oppression. What does it say of Param, that they must still suffer through such carnage?)

Saine calls out your name in the distance, startling you out of your reverie. He gives you a wan smile, almost apologetic—as if privy to the thoughts running through your mind. He jerks his head in the road's direction, and shouts the words you thought you had been longing to hear.

[i]Let's go[/i], he says. [i]Home.[/i]

The words leave a hollow ring in your ears.
*goto endchapter3

*label bombroute
*page_break
*achieve nobaron
Mercifully, Barza does not get to keep his word.

Permission to travel in and out of Merdel remains limited to the White Fangs, and so it is Saine who fetches the horse and rides to Silcur, in hopes of acquiring the bombs they use down in the Yied Mines. In the meantime, you and Ilya return to the sickbay to resume your treatment of the remaining patients. Barza escorts you to the house's front door, and takes Leon with him as he leaves. After all, he has the unenviable task of informing the village that their sacred ground are to be blown to pieces. You can only hope the armed warrior standing by his side as he delivers the news will serve as adequate insurance.

The sun hangs low in the sky when Saine completes his return trip, an array of explosives strapped onto the hind of his horse. He walks in just in time to see a dead body being carted out of the sickbay, the hearse she is brought out on still stained white by the blood of her forebears. The young prince calls out for his brother in an urgent cadence, clearly still unsettled by the sight, and the pair make for Merdel Cave before Barza could offer to accompany them.

(You are still taken aback when you hear the blast resound in the distance, even knowing that it would come. Its echo reverberates through the room and lingers in your memory, a spirit aghast at the blasphemy you had spoken into being).

The effects, at least, are immediately noticeable. The number of new cases would drop to zero on the following day, and what patients still remained would make miraculous leaps in recovery over the following week. Despite your medicinal ingredients having wholly run out before the end of the third day, the casualty rate would remain mercifully low until the sickbay's population could be counted on one hand.

Between full days spent working the sickbay floor and nights of fitful sleep, you never could have a proper conversation with Merdel's villagers. It is instead Leon and Saine who would tell you the tales of a village restored, of fathers and daughters and friends nursing hope in their eyes the way they hadn't in weeks.

*choice
    #Seeing our efforts bear fruit makes it easier to come to terms with everything.
        It would be impossible to call what had happened in Merdel Village anything short of a tragedy, but there is merit in hearing that it has not broken the villagers. Recovery will no doubt be a long, arduous effort—but that the people have a shot at it, at least, provides you no small amount of comfort.
        
        Still, the fact remains that the cave's destruction has erased any and all evidence that may lead you to the curse's originator. Barza has sworn revenge regardless, insisting that he will tear through the cave's rubble and claw the artifact's pieces out himself—sounding so resolute that you dare not contradict him.
    #The dead still piles owing to our incompetence. We ought not celebrate atop their corpses.
        You hear the tales they do not tell you, as plainly as if they had been spoken. Of grieving widows, and orphans too young to have lost it all—Merdel Village has been devastated by this senseless curse, and their path to recovery will be long and painful.
        
        And your own limitations have played no small part in bringing about such tragedy.
        
        Moreover, the fact remains that the cave's destruction has already erased any and all evidence that may lead you to the curse's originator. Barza has sworn revenge regardless, insisting that he will tear through the cave's rubble and claw the artifact's pieces out himself—sounding so resolute that you dare not contradict him.
    #I'm just glad it's over—for the villagers' sake, as well as for mine.
        The work that you do in the curse's aftermath feels almost like respite, after the torture of that first day. To not have the lives of others be dependent on every little choice you make feels like a greater blessing than you can put to words.

        Still, the fact remains that the cave's destruction has erased any and all evidence that may lead you to the curse's originator. Barza has sworn revenge regardless, insisting that he will tear through the cave's rubble and claw the artifact's pieces out himself—sounding so resolute that you dare not contradict him.

It is just over a week until the last of the patients is discharged, and the last body returned to the earth.

You bid your farewells to the villagers, all of whom show you no shortage of gratitude for your services. Ilya seizes the opportunity to play diplomat, speaking at length about the lofty ideals of the Jovian Church, and how her acts had simply been an extension thereof. When you are both out of the villagers' earshot, she privately confesses to you that the act leaves a bitter taste in her mouth—and yet it is a necessary one, if one hopes to mend relations between the Parami and Arcadians.

You stop by Silcur on the way back to Sienan, and bring the baron up to speed on what had transpired back in Merdel. His relief at the crisis's aversion is palpable, and he immediately offers a generous sum of gold as a reward—an extraordinary gesture, given his house's subpar financial means.

*choice
    #I'll always be an adventurer at heart. Refusing a reward would wound my soul.
        *set noble %- 15
        *set prenoble %- 15
        You agree to the offer readily, earning a couple of raised eyebrows from your traveling companions. The royals and Ilya politely decline their share—the latter with a subtle reminder that she is in fact the daughter of a [i]marquess[/i]. The baron apologizes profusely for the affront, but Ilya only laughs and brushes it off. The matter is forgotten before long.
    #I suggesting that the funds be used to assist in Merdel's recovery instead.
        *set noble %+ 15
        *set prenoble %+ 15
        The baron looks stricken when he hears the proposal, and confesses that he's ashamed to not have thought to do so himself. Ilya diverts the topic and instead speaks to him of safety measures against malignant enchantments, just in case the 'plague' returns once more. He listens intently and vows to implement the methods she suggested, and the matter is closed before long.

*label paramitrade
As you make your way into the Parami trade route, you cast one last glance in Merdel village's direction, the straw of its thatched roofs nearly swallowed up by the distant horizon. You reflect back on the week that you had spent there—on the lives both lost and saved, families ravaged by a callous curse, a sacred grave reduced to rubble.

(By all accounts, Arcadians have long since been liberated from the chains of oppression. What does it say of Param, that they must still suffer through such carnage?)

Saine calls out your name in the distance, startling you out of your reverie. He gives you a wan smile, almost apologetic—as if privy to the thoughts running through your mind. He jerks his head in the road's direction, and shouts the words you thought you had been longing to hear.

[i]Let's go[/i], he says. [i]Home.[/i]

The words leave a hollow ring in your ears.

*label endchapter3
*page_break

The road to Sienan fades in the distance, and you find yourself surfacing in the void once more.

You are no stranger to tragedy, but the plague of Merdel Village remains one of the most harrowing experiences you've ever had. The memory of it rings low and baleful in your soul, and you carry it like a burden into the next chapters of your life.

More fragments appear in your field of vision, and one in particular gleams like a star in the dark expanse. As you peer into its depths, you catch sight of...

*set silcur 1
*choice
  *selectable_if (silcur = 0) #...a rundown countryside inn, dimly lit in the rainy night.
      placeholder
  *selectable_if (silcur = 0) #...a vibrant forest at high noon, with cheery birdsong filling the atmosphere.
      placeholder
  *selectable_if (silcur = 0) #...a holy sword raised high, blinding as it sings through the air.
      placeholder
  *selectable_if (silcur = 1) #...a throne room gilded with the finest gold, painted in colors by the glass-stained light.
      The memory pulses and expands, growing ever brighter, and you are soon swallowed by its blinding light.
      *goto banquetchap
  *selectable_if (silcur = 0) #...the alarmed visage of your comrade, murmuring in the dark.
      placeholder
  *selectable_if (silcur = 0) #...a grand ballroom bursting with people, overjoyed in the face of tragedy overcome.
      placeholder

*label banquetchap
*comment Chapter 4 - Weeping Twilight
*image header_c4.png center Chapter Four, Weeping Twilight. We are ever at the mercy of fate's scarlet hand.
*page_break
"So that's how it is."

King Julius sighs as he leans back on his golden throne, fingers raised to massage his temples. "This is most unsettling news. For such a thing to be done to the Arcadians, right on the cusp of the banquet…"

*if (silcurtruth)
    "It is fortunate that the mystery was solved, but it's only a piece of the bigger puzzle," Leon says judiciously, though you know his calm is little more than a facade. "There are larger forces than a single corrupt nobleman at work here, Your Majesty, and it is to Param's best interests to see them properly investigated."
    
    The king nods sagely at his brother's words. "Be at ease, Leomar. I will sanction an investigation into the matter. You will relay all pertinent information you have on the issue to Ante, and her unit will take it from there. Ignis?"
*else
    "And the perpetrator is still at large, too," Leon grouses, his own scowl a mimic of his brother's. "We had to act quickly given the lives that were hanging on the line. We had to destroy the cave and the artifact both, or risk more people dying to the curse."

    The king nods sagely at his brother's words. "I believe that you made the right call. I will still sanction an investigation into the matter—it would not be the first time that Ante's unit finds a lead, even without material evidence to go on with. Ignis?"

The knight-captain stands at attention, a hand crossed over his chest in salute. "Yes, Your Majesty."

"See to it that the best possible investigation unit is organized. We have done Silcur wrong by sending Lady Ilya with such limited resources. I would like no expense to be spared, this time around."

"As you command."

"As for all of you," the king says, his gaze wandering between you and your party. "I would have liked to give you more of an opportunity to rest, given that you had only just arrived yesterday. But the banquet is an event of great importance, and so I must request that you prepare for it immediately."

"Understood, Brother," Saine says evenly, though you don't miss the edge in his tone. "We shall do as you ask."

"Good. Retainer, there are other matters that I wish to discuss with Lady Ilya and the princes. For now, you are dismissed."

You dip your head low in respect. "By your leave, Your Majesty."
*comment ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~  BACK TO THE BANQUET ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
*page_break
After exiting the throne room, you are immediately accosted by a gaggle of palace servants that whisks you away to a needlessly opulent bathroom. They scrub mercilessly at the dirt and grime of the road—some of which still remained, despite this being the third time the maids have hacked away at them—and by the end of it all you're positive you've grown welts in places they shouldn't be.

The maids dump you in front of a boudoir and present you with a veritable parade of fineries. In a manner at once subservient and domineering, they ask you to choose from the lineup of impeccably tailored clothing. In the end, the outfit you settle for is…

*temp clothoptions ""
*if (gender = "male")
    *set clothoptions "masculine"
    *goto clothselect
*elseif (gender = "female")
    *set clothoptions "feminine"
    *goto clothselect
*else
    *set clothoptions "nonbinary"
    *goto clothselect
*label clothselect
*choice
    #A close-fitted robe with oversized lapels and wide, flaring coattails. A favorite of noble mages, if I wish to look the part.
        *goto afterdress
    *if ((clothoptions = "masculine") or (clothoptions = "nonbinary")) #A simple white dress shirt with a black jacket over it and matching pants. Classic, though detractors will call it boring.
        *goto afterdress
    *if ((clothoptions = "masculine") or (clothoptions = "nonbinary")) #A scarlet silken tunic with elaborate gold embroideries woven throughout, paired with simple black trousers. The garment's influences are distinctly Imperial.
        *goto afterdress
    *if ((clothoptions = "masculine") or (clothoptions = "nonbinary")) #A fine, loose-fitting garment made of silk and velvet, with a hemline that reaches the ground. A Parami twist on classic Yotai fashion.
        *goto afterdress
    *if (clothoptions = "masculine") #I would like to pick from a selection of feminine clothing.
        *set clothoptions "feminine"
        *label servantconfuse
        The servant's eyebrows raise almost imperceptibly at your request, but she quickly rushes to obey it. After some time, she reenters the room and presents a new selection of clothes before you.
        
        The outfit you finally settle on is…
        *goto clothselect
    *if ((clothoptions= "feminine") or (clothoptions = "nonbinary")) #A simple pastel dress with an empire waist and matching gloves. The Parami noblewoman's old faithful.
        *goto afterdress
    *if ((clothoptions= "feminine") or (clothoptions = "nonbinary")) #An elaborate gold ballroom gown, with a snug bodice and a sizable tulle train. A little on the excessive side, but there's no better place for it than a royal banquet.
        *goto afterdress
    *if ((clothoptions= "feminine") or (clothoptions = "nonbinary")) #A long, close-fitted dress made of dark sequined fabric imported from Yotai. The little rhinestones interspersed throughout shine like stars against a midnight sky as they catch the light.
        *goto afterdress
    *if (clothoptions = "feminine") #I would like to pick from a selection of masculine clothing.
        *set clothoptions "masculine"
        *goto servantconfuse
    
*label afterdress
The servant obediently notes your selection and takes the garment off the mannequin. They dress you at a dizzying speed, and soon you find yourself standing before the banquet hall.

You walk through the hall's grand entrance.
*page_break

"The Honorable ${fname}, Royal Retainer to Prince Leomar Nantael de Param," the herald announces, and the party all but trip over themselves to glower at you in a decidedly ignoble manner.

Leon had warned you of this reaction: heirs of esteemed noble houses had been vying for your position their entire adult life. That a common mage of unknown origin has swooped in and stolen the title for ${themselves} is no small bruise to their sizable pride.

How do you feel about this reception?
*choice
    #If they want the position for themselves, they are welcome to challenge me for it.
        *set charming %- 15
        *set precharming %- 15
        They'll find that even a common mutt has some bite to it yet.
        *goto aaa
    #I can sympathize with their agony somewhat. The title [i]does[/i] make me look rather dashing.
        *set charming %+ 15
        *set precharming %+ 15
        Nothing wrong with a little preening. You worked hard for it, after all.
        *goto aaa
    #I bask in their fury. All breeding, no substance—they pose no threat to me.
        *set noble %- 15
        *set prenoble %- 15
        The king said it himself—you are the most qualified retainer Param has seen in a long time. They can't touch you even in their wildest dreams.
        *goto aaa
    #I pity them. The burden of their station must be very great indeed.
        You shudder to think about the weight of those lofty expectations, and are grateful that they are not saddled on you.
        *set noble %+ 15
        *set prenoble %+ 15
        *goto aaa
    
*label aaa

You make your way towards the eastern end of the ballroom, where a lavish spread of Parami delicacies have been laid out on a long silver table. Just as you are about to help yourself, the herald bellows once more:

"Shiraya Cheilong, Saintess of the Jovian Church."
*page_break
If the room had greeted your arrival with a conspiratorial murmur, the saintess instead plunges it into a riotous uproar. You gather from the hushed whispers of the nobles around you that the saintess has not made a public appearance in nearly two years. A beeline of would-be ingratiators immediately gathers after her, but they are warded by the stone-faced paladins serving as her escort. The saintess proceeds uninterrupted towards the king's pedestal.

She dips into a low curtsy as she greets the king, who regards her beatifically from his perch on the raised platform. "Shiraya Cheilong greets the Blessed Julius, upon whom Jove smiles," she offers serenely, her black locks falling in a flawless cascade around her lowered head. Despite her modest attire—a plain blue sheath dress under ivory white robes—she still commands a grace befitting one of her lofty station.

The king accepts her greeting and directs her to rise. "We bid you welcome to Sienan Keep, Saintess. Yours is always a welcome presence within these halls."

The woman chuckles into her sleeve, the sound clear as a bell. "I am only sorry I cannot visit more. The demands of the faith are many."

King Julius nods in empathic understanding—few understand the burden of power as well as he. "I am sure they are."

"But this is a hallowed occasion, Your Majesty," she states, gesturing about the room. "The Church rejoices at the signing of the Accords, and extends its warmest compliments to your tireless efforts."

"We are thankful for your consideration, Saintess. Please, enjoy the festivities."

The saintess curtsies once more at those words, and disappears into the crowd.

*temp titlegreet ""
*if (gender = "male")
    *set titlegreet "my lord"
    *goto whirlon
*elseif (gender = "female")
    *set titlegreet "my lady"
    *goto whirlon
*else
    *set titlegreet "Retainer"
    *goto whirlon
*label whirlon

"A moment of your time, ${titlegreet}."
*page_break

You whirl on the voice to behold one of the saintess's escorts, a middle-aged paladin with hooded eyes and a gentle demeanor. "I hope I've not interrupted you."

*choice
    #"Not at all. How can I help you?"
        *set charming %+ 5
        *set precharming %+ 5
        *set noble %+ 5
        *set prenoble %+ 5
        "Thank you, ${titlegreet}. The Saintess wishes to speak to you, and I am to act as escort, if it pleases you."
        *goto afterhelp
    #"What business do you have with me?"
        *set charming %- 5
        *set precharming %- 5
        *set noble %- 5
        *set prenoble %- 5
        The holy knight lowers his head slightly at your curt tone. "I apologize if I've caught you at a bad time, ${titlegreet}. But the Saintess wishes to speak to you, and I am to act as escort, if it pleases you."
        *goto afterhelp
    
        *label afterhelp
        
        You feel your eyebrows raise at the statement. You don't know a great deal about the Jovian Church, but you [i]do[/i] know that the saintess's position is one that commands vast political influence. It is unclear why she'd want anything to do with a knight—[i]in-training, technically![/i]—but you also know that it would be deeply unwise to refuse her request.

*page_break You follow him.
When you find the saintess, she appears to be locked in tense conversation with a noblewoman you don't recognize. Though her expression and posture remain immovably serene, there is a slight tinge to the saintess's tone that speaks of subdued ire.

"I cannot speak for the deeds of saintesses long since welcomed back into Jove's embrace, my lady."

The noblewoman laughs derisively from behind her fan. The stitching of her ornate indigo gown marks her as a Salantir noblewoman of some standing. "You have the tongue of a bureaucrat, Saintess. Were that you had applied it to hastening the Accords—rather than riding its coattails to the Church's benefit."

The paladin beside you moves to accost the woman, but the saintess raises one hand to halt him. "You do our influence too much credit, and our efforts too little. The Church has requested the signing of the Accords since the time of King Julius's grandfather. But we are simple clerics, my lady, and we cannot do much to overturn royal decrees."

"Yet your Church curried favor enough with the Parami kings of old when it bid them invade Arcadia. Surely such transparent platitudes are beneath you, my dear saintess." The woman turns towards you, having finished her disparaging spiel. "Ah, but here comes a fresh perspective, a life lived so far removed from the axis of power. What say you, dear? Can you not smell the blood of innocent Arcadians on the hands of our saintess?"

*choice
    #"This is uncalled for, Madam. There is much to admire in the saintess's unflagging efforts."
        The noblewoman scoffs at your response. "I suppose I expected too much out of one so closely aligned with the Parami royals. No matter," she says, sparing a severe glance in the saintess's direction. "This has been an…[i]enlightening[/i] diversion, dear saintess. 
        *goto afterderide
    #"I agree. The Church's endorsement is paltry redress for their hand in the carnage."
        The noblewoman regards you with a curious glint in her eyes. "A most refreshing response, ${titlegreet}. I daresay your perspective is one sorely needed in the circle of power," she says, shooting a rather smug smile in the saintess's direction. "Thank you for your time, dear Saintess. 
        *goto afterderide
    #"It does the Arcadians no good for their benefactors to antagonize one another."
        The noblewoman sighs longsufferingly. "I had hoped that you would be a
        *if (gender = "male")
            man 
            *goto aftergenderz
        *elseif (gender = "female")
            woman 
            *goto aftergenderz
        *else
            person 
            *goto aftergenderz
        *label aftergenderz
        of principles, ${titlegreet}. Is there naught to be found in Param but unscrupulous diplomats?" she asks dramatically, sparing a severe glance in the saintess's direction. "Regardless…I suppose this has been an enlightening diversion, dear saintess. 
        *goto afterderide

*label afterderide
Do take care—the winter chill bites rather viciously this year."

The woman dips into a light curtsy and walks away, the air smelling of lavender and sage in her wake.

The saintess heaves a weary sigh as she watches the noblewoman depart. "Countess Meridagne. A difficult woman, even among the Salantir. Her concern for the Arcadians are admirable, but there is nothing to be gained from so fractious an attitude. I hope those she advocates for do not suffer for it.

"But enough about that," the saintess says as she faces you, her seraphic smile slipping back on like a mask. "We have much to discuss. May I address you as ${fname}?"

You nod in response; it is strange that she would even ask, given the canyon that separates your respective standings. "At your service, Saintess."
*page_break
"I won't waste much of your time, then. Your exploits have been relaid to me in great length, ${fname}, and I think the kingdom has much to learn from them. Of particular interest to us is your rescue of Lady Ilya, who I understand would have been lost to us without your intervention."

*choice
    #"I see my reputation precedes me."
        The saintess smiles. "It is good to be conscious of the credit one is due, ${fname}."
    #"The stories do me too much credit, saintess."
        The saintess smiles. "There is no need to be modest, ${fname}; Lady Ilya told me so herself."
    #"She's helped me out plenty, too. I consider us even."
        The saintess smiles. "Good companions are a rarity and a treasure both. I'm glad you and Lady Ilya have had the fortune to meet one another."

*label aftercharming
*if (ilyarescue = "alchemy")
    *set temp1 "alchemist"
    *goto proceedd
*elseif (ilyarescue = "enchantment")
    *set temp1 "enchantress"
    *goto proceedd

*label proceedd
*if (ilyarescue = "alchemy")
    You proceed to discuss the antivenom potion you had concocted on that fateful day, and how its risks could be mitigated to allow for scaled up production.
    *label knowalch
    You find the saintess to be a tremendously knowledgeable ${temp1}, 
    *label immediateprod
    and the conversation is immediately productive despite its short duration.
    
    She extracts a promise from you to meet her in the Old Cathedral for further discussion, an offer to which you are happy to agree.
    *goto postsaintess

*elseif (ilyarescue = "enchantment")
    You proceed to discuss the resistance enchantment you had cast on that fateful day, and your method of subverting the risks of enchanting an indisposed subject. 
    *goto knowalch

*elseif (ilyarescue = "thaum")
    You proceed to discuss the properties of the Elyssian beast medula you had extracted on that fateful day, and how the ingredient could be applied to treat other fatal poisons. You find that the saintess has a remarkable understanding on the principles of thaum for one who does not practice the art, 
    *goto immediateprod

*else
    You proceed to discuss the benefits and risks of using spirit gates as a means of transportation, and how the method might be applied for the Church's healers to travel faster as they serve those in need. You find the saintess to be remarkably open-minded to a school so recently tabooed by the Church, 
    *goto immediateprod

*label postsaintess
*page_break
As the saintess disappears into the crowd, it occurs to you that you have not seen any of your companions this whole evening. You survey the room for their familiar faces, and find that they are all too easy to discern.

In an inconspicuous corner of the room, Leon dutifully tends to a horde of nobles, a strained smile plastered on his face. He had tried to post himself behind a large statue to avoid their notice, but instead they orbit around prince and sculpture both like moons compelled by a strong gravity.

At the center of the ballroom, Ilya seems to have morphed into the flower of high society, seamlessly exchanging quips and dancing with her peers. You know her too well to miss the way the corner of her lips quirk up in annoyance and exhaustion, the only flaw in her otherwise exquisite poker face.

By the western curtains, beyond the door to the balcony, a brown-haired boy dressed in royal blues has draped himself over the marble railings. If the forbidding aura he exudes had failed to ward would-be-ingratiators, the royal guards posted by the door seemed to have proven a sufficient failsafe.

It seems your comrades are united in their disdain for the noble life. Perhaps they would appreciate an intervention.

What will you do?
*choice
  #Free Leon from the nobles' clutches.
    When the prince sees you approaching, his eyes light up the way a parched traveler's might upon encountering a desert oasis. "My Lady, if you'd please excuse me," he manages sheepishly, extracting himself from the fawning noble. "It seems my retainer has need of me."
    
    You pointedly ignore the venomous glare she launches in your direction. "Come now, you must make good use of your time while you're in the capital, Your Highness. You have been absent from the circles for [i]years![/i] Think of your reputation, won't you?"
    
    Leon looks at you despairingly.
    *choice
        #"There is an urgent matter we must discuss. This way, Your Highness."
            *set charming %- 15
            *set precharming %- 15
            *set rleon %+ 10
            Leon nods and makes his way towards you. "I will call on your household before I leave the capital, Lady de Thianne," he placates.
            
            "I don't know if you can fit that in your schedule, Your Highness. Given what happened yesterday…"
            
            Leon cocks his head at you in confusion, and you resist the urge to roll your eyes. [i]Play along[/i], you try to tell him, and his eyes widen when he catches on to the ploy. "Ah, right, of course. I do apologize, My Lady—next time, then. Please give my regards to your father."
            
            The prince smiles as he beats a hasty retreat, and you follow him obediently.
            *goto excellentwork
        #Sneer at the woman. "Are you insinuating an assault on the Prince's honor, My Lady?"
            *set charming %+ 15
            *set precharming %+ 15
            *set rleon %+ 10
            The lady flinches as she realizes the implications of her words. "Why, I never—that is to say, I was simply—"
            
            "I'm sure it was just a slip of the tongue, My Lady," you allow, though your glare on her doesn't falter. "Then, if you will excuse us."
            
            You turn on the ball of your feet and march away, the prince following you obediently like a duckling.
            *label excellentwork
            *page_break
            "Phenomenal work, ${fname}," he remarks when you've made your escape, beaming. "I rather like you as a retainer."
            
            "Someone has to rescue you from your own good intentions. Don't smile, Your Highness, our discussion is [i]very[/i] serious."
            
            The prince immediately schools his expression. "Right," he whispers, light dancing in his eyes. "I
            *goto afterhonor
        #Do nothing. Let Leon sort out this mess.
            *set charming %- 15
            *set precharming %- 15
            *set rleon %- 10
            He narrows his eyes at you, exasperated. "I'm sure ${they} wouldn't come find me if it wasn't important," the prince says as he yanks his arm away. "I will call on your household before I leave the capital, so for now [i]please excuse us[/i], Lady de Thianne."
            
            The prince maintains an expertly neutral expression as he beats a hasty retreat. You follow after him obediently.
            *page_break
            "Could've used a little help there, ${fname}," he grumbles.
            
            "I did help, Your Highness. You ended up getting away, didn't you?"
            
            The prince crosses his arms petulantly. "You're lucky I like you. I
            *goto afterhonor
    *label afterhonor
    really did have something I want to talk about, though."
        
    "I'm all ears, Your Highness."
        
    "Leon," he corrects.
        
    "Prince Leon," you try.
        
    "[i]Leon.[/i]"
        
    "Leon, then."
        
    The prince beams as he begins his explanation.
    *page_break
    "Did my brother tell you anything about what we'll be doing next?" He didn't, and you tell Leon as much; the prince grins. "The mission takes us out of Param, ${fname}. We're going to Yotai!"
        
    The news catches you by relative surprise; the king had said that Leon's missions would be strictly domestic, after all. The Yotai Free Cities is a neighboring nation to the east of Param, a merchant-prince confederacy that occupies Arvanand's eastern coastline. It serves as Arvanand's trading hub with the eastward continents, and is a naval might that can match the Imperial Navy ship for ship. "What business do we have with the Free Cities?"
        
    "Julius wants me to play diplomat, if you can believe it. We'll be accompanying our best shipwrights and engineers to speed up the Yotai navy's reconstruction," he explains. "There's been word of unsettling activities in the Empire lately. Julius thinks they may be considering a second invasion, and we'll need Yotai to be ready."
        
    You nod in understanding. The Yotai Navy was instrumental in repelling the Imperial invasion, but much of their forces had been obliterated in the process. If a second invasion was truly on the horizon, an unprepared Yotai could spell the continent's doom. "You seem awfully happy about this."
        
    "Ah, do I? Sorry, this'll be my first time going to Yotai. I've heard a lot of good things about their cuisine," he explains sheepishly. "And the city-state we're going to is where the Shuria School originated from, you know? I hope I get to spar with one of the masters."
        
    *choice
          #"I wonder what their people are like."
              *set charming %+ 15
              *set precharming %+ 15
              *set rleon %+ 10
              "You'd think they're very different right? They trace their ancestry all the way back to Shun-En, across the ocean," the prince explains. "But they're proper Arvanians now, and you can't even tell their accents apart. The saintess is originally from Yotai, did you know? Though the Cheilong clan isn't really all that well-known…"
                
              Leon continues his lengthy monologue on the finer points of Yotai culture. It's nothing you don't already know, 
              *label indulgeprince
              but you indulge the excitable prince anyway, if only to divert him from his royal obligations.
              *goto afterwonder
            
          #"This isn't a vacation, Leon."
              *set optimistic %- 15
              *set preoptimistic- 15
              *set rleon %- 10
              Leon furrows his brows. "I know that, ${fname}. You saw my work with the White Fangs, right? I take my work seriously," he says, and there is an uncharacteristic set to his jaw as he leans against the wall. "In any case, I think sparring with the masters is useful experience since our work involves will involve a lot of combat after the Yotai visit.  
              *label shuriaschool
              "Are you familiar with the Shuria School, ${fname}? Their footwork is particularly fascinating…"
                
              Leon continues his lengthy monologue on the finer points of Yotai swordsmanship. It's not a field you have any particular interest in, 
              *goto indulgeprince
            
          #I nod along pleasantly and let him talk.
              *set charming %- 15
              *set precharming %- 15
              *set rleon %+ 10
              "Ah, but the masters might be on their pilgrimage this time of year. I hope we get to catch them before they leave—if not, I'm sure their disciples would still make for a fine substitute," he rambles, thoughtfully nodding to himself. 
              *goto shuriaschool
        
   *label afterwonder
   *page_break
   "Alright, I think that's enough of a break," Leon decides eventually, stretching his arms in a distinctly un-princelike fashion. He casts a glance at the nobles impatiently pacing the carpet some ten steps away, and sighs dramatically. "Back into the fray I go. Thanks for the talk, ${fname}, it really was—"
       
   Leon never gets to finish his sentence, as he 
   *goto shriek
   
  #I'll see if Ilya would indulge me with a dance.
    The healer looks up as you approach, her practiced facade slipping ever so slightly. 
    *temp witchquote ""
    *temp witchquotez ""
    *if (witchnight = "false")
      *set witchquote "You must think I look silly, huh?"
      *set witchquotez "Not at all."
      She looks incredibly different in her off-shoulder, figure-hugging ballgown, the sequined black fabric painting a stark contrast against her milky skin and ivory hair.
      *goto shegreets
    *else
      *set witchquote "Thanks for the help back then. The witchnight has been a smashing success."
      *set witchquotez "I can see that."
      It is difficult to miss her exquisite ballgown, an off-shoulder, figure-hugging piece glimmering with the deep purple of witchnight. Against the sequined, inky fabric, her pale complexion and ivory hair almost seemed to glow. [i]So that's what it was for[/i], you duly note.
      *goto shegreets
    *label shegreets
    
    "${fname}," she greets, disentangling herself from the crowd of nobles. She catches your stare on her gown, and purses her lips sheepishly. "${witchquote}"
    *choice
       #"${witchquotez} You look stunning tonight."
         *set charming %+ 5
         *set precharming %+ 5
         She smiles, a slight blush dusting her cheeks. "Thank you. You clean up pretty well, yourself."
         *label ilyafake
         *fake_choice
             #"So this is what you look like in your element, huh?"
             #"You look exhausted, Ilya. Haven't had your fill of these nobles yet?"
             #"I've never been to a ballroom before. Care to teach me the waltz?"                
         *goto ilyawhodis
     
       #"It was nothing. I'm just glad to be of service."
         *set charming %- 5
         *set precharming %- 5
         She chuckles at that. "You really are too nice for your own good, you know."
         *goto ilyafake

    *label ilyawhodis
     
    Before you can say anything, a boyish voice interrupts your conversation. "Oh Ilya, there you are."

    The voice belongs to a fresh-faced young man dressed in a well-tailored tunic and jacket, his tawny hair sticking up in untamable curls. He places a hand on the small of Ilya's back, his gaze on her completely besotted. "Oh, sorry, am I interrupting anything?" he says when he recognizes your presence.
     
    "Not at all," Ilya says, her smile all business. "${fname}, this is Lord Kavan de Juvan, firstborn of the Count de Juvan. Kavan, the Honorable ${fname}, Royal Retainer to Prince Leomar."
     
    "It's a pleasure," he beams, taking your hand in his—a rather blatant violation of Parami ballroom decorum. "Thank you for keeping Ilya safe out there. I don't know what I would've done if I'd lost her."
    *temp gainebrighten ""
    *choice
         #Snatch your hand away. "There's no need for that. Just looking out for my friend."
             *set charming %- 15
             *set precharming %- 15
             *set gainebrighten " once more."
             Kavan retracts his hand, chastened. "Ah, I'm sorry. I really do need to work on my manners."
             
             "I'm sure ${they} @{plural don't|doesn't} mind too much, Kavan. But will you excuse us a moment?
             ${fname}'s work will take ${them} out of Sienan soon, so this banquet may very well be the last I see of ${them}."
             
             The young man brightens once more. "Of course. I'll be by the banquet table, then." He gives you both a light bow, and you soon lose sight of his form in the crowd.
             *goto aftergaine
         #Shrug and return the handshake. "No worries. Ilya's helped me out a lot, too."
             *set charming %+ 15
             *set precharming %+ 15
             *set gainebrighten "."
             Kavan's smile is a size too big for his face. "She really is too kind, isn't she? Why, has she told you about the time she—"
             
             "We agreed not to talk about that," the healer interrupts huffily. "In any case, will you excuse us for the moment? ${fname}'s work will take ${them} out of Sienan soon, so this banquet may very well be the last I see of ${them}."
             
             The young man brightens. "Of course. I'll be by the banquet table, then." He gives you both a light bow, and you soon lose sight of his form in the crowd.
             *goto aftergaine
         #"Careful there. Shake my wrist three more times and you'll have to marry me."
             *set charming %+ 15
             *set precharming %+ 15
             Kavan's laugh is high-pitched and boisterous; it draws the attention of the surrounding nobles. "I hadn't expected you to be so familiar with Parami traditions, ${fname}. But that's a dated tradition, you know, or else any old fellow could just—"
             
             "I'm sure ${they} @{plural find|finds} the history lesson riveting, Kavan," Ilya interrupts. There's a strain to her smile, though of course Kavan fails to notice. "But will you excuse us for the moment?
             ${fname}'s work will take ${them} out of Sienan soon, so this banquet may very well be the last I see of ${them}."
             
             The young man brightens once more. "Of course. I'll be by the banquet table, then." He gives you both a light bow, and you soon lose sight of his form in the crowd.
             *goto aftergaine
    *label aftergaine
    
    "Now, then," Ilya says, threading her hand through her white hair. "Shall we dance?"
    *page_break
    The orchestra launches itself into a familiar jig as Ilya leads you towards the dance floor. Against the musical backdrop of the Duchess's Basse, you and Ilya bow to each other as gawkers bore holes into your back.
    *if (gender = "male")
        "Pay them no mind, ${fname}. Just the gentry's greetings: all the fresh meat of the nobility are granted the same treatment," she says, easing into the jig with a practiced deftness. "Shall I teach you the steps?"
    *else
        "Pay them no mind, ${fname}. It is only that noblewomen are expected to dance with [i]men[/i] in this ballroom," she says, easing into the jig with a practiced deftness. "Shall I teach you the steps?"
    
    *label invitees
    *set ilyahouse true
    *temp ilyadance1 ""
    *temp ilyadance2 true
    *temp ilyadance3 true
    You almost laugh at the offer: the Duchess's Basse is a Salantir composition, and one that had been drilled into you thoroughly during your time there. But would it be prudent to hide your proficiency instead?
    *choice
            #I feign ignorance. My role is that of a baseborn mage, after all.
                *set charming %- 5
                *set precharming %- 5
                *set rilya %+ 10
                *set ilyadance1 "bad"
                You swallow your pride and stumble into a halfwit's routine, virtually ignoring the orchestra's rhythm and all but tripping over your own feet. Ilya remains remarkably patient with you throughout, though by the third time you stepped on her feet you could spot her right brow twitching ever so slightly. Regardless, the music goes on and so do you.
                *label sokavanhuh
                
                "So," you 
                *if (ilyadance1 = "bad")
                    say, trying not to wince as you miss your cue again. 
                    *goto countkavan
                *else
                    say as you match her steps perfectly. 
                    *goto countkavan
                
                *label countkavan
                "Lord Kavan de Juvan, huh."
                
                "I figured you'd ask about that," she groans, resigned. "He's a sweet boy, as you've seen. Heir to a prominent noble house…" her voice trails off 
                *if (ilyadance1 = "bad")
                    as she leans to correct your posture. 
                    *goto eyebrowsraise
                *else
                    as she tugs a stray strand of hair behind her ear. 
                    *goto eyebrowsraise
                
                *label eyebrowsraise
                "And a long-time friend of mine."
                
                Your eyebrow raises at that. "How loosely do they define [i]friendship[/i] among the nobility?"
                        
                "Not loosely enough," she sighs. "I suppose a better term for him is [i]suitor[/i]. He has been persistently proposing to me for some time now."
                        
                You nod thoughtfully. "And you're not interested?"
                
                "I wish I was. It would solve all my problems handily." 
                *if (ilyarom)
                    She pauses, her expression wistful. "Of course, now I have you to worry about too."
                    *goto midbasse
                *else
                    *goto midbasse
                *label midbasse
                *if ((ilyadance2 = "false") and (ilyadance3 = "false"))
                    *goto afterbasse
                *else
                    *choice
                        *selectable_if (ilyadance2) #"Just what are these problems you're referring to?
                            *set ilyadance2 false
                            "My father is dying," she begins. "And he has no heir to survive him. My brothers are not yet of age, and I…am a woman. A frivolous, irresponsible being, to hear Parami laws tell it."

                            You gulp at the acid in her tone. "I'm sorry to hear that, Ilya."

                            "I've cried my share of tears over it, ${fname}. There's nothing to do but to salvage my family, before the [i]honorable[/i] Baron de Alviar wrests the estate from his own niece and nephews," she retorts, her eyes burning with the righteous fury she reserves for highway bandits. "I will not see my brothers destitute, and so I must fight."

                            "How?"

                            Ilya gazes across the room, to where the saintess is entertaining a gaggle of Salantir nobles. "I must become more than just a woman. An exemplar—a saintess-in-training, handpicked by the Church to inherit the torch of Jove once the saintess passes. Only then will they recognize my rights to property. But the process is lengthy and uncertain. I'm the biggest contender right now, but what if the saintess has a change of heart? ${fname}, what if my father passes before I am named her successor?

                            "And so this is where I find myself. The only other way for me to succeed my father's estate is through matrimony, to a lord of high standing. Then the state will recognize me as a…[i]guided woman[/i], one that receives trustworthy counsel on the running of her fief," she pauses, and looks across the room at Kavan. "Never mind that said counselor will run it into the ground, well-meaning though he is."
                            *goto midbasse
                        *selectable_if (ilyadance3) #"What's wrong with marrying Kavan? He seems like a nice kid."
                            *set ilyadance3 false
                            *if (ilyarom)
                                She looks up at you, scrutinizing. "${fname}, are you…sulking?"
                                *choice
                                    #"Yes. I don't like the way he looks at you."
                                        *set rilya %+ 10
                                        She giggles. "There's nothing there, ${fname}, I promise. Not on my part at least."

                                        "He clings to you quite a bit though, doesn't he."

                                        "You'll have to forgive him his boyish infatuation. Our families are very close, so we've been friends from the crib."

                                        "And what does your family think about your future…prospects with him?"

                                        Ilya's smile is wistful. "They've said nothing of it, out of consideration to me. But if it's the only way for our family to stay afloat…I don't want to disappoint them, ${fname}." She pauses, then, and looks you directly in the eyes. "But I'll find a way to make everything right. Wait for me a bit longer."
                                        *goto midbasse
                                    #"No, I really do think he's a nice guy."
                                        *set rilya %- 5
                                        Ilya purses her lips, slightly distraught. "I see," she says, uncharacteristically missing a step. "He really is. And were circumstances different, I might have found his boyish infatuation endearing. But I cannot love him, ${fname}, when he is like a brother to me." The healer twists her arm inwards and turns on the ball of her feet. "Besides, I have my eyes on someone else now."

                                        "And who might that be?"

                                        "Who indeed."
                                        *goto midbasse
                            *else
                                Ilya sighs, longsuffering. "I can't feel that way for him, ${fname}—and believe me, I've tried. He is like a brother to me, and his love should go to someone capable of matching it. Just as I will not see my brothers destitute, I will not lead him down this path of misery. He deserves better."
                                *goto midbasse
            #Surely there are places for a commoner to learn the Basse, should they wish to.
                *set charming %+5
                *set precharming %+ 5
                *set rilya %+ 10
                *set ilyadance1 "good"
                You fall into step in perfect harmony with Ilya, ignoring the way her eyes widen at your sudden display of skill. She furrows her brows and looks ready to interrogate you, but you shake your head in preemption and she withdraws her questions with a sigh. "You and your secrets," she scolds. You lean forward with your palm on the small of her back, and Ilya turns to the surge of orchestral music.
                *goto sokavanhuh
                
                *label afterbasse
                
                The music swells one last time, before drawing to a close.
                *page_break
                
                "Ah, but look at me rambling on about my problems. This banquet's supposed to be a cheerful occasion, right? Sorry to be a wet rag," she says, curtsying to close the dance. "It was a good talk, ${fname}. Thank you for—"
                
                Ilya never gets to finish her sentence, as she 
                *goto shriek
                
                
  #Meet with Saine on the balcony.
      *set saineace true
      You are accosted by a guard as you make your way to him. "Halt, Retainer. The prince wishes to be left alone."
      
      Saine catches the exchange from his perch on the balcony and turns around to regard you. With a wave of his hand, he bids the guard let you pass. "Have they gotten on your nerves too, ${fname}?" he inquires, smirking.
      *choice
          #"I don't mind the banquet, actually. The sugared ham is easy on the tongue."
              *set charming %+ 15
              *set precharming %+ 15
              The prince's laugh rings hollow. "That's about the only thing this farce has going for it. But I envy your fortitude, ${fname}. I wish I had it for myself."
              *goto aftergame
          #"I'm losing my mind. I don't know how you put up with this every day."
              *set emotional %+ 15
              *set preemotional %+ 15
              *set rsaine %+ 5
              "[i]Put up[/i] is a strong word for it," he chuckles. "Poor Julius must be sprouting grey hairs under that crown. Not that he doesn't deserve it, the jerk."
              *goto aftergame
          #"It's fine for a day, but I imagine it grates quickly as a lifestyle."
              *set emotional %- 15
              *set preemotional %- 15
              *set rsaine %+ 5
              "You imagine correctly," he sighs, massaging his temple. "Day in and day out, all I do is entertain crooked nobles with a smile on their face and a dagger in their doublet. They say to be born a royal is a blessing; I wonder if the Church does refunds."
              *goto aftergame
          
      *label aftergame
          
      You watch quietly as Saine leans against the railing, arms crossed over his chest. "${fname}, can you keep a secret?"
          
      *choice
              #"Of course. You know you can trust me."
                  *set charming %+ 5
                  *set precharming %+ 5
                  *set noble %+ 5
                  *set prenoble %+ 5
                  *set rsaine %+ 5
                  "Jove bless you, ${fname}. Good to know someone's on my side in this blasted court."
                  
                  "Of course, Your Highness. Just doing my duty…"
                  
                  *choice
                      #...as a retainer of the court.
                          *set rsaine %-5
                          "Oh come on, not you too." The prince whines, furrowing his brows. "Don't stand on ceremony with me, ${fname}, or I really will go crazy. And just Saine will do, please and thank you."
                          *goto sainesecret
                      #...as your friend.
                          The prince nods sagely. "That's right. You're my friend, ${fname}. So just Saine will do, please and thank you."
                          *goto sainesecret
              
              #"I'd rather not hear it, Your Highness."
                  *set charming %- 5
                  *set precharming %- 5
                  *set noble %- 5
                  *set prenoble %- 5
                  *set rsaine %- 5
                  "Well that's too bad, 'cause you're going to," he snickers. "If I'm going to be a royal I might as well make use of the status, right?"
                  
                  Though his tone remains carefully airy, the furrow in his brow tells you that his mood has likely gone south. You decide this would be a poor time to commit lèse-majesté. "As you wish, Your Highness."
                  
                  "Just Saine will do, please and thank you," he corrects sagely. 
                  *goto sainesecret
                  
      *label sainesecret
        
      You nod in understanding, and the prince smiles. "Anyway, about that secret. I…might be running away again, ${fname}."
        
      Your expression is carefully neutral as you consider your next words.
      *temp sq1 true
      *temp sq2 true
      *temp sq3 true
      *label sainehub
      *if (((sq1 = "false") and (sq2 = "false")) and (sq3 = "false"))
          *goto aftersainehub1
      *else
          *goto sainehubchoice
        
      *label sainehubchoice
      *choice
            *selectable_if (sq1) #"Can I ask why, Saine?"
                *set sq1 false
                Saine looks out at the horizon and exhales, the action shaking his whole body. Against the endless expanse of the night sky, his wiry frame looks positively minute; it occurs to you that for all his maturity, the boy is barely sixteen. "My brother is shipping me off to Thayle—across the ocean, near the Imperial border," he begins, shuffling his feet. "It would be one thing if it was just a diplomatic post. But anyone can see he means to have me [i]married[/i], ${fname}. The Thaylian princess turns fifteen this year, and I'm to be posted in her palace. [i]In her palace![/i] Julius wouldn't know subtle if it socked him in the face."
                
                You nod solemnly. Arranged marriages are the norm within higher circles of power, though you understand resentment for it has been on the rise of late.
                *choice
                    #"Isn't it a bit early to take such extreme measures?"
                        *set charming %+ 5
                        *set precharming %+ 5
                        "She might even turn out to be a nice girl," you hum.
                        
                        "Everyone says she is, ${fname}, but that's besides the point," the prince says, smiling ruefully. There's a hesitant tremble to his lips, but in a moment his gaze turns resolute and he presses onwards. "I can't love her, ${fname}. I can't love [i]anyone[/i]; I
                        *label justdonthave
                        just don't have it in me. Julius says he understands, but he'll have me sent anyway—noblesse oblige this, noblesse oblige that—he'll never get it, ${fname}. I'll be miserable for the rest of my life, and he'll chalk it up as a [i]noble sacrifice[/i]."
                        
                        The prince looks up at you expectantly.
                        *choice
                            #"I understand, Saine. If you're set on running away, I'll help however I can."
                                *set rsaine %+ 10
                                Saine looks dangerously close to tears as he drinks your words in. "Thank you," he manages, his voice trembling. "Thank you."
                                *goto sainehub
                            
                            #"This is the burden of royalty, Saine. You must learn to accept it."
                                *set rsaine %- 25
                                Saine startles at your response, looking utterly betrayed. "I can't believe you, ${fname}," he breathes, after a long moment. "You're all the same, aren't you? No one gets it. No one will [i]ever[/i] get it." He turns his back on you, his shoulders trembling with barely contained fury. "Thank you for your time, ${fname}. [i]Leave[/i]."
                                *goto aftersainehub2
                            
                    #Don't comment on the matter. Saine looks like he has more to say, anyway.
                        *set charming %- 5
                        *set precharming %- 5
                        "And this is where I tell you my second secret, I guess," the prince says, smiling ruefully. There's a hesitant tremble to his lips, but in a moment his gaze turns resolute and he presses onwards. "I can't get married, ${fname}. I [i]can't[/i]. Even the thought of loving someone in that way, or engaging in—in—" the prince gulps, clearly thinking better of whatever he was about to say. "I 
                        *goto justdonthave
                    
            *selectable_if (sq2) #"Where are you planning to go?"
                *set sq2 false
                The prince blows on a strand of his hair. "I don't know—I was hoping you had suggestions, ${fname}. Yotai sounds like a nice place, but Salantira is where the royal spy network is the weakest."
                
                "Have you considered going overseas?"
                
                Saine hesitates, considering. "I'd rather not. I'm rather fond of Arvanand." The prince gives you a sideway glance, his green eyes sharp and determined. "But I will if I have to."
                *goto sainehub
            
            *selectable_if (sq3) #"Does anyone else know?"
                *set sq3 false
                "No, it's just you. Leon and Ilya are nice enough, but I'm not sure they'll get where I'm coming from. They're only…[i]annoyed[/i] with their position; it's not the same. And honestly? I think Ilya would tattle."
                
                You picture the straitlaced healer, always the worrywart, and are inclined to agree.
                *choice
                    #"Thank you for trusting me. I'll never breathe a word to anyone."
                        *set rsaine %+ 5
                        Saine's smile is very close to blinding. "See, I knew I could trust you," he laughs.
                        *goto sainehub
                    
                    #"I think you should tell them, Saine."
                        "Maybe I will, if you think it's a good idea," he relents. "But not anytime soon. They don't know that I'm…like this. I'll need to think about it."
                        *goto sainehub
                    
                    #"I'm sorry, Saine. I don't know if I can keep your secret."
                        *set rsaine %- 15
                        His gaze on you turns harsh and imperious, and at once you're reminded that whatever else he is, Saine is first and foremost [i]royalty[/i]. "Don't, ${fname}," he hisses. "I mean it."
                        
                        You gulp and drop the subject.
                        *goto sainehub
            
    *label aftersainehub1
    *page_break
    "Thanks for hearing me out, ${fname}," Saine says as he pushes himself off the railing. "It was nice to talk to someone about this. Then I'll see you—"
        
    Saine never gets to finish his sentence, as he 
    *goto shriek
    *label aftersainehub2
    *page_break You do so.
    *goto shriek2
    
*label shriek2
Upon entering the room, you hear a bone-chilling shriek from the direction of the throne.
*goto chaos

*label shriek
is interrupted by a bone-chilling shriek from the direction of the throne.

*label chaos

The room descends into chaos.
*page_break
Your palms crackle instinctively with the spark of newly-wakened magic as you weave through the stream of fleeing nobles. Navigating the din and furor of the room proved a difficult task, but you thaum a smattering of thunder around you and the aristocrats gives you a wide berth.

There's a roar like a wounded animal, and from behind you Leon leaps forward, the prince's muscles taut as his face twists in anguish. In front of him, around him, loyal knights sworn in service to the crown lay like puppets with their strings cut, their skin branded with burning gashes you find all too familiar; the sight sets your stomach to sinking.

"Let him go," Leon snarls, in his hand a blade he appropriated from a dead knight. Opposite of him is a lady clad in a familiar indigo gown, her spine straight and expression bellicose as she presses burning talons against the king's throat. Countess Meridagne's visage twists into a manic sneer as she sees you approach.

"Ah, finally all the players are here! I was getting so very bored," she cackles, the air around her crackling with the telltale signs of a glamor breaking. The illusion bleeds away from her form like water off a pail: gone is the haughty noblewoman in all her indigo fineries, and in her place stands a figure you had hoped to never see again.

Your breath catches in your throat as you speak.
*page_break "Sister."
"Yes, ${fname}, how good of you to join me on this fine occasion," she jeers, her long black hair whipping about from the force of an arcane wind. Her red gaze is alert and piercing; they gleam like rubies against the light of her fiery talons. "Rein in the blond mutt, will you? The king and I have business to discuss."

"[i]I said drop him, witch![/i]" Leon shouts, his posture crouched like a tiger ready to pounce. Around him what remains of the royal guard form a wall like an impenetrable fortress, barricading Sister from potential escape routes.

Sister laughs and drags a single claw across the king's jugular. The man does not grant her the gratification of a scream, but his teeth bite down upon his lower lip with enough force to draw blood. "Take another step, little prince, and we'll see what your brother thinks of his second mouth."

Leon snarls menacingly, but does as he is told. Beside him Saine draws himself up, horror etched plainly onto his features. "Who are you? Why are you doing this?"

"What's this? Hasn't ${fname} told you about me yet? I'm hurt, you know," Sister says mockingly. She dips into a farcical curtsy with the king still in her arms. "Madame Altinier, Royal Mage of the Salantir High Court, if it pleases you. Come to put an end to your farce of a banquet."

Ilya stills beside you, her expression utterly bewildered. "Why would the royal mage sabotage a banquet in honor of Salantira? Madame, you're not making any sense."

"Ah, but didn't you hear me, maggot? This banquet is a [i]farce![/i] Arcadians spent centuries squirming under your tyrant's boot, and how do you assuage their pain? By getting your peerage fat off of wealth you wrested from them!" The king struggles in her grip, but Sister's hold on him is steady. "Tut, tut. Stay still, my king, or else my fingers will get so very slippery."

"The Parami and Arcadians [i]will[/i] know peace," King Julius retorts, heaving as he does. "Your act of terror here will mean nothing."

Sister cackles at that, the sound full and high as it rings about the room. "An [i]act of terror![/i] You are such a relentless optimist. I rather like that in my men."

King Julius eyes her incredulously. "Speak plainly, witch."

"This is no act of terror, fool. This is war! The might of Salantira will bear down upon your nation!" Sister is screaming now, and around her the arcane winds pick up and coagulate into masses of dark energy; the air is thick with an abundance of mana no one person should be able to conjure. "And in the meantime, you'll make a fine decoration for the palace gates."

And with that, Sister sinks her talons into the king's throat. He takes one last wheezing, gasping breath, and you feel your heart sink as the light leaves his eyes.

The king's body crumples to the floor.

*page_break

Leon wails at the sight, a guttural, animalistic sound that sends chills down your spine as he lunges for the black-haired witch. "Don't think you'll make it out of here alive!" he shouts, charging past the winds even as they cut into his skin. "You die today!"

At once the prince is upon her, but when the blade is brought down it pins only the witch's cloak to the ground. Leon whips his head up, green eyes searching, and when he finds her again she is on the far side of the hall, dark energy violently bursting forth from her palms. "Witness now the might of Salantira!" she bellows, and all throughout the room the air tangles and twists upon itself. Her magic rips sutures in the fabric of space, and where the astral cavities open, Salantir knights spill out in droves.

"What in the world…" Ilya whispers beside you, her voice trembling. "Are these…spirit gates?"

You wish. It's something far more powerful, though you can scarcely find the time to explain it now.

*page_break

The royal guards are caught off guard by the sudden onslaught, and all across the hall they are flanked and cornered, falling one by one to enemies that Sister spirits out of thin air. And though the Parami knights are some of the world's best, they are caught by surprise and outnumbered two-to-one besides; they are losing ground quickly.

You have to do something.
*choice
    #I use small, targeted blasts of lightning to pick the Salantir knights off from afar.
        *set thunderstrike true
        *set tcounter +1
        *if (thaum > 62)
            *set prestige + 5
            You do not shoot to kill, lest the blast catches the Parami knights as well. But a well-placed strike provides the necessary diversion for the Parami to find an opening or catch their breath, and for a moment the battle's tide turns to your favor. Yet the Salantir are relentless, and they soon 
            *goto redouble
        *else
            The spells shoot from your fingers in rapid succession, but your control slips and one of the lightnings arc sideways, catching a Parami knight on her breastplate. It was a glancing blow, one she easily shakes off, but you might not be as lucky next time. It becomes apparent that your mastery of thaum cannot match your ambition, and so you terminate the plan.
            *goto afterspellz
    
    #I cast enchantments on the Parami knights to give them an edge in their fights.
        *if (enchantment > 62)
            *set prestige + 5
            *set glyphofstrength true
            *set ecounter +1
            Your rapid-fire casting of the Glyphs of Strength seems to turn the tide of battle for a moment, but soon the Salantir 
            *label redouble
            redouble their assault with a nearly inhuman fervor. They spin into odd, jerking maneuvers that seem to disregard their own lives; they close distances quickly and let their shields clatter uselessly to the side. Anything to get a clean hit in, anything to overpower the Parami.

            And despite your best efforts, it's working.
            *goto afterspellz
        *else
            You attempt to cast multiple Glyphs of Strength in rapid succession, but your control on the enchantment slips and the spell circles dissipate into air. You try a second time, a third, but the spells sullenly refuse to be coaxed. It feels remarkably as if it has deemed you an unworthy master.
            
            You exhale slowly, willing the panic forming in your head to settle. Mass enchantments, it turns out, requires a tremendous amount of control and specialized knowledge. You don't appear to possess sufficient quantities of either at the moment, and Param is paying the price.
            *goto afterspellz
    
    #Too much ambition can lead to friendly fire. I focus on my own opponents.
        It's almost humiliating, to be reduced to basic attack magic when you're capable of so much more. But with so many allies in the line of fire, anything more would be truly irresponsible. You sling low-level thaum and spiritism spells at the surrounding knights, hoping to make a dent in the relentless wave of Salantir invaders.
        *goto afterspellz

*label afterspellz
        
"Out of my way!" Leon roars as he charges with a singular fury, swinging his blade like a madman. But for all that he's a talented swordsman, the Salantir knights are elites themselves, and their numbers show no sign of abating. 

"Leon, we're losing knights!" Ilya yells, sweat beading down her forehead as she casts enchantments en masse. "Cut us a path out of here, we have to retreat!"

Leon stalls his charge, hesitant. His sword arm trembles as he casts a glance towards Sister, still casting furiously to keep the portal open.
*choice
    #"We can't win against her, not like this. You'd be throwing your knights' lives away."
        *set optimistic %- 15
        *set preoptimistic %- 15
    #"After we make it out, we can come back for her head. I promise."
        *set optimistic %+ 15
        *set preoptimistic %+ 15
    #"Leon, please, I'm begging you. Think of what your brother would want."
        *set emotional %+ 15
        *set preemotional %+ 15
    #Say nothing. I trust Leon to make the right decision.
        *set charming %- 15
        *set precharming %- 15
"Alright," the prince relents, though the furious set of his jaw promises retribution. "Knights! To me!"

The warriors rally around the prince at once, and like a battering ram they cut a path towards the hall's exit. The Salantir scramble to halt the escape, but they had the disadvantage of position: most had placed themselves between Leon and Sister, apparently counting on the prince's fury to keep him fighting. His decision to retreat means the loss of their flanking advantage; their barricade becomes pliant as warm butter, against whom Leon and his knights play the knife.

For your part, the clear line of sight means that you were able to cast your more powerful spells without fear of friendly fire. You summon the recesses of your mana reserves and fire off as many ${firstspell} as you can, hoping the impact can take some heat off the vanguard.

Your group safely makes it to the exit, and with a flicker of speed and shadows, Saine joins you with the saintess in tow. "Thank you for the rescue," the saintess pants as she leans upon the young prince, one hand covering her bleeding abdomen. She mutters a few words in the sacred tongue, and the gaping wound closes in on itself. "I will see to your injuries outside, knights," the saintess announces, once again standing upright. "For now, we must escape."
*comment ~~~~PALACE ESCAPE~~~~~
*page_break
The path leading out of the banquet hall is mercifully vacant, and though the Salantir are hot on your heels it is only their mages' hastily-slung magefire that poses any threat to your escape. The saintess skilfully wards the thaum with barrier enchantments as you barrel through the halls and down the keep's grand staircase. Your head is throbbing from the clangor of armor and metallic scent of blood, but adrenaline keeps you going as the group shoots for the exit.

The vanguard is nine or ten steps from freedom when once more the air twists upon itself and tears a new cavity in space. Out walks Sister from the abyss, and with an outstretched hand she calls a Fist of the Dark Lord to hammer the knights backward, repelling them from the castle gate. The collision sends them reeling, but it is only a moment before they regain their footing, shaking off the spell's impact and ready to rush her.
*page_break
"You didn't think it would be [i]that[/i] easy, did you?" Sister taunts, and there is another voice under her bellow, something harsh and guttural and [i]ancient[/i]. The ground trembles under the weight of her oppressive mana, and behind her the void starts and vibrates and [i]expands[/i], dark tendrils reaching out until they form a pitch-black palisade that swallows the castle gate whole. Behind you the Salantir knights complete their pursuit, and with a rallying call they raise their blades against the corralled Parami. Sister watches the skirmish with barely-contained glee. "Dance for me!"

Leon swears under his breath as he rolls away from a blow and sweeps his opponent's feet out from under him. "${fname}!" the prince calls out desperately. "Is there anything you can do to get us past her?"

*choice
    #I swallow a gulp. I can certainly try.
    #I don't like our chances, but I won't just quietly bend the knee to her.
        *set optimistic %- 15
    #I've escaped her clutches once before, and I can do it again.
        *set optimistic %+ 15

You look at Sister's imposing figure, stance firm as her long black hair whips about her in unkempt tendrils. She holds your gaze against her own, expectant and exhilarated, her burning talons lying in wait at her sides like an embrace.

You tap into the last vestiges of your mana, setting the spell circles to bloom around you. Like clockwork the ancient words stage dive off your tongue as the runic formation flickers and then [i]blazes[/i] to life, crackling with the promise of a magical eruption.

The only way for you to dispel the arcane barrier is by defeating its master. And if you're to have a chance of doing [i]that[/i], you'll need to cast your strongest spell.

You dig your heels in as the circles drink your mana like parched land seeing its first rainfall. Your blood sings with a power that thrums quick and steady against your veins, your words quiet as an oath as you breathe the spell into being:

*if (ultima = "thaum")
    *page_break "Skywrath."
    *set ultima2 "Skywrath"
    *set specialvar 1
    The lightning screeches and darts when it comes, when it spills out from the runes and surges forward towards Sister. You recoil from the power of the spell's blast, ears ringing from the way it crackles angrily, searing against the air as it bounds forward in merciless streaks—
    
    And is gone.
*if (ultima = "alchemy")
    *page_break "Widow's Stream."
    *set ultima2 "Widow's Stream"
    *set specialvar 2
    Vials crash and shatter as they collide with the spell circle, the toxic concoction a deadly purple feeding the runes with its strength. The spell launches forward then, viscous and heavy and smelling of decay. Your knees tremble under the exertion, breath catching as the spell bounds towards Sister like a lumbering beast—
    
    And is gone.
*if (ultima = "spiritism")
    *page_break "Gatebreaker."
    *set ultima2 "Gatebreaker"
    *set specialvar 4
    The stench of death is unmistakable as the void opens in front of you, screeching as it tears into the world of the living. The ghasts are wailing when they emerge, clawing their way out; their forms are wispy and grey against the night sky, putrid flesh dangling from the bone as they sail, [i]soar[/i] towards Sister—
    
    And are gone.
*if (ultima = "enchantment")
    *page_break "Banecircle."
    *set ultima2 "Banecircle"
    *set specialvar 3
    The light screeches and darts when it comes, when it spills out from the runes and surges forward to the ground where Sister is stood. Your knees tremble from the exertion, but the spell catches onto the packed earth and it glows, [i]shines[/i] like a beacon and you allow yourself to [i]hope[/i]—
    
    And it's gone.
*page_break
"You can't seriously hope to defeat me with [i]ercei[/i] magic, ${fname}," Sister rebukes, closing the abyss that swallowed your spell whole. There is a quiver to her voice and a shallowness to her breath, but her scarlet eyes are lucid and piercing as she stares you down. "Do you still insist on denying Father's gift? Even if it costs you the lives of this [i]ercei[/i] rabble?"

The remark gives you pause. You picture the solemn, kindly king who now lays dead on the palace floor, and find that Leon's face all too easily replaces his.

*fake_choice
    #The image inspires more dread in me than I can rightly express.
    #Sister cannot be allowed to do as she pleases. She must be stopped.
    #If she's going to kill my friends, I'll make sure she bleeds for it.
        
You glare at Sister, quietly resolved as the seals branded upon your skin jolt and ignite. Like a dam breaking, your body shakes from the flood of power long-sealed, and when Sister recognizes it her smile contorts into one of wretched glee. "Finally. Give me your worst, ${fname}."

*page_break And so you do.

The trance feels as strange as you remember, the sensation at once scorching and biting-cold as you sink into the depths of your mind. When you are lucid again it is in a frigid, dark expanse, lighted only by the grey-green flare of dying embers, flickering where the black earth opens into a chasm.

On the cliff's edge you can feel a familiar force, strong and ancient and quiet, like a coiled viper a second from the lunge. You look up at the host of concentrated power and behold…

*label phantasmaselect
*choice
    #A kingly figure clad in a lavish blue-and-ivory robe. Looking into his pure white eyes feels like staring at the sun. 
        You reach out to him, and the figure stares back at you solemnly.
        
        [i]I am Satiel, the High Intercessor.[/i] You feel your head rattling with the sound of his imperious, booming voice. Your knees nearly give out under the weight of his attention, but you force your gaze to hold steady against those blinding white eyes. [i]Beloved of Isha, I have heard your call once more. Seek you the power of judgment? Bear you its burden?[/i]
        *choice
            *selectable_if (thaum >= 60) #(Thaum) "Yes, I will. I must."
                *set phant1 "Satiel"
                *set phant1title  "the High Intercessor"
                *set thaum %+ 25
                *set phantvar 1
                *set satiel true
                *achieve satiel
                [i]I have seen your resolve, Beloved. So it shall be done: my power is yours.[/i]
                
                The figure stretches both his hands skyward, and a host of radiant light gathers above him. The light expands radially, swallowing him whole, before streaking directly towards you and engulfing you in turn. When it fades, you find your veins singing with the weight of newfound power, though it is all you can do not to buckle under its load.
                *goto phantasmadone
            *selectable_if (thaum >= 60) #"No, Satiel. I have changed my mind."
                *label refusesatiel
                The figure regards you with something like dismay, and he fades in solemn silence into the abyss of your mind.
                *goto phantasmareselect
            *selectable_if (thaum < 60) #"No, Satiel. I cannot bear the weight of your power."
                *goto refusesatiel
    #A lithe figure donning a sinister jester's mask. The myriad knives hidden between the folds of their cloak are coated with an ominous purple sheen.
        The jester bows deeply before you, the motion far too elaborate to be anything but mocking.
        
        [i]Airas, the Beckoning Hand, at your service.[/i] Their tone carries a light-hearted sing-songy inflection, but you would be a fool to miss the dangerous glint peering at you from behind their mask. You force yourself to not cower before the menacing figure. [i]You have called for me again, Beloved of Isha. Will you prove a worthy match for my power this time, I wonder?[/i]
        *choice
            *selectable_if (alchemy >= 60) #(Alchemy) "Yes, I will. I must."
                *set phant1 "Airas"
                *set phant1title "the Beckoning Hand"
                *set alchemy %+ 25
                *set phantvar 2
                *set airas true
                *achieve airas
                [i]We shall see, won't we, Beloved? Take it, then: my powers are yours, such as they are.[/i]
                
                Airas' figure disintegrates before your very eyes, dispersing itself into a cloud of purple smoke. The pernicious mist settles around you like a cloak, and you force yourself to breathe it in as if it was nectar. Though your skin and lungs are all but burning by the end, you can feel your veins singing with the unmistakable sensation of newfound power.
                *goto phantasmadone
            *selectable_if (alchemy >= 60) #"Begone, Airas. I've changed my mind."
                *label refuseairas
                Airas' stance is carefully neutral, but not even their mask can conceal the quiet fury percolating in their eyes. [i]So be it,[/i] they say judiciously, melting back into the void.
                *goto phantasmareselect
            *selectable_if (alchemy < 60) #"Begone, Airas. I can't bear the weight of your power."
                *goto refuseairas
            
    #A monstrous, haggard shaman in tattered robes. His features are twisted into a madman’s grin as he brandishes a staff of misshapen boughs.
        The shaman is animated and wild-eyed as he regards you, manically swinging his staff to and fro.
        
        [i]I am Gweila, the Clear-Sighted![/i] The shaman's voice is at once shrill and thundering, and you nearly reel back from the way that it reverberates through your skull. But you force yourself to stand your ground—a gesture the shaman seemed to approve of. [i]So you come again, Beloved of Isha, so you have! You have need of Gweila? You want Gweila's power?[/i]
        
        *choice
            *selectable_if (enchantment >= 60) #(Enchantment) "Yes, I do. I must have it."
                *set phant1 "Gweila"
                *set phant1title "the Clear-Sighted"
                *set enchantment %+ 25
                *set phantvar 3
                *set gweila true
                *achieve gweila
                [i]Ha! Haha! Then Gweila gives you power! Be strong, or Gweila's power kills you![/i]
                
                Gweila swings his staff once more and fades into a mass of green smoke, laughing maniacally all the while. As the smog engulfs you whole, you feel your mind ringing as if about to burst from your skull—it is all you can do not to keep from collapsing from the pain. And though in the end the throbbing fades into something you'd still hesitate to call bearable, the newfound power singing through your veins proved an equitable recompense.
                *goto phantasmadone
            *selectable_if (enchantment >= 60) #"I changed my mind, Gweila. I don't want it, after all."
                *label refusegweila
                Gweila's features twist into a petulant scowl. [i]Then Gweila takes power with him! Your loss! Your loss, Beloved![/i] Having said his piece, the shaman turns away huffily and melts back into the abyss.
                *goto phantasmareselect
            *selectable_if (enchantment < 60) #"I think your power will kill me, Gweila. I won't take it."
                *goto refusegweila
            
    #A shapely woman that exudes an aura of death. Her blackened lips smile from behind a deep green veil as she offers you a skeletal hand.
        You reach out to the woman, and her lips quirk up—not unkindly, but it’s difficult to perceive her as anything but sinister.

        [i]Nyx, the Condemned[/i], she says, head slightly lowered by way of greeting. Her voice is grave and distinctly supernatural, and the way it echoes around your head inspires aught but terror. You force yourself to remain upright, to assert yourself as worthy. [i]We meet again, Beloved of Isha. Do you seek my power? Will you to treat with death once more?"[/i]
        *choice
            *selectable_if (spiritism >= 60) #(Spiritism) "Yes, I will. I must."
                *set phant1 "Nyx"
                *set phant1title "the Condemned"
                *set spiritism %+ 25
                *set phantvar 4
                *set nyx true
                *achieve nyx
                [i]Death is a tricky beast, Beloved. Tread lightly—see that it serves you, and not you it.[/i]
                
                Nyx curtsies with all the grace of an Imperial duchess, and her form fades into a mass of thick, swirling mist. As the haze engulfs you whole, it is all you can do not to scream at the way your skin writhes and boils as if melting from the bone. You persevere—and though in the end your pain dulls into something you'd still hesitate to call bearable, the newfound power singing through your veins proved an equitable recompense. 
                *goto phantasmadone
            *selectable_if (spiritism >= 60) #"Apologies, Nyx. I have changed my mind."
                *label refusenyx
                Nyx nods serenely, dipping into a light curtsy. [i]It is the wise
                *if (gender = "male")
                    man
                    *goto abyss
                *elseif (gender = "female")
                    woman
                    *goto abyss
                *else
                    one
                    *goto abyss
                *label abyss
                who does not jump headfirst into the abyss. Farewell, Beloved.[/i] And with that, she fades back into the void.
                *goto phantasmareselect
            *selectable_if (spiritism < 60) #"Apologies, Nyx. I am unfit to wield your power."
                *goto refusenyx

*label phantasmareselect
*page_break
The chasm peers at you with a baleful sort of silence. Yet it is only a moment before a new energy signature gathers above the abyss, the air growing turgid from the force bearing down upon it. 

You look up at the concentrated host of power to behold…
*goto phantasmaselect

*label phantasmadone
*set codexarcana true
*set phant1acq true
*page_break
Under you, around you, the expanse melts away in a slow and languid flux, and your consciousness comes back to the surface: slowly, and then all at once. You again find yourself in front of the castle gate, a wall of impervious darkness towering before you, Sister's form taut and gaze burning with expectation.

One you are now ready to meet.

${phant1}'s power courses through you, the sensation at once familiar and foreign. Where ${ultima2} had felt like lighting a torch against an inferno, this time [i]you are the inferno[/i], violent mana blistering and bleeding from your every pore.

*page_break
Sister bounds forward with her talons outstretched, closing in because that's the way she truly likes to fight, nimble and lithe with all the force of a trained assassin. But it is child's play to 
*if (phant1 = "Satiel")
    *set reckoninglight true
    blind her with a flash of radiant light, easier still to weave around the mage and knee her in the navel while you bring your spell down to bear.

    You feel Satiel in the back of your mind, his bearded face beatific as he pours his power in unmeasured streams. [i]Reckoning Light[/i], he says in your head, and the spell lurches from your palms instinctively: no spell circles, no chants, just power raw and unbridled as it explodes into the air around you, catching Sister in the blast—
    *goto sisteravoid

*elseif (phant1 = "Airas")
    *set venomdance true
    transmute the ground she walks on into air; bodily the mage tumbles into the crater, any foothold she finds on the way down immediately spirited away.

    You feel Airas in the back of your mind, the familiar, murderous glint of those eyes just barely visible beyond their jester's mask. [i]Venom Dance[/i], they say in your head, and the spell lurches from your palms instinctively: no spell circles, no chants, just power raw and unbridled as the spell is unleashed. It lurches forward in a furious, noxious haze—not so much poisoning the air as [i]turning the air into poison[/i]—and catches Sister as she falls—
    *goto sisteravoid

*elseif (phant1 = "Gweila")
    *set shamanselegy true
    enchant your body with a fortitude spell, easier still to weave around the mage when her talons find no purchase on your ensorcelled frame. You knee Sister in the navel, hard and fast, and she doubles over as you bring your spell down to bear.

    You feel Gweila in the back of your mind, wiry white hair tousled around his cackling visage as he pours his power in unmeasured streams. [i]Shaman's Elegy[/i], he says in your head, and in a breath ${ultima2} lurches from your palms instinctively: no spell circles, no chants, just power raw and unbridled, twice or three times more than what you're normally capable of. The spell catches Sister at point-blank range, thrumming, raging as it engulfs her—
    *goto sisteravoid

*else
    *set plaguehand true
    block her advance with fallen knights whose bodies you've bound to your will, easier still to weave around the mage as she deals with the lumbering fiends. You catch her by surprise and knee her in the navel as you bring your spell down to bear.
    
    You feel Nyx in the back of your mind, her veiled face beatific as she pours her power in unmeasured streams. [i]Plaguehand[/i], she says in your head, and the spell settles on your palms instinctively: no spell circles, no chants, just power raw and unbridled coiled around your fingertips. One touch is all it would take, one touch to melt the skin from her bones and wrack her with torturous pain; you reach out to her cowering form and Sister flinches, twists from the agony—
    *goto sisteravoid

*label sisteravoid
*page_break
And your control over the spell slips. A small mistake, one quickly corrected, but all it takes is a second for ${phant1}'s power to burst. The ancient, terrible force hemorrhages all throughout your body, desiccating your mana ducts as it goes with a firm reminder that [i]this is not power you are meant to command, not one that you can bear[/i]; at the end of it all you are collapsed on the packed earth, retching and heaving from a twisting pain you recall so well from your childhood.

Sister is looming over your crumpled form, cavalier despite the sag to her posture, the wounds peeking out from under her tattered cloak. "So this is what you're capable of, ${fname}. I should've killed you when I had the chance."

*choice
    #"You won't get away with this."
        *set emotional %- 15
        *set preemotional %- 15
        *goto nonpess
    #"Don't think this is over: I can still fight."
        *set optimistic %+ 15
        *set preoptimistic %+ 15
        *goto nonpess
    #"Please...please spare me."
        *set emotional %+ 15
        *set preemotional %+ 15
        *goto nonpess
    #There's no point in saying anything. It's over.
        *set optimistic %- 15
        *set preoptimistic- 15
        *goto pessimist

*label pessimist
You will yourself to accept the wretched fate that's been laid out before you. But even as you resign yourself to your impending doom, your body is wracked with involuntary sobs, so great is the pain; Sister stares you down with something like disappointment in her eyes.
*goto somuchtogether

*label nonpess
You open your mouth to speak but find that you can only wheeze, breath catching in your throat as your insides catch fire at the attempt. Your body is wracked with involuntary sobs, so great is the pain; Sister stares you down with something like disappointment in her eyes.
*label somuchtogether

"We could've been so much together," she mourns, and at her side her claws ignite with a new fire—blue-green this time, luminescent against the night sky. It flickers hypnotically as Sister raises the talons high.  "Alas, ${fname}. This is where you die."

*page_break The talons fall.

"That's enough, Altinier."

Sister's brow furrows, lips quirking into an incredulous smile as she eyes the approaching figure. "And what makes you think you're the judge of that, my dear saintess?"

The saintess in question raises a dagger against her own throat, blood leaking where it grazes her skin. "You need me, don't you?" she demands, her smirk an alien slit on her normally benevolent face. "For whatever reason, you do. Your knights had plenty of opportunities to kill me, and by all accounts they [i]should[/i] have when I'm the strongest theurge in the room. And yet all they could manage—all they [i]chose[/i] to manage—are mere glancing blows and surface wounds. I wonder why that is?"

Sister's growl is low and sharp, though if you didn't know better you'd think she's eyeing the saintess with a grudging sort of respect. "Put the knife away, Saintess. Or else…"

"What, you'll kill me?" the saintess laughs at the implied threat, the sound high and clear as a bell. "It seems the ball is in my court now, Altinier, so you will do as I say," she says, pointing at you with her free hand. "You will let ${them} go—you will let them [i]all[/i] go, or I will see to it that whatever you seek to accomplish here is foiled."

"How noble of you," Sister hisses. "But where's the guarantee that you won't just off yourself the moment they're out of sight, hm?"

"An oath, then. Under the name of Jove, I swear it: let them go, and I will bring no harm onto myself while in your custody."

Sister licks her teeth as she considers the offer, contempt palpable on her features—and then around her the arcane wall falls like a curtain, inky-black mana dissipating into air. 

"Go," she spits at you. "Before I change my mind."

*page_break

You writhe in pain as Leon hoists you up, shooting a sorrowful look at the saintess as he does. You imagine his pride must be wounded, to willingly leave Param's holiest woman in the clutches of the enemy. Yet the prince has an army to lead and a brother to avenge, the sort of thankless work that demands one to sacrifice the unsacrificable. So he swallows what reservations he has, eyes firmly affixed on the horizon as he marches resolutely to the gate.

"Saintess, we can't," Ilya sobs, the healer battered and bruised as she clings onto her mentor's robes. "We can't leave you behind."

"And yet you must. There is hope yet for this kingdom, and you must live to bear it." The saintess turns to Ilya, smiling benevolently. "Go, Ilya. I'll be waiting for the day you come back for me."

The healer's lips quiver as she tears her gaze away. "We will, Saintess. I swear it."

The world spins and blurs at the sight, and you can feel the distinct sensation of your consciousness slowly slipping away from you. As the party departs into the night you steal one last glance at the saintess, lonely and steadfast as the Salantir closes in around her.

And if you recognize the ghost of a quiver in her warm, serene smile—well. You say aught of it to anyone.

*page_break Darkness takes you.
*achieve escapesienan

…

*page_break

[i]It takes far too long for you to convince Eli to show you ${ehis} wounds.[/i]

[i]"It doesn't hurt," the older[/i]
*if (geli = "male")
    [i]boy[/i]
*else
    [i]girl[/i]
[i]says, even as ${ehe} heaves, even as ${ehe} grits his teeth.[/i]

[i]The angry red gash on Eli's abdomen seemed to simmer as it peers at you from the gaps between ${ehis} fingers. You could still recall the manic look in Sister's eyes as her spell seared against ${ehis} skin, bright orange and deadly. You carry injuries from the encounter, as well, but it is the sting of her betrayal that pains you the most.[/i]

[i]The older pushes your hand away, refusing what little drops of potion you have left to offer. "Save it, ${fname}. I won't make it out of here either way."[/i]
*choice
    #$!{ehe} doesn't know that. I administer the potion, even against ${ehis} will.
        *set noble %+ 15
        *set prenoble %+ 15
        [i]You level a glare on Eli, severe, a threat already at the tip of your tongue.[/i]

        [i]"Alright," ${ehe} yields, before you can say it. "But you'll regret this."[/i]

        [i]"I'd regret it more if I just sat here and watch you bleed to death."[/i]

        [i]Eli sighs in disapproval, but obediently removes ${ehis} hand from the wound. The poultice's green-grey drops sizzle against ${ehis} raw skin, and the[/i]
        *if (geli = "male")
            [i]boy[/i]
        *else
            [i]girl[/i]
        [i]winces as the injury closes upon itself.[/i]

        [i]You allow yourself to feel relief as some of the color returns to Eli's face. Much of ${ehis} injuries are internal, and far beyond what a simple potion could fix, but at least this way you've stemmed the bulk of ${ehis} bleeding.[/i]
    #I refrain. $!{ehe} has the right of it, whether I like it or not.
        *set noble %- 15
        *set prenoble %- 15
        [i]You cork the vial back and stash it in the folds of your cloak. "Good," ${ehe} says approvingly. "It's a long way to Param, especially with her on your heels. Use it wisely."[/i]

        [i]"I will, Eli. I'll make sure to survive—for both of us."[/i]

        [i]The older[/i]
        *if (geli = "male")
            [i]boy[/i]
        *else
            [i]girl[/i]
        [i]inclines ${ehis} head, content, and leans back against the dilapidated brick wall. Blood gushes freely still from the cavity in ${ehis} stomach.[/i]

        [i]You avert your gaze.[/i]
    #I break into tears. The mere thought of losing ${ehim} causes me immeasurable despair.
        *set emotional %+ 15
        *set preemotional %+ 15
        [i]"How could you say that?" you sniff. "How could you just give up?"[/i]
        
        [i]Eli has the grace to look chastened. "I'm sorry, ${fname}. I would never leave you, if it were up to me. I'm just—I'm just looking out for you."[/i]
        
        [i]"Then stay with me," you say, holding ${ehis} gaze in your own. "Don't you dare give up without a fight."[/i]
        
        [i]Eli furrows ${ehis} brows, but obediently removes ${ehis} hand from the wound. The poultice's green-grey drops sizzle as you administer it against ${ehis} skin. The older @{evar boy|girl} winces as the injury closes upon itself.[/i]
        
        [i]You allow yourself to feel relief as some of the color returns to Eli's face. Much of ${ehis} injuries are internal, and far beyond what a simple potion could fix, but at least this way you've stemmed the bulk of ${ehis} bleeding.[/i]
*page_break
[i]"I can't believe she would do this," you whimper. Sister had always been strange and enigmatic, but the look in her eyes as she chased you down was downright inhuman.[/i]

[i]"She's good," Eli concedes solemnly. "She played all of us like puppets. We were lucky to find out at all."[/i]

[i]"You think she'll be able to track us all the way here?"[/i]

[i]Eli nods grimly. "She has the spymaster under her thrall. Can't rest easy until we cross the border...we need to move fast."[/i]

[i]You sigh, burying your face in your palms. There is wisdom in what ${ehe} says, of course, but the both of you are barely able to function as is. The miles-long journey will have to wait for a day at least, lest you collapse altogether on the high road.[/i]

[i]Before you can say anything, Eli raises a finger to ${ehis} lips, signaling for your silence. [/i]Did you hear that?[i] ${ehe} mouths, eyes wary as they scan the vicinity. You follow suit, and indeed something feels oddly amiss—though what it is, precisely, evades you still. Anxiety grips you once more, and around you the darkness looms like a gaping maw.[/i]

[i]A beat, a breath, and then someone whispers behind you.[/i]

*page_break [i]"I've found you."[/i]
[i]Pain erupts on your shoulder as Sister's long, fiery talons pierce flesh and bone alike, engulfing them in bright orange flames. You are propelled forwards by the spell's impact, feeling a rib fracture as you crash against a stone palisade.[/i]

[i]In a second Eli is on ${ehis} feet, casting furiously, and ${ehe} completes the spell even as a Fist of the Dark Lord sends ${ehim} reeling not five seconds later. The very air near Sister begins to shimmer like starlight, and in an instant the particles expand into a solid-light construct corralling her inside.[/i]

[i]Sister is laughing and clapping even as the barrier closes around her. "Well done, little Eli," she says airily. "You've grown so much while I wasn't looking! You'll make for a splendid tool."[/i]

[i]Eli spits blood out of ${ehis} mouth, ${ehis} expression one of palpable disdain. "You're being arrogant," the @{evar boy|girl} accuses quietly, though
${ehis} split lip slurs the words. "Not even you can break through my barrier, witch."[/i]

[i]Sister's grin all but splits her face in two. "You're right, of course. Unfortunately for you, I don't need to."[/i]
*page_break [i]"Come out now!"[/i]
[i]Behind you, around you, cloaked figures spill out from the dilapidated city's shadows. Most of them are all-too-familiar faces—palace guards and royal mages, once warm and friendly, now dead-eyed and listless.[/i]

[i]You and Eli stare at the figures in open horror, and Sister drinks in your despair like nectar. "You should've just sat there with the wool in your eyes while I was still being nice. Now look how you've forced my hand!"[/i]
*choice
    #I need to stop this. Just swear my fealty to her, at least for now.
        *set noble %- 15
        *set prenoble %- 15
        *set intrigue %+ 10
        [i]"Stop it, Sister. We surrender."[/i]

        [i]Two pairs of eyes regard you with surprise. "${fname}?" Eli asks, low and horrified.[/i]

        [i]"It's over, Eli. One way or another, we'll have to do as she bids. I'd rather not be brain-dead, in that case."[/i]

        [i]Sister grins at the concession, all teeth. "What a novel idea, dear. I'm glad you've come to see things my way," she drawls. "Unfortunately for you, I've learned my lesson. I don't need a sword that can turn on its master. Now come and be my good little puppet!"[/i]

        [i]"Sister, wait—"[/i]

        [i]"I'll have none of that!"[/i]

        [i]She raises an authoritative hand, and all around you her thralls stand at attention. "Bring me my[/i]
        *if (gender = "male") and (geli = "male")
            [i]brothers!"[/i]
        *elseif (gender = "female") and (geli = "female")
            [i]sisters!"[/i]
        *else
            [i]siblings!"[/i]
    #I'll never submit to this evil. Make a stand, be it my last or otherwise.
        *set noble %+ 15
        *set prenoble %+ 15
        *set charisma %+ 10
        [i]"You'll never take us alive, scum."[/i]

        [i]"Such harsh language you're using with your sister!" she says, covering her mouth in mock offense. "But never fear, dear [/i]
        *if (gender = "male")
            [i]brother.[/i]
        *elseif (gender = "female")
            [i]sister.[/i]
        *else
            [i]child.[/i]
        [i]I'll beat some manners into you yet!"[/i]

        [i]"Do your worst, witch!"[/i]

        [i]Sister grins at the taunt, all teeth. "Careful what you wish for," she laughs, and with a wave of her hand all her thralls stand at attention. "Bring me my[/i]
        *if (gender = "male") and (geli = "male")
            [i]brothers!"[/i]
        *elseif (gender = "female") and (geli = "female")
            [i]sisters!"[/i]
        *else
            [i]siblings!"[/i]
*label commands
*page_break [i]They rush forward.[/i]
[i]All around you, blades and arrows and magefire sail through the air, and it is only through sheer dumb luck that you come out of the first assault relatively intact. But as an arrow grazes past your nape and your blood sings with fight-or-flight response, you feel the seals on your skin flickering to life and coming undone.[/i]

[i]"Get it under control, ${fname}," Eli growls, quiet and dark. "You're not ready! It'll kill you!"[/i]

[i]"Then I'll at least take her with me!"[/i]

[i]"No," ${ehe} says, brown eyes shining with resolve. "I will."[/i]

[i]With mana ${ehe} shouldn't have been able to muster, a massive magic circle forms underneath Eli's feet. The runes on ${ehis} body flare to life, white-hot markings blossoming on ${ehis} shoulders, ${ehis} neck, all over ${ehis} limbs, and the air trembles under the weight of ${ehis} magical power.[/i]

[i]"Go, ${fname}," ${ehe} says, fingers working feverishly on ${ehis} strongest spell, the one that will cost ${ehim} ${ehis} life. "Survive!"[/i]

[i]As if ensorcelled by ${ehis} words, your body launches itself into a hasty retreat before your mind could acquiesce.[/i]
*page_break
[i]"NO! $!!{fname} IS MINE!"[/i]

[i]Sister yells furiously as she casts in a panicked frenzy, the darkened tendrils of her spells lashing out to grab and constrain you. But Eli's barrier holds strong in spite of her fury, and her spells slam flat against the wall of solid light before they could find purchase.[/i]

[i]"Get ${them}! You useless things, get ${them} right now!"[/i]

[i]The bewitched warriors all but trip over themselves in their haste to obey their master and capture you. With adrenaline coursing through your veins, you pour every last bit of mana in your reserves to your fingertips and cast...[/i]
*choice
  #Clay Cannon, as many times as you can.
    *set alchemy %+ 10
    *set claycannon true
    *set acounter +1
    [i]Earthen projectiles[/i]
    *goto slamagainst
  #Glyph of Subjugation, as many times as you can.
    *set enchantment %+ 10
    *set glyphofsubjugation true
    *set ecounter +1
    [i]As you override Sister's control over your pursuers, they throw themselves bodily back to whence they came. As the enchantment fades and takes the last of your mana with it, you see their bodies bowed over and corraled around their master. You feel quite like dropping to the ground yourself.[/i]
    *goto sisterpunch
  #Morana's Wail, as many times as you can.
    *set thaum %+ 10
    *set moranaswail true
    *set tcounter +1
    [i]The frozen pillars[/i] 
    *goto slamagainst
  #Fist of the Dark Lord, as many times as you can.
    *set spiritism %+ 10
    *set fistofthedarklord true
    *set scounter +1
    [i]The dark, gargantuan fists[/i] 
    *goto slamagainst
*label slamagainst
[i]slam against your pursuers in rapid succession, and against the spell's impact they are pushed back to whence they came. When the dust clears, their bodies are bowed over and corraled around their master—and you feel quite like dropping to the ground yourself.[/i]
*label sisterpunch

[i]Sister is cursing and yelling at Eli as you run, fingertips bloody where she tried to scratch against the barriers. The brunette ignores her, looking instead towards you as the spell circle completes itself and takes ${ehis} life as tribute.[/i]

[i]You can identify the exact moment the light leaves ${ehis} eyes.[/i]

[i]The last thing you see as you retreat is Eli's slack body suspended in midair, disintegrating as ${ehe} bursts into radiant, resplendent light.[/i]

*page_break
You awaken with a sudden jolt, bolting upright as the felt roof and latticed poles around you come into focus. At once Ilya is upon you, her eyes deep-set with exhaustion, and with a feverish zeal the healer mumbles theurgy in the ancient tongue. The effect is instantaneous: relief washes over your body like a gentle wave, and what remains of the searing, throbbing pain you had felt that day quietly settles into a pulsing ache.

"You're awake. Thank Jove, you're awake." Ilya breathes in shudders, the hoarseness in her voice speaking of persistent tears. "You've been in and out of consciousness for days. We—we feared the worst, ${fname}. Here, can you stand up?"

You find that you can, with a little support from Ilya. She demands that you turn back in and get properly rested, but your mind is buzzing with knowledge, answers that are sure to turn the tide of Param's fate. You rather mislike the feeling of sitting on it, now more than ever.

"After I see Leon," you insist. "There's too much to say, Ilya."

The healer holds your gaze for a moment, as if daring you to cross her. But before long she heaves a longsuffering sigh, and relents as she guides you to the rest of the camp.
*page_break
You follow Ilya into the war tent, and immediately you're greeted by the sight of the harrowed princes, eyes red and figures slack as they lean back against their chairs.

They have never looked worse, even in the White Fangs' worst days.

Saine is the first to notice your entrance, and he all but reanimates.

"${fname}!" He immediately jumps up from his seat, wrapping you up in a tight but careful hug. His tears run wet against your tunic. "We—we were so scared, and—" he stops mid-sentence to look up at you, glassy green eyes holding your gaze as if you could fade away at any moment. "I don't know what we would've done if we'd lost you, too."

"Thank Jove we didn't," Leon says, his voice hoarse. The older prince's armor lies in a pile around his feet, his bare chest bloody even through the copious bandages they've wrapped him in. "I'm really glad to see you're awake." He gets up and gingerly joins the hug. "Finally, some good news for once."

"Touching display, but that's enough of that," Ilya huffs from beside you. "You're all still recovering, alright? If you rip a suture from all this 
*if gender = "male"
  bromance,
*else
  affection,
I am [i]not[/i] doing them again."

Saine is the first to let go. "Yes, ma'am," he mutters obediently, wiping at his tears.

"Bossy," Leon complains under his breath as he removes his arm, loud enough for everyone to hear. Ilya pointedly ignores him.

"Anyway, ${fname} is here for more than just a reunion. There's important information ${they} @{plural wish|wishes} to share."

Leon nods sagely. "I figured that might be the case. You obviously knew each other...if you know anything that could shed some light on the invasion, ${fname}, please tell us."

"I will, of course. Where should we begin?"
*temp q1 0
*temp q2 0
*temp q3 0
*temp q4 0
*temp q5 0
*label expohubb
*choice
  *selectable_if (q1 = 0) #"Who was it that murdered my brother?"
    *set q1 1
    "Mireil Altinier," you say. There is a heaviness in your throat as the name makes its way up; you had hoped to never say it again, though of course that was rather naive of you. "She is the last remaining member of House Altinier, a former marquess house in the Grand Duchy of Salantira."

    Ilya's eyes glint with recognition. "Altinier...you don't mean the House of Scholars?"

    "You've heard of it," you say, mildly surprised. Official Salantir history records the noble house as having perished two generations ago—it's a surprise anyone remembers it at all, let alone a Parami mage. "That's what they were called, before they met their supposed end."

    "Supposed," Saine repeats, slowly.

    You nod. "In truth, the last Marquess Altinier had a son he kept away from the public eye—Thaubal Altinier. He was said to be the greatest talent the House ever produced, and that was why his identity was hidden. Being distracted with noble duties would be a waste of his abundant gifts." You pause, pushing away the unpleasant memories you have of the man. "Or so he would tell us."

    "So you've met him."

    "Yes. He is Mireil's father—and for a time, mine as well."
    *goto expohubb
  *selectable_if (q2 = 0) #"Are you related to her?"
    *set q2 1
    "Not by blood, if that's what you're asking. But I considered her my sister, once."

    "Your sister," Leon repeats, carefully neutral. "If you're not blood siblings, where did the two of you meet?"

    "In Thaubal Altinier's laboratory," you recount, closing your eyes. "Though I would sooner call it a slaughterhouse. He did...unspeakable things there. Experiments, he would call them, molding our bodies into vessels for some ancient lost magic. It was pure torture. Most of us couldn't take it. There were thirty of us kidnapped children, in the beginning..."

    Saine gulps. "And?"

    "Only three made it back out," you admit, willfully ignoring your companion's horrified stares. "One of us passed away too, a while—" You pause, breath catching in your throat as Eli's glazed eyes flash in your mind—curse these dreams, but they are so vivid. Your friends wait patiently for you to regain your bearings, Ilya's hands hesitant as they reach for your own.
    
    "I'm sorry," you manage, shaking Eli out of your head. "So now it's just me and Sis—Mireil."

    A long silence hung over the room. "${fname}..." Ilya finally says, voice wavering. Her knuckles are white where she's gripping her skirt. "I'm sorry you had to go through that."

    You look away. "I am, too."
    *goto expohubb
  *selectable_if (q3 = 0) #"Why did she invade Sienan?"
    *set q3 1
    "My guess is as good as yours," you admit. "She was always the ambitious type...perhaps she wasn't content with just ruling over Salantira."

    Leon grits his teeth at that. "Then all of this...destruction and murder...just to stroke her ego?"

    "It's a common fuel for war, regrettably," Ilya says, eyes downcast. "Param has seen peace for a long time, but there has always been undeniable tensions between us and the Salantir. We were complacent with the Grand Duchy."
    *if (learning > 50)
      *set rIlya %+ 10

      "In any case, they won't stop at anything short of full conquest," you add. "If they had a smaller goal, they would've made a diplomatic demand of it prior to going to war."

      Ilya looks at you approvingly. "Given the scale of the invasion, I'm inclined to agree."
      *goto expohubb
    *else
      *goto expohubb
  *selectable_if (q4 = 0) #"Why does she command the Salantir army?"
    *set q4 1
    "Because she commands the Salantir Grand Duke."

    "What do you mean?"

    "Just what I said. Grand Duke Ystalvius obeys her every word—he's been her thrall for the past four, maybe five years. Most of the high court, as well."

    "That's insane," Leon says. "How...how did she manage to do something like that?"

    "It was the ducal troops that freed us from Thaubal's laboratory. The Grand Duke took us in, after that—I believe he was an acquaintance of my mother. From that proximity it didn't take much for Mir to take over."

    Ilya leans forward. "How so? Don't tell me she used Glyphs of Subjugation on the entire court?"

    You shake your head. No matter how powerful Mir is, a feat like that would completely drain her of mana in a matter of hours. "No. She used Palmerra—a brainwashing drug," you say. "The formula is thought to be lost when Arcadia fell, but Thaubal somehow had a copy in his laboratory. And Mir...she's a gifted alchemist."

    The prince purses his lips as he looks away. "Why...why did you keep this to yourself?" Leon asks, and if you didn't know better you'd think that was an edge of hostility to his tone. "If you'd told someone—"

    "Then they'd have me sent to the madhouse," you counter. "And at any rate, I thought she'd be happy with her little throne in Salantira. I wouldn't have seen this invasion coming, either way."

    Leon finds sudden interest in his shoes. "You're right, of course. Sorry, I—it's been a tough few days."

    You nod, carefully neutral.
    *goto expohubb
  *selectable_if (q5 = 0) #"What was that magic she used at the keep?"
    *set q5 1
    *set codexarcana true
    "The fruits of Thaubal Altinier's labor: extinct, powerful magic from a lost civilization," you recite. Thaubal had drilled the knowledge into you, back then, proud and sneering. "Arcana is what we call the magic. The civilization, you know of as Arcadia."

    All three receive the news with resignation. Ilya is the first to speak. "The Sorcerium…I had thought that might be the case."

    "The old Parami kings ordered a complete purge of their magical knowledge, but evidently some slipped through the cracks," you explain. "The arcana Mir uses allows her to manipulate the fabric of space, as you've witnessed."

    The healer purses her lips, carefully mulling over your words. "This is just a guess, but...your sudden increase in power, back in the keep...?"

    You nod in the affirmative. "That was arcana, too. A different type."

    "So you've had something like this up your sleeve all along?"

    "Yes, but you've seen for yourself the risks it carries," you say, subconsciously trailing your fingers across your damaged seals. "It's a compatibility issue, I think. I can't control it for long, and after each usage I'd be spent and at the brink of death. That's why the Grand Duchy put these seals on me, all those years ago," you say, gesturing to the faded markings along your arms.

    "So you risked your life to save ours," Leon says, not meeting your gaze. You answer him with silence.
    *goto expohubb
  #"That was all I wanted to ask. Thank you."
    "Of course," you breathe. The interview had dredged up many unpleasant memories from your dark past, and the experience left you a bit winded. Regardless, there's still much to be done. "What will you do now?"

    "We fight, of course," Leon says, without the slightest bit of hesitation. The deadly anger in his tone is well-hidden, you note. "Our tacticians recommended diplomacy with the Salantir royals, but your information changes things." You can't help but notice that he looks just the slightest bit [i]relieved[/i] that Param and Salantira will come to blows. "Call them back in, Saine. We must discuss a new approach."

    "Then we'll excuse ourselves as well," Ilya says, a hand on your forearm. "${fname} still needs more bedrest."

    The three of you exit the tent together, willfully ignoring the furious set of Leon's jaw and the dangerous, dark look in his eyes.
    *goto newcourse
*label newcourse
*page_break
The new course of action is announced at dawn the next day. The surviving Parami soldiers gather around a small hill just outside of camp as Leon makes the announcement. Despite the sun still hiding behind the eastern mountains, despite the sleep still clinging to their eyes, every last man is alert and attentive, hanging on to the prince's every word.

The scouts' report is relaid first—many cities near the Salantir border had been successfully conquered, falling victim to the unexpected invasion. Calinger was the most recent city to be taken, though by all accounts the militia made the invaders bleed for every inch of land they took.

"We will honor their sacrifice," Leon says of them, determined. His voice thunders with an undercurrent of rage, and the knights stood rapt as they nod their agreement. "We shall free their great city, in due time. We will regroup first at Kantena, and rally the whole of Param to war. The blood of warriors run through our veins! We shall wash these invaders out of Param, and make them regret the day they were born!"

You picture the friendly, kind-hearted adventurer you met on the road to Calinger—his image seems to melt away in the face of this vengeful commander. But there's no denying his charisma is effective—the knights' backs stood a little straighter as they cheer their approval, the fury of their prince mimicked in their own countenance.
*page_break
"Upon the name of Julius, I swear it," Leon proclaims, in the end, and not even the carnage muddying his face could distract from the vindictive glint in his eyes. "They will live to regret this. For Param!"

Like a beacon, like an oath, the banner is raised and greeted with riotous cheers. Less than two hundred men are stood upon the knoll, bruised and beaten; but what is lacked in number—and indeed, odds of victory—they made up for in sheer conviction.

Dawn breaks over the distant mountains, marking the start of a new day, and an unshakable feeling in your chest tells you that this is also the start of a new era.
*page_break
News of the invasion spread like wildfire across the realm, as did the call of the vengeful prince whose brother hung upon the royal gates. Any strategist of some mettle would deem their cause hopeless, that Salantira had the Kingdom soundly beaten, and scoff at the fledgling prince leading a suicide charge.

And yet the rebellion rages onward and liberates city after city in a series of military miracles, and a trail of freedom blazes through the conquered kingdom. As the prince's militia outmaneuvers the Salantir at every turn, the broken and mourning people of the land find their hearts igniting with a righteous fire—one they thought had died alongside their king on the palace floor. The prince's call to arms resonate in their blood and boils it anew, and they flock like birds to his defiant banner.
*page_break
In the fertile south, in a hundred different holdings, the Old Nobles honor their treaties and raise their levies in droves. Ancestral armor donned and war steeds ridden, they ride north in neat, perfect columns, proud standards billowing like waves in the buoyant wind.

In the far north, from snow-laden fortresses and castles nestled between ancient pines, archers and mages in icy-white armor brave the biting cold journey through the Yerefan mountains. Decades of hunting have kept their aim true and form hardy as they point their weapons south against the rise of a new enemy.

In the eastern lands' scattered hamlets, daughters cry into the folds of their mother's skirts as fathers prepare for the long journey ahead. Goodbyes said and promises made, one by one they leave their homesteads and march west, makeshift blades raised in honor of their dead, kindly king.

The rebellion descends upon the land like a mighty wave, and one by one the unwitting invaders, caught off-guard by a united Param, are washed out from its cities in a tide of blood. The kingdom's morale skyrockets with each victory, and by the campaign's second year no one dares doubt the prowess of the newly-christened Sun Prince and his heroic band of freedom fighters.
*page_break
*achieve rebel
It is on the dawn of the war's third year that Leon finally raises his banner over Calinger, liberating the Parami east from Salantir occupation once and for all. Thunderous cheers explode from the crowd below as he raises his sword atop the battlement, the rest of the White Fangs alert and immovable around him as he completes his address.

"Wait for me, Julius," he murmurs grimly at the end of it all, quiet enough that only you can hear him. He turns his gaze toward the western horizon, towards Sienan—the last stronghold of the Salantir invasion. "I swear it to you. For what they've done...I'll make them pay in blood."
*page_break
*set memorypoint "complete_sienan"
*goto_scene Junction