*comment game
In the Old Cathedral, the saintess raises a chalice at the altar as the congregation weeps for the Hero of Sienan. What is the name gracing their lips?
*input_text fname
*set nameset true

In a small town in the Parami east, the innkeep's lips tremble as she plants flowers around a pair of graves. Whose names are etched onto the headstones?
*choice
    #The innkeep's two sons.
        *set they "he"
        *set their "his"
        *set them "him"
        *set themselves "himself"
        *set theirs "his"
        *set pronvar 1
        *set plural false
        *set gender "male"
    #A daughter, and a son.
        *set they "she"
        *set their "her"
        *set them "her"
        *set themselves "herself"
        *set theirs "hers"
        *set pronvar 2
        *set plural false
        *set gender "female"
    #A son, and someone who eschewed such labels.
        *set they "they"
        *set their "their"
        *set them "them"
        *set themselves "themselves"
        *set theirs "theirs"
        *set pronvar 3
        *set plural true
        *set gender "nonbinary"

*set genderset true

In a city to the far west, Saint Augur's blade is raised for the knighting of a new paladin. Whose name is ordained by the Commander?
*choice
    #Elias Revelois.
        *set geli "male"
        *set elias "Elias"
        *set ehe "he"
        *set ehim "him"
        *set ehis "his"
        *set etheirs "his"
        *set ehes "he's"
        *set evar 1
    #Eliana Revelois.
        *set geli "female"
        *set elias "Eliana"
        *set ehe "she"
        *set ehim "her"
        *set ehis "her"
        *set etheirs "hers"
        *set ehes "she's"
        *set evar 2

The traitor is fastened upon the stake, ${their} form slack as ${their} breath is taken from ${them}. But away from the frenzied jeers of the savage crowd, away from the harrowed gaze of the Sun King himself, in the depths of ${their} waning mind—${they} @{plural are|is} swimming in a dark, vast ocean of memories.

One last fragment appears in your ${their} field of vision, gleaming like a star in the dark expanse. $!{they} @{plural peer|peers} into its depths, swaying and hypnotic, and before long ${they} @{plural are|is} swallowed by its blinding light.

*page_break

"I am bored out of my mind."

Sister pushes herself off the desk as she makes the declaration, twirling a small flask between her fingers. The liquid inside sloshes against the smooth glass surface, its color a beautiful, glittering blue—the telltale sign of a perfectly brewed heim antivenom. You note the slight viscosity to the solution, how it remains inert for a moment before sliding around its glass haven—and wonder what sort of witchcraft Sister engaged in to achieve such an effect.

You bite your lip and turn your gaze downward, drinking in the sight of your own miserly concoction. You had followed the instructions to the letter, this time around, brought out the big cast-iron cauldron and carefully measured the ingredients. And still your potion had become a perfect mimicry of bile, the smell of it so putrid that kind, considerate Eli had silently pressed ${ehis} nose up against ${ehis} shirt.

