*comment Chapter 6 - Traitor's Finale
*image header_c6.png center Chapter 6, Traitor's Finale. The best of deeds die in the dark.
*page_break

The banquet hall is less grandiose than you remember it.

Remnants of Sister's iron grip on Sienan Keep pervade the wide, opulent room in a hundred little ways. There are cracks in the floor-to-ceiling windows, stray flecks of dried blood in the rafters where the royal painters couldn't reach. The kind of thinly-veiled defects that aristocrats would normally turn their noses up at—and yet here they are, decked out in their fineries and beaming as if they've got a new lease on life.

Probably because they do. For the time being, that is.
*page_break
[i]Three months,[/i] Sister had said. Three months to prevent the largest magical explosion Arvanand has ever seen, and all by your lonesome. Because try as you might to secure others' cooperation, the arcane collar squeezes around your neck if you so much as [i]breathe[/i] a word of your ordeal to anyone.

Thaubal Altinier's old trick—one you thought you'd seen the last of when you left his torture chamber. Though it's apparent now that Sister had no qualms making use of a curse that had brought her so much suffering as well.

How do you feel about your imminent tribulation?
*choice
    #Crisis looms over Sienan, and I'm the only one who knows it. Nausea overwhelms me.
        *set emotional %+ 15
        *set preemotional %+ 15
        *goto sisterhad
    #The crisis can be resolved. I've gotten Param out of worse situations before, haven't I?
        *set optimistic %+ 15
        *set preoptimistic %+ 15
        It may be the case that Sister had the advantage of time on her side—having had years to work on a spell she gave you just three months to undo—but she had planned the invasion for nearly a decade, and you foiled it in two years. You just need to keep your wits about you, and chip away at the problem as you always have. Surely, there must be a way out.
        
        That being said, [i]finding[/i] that way out will likely be a very time-consuming process, and time is a precious luxury right now. Yet here you are anyway; why is that?
    #Damn this waste of time. I needed to start working on countermeasures [i]yesterday[/i].
        *set noble %- 10
        *label sisterhad
        Sister had likely been working on this spell the moment Leon's army made itself scarce from Sienan. You have three months to undo years of work—not to mention said work was performed by a formidable mage, one far more well-versed in magical theorems than you. Add to that the fact that her spell is likely fashioned with [i]arcana[/i], and the picture becomes crystal-clear: you have the odds massively stacked against you.
        
        And yet, here you are anyway. Why is that?

*choice
    #I'm the @{pronvar man|woman|mage} of the hour. The people want me; the feeling is mutual.
        *set charming %+ 15
        *set precharming %+ 15
        *set emotional %+ 15
        *set preemotional %+ 15
        *set charisma %+ 10
        There's nothing quite like the admiration of the masses. Perhaps not the most discerning choice you could have made with danger so imminent, but a well-rested, well-motivated mage is sure to perform better under pressure than @{pronvar his|her|their} tired, haggard counterpart. And given the gravity of the situation you face, you're under no shortage of pressure.
        
        In any case, basking in the spotlight proves to be as recuperative as it is exciting. You've affected your best diplomatic
        *goto charismacheck
    #The feeling is decidedly [i]not[/i] mutual. Freedom is in limited supply for war heroes.
        *set charming %- 15
        *set precharming %- 15
        *set noble %+ 15
        *set prenoble %+ 15
        *set charisma %+ 10
        There's nothing that ignites the spirit better than seeing a revered champion, one who will help lead the war-torn Param to a brighter tomorrow. The road to rebuilding and recovery is a difficult one, and these are the types of stilted platitudes that will help people on their way.
        
        In any case, the extent of your duties is simply to look dignified and charismatic as you flit aimlessly about the banquet hall. You've affected your best diplomatic
        *label charismacheck
        *if (charisma > 70)
            facade—a rather flawless one, if you do say so yourself. The guests respond to your megawatt charisma in kind, flocking to your side like birds ([i]vultures[/i], Saine would correct you), trying to glean more details of your strange powers and lofty exploits. Those who stay away whisper admiringly in your direction from behind their fans and fineries. All in all, you can safely consider your duty fulfilled.
        *elseif (charisma > 50)
            facade—a serviceable one, because really that's all they should be asking of you. Regardless, it appears the guests do not much care about your lack of a megawatt charisma, finding more interest in your strange powers and lofty exploits. They whisper admiringly in your direction from behind their fans and fineries, and you consider your duty fulfilled.
        *else
            facade—as [i]diplomatic[/i] as your face gets, anyway, what with the deformity spanning a large portion of your cheek. Regardless, it appears the guests have rather taken to the scarred-warrior look, from the way they whisper admiringly in your direction from behind their fans and fineries. You consider your duty fulfilled.
        
        The princes, you observe out the corner of your eye, seem to be doing their best to fulfill theirs. As they wear their strained smiles to greet the inexhaustible fleet of nobles, you're reminded of that first night you entered this very hall. The night the princes lost their sibling, and the night you were…[i]reunited[/i] with yours.
        
        It truly feels like it's been a lifetime ago.
    #Red tape now, privacy later. This is a necessary sacrifice.
        *set emotional %- 15
        *set preemotional %- 15
        *set intrigue %+ 10
        Of course. Pursuing countermeasures necessitates you to conduct various unscrupulous activities, including but not limited to research into ancient and [i]decidedly illegal[/i] magic. Parting on awkward terms with the court will make your flying under the radar nearly impossible. Attending the ball is a necessary evil.
        
        In any case, you've done your duty the moment you walked through the hall's pretentiously large mahogany doors. The same couldn't be said for the rest of the White Fangs, however. You can spot them in various corners of the room, the strained smiles they're wearing eerily similar to the ones you saw, that first night you entered this very hall. The night the princes lost their sibling, and the night you were…[i]reunited[/i] with yours.
        
        It truly feels like it's been a lifetime ago.
    #Can't defuse a magical bomb without resources; where better to find [i]that[/i] than with nobles?
        *set emotional %- 15
        *set preemotional %- 15
        *set learning %+ 10
        There will inevitably be massive shakeups in the aristocracy, with various nobles having distinguished themselves through their contributions in the war effort. Knowing the lay of the land will be instrumental should you need to peruse their resources—this is background work, but every bit as important as the actual search for solutions.
        
        In any case, your focus on mapping out the aristocracy's new power rankings has left you somewhat isolated from the remainder of the White Fangs. You can spot them in various corners of the room, the strained smiles they're wearing eerily similar to the ones you saw, that first night you entered this very hall. The night the princes lost their sibling, and the night you were…[i]reunited[/i] with yours.
        
        It truly feels like it's been a lifetime ago.
    #Truth be told, I'm just here to provide moral support to the royals.
        *set noble %+ 15
        *set prenoble %+ 15
        *set rleon %+ 15
        *set rsaine %+ 15
        *if (charming > 50)
            The princes knew you're the type to enjoy social gatherings anyway, but Saine still showed up to your door, puppy-dog eyes on full display as he asked if you wanted to attend the banquet. You immediately accepted the offer, because one, Saine could make a career out of impersonating puppies, and two, you could use the opportunity to blow off some steam anyway.
        *else
            The princes knew you're the type to be averse to social gatherings, but Saine still showed up to your door anyway, puppy-dog eyes on full display as he asked if you wanted to attend the banquet. You agreed to the offer, because one, Saine could make a career out of impersonating puppies, and two, the princes probably could use the vote of confidence on their first day managing a kingdom at peace.
            
            They certainly made no secret of their gratitude, and you're just happy you're able to help somewhat. Duty calls them away for the majority of the banquet, however, and as the princes wear their strained smiles to greet the inexhaustible fleet of nobles, you're reminded of that first night you entered this very hall. The night the princes lost their sibling, and the night you were…[i]reunited[/i] with yours.
         
            It truly feels like it's been a lifetime ago.
    #A makeshift farewell to my friends—for a while or for good, I don't know.
        *set charming %+ 15
        *set precharming %+ 15
        *set rleon %+ 10
        *set rsaine %+ 10
        *set rilya %+ 10
        You don't know where the search for countermeasures will take you, after all. And though you try not to think about it, there's a real possibility that the White Fangs will be caught in the blast in the event of a failure. You hardly want your last words to them to be some variation of "Sorry, I have important business to take care of ([i]more important than you[/i]) so goodbye!"
            
        They seem to be glad for your presence, at any rate. Duties force them to scatter to the four winds, however, and as the triad wear their strained smiles to greet the inexhaustible fleet of nobles, you're reminded of the first time you entered this very hall. The night the princes lost their sibling, and the night you were…[i]reunited[/i] with yours.
            
        It truly feels like it's been a lifetime ago.

*page_break
*temp titlegreet ""
*if (gender = "male")
    *set titlegreet "Lord"
*elseif (gender = "female")
    *set titlegreet "Lady"
*else
    *set titlegreet "Retainer"
"${titlegreet} ${fname}, it's good to see you here."

You turn around to behold a familiar, generously-freckled face, the shock of straw-colored hair as lifeless as ever. "Gael."
*choice
    #"You've cleaned up well. Got a nice girl you fancy in this hall?"
        *set charming %+ 15
        *set precharming %+ 15
        The paladin scratches at his cheek bashfully. "Ah, could you tell?" he says, fixing his collar subconsciously. "It's…been a long time, since we last met. We had been en route to a proper engagement, but when the war broke out—well. It was hardly the only plan that needed to be put on hold."
        
        You smile encouragingly. "Time to get it back in motion, then. You've worked hard to secure this peace—enjoy it."
        
        He breaks out that boyish grin of his, snaggletooth and all. "Thank you, ${sirdame}. I'll be sure to do that," he says, his gaze already drifting to a pretty girl in a tangerine gown. "But what about you, @{pronvar Sir|Dame|Retainer}? I heard you turned down the position of Royal Mage…"
        
        Of course you turned it down.
    #"Alright, let's get this over with. What favor do you wish to ask of me?"
        *set optimistic %- 15
        *set preoptimistic %- 15
        The paladin scrunches his nose, seeming to be confused more than anything else. "Favor, ${sirdame}? I just came to talk to you, I promise."
        
        You ease into a relaxed stance. "I see. Sorry—I guess being around nobles so much are starting to grate on my nerves."
        
        "I can understand that," he says, nodding thoughtfully. "If you don't mind me asking, ${sirdame}, is that why you turned down the position of Royal Mage?"
        
        That may very well be one of the reasons, but certainly not the primary one.
    #Throw your arms around the young paladin. "It's finally over, huh? We made it."
        *set emotional %+ 15
        *set preemotional %+ 15
        Gael startles at your affectionate embrace, but soon laughs airily and returns it in kind. "We did, ${sirdame}. In large part thanks to you."
        
        You pull apart from the hug, giving the younger a wide grin. "I couldn't have done it without your enchantments, Gael. So thank you. I mean it."
        
        The paladin scratches at his cheek bashfully. "You're just saying that, I bet. I mean, you'd be the Royal Mage right now if you didn't turn the offer down." The boy looks up at you with barely-hidden curiosity. "Why did you do that, if you don't mind me asking?"
        
        Of course you turned it down.
    #Nod at the boy by way of greeting.
        *set charming %- 15
        *set precharming %- 15
        The paladin draws himself up beside you, joining in on your silent observation of the room.
        *if (charming > 50)
            "You seem unusually quiet today, ${sirdame}. Is there something on your mind?"
        *else
            "Taciturn as always, aren't you, ${sirdame}? Is something on your mind?"
            
            "Nothing you should be concerned about," you say at length. "And I suppose this ball has rubbed you the wrong way as well?"
            
            Gael laughs at that, the sound airy and bright. "No, I think court life rather agrees with me. I did want to ask you a question, though, if you don't mind me prying."
            
            "I'd have to hear the question first, then, wouldn't I?"
            
            "I guess you would," he agrees easily. "${sirdame}, I heard you…turned down the position of Royal Mage. Can I ask why?"
            
            Of course you turned it down.
Being anointed Royal Mage is a heavily ceremonial, time-consuming affair, and time is not something you're in abundance of right now. You could hardly tell Gael as much, however, what with the ancient curse firmly wrapped around your jugular.