*choice
    #I make no secret of my frustration. It was supposed to turn out great!
        "I don't understand," you fume through gritted teeth. You cast a scrutinizing gaze towards the spell lines you've carved onto the base of the cauldron, trying to find the culprit of a seal that had corrupted your potion. "I made sure to do everything correctly this time."
        
        "I'm sure you did," Sister cajoles, tapping a finger against her chin. "But sometimes things don't quite turn out how we hoped they would. As for your concoction…would you like a hint, perhaps?"
        *goto hint
    #I go over my spell circles once more. I have to figure out where things went wrong.
        Sister watches silently as you squint at the spell lines you've carved onto the base of the cauldron, trying to find the stray seal or two that had resulted in the corrupted batch. When you don't find it, she taps a finger against her chin and leans back against her desk. "Would you like a hint, little @{pronvar brother|sister|one}?"
        *label hint
        *choice
            #No way. I have to figure this one out myself, or I'll never grow as an alchemist.
                You tell Sister as much, and the older girl's lips quirk into a wry smile. "You always were the determined sort," she sighs. "But spending your whole afternoon poking at faulty runes is hardly productive."
                
                "It'll only take me a couple of minutes," you insist.
                
                "Very well, have it your way," Sister concedes. "I suppose I'll just be over here, doing absolutely nothing. What a joy that tutor has been. 'This will be the most challenging task I have given you yet, and so you must exert your full focus'…the gall that he has, to think so highly of himself when he is barely a mage himself!"
                
                "I don't know, Sister," Eli quips from the other side of the room. The liquid pooling in ${ehis} cauldron is a stark, viscous blue—far from perfect, but a definite improvement over your own. "I find this potion to be quite troublesome."
                
                "Of course you would, with how the blasted man has been instructing you," she seethes.
                
                "He was appointed by the Grand Duke himself, Sister," Eli replies in turn. "And for what it's worth, I found his instruction useful."
            #Viscount Sophein wouldn't approve of that, but he's not here right now. I allow Sister to help.
                Sister's smile is smug, cat-like. "You've mistaken the Third Lock of Flames for the Line of Heaven," she explains. "Your spell circle draws out the toxins from the yuretain leaves, but the missing Line of Heaven means that they do not get purified before the second transmutation. Are you following?"
                
                You gaze intently at the runework Sister had mentioned, and can't help but to seethe at your own mistake. It was as elementary a mistake as they come, a similarity discussed in the very first chapter of Old Saarta's Compendium. You should be well past the point of making a mistake like this—that it had stumped you for an hour to boot is a greater humiliation than you can describe.
                
                "There, there," Sister consoles, taking note of the dark look crossing your features. "I'm sure you would have been able to get it right, had that tutor of ours performed his job correctly. The gall that he has, to think so highly of himself when he is barely a mage himself!"
                
                "He was appointed by the Grand Duke himself, Sister," Eli offers from the other side of the room. The @{evar boy|girl} is working on ${ehis} own potion as ${ehe} says this, the liquid a stark, viscous blue—far from perfect, but a definite improvement over your own. "And for what it's worth, I found his instruction useful."
    #You know what? I give up. Alchemy will just never be my strong suit.
        Sister turns to you when she hears your resigned sigh, her smile catlike as you drop your ladle into the cauldron in surrender. "Given up already, have we?"
        
        "There is no saving this concoction," you mutter dryly. "If it will land me a failing mark either way, I'd rather not spend any more time on it than is strictly necessary."
        
        "I respect your efficiency," Sister says. "You will have to retake this examination, however, so listen well: you've mistaken the Third Lock of Flames for the Line of Heaven."
        
        You suppress a frustrated grunt. "I had an inkling it was going to be something like that."
        
        "Did you? Then I suppose you can figure out how to construct the correct circle next time. Without the Line of Heaven, the yuretain toxins won't have been purified before the second transmutation. That will be the culprit behind your potion's…corruption."
        
        "I see," you sigh. "I'll keep this in mind next time."
        
        "And that's the most important thing, little @{pronvar brother|sister|one}. Magic is a field just like any other—we make mistakes, we learn from them, and we move forward," Sister says sagely. "Now if only that tutor of ours could share this philosophy…but he is well past the point of help, I think. The gall that he has, to think so highly of himself when he is barely a mage himself!"
        
        "He was appointed by the Grand Duke himself, Sister," Eli offers from the other side of the room. The @{evar boy|girl} is working on ${ehis} own potion as ${ehe} says this, the liquid a stark, viscous blue—far from perfect, but a definite improvement over your own. "And for what it's worth, I found his instruction useful."
        
"I'm afraid it is worth nothing at all, Eli," Sister says judiciously. "You have a high opinion of absolutely everyone."
        
Eli replies with a thin-lipped smile, unable to contradict the older mage. "But there's no denying that my alchemy has been improving under his tutelage," ${ehe} offers.
        
"Yes, of course, but at what cost?" Sister refutes, casting a forlorn gaze about the room. "He has us locked up in a study for days, practicing a concoction he had never bothered to properly teach. All the while he attaches himself to the Grand Duke's coattails, citing our 'remarkable progress!' as his success rather than ours." Sister shakes her head, scoffing derisively. "Any baseborn mage could have done a better job than him. And I've about had it with being cooped up in here."
        
*choice
    #"I agree. This is not much of an improvement over Thaubal's laboratory."
        Eli whirls on you, startled to an almost comical degree, while Sister lets out a peal of hearty laughter. "Yes, the parallels are hard to ignore, aren't they? That we have been kept somewhere out of the way, to be polished into a magical tool of destruction. At least Thaubal hadn't been so roundabout in his methods…"
        
        "I'd rather you not joke about that," Eli says under ${ehis} breath, though ${ehe} seems disinclined from pressing the issue.
        
        "Of course, dear," Sister says airily. "In any case, I refuse to be held here another second."
        
        Sister pushes herself off the desk she had been leaning on, goes towards the corner of the room and presses her palms against the walls. A swell of mana begins to thicken in the air, viscid and leaden with a strange, foreign energy, and both you and Eli bodily jerk backwards out of sheer instinct.
        *goto comenow
    #"And what will you do about it, aside from complaining to the choir?"
        A small, mischievous smile slowly spreads across Sister's face. "Why, ${fname}, I'm glad you asked."
        
        Sister pushes herself off the desk she had been leaning on, goes towards the corner of the room and presses her palms against the walls. A swell of mana begins to thicken in the air, viscid and leaden with a strange and foreign energy, and both you and Eli bodily jerk backwards out of sheer instinct.
        *goto comenow
    #"Well, it's not like we have any choice in the matter."
        A small, mischievous smile slowly spreads across Sister's face. "Is that what you think, ${fname}?"
        
        You quirk an eyebrow at her. "There are guards stationed all the way down this hallway. Surely you don't think we can simply maneuver our way out without their notice?"
        
        "Who said anything about hallways? ${fname}, you really must learn to think outside the box."
        
        Having said these words, Sister pushes herself off the desk she had been leaning on and goes towards the corner of the room. As she presses her palms against the walls, there is a swell of mana that begins to thicken in the air, viscid and leaden with a strange, foreign energy, and the weight of it forces you and Eli to jerk backwards out of sheer instinct.
        *goto comenow

*label comenow

"Come now," Sister sighs, her voice laced with mock disappointment. In front of her the spell has come full circle, manifesting in the form of a cavity in the walls, pulsing and rippling with her violent mana. "Is such an overblown reaction truly necessary?"

"You're using [i]arcana[/i]," Eli hisses, ${ehis} voice low as if in fear ${ehe} might be heard through the study's stone walls. "I thought we agreed never to touch it again, except in cases of emergency."

"Look at me, Eli," Sister says, tilting her head slightly. "Can you not see that I'm at the edge of madness? One more minute in here and I might blast through these walls and find the viscount myself. We'll see how noble he is when I drag him by the hair, around the courtyard and through the stables, dump him in the muck where he can rot—"
        
Eli takes another step back, ${ehis} horror mounting. "[i]Sister[/i]," ${ehe} hisses.
        
"Don't take me so seriously, Eli," she sighs, flicking strands of black hair over her shoulder. "I may have one or two screws loose, but I'm no murderer."

*temp sistercount 0
*temp portalask false
*temp guardask false
*temp potionask false
*label sisterhub
*choice
    *selectable_if (portalask = false) #"Where does your portal lead, Sister?"
        *set sistercount +1
        *set portalask true
        "Wouldn't you rather be surprised?"
        
        "We're not going anywhere unless you tell us up front," Eli says firmly.
        
        "You never fail to be a bore, Eli," Sister chides. She turns her gaze southward, towards the study's wide, curving windows, and tilts her head up to gaze at the night sky. "Today marks exactly seven days before Rigain's Solstice. To hear the Jovian scriptures tell it, the night sky above Rigain Cliffs will be a sea of falling stars tonight."
        
        Eli's gaze on Sister remains wary, though there is now a spark of intrigue percolating ${ehis} brown eyes. "And you wish to see it for yourself?"
        
        "Precisely," Sister confirms, smiling. "Furthermore, the path to the cliffs is off-limits to visitors at the moment—an unexplained monster infestation, if you could believe it. A good thing for us, however—that means we'd have the view all to ourselves.."
        
        "Wait. Wait a moment," Eli protests, pressing both hands against ${ehis} temple. "You want us to not only disobey the Grand Duke, but tread through monster-infested fields on top of that?"
        
        "The portal will take us to the base of Rigain Cliffs, far beyond the spots marked as dangerous by the knights," Sister says. "Even if we do get attacked, you need only stand still and look pretty. I'm more than capable of handling one or two stray baelhounds."
        *goto sisterhub
    *selectable_if (guardask = false) #"Are you sure that the guards won't come after us?"
        *set sistercount +1
        *set guardask true
        "Why don't you tell me, ${fname}? Do you have reason to believe they would break their routine, after fully neglecting our existence for the past, oh, two weeks or so?"
        
        "…No," you offer quietly. "I suppose they'll stick to their patrol routes, as they've always done."
        
        "Indeed. We will be back in time for breakfast, and that will be their only concern dealt with."
        *goto sisterhub
    *selectable_if (potionask = false) #"And what of the batch of potions we have yet to brew?"
        *set sistercount +1
        *set potionask true
        "Did I not tell you, ${fname}?" Sister asks, a mischievous glint in her eyes. "I've been bored out of my mind."
        
        With a wave of her hand, Sister calls for a small cavity to manifest itself into the air above her. She activates the portal with a flourish of mana, and then slowly but surely a stream of deerskin flasks fall out of the portal and hit the carpet with soft thuds. Eli picks one up from where it had rolled next to ${ehis} feet, and does little to hide ${ehis} surprise once ${ehe}'s peered inside.
        
        "Heim antivenom," Eli remarks, dumbfounded. "Then, are all of these…but when did you—?"
        
        "Trivial matters. I shall tell you during our trip, if you insist on knowing," Sister says. "The point is this: when the good viscount drops by tomorrow and collects the fruits of our labor, he will find that we have excelled past his unreasonable expectations. How could he suspect that we've traipsed our way over to Rigain Cliffs, when we've been the picture of productivity, here in our little study?"
        *goto sisterhub
    #"Very well, Sister. Let's go."
        Sister graces you with an approving look, for a moment, before turning her attention towards Eli. "And what of you, Eli? Will you come with us, or stay here like a good little duckling?"
        
        Eli shifts nervously on the balls of ${ehis} feet, clearly apprehensive of the whole affair. In response, Sister reaches out and grips the healer around the wrist, gives ${ehim} the most reassuring smile she can manage—and she is so convincing that the latter relents with a sigh.
        
        "Very well," ${ehe} concedes. "But we really ought not stay for long."
        
        "We'll be back before you know it," Sister promises, before dipping into a bow and holding out an arm towards the portal. "Well then, my dearest siblings. After you."
        
        *page_break And into the breach you go.