So with practiced ease you tell the paladin your excuse. The same thing you told all the nobles—and indeed, even the White Fangs.
*temp excuse ""
*choice
    #"I need a lot of rest, but I'll definitely reconsider the offer once I'm better."
        *set excuse "rest"
        ${phant1} has definitely taken a massive toll on your mana ducts, after all. You'll need to have Ilya assess the full scope of the damage and determine your new limits, eventually. That's not something you can fit in your timetable right now, unfortunately.
        
        But do you really intend to become Royal Mage, once your health has been confirmed and the crisis averted?
        *choice
            #Yes, I intend to claim the position. None is better qualified for it than I.
                *set emotional %- 15
                *set preemotional %- 15
                Param may be a feudalistic nation, but positions like Royal Mage have always been purely meritocratic in nature. It's only logical that the position should fall to you.
                
                The
            #Yes, I intend to claim the position. I worked hard for it, after all.
                *set emotional %+ 15
                *set preemotional %+ 15
                It wouldn't be an exaggeration to say your contributions in the war saved Param, to say nothing of the fact that you're about to save it a second time. The position [i]belongs[/i] to you.
                
                The
            #Yes, I intend to claim the position. It would be what's best for Param's future.
                *set noble %+ 15
                *set prenoble %+ 15
                The brutal aftermath of the war had transformed the Parami government into a minefield rife with power vacuums and opportunistic nobles. It is more pivotal than ever to have a Royal Mage with nothing but Param's best interests at heart, and no one fulfills that criteria better than you.
                
                The
            #No, but it sure provides a convenient excuse.
                *label kernel
                *set optimistic %- 15
                *set preoptimistic %- 15
                There's no reason to give Gael even a kernel of the truth. You don't know what the boy would do with the information, after all.
                
                Regardless, the
        paladin nods enthusiastically at your words. "Of course, ${sirdame}—you've done so much for the war effort. I must confess it's wonderful to hear that you'll—"
    #"I'd sooner die than get involved with noble politics."
        *set excuse "ewnobles"
        It's certainly believable that a backwater mage like you ([i]are supposed to be[/i]) would find the aristocracy thoroughly unpleasant. But is it the truth?
        *choice
            #Yes. I'm sure they do necessary, important work; I just want no part of it.
                *set optimistic %+ 15
                *set preoptimistic %+ 15
                You find that a simple life lived away from the axis of power suits you best. You would've never come anywhere near the aristocracy were it not for the strange workings of fate.
                
                The
            #Yes. They're a bunch of bloodsuckers with no thought for anyone but themselves.
                *set optimistic %- 15
                *set preoptimistic %- 15
                You've had the opportunity to witness the worst excesses of nobility during your time in the war. It's a wonder the White Fangs turned out the way they are, being raised in an environment like that.
                
                The
            #Yes. These nobles can talk until they're foaming at the mouth. Utterly unbearable.
                *set charming %- 15
                *set precharming %- 15
                After all, words are the tools of their trade, as much as spells are yours. It's a wonder they get anything done, though, with so much of their time tied up with idle small talk.
                
                The
            #I don't really mind it, actually. But it sure makes for a convenient excuse.
                *set optimistic %- 15
                *set preoptimistic %- 15
                There's no reason to give Gael even a kernel of the truth. You don't know what the boy would do with the information, after all.
                
                Regardless, the
        paladin gives you a wry smile. "I suppose I can see how you'd tire of it quickly, ${sirdame}. I've been brought up in these circles all my life, but even I—"
    #"I'd rather focus on furthering my magical studies.
        *set excuse "magic"
        You may be an accomplished mage, but magic is a vast, boundless art: there is always something more to discover, for those inclined to pursue it.
        
        But were it not for the looming disaster, would this really be the path you'd pursue?
        *choice
            #Yes, I don't care about much else, though I'd be happy to help when needed.
                *set noble %+ 15
                *set prenoble %+ 15
                After all, what's the use of being the most proficient mage in the continent, if you don't use it to better the world?
                
                The
            #It's only a lie because I don't plan to come running when the crown whistles.
                *set noble %- 15
                *set prenoble %- 15
                You've been far too busy fighting wars and scraping together a living to truly pursue the enticing lure of dedicated magical studies. With the stability being a war hero has afforded you, that can now change.
                
                The
            #Of course it's a lie. But it's a convenient excuse, and that's all that matters.
                *set optimistic %- 15
                *set preoptimistic %- 15
                There's no reason to give Gael even a kernel of the truth. You don't know what the boy would do with the information, after all.
                
                Regardless, the
        paladin nods thoughtfully at your words. "I envy you, ${sirdame}. That you're able to do that, I mean. If it were up to me, I would also—"
    #"It's nothing so exciting. I just don't like the spotlight."
        *set excuse "ewattention"
        Certainly the job of a Royal Mage is one that's bound to draw the eyes of the aristocracy. It's a position that commands a lot of political power (to say nothing of [i]actual[/i], combative power the titleholder is bound to already have), and accepting it will make you all but the centerpiece of the court.
        
        The question is, are you truly averse to that?
        *choice
            #Yes. A quiet, boring life where I eventually fade into obscurity suits me just fine.
                *set charming %- 15
                *set precharming %- 15
                *set emotional %- 15
                *set preemotional %- 15
                No amount of power and influence can buy the priceless treasures of peace and quiet.
                
                The
            #I rather like the attention, actually, but this does make for a convenient excuse.
                *set charming %+ 15
                *set precharming %+ 15
                *set emotional %+ 15
                *set preemotional %+ 15
                *set optimistic %- 15
                *set preoptimistic %- 15
                There's no reason to give Gael even a kernel of the truth. You don't know what the boy would do with the information, after all.
                
                Regardless, the
            #I have no need for attention, but power is never a bad thing to have.
                *set emotional %- 15
                *set preemotional %- 15
                *set optimistic %- 15
                *set preoptimistic %- 15
                *label kernel2
                Be that as it may, there's no reason to give Gael even a kernel of the truth. You don't know what the boy would do with the information, after all.
                
                Regardless, the
            #I [i]loathe[/i] the attention, but it's an...[i]acceptable[/i] price for power.
                *set charming %- 15
                *set precharming %- 15
                *set optimistic %- 15
                *set preoptimistic %- 15
                *goto kernel2
        paladin nods thoughtfully at your words. "I understand, ${sirdame}. I've been raised in these circles all my life, but even I still—"
    #"It's nothing you need to concern yourself with."
        *set charming %- 15
        *set precharming %- 15
        The paladin takes a step back, chastened by the rebuff. "Of course, ${sirdame}. I apologize for the presump—"
*page_break "${fname}."
Saine smiles at Gael by way of greeting as he draws himself up beside you. "Sorry to interrupt the conversation," the prince says, his lips pulled into a taut smile. "${fname}, it's time."

You nod in acknowledgment. You had your reasons for attending the banquet, but ultimately the clock keeps ticking and you haven't much time to waste. Saine being here means that the carriage is already waiting outside, on standby to take you out of Sienan and beyond Parami borders.

Because in dealing with the unknown forces of arcana, there's really only one lead you could pursue. Deep in Salantira, in the underground laboratory of a ruined, abandoned manor, hundreds of books on the lost art grace the dusty shelves that once belonged to Thaubal Altinier. If you're to have any chance at understanding the nature of the curse and how you might go about reversing it, you must be willing to return to the site of your childhood trauma.

It's a hefty price to pay, given all that you went through under Thaubal's discretion. Why suffer it?
*choice
    #I can't just look the other way. Trauma be damned, I [i]have[/i] to do this.
        *set noble %+ 15
        *set prenoble %+ 15
        You think of all the new allies you met, bonds you formed over the course of the war. Many of them call Sienan home—to do nothing as they perished would cause you the greatest trauma of all.
    #Thaubal's laboratory is a treasure trove of knowledge. I can finally peruse it without fear.
        *set noble %- 15
        *set prenoble %- 15
        Hundreds of tomes and manuscripts on powerful arts practiced by a lost civilization—the value of that knowledge is simply [i]colossal[/i].
    #I've had years to recover from it. I barely even think of the place anymore.
        *set emotional %- 15
        *set preemotional %- 15
        *goto athingof
    #I've had years to recover from it, and I can defend myself. I'll be [i]fine[/i].
        *set optimistic %+ 15
        *set preoptimistic %+ 15
        *label athingof
        Everything you experienced in that lab is a thing of the past, and no more than that. You are possibly the strongest mage in the continent—[i]no one can harm you anymore[/i], not like that.
    #That lab may well be my only shot at recovery. I have to go there.
        *set optimistic %- 15
        *set preoptimistic %- 15
        Ilya is a talented theurge, talented enough to vie for the position of saintess; and yet even she confessed readily that ${phant1}'s impact on your body is well beyond her understanding and capacity to heal.
    #Images of the dead torment me still. How could I add to the pile?
        *set emotional %+ 15
        *set preemotional %+ 15
        You have to at least [i]try[/i], or else the fact that you stood by as thousands perished will haunt you to your grave.

"Gael, if you'll excuse us," Saine says, tugging on your hand.

Before you leave, you manage to fish a piece of parchment out from your robe, neatly folded and imbued with a magical seal. You slip the paper to Gael, who receives it with some surprise. The young paladin looks ready to question you, but you raise a finger to your lips to motion for his silence, and he obliges despite the confusion written plain on his features.

The parchment you had given him is a letter you had penned earlier in the day. The initial intention was to test the limits of Sister's curse, to put to paper what your voice refused to disclose. A futile act you had been forced to abort, in the end, when the curse would manifest like shackles around your wrist, pressing inwards with the force of a battering ram. You were forced to spend hours nursing the invisible injury, waiting for the pain to subside for what had felt like an eternity. When you found the strength to lift the pen once more, the words that came out were a different beast entirely.

You can't help but feel wistful as you watch Gael pocket the parchment. A simple page scrawled with the haphazard script of a lifelong academic, ascribed with words far heavier than you had expected to write, in the aftermath of the Sun King's triumph. But the road that lies ahead of you is treacherous and uncertain, perhaps even more so than the bloody war you had fought so hard to end. It seemed only prudent to say your farewells where your voice may fail you.

To whom is the letter addressed?

*choice
    *if (leonrom) #Leon. I love him with all my being, and I make sure he knows it.
        *set rleon %+ 15
        *set letterto "leonlove"
        Yours is a bond tempered in the fires of war, burning brighter over the course of a few years than most do over entire lifetimes. You recall the night you'd spent on the cliff over Sienan, just the two of you, a borderless carpet of stars above your heads. The memory fills your heart with something that stings and heals you both in equal measure—and yet above the conflicting sea of emotions, one truth reigns supreme:
        
        That no matter what happens next, Leon is the best thing that has ever happened to you. And you are incredibly, impossibly grateful, to have loved him as you did.
    *if (leonrom = false) #Leon. I thank him for everything, and wish him luck on his kingship.
        *set rleon %+ 10
        *set letterto "leonfriend"
        His will be a reign purchased with blood, and the earth is still warm and drenched where his people had fallen in his name. There will be maze of nobles to prod and placate, angry and broken masses to appease, scorched fields to be cleared and turned into breadbaskets once more. This on top of his personal griefs, for the comrades and innocents engulfed by the fires of war. For the brother whose legacy still lays heavy on his shoulders.
        
        It is an utterly unenviable position, and you almost feel guilty that you won't be by his side in his reign's infancy. And yet if you were to stay, then said reign is as good as over.
    *if (ilyarom) #Ilya. I love her with all my being, and I make sure she knows it.
        *set rilya %+ 15
        *set letterto "ilyalove"
        Yours is a bond tempered in the fires of war, burning brighter over the course of a few years than most do over entire lifetimes. You recall the night you'd spent on the cliff over Sienan, just the two of you, a borderless carpet of stars above your heads. The memory fills your heart with something that stings and heals you both in equal measure—and yet above the conflicting sea of emotions, one truth reigns supreme:
        
        That no matter what happens next, Ilya is the best thing that has ever happened to you. And you are incredibly, impossibly grateful, to have loved her as you did.
    *if (ilyarom = false) #Ilya. She has a long road ahead of her, and could use an encouraging word.
        *set rilya %+ 10
        *set letterto "ilyafriend"
        She is not the saintess [i]yet[/i], but she is all but guaranteed the position given her instrumental role in the rebellion. But the Church is nothing if not fond of its song and dance, and you suspect it will be months before the mantle is properly given to her. Not that it matters—whatever she is referred to as in noble circles, her personal war is far from over. She will be tasked with the healing a broken people, standing on soil soaked in the blood of their beloved.
        
        It is an utterly unenviable position, and you almost feel guilty that you won't be by her side when she first takes the pedestal. And yet you must go all the same, for her and her nation both.
    *if (saineace) #Saine. His struggles persist still, and I won't be around to advise him.
        *set rsaine %+ 15
        *set letterto "saineace"
        What must it be like, to consider consigning your life away for the benefit of thousands? At the tender age of nineteen, Saine has had more blood on his hands than a career knight, bears the load of a thousand watchful eyes. Even as his form passed nimbly through the battlefield, even as he affected good cheer and indifference, there were always shadows in the lines of his face that ages him by years. And so you make sure to tell him that he is entitled to his youth, that whatever path he chooses to tread will not make a monster out of him.
        
        It is almost laughable, that the letter is all you could manage for one deserving of so much more. You can't help the acute guilt building in your chest that you won't be by his side as he begins to make the hard calls. And yet you must go all the same, for him and his nation both.
    *if (saineace = false) #Saine. With how exuberant he is, he'll be very prone to loneliness.
        *set rsaine %+ 10
        *set letterto "sainefriend"
        Not that he would admit it, of course. Saine had been remarkably strong and steady as the Sun Prince's shadow, and knights and commoners alike would speak in hushed whispers of their fear of him. How could a child of not yet twenty wield the dagger with such merciless precision, bathe in the blood of his enemies without so much as a flicker of distress in his eyes?
        
        These are questions you have pondered yourself, and despite your status as one of the prince's closest confidants, it remains difficult for you to glean an answer. But you know, at least, that the young rogue takes to words of amity and comfort like a duck to water—and so you write to ensure him that your friendship is his, for as long as he desires it.
    #Aunt Bess. I tell her that I'll be home soon.
        *set letterto "besshome"
        You wonder what had possessed you to write so optimistic a piece. Few mages will ever reach the heights of greatness that Sister did in her short life, and she casts a long shadow even as her body lays cold and buried six feet under. There is no guarantee that you will make it through this ordeal alive, and you know as well as anyone that false hope is the farthest thing from kindness.
        
        And yet you could not stop the words from spilling out onto the parchment, building the image of a stalwart mage tying up one last loose end before the war could properly draw to a close. You write of a city bathed in the light of the Sun, of victory standards billowing against the wind, an era of peace just waiting in the wings. A well-tread path you still remember like the back of your hand, crawling up hills and twisting past treelines, leading you home the way it had done all those years ago.
        
        What a kindness that would be. You can only hope you'll live to see it.
    #Aunt Bess. I thank her once more for the year I spent in her care.
        *set letterto "bessthank"
        You expended your best efforts to make the letter read neutral—hopeful, even—and insinuate that the farewells you had exchanged all those years ago will not be the last you'll see of each other. And yet you couldn't help the wistful pang you feel in your chest as you read the letter over, and you wonder if Aunt Bess will pick up on the hint of finality permeating the words.
        
        It winds up a little stilted, in the end, a touch too formal to be a simple thank-you letter—though it's impossible to tell what it is you're not being forthcoming about. Regardless, you think it will help Aunt Bess to know that you survived the war. Perhaps, if fate is kind enough to let it transpire, one day you will find yourself on that sun-dappled path you remember like the back of your hand. A cobblestone road that crawls up hills and twists around treelines, leading you home the way it had done all those years ago.
        
        What a kindness that would be. You can only hope you'll live to see it.
        
Gael's eyebrows are still knit together in confusion as Saine pulls you away, but the young paladin manages an uncertain smile and waves goodbye. Tonight he will find the instructions attached onto the side of the envelope, and—being the steadfast, dutiful knight you know him to be—he will see to it that the letter reaches who it needs to. You purse your lips wistfully as his figure is drowned by the crowded ballroom, then turn around to follow Saine across the hall, down the grand staircase, and out of the keep.

Leon and Ilya are waiting for you next to the carriage, a nondescript car of polished wood drawn by a sturdy-looking stallion. The coachman tips his hat to you, his gaze not quite meeting your own. Next to him, Leon stirs as he sees you arrive.

"There you are, ${fname}," he says, jumping off his perch on the coachman's seat. He's still donning his royal habits, Julius's old ermine coat a size too small on him. "You hired a real solid coachman, you know. Wouldn't tell me where you're headed no matter how much I ask."