"I knew this was going to happen," Eli mourns, pinching the bridge of ${ehis} nose. Charging towards ${ehim} is a savage beast standing nearly twice ${ehis} height, its glowing red eyes a stark contrast to its luminous black fur. The baelhound roars as it continues its approach, and you can't help but to be unnerved by its full set of saber-like teeth. "I should've never listened to you."

Sister grants ${ehim} a lopsided grin instead of an answer, and reaches for the weapon she's stowed inside her doublet.  A smooth and silvery blade, and you instantly recognize it as the standard-issue sword granted to the ducal knights. She tosses it towards Eli, and the @{evar boy|girl} catches and brandishes it in one swift motion. "Apologies for the little white lie, but you would have never left that dingy old study otherwise," Sister chuckles. "Think of this as an exercise to stretch your muscles. It's been weeks since you've last held a blade, after all."

Eli grunts ${ehis} complaint, but obediently moves forward to meet the baelhound in battle. There is a shrill series of noises pervading the air as the sharp edge of ${ehis} blade clashes against the beast's claws—a courtesy dance to begin the battle as each sizes the other one up. From where you're standing they seem roughly evenly matched, each hit careful and metrical, expertly dealt but easily parried.

But before long the beast breaks away from the rhythm and begins to attack in jerking, irregular lunges, and Eli has to play the defensive lest its venomed claws find purchase on ${ehis} skin. A particularly heavy lunge has the older mage pinned under the beast's descending claws, ${ehis} quivering blade all that stands between ${ehim} and a bloody death. For a moment you fear that the blade might give way and allow the beast's claws to pierce Eli's abdomen, but impressively the older @{evar boy|girl} manages to bring ${ehis} knee up and bash ${ehis} opponent in the jaw, the force of it strong enough to dislodge the beast from ${ehis} weapon.

"Very good, Eli," Sister calls out from where she's standing beside you.

*page_break "Now step aside!"

Sister leaps forward as she says this, quick as lightning, a set of burning talons outstretched from her fingertips. She launches past Eli and digs her claws into the beast's hide; it feels the scorching heat of her attack and rears back in pain, flailing its tail in a bid to dislodge its assailant. Sister squares her shoulder and pushes her claws further, deeper, and between the beast's agonized roars you can hear her words on the wind:

"${fname}, you're up!"

*choice
    #Cast Morana's Wail.
        It is a relatively advanced spell, and one you had not yet fully managed in proper combat before. But all the same you form the runes with intent, allow it to bloom into a spell circle that wavers like light off a pond's surface. A blast of frigid air bursts forth from its depths, then, twists into chunks of solid ice that lurch forward towards the beast at a deadly pace. The baelhound, still locked in combat with Sister, fails to notice the cannonball advance until it has stricken it in the side and forces it over and onto the ground.
        
        "Very impressive," Sister laughs as she looms over the baelhound, having dislodged herself mere moments before impact. No longer needing to worry about a counterattack, she lazily crouches in front of the injured beast's face and trails a talon down its muzzle. Before it could so much as hiss in retaliation, Sister sets her claws to burning once more and, in a single fluid motion, plunges them deep into the beast's eyes.
        
        A weak, desperate roar escapes the beast's maw as Sister forces her talons forward, skull and sinew giving way under force and heat alike. Deeper and deeper her arm goes, until her shoulder has collided with the baelhound's eye socket; as her claws meet with its brain the beast spasms thrice, violently, the force setting the very earth to shaking.
        
        And then with a final, resounding thud, the beast falls into perfect stillness. Sister steps backward to admire her handiwork, dusting her hands off as she nods in satisfaction.
    #Cast Clay Cannon.
        It is a relatively advanced spell, and one you had not yet fully managed in proper combat before. But all the same you form the runes with intent, allow it to bloom into a spell circle that wavers like light off a pond's surface. Alchemic clay floats out of your pockets and meets with the spell circle before it trembles and [i]expands[/i], lurching forward towards the beast at a deadly pace. The baelhound, still locked in combat with Sister, fails to notice the cannonball advance until it has stricken it in the side and forces it over and onto the ground.
        
        "Very impressive," Sister laughs as she looms over the baelhound, having dislodged herself mere moments before impact. No longer needing to worry about a counterattack, she lazily crouches in front of the injured beast's face and trails a talon down its muzzle. Before it could so much as hiss in retaliation, Sister sets her claws to burning once more and, in a single fluid motion, plunges them deep into the beast's eyes.
        
        A weak, desperate roar escapes the beast's maw as Sister forces her talons forward, skull and sinew giving way under force and heat alike. Deeper and deeper her arm goes, until her shoulder has collided with the baelhound's eye socket; as her claws meet with its brain the beast spasms thrice, violently, the force setting the very earth to shaking.
        
        And then with a final, resounding thud, the beast falls into perfect stillness. Sister steps backward to admire her handiwork, dusting her hands off as she ndos in satisfaction.
    #Cast Fist of the Dark Lord.
        It is a relatively advanced spell, and one you had not yet fully managed in proper combat before. But all the same you form the runes with intent, allow it to bloom into a spell circle that wavers like light off a pond's surface. A rapid torrent of pitch-black specters burst forth from tis depths, then, twists into a solid construct of arcane might that lurch towards the beast at a deadly pace. The baelhound, still locked in combat with Sister, fails to notice the cannonball advance until it has stricken it in the side and forces it over and onto the ground.
        
        "Very impressive," Sister laughs as she looms over the baelhound, having dislodged herself mere moments before impact. No longer needing to worry about a counterattack, she lazily crouches in front of the injured beast's face and trails a talon down its muzzle. Before it could so much as hiss in retaliation, Sister sets her claws to burning once more and, in a single fluid motion, plunges them deep into the beast's eyes.
        
        A weak, desperate roar escapes the beast's maw as Sister forces her talons forward, skull and sinew giving way under force and heat alike. Deeper and deeper her arm goes, until her shoulder has collided with the baelhound's eye socket; as her claws meet with its brain the beast spasms thrice, violently, the force setting the very earth to shaking.
        
        And then with a final, resounding thud, the beast falls into perfect stillness. Sister steps backward to admire her handiwork, dusting her hands off as she ndos in satisfaction.
    #Cast Glyph of Subjugation.
        It is a relatively advanced spell, and one you had not yet fully managed in proper combat before. But all the same you form the runes with intent, allow it to bloom into a spell circle that wavers like light off a pond's surface. The Glyph manifests in full, painting streaks of mana against the skin of the raging beast, and shines like a beacon before fading away, taking the beast's freedom with it.
        
        "Very impressive," Sister laughs from where she is embedded upon the baelhound. No longer needing to worry about a counterattack, she slips lazily down the ridge of its withers and backflips over its muzzle; she licks her burning talons once, her smile unfaltering even as they sizzle against her tongue, and plunges them deep into the beast's eyes.
        
        A whimper escapes the beast's frozen jaw as Sister forces her talons forward, skull and sinew giving way under force and heat alike. And then a strange, rain-slick sensation washes over you, before your Glyph is forcefully withdrawn—and you know then that Sister's claws have forced their way into the baelhound's brain, and there is no consciousness left for your spell to hold onto.
        
        The beast falls onto the ground with a loud, resounding thud, and Eli stabs it once more in the heart for good measure. Sister nods in approval as she beholds your combined handiwork.

"Excellent work, you two. I see palace life has done little to dull your senses."