*choice
    #"Stop bullying my driver, Leon."
        *set rleon %+ 5
        "[i]Bullying[/i] is such a strong word," the prince says easily, giving the coachman a firm pat on the back. "It's not like I threatened the good man with lèse-majesté or anything."
        
        Beside him Ilya heaves a longsuffering sigh. "That's exactly what he did."
        
        The blond shrugs. "It's your word against mine, Ilya. And I think [i]I'm[/i] the crown prince."
        
        "Ignore him, ${fname}," Saine cuts in. "He's had to hold his tongue so much lately that he'll jump on the first chance he gets to be insufferable."
        
        "Hey!"
        
        "Anyway," the rogue continues, turning his back on Leon.
    #"I can set his house on fire from fifty leagues away."
        *set rleon %+ 5
        The driver gulps at your choice of words, finding very sudden interest in the stretch of road ahead.
        
        "You've scared the poor guy," the prince remarks, giving the coachman a firm pat on the back. "Sorry for my archmage; I promise @{pronvar he's|she's|they're} all bite."
        
        "Ignore him, ${fname}," Saine cuts in. "He's had to hold his tongue so much lately that he'll he'll jump on the first chance he gets to be insufferable."
        
        "Hey!"
        
        "Anyway," the rogue continues, turning his back on Leon.
    #I roll my eyes. When will he learn to respect your privacy?
        *set charming %- 15
        *set precharming %- 15
        Leon's face falls at your expression. "Sorry, um. I wasn't seriously prying. You know that, right?"
        
        You grunt noncommittally. Even if it was truly a joke, you think it was in poor taste.
        
        "Sorry about him, ${fname}," Saine says, breaking the awkward silence. "He's had to hold his tongue so much lately that he'll he'll jump on the first chance he gets to be insufferable."
        
        Leon grumbles inaudibly at the jab, but makes no attempt to contradict his brother.
        
        "The more important thing is," the younger continues, 
"Are you absolutely [i]sure[/i] you can't stay a while longer? The coronation's in just a week…"

"Stop it, Saine," Ilya chides gently.
*if (excuse = "rest")
    "@{pronvar He's|She's|They've} run
    ${themselves} ragged fighting this war, and there's nothing theurgy can even do for ${them}. If ${they}
    @{plural say|says}
    ${they}
    @{plural need|needs} rest, then that's that."
    
    "I know…but still," Saine says under his breath, quiet enough that only you can hear him. It doesn't appear he intends to finish the sentence.