*choice
    #"But why should we care? There hasn't been a war in Arvanand for centuries!"
        "It pays to be prepared for any possible eventualities," Sister replies sweetly.  "There may be strife in our future yet."
        
        *label incredulous
        Eli shoots the older mage an incredulous gaze, even as ${ehe} wipes drops of beast-blood from ${ehis} chin. "What are you getting at?"
        
        "Oh, pay me no mind. I think our time in that little lab has me jumping at shadows," Sister says. "Still, I think it is good that we were able to do this. I daresay this ought not be our last…excursion."
        
        "[i]Sister[/i]."
        
        The older mage laughs derisively, even as she holds her hands up in surrender. "Things would be much easier if you weren't so uptight," she giggles. "A discussion for another time, perhaps. Look—the beast is slain, and the path to our destination is clear. Shall we collect the fruits of our labor?"
        
        Eli lets out a short, exasperated grunt, but eventually jerks ${ehis} chin towards the hill. "After you."
        
        Sister tilts her head in acknowledgment, mischief still carved into the curve of her smile. "With pleasure," she says, pleasant as ever as she skips up the knoll.
        *goto nexttt
    #"I appreciate the exercise. That was the first good challenge I've had in weeks."
        Sister dips into a deep, elaborate bow. "Happy to be of service—and to see that [i]someone[/i] gets it," Sister says. "Eli here could stand to take a page out of your book. It pays to be prepared for any possible eventualities…"
        
        *goto incredulous
    #"You should have told us if this was your plan all along."
        "A little deceit to keep you on your toes," Sister giggles. "But very well, please accept my apologies. It's just…it pays to be prepared for any eventualities. There maybe strife in our future yet."
        
        *goto incredulous
*label nexttt
*page_break

The path up to the cliffs take you through a dark, densely-forested patch of land that looks straight out of an old wives' tale. Sister is fearless as ever as she takes the lead, guided forward only by the dim glow of the fire spell she keeps in her palm. Periodically she would look upwards, behold the thick canopy of leaves that stretch out like a net above her. You and Eli, battle-worn and ready to collect your spoils, would follow suit—only to be disappointed each time, as not a shred of the night sky could be seen beyond the layers of foliage.

"Are we almost there?" Eli asks finally, uncharacteristically irritated. "I don't know if I have the patience to go much farther."

"Patience, Eli. Do not miss the forest for the trees," a cough, a cursory gaze towards the surrounding vegetation. "As it were."

"Very funny. And about the farthest thing from an answer."

"By Jove! And the Grand Duke could [i]not[/i] shut up about how well-mannered you were," Sister says, laughing into her free palm. "Who are you, and what have you done with Eli?"

"Mireil, I swear if you don't—"

"There, there. No need for you to get so riled up—not when we're so close to our destination, see?"

At Sister's command, the spark of fire dancing in her palm slithers deeper into the forest, painting a streak of orange light through the darkness. You and Eli both watch it as it goes, farther and farther away, before bursting into a shower of light that illuminates the surrounding darkness.

You catch a glimpse of what lies ahead, before the light fizzles and fades away: an opening in the treeline, a flat bed of grass, and beyond that—the edge of Rigain Cliffs.

*choice
    #My heart skips a beat in excitement. I'm finally going to see a star shower!
        Sister takes note of your growing smile, and returns it with one of her own. "That's the spirit, ${fname}," she says, before rounding on Eli. "You could stand to be this cute, you know?"
        
        Eli answers the older mage with stony silence, simply jutting ${ehis} chin out towards the cliff.
        
        *label alwayslike
        "You're always like this," Sister scoffs, even as she turns around and walks towards the forest's edge. In the split second after her first step, you feel something warm and calloused slip into the gaps of your fingers—Eli's hand, ${ehis} grip just a hair too tight for comfort.
        
        "Don't follow too closely behind her," ${ehe} says steadily. "She might be up to something."
        
        *choice
            #I let ${ehim} guide me forward.
                There is a yank against your hand as Eli makes ${ehis} way forward, a sort of vigilance that never leaves ${ehis} gaze. "Stay alert," ${ehe} says one last time, before stepping carefully in Sister's footsteps.
                *page_break And you follow suit.
                *goto cliff
            #I take my hand back. I'm more than capable of looking after myself.
                Eli feels your hand slip out of ${ehis} grip, and lets ${ehis} lips twist into a wistful smile. "Stay alert," ${ehe} offers one last time, before stepping carefully in Sister's footsteps.
                *page_break And so do you.
                *goto cliff
    #Finally. I'm ready to get this over with already.
        Sister takes note of your sigh of relief, and lets a smile tug at her lips. "Tired already, are we? You should work a little on your stamina, ${fname}."
        
        "Perhaps if you hadn't led ${them} into an unnecessary battle," $!{ehe} steps between you and Sister, then, and juts ${ehis} chin out towards the edge of the cliff. "Go on, Mireil."
        
        *goto alwayslike
    #I can't help but to be wary. What else does Sister have in store for us on the other side?
        Sister takes note of your narrowed eyes, and holds a hand to her heart in mock offense. "What's this? Surely you don't doubt my integrity."
        
        "A little difficult to do that, when we're fresh out of combat with a [i]baelhound[/i]," Eli says shortly. $!{ehe} steps between you and Sister, then, and juts ${ehis} chin out towards the edge of the cliff. "Go on, Mireil."
        
        *goto alwayslike

*label cliff
When you make it out the other side, your shoulders are sagging from weariness, and there is blood dripping where your skin brushed against the brambles. All the same your heart swells once the foliage thins and disappears, opening into the open plain you had seen Sister's spell light up—and the expanse of dark land past that, stretching infinitely beyond the cliff face.

You swallow a dry gulp and turn your gaze heavenward, expecting to see the falling stars that Sister had promised of you—only to feel your heart drop at the sight that greets you instead.

A vast expanse of nothingness. A shade of black plucked straight from the darkest charcoal, the sickle moon a lonely maiden in the starless sky.

Sister cocks her head to one side, peers curiously at the empty night. "Huh. I guess we're out of luck today."

*choice
    #So we are. It looks like the Rigain Cliffs star showers are nothing but a myth.
        You feel Sister's gaze on you, warm and approving. "You seem to be taking this in stride, ${fname}. I'm glad to see that our little predicament hasn't put you out of—"
        
        *page_break "Bring out your talons, Mireil."
    #I can't help my disappointment. I was really looking forward to this.
        You feel Sister's gaze on you, doe-eyed in a way that she cannot mean. "Come now, ${fname}, don't make that face. We got to get away from the study, right? Surely some fresh air was worth the—"
        
        *page_break "Bring out your talons, Mireil."
    #I'm furious—all that work, just for Sister to lead us on a wild goose chase.
        You feel Sister's gaze on you, doe-eyed in a way that she cannot mean. "Come now, ${fname}. You know the legends just as well as I do! How was I supposed to know that—"
        
        *page_break "Bring out your talons, Mireil."

There is a chink of metal against leather as Eli unsheathes ${ehis} blade, staring Sister down all the while. The healer's brows are furrowed in frustration, ${ehis} jaw set in cautious fury.

Sister gazes on the healer with half-lidded eyes. "Care to explain why you've drawn your blade against me, Eli?"

"You're planning a stealth attack, aren't you? Some sick attempt at a spar?" ${ehe} accuses, shifting into a combat stance. "Such things are beneath you. Fight me head on, like a real warrior."

Sister runs a hand through her hair, a low chuckle escaping her lips. "You are ever so tiring. What have I done to earn such distrust?"

Eli shifts ${ehis} stance in lieu of an answer, showing the shallow gash on ${ehis} ribs that ${ehe} hadn't bothered to heal. "I hope that wasn't a serious question."

"You would hold even this against me? I had done you a [i]favor[/i]," Sister sighs. Despite her complaint, however, she lowers herself into a combat stance, lets her burning talons extend once more from her fingertips. "But I suppose if you're raring for a fight…well. Far be it from me to deny you the pleasure."

Eli takes a cautious step forward, leans deeper into ${ehis} stance. "You're going down."

"Tempting," Sister replies, before shifting suddenly to the right—towards [i]you[/i]. "But I think I'll play with ${fname} first. Here I come!"

(You had seen the gambit coming, of course, and your mana flares in the split second before her advance. Warmth courses through your veins, thick and heavy. A dance of fingers, a beat of silence, and then your spell sings.)

*page_break

At the end of it all, the three of you lie collapsed on the ground—sweat on your brows, thaum-smoke in your lungs, the scent of burning grass pervading the air. Sister withdraws her talons at last, satisfied with her victory, and reaches a hand towards the night sky. You follow her line of sight, watch the last of her flames flicker to its death—to be replaced by another light, far beyond her fingertips, nestled in the sky.

A streak of white light, moving like a brushstoke against the dark night. You blink your eyes hard, unsure if your mind is playing tricks on you—but then a second streak follows, and a third after that, and soon the entire sky becomes a canvas for the falling stars.