*elseif (excuse = "ewnobles")
    "Given how strongly ${they} @{plural feel|feels} about the nobility, it's a miracle
    @{pronvar he's|she's|they've} even lasted this long. We shouldn't force
    ${them} to stay any longer."
    
    "Lucky," Saine says under his breath, quiet enough that only you can hear him.
*elseif (excuse = "magic")
    "@{pronvar He's|She's|They've} already done so much for Param—the least we can do is to let
    ${them} do as ${they}
    @{plural like|likes}
    , now that the war's over. We'll have to make do without ${them} for now, alright?"
    
    "I know," Saine says under his breath, quiet enough that only you can hear him. His pout never quite goes away, however.
*elseif (excuse = "ewattention")
    "We've already gone over this, right? ${fname} has already done so much for Param—the least we can do is to let ${them} do as ${they} @{plural like|likes},
    now that the war's over. We'll have to make do without ${them} for now, alright?"
    
    "I know," Saine says under his breath, quiet enough that only you can hear him. His pout never quite goes away, however.
*else
    "We've already gone over this, right? ${fname} has already done so much for Param—the least we can do is to let ${them} go, no questions asked."

    "But still," Saine says under his breath, quiet enough that only you can hear him. It doesn't appear he intends to finish the sentence.
    
*temp comeback 0
*comment comeback is 0 if false, 1 if true, 2 if maybe
*choice
    #"I'll be back before you know it, little man. Don't miss me too much, now."
        *set charming %+ 15
        *set precharming %+ 15
        *set comeback 1
        "You better," the younger says weakly, pulling you into a hug. "I'm gonna miss you."
        
        "I'll miss you too, Saine."
    #"It's been a good few years, despite everything."
        "Sorry we dragged you into it," the younger says sheepishly. "You helped us out a lot."
        
        You manage a small smile. "I know."
        
        "This isn't goodbye, though, is it?" Saine asks, his lips trembling as his hands hang onto your coat. "We're going to see you again, right?"
        *goto sainetremble
    #"I think this is a good point to part ways. Goodbye, everyone."
        Saine's lips tremble as his hand hangs meekly onto your coat. "Are we going to see you again?"
        *label sainetremble
        *choice
            #"Definitely."
                *set comeback 1
                "I'll hold you to that," the prince says, insistent as he locks his gaze with yours.
                
                You can't help but to chuckle. "I'm sure you will."
            #"Maybe someday."
                *set comeback 2
                *if (ilyarom)
                    Ilya goes very, very still at your words, though her expression remains carefully impassive.
                    
                    "You're too mean," Saine complains. "I'll come and find you in a year, okay? See if you can escape me then."
                    
                    "Saine," Leon scolds behind him, too weakly to be anything but a formality.
                    
                    "I know, I know," he says, waving his hand dismissively. "I'm not saying I'll drag ${them} back here or anything. Just—it's been five years together, Ilya…I'm gonna miss ${them}."
                    
                    *if (charming > 50)
                        You give him a wry smile. "Sorry about this, kiddo."
                    *else
                        You give him a wry smile. "Sorry about this."
                    
                    Ilya looks conflicted as she witnesses the exchange, the emotions in her eyes inscrutable. "In any case, this'll be it, ${fname}. Your carriage is waiting."
                    *goto choices
                *elseif (leonrom)
                    Leon averts his gaze at your words, his teeth gnawing on his lower lip in a nervous tick.
                    *goto toomean
                *label toomean
                "You're too mean. I'll come find you in a year, okay? See if you can escape me then."
                
                "Saine," Ilya scolds behind him, already making to pull the younger away.
                *label iknow
                
                "I know, I know," he says, waving his hand dismissively. "I'm not saying I'll drag ${them} back here or anything. Just—it's been five years together, Ilya…I'm gonna miss ${them}."
                
                *if (charming > 50)
                    You give him a wry smile. "Sorry about this, kiddo."
                *else
                    You give him a wry smile. "Sorry about this."           
                
                Leon looks conflicted as he witnesses the exchange, the emotions in his eyes inscrutable. "In any case, this'll be it, ${fname}. Your carriage is waiting."
                *goto choices
            #"Probably not."
                *set rsaine %- 10
                *if (ilyarom)
                    Ilya goes very, very still at your words, though her expression remains carefully impassive.
                    
                    "You're too mean," Saine complains. "I'll come and find you in a year, okay? See if you can escape me then."
                    
                    "Saine," Leon scolds behind him, too weakly to be anything but a formality.
                    
                    The prince turns around to regard his brother. "You can't stop me," he says, insistent, before whirling towards you and holding your gaze in his own. "And neither can you."
                
                    You give him a wry smile. "I suppose we'll see, won't we?"
                    
                    Ilya sighs at the exchange, her breath painting a white puff in the night air. "Don't aggravate him, ${fname}," she scolds. "In any case, your carriage is waiting. I think your coachman's starting to catch a cold."
                    
                    As if on cue, the man sneezes into his sleeve.
                    *goto choices
                *elseif (leonrom)
                    Leon averts his gaze at your words, his teeth gnawing on his lower lip in a nervous tick.
                    
                *label meanie
                "You're too mean. I'll come find you in a year, okay? See if you can escape me then."
                
                "Saine," Ilya scolds behind him, already making to pull the younger away.
                
                The prince turns around to regard her. "You can't stop me," he says, insistent, before whirling towards you and holding your gaze in his own. "And neither can you."
                
                You give him a wry smile. "I suppose we'll see, won't we?"
                
                Leon looks conflicted as he witnesses the exchange, the emotions in his eyes inscrutable. "In any case, I guess this is it, ${fname}," he says judiciously, after a while. "Your carriage is waiting."
                *goto choices

*label choices
*choice
    #There's actually some things I'd like to ask them, before I go.
        *goto luckily
    #I've said everything I needed to say. I make to leave.
        *goto boarding
    
*label luckily
Luckily enough, none of them look to be in any hurry to return to the banquet.

*label choicehub
*choice
    *disable_reuse #"Leon, what are your plans after the coronation?"
        The blond runs a hand through his hair, grimacing as he contemplates the road ahead.
        
        "The war has really taken its toll on us. The rebuilding will be costly, but Salantira's coffers will pay for the bulk of it. But the administrative work…it's daunting." Leon steels himself then, looking you dead in the eyes as if he had something to prove. "But I'll see it through, ${fname}. Param will know prosperity and peace—just as Julius wanted."
        *choice
            #"That sounds well and good, but don't forget about what [i]you[/i] want."
                *set rleon %+ 10
                Leon's brows furrow in confusion. "What do you mean?"
                
                "Your brother was a great man, but there is no need to live in his shadow. You were the one who led this army to victory, and it's [i]you[/i] that the people now put their trust in. Rule according to your ideals."
                
                "I see," the prince says after a while, scratching at his cheek bashfully. "Thank you, ${fname}. It's…nice. To hear you have such faith in me, I mean."
            #"I'll be rooting for you."
                *set rleon %+ 5
                "You can do more than just root for me, ${fname}.
                *if (comeback = 0)
                    Let me know if you ever change your mind, alright? The doors of Sienan Keep will always be open for you."
                    
                    You manage a smile. "I'll keep that in mind."
                *elseif (comeback = 1)
                    Let me know if you do end up wanting to come back—the doors of Sienan Keep will always be open for you."
                    
                    You manage a smile. "I'll keep that in mind."
                *else
                    I'll hold down the fort while you're gone, but don't take too long, alright?"
                    
                    You grin at the prince. "I won't, I promise."
            #"Saine, keep your brother out of trouble, will you?"
                *if (comeback = 0)
                    "Do it yourself," the younger grumbles under his breath. "If you're so worried about him, why don't you stick around, ${fname}?"
                    
                    Ilya stirs beside him. "[i]Saine[/i]."
                    
                    "Fine, fine, I get it already."
                *elseif (comeback = 1)
                    *set rsaine %+ 10
                    Saine breaks out into a mischievous grin. "I'll try my best, but he [i]can[/i] be really hopeless sometimes. You better come back quickly, ${fname}."
                    
                    "I'll keep that in mind," you say, chuckling under your breath.
                    
                    Leon looks between the two of you, an expression of mock hurt plain on his features. "I'm very offended by all this, just so we're clear."
                    
                    "Noted, Brother."
                *else
                    "If I have to," the younger says, giving you a tentative grin. "But it's a lot of work taking care of him, you know? So you better come back quickly, ${fname}."
                    
                    "Maybe I will," you say, chuckling under your breath.
                    
                    Leon crosses his arms at the exchange, an expression of mock hurt plain on his features. "I'm very offended by all this, just so we're all clear."
                    
                    "Noted, Brother."
        *goto choicehub
    *disable_reuse #"Ilya, how is the saintess doing?"
        Ilya wrings her hand nervously. "Not good. We haven't…really made any progress with her."
        
        You had suspected as much. The saintess had been found immediately after your duel with Sister, confined in a chamber adjacent to the Sanctum of Jove. It was through sheer dumb luck that she wasn't at all caught in the combat's crossfire, though her condition remains worrying all the same.
        
        You still remember the way Ilya's face twisted with anguish when she first caught sight of her mentor. Sister truly did not hold back with the saintess—her scars ran deep and her black hair had fallen out in clumps, but most alarming of all was the hazy emptiness clouding her vision. To this day, Shiraya Cheilong does not respond to any external stimuli.
        
        "I'm told none of the theurges can do anything for her," Leon mourns. "I'm sorry we weren't able to get to her quicker."
        
        "We….we got here as fast as we could. There is no one to blame aside from Mireil," Ilya insists, and you get the distinct impression it isn't Leon she's trying to convince. "It's certainly perplexing, though. So many talented theurges are with us due to the war effort, but every single one's at a loss. All she's done for us—and we couldn't do anything to save her."
         
        "You will," Leon interrupts, looking at the healer with intent. "It will take time, but I know you can do it. Don't lose hope, Ilya."
        
        The healer manages a weak smile, though doubt still lingers in her eyes.
        *goto choicehub
    *disable_reuse #"Saine, do you still have that journal with you?"
        The younger prince perks up, nodding as he produces the tome from within the folds of his coat. The book is scarlet, its leather bindings tattooed with a formidable seal and pulsing with Sister's mana signature. "You mean this [i]thing[/i], right?"
        
        Ilya eyes the tome with a cautious sort of hope. "This…journal Mireil kept—it might be our only lead to heal the saintess. If Mireil's gone to such painstaking lengths to seal its contents, there must be something useful in it."
        
        You nod in solemn agreement. You had considered perusing it for your own ordeal, but one look at the intricate sealwork tells you it would take months, perhaps years to decode and break. The saintess is in no physical danger, and can therefore afford the wait. The ticking magical bomb is not so lenient.
        
        "I'll keep cracking away at it," Ilya says at length. "I owe the saintess that much, at least."
        *goto choicehub
    #"I should probably go."
        *goto boarding
*label boarding
*if (leonrom)
    You give the three a wry smile, but find that your gaze stops as it crosses paths with Leon's. There are lines in his face that makes him look older, older still than the grizzled war commander he had been forced to become. His mouth opens, for a second, before closing again as he averts his gaze to the ground.
    
    Saine studies his brother with an eagle eye. "You look like you have something to say, Brother," he says, slow and deliberate.
    
    The Sun Prince startles at the address. "What? I don't—that is to say, I—"
    
    "Ilya, I think the little [i]party[/i] will have noticed our absence by now. Hold down the fort with me?"
    
    A long, tense silence hangs in the air as Ilya furrows her brows at the young prince. But then she turns to study you and Leon both and you can practically hear the pieces falling into place in her mind. "Ah."
    
    "[i]Ilya, the party.[/i]"
    
    She chuckles into her hand, giving you a knowing smile. "Right behind you."
    *page_break
    Leon watches the pair as they leave, scratching bashfully at his cheek. "I think they're onto us."
    *choice
        #"You [i]think?[/i]"
            The blond gives you a withering look. "Sorry. You know I'm not good at these things."
            
            "All too well."
            
            *if (comeback = 0)
                Leon huffs a breath. "It isn't important right now, anyway," he says, shifting his stance. "Do you mean it, ${fname}? That you don't…intend to come back."
                
                It's a loaded question, and the implication hangs heavy in the air even when the prince withholds the words: [i]Is this the end? Have you changed your mind about us?[/i]
                *label nocomeback
                *choice
                    #"Don't be ridiculous. You know I'll come back, Leon. For you."
                        *set rleon %+ 15
                        The blond lets out a shaky laughter, green eyes looking up at you with palpable relief. "Thank Jove," he whispers, and at once the prince moves to wrap you in a full-bodied embrace. "I'm…I'm so glad, ${fname}. I was so scared that I'd lose you, after everything."
                        
                        "I'm sorry," you manage, because it's the only thing you could say, "for worrying you."
                        
                        Leon's hold around you is steady, a bit too tight for comfort—as if fearing you might slip like sand through his embrace. "I don't know why the lie was a necessity, ${fname}, but I trust you. Wholeheartedly. I'll keep your secret, even from Ilya and Saine. Just—come back to me. Promise me you will."
                        
                        "I swear it," you whisper, the oath too quiet to drown out the heart hammering in your chest. "I'll always come back to you."
                        
                        For all that the man is decked out in ermine, you can still feel his muscles stiffening under the garment. He presses his forehead against yours, then, and against the night air his skin is warm to the touch—like a beckoning hearth, a siren call reminding you that this is [i]home[/i]. His gaze flits over your lips, harsh, intent, but in a second he withdraws on himself and instead kisses you chastely on the forehead. "I'll be waiting," he rasps, reluctantly breaking the embrace. "Go, ${fname}."
                        
                        It is a moment before you find the strength to do as he says. But all the same you do it, ignoring the ache in your heart as you turn to leave: fierce, and biting.
                        *goto carriage
                    #"I'm sorry, Leon. This is goodbye."
                        *set rleon %- 20
                        *set leonrom false
                        The blond looks away, but it's a futile attempt at evasion and you catch sight of his expression anyway: grim, broken. "I see," he says after a beat, his voice valiantly steady. "I…can't understand it, ${fname}. I thought I meant something to you."
                        
                        "I'm sorry," you say for the umpteenth time, as if the words will do anything to stymie the pain. But the future is uncertain, and promises made here, in this circumstance, are just asking to be broken; these words are all you have.
                        
                        Leon does not look at you when he replies. "Farewell, ${fname}," he rasps, hands trembling at his sides. "I wish you well."
                        *goto carriage
            *elseif (comeback = 1)
                Leon huffs a breath. "It isn't important right now, anyway," he says, shifting his stance. "I…I just can't believe you're going, ${fname}. Just when we can finally start something."
                
                It's a loaded statement, and the implication hangs heavy in the air even when the prince withholds the words: [i]Do you truly mean to come back? Or is this some roundabout way of saying you've changed your mind?[/i]
                *label yescomeback
                *choice
                    #"You're the only one for me, Leon. You know that."
                        *set rleon %+ 15
                        The blond lets out a shaking breath, and as the tension melts from his features he is youth personified, all boyish grin and boisterous cheer. "Thank Jove," he whispers, and at once the prince moves to wrap you in a full-bodied embrace. "I'm sorry, ${fname}, for doubting you. It's just—if I lose you like this, after everything, I wouldn't be able to live with myself."
                        
                        "I'm sorry too," you manage, even as Leon presses his face against your shoulder. "I know I'm asking for a lot, but please wait for me, Leon."
                        
                        The prince's hold around you is steady, a bit too tight for comfort, as if in fear that you might slip through his embrace like grains of sand. "Of course, ${fname}. This much is nothing, if it's for you, you know that. Just—come back to me. Promise me you will." 
                     
                        "I swear it," you whisper, the oath too quiet to drown out the heart hammering in your chest. "I'll always come back to you."
                        
                        For all that the man is decked out in ermine, you can still feel his muscles stiffening under the garment. He presses his forehead against yours, then, and against the night air his skin is warm to the touch—like a beckoning hearth, a siren call reminding you that this is [i]home[/i]. His gaze flits over your lips, harsh, intent, but in a second he withdraws on himself and instead kisses you chastely on the forehead. "I'll be waiting," he rasps, reluctantly breaking the embrace. "Go, ${fname}."
                        
                        It is a moment before you find the strength to do as he says. But all the same you do it, ignoring the ache in your heart as you turn to leave: fierce, and biting.
                        *goto carriage
                    #"I'm sorry, Leon. I think this is goodbye."
                        *set rleon %- 20
                        *set leonrom false
                        The blond looks away, but it's a futile attempt at evasion and you catch sight of his expression anyway: grim, broken. "I see," he says after a beat, his voice valiantly steady. "I…can't understand it, ${fname}. I thought I meant something to you."
                        
                        "I'm sorry," you say for the umpteenth time, as if the words will do anything to stymie the pain. But the future is uncertain, and promises made here, in this circumstance, are just asking to be broken; these words are all you have.
                        
                        Leon does not look at you when he replies. "Farewell, ${fname}," he rasps, hands trembling at his sides. "I wish you well."
                        *goto carriage
                        
            *else
                Leon huffs a breath. "It isn't important right now, anyway," he says, shifting his stance. "Do you mean it, ${fname}? That you might not even come back?"
                
                It's a loaded question, and the implication hangs heavy in the air even when the prince withholds the words: [i]Is this the end? Have you changed your mind about us?[/i]
                *goto nocomeback
        #"It was bound to happen sooner or later. Don't worry about it."
            *if (comeback = 0)
                "True enough. And it's not important right now, anyway," he sighs, shifting his stance. "Do you mean it, ${fname}? That you don't…intend to come back."
                
                It's a loaded question, and the implication hangs heavy in the air even when the prince withholds the words: [i]Is this the end? Have you changed your mind about us?[/i]
                *goto nocomeback
            *elseif (comeback = 1)
                "True enough. And it's not important right now, anyway," he sighs, shifting his stance. "I…I just can't believe you're going, ${fname}. Just when we can finally start something."
                
                It's a loaded statement, and the implication hangs heavy in the air even when the prince withholds the words: [i]Do you truly mean to come back? Or is this some roundabout way of saying you've changed your mind?[/i]
                *goto yescomeback
            *else
                "True enough. And it's not important right now, anyway," he sighs, shifting his stance. "Do you mean it, ${fname}? That you might not even come back?"
                
                It's a loaded question, and the implication hangs heavy in the air even when the prince withholds the words: [i]Is this the end? Have you changed your mind about us?[/i]
                *goto nocomeback
        #"I'm surprised we hadn't told them yet, actually. I guess it never really came up."
            *if (comeback = 0)
                "True enough—it's been a busy few days, after all. And it isn't really important, not right now," he says, shifting his stance. "Do you mean it, ${fname}? That you don't…intend to come back."
                
                It's a loaded question, and the implication hangs heavy in the air even when the prince withholds the words: [i]Is this the end? Have you changed your mind about us?[/i]
                *goto nocomeback
            *elseif (comeback = 1)
                "True enough—it's been a busy few days, after all. And it isn't really important, not right now," he says, shifting his stance. "I…I just can't believe you're going, ${fname}. Just when we can finally start something."
                
                It's a loaded statement, and the implication hangs heavy in the air even when the prince withholds the words: [i]Do you truly mean to come back? Or is this some roundabout way of saying you've changed your mind?[/i]
                *goto yescomeback
            *else
                True enough—it's been a busy few days, after all. And it isn't really important, not right now," he says, shifting his stance. "Do you mean it, ${fname}? That you might not even come back?"
                
                It's a loaded question, and the implication hangs heavy in the air even when the prince withholds the words: [i]Is this the end? Have you changed your mind about us?[/i]
                *goto nocomeback
    *label carriage
    
    You board the carriage.
    *page_break
    Leon's figure fades into the night as distance stretches between you, and it takes all of your willpower to tear your gaze away.
    *goto nextscene
    
*elseif (ilyarom)
    You give the three a wry smile, but find that your gaze stops as it crosses paths with Ilya's. There is a hesitant set to her features, something turbulent in the way her blue eyes regard you. Her mouth opens, for a second, before closing again as she finds sudden interest in her shoes.
    
    Saine studies the healer with an eagle eye. "You look like you have something to say, Ilya," he says, slow and deliberate.
    
    The healer's lips quirk up at the address, the admission already at the tip of her tongue. "Perhaps I do."
    
    "Brother, don't you think it's about time for you to return to the banquet? The nobles will have noticed your absence by now."
    
    Leon furrows his brows at the younger. "Well, I mean, of course. But I was hoping we could see ${fname}—"
    
    "Brother, the banquet, [i]now[/i]."
    
    "Saine, what's gotten into you? It's not like—"
    
    And with a growling, exasperated grunt, Saine tackles his brother bodily and blinks them both out of existence. Leon's yelp resurfaces on the far side of the keep's hallways, barely audible in the distance.
    *page_break
    Ilya huffs in amusement at the princes' antics. "I don't know how Leon would function without Saine, honestly." 
    *choice
        #"Hopefully, we'll never have to find out."
            "I don't think we will. Saine has done a lot of growing, after the war. I think he's grown a little bit more into his role as royalty."
            
            You make a noise of assent, but find that you can focus on little else than the healer before you. To Ilya's credit, she picks up on the mood quickly.
            
            *label ilyapick
            *if (comeback = 0)
                "So you're leaving," she says after a tense beat of silence, and though her voice is stable, carefully neutral, she refuses to meet your gaze. "Pretty cruel of you, to only let me know now, like this."
                *label ilya0
                *choice
                    #"I'm sorry, Ilya. I think this is for the best."
                        *label poorilya
                        *set rilya %- 20
                        *set ilyarom false
                        The healer turns away quickly, but not before you could get a glimpse of her expression, twisted with devastation. "I will try to respect your decision, ${fname}," she stays, almost eerily steady. "I have never before felt pain like this, but I will try. You waited for me for so long—you deserve this much, at least."
                        
                        "I'm sorry," you say for the umpteenth time, as if the words will do anything to stymie the pain. But the future is uncertain, and promises made here, in this circumstance, are just asking to be broken; these words are all you have.
                        
                        "I know. I know you are," she says through gritted teeth. "I will be fine one day, ${fname}, so don't feel any guilt about what happened here. You deserve to be happy, and I wish—I wish you well—"
                        
                        Ilya chokes on her words, shoulders hunched forward and lip bitten to restrain the cry, but her efforts are in vain. When the tears come it is like a dam breaking—deep, convulsive sobs that shake the healer's entire body. "Go," she sniffles, weeping into her sleeve. "Please."
                        
                        You move to oblige, because it is the only kindness you could afford her.
                        *goto carriage2
                    #"I could never leave you. Not like this."
                        *set rilya %+ 15
                        The healer looks up at you, eyes widened with a cautious hope. "Then, what you said earlier—it was a lie?"
                        
                        You nod in confirmation, and in a second all the tension leaves the healer's body. She heaves out a shaking, shuddering breath, and though there is anger in her features it is drowned in a sea of [i]relief[/i]. "You're really determined to make me cry today, aren't you."
                        
                        "I'm sorry," you manage, because it's the only thing you could say, "for worrying you."
                        
                        Ilya closes her eyes, for a beat, clearly still in the midst of processing her feelings—and when she opens them again they are glassy with the threat of incoming tears. "I don't appreciate the lie, ${fname}, but I trust you. I trust that you wouldn't pull something like this unless—unless it was—"
                        
                        Ilya chokes on her words, shoulders hunched forward and lip bitten to restrain the cry, but her efforts are in vain. When the tears come it is like a dam breaking—deep, convulsive sobs that shake the healer's entire body.
                        *label ilyahug
                        *choice
                            #Hug her.
                                Ilya flinches when you first wrap your arms around her, but she soon relaxes into the embrace, still weeping into the palm of her hand. "You must think me overdramatic," she half-laughs. "It's just…the thought of you leaving, [i]now[/i], just as everything is falling into place…I couldn't bear it. I couldn't bear it."
                                
                                "I would never do that to you. You know I wouldn't."
                                
                                "Then swear it to me," she says, sapphire eyes fierce even through the tears. "Swear you'll come back, the first chance you get."
                                
                                "I swear," you whisper, the oath too quiet to drown out the heart hammering in your chest. "I'll always come back to you."
                                
                                She returns the embrace, then, and your senses come alive as you commit her essence to memory—the high flush in her cheeks, the warmth of her body heat, the scent of lavender as she presses gentle kisses against your cheek. [i]This is home[/i], you think, the thought burning like a bonfire in the dead of night. [i]This is what I'm fighting for.[/i]
                                
                                It must've been nearly a minute before Ilya parts from the embrace, the motion clumsy and laden with reluctance. "I'll be waiting for you, ${fname}," she says, and though her sobs have mellowed out you can hear the desperation in her rasp. "Go."
                        
                                It is a moment before you find the strength to do as she says. But all the same you do it, ignoring the ache in your heart as you turn to leave: fierce, and biting.
                                *goto carriage2
                            #Wait for her to calm down.
                                Ilya sniffles into her arms for another half-minute, pointedly hiding her expression as she reins herself in. "You must think me overdramatic," she half-laughs afterwards. "It's just…the thought of you leaving, [i]now[/i], just as everything is falling into place…I couldn't bear it. I couldn't bear it."
                                
                                "I would never do that to you. You know I wouldn't."
                                
                                "Then swear it to me," she says, sapphire eyes fierce even through the tears. "Swear you'll come back, the first chance you get."
                                
                                "I swear," you whisper, the oath too quiet to drown out the heart hammering in your chest. "I'll always come back to you.
                                
                                She pulls you into an embrace, then, and your senses come alive as you commit her essence to memory—the high flush in her cheeks, the warmth of her body heat, the scent of lavender as she presses gentle kisses against your cheek. [i]This is home[/i], you think, the thought burning like a bonfire in the dead of night. [i]This is what I'm fighting for.[/i]
                                
                                It must've been nearly a minute before Ilya parts from the embrace, the motion clumsy and laden with reluctance. "I'll be waiting for you, ${fname}," she says, and though her sobs have mellowed out you can hear the desperation in her rasp. "Go."
                        
                                It is a moment before you find the strength to do as she says. But all the same you do it, ignoring the ache in your heart as you turn to leave: fierce, and biting.
                                *goto carriage2
            *elseif (comeback = 1)
                "So you're leaving," she says after a beat of silence, and though her voice is stable, carefully neutral, she refuses to meet your gaze. "And you won't tell us where you're going, or when you'll come back." Ilya meets your gaze with intent, and you feel rather than hear the next part of her statement: [i]or if you'll even come back.[/i]
                *label ilya1
                *choice
                    #"I'm sorry. I think this is goodbye."
                        *goto poorilya
                    #"I would never lie to you about this, Ilya. You know that."
                        In a second all the tension leaves the healer's body. She heaves out a shaking, shuddering breath, and though a longing sort of desperation paints her features it is drowned in a sea of [i]relief[/i]. "I do. I know that. I'm sorry if it seemed like I was doubting you, because I [i]don't[/i], it's just that—it's just that I—"
                            
                        Ilya chokes on her words, shoulders hunched forward and lip bitten to restrain the cry, but her efforts are in vain. When the tears come it is like a dam breaking—deep, convulsive sobs that shake the healer's entire body.
                        *goto ilyahug
            *else
                "So you're leaving," she says after a tense beat of silence, and though her voice is stable, carefully neutral, she refuses to meet your gaze. "And you won't tell us where you're going, or if you'll even come back. It's…pretty cruel of you, ${fname}, to leave me with what-ifs and uncertainties like this.
                    
                "So tell me," she asserts, looking you dead right in the eye. "Will you come back, or will you not? I won't take maybe as an answer, ${fname}."
                *choice
                    #"I'm sorry, Ilya. I think it's best we part ways here."
                        *goto poorilya
                    #"I could never leave you, Ilya. Not after everything."
                        The healer looks up at you, eyes widened with a cautious hope. "Can I take that as a promise, ${fname}?"
                            
                        You nod in confirmation, and in a second all the tension leaves the healer's body. She heaves out a shaking, shuddering breath, and though there is melancholy in her features it is drowned in a sea of [i]relief[/i]. "Then….then that will have to be enough."
                        
                        "I'm sorry," you manage, because it's the only thing you could say, "for worrying you."
                        
                        Ilya closes her eyes, for a beat, clearly still in the midst of processing her feelings—and when she opens them again they are glassy with the threat of incoming tears. "That was a mean trick you pulled, ${fname}, but I trust you. I trust that you wouldn't do something like this unless—unless it was—"
                        
                        Ilya chokes on her words, shoulders hunched forward and lip bitten to restrain the cry, but her efforts are in vain. When the tears come it is like a dam breaking—deep, convulsive sobs that shake the healer's entire body.
                        *goto ilyahug
        #"You don't think it's endearing of him?"
            "It would be, perhaps, if he was still a mercenary stationed out in Calinger. But he's inheriting Julius's crown…I can't help but to worry."
            
            You make a noise of assent, but find that you can focus on little else than the healer before you. To Ilya's credit, she picks up on the mood quickly.
            *goto ilyapick
        #"Enough about them, Ilya. We need to talk about [i]us[/i]."
            "I had hoped you'd play along with the small talk," she says, laughing nervously. "I'm not sure I'm ready for what you're about to say."
            
            *if (comeback = 0)
                "Ilya, I—"
                
                "You're leaving," she cuts in quickly, and though her voice is stable, carefully neutral, she refuses to meet your gaze. "For good, by the looks of it. Pretty cruel of you, to only let me know now, like this."
                *goto ilya0
            *elseif (comeback = 1)
                "What do you mean by that?"
                
                "You're leaving," she says after a beat of silence, and though her voice is stable, carefully neutral, she refuses to meet your gaze. "And you won't tell us where you're going, or when you'll come back." Ilya meets your gaze with intent, and you feel rather than hear the next part of her statement: [i]or if you'll even come back.[/i]
                *goto ilya1
            *else
                "Ilya, I—"
                
                "You're leaving," she cuts in quickly, and though her voice is stable, carefully neutral, she refuses to meet your gaze. "And you won't tell us where you're going, or if you'll even come back. It's…pretty cruel of you, ${fname}, to leave me with what-ifs and uncertainties like this.
                    
                "So tell me," she asserts, looking you dead right in the eye. "Will you come back, or will you not? I won't take maybe as an answer, ${fname}."
                *choice
                        #"I'm sorry, Ilya. I think it's best we part ways here."
                            *goto poorilya
                        #"I could never leave you, Ilya. Not after everything."
                            The healer looks up at you, eyes widened with a cautious hope. "Can I take that as a promise, ${fname}?"
                            
                            You nod in confirmation, and in a second all the tension leaves the healer's body. She heaves out a shaking, shuddering breath, and though there is melancholy in her features it is drowned in a sea of [i]relief[/i]. "Then….then that will have to be enough."
                        
                            "I'm sorry," you manage, because it's the only thing you could say, "for worrying you."
                        
                            Ilya closes her eyes, for a beat, clearly still in the midst of processing her feelings—and when she opens them again they are glassy with the threat of incoming tears. "That was a mean trick you pulled, ${fname}, but I trust you. I trust that you wouldn't do something like this unless—unless it was—"
                        
                            Ilya chokes on her words, shoulders hunched forward and lip bitten to restrain the cry, but her efforts are in vain. When the tears come it is like a dam breaking—deep, convulsive sobs that shake the healer's entire body.
                            *goto ilyahug
    *label carriage2
    
    You board the carriage.
    *page_break
    Ilya's figure fades into the night as the distance stretches between you, and it takes all of your willpower to tear your gaze away.
    *goto nextscene
*else
    You give the three a wry smile as you board the carriage. The White Fangs fade into the night as the distance stretches between you, and it takes all of your willpower to tear your gaze away.
    *goto nextscene

*label nextscene
*page_break
[i]Achoo![/i]

The sneeze rings loudly, echoing in the space around you as you descend the narrow set of stairs. You brush cobwebs and gathering dust aside with your bare arms, trying not to cringe at the way they cling onto skin and fabric alike. This dilapidated old basement is all that remains of the Altinier marquisate, the old manor above it burnt to the ground and long since overrun by wild animals and overgrowth.

Thaubal's silencing curse had kept you from talking about this place, about the lone plinth in the manor's garden that opens up the ground when you feed it mana. It would be seven long years of silence until the arcane collar lost its power, though of course it took Sister but a single second to renew your torment. And here you now are, forced to confront your old demons once more.

As expected, the room is in exactly the same state you left it, the night of the fire twelve years ago. The same cold linoleum flooring, the same stale, musty air, now mixed with years of dust and something rotten. You do your best to stifle the retch already forming in your throat—after all, this place will become your home for the foreseeable future.

Or else Sienan will pay the price.
*page_break You get to work.
Days in the basement pass by in an urgent, furious haze. It takes you nearly the whole three months to rifle through the ancient texts, translating accounts written in archaic Arcadian and simulating any and all spellwork that looks remotely similar to Sister's curse. 
*if (injury = "concussion")
    Of course, it certainly doesn't help matters that your memory often fails you these days, due to the old head injury you received during your time with the White Fangs.
But your efforts bear fruit in the end, and when you find the spell you can tell it apart at once.

*page_break

Its runework is a thing of violent beauty, all harsh strokes and concentric layers, and drawn in the innermost ring are the three runes you had seared into memory that fateful day—gather, time, detonation. Sister's work is a perfect replica of the illustration, and the resemblance is so instantly recognizable that you almost want to laugh.

The only reason it took you so long to find it is because you'd been looking in the wrong tomes. It is your greatest fallacy to have begun your search in volumes of…
*choice
    #...attack spells.
        *set thaum %+ 15
        Bolts of thunder and seas of fire, transcendent magic Arcadia had once used to level whole cities.
    #...violent enchantments.
        *set enchantment %+ 15
        Wicked glyphs and runes that stretched for leagues, transcendent magic Arcadia had once used to level whole cities.
    #...alchemical concoctions.
        *set alchemy %+ 15
        Explosive powders and catalysts now banned from use, transcendent magic Arcadia had once used to level whole cities.
    #...nether-born curses.
        *set spiritism %+ 15
        City-wide poxes and ghasts spawned from beyond, transcendent magic Arcadia had once used to level whole cities.
But the book in your hands is a different beast entirely—its subject is [i]ritual magic[/i], an art that demands the sacrifice of life and mana both in exchange for its effects.

Not only is a mage of truly exceptional talent required to be given as tribute—[i]especially so given the scale of Sister's curse[/i]—but said mage must also be in full cooperation with it. The besetting sin of ritual magic, after all, is that the slightest bit of reluctance in offering up their life would defuse the curse even as it forms. It is very rare that rituals are ever completed with anyone but the caster themselves as the catalyst.

But Sister laid dead in the Sanctum that day, as surely as the night is dark, and the most ardent of her followers have all been put to the sword. It should be impossible for Sister to make good on her threats—there is no one left to sacrifice, no way for the curse to come to bear.

*page_break Unless...

You jerk up in your chair as realization dawns upon you like a guillotine. 

There [i]is[/i] such a mage in Sienan this very moment, someone with boundless magical talents who had years to refine her art to perfection. The consummate tribute for Sister's plans, someone who wouldn't—[i]couldn't[/i] offer any resistance, even as the curse threatens to destroy everything she holds dear.

The pinnacle of theurges, who now sits catatonic in her chambers in the Jovian Church.

The saintess.

[i]The saintess is the sacrifice.[/i]
*page_break
*if (gender = "male")
    "We've arrived, sir."
*elseif (gender = "female")
    "We've arrived, madam."
*else
    "We've arrived."

You shake out of your solemn reverie and find that your driver speaks the truth. Your carriage has pulled up on Vesavian Street, home to one of Sienan's most bustling intersections—and, of interest to you, the Old Cathedral.

You peer out the window to size the building up: it is ivory-white and tall, dwarfed only by Sienan Keep in the cityscape. Glyphs of protection line the walls from steeple to base; generations of Church enchanters worked for centuries to lay the spellwork, designed to keep magical assaults at bay. Yet for all that they glimmer forebodingly even in the dead of night, they will prove no match for Sister's spell should it complete its circuit.

It is [i]your[/i] job to see that it doesn't.
*choice
    #I'm terrified. There are so many ways the plan could go wrong.
        *set emotional %+ 15
        *set preemotional %+ 15
        *set optimistic %- 15
        *set preoptimistic %- 15
        The plan has far too many moving parts, too many factors that could go haywire at any moment. To say nothing of the fact that you're to pull it off [i]alone[/i], with the deadline for a city-wide explosion dogging your heels. The stakes are high, and judging from the relentless hammering of your heart, so is your blood pressure.
    #This can easily go south, but it's too late for me to second-guess myself.
        *set emotional %- 15
        *set preemotional %- 15
        *set optimistic %- 15
        *set preoptimistic %- 15
        The plan is a haphazard, last-minute concoction, barely functional and fraying at the seams besides. There are too many moving parts, too many factors that could go haywire at any moment. But it's the only plan you've got, and the only shot Sienan has at averting catastrophe. There's no other option: you [i]must[/i] do this.
    #I've been in plenty life-or-death situations before. If anyone can do it, it's me.
        *set optimistic %+ 15
        *set preoptimistic %+ 15
        *set emotional %- 15
        *set preemotional %- 15
        You can still remember your solo mission one year into the war, when you had infiltrated an enemy base and burned every last Salantir trebuchet to the ground. Your actions had saved thousands of Parami lives then, and returned a pivotal fortress to the rebellion. You are no stranger to working miracles—there is no reason to be nervous.
    #I'll be damned if I lose to a mage already three months dead.
        *set emotional %+ 15
        *set preemotional %+ 15
        *set optimistic %+ 15
        *set preoptimistic %+ 15
        Sister fully expected to come out victorious in the Sanctum of Jove, but you proved to her that it was a mistake to underestimate you. Her plan might have caught that inexperienced, fledgling little mage she chased out of Salantira off guard, but you have years of experience on ${them}, a grizzled war veteran in your own right with no shortage of motivation to get this [i]right[/i]. 
        
You procure a generous amount of silver from your robe pocket, far more than a ride from just outside of town should cost you. But you buy his silence as well as the ride, and the driver nods grimly as he accepts the coins.

You approach the Cathedral's complex and the barracks come into view. It's an unremarkable structure, all square edges and fraying white paint, deceptively simple despite being the final barricade between you and the saintess. You can spot the Jovian paladins through the glass windows, eagerly awaiting dinner in the mess hall and sparring with one another—[i]indoors, against all conventional wisdom[/i]—but all the same you understand them to be the biggest threat to your mission.

After all, the Cathedral's defensive enchantments will alert them in the event of an intrusion; hardly ideal, given that [i]you[/i] are the intruder. And for all that you are a skilled mage, it's difficult to find the prospect of fighting thirty experienced paladins by yourself attractive. [i]Especially[/i] when you need to construct and complete the most complex dispelling enchantment you've ever casted in your life immediately afterwards.

Luckily enough, you have the drop on them, and a countermeasure all planned out.
*temp paladin ""
*choice
    *selectable_if (enchantment > 65) #I cast a sleeping enchantment over the entire barracks.
        *label enchantmentz
        *set paladin "enchantment"
        *set glyphofslumber true
        *set ecounter +1
        *set prestige +5
        It takes you a long while to lay the Glyph of Slumber's groundwork, the sprawling spell circle glowing dimly as it stretches to encompass the whole of the barrack grounds. You do your best to cloak your mana signature, hoping against hope that the paladins won't be able to detect the mana profusely hemorrhaging from your form into the air around them. They are warriors first and foremost, but basic magical training is part of the requirements for initiation—and it only takes one proficient mage out of the thirty for your gambit to be foiled.
        
        Thankfully, it seems your fears were unfounded. The paladins continue to merrily swordfight and slobber over their meals, even as the enchantment settles around them and blazes to life. A rather worrying lack of discipline, on their part, but a wonderful stroke of luck for you—one by one they drop to the ground under the Glyph's influence.
        *goto itisdone
    *selectable_if (charisma > 74) #I convince the paladins that remnants of the Salantir army are wreaking havoc downtown.
        *set paladin "charisma"
        It will be a hard sell, given how soundly Salantira was beaten three months ago. So to kick your performance into high gear and create a sense of urgency…
        *choice
            #...I smear my midriff with red paint. They'll be too panicked to notice the ruse.
                *set optimistic %+ 15
                *set preoptimistic %+ 15
                You smear the liquid strategically around your abdomen, let it drench your robe until it is nearly [i]dripping[/i] with 'blood'.
                *if (acting)
                    Rean and Sofiya would be horrified at your sloppy gambit, but the night is dark and the paladins exhausted from their day of training—this will work out fine, you're sure.
                *else
                    You're under no illusion that this is anything other than a sloppy gambit, but the night is dark and the paladins exhausted from their day of training—this will work out fine, you're sure.            
            #...I cause actual injury to myself. I won't take any chances.
                *set optimistic %- 15
                *set preoptimistic %- 15
                You make the shallow cut to your abdomen, wincing as you press the injury to draw blood. But the war had all but tripled your tolerance to pain, and you let the wound bleed until your robes is nearly [i]dripping[/i] with blood.
                *if (acting)
                    
                    [i]Method acting,[/i] Rean and Sofiya had called it? Time to put it to the test.
                *else
                    You've done all you can to make the act believable—the only thing left to do is to deliver a convincing performance.
        *label openup
        *set prestige +5
        "Open up! Open up!"
                
        There is a rushing of steps as you bang on the barrack's door, and when it opens you spot an all-too-familiar face. "Gael," you exhale, doing your best to keep your breath ragged. "I—I came to warn you, I—"
                
        Gael spots the bloody hand clutching at your abdomen, and his eyes goes so impossibly wide; they seem primed to leap out of their sockets. "${sirdame}, what—what happened to you? No, before that, we need to get you a heal—"
                
        "Never mind that, I'll be fine," you hiss through gritted teeth, forging your tone into an urgent cadence. "There are attackers down by Sienan Square, and they're powerful—leftovers from Salantira, I think. I tried to stop them, but there are too many and I—" you crumple in on yourself, heaving out heavy, labored breaths for dramatic effect.
        
        "${sirdame}!"
        
        You slap away the hand Gael offers, looking him dead in the eye with all the desperation you could muster. "Please, you have to go [i]now[/i], all of you. The people are in danger."
        
        "We will, ${sirdame}, just—let me find a healer from the Cathedral," he says, even as around him the rest of his order moves to address the supposed threat.
        
        "I can do it myself. I'm fine, I swear it—it's [i]the people[/i] who need you, Gael, so don't you dare waste any more time."
        
        He looks conflicted, for a moment, but soon moves to obey your words. He grips one of the iron blades mounted upon the barrack wall, and joins his sword siblings as they make for Sienan Square.
        
        You watch on as the knight's armored back fades in the distance.
        *goto itisdone
    *selectable_if ((alchemy > 65) and (intrigue > 49)) #I prepared some Palmerra in Thaubal's laboratory. I can slip it into their dinner.
        *set paladin "alchemy"
        *set palmerra true
        *set acounter +1
        *set rustelixir true
        *set acounter +1
        Thankfully, the paladins' mess hall is awfully simple. Some twenty round tables are scattered across the length of the room, generously spaced from one another, and in the hall's center is an enormous pot of deer stew prepared by the Cathedral's kitchen staff. The meal is still piping hot, the fire underneath it having just recently been doused, and so there should be a good ten minutes or so before the paladins gather around the pot to take their share of dinner.
        
        You crawl quietly along the edge of the barrack walls, careful not to let your head peek through the wide glass windows. As you turn the corner you affix a piece of rope to where the building's roof juts out, and with practiced deftness you use it as support to pull yourself up to the building's roof. You make your way to the center of the roof where you estimate the pot to be, already procuring the Rust Elixir from your robe pocket. Two, three drops later a keyhole-sized cavity opens in the roofing, and you peek through it to confirm that you are indeed positioned directly above the cauldron.
        
        Slowly, carefully, you empty the bottle of Palmerra into the cavity, the sound of it splashing against the stew drowned out by the din of the room.
        *page_break
        *set prestige +5
        The drug works as intended. Twenty minutes later you stand in the doorway as fifty blank-eyed paladins sit in the hall around you. Their trance is perfectly temporary—it takes years of drugging before their minds could be truly damaged, the way Sister had damaged the Grand Duke's—but you can't help but find the sight eerie all the same.
        
        "Do not move," you command them. "Until morning comes, you will stay here."
        
        And so they do.
        *goto itisdone
    #I fight my way through. With the element of surprise, I can easily overwhelm them.
        *goto breakthrough

*label breakthrough
*set paladin "thaum"
*set gaelalive false

Jovian paladins are no easy foes, and the task laid out before you is tremendous: a balancing act between conserving your mana, neutralizing the paladins, and keeping them alive all the while. For all that you are confident in your skills, it is deeply unlikely that you'll be able to achieve the task without compromise. Given the scale of the threat before you, it is painfully clear which metric you must let fall by the wayside, should worse comes to worst.

For a brief, trifling moment you contemplate the wisdom of bolting straight for the Cathedral, in hopes that the paladins would be too deep in their own business to notice. The thought dies as quickly as it had formed—despite what appearances might suggest, they are some of the most competent guards in all of Arvanand, and having them corner you at elevation is a folly you'd rather not risk.

There is a loud bang as one of the paladins slam against the door in a drunken stupor, eliciting a raucous round of laughter from his peers. The force of the impact unhinges the wooden construct from its jambs, and the barracks lay open as if in invitation.

*page_break It's now or never.

You walk almost leisurely to the entrance, letting your mana uncoil and wash over your body in vigorous waves. There is a knot in your stomach that tightens as the reality starts to sink in—that many of these paladins will die before the night is out, so that Sienan can be saved.

A red-haired knight catches you approaching at the door and waves you over. "$!{sirdame}!" she calls out, beaming. "You're back! We haven't seen you in so long—oh, I bet the king will be so pleased!"

Lynora. She was drafted mere months before the war, but her prodigious talent for combat more than makes up for her lack of experience. She had played an instrumental role in the Battle of Calinger, and is one of the few survivors of the forlorn hope that decimated her squadron.

A formidable warrior, in all respects. But here, unarmored and unprepared, she is as pliant and defenseless as any common peasant.
*choice
    *selectable_if (thaum > 49) #I launch the barrage of thaum spells I've been preparing, starting with Morana's Wail.
        The icicles roar into existence with a frigid blast of air, and you try not to flinch at the way Lynora's face twists into a grimace as they ram edgewise against her body. There's a sickening crunch that draws the attention of the whole room as she slams against the barracks walls, and when gravity pulls her down she is bleeding and wholly unconscious.
        
        You do not give the paladins any time to react, as the next round of your salvo is already materializing in the air around you. Sunflame crackles furiously as you toss it across the room, catching a table of knights with their drinks still in their hands and setting them to writhe on the stone floor. Boomerang Gales slice through the air with cold precision, drawing blood from the knights' unarmored forms and curving around the walls to return for more. A Flametongue there, a Thunderstrike elsewhere—there is no end to your barrage of spells, and though the paladins try their best to mount a counteroffensive they remain sorely outmatched. Your deadly whirlpool of spells spins and bellows and shrieks, and at the end of it all the entirety of the order lays broken at your feet.
        
        *if (thaum > 70)
            *set prestige +3
            It speaks to your skill as a thaumer that your spells are so accurate in both aim and power, and for all that the hall is littered with bodies most of them are still breathing. Inevitably, there were a couple of instances where the violence of your magic had transcended your control, and you try not to think of the way Sunflame had burned a shade too brightly to leave its victims alive. The image of Gael's horror as he is caught in the fatal blaze will forever be imprinted in your memory, but you can at least save yourself the pain of beholding his burnt, broken form at the far end of the hall.
        *else
            *set prestige +1
            You've had days to plan the assault, and every spell cast was by design—it is only natural that you would come out victorious. The true challenge had been in the execution—in grafting enough strength to your magic to proceed, but not enough to leave the paladins dead.
            
            In this, it is safe to say you've failed. The hall is littered by the broken forms of the paladin order, many among them comrades who had fought right by your side during the war. They had come home to a nation restored, to a family that awaited their return with bated breaths—and they are gone before they could truly sink their teeth into the hard-won peace.
            
            (Sunflame had burned a shade too bright to leave its victims alive. The image of Gael's horror as he is caught in the fatal blaze will forever be imprinted in your memory, but you can at least save yourself the pain of beholding his burnt, broken form at the far end of the hall.)
            
            You swallow the thickness forming in your throat,
            *if (emotional > 50)
                and do your best to ignore the way your feet shake under the weight of all that you've done. You make your way out of the barracks.
            *else
                grateful for the frigid calm that has settled in the cavity of your chest, and make your way out of the barracks.
            *goto itisdone
    *selectable_if (alchemy > 49) #A round of Clay Cannons would achieve a similar effect.
        *set prestige +1
        There's a shuddering in the air as your mana bleeds and transforms the alchemic clay into cannonballs, slamming itself against the paladin at point-blank range. You try not to flinch at the way her face twists into a grimace as the spell rams edgewise against her body. There's a sickening crunch that draws the attention of the whole room as she slams against the barracks walls, and when gravity pulls her down she is bleeding and wholly unconscious.
        
        You do not give the paladins any time to react, as the next round of your salvo is already materializing in the air around you. It is a brutal, artless affair, to launch the earthen cannonballs around the enclosed space with reckless abandon—but there is no denying that it is effective.
        
        A brown-haired knight reaches for the blade he's stowed away under the table. He never gets to reach it.
        *page_break [i]Slam![/i]
        The most senior of the knights yells in your direction, asking, demanding you to snap out of it.
        *page_break [i]Slam![/i]
        An enchantment settles around the form of the order's youngest, but you are too strong to be stopped by a makeshift Glyph.
        *page_break [i]Slam![/i]
        You succeed, in the end, and with no injuries but for a few minor scratches. But taking in the sight of the room—the crooked forms laying still on the stone floor, the splatters of deep scarlet coating the walls—the victory tastes all too much like defeat.
        
        (Gael had jumped in front of a recruit, right at the end of the barrage. In wartime, sudden movements usually meant the draw of an archer's bowstring, or a flash of mana right before the spell. You had shot to kill before you could stop yourself.)
        
        You turn your face away from the carnage—this is what needed to be done, and you are well past the point of regret. Ignoring the thickness forming in your throat,
        *if (emotional > 50)
            your feet shaking under the weight of all that you've done, you make your way out of the barracks.
        *else
            the talons of a frigid calm clenched around your heart, you make your way out of the barracks.
        *goto itisdone
    *selectable_if (spiritism > 49) #Fists of the Dark Lord should get the job done just as well.
        *set prestige +1
        The gates manifest with a burst of dark magic, an array of six portals rippling into existence through the force of your mana. The first of the Fists slams against Lynora at point-blank range, and you try not to flinch at the way her face twists into a grimace when the hit connects and tosses her across the hall. There's a sickening crunch that draws the attention of the whole room as she slams against the barrack walls, and when gravity pulls her down she is bleeding and wholly unconscious.
        
        You do not give the paladins any time to react, taking advantage of their shock to carry out the next part of your assault. It is a brutal, artless affair, to launch the dark constructs around the enclosed space with reckless abandon—but there is no denying that it is effective.
        
        A brown-haired knight reaches for the blade he's stowed away under the table. He never gets to reach it.
        *page_break [i]Slam![/i]
        The most senior of the knights yells in your direction, asking, demanding you to snap out of it.
        *page_break [i]Slam![/i]
        An enchantment settles around the form of the order's youngest, but you are too strong to be stopped by a makeshift Glyph.
        *page_break [i]Slam![/i]
        You succeed, in the end, and with no injuries but for a few minor scratches. But taking in the sight of the room—the crooked forms laying still on the stone floor, the splatters of deep scarlet coating the walls—the victory tastes all too much like defeat.
        
        (Gael had jumped in front of a recruit, right at the end of the barrage. In wartime, sudden movements usually meant the draw of an archer's bowstring, or the flash of mana right before the spell. You had shot to kill before you could stop yourself.)
        
        You turn your face away from the carnage—this is what needed to be done, and you are well past the point of regret. Ignoring the thickness forming in your throat,
        *if (emotional > 50)
            your feet shaking under the weight of all that you've done, you make your way out of the barracks.
        *else
            the talons of a frigid calm clenched around your heart, you make your way out of the barracks.
        *goto itisdone

*label itisdone
*page_break It is done.
*if (paladin = "thaum")
    *achieve killpaladins
*else
    *achieve dontkillpaladins

The first phase of the plan is complete, and you enter the Cathedral unimpeded. There is an uneasy tension in the air despite it all, and you can almost [i]feel[/i] the prickle of Sister's mana pervading the air. Today marks the third month after Sister's death, to the date—there isn't much time left, and you can only hope there will be enough.

You bound up the Cathedral's spiraling stairway, rehearsing the dispelling enchantment in your head as you run. It's a complex, ancient spell gleaned from the same tome where you found Sister's spell, one that will take you at least half an hour to properly construct. You've bought yourself plenty of time with the paladins out of the picture, and your race now is only against the detonation itself.

All the same, you can't shake off the dread settling in your stomach, the one that tells you you'll be dead before the night is out.
*choice
    #Nonsense—I feel good about my chances. I can do this.
        *set optimistic %+ 15
        *set preoptimistic %+ 15
        You practiced the enchantment countless times on your way to Sienan, and you know it now like the back of your hand. You can finish it quickly, now that the possibility of interference has been removed.
    #I knew about the risks going in, and I'm prepared to lay down my life.
        *set noble %+ 15
        *set prenoble %+ 15
        This crisis is bigger than you, bigger than any one person. When so many lives hang in the balance, there's really only one course of action you can take.
    #I'm surprised the spell hasn't detonated yet. I wonder if my luck will hold out.
        *set optimistic %- 15
        *set preoptimistic %- 15
        Sister is the type to make good on her threats, after all. It's a wonder the spell didn't detonate as soon as the clock struck twelve—that you've had an additional [i]twenty hours[/i] to carry out your countermeasure is already an immeasurable blessing.

The top floor of the Cathedral is a circular foyer featuring naught but a single doorway. You behold that door before you now, a marble masterwork carved with delicate murals of Jovian theology, its smooth surface layered with an excess of protective glyphs. There's no mistaking it—this is the Saintess's chambers.

Your mana flares to life as you command it to strike at the door. The glyphs hold strong against your assault, for a while, but ultimately you are a much more talented mage than mere Jovian clerics, and spell and doorway both buckle under the force of your spell.

*page_break "HALT!"

You flinch where you stand as a large black dagger sails past you and embeds itself into the wall. It did not graze at your carotid artery, but it was a [i]damn near thing.[/i]

You sincerely doubt its owner had intended to miss.

"Step away from the doorway, ${sirdame}," Ante says as she draws herself up behind you, ten of her underlings in tow. "No one is allowed to see the saintess.
*if (paladin = "alchemy")
    [i]Especially[/i] someone who's poisoned the entirety of the Paladin Order."
*elseif (paladin = "charisma")
    [i]Especially[/i] someone who had to fake injuries to get inside the Cathedral."
*elseif (paladin = "enchantment")
    [i]Especially[/i] someone who's placed a curse on the entirety of the Paladin Order."
*else
    [i]Especially[/i] someone who's just decimated the entirety of the Paladin Order."

[i]Jove damn it.[/i]

*choice
    #I beg Ante to let me pass.
        *set emotional %+ 15
        *set preemotional %+ 15
        "Ante, there is no time to explain. Please, just let me—"
        
        "[i]You will step away from the door, ${sirdame}[/i]," she says, her grip steady around her pair of black daggers. "This is your last warning…"
    #Beg? Try [i]threaten[/i]. Surely she understands who she's dealing with.
        *set noble %- 15
        *set prenoble %- 15
        "You must have a death wish, Ante, if you think you can just—"
        
        "[i]You will step away from the door, ${sirdame}[/i]," she says, her grip steady around her pair of black daggers. "You are exhausted and outnumbered besides. Surely you can see your situation for…"
    #I outrank her, by virtue of my retainer status. I order her to stand aside.
        *set emotional %- 15
        *set preemotional %- 15
        "You seem to have forgotten your place, Ante. Step aside before I—"
        
        "[i]You will step away from the door, ${sirdame}[/i]," she says, her grip steady around her pair of black daggers. "I care little for my well-being, when the saintess is in such obvious…"
    #I persuade her to stand down, and watch me as I do my work.
        *set charming %+ 15
        *set precharming %+ 15
        "I mean the saintess no harm, Ante. You're welcome to watch me work if that will—"
        
        "[i]You will step away from the door, ${sirdame}[/i]," she says, her grip steady around her pair of black daggers. "I don't know what manner of fool you take me for, but I won't let you just…"

*page_break The air shifts.
Ante's words fade into white noise as you feel the atmosphere changing, feel the clouds of violent, blistering mana bleeding out from within the saintess's chambers. The acrid energy instantly puts you in mind of Sister's sneering visage, and as the weight of it bears down upon you there is only one conclusion you can draw: the explosion is nigh. It is [i]here[/i].

[i]And Ante is still wasting your time.[/i]

[i]Do not use this power again, ${fname},[/i] Ilya had said when she tended to your wounds. [i]This…this phantasma. It might really kill you next time.[/i]

Her gentle warnings echo in your head like a siren, but you see the situation before you and know you must ignore such wisdom. Here in the Old Cathedral, you are outnumbered eleven-to-one, and behind you the blast is already building. Only one option left to you now.
*fake_choice
    #Call upon ${phant1}.

Your mana veins groan and shriek as @{phantvar Satiel|Airas|Gweila|Nyx}'s power bleeds through you once more, and as it does you feel a rupturing pain the likes of which you've never felt before. Every single cell in your body is igniting violently, caving in upon themselves as they finally break under the ancient load—and though every one of your senses are screaming [i]stop[/i], you force the violent mana to flow through you and bleed into the air.

*if (phant1 = "Satiel")
    Reckoning Light bursts forth from your fingertips, and through the blinding light you can feel rather than see its arc, bounding forward as it tears through Ante's subordinates like a wrecking ball. Ante is screaming as she's caught in the blast, and though a Glyph of Magebane blooms in a circle around her feet Satiel is ancient and powerful and [i]so much more than magic[/i], and all the same she is sent crashing against the stair railing.
    
    You feel quite like collapsing yourself at the end of it all, but you force your eyes open to behold the carnage before you. Ante is cursing and heaving as she paws at her abdomen, and all around her her subordinates lay broken and lifeless on the marble floor.
*elseif (phant1 = "Airas")
    Venom Dance bursts forth from your fingertips, and through the cloud of putrid mist you can feel rather than see its arc, bounding forward as it seeps into the spies' skin and burns their lungs. Ante is screaming as her pores absorb the poison, and though a Glyph of Magebane blooms in a circle around her feet Airas is ancient and powerful and [i]so much more than magic[/i], and all the same she crumples upon herself as the toxin sears through her blood.
    
    You feel quite like collapsing yourself at the end of it all, but you force your eyes open to behold the carnage before you. Ante is cursing and heaving as she paws at her chest, and all around her her subordinates lay broken and lifeless on the marble floor.
*elseif (phant1 = "Gweila")
    ${ultima2} bursts forth from your fingertips, and through the oppressive force of Shaman's Elegy you can feel rather than see its arc, bounding forward as it tears through Ante's subordinates like a wrecking ball. Ante is screaming as she's caught in the blast, and though a Glyph of Magebane blooms in a circle around her feet Gweila is ancient and powerful and [i]so much more than magic[/i], and all the same she is sent crashing against the stair railing.
    
    You feel quite like collapsing yourself at the end of it all, but you force your eyes open to behold the carnage before you. Ante is cursing and heaving as she paws at her abdomen, and all around her her subordinates lay broken and lifeless on the marble floor.
*else
    Plaguehand settles on your fingertips as you lunge forward, Nyx's power launching you into a nimble dance as you methodically flay the enemies before you alive. Ante is screaming as your palms graze her shoulder, and though a Glyph of Magebane blooms in a circle around her feet Nyxl is ancient and powerful and [i]so much more than magic[/i], and all the same she is sent crashing against the stair railing.
    
    You feel quite like collapsing yourself at the end of it all, but you force your eyes open to behold the carnage before you. Ante is cursing and heaving as she paws at her shoulder, and all around her her subordinates lay broken and lifeless on the marble floor.
    
You've killed them. You've killed all of them.
*choice
    #I didn't want to! I had no choice!
        *set emotional %+ 15
        *set preemotional %+ 15
        You are a victim as much as they are, a victim of Sister and of this wretched circumstance.
    #They should've known this was a risk when they chose to get in my way.
        *set noble %- 15
        *set prenoble %- 15
        Did you not tell them to let you pass?  Did you not give them the chance to retreat? They only have themselves to blame, in the end.
    #They would pass anyway if the blast isn't dealt with. This is the lesser evil.
        *set emotional %- 15
        *set preemotional %- 15
        There's no use crying over could-have-beens. There is an arcane bomb that needs defusing, and you're the only one who is up to the task.
        
"Monster," Ante growls from her perch on the floor, her entire body shaking from the effort. "Don't…don't you dare lay a hand on the saintess."

So she says, but the air still trembles with a spell primed to detonate, and you have neither the time nor energy left to cast the dispelling enchantment. Quiet dread simmers in your gut as you're forced to acknowledge the truth. That if the spell is to be defused, then you must commit the highest of all blasphemies. That to save Sienan, you must snuff out its brightest light.

[i]You must kill the saintess.[/i]
*page_break
You turn your back on the spymaster, your fingers scraping along the wall until it finds her dagger, still embedded into marble. You withdraw it in a single, fluid motion, and with painful, hobbling steps you make your way inside the saintess's chambers.

Shiraya Cheilong is seated on a plush white chair at the center of the room, staring blankly ahead even as you approach her with the dagger in your hand. She is still as you kneel in front of her, silent as your arms reach around her back and pull her forward.

[i]Stop.[/i] You can hear Ante's voice as you cradle the saintess in your arms, the urgent cadence in her voice as she begs you to show mercy. [i]Stop.[/i]

You sink the dagger into the saintess's heart.

She takes one last shuddering breath, and as she does a spark of lucidity returns to her eyes. Her head shifts as she regards you, and even as she bleeds to her death the emotions swirling in those brown eyes are unmistakable: serenity, peace, and gratitude.

She passes quietly in your arms, and your consciousness leaves you.

*page_break
…
*page_break
"Why have you done this?"

It was a struggle to even look up at the familiar face. It's your seventh day in the dungeon, though of even that much you couldn't be sure—days pass by at a lethargic pace in your solitary confinement, and you only have the guard rotations to supplement your judgment.

Your hands lay limp at your side, body rotting and weakened—from the odious slop they've been feeding you, the layers of magical bindings that pull taut around your wrists. And yet the guards still kicked up a fuss about letting the king into your cell—you almost want to laugh. Leon would give you a run for your money even at your prime; the hollow shell of a mage that has taken your place poses no more threat to the warrior-king than an ant.

The blond holds your gaze, his face inches away from your own, a million different emotions swirling in his eyes. "I'll ask you again," he says, steel in his voice. "Why have you done this?"

*temp leonachieve 0
*temp leonact false
*choice
  #Insist on your innocence.
    *set optimistic %+ 15
    *set preoptimistic %+ 15
    *set emotional %+ 15
    *set preemotional %+ 15
    *set leonachieve 1
    "Please, you have to believe me," you plead, voice barely audible. "I'm innocent. I truly am."

    "I want to believe you, ${fname}. So tell me the truth. Tell me what happened."

    You try not to let your tears spill out. "I-I can't tell you. I really can't. But I would never hurt you, or Saine or Ilya or your people. Please, you know that."

    He laughs, the sound hollow as it echoes through the dungeon. "You must mistake me for the fool of a boy you met in the Esteram Forest all those years ago. I am a king now, ${fname}, and I [i]will[/i] have answers. Or I'll chop your head off myself."

    "Didn't you say you'd trust me?" You say, grasping at the last chip you have in your repertoire. "With your life, until the day you die? Was that all a lie?"

    You flinch as he punches the wall beside your head, stone giving way beneath his knuckles. "I [i]did[/i] trust you! All the times Ante reported you for your suspicious behavior, urged me to stop you, I ignored every single warning! And look where it got me," he's heaving, features twisting in anger. "I will not be made a fool of twice."

    "Leon..."
    *choice
      #"...I understand. And I'm sorry."
        *set noble %+ 15
        *set prenoble %+ 15
        "I've put you through a lot, haven't I," you say ruefully.
        
        "Then you admit your guilt," he says, barely holding himself together. "What you did was atrocious, ${fname}, and I [i]will[/i] see you dead."
        
        "Then so be it," you say…
        *goto sobeit
      #"...I will never forgive you for this."
        *set noble %- 15
        *set prenoble %- 15
        He slugs you across the face, and you taste blood when the hit connects. Gone is the last vestiges of the friendly adventurer you met so long ago—the king instead regards you with a wild-eyed fury. "The gall that you have, murderer. I should have killed you when I had the chance."

        "And I should've let Mireil kill you and yours. Or that Elyssian beast for that matter."

        "I guess we're both fools, then," he laughs bitterly.
        *goto willburn
  #Be evasive.
    *set charming %- 15
    *set precharming %- 15
    *set emotional %- 15
    *set preemotional %- 15
    *set leonachieve 2
    You avoid his gaze, crystal-green and piercing. "What I did was for the good of Param, whether you believe me or not."

    "So you don't deny that you're connected to the massacre. That—that you did it."

    [i]I am connected, but not in the way you're thinking[/i], you want to say, but you feel the arcane collar tighten around your throat. [i]So even that much is forbidden by the curse.[/i] "I have nothing to say to that."

    He punches the wall beside your head, and you hear the stone give way beneath his knuckles. "Do you take me for some kind of fool, [i]${lname}[/i]?" He pronounced your surname as if it was acid, spitting it out with disgust. "The infant prince you met in the forest might have taken you at your word, all those years ago, but I am a king—one whose people you murdered. So tell me the truth. Or I will chop your head off myself."

    "Then so be it," you say...
    *label sobeit
    *choice
      *if (leonrom) #...serenely. Despite it all, I will never regret loving him.
        "Then so be it, Leon." He flinches at the mention of his name, the alias he's been forced to discard; pain and longing are plain in his eyes. "I love you. And I will continue loving you until I draw my last breath."
        
        "You're too cruel," he says, his fury quieting into something else entirely. Desperation. Hurt. "Even if you say this…even so. Unless you tell me the truth, I—I will see you dead."
        
        "Then let me have this." You move forward to meet your forehead with his, even as the bindings pull taut around your neck. The king leans in instinctively, eyes shut tight to bar the tears from spilling forth. "If I am to die, then let me feel the warmth of the Sun one last time."
        
        "Damn you," he growls, his voice trembling despite the words' conviction. His breath is warm against your lips, and you think lucidly that in another life, you would have been able to close the gap. That you would have been his, and he yours. "I hope you're happy that you've played me for a fool. That even after everything you've done, I'm still in love with you. And I will mourn you until the day I die."
        
        He rises to his feet then, and as he exits the cell you can hear him mutter under his breath. Quietly, as if he meant for no one but himself to hear. "Farewell, ${fname}."
        *goto hesgone
      #...resignedly. I can't find it in me to place blame on him.
        *set noble %+ 15
        *set prenoble %+ 15
        "Then so be it, Leon." He flinches at the mention of his name, the alias he's been forced to discard; pain and longing are plain in his eyes. "If one day you come to learn the truth, know that I forgive you."

        "Enough with the mind games," he mutters, voice trembling.

        You manage a little smile. "You don't have to believe me now, but I do mean it."

        Silence, for a while. When he speaks again, you hear the hesitation plain in his voice, though his words scald against your ears. "You're a traitor and a murderer, ${lname}. And I will see you burn. May your death grant peace to all the souls you've murdered."
        *goto hesgone
      #...contemptuously. Anger bubbles up in my throat, burning as it rises.
        *set noble %- 15
        *set prenoble %- 15
        "Then so be it, [i]Your Majesty[/i]," you spit, defiant. "You call me the traitor, but I've not forgotten what you told me. That you would trust me with your life, until the day you die."

        "I said that to my best friend, my staunchest comrade," he says, voice trembling. "I see nothing in front of me but a demon wearing ${their} face."

        You laugh derisively. "How convenient. You've become a true politician."

        "I wish I'd been one all along," he mutters under his breath. 
        *label willburn
        "You will burn like the traitor you are, ${lname}. May your death grant peace to all the souls you've murdered."
        *goto hesgone
  #This is a lost cause. Play the antagonist to the end.
    *set leonact true
    *set charming %+ 15
    *set precharming %+ 15
    *set optimistic %- 15
    *set preoptimistic %- 15
    *set leonachieve 3
    You scoff. "Wouldn't you like to know."
    
    *if (leonrom)
        His face contorts with indescribable anguish. "I really did love you, you know. I'd never have guessed that it would—you would—"
        
        You interrupt him with a derisive laugh, though it burns your throat going up. "Sounds like it was your mistake from the start, then. What's that got to do with me?"
        
        "Are you having fun, ${fname}? Proud that you played me for a fool?" Leon chokes, his voice sounding as if it's been submerged in water. "Ive—Saine. He pleaded with me all night yesterday. Said there must be some bigger picture, that you're innocent somehow and I must spare you."
        
        "Then he's a bigger fool than you are."
        
        Leon's face twists into a grimace at your words, his green eyes searching, [i]demanding[/i] for any trace of the person he thought he knew. "I've been so blind," he rasps, shaking his head. "And the worst thing is—I'd have rather you let me [i]stay[/i] blind. I would've let you go, ${fname}, if you'd just admitted to everything and said you were sorry. We could've staged an execution and snuck you out, if we knew you weren't going to harm us again. You know I would've done it—because like the fool I am, even now [i]I'm still in love with you.[/i]"
        
        The blond cups your face in his hands; you feel the tremble of his fingers against your jaw, see the desperation in his eyes. "So I'm begging you, please—please tell me. Why are you being like this?"
        *goto aggravate
    *else
        His face contorts with disgust. "I really trusted you, you know. All of us did."

        You manage a derisive laugh, though it burns your throat going up. "Sounds like it was your mistake from the start, then. What's that got to do with me?"

        "You are utter filth," he spits. "Ive—Saine. He pleaded with me all night yesterday. Said there must be some bigger picture, that you're innocent somehow and I must spare you."

        "Then he's an even bigger fool than you are."

        You saw the punch coming, of course. Spitting out blood, you look him in the eyes and see the murderous glint. "We could have forgiven you, you know," he says, shaking. "If you had just admitted to everything and said you were sorry. We could've staged an execution and snuck you out, if we knew you weren't going to harm us again. You know we would've considered it. Why are you being like this?"
    
    You feel the arcane collar tighten around your neck and almost burst—into laughter or into tears, you don't quite know. Admitting your motivations was never a possibility, but indeed, why aggravate him?
    *label aggravate
    *choice
      #Doubts on my innocence will only plague him. It'll be easier to hate me entirely.
        *set noble %+ 15
        *set prenoble %+ 15
        You steel your patience and continue the facade. "Arcadia's bloodlust has been sated," you laugh, with a conviction that surprises even yourself. "Thanks to Param's foolish king. I die a martyr for Arcadian glory—I have no regrets."

        Leon backs away, looking stricken. "So it's like that, huh. From the start..." he grimaces, and you think he's close to tears. "A foolish king, indeed."

        It is painful seeing him like this. You try to convince yourself this is what's best in the long run, and yet you find your resolve shaken as you meet his gaze. But you've crossed the point of no return, and so you press onward.
      *if (leonrom = false) #Am I not allowed to spite him? My soon-to-be murderer, whom I saved?
        *set noble %- 15
        *set prenoble %- 15
        You steel yourself, summoning whatever words you think will hurt him the most. "Arcadia's bloodlust has been sated," you laugh, with a conviction that surprises even yourself. "Thanks to Param's foolish king. I die a martyr for Arcadian glory—I have no regrets."

        Leon backs away, looking stricken. "So it's like that, huh. From the start..." he grimaces, and you think he's close to tears. "A foolish king, indeed."

        You savor the taste of this moment, the only oasis of retribution you will glean from your friend-turned-persecutor. Tomorrow, you will burn—and you'll take some peace with you as you do, having had this last laugh.
      *if (leonrom) #Am I not allowed to spite him? My soon-to-be murderer, whom I loved?
        *set noble %- 15
        *set prenoble %- 15
        You steel yourself, summoning whatever words you think will hurt him the most. "Arcadia's bloodlust has been sated," you laugh, with a conviction that surprises even yourself. "Thanks to Param's foolish king. I die a martyr for Arcadian glory—I have no regrets."

        Leon backs away, looking stricken. "So it's like that, huh. From the start..." he grimaces, and you think he's close to tears. "A foolish king, indeed."

        You savor the taste of this moment, the only oasis of retribution you will glean from your lover-turned-persecutor. Tomorrow, you will burn—and you'll take some peace with you as you do, having had this last laugh.
   "Leave me. [i]Your majesty.[/i]"

   He gives you one last glance, and you can't find words to describe the depth of hatred percolating in his eyes. As he exits the cell, you hear him mutter under his breath. "May you never know the peace of Jove's embrace."
   *goto hesgone

*label hesgone
*page_break And he is gone. 
*if (leonachieve = 1)
    *achieve innocent
*elseif (leonachieve = 2)
    *achieve evasive
*else
    *comment (leonachieve = 3)
    *achieve antagonist

Time passes languidly in Leon's absence.

You pass most of it in quiet repose, your focus shared equally on all you've been through and what you'll yet endure—until your reverie is interrupted by a series of violent clangs. You jerk awake, instantly alarmed—if the clamor hadn't already alerted you that something was off, certainly the pitch darkness in what should've been a constantly lit dungeon did.

Someone is here. Someone who shouldn't be.

*page_break
"Wh-who's the—" the guard stationed in front of your cell crumples to the ground before he could finish his sentence. In his place stands what appears to be a shrouded figure, hand glowing with the aftermath of a spell.

*if (emotional > 50)
    "Leave me alone, I beg you. I've gone through enough," you say weakly. Whoever dares to assault the royal dungeons must harbor a wicked vendetta. You are weakened and your powers sealed—you have no means to defend yourself against the torture this person no doubt has planned for you.
    
    "${fname}," replied the figure, her voice soft and high and—familiar. "Calm down. I've come to get you out."
*else
    "Come to kill me?" you ask. Did the people tire of Leon's indecision? Couldn't wait but to finish you off themselves?

    "No, ${fname}. I've come to get you out," replied the figure, and her voice is soft and high and—familiar.

"Ilya?" you manage through your disbelief.

"It's me," she says, and you hear rather than see her smile. "I've cleared a path from here to the keep's eastern gate. Saine is standing by there, he'll take care of the rest. Hold still, I'll break this lock for you."

The cell illuminates as she begins decrypting the complex magical lock, and you regard her for the first time in three months. The same pretty, heart-shaped face you remember, her white hair disheveled and matted with sweat. She's clearly exhausted herself to get to this point.

*choice
    #"You shouldn't have done this. I can't imagine what Leon will do to you."
        *set optimistic %+ 15
        *set preoptimistic %+ 15
        "He's not so bloodthirsty, though I can understand why you'd think otherwise," she says, chuckling mirthlessly. "Besides, with you gone I'll be the kingdom's best mage, not to mention the foremost saintess candidate. I am not someone he can dispose of, treason or not."
        
        *if (charming > 50)
            The snigger escapes your lips before you could stop it. "I'd have never taken you for such a rulebreaker, Ilya. You really have changed a lot, haven't you?"
        *else
            "You would've never done something like this, back in our White Fangs days. You really have changed a lot, haven't you?"
        
        "That's right, ${fname}. So much can happen in just a few years—so much happiness, so much experience, so much growth. So make sure you get out there and experience eighty more."
    #"Thank you for doing this, Ilya."
        "Of course. I don't know what Leon's thinking—it's as if he doesn't know you at all."
        
        It's hard not to hear the unbridled exasperation in her voice. "You don't think I did it."
        
        "Of course not, ${fname}.
        *if (noble > 70)
            You're possibly the kindest, most honorable person I've ever met. You would never be capable of something like this."
        *elseif (noble > 50)
            You're a good person, ${fname}—you would never be capable of something like this."
        *else
            I can see how others might think that, given some of the harsher calls you've made in the past. But I know you're a good person at heart, ${fname}—you would never be capable of something like this."
            
        *if (charming > 50)
            "I'd have never pegged you as the blind faith type, Ilya. Not even an interrogation?"

            "Keep this up, and maybe we'll have one," she sighs. "In all seriousness, I'm sure you'll tell us when you can.
        *else
            "Blind faith is rather unlike you, Ilya."
            
            "I don't need you to tell me that," she sighs. "In all seriousness, I'm sure you'll tell us the whole story when you can.
        So I'll make sure you live to see the day, ${fname}."
    #"Stop it. I did everything they accused me of."
        "Right, because that's exactly what a saintess-killer would say," she says quickly, not even giving your act the time of day. "Whatever you're trying to do right now, stop it.
        *if (noble > 70)
            You're possibly the kindest, most honorable person I've ever met. You would never be capable of something like this."
        *elseif (noble > 50)
            You're a good person, ${fname}—you would never be capable of something like this."
        *else
            You think you can pull a fast one on me just because you've made a couple of harsh calls in the past? You're a good person at heart, ${fname}—you would never be capable of something like this."

        *if (charming > 50)
            The snigger escaped your lips before you could stop it. "I never could fool you, Ilya. You'll forgive me for trying that little gambit, right?"
            
            "As long as you're sorry," she says, chuckling mirthlessly.
        *else
            You grunt under your breath, mourning the foiled gambit. "You could've just played along," you complain weakly.
            
            "How could I, ${fname}? Your acting is atrocious," she says, chuckling mirthlessly.
            
        *if (leonact)
            "Leon believed it."
            
            "He's hardly the standard you should hold yourself to," she counters blithely.

Ilya continues to work on the lock even as she maintains her banter with you. Watching the runes glow and hum under the influence of her magic, you can tell she's making incredible progress. She'll have you out in fifteen minutes, quite possibly less.
*choice
  #Stop her.
    *set noble %+ 15
    *set prenoble %+ 15
    *achieve dontletilya
    "That's enough, Ilya."

    The lock loses its glow, and though you can't see her face you feel it fall all the same. "...Why?"
    *choice
      #"I won't have you and Saine risk yourselves for my sake.:
        *set noble %+ 15
        *set prenoble %+ 15
        "There [i]is[/i] no risk! You think Leon will kill me? Or his own brother?"

        "You can never be too sure."

        "You're full of it, and you know it." You flinch—she has always been assertive, but there's a desperate sort of conviction layering her tone, one you've never heard from her before. "He'll pardon Saine without even blinking. Jail time for me, maybe, but four or five years at most. Against your life, that's a cheap—"

        "And how many will die here in Param, because its best healer is behind bars? How many will treat their traitorous prince with respect, or the corrupt king that pardoned him for that matter?" You shake your head. "That's enough, Ilya. If this country wants to paint me the selfish villain, I'd rather not prove them right."

        "But I-I'm just—" she collapses to the floor, the conviction ironed out of her voice. "This is unfair. You d-deserve better."

        You give a noncommittal grunt. You have to admit that the gesture is sweet, if misguided. "In any case, I'm grateful for the thought. Please pass it on to Saine as well. But you must leave quickly, before the guards wake."
        *label lasttime

        "T-then this is the last time I-I'm gonna see you."
        
        *if (ilyarom)
            You nod. "I'm sorry."

            For a long, tense minute, the dungeon is silent but for the sound of Ilya's sobbing. "I'm sorry, too," she sniffs, devastation plain in her voice. "And ${fname}, I…I love you."
            *choice
                #"I love you too."
                    The healer goes into perfect stillness at that, and you could almost see her searing the words into memory; it is all you could do to watch her outline as she strengthens herself. The heartbreak will be crippling, you're sure—and there will be nothing you can do for her, not when your death will be the cause of her pain.
                #Saying it back would only make things harder for her. I say nothing.
                    The healer goes into perfect stillness, and you could almost make out her expression as she fills in the gaps of your silence.
                    
                    Ilya has always been the perceptive sort, and doubtless she will see through your gambit and know the thoughts that lie at its core. The heartbreak will be crippling, you're sure—and there will be nothing you can do for her, not when your death will be the cause of her pain.
                #I say nothing, because I don't love her back.
                    *set ilyarom false
                    The healer goes into perfect stillness, and you could almost make out her expression as she fills in the gaps, hears the words that's been left unsaid.
                    
                    Ilya has always been the perceptive sort, and doubtless she'll understand the meaning behind your silence. The heartbreak will be crippling, you're sure—but there's no use for her maintaining a flame for a dead @{pronvar man|woman|person}. It is for the best that you do not return her feelings.
        *else
            You nod. "I'm sorry. Live well, Ilya."

        She stays for another minute, but eventually does as you say. You hear the dungeon door open and the healer's step faltering—and it is sobering to think that hers is the last friendly face you will ever see.
        *choice
            #Let her leave.
                *goto cruelfate
            #"Ilya, thank you. You and Saine both—for believing in me."
                *set rilya %+ 10
                *set rsaine %+ 10
                Ilya freezes by the dungeon door. "Of course we'd believe you, ${fname}," she says, her voice a gentle tremble. "But what good is our faith, when tomorrow you die all the same?"
                
                "It means more than you can know. I promise."
                
                The healer is silent, for a while. "It is just like you to repay our failure with solace."
                
                You manage a weak laugh. "I mean every word I said."
                
                "Then I'll trust you, because it's the only thing I can do. I…farewell, ${fname}."
            #"Don't hold a grudge against Leon. Please—he's only done as he had to."
                *set noble %+ 15
                *set prenoble %+ 15
                *set ilyaplsforgiveleon true
                *achieve pleadforleon
                It is a long moment before you hear her reply. "I will try, ${fname}," she replies gently. "For your sake, I promise that I will."
        *label cruelfate
        
        You will yourself to accept your cruel fate as the dungeon door creaks shut with a depressing finality.
        *goto endscene
      #"I'm tired. I've had enough of life as a fugitive, always running from something."
        *set emotional %- 15
        *set preemotional %- 15
        "You can't mean that," she says, voice trembling.

        "I do. These past few years with you guys have been the only time I truly felt alive—I don't think I can go back to how it was before."

        "Then take me with you!" You flinch—she has always been assertive, but there's a desperate sort of conviction layering her tone, one you've never heard from her before. "I owe you my life, ${fname}, and I haven't forgotten that debt even if you have. Where you go, I [i]will[/i] follow."
        
        You have to admit that the gesture is sweet, if misguided. 
        
        *if (ilyasaint)
            "You told me it was your dream to be the saintess."
        *else
            "You have a place here. A family that loves you, and one you love back."

        "Yes, but—"

        "What if three, five years down the line you become tired of the fugitive life, as I have become? What if you resent me for it? What about all the lives that will be lost here in Param, because their best healer has gone rogue?"

        When she replies again, she has lost much of her conviction. "I-I don't owe anything to anyone but you. I can find new dreams, and I—I don't care a lick for people who'd hurt you like this."

        "You can't mean that," you say, as kindly as you can.

        She is still for a while, but then shakes her head as she begins openly sobbing. "N-no, I don't. B-But this...this is unfair. You d-deserve better."

        You laugh, the sound an eerie echo in the silent dungeon. "I really am grateful for the thought, in any case. Please pass it on to Saine as well. But you must leave quickly, before the guards wake."
        *goto lasttime
  #Let it happen. If Ilya is willing to risk herself, then so be it.
    *set noble %- 15
    *set prenoble %- 15
    *achieve letilya
    She continues working on the lock, and the room is dead silent but for the hum of her decryption spell.

    "What a shame, Lady Ilya."

    The voice is quiet and frigid, and you both recognize it immediately as Ante's. Ilya quickly whirls on her, fingers crackling with the foundation of an enchantment, but it snuffs itself out immediately. "Do not bother, milady. I took the liberty of placing a Magebane on you."

    Sure enough, you could see a Glyph of Magebane present under Ilya's feet, its runework camouflaged against the dingy cell floor in a way only Ante is capable of. "Let us go, Ante," the healer growls, a defiant expression etched onto her face. "${fname} is innocent."

    "And what basis underly such claims, milady, beyond the criminal's word and your own rosy nostalgia?"

    "$!{they} would never do what you accuse ${them} of. You don't know ${them} like we do!" 

    "But King Leon does, and even he can see this farce for what it is," Ante drawls, though there is tension in her tone. "You are not wrong to say you are the kingdom's best mage, milady. Please reconsider your treason."

    Alarmingly, Ilya looks ready to try her luck at physical combat. There's no way it will end well for her, least of all with Ante as her opponent. "That's enough, Ilya," you croak, resigned. "This is the end of the road."

    Ante regards you, mildly surprised. "Finally, some wisdom," she says, Ilya bristling beside her. "Will you tell us, then? How you brought Lady Ilya and Prince Iver under your thrall."

    *choice
      #"I guess it [i]would[/i] be hard for you to grasp the concept of friends, Ante."
        *set charming %+ 15
        *set precharming %+ 15
      #"It must have been my good looks and winning personality."
        *set charming %+ 15
        *set precharming %+ 15
      #"I have nothing to say to you."
        *set charming %- 15
        *set precharming %- 15

You could feel rather than hear her sigh. "I suppose I shouldn't have expected anything else." She turns to the healer beside her. "Milady, leave with my adjutant and I shall pretend tonight never happened."

"Go, Ilya," you say quickly, before she does anything reckless. "Thank you for trying."
*goto lasttime
*label endscene

And that was the last you ever saw of her.
*page_break
*set memorypoint "complete_prison"
*goto_scene Junction