'${fname}," Sister says quietly, tracing her finger against your eye. "You're tearing up."

*choice
    #"I'm—[i]not[/i]."
        Sister's smile is at once wistful and amused. "Of course, ${fname}. You're not tearing up."
    #"Stop it. Don't look at me."
        "It's okay," Eli says carefully, rolling onto ${ehis} side to face you. "You can let it out."
    #"Sorry, I don't know what came over me."
        "It's okay," Eli says carefully, rolling onto ${ehis} side to face you. "You can let it out."

(And those words are all it takes for the dam to break.

The first time you'd beheld the open sky, rain fell upon you like a waterfall. The water stung in your eyes, tasted strange on your tongue. Still you'd looked upwards, sight unbroken to the heavens above—for beyond the clouds there laid a single, shimmering star. Shining defiantly in the dark of night, even through the clouds, even through the rain pooling in your eyes.

The sight of it had lit something in the pit of your stomach, warm and kind and feeling all too much like [i]hope[/i]. And even as Father called you back inside, even through the scalpels and scars and rituals, it would flicker there like a guiding light—a star of your own.)

Warm bodies press up against your sides, scarred arms wrapping you tight in their embrace. Sister hums a strange, foreign lullaby, her hand tracing patterns in your hair; Eli presses ${ehis} forehead against yours, ${ehis} steady gaze a stark contrast to your trembling lips.

Your tears fall in streams down your cheek, and they hold you close.

*page_break

The next day, when the sun breaks over the eastern mountains, the Grand Duke's castle becomes engulfed in a whirlwind of whispers and suspicion.

Just ahead of their expedition to slay the baelhound, the ducal knights would find their captain unconscious, slumped over at his desk and missing his blade. White in the face, his deputy would lead the expedition in his stead, point her trembling blade towards the forest where it had terrorized innocents of late.

She would find its carcass, burnt and lacerated, at the base of Rigain Cliffs. And up past the dense forest of trees, in the field where Rigain once struck down her blasphemous lord: clear signs of a wild, ferocious battle, carried out just the night before. And at the center of the destruction, amidst burnt grass and burrowed soil, lies a blade that perfectly matches her own—but for the golden sigil adorning its hilt, engraved with the name of her very own captain.

A search amongst the castle personnel is immediately launched, rewards offered for whoever can shed light on the strange chain of events. And yet no one could offer an explanation, for everyone could vouch for everyone on the seventh night to Rigain's Solstice. The chapel had been packed with courtiers and servants alike, and each guard had been present as they swapped rotations through the night. As surely as the night is dark, everyone in the castle was accounted for.

Everyone, that is, except for the three mage-trainees locked up in their North Tower study. A fact that their tutor had been quick to point out, though he was met with doubt and disdain in equal measure. Suspense of disbelief might have allowed for them to imagine Mireil, ever talented and rebellious, to waltz down the hall and pilfer the captain's blade, before slipping out and downing the baelhound all by her lonesome…

But what of responsible, well-mannered Eli, drowsy after having completed a full batch of antivenom? Little ${fname}, a mage still trying to find ${their} footing, who would have likely withered if ${they}'d so much as stared a baelhound in the face?

The theory was quickly discarded, and so it was that the mystery of Rigain Cliffs would pervade the castle for many months to come.

*page_break

A year later, after you won your first bout against the good viscount, he comes fuming to the Grand Duke, old claims dancing on his tongue once more. But the baelhound's carcass is long since buried, and the castle's wariness had mellowed to mild interest. The matter is dropped before long, and the viscount discharged from his position as royal tutor, having now lost a bout against all three of his pupils.

Sister watches him go through the study's window, mirth and mischief dancing in her scarlet eyes. She turns around with a satisfied smile, steps past the cauldrons where you and Eli are stationed, and crosses a date off from the calendar parchment.

"Seven days before Rigain's Solstice," she notes happily, casting a sideways glance at you and Eli. "It looks like the stars will be coming down again tonight."

Eli's sigh is weary, resigned. "You're not thinking of…?"

Sister does not deign to answer the healer, only lets her mana bleed from her hands and twist it into a dark and familiar cavity. The portal looms balefully from where it's suspended in mid-air, and Sister whips her hair back before resting her gaze upon you both. The planes of her face painted by the shade of her mana, her hand outstretched into a beckon. Her lips part, and you can hear the words before she says it—

*page_break

"Well, then. Shall we go?"

*page_break And you do.

This is the end of [i]Starfall[/i]. Thank you for playing!

*ending