Aulain rises into view from the low horizon, its scarred walls and squat structures a grayish blue in the cloudy gloom. The hour should be noon, as far as you can tell, but what sunlight may serve as confirmation has been drowned out by the storm raging overhead.

The air is damp and cold, clinging to your bones like a stubborn grip. ${yusuha} does what ${yhe} can to combat the atmosphere—even now ${yhis} wind barrier hums and swirls around your party, swatting away the bulk of the furious downpour. Though ${yhe} had fulfilled the task flawlessly at first, ${yhis} efforts had begun to flag from exhaustion, and now the stray pelts of rain cling to your garment, basking you with a chilly soak.

${falco} sneezes a few steps ahead, and ${yusuha} gives ${fhim} an apologetic look. The younger mage responds with a baleful stare, though ${fhe} makes nothing bigger of it. After all, no one had expected for the mission to extend to stormy Aulain, which looks at any moment ready to slip into a watery grave. But such is the Saber's lot: you spirit leads out of thin air, and follow them to the ends of Arvanand. You can only hope what lies at the end of this path will be worth the hassle.

You drag your feet past another patch of sunken soil, grimacing as the mud begins to creep into your boots. You're starting to properly realize what a luxury it is, to travel by Spirit Gates. Alas, with Specter having egressed with Razor and Colossus to seek proper treatment, you're down a spiritist.
*if (spiritism > 64)
    And though both you and ${falco} had taken turns on spirit gate duty for the rest of the distance, it's been deemed unwise to continue that for this last stretch. Whoever waits within the city has apparently bested Eli and slain scores of Saint Augur paladins—meaning you'll both need be in fighting form. Reglaire Castle drained you both thoroughly, and the journey here did your mana ducts no favors. It was agreed, then, that ${yusuha} has to pick up the slack for this last stretch.
*else
    That left ${falco} on spirit gate duty, and all by ${fhis} lonesome, at that. And while ${fhe}'s done a serviceable job thus far, it's been deemed unwise for ${fhim} to continue that for this last stretch. Whoever waits within the city has apparently bested Eli and slain scores of Saint Augur paladins, meaning that you'll need ${falco}—juggernaut combatant that ${fhe} is—to be in fighting form. Reglaire Castle had drained ${fhim} thoroughly, and the journey here did ${fhis} mana ducts no favors. It was agreed, then, that ${yusuha} has to pick up the slack for this last stretch.

None of you are pleased about it.
*if (alias)
    And despite the fact the relief you feel at being able to abandon your false name for once, in the grand scheme of things, you are no exception.
    *set fname "${realname}"

"I can't believe we let you rope us into this, Plague," ${yusuha} declares, pushing back strands of ${yhis} hair. They flop wetly against ${yhis} cheek and—to ${yusuha}'s exasperation—swing back to their original place. "I could be sleeping right now. On a warm bed, could you imagine that?"

Eli looks at ${yusuha} sheepishly, ${ehis} own hair clinging fiercely to ${ehis} skin. "For what it's worth, I'm sorry. But I can't just abandon them to their fate."

"You always were a bleeding heart. I see you've deemed that part of you worth retaining. Unwise," ${falco} scoffs, crossing ${fhis} arms.

"But you still agreed to come here and trek through the mud with me," Eli says, giving ${falco} a small smile. "I appreciate it."

${falco} snorts and turns ${fhis} face away. "The only reason I'm here is the possibility of further intel. Don't lump me in with the rest of you."

Despite the harshness of ${falco}'s tone, Eli's smile does not dissipate. "Of course, Zealot."

*choice
    #"Aren't you a little too good at dealing with ${fhim}, Plague?"
        *set reli %+ 5
        The moniker rolls oddly off your tongue. Despite the evident benefits of anonymity in your situation, this whole callsign business still takes some getting used to. It certainly doesn't help that you have to call [i]Eli[/i] of all people by one.
        
        There's a pause before Eli's response comes, and you can't help but wonder if ${ehe} feels the same. "Zealot's been instrumental in the rescue and repatriation of countless Arcadians," ${ehe} finally says, lips edging into a smile. "I tried to do the same while I was with Thulrum, but I wasn't quite as effective. Still, I think we're not so different deep down, ${fhe} and I."
        
        ${falco} makes a face as if Eli had spat in ${fhis} pie. "I'll slice your tongue off while you sleep."
        
        Eli's grin is positively beatific. "It's unbecoming to make false threats."
        
        There's a flash of movement as ${falco} reaches for ${fhis} spear, but ${yusuha} raises a hand to stop ${fhim} before ${fhe} can try anything. "I don't have the energy to deal with this. Whoever attacks first [i]will[/i] be pushed out of the barrier."
        
        *label pahdamn
        ${falco} glares up at the redhead. "Pah. The damn thing barely even works."
        
        "Shall I demonstrate exactly how well it's been working?"
        
        Like a divine punctuation, a bolt of thunder strikes a dead tree outside the barrier and cleaves it nearly in half. ${falco} winces and sagely decides to let the matter rest. "Fine," ${fhe} says shortly, before stalking off to the edge of the wind barrier.
    #"It's alright to admit that you're a good person every now and again, Zealot."
        *set rfalco %+ 5
        The moniker rolls oddly off your tongue. Despite the evident benefits of anonymity in your situation, this whole callsign business still takes some getting used to. Though if nothing else, ${falco}'s callsign at least seems highly appropriate for ${fhim}. Few believe so fervently in a cause as ${fhe}.
        
        "Your chatter never seems to cease," ${falco} says cuttingly. "We should stop hiring minstrels for the Day of Arrival. Clearly we have talent enough in our midst."
        
        "You already consider ${them} one of your own," Eli says, grinning. "I'm glad. It seems you've grown to be quite welcoming in the time I've been away."
        
        ${falco} bristles at the statement, lips pulled into a scowl. "Not nearly as welcoming as the grave. Which is where you'll be headed should you choose to keep this up."
        
        "I may not be the best person to threaten with that," Eli says. "You wouldn't have gone all this way for me if I were so disposable."
        
        ${falco}'s lips twist into a grimace, and—in what seems to you a particularly outsized response—reaches for ${fhis} spear. It's more instinct than intention, you realize, and a quick glance at Eli tells you that ${ehe} likely thinks the same. $!{ehis} stance is perfectly relaxed, and ${ehis} blade remains in its sheathe. And whatever design ${falco} may have had is promptly halted by ${yusuha}, who holds up a tired hand to stop ${fhim}. "I don't have the energy to deal with this. Whoever attacks first [i]will[/i] be pushed out of the barrier."
        
        *goto pahdamn
    #"Has ${fhis} personality always been like this, Fox?"
        *set ryusuha %+ 5
        The moniker rolls oddly off your tongue. Despite the evident benefits of anonymity in your situation, this whole callsign business still takes some getting used to. Though if nothing else, ${yusuha}'s callsign seems to suit ${yhim}.
        
        "$!{fhe}'s always got a bit of a hard edge, our Zealot," ${yusuha} says, reaching out to pat the younger mage on the shoulder. ${falco} bats ${yhis} arm away with a snarl, which the redhead seems to take in stride. "But every now and again we get to see a glimpse of the heart beating in there. Tends to resurface whenever Plague is around—and here we are."
        
        "Zealot's been instrumental in the rescue and repatriation of countless Arcadians," Eli says. "$!{fhe}'s as selfless as ${fhe} is dedicated. I have a lot to learn from ${fhim}."
        
        The alleged @{fvar man|woman} of the hour—and truly, ${falco} is nothing if not predictable—looks as if ${fhe}'s ready to gag. $!{fhis} mouth flutters open and close as ${fhe} grasps at a response, but in the end all ${fhe} manages is an affronted scoff.
        
        "There was a time where you would have spirited some excuse for it," Eli remarks, grinning. "But you're coming around it seems."
        
        ${falco}'s lips twist into a grimace, and—in what seems to you a particularly outsized response—reaches for ${fhis} spear. It's more instinct than intention, you realize, and a quick glance at Eli tells you that ${ehe} likely thinks the same. $!{ehis} stance is perfectly relaxed, and ${ehis} blade remains in its sheathe. Not that it would  have mattered, for whatever design ${falco} may have had is promptly halted by ${yusuha}, who tiredly raises a hand to stop ${fhim}. "I don't have the energy to deal with this. Whoever attacks first [i]will[/i] be pushed out of the barrier."
        
        *goto pahdamn

*choice
    #"What's got ${fhis} knickers in a twist this time?"
        ${yusuha}'s gaze trails after ${falco}, light playing in ${yhis} eyes. "Who can say? My vision extends that far down."
        
        Eli shakes ${ehis} head in apparent reproach. "That's a low blow, Fox."
        
        "Oh, come off it. Given the insults ${fhe} regularly flings our way, ${fhe} should be able to—wait." ${yusuha} rounds on Eli, lips pulled into a grin. "You did that on purpose, didn't you?"
        
        "I don't know what you're talking about," Eli responds. $!{ehis} expression remains neutral—whether that's a sign of sincerity or expertise, you find it impressive all the same.
        
        "Sure, play the fool. But we both know you're not half the saint you portray yourself to be," ${yusuha} says. "Though there are far more obvious giveaways for [i]that[/i]. No saint would dress themelves as ghoulishly as you."
        
        Eli balks at the affront and picks at stray flecks of dust on ${ehis} garment. "There's nothing wrong with my clothes," ${ehe} says. "Look, no blood."
        
        "Isha grant that there were. If nothing else, there'd be less of that abomination for us to look at…"
        *goto abomination
    #"It's almost a relief that ${fhe} hates everyone equally."
        "Oh, ${fhe}'ll make a show of being grumpy, but ${falco} respects Plague a great deal," ${yusuha} remarks. ${falco} is far enough away that ${fhe} can pretend not to hear you, but you still spot ${fhis} form twitching from discomfort. ${yusuha} hides a smile behind ${yhis} sleeve. "They used to be thick as thieves, back in the day. Went on missions together so often that I feared they'd [i]actually[/i] join at the hip."
        
        You ponder the image for a moment—kind, magnanimous Eli, ever a grounding presence, tempering the worst of ${falco}'s hard edges. It's not too difficult to imagine, especially given the ease with which Eli wrangled the prickly spiritist. "I should have liked to see that," you remark."
        
        "Well, you'll be seeing plenty of it from now on. As will I, unfortunately."
        
        You turn to face the redhead. "Unfortunately?"
        
        ${yusuha} turns a contemptuous glare towards Eli. "Come now, ${callsign}. Have you [i]looked[/i] at the @{evar man|woman}?"
        
        Eli balks at the affront and picks at stray flecks of dust on ${ehis} garment. "There's nothing wrong with my clothes," ${ehe} says. "Look, no blood."
        
        "Isha grant that there were. If nothing else, there'd be less of that abomination for us to look at…"
        
        *goto abomination
    #"You've grown a mischievous streak since the last time I saw you, Plague."
        "Is that what it looks like?" Eli says pleasantly. "I was just being friendly."
        
        "You're full of shit and you know it," ${yusuha} scoffs, though not without humor. "Even I don't know how to push ${fhis} buttons so masterfully."
        
        Eli tilts ${ehis} head, amused. "And you accuse [i]me[/i] of lying?"
        
        "$!{fhe} doesn't respect me enough for it to work," ${yusuha} says, waving ${yhis} hand dismissively. "Evidently that's not the case with you. And fair enough, given how much help you've lent to ${fhis} operations over the years. Still think you should lose a few points for that getup, at least."
        
        Eli, detecting the affront, picks at stray flecks of dust on ${ehis} garment. "There's nothing wrong with my clothes," ${ehe} says. "Look, no blood."
        
        "Isha grant that there were. If nothing else, there'd be less of that abomination for us to look at…"
        *label abomination
        
        The abomination in question happens to be a garment that ${falco} had fished out of ${fhis} rucksack, after Eli's magic had you all feeling right as rain. It is a markedly foreign and misshapen ensemble: an oddly-textured, high-collared jacket with lining a harsh shade of green, worn over a pale tunic fashioned from low-quality thread. Tying it all together is a familiar ring of interlocked golden squares, gleaming softly as it dangles from Eli's neck.
        
        Eli is by no means an unattractive @{evar man|woman}. In fact, the years you'd been apart had been nothing but kind to ${ehim}, filling out ${ehis} once-scrawny figure and lending a confident gait to ${ehis} stride. But even so, you have to admit that ${ehis} outfit of choice has made ${ehim}…difficult to look at.

*choice
    #"Don't listen to ${yhim}. You look good, Plague."
        *set reli %+ 4
        Eli smiles to ${ehim}self, and does not quite meet your eyes. The look ${yusuha} gives you, on the other hand, is positively [i]withering[/i]. "You're encouraging ${ehim}. $!{ehe} looks like a court jester and you're encouraging ${ehim}."
        
        "I've never seen a better-looking court jester," you say.
        
        "I don't think I look like a court jester," Eli says.
        
        "Shush," ${yusuha} says, holding a finger up to Eli's face. "$!{ehe}'s racked up a fair bit of goodwill with you, ${callsign}. I understand that. But think of all the long missions which lie ahead, where you'll be [i]forced[/i] to constantly look at that thing. You have a chance at making both of our lives easier. I trust that you'll make the right choice."
        
        "This is all a little harsh," Eli protests, brows furrowed. "It's comfortable, allows for a large range of movement. I like it."
    #"Does the Saber not have coin enough to make ${ehim} another set?"
        *set ryusuha %+ 4
        Eli looks as if you've pressed a dagger between ${ehis} ribs. "${fname}…"
        
        "It's ${callsign} until we get back," ${yusuha} chides briefly, before turning ${yhis} attention on you. "And we [i]did[/i] make ${ehim} other sets. Plural. Nothing ever seized ${ehis} fancy the way that thing has, unfortunately."
        
        You tilt your head at that. The garment had come from [i]${falco}'s[/i] rucksack, after all. "You left it behind when you departed from Thulrum."
        
        "I earned a bit of goodwill in the right places," Eli says, and you immediately know ${ehe}'s underplaying ${ehis} contributions. There's likely some village out there which would long have fallen apart without ${ehis} meddling, but few can match ${ehis} talent in parrying inquiries. "I was lucky enough to find someone willing to furnish my requests, specific though they may be."
        
        ${yusuha} slams a palm against ${yhis} face. "And you didn't part with the knockoff until your captors forced you to, I'd bet. Isha-on-high, you've been terrorizing the countryside."
        
        "That's a little harsh," Eli protests, brows furrowed. "It was a comfortable set, as is this one. Allows for a large range of movement. I like it."
    #"Isn't ${ehis} outfit Saber-issued? Sounds like you had your chance to stop ${ehim}."
        *set reli %+ 4
        "It was just a bad joke, I'll have you know. And I wasn't even the one responsible for it," ${yusuha} sighs. "Plague here was being a real menace to the quartermaster—"
        
        "I may have broken a few training swords," Eli interjects hastily.
        
        "You cleaned out nearly half the supply—one day before the templars were scheduled to hold their monthly training camp," ${yusuha} corrects. "All this before you were formally recruited into the Saber, to boot."
        
        You heave a sigh at that. Eli's gaffe is a little too easy to believe—the Salantir royal guards had access to sturdy, top-of-the-line training swords, and the exercises they run through take full advantage of that. Given that Eli had learned under a royal spellblade, ${ehis} mana-enhanced swordsmanship must have paired poorly with standard wooden blades. "So Mys—that is, the quartermaster—saddled ${ehim} with this garment as punishment?"
        
        "Got it in one," ${yusuha} confirms. "She had a second one made in the meantime, something less difficult on the eyes. Sent it to ${ehis} doorstep a month or so into ${ehis} tenure as a Saber. She hadn't counted on Plague taking a liking to her prank, and had the gall to [i]shrug[/i] when ${ehe} sent it back." ${yusuha} pinches the bridge of ${yhis} nose. "Damn the woman. She's not the one who has to see @{evar the bastard|the fool} wear it every mission!"
        
        Eli crosses ${ehis} arms. "It's comfortable, allows for a large range of movement. I like it."
    #"You're still wearing that necklace."
        *set reli %+ 8
        Instinctively, Eli rests a hand upon the chain of linked gold, fingers trailing along its smooth surface. Satyran gold is a metal of the highest quality, and even the decade that's passed since the necklace's inception could do nothing to dull its shine and polish. Eli's gaze on you is at once intent and warm, and you hear ${ehis} sentiment as plainly as if ${ehe} had put it to word.
        
        That ${ehe} considers the item ${ehis} most prized possession, and ${ehe} would sooner die than part ways with it.
        
        "I do recall ${ehim} saying ${ehe}'d gotten it from an old friend," ${yusuha} says with a sideways glance. "I suppose I should have put two and two together."
        
        "I seem to recall you had some choice words for it," Eli points out, lips pulling into a grin. "'An addition so ghastly that not even Myst could have devised—'"
        
        "That's because I thought someone as deranged as [i]you[/i] had made it," ${yusuha} interjects. "Now that I know ${callsign} is to blame—that is, to [i]credit[/i]—it seems positively rustic. Wonderful, even."
        
        Eli raises a brow at ${yhim}. "Is that right?"
        
        "It is," ${yusuha} confirms. "And at any rate, it's hardly the biggest offender. That honor falls to that wretched coat you have on."
        
        "That's harsh," Eli protests. "It's comfortable, allows for a large range of movement. I like it."

*choice
    #"Then that's all that matters, Eli. Don't you pay ${yhim} any mind."
        *set reli %+ 5
        Your words elicit a grin from Eli, and a groan from ${yusuha}. "You are a menace," ${yhe} declares. "I'm going to make you see the light if it's the last thing I do. [i]Both of you[/i]."
    #"Is there nothing we can do to convince you to part ways with it?"
        *set reli %- 2
        "Not you too," ${ehe} whimpers.
        
        "Just give it a proper think, yeah?" ${yusuha} says, reaching around and patting Eli on the shoulder. "We'll get Myst to get you something similar. Just not in this material, and [i]certainly[/i] not in this color."
        
        "I won't promise you anything," Eli says tightly.
        
        ${yusuha} groans. "We'll make you see the light yet."
    #"Well, as long as it lets you fight well."
        "You won't need to worry about that," Eli says freely, affecting ${ehis} most reassuring smile. "These two would never put up with me if I couldn't hold my own in battle."
                
        "I can't disagree with that, unfortunately," ${yusuha} sniffs. "But I resent you sounding like you're proud of it."
        
        Eli tilts ${ehis} head, confused. "That I'm a good fighter?"
        
        "That you're good enough that we'll tolerate this affront to the senses."
        
        Eli grins. "Thanks for that."
        
        "I'll make you see the light yet," ${yusuha} grumbles under ${yhis} breath.
        
There's a lull in the conversation, then, and the drumming of raindrops and sweeping of the winds are heavy in your ears. The silence makes you cognizant of that ineffable feeling percolating in the air. You can taste it in the back of your mouth, in every word which dives from your tongue. A strangled, contrived normalcy, as if all the elephants of Arvanand do not stand in the room with you.

Nothing about this is normal. But it's been so much easier to pretend.

To ${yhis} credit, ${yusuha} is quick to pick up on the strange, dormant tension in the air, weighty with the load of words unsaid. "I'll check up on Zealot," ${yhe} says lightly, stretching ${yhis} arms overhead. None of you are fooled by the pretext. You appreciate it all the same. "We'll be in a bind if ${fhe} decides to sulk."

"You do that," Eli says with a small smile, though you don't miss the weight of ${ehis} tone. Anxiety—though who can say if you're projecting?

${yusuha} dips ${yhis} head lightly and strides on ahead, wrapping a friendly arm around ${falco} as ${yhe} comes up on the younger mage. The standard bickering ensues, though their precise words are swallowed by the storm's pulsing din.

*page_break Leaving only the two of you.

You fix a wry gaze on the muddy ground, half wishing for it to swallow you whole. When the mask came off so did your inhibitions, and your tales and confessions ran free as if a floodgate had opened. You beheld a familiar hand and reached for it hungrily, desperately. Built a sanctuary in Eli's sympathetic eyes and willing ears, a place where at last you can lay your burdens down. And Eli sat there, listening, as you knew ${ehe} would, because that's what ${ehe} always did.

It seems obvious that Eli would always be Eli: a sturdy, reliable rock in the storm. It occurs too late to you that ${ehe} had told you little about ${ehim}self, what ${ehe} had been up to over the years. The parts of ${ehim} which had changed, the parts which had stayed the same.

The mere thought of it lingers like bad ale in the back of your mouth. Eli had always been one of your closest acquaintances, a constant, grounding presence as you braved the winds of change. $!{ehe} had ground ${ehis} teeth as Thaubal carved runes into you, fingers pale around the bars of ${ehis} cell. $!{ehe} had pored over tomes and crafted clumsy spell circles. Stayed by your side as Sister raced ahead to her prodigious destiny, the one which would eventually swallow you all.

And here you stand in its aftermath. Sister is a cold and distant memory, a guardian turned murderer and buried six feet under. And Eli—sweet, gracious Eli, who had laid down ${ehis} life so that you might live—is here in the flesh. Warm. Real.

Wearing a different face, walking with a different gait.

You sneak a sideways glance, taking in the awkward way with which ${ehe} holds the back of ${ehis} neck. It's difficult still to shake the image of that noble, upstanding @{evar boy|girl} who had stolen away with you in the night. How old had ${ehe} been when ${ehe} made ${ehim}self martyr? Fourteen, fifteen? There was a youthfulness to ${ehis} features, a fullness to ${ehis} cheeks which had since hollowed out. $!{ehe} keeps ${ehis} hair longer than the royal knights' mandated @{evar military crop|bob}, and ${ehis} tan is more prominent now. Years out in the field instead of within the Grand Duke's hallowed keep will do that to a @{evar man|woman}, you suppose.

But all of this is superficial. What really strikes you is a simple, singular fact: that Eli has been working for Arcadia. For [i]Tahlia[/i]. The selfsame woman who had so readily claimed responsibility for Sister's ascent. For the very throne from which she supped on the continent's blood.

*choice
    #I wonder how much ${ehe} knew, and what set ${ehim} on this path.
        *set emotional %- 15
        And that's really the question at the center of things, isn't it? Was ${ehe} led by ${ehis} nose by Tahlia, secretive woman that she is, fully ignorant of her role in Sister's insurrection? Is ${ehe} a loyalist the way that ${falco} is, someone who would excuse Tahlia's more ruthless acts in favor of her noble goals? Or was ${ehe} a hapless victim pressed into her service, who had then egressed the second that ${ehe} had the chance?
        
        And most pertinently of all—where does that leave you when all is said and done?
        
        It's a many-headed dragon, and you're not sure which angle to use in prising answers from ${ehim}. When you learned that Eli yet lived, it was all you could do to throw yourself bodily into the rescue. You banished all thoughts of complications to the recesses of your mind, to be considered at a later time. Well, said later time has arrived. Here stands a ghost from your past, against all odds, and there is such a twist to your stars that you're not certain things may ever be the same.
    #Well and good. Now we fight for the same cause.
        *set emotional %- 15
        Still, there is the question of motivations to consider. What ties bound ${ehim} to Arcadia, and why did ${ehe} break free of the tethers? You imagine Eli would have felt at home doing Saber work, pulling Arcadians out of unfortunate situations, helping them build a new life in Thulrum. Did ${ehe} take issue with the Saber's methods? Does this mean ${ehis} current partnership with them is transient, to be broken off when circumstances change?
        
        And most pertinently of all—where does that leave you when all is said and done?
        
        It's a many-headed dragon, and you're not sure which angle to use in prising answers from ${ehim}. When you learned that Eli yet lived, it was all you could do to throw yourself bodily into the rescue. You banished all thoughts of complications to the recesses of your mind, to be considered at a later time. Well, said later time has arrived. Here stands a ghost from your past, against all odds, and there is such a twist to your stars that you're not certain things may ever be the same.
    #I'm not surprised. It's just like Eli to side with the downtrodden, circumstances be damned.
        *set optimistic %+ 15
        Eli never did hold much thought for ${ehis} own preservation. Always all too ready to throw ${ehim}self into peril, so that others may be free of it. Shoulder the weight all alone, and damn the consequences.
        
        (Damn your anguish. The way you had been forced to spend those dark days all alone, trusting no one, jumping at shadows by your bedroll, where ${ehe} should've been. Damn your grief, those nights you spent shivering in the woods, seeing ${ehis} face in the mist of your breath. Lifeless, lost to you. Forever lost to you. Or so you had thought.)
        
        It is easy enough to see why Eli would fall into step with Tahlia, even were she less exacting with ${ehim} than she was with you. The suffering of Arcadians was well-known to you, drew your sympathy even before you were directly faced with it. Eli, on the other hand, counted ${ehim}self among the Saber. Saw for ${ehim}self the work Tahlia's people were doing, the circumstances they rescue Arcadians from. It would be just like ${ehim} to tolerate Tahlia's dealings with Sister, if it meant that more people would successfully be moved to Thulrum, where they could lead a new life unshackled by their troubled past.
    #I wish we'd met sooner, before deeds were done that we can't take back.
        *set emotional %+ 15
        The past few years have seen you don different masks, many of which you struggle to be proud of. Your role in the rebellion shifts depending on who is asked—war hero to some, ruthless slaughterer to others. You had given your all in service to a kingdom which sits upon a trove of Arcadian riches, believing all the while that it was the best path forward. And, when all is said and done, the charge of your execution was not inaccurate. Full true was it that you scattered the lives of Ante's spies with but a wave of your hands, and that you sank your dagger into a defenseless woman's chest.
        
        As for Eli…${ehe} had been a part of the Saber. That much has been made plain to you. $!{ehe} had joined them on their missions, aspired to their honorable goals, and tolerated their excesses. How many have died in ${ehis} kindly hands? How many bodies litter ${ehis} noble path?
        
        And does ${ehe} regret any of it?

"Lost in thought?" Eli asks, giving you a small, uncertain smile. "It's…a lot to take in at once."

"That's quite the understatement," you sigh.

"Sorry. I hate to spring this whole Aulain business on you so shortly after, well…" Eli's voice trails off, and the older @{evar man|woman} casts ${ehis} gaze to the ground. "I just can't think of any other way. And the Saber has something to gain from all this, so…"

You wonder at ${ehis} words. Does ${ehe} genuinely think your turmoil is about being thrust into another mission, or is ${ehe} just being obtuse?

Perhaps you ought to take ${ehis} words as a sign. Whether ${ehe} intended to or not, Eli provided a way for you to steer the conversation to safer waters. What ${ehe}'s been up to, what ${ehe} expects on the mission ahead—mundane things, with the cold edge of factuality. Invite no disagreement, leave no space for conflict. Not when your reunion is still so fresh, your emotions so raw.

*choice
    #I'll roll with ${ehis} cues, leaving the discussion for another day.
        *set reli %+ 7
        There is plenty enough to talk about without poking at dangerous sores—at least, not before you've both collected all your wayward thoughts. Perhaps not in the middle of a storm, heading into a mission which would benefit from a united front.
        
        It's not because you're afraid to find out what may come of the discussion. Not at all.
        
        "You seem rather eager to get back to Aulain," you try. The words come a bit stilted, affected by the course of your thoughts. If Eli picked up on it, ${ehe} shows no sign of it, seeming instead to be preoccupied with ${ehis} own relief.
        
        It seems ${ehe} was being willfully obtuse, after all. You make a mental note of it, filing it away for later consideration.
        
        "I am. Eager to get back, I mean," Eli admits. "With things the way they are, I think help will be urgently needed."
        
        "Many would simply wash their hands of it," you point out, knowing full well that Eli isn't the sort. "It's not as if Aulain's troubles are your fault."
                
        Eli shakes ${ehis} head softly. "I've made a lot of friends there. Good people down on their luck, in a city close to collapsing upon itself. Things were already bad enough for them, and now with this new threat rearing its head…it wouldn't feel right, just tossing them to the wolves like that."
    #This conversation needs to be had sometime. It might as well be now.
        It's an uncomfortable thing to consider, in truth. That you might be at a crossroads so soon after being reunited. But if it's your destiny to splinter again, to obey the diverging callings of your heart, then you'd rather know now than later.
        
        You have grieved your separation enough. You mislike the thought of doing so a second time.
    
        "We need to talk." You feel your jaw tensing as the words leave your mouth. You know you have to brace for the worst, but it's not easy. It could never be, not with Eli. "And I don't mean about this mission. We need to talk about Arcadia."
        
        Your phrasing is vague enough that ${ehe} can attempt to dodge your meaning, if ${ehe} had a mind to. To ${ehis} credit, ${ehe} does not do so. "I know," ${ehe} says, the edge of ${ehis} lips curling against ${ehis} teeth. An old tic, and one that you recognize. So ${ehe} [i]has[/i] been dreading the conversation. "It's just…I don't know if this is the time and place for it."
        
        "I struggle to see why it wouldn't be," you press. Calm, but firm. $!{ehe} needs to know that you'll not allow ${ehim} to sidestep this—at least not without effort. "Those two are out of earshot, and there's time enough until we reach Aulain. Time and place."
        
        Eli purses ${ehis} lips, nodding slowly. You know ${ehe} sees your point. "You're right, of course. But the issue isn't with our circumstances. It's with me," ${ehe} finally admits. "Iit's just…I feel like I'm being pulled every which way right now. My mind is in a hundred different places, racing a hundred leagues a minute. I'm worried about my friends in Aulain. I'm frightened about this whole affair, what I may be dragging you into. And I'm…I don't know how to do it justice, how relieved and happy I am, that you're here. That I've managed to find you." Eli laughs awkwardly and swings ${ehis} gaze towards the ground. "Though of course, it's the other way around, isn't it? You were the one to find me, in the end.
        
        "I guess what I'm saying is this: things haven't quite clicked into place for me, and I don't think they will anytime soon, given….well, everything I'm still trying to piece together how I feel, what I want to do about it. I'm scared that if we have this conversation now, I'll say something stupid and just…ruin everything."
        *choice
            #I tell ${ehim} I understand. We can have this talk later.
                *set reli %+ 7
                Eli's features light up with relief. It's blinding enough that you find yourself instinctively turning your gaze away.
                
                "Thank you," ${ehe} says, quietly thoughtful. "We [i]will[/i] talk about it, I promise."
                
                "I'll hold you to that. Though it'll be a while yet before we return to Thulrum." You glance up at Eli, then, considering. Eli is clamming up on the matter of Arcadia, but perhaps ${ehe}'ll be more forthcoming about other aspects of ${ehis} life. "You seem rather eager to get back to Aulain."
                
                "I am. With things the way they are, I think help will be urgently needed," Eli admits. 
                
                "Many would simply wash their hands of it," you point out, knowing full well that Eli isn't the sort. "It's not as if Aulain's troubles are your fault."
                
                Eli shakes ${ehis} head softly. "I've made a lot of friends there. Good people down on their luck, in a city close to collapsing upon itself. Things were already bad enough for them, and now with this new threat rearing its head…it wouldn't feel right, just tossing them to the wolves like that."
            #I want the truth, raw and unfiltered. Not some artificial, dressed up version of it.
                "It doesn't have to be so complex," you say, trying to rein in your frustration. "I just want you to talk to me."
                
                "I…can't do that right now," ${ehe} says, seemingly with great difficulty. "Not in the way that you want, in the way that counts."
                
                "Because you need to come up with an acceptable lie?"
                
                "${fname}…"
                
                "Give me something, at least," you sigh, offering the words like an olive branch. Perhaps you can settle for a middle ground. "You've become so tied up with Aulain. Enough to be desperate to get back there, despite everything. Why?"

                "Aulain's been facing a bit of a crisis," Eli says, and really, of course it has. Nothing would bind Eli more surely to a cause than people in need. "I've made a lot of friends there. Good people down on their luck, in a city close to collapsing upon itself. Things were already bad enough for them, and now with this new threat rearing its head…it wouldn't feel right, just tossing them to the wolves like that."
                
"And who exactly is [i]them[/i]?" you ask.
        
Eli pauses for a moment, considering. "Have you ever heard of the Order of Saint Augur?"
        
You nod your head slowly. "Heard of it, yes. But I'm hardly familiar," you admit. "It's a religious order based out of Aulain, isn't it? Warriors in service to the Church of Jove, like Sienan's paladins?"
        
"Officially, yes," Eli concedes, one hand rubbing at the back of ${ehis} neck. "Though it's a much smaller operation, and more concerned with keeping the peace than with praying to Jove. Aulain has quite the notorious bandit problem, what with it being so close to the border; the local commander recruited me after seeing me fight off a couple of them—that would be Father Gerian."
        
You pause to consider ${ehis} words. "And you agreed?"
        
"I'm no Jovian faithful, but the Order does good work," ${ehe} shrugs. "I don't regret joining up with them."

*temp encounter false
*temp canskip false
*label elihub
*choice
    *disable_reuse #"What's the situation like in Aulain?"
        "Not great," ${ehe} admits with some reluctance. "Aulain's waterways have been struggling to keep up with the rainfall in recent years, and this storm is worse than anything I've ever seen. I fear a greatflood may be imminent."
        
        You fix a look on ${ehim}. "And what do you hope for us to accomplish against a natural disaster?"
        
        "There are a couple of avenues we could explore, but the discussion is moot until we know what's going on inside the city," Eli says. "The other members of the Order will be hard at work, I think. They should provision us with the details we need to formulate a proper plan."
        
        You consider ${ehis} words for a moment. If this Order is what Eli says it is, then his proposed course of action seems a sizable overreach. "Shouldn't this be the responsibility of Aulain's rulers?"
        
        Eli's expression turns dark. "Yes. But Aulain's nobility is…flawed, to say the least," ${ehe} says. "It's unlikely that they'd look after anyone's interests but their own. Theirs, and that of their Trueblades."
        
        "Trueblades?"
        
        "Aulain's official peacekeeping force, at least on paper. In truth, they're but pawns of the nobility. Hedge knights and mercenaries, the lot of them, barking when their masters whistle and jingle coins in front of them," Eli explains bitterly. "It is the Order which actually hunts down criminals and resolves conflicts, and so the nobility has graciously allowed us to coexist alongside the Trueblades. We may be a rivaling force, but a useful one."
        
        "I'm getting the sense you haven't the highest opinion. Of either the nobility or the Trueblades."
        
        "I must be getting sloppy," Eli declares, though not without humor. "The commander would have chewed me out for it. We have trouble enough without the nobles breathing down our necks."
        *goto elihub
    *disable_reuse #"Just who is it that we're up against, anyway?"
        *set encounter true
        Eli scratches at the back of ${ehis} head. "I wish I could tell you, but I don't have much of a clue, either. They showed up in Aulain one day, went after a couple of local orphans in the dead of night. The Order's leadership sent me and a couple of other knights on the case. They turned up easily enough—they're not great at covering their tracks, or perhaps just never bothered—but we were…outmatched." A grim look enters Eli's eyes, one that you know well. You'd hazard a guess ${ehis} companions didn't survive the encounter. "We managed to hold them off long enough for Father Gerian to escape with the kids, but at great cost."
        
        "They captured you," you say quietly, sidestepping the elephant in the room. "It's no easy feat, to best an arcanist in combat. And an Arcadia-trained one, at that. You said there were only two assailants?"
        
        Eli nods by way of confirmation. "A girl and a boy—twins, from what I could gather. That enchanter in Reglaire Castle wasn't present at Aulain, as far as I know."
        *goto elihub
    *disable_reuse *if (encounter) #"Tell us more about your encounter with them."
        "It was rough. Humiliating, even. They had us on the backfoot the whole time," Eli laments, gritting ${ehis} teeth. "The boy was a lancer, and the girl wielded a scythe. Both had access to strong thaum, and they were able to seamlessly cast while engaging in close-range combat. I was able to stall them by blocking the exits and keeping my arcana active at all times. But my mana ran out, and they got to me not long after that. Knocked me out like a light, and well…you know the rest."
        
        "Was their thaum truly so strong?"
        
        "Yes," ${ehe} replies immediately. "Strong enough to rival some of Arvanand's finest thaumers. Though the greater danger is how [i]quickly[/i] they can string the spells together, one after another. That, combined with the fact that their melee combat doesn't seem to be compromised by their multitasking."
        
        "Sounds like a nightmare to deal with," you acknowledge. "But we have the numbers advantage. To make no mention of the fact that we're all arcanists."
        
        Eli nods, ${ehis} expression grim. "I'm counting on that, too."
        *goto elihub
    #I've learned everything I need to know.
        *goto postelihub

*label postelihub

"I see," Eli says, after you tell ${ehim} as much. "Then…I should catch up with ${yusuha} and ${falco}. Keep them apprised of the situation."

"You should," you agree, carefully keeping the reluctance from your tone. "I'll be there in a bit. I have some thinking to do."

"Mm." Eli begins to stride ahead, then, ${ehis} steps too resolute to be natural. But after a few paces ${ehe} turns around, brown eyes evenly meeting yours. "${fname}, I…" Eli's voice comes out hoarse, and ${ehe} takes a moment to clear ${ehis} throat. "Whatever else may happen, I'm glad we got to meet like this. Well. Glad is a poor word for it, but I'm sure you understand."

You give ${ehim} a nod—it seems the right thing to do. "You should go before ${falco} makes a scene," you call out after ${ehim}. "$!{fhe} seems the sort to hate being left in the dark."

"You already have the measure of ${fhim}, I see."

"And I'll have yours soon enough."

Eli offers you a smile at that—carefully restrained, as if ${ehe} doesn't dare presume overmuch—before turning back around and going on ${ehis} way.

*page_break

The storm only worsens by the time you enter Aulain proper, the rainfall so heavy that your vision extends only a few paces ahead. The city gates have been left unmanned, for no one sane would have designs of visiting Aulain in this weather. You cross under the portcullis uneventfully, emerging onto a thoroughfare flanked by a pair of wide gutters filled with rushing water. You watch them warily as you make your way forward. Much of Aulain's ancient, expansive waterways have been destroyed by centuries of warfare, and the city courts a greatflood more and more closely each year.

A revitalization project ordered by the Grand Duchy ground to a halt when the Parami-Salantir war broke out, and it remained dormant as Salantira City erupted in a violent post-war power struggle. Now Aulain's very air stinks of wry hope and desperation—that the capital can sort itself out before Aulain completes its surrender to the merciless rain.

The city's desolate silence puts Eli in a dark mood, and ${ehe} hastens ${ehis} steps at the head of the party. The older mage proves that ${ehe} knows Aulain as well as ${ehe} claims. $!{ehe} accesses a tangle of impossibly narrow alleyways flanked by tall buildings, all of them set into wayward leans by the uneven topography. The roofing and balconies of residential buildings overlap with one another overhead, forming a natural barrier against much of the downpour. ${yusuha} sighs in relief and relaxes ${yhis} wind barrier, setting it to a gentle, lazy swirl.

${falco}'s brows knit as ${fhe} surveys the road ahead. "How far to your contact?"

"We're very close," Eli says. "Saint's Street is right up ahead…"

True to Eli's words, as you round the next corner, a new section of Aulain shows itself to you. Saint's Street crouches in the shade of the southern wall's battlements, the weathered tip of which reaches inward like a blocky claw. The strange architectural choice provisions the street with much-needed shelter from the ongoing storm. A maze of scaffolding sprouts from the battlements' edges, spilling out into the thoroughfare, topped with an expansive mass of tar-coated canvas. The corners of the sheet droop low on either side of the scaffolding, feeding a rush of rainwater into moat-like gutters.

Under the haphazard construct, the single biggest mass of people you've ever laid eyes on huddle together, shivering and soaked to the bone. Resignation and fear are thick in the air, and the stench of something rotten is mixed in with the petrichor. Realization washes over you like ice. Even with the greatflood still an uncertain threat on the horizon, the squalor it sets into motion takes its toll all the same.

Eli forces a firm, stalwart stance as ${ehe} navigates through the crowd of bodies, but the dark look in ${ehis} eyes is unmistakable. ${yusuha} reaches out a comforting hand but falters, and ${yhis} hand falls limply by ${yhis} side.

*choice
    #I pick up where ${yusuha} left off, and reach for Eli's shoulder.
        Eli stills for a moment when ${ehe} feels your hand, then reaches up and grasps it, firm and quick. $!{ehe} lets it go after a moment and you let it drop, watching as Eli strides onward, ${ehis} posture straighter, ${ehis} steps more solid.
        
        The sheltering townsfolk do not so much as look at you as you pass by, their stares instead favoring the rain-streaked ground. You feel a pulse of mana thrumming in your mask, the enchantment it powers hard at work.
        
        *label wardpercept
        ${yusuha} had alleged that it wards the perception of others, making it so that you appear as a formless piece of the scenery, like an ambient noise or a rush of drifting leaves. Eminently useful in situations such as these, though it would be more so if you didn't have to ration it so aggressively. It appears only a select few in all of Thulrum can recharge the enchantment, and at a steep price, at that. But the results seem well worth the hassle, as none among the citizenry so much as spares you a second glance.
        
        A dark-haired woman stands by the edge of the scaffolding, eyes warily scanning the crowd, one hand resting on the hilt of her blade. The sigil on her half-plate armor is distinct: a sword set into a stone, enwreathed with rays of light—the crest of the Order of Saint Augur. Eli's steps quicken when ${ehe} spots her, doffing ${ehis} beaked, crow-like mask as ${ehe} does.
    #I urge Eli to slow down.
        "Slow down, Plague. You could hurt someone."
        
        It takes a moment for Eli to process your words, and you can see ${ehim} centering ${ehim}self, breaking away from the zeal powering ${ehis} strides. So tangibly that it might as well be a physical act.
        
        $!{ehe} takes a cursory glance at ${ehis} surroundings, for the first time [i]seeing[/i] the squalor rather than thinking of it. Noticing the way ${ehe} tracks mud through the shelter, spraying dirty water on some poor girl's already-drab skirt. The apology must itch on ${ehis} tongue, you think grimly. But ${ehe} knows as well as you do that putting it to words would be a futile exercise.
        
        After all, the girl doesn't even notice the affront. Doesn't notice the @{evar man|woman} responsible for it, nor the masked figures bringing up ${ehis} rear. Like all the other sheltering townsfolk, her gaze favors only the rain-streaked ground. And it's by design. A pulse of mana thrums in your mask, the enchantment it powers hard at work.
        
        *goto wardpercept
    #I trail wordlessly after ${ehim}.
        *set charming %- 15
        There's a blind, senseless zeal to Eli's strides, as if ${ehis} attention is fixed on the far horizon, away from Saint's Street and its pervasive mire. $!{ehe} thinks of the squalor but does not [i]see[/i] it. Does not flinch when ${ehis} steps disturb a puddle and spray dirty water on some poor girl's already-drab skirt. $!{ehe} would have been horrified, you think grimly, had ${ehis} mind not been a thousand leagues away. As it stands, ${ehe} doesn't spare the girl a single glance, and she ignores ${ehim} in turn.
        
        As a matter of fact, the girl ignores you all. Like all the other sheltering townsfolk, she doesn't so much as look up as you weave through the throng, her stare instead favoring the rain-streaked ground. You feel a pulse of mana thrumming in your mask, the enchantment it powers hard at work.
        
        *goto wardpercept
        
*page_break "Kalla."

The woman jerks around when she hears the question, her blade half-drawn in its scabbard. But as soon as she catches sight of Eli's face, her wariness melts into relief. "Eli," she says, disbelief coloring her tone. "But how…? Father Gerian told me that they took you—never mind, I'm glad to see you made it back safely."

"Thank you, but we have pressing things to attend to," Eli says briefly. "Is a greatflood imminent?"

Kalla bites down on her lip and drops her voice to a whisper. "I don't know. Our ranks are in disarray, and we haven't been able to organize a proper survey of the waterways."

Eli glares at her fiercely. "But you gathered them at Saint's Street? If a greatflood hits, everyone here will die."

"You think I don't know that? Damn it, Eli, I'm risking my own life too," she hisses. "Meviel's squad is trying to arrange for evacuation caravans to the highcity. Jove knows what awaits us up there—not much better than just staying here, or so Meviel's envoys tell us—but we're hurting for options after what happened at the Cathedral."

Eli stills beside you. "What happened?"

"You…you don't know." Kalla purses her lips, then tosses her gaze to the ground. "There was an attack on the Cathedral last night. A dozen squires and five knights lost their lives. Among the casualties…is the Commander, Father Gerian."

*choice
    #My heart sinks at the news. I wish we'd been able to come sooner.
        *set emotional %+ 15
        You had known something foul is brewing on Aulain's streets. A powerful force has made its nest in the city's shadows, hiding talons so sharp that even Eli found ${ehim}self bested. Eli, a career @{evar swordsman|swordswoman} and an arcanist besides. 
        
        The poor, mundane knights of the Order never stood a chance. Not without your aid—and now that it's late in coming, Father Gerian and his subordinates have paid the price.
        
        It's easy enough to make a bargain of the circumstances. It's not as if you took your sweet time getting here—in fact, your pace was likely far quicker than is wise, given how winded you were after Reglaire. And even if you had pushed yourself beyond all reason, forced a path of spirit gates despite the consequences, it would likely still have been too late for Father Gerian. $!{ehis} death was tragic, but unavoidable, and the blame does not rest with you.
        
        (It's one thing to make rationalizations. It's another thing entirely to believe them.)
    #I duly note the information. It appears we face a capable and ruthless enemy.
        *set noble %- 15
        You knew they were strong—to think otherwise would be to mock Eli, who they had subdued and made a captive of—but Kalla's account tells you they're not above kidnapping children and killing inexperienced squires. You're dealing with trained killers, the likes of which seldom operate without a broader agenda and some greater force backing them. Should you eventually come to blows, there can be no room for mercy. Only the untangling of the complex web they've woven, ensuring whatever horrors they seek to further inflict are laid to rest, here and now.
        
        To say nothing of the fact that they may be connected to the attack on Thulrum. If they are—if they've made a habit of endangering civilian lives—then they are owed nothing but the cold edge of a guillotine blade.
    #I'm mostly concerned for Eli. The loss of ${ehis} commander must cut deep.
        *set noble %+ 15
        Eli hasn't spoken much about the Father and his Order, but it's nevertheless plain that ${ehe} holds great respect for them. With ${ehis} talents as a @{evar swordsman|swordswoman} and arcanist both, ${ehe} would have been able to make an easy living no matter where ${ehe} went. That ${ehe} decided to put down roots in solitary Aulain, with its drab weather and notoriously troubled politics, speaks volumes of what ${ehe} saw in the Aulaini. And from what little you've managed to glean about him, the Father seems an exemplar of Aulaini virtues. Resilient, selfless, wise.
        
        His loss is a tragedy in anyone's eyes. You imagine it's even moreso when one has worked so closely with him, the way that Eli has.
    #A shame there were no witnesses. Facing such an enemy demands intel and preparation.
        *set emotional %- 15
        Reglaire was a more torrid affair than you were expecting, and whatever lead you're chasing is likely to be an extension of it. With Specter and the others out of commission, you're down three members—not quite at half strength, given the gulf of power between the Saber's footsoldiers and its arcanists, but less boots on the ground all the same. Eli's commander lies slain in his own stronghold, and his vaunted Order has all but collapsed in its wake. You know precious little about what you're up against, except that it's dangerous.
        
        You grit your teeth, lamenting the way you've been forced on the backfoot. You can't shake the feeling that whatever force lies at the center of these troubles are toying with you. Watching with amusement as you chase your own tail, as you dance in circles.
        
        You never were a fan of being outmaneuvered.

Eli's silence is grim and contemplative, and it is a while before ${ehe} speaks again. "I see," ${ehe} says through gritted teeth. "And the perpetrators? It was those twins, wasn't it?"

"Twins…? I don't know, Eli. Whoever did this left no witnesses. Jove take them, they killed everyone there. Even the orphans the Father had been sheltering have gone missing—it will be a grim task to look for their bodies if the greatflood doesn't take us first."

Eli grinds ${ehis} teeth, hands balling up into fists beside ${ehim}. "Do you think the caravans will come?"

Kalla laughs drily at that. "You know the answer to that. They'll bunker up and leave the rest of the city to drown," she says. "And when Aulain is in ruins, they'll call on their merchant contacts—the same ones they've let bleed this damn city dry for so long. Get a cushy little mansion in Salantira City for services rendered. Might even take a Trueblade platoon or two with them." She shakes her head grimly. "Those leeches are nothing if not predictable. The tragedy is that we still have to beg for their scraps all the same."

Eli's scowl deepens. "Meviel fights a losing battle, then," ${ehe} says tersely. "You mentioned an envoy. What did they tell you?"

"That it's pandemonium up there," Kalla says, looking distantly towards the horizon. A shadow lurks within the storm's gloom, something grand and imposing that towers over Aulain's sprawl. Bastion Cliff, the base upon which the highcity sits, offering salvation to those deemed worthy enough to receive it. "A nobles' spat, in all likelihood, but one that grew out of proportion. He said Trueblades are up in arms, and in the chaos no one with authority can be reached. Can you imagine that? Tens of thousands stand to die down here, damnation's own storm is hanging over our heads, and those nobles [i]still[/i] find a way to be useless, the damn fools."

Eli stills for a moment, before sweeping ${ehis} gaze towards the rest of your party. A tacit request for permission—to change the face of your mission yet again. No longer to aid ${ehis} order against some mysterious assailants, but to save the whole damn city from its fate. A tall ask if ever there was one.

Casting a glance sideways, you see ${yusuha} give Eli a resolute nod. ${falco}, on the other hand, crosses ${fhis} arms. Displeased, but not enough to be oppositional.

*choice
    #My expression is a mirror of ${yusuha}'s. It's a given that we ought to help.
        *set noble %+ 15
        A great tragedy is unfolding before your eyes, and your interference may well decide the fate of countless innocents. The scope of your involvement remains to be seen—and so too does your odds of success, you think uncomfortably—but as Reglaire had proven, you have power enough between you to change the face of a city. Perhaps said power can be channeled for the better. Invested in service of salvation, rather than carnage.
        
        If nothing else, you have to at least try.
        
        Eli catches the look on your face and appears to be bolstered by it. $!{ehis} grim anxiety has turned to resolve by the time ${ehe} faces Kalla again and tells her, "We'll go up to the highcity. One way or another, we'll make sure the evacuation happens.        
    #My expression is a mirror of ${falco}'s. This is not what we're here for.
        *set noble %- 15
        It's not as if you don't sympathize at all with these people's plight, but you can hardly afford to play hero. Whatever power you may possess, in the end you are a party of four. [i]Four[/i], saddled with a mission you know not where to begin completing. And you're supposed to somehow whip Aulain's ruling class into shape and organize an evacuation, all before a disaster of unknown proportions escorts this doomed city to its fate?
        
        It's ludicrous, no matter which way you try to twist it.
        
        Still, given Eli and ${yusuha}'s dispositions, abandoning these people to their fate is sure to cause them distress. Enough for them to get distracted, and jeopardize the entire mission. And with Eli's captors having apparently disappeared after their gruesome work, it's not as if you have somewhere else to be.
        
        You heave a resigned sigh. What you need right now is a lead. You suppose the highcity is as good a place as any to start looking for one.
        
        Relief flood Eli's features when ${ehe} catches sight of your reluctant assent, and ${ehe} bodily turns back to face Kalla. "We'll go up to the highcity. One way or another, we'll make sure the evacuation happens."
    #Something's off about this. A civil dispute at the brink of a greatflood demands investigation.
        It's not like you're a stranger to the foolish, frivolous whims of nobility, having spent a good portion of your life a silent satellite to their circles. You know well the worst of their excesses—the unerring selfishness, the endless bureaucracy—but even then the current state of affairs beggars belief. To invite ruin into the lone oasis of a doomed city seems to you the height of foolishness none would sanely climb.
        
        Even if Aulain's nobles were universally deserving of Kalla's harsh evaluation, they can at least be trusted to look after their own interests. And no one stands to win from a bloody conflict in this circumstance,
        
        Eli seems to take your thoughtful expression for tacit approval. Relief floods ${ehis} features, and ${ehe} turns ${ehis} attention back on Kalla. "We'll go up to the highcity. One way or another, we'll make sure the evacuation happens."
        
"You're welcome to try, though you'll forgive me for not holding my breath," Kalla sighs. Realization dawns on her then, and she stares quizzically at Eli. "Wait. What do you mean [i]we[/i]?"

The magic in your mask coils and hums, hard at work. Kalla is close to perceiving you.

*choice
    #Now seems as good a time as any. I remove my mask.
        *set rfalco %- 3
        *set ryusuha %- 3
        *set reli %+ 3
        *set optimistic %+ 15
        Taking that as your cue, you remove the mask from your face. You feel ${falco} and ${yusuha}'s eyes on you like pinpricks at the back of your neck, but they make no move to stop you.
        
        A dazed look enters Kalla's eyes as the enchantment reorients her perception; she blinks hard, and then it's as if you've been there all along. "What…" she shakes her head, swallowing her confusion. "Friend of yours, Eli?"
        
        "Yes," Eli confirms, the fondness in ${ehis} tone an odd fit for the atmosphere. "I ran into ${them} by chance on the way here. @{pronvar He's|She's|They've} agreed to help out…"
        
        *if (charming > 50)
            "Though I didn't quite plan for a greatflood," you say, affecting a lighthearted tone. "We're after the ones who attacked Eli, but I suppose this is the more pressing concern."

            Kalla seems stunned, for a moment, and then she bodily rounds on Eli. "You fool. What did you get this poor @{pronvar man|woman|person} into?"

            "@{pronvar He's|She's|They're} strong, probably stronger than me. You won't need to worry—${they} can more than hold ${their} own," Eli replies.

            Kalla turns a searching, critical gaze on you, but she eventually sighs in resignation. "We shouldn't turn down a willing pair of hands given how dire the situation is," she says. "But I hope you curse Eli out for dragging you into Aulain's problems."
            
            "Duly noted. I'll make sure ${ehe} never hears the end of it."
            
            Kalla snorts at that, her mood having taken a turn for the better. "You have my gratitude. Both of you. Whatever you can do to ease our burdens, we'll happily accept. And if you can truly arrange for the evacuation…"
            
            "You have my word," Eli says resolutely.
        
            Kalla feels the gravity of ${ehis} words, and for the briefest of seconds you could swear there was a glimmer of hope in her eyes. "May Jove speed your way," she says, bowing her head slightly. It's an awkward gesture, and the way she does it is stilted—clearly, she's not in the habit of doing it often. "And may you deliver us all from this plight."
        *else
            "I'm not one to abandon my friends," you say. "I'll do what I can."
            
            Kalla seems stunned, for a moment, and then she bodily rounds on Eli. "You fool. What did you get this poor @{pronvar man|woman|person} into?"

            "@{pronvar He's|She's|They're} strong, probably stronger than me. You won't need to worry—${they} can more than hold ${their} own," Eli replies.

            Kalla turns a searching, critical gaze on you, but she eventually sighs in resignation. "We shouldn't turn down a willing pair of hands given how dire the situation is," she says. "But I hope you curse Eli out for dragging you into Aulain's problems."
            
            "I'm here of my own volition," you say, shaking your head.
            
            "Unwise," she remarks, resigned. "But you have my gratitude all the same. Whatever you can do to ease our burdens, we'll happily accept. And if you can truly arrange for the evacuation…"
            
            "You have my word," Eli says resolutely.
        
            Kalla feels the gravity of ${ehis} words, and for the briefest of seconds you could swear there was a glimmer of hope in her eyes. "May Jove speed your way," she says, bowing her head slightly. It's an awkward gesture, and the way she does it is stilted—clearly, she's not in the habit of doing it often. "And may you deliver us all from this plight."
    *selectable_if (enchantment > 65) #I remove my mask, casting a glamour in its stead to hide my true appearance.
        *set optimistic %- 15
        *set rfalco %+ 5
        *set ryusuha %+ 5
        Your mana sings as the spell settles over your face and your new identity slips into place. A face plucked from the endless tableau of your memories, some shopkeep or other with tired eyes and a nondescript smile. ${falco} observes you silently before following your lead, ${fhis} spell settling quietly over both ${fhim} and ${yusuha}.
        
        And then as one, the masks come off. A dazed look enters Kalla's eyes as the enchantment reorients her perception; she blinks hard, and it's as if you've been there all along. "What…" she shakes her head, swallowing her confusion. "Friends of yours, Eli?"
        
        "Yes," Eli confirms. "I ran into ${them} by chance. They've agreed to help out…"
        
        "Though I don't know how much we can promise," ${yusuha} says, apologetic. "We're good in a fight, but our foes are typically more tangible than a storm and a nobles' quarrel."
        
        "We'll be glad for the extra pairs of hands nevertheless," Kalla admits. "I don't mean to doubt your abilities, but it may truly be a battlefield up there, if not pure anarchy altogether. You shouldn't feel obliged to risk your neck for Aulain, no matter what Eli told you. It's not too late to back out."
        
        "We can handle ourselves," you say, matching Eli's resolve with your own. "Eli wouldn't drag us into this otherwise."
        
        Kalla purses her lips, considering. "I…suppose you're right. Though I think you should still curse ${ehim} out."
        
        "We already have," ${falco} deadpans.
        
        "There's a sensible one among you, at least." Kalla's laugh is hollow, mirthless. "You have our gratitude, all of you. Whatever you can do to ease our burdens, we'll happily accept. And if you can truly arrange for the evacuation…"
            
        "You have my word," Eli says resolutely.
        
        Kalla feels the gravity of ${ehis} words, and for the briefest of seconds you could swear there was a glimmer of hope in her eyes. "May Jove speed your way," she says, bowing her head slightly. It's an awkward gesture, and the way she does it is stilted—clearly, she's not in the habit of doing it often. "And may you deliver us all from this plight."
    #I keep my mask on. It would be sloppy work to do otherwise.
        *set noble %- 15
        *set rfalco %+ 5
        *set ryusuha %+ 5
        *label boreeli
        Kalla's eyes bore into Eli questioningly, waiting for ${ehis} answer. Eli shifts uncomfortably where ${ehe} stands before answering. "I ran into some old friends out there, and they graciously agreed to help out with the Order's problems. They're out surveying the city right now, trying to find leads on the assailant."
        
        "And you think they'll help out the poor fools of this city?"
        
        "They're good people. I'm sure they can be persuaded," Eli says. "And they're strong fighters, besides. Plenty capable of holding their own."
        
        "They ought to curse you for having dragged them into Aulain's problems. Jove knows we never see the end of them," Kalla says, sighing tiredly. "But you have my gratitude, as do they. Whatever you can do to ease our burdens, we'll happily accept. And if you can truly arrange for the evacuation…"
        
        "You have my word," Eli says resolutely.
        
        Kalla feels the gravity of ${ehis} words, and for the briefest of seconds you could swear there was a glimmer of hope in her eyes. "May Jove speed your way," she says, bowing her head slightly. It's an awkward gesture, and the way she does it is stilted—clearly, she's not in the habit of doing it often. "And may you deliver us all from this plight."
    #I keep my mask on. It may well endanger Kalla to do otherwise.
        *set noble %+ 15
        *set rfalco %+ 5
        *set ryusuha %+ 5
        *goto boreeli

*page_break

At the blissful heights of Aulain's halcyon days, the highcity had been a place of community and merriment: a devoted refuge for its populace to escape the doldrums of everyday life, the endless rhythm of work. And what a refuge it is, for even under the battery of countless wars and endless rains, shades of its former glory survives to this day, crouching in the shadowed mist. It is a shell of what it once was, you know this, but there's an imposing stateliness in the curve of its arches, the crooked shadows of its dilapidated buildings. It's all the more impressive when you consider that the Aulaini of old had to change the face of the land so that their highcity could preen at its peak.

It's a well-chronicled tale, and one you've heard often enough from the lips of your tutors. Magic and engineering alike were judiciously employed over the course of decades to erode the gentle slope of the clifftop, setting it to a flat, even surface. Then in came the architects and the masons, forging a paradise of stone amidst the whistling updrafts. Tall marble pillars sprouted along the clifftop like trees, growing grander and more numerous with the passing of generations. A wide plaza took root at its center, its floor polished marble splashed with veins of jade. And from these veins grew buildings of white and green and gold: governmental halls where the nobility held court, sprawling indoor markets where flowed the wealth of nations, galleries showcasing the land's finest works.

Ostentations fit for Arvanand's finest city, one and all, but a single structure had towered above them all. Its grand and ornate pillars are visible even from this distance, the skyline uneven, evidence of the prejudiced erosion of the ages. Slender, snaking halls form the structure's main body, crawling up at a gentle and seamless slope, growing narrower as it rises higher. Its capstone is a grand, gilded bell, which would have shined brilliantly under the glare of sunlight. In the shadow of the storm, it's nowhere near so impressive. Just another shadow, cowering in the gloom.

${yusuha} draws ${yhim}self up beside you, gaze transfixed upon the structure. "Holysong Heights," ${yhe} says. Breathless, though you don't know whether that's from awe or the strain of the climb. The latter seems the safer bet. It was a long way up to the highcity, and through your travels with ${yusuha}, you've learned ${yhe} isn't so in shape as ${yhis} figure suggests. You've a feeling that vanity is the bigger player there, rather than disciplined training and exercise. "It's a stunning view, all things considered."

Eli's gaze is solemn, melancholic. "It was an important holy site, once."

"Jovian, I would assume," ${yusuha} guesses.

"Not originally. The ancient Aulaini were pagans, and they believed the sky to be the realm of divines," Eli supplies. "And so, the obsession with building upwards. The highcity and Holysong Heights both—they're meant to bring mortals closer to the deified plane, ensure that they are showered with favor and grace."

*choice
    #"Before the Jovian kingdoms sacked their city and reappropriated the Heights. Typical."
        *set optimistic %- 15
        Unlike the purge of Arcadia, the sacking of Aulain is a tale readily admitted to by Parami and Salantir history books alike. It is a universally held truth that when the legions of the Gallantine Archbishopric first laid low the great city-state of Aulain, its clerics were given free run of the highcity. They painted a new, monotheistic coat over centuries of pagan worship and spewed their doctrines from its vaunted altars, even as the city below endured unchecked rapine and grisly violence.
        
        The Archbishopric's aggressive expansion and brutality to their annexed peoples would prove unsustainable. The state would fall before the turn of the century, with its neighbors immediately descending upon its holdings like vultures. Aulain fell under the dominion of some Salantir predecessor state or other, one secular enough to allow its populace a return to their pagan roots. But by then, too few Aulaini held fast to their bygone faith to keep the fire alive, and Jovism had become too powerful a tool of keeping the peace.
        
        And so it was that, for the centuries which followed, the Holysong Heights remained a center of the Jovian faith. That is, until Aulain's star grew so dim so as to disappear. Swallowed whole by war-smoke and magefire.
        
        The grimness of your thoughts must have shown on your face, for the air between your party takes on a similar weight. In the end, it is ${yusuha} who breaks the silence. "Much was lost in those days which can't be reclaimed. It's a shame."
        
        "We'll ensure Arcadia doesn't share its fate," ${falco} says, resolute.
        
        "I imagine our success here will go a long way towards achieving that," ${yusuha} adds thoughtfully, before turning towards Eli. "You promised a great deal to the lady knight down there. I assume you have a plan?"
        
        Eli's answer, worryingly, comes with great lethargy. "Something like that."
        
        "What do you mean, 'something like that'?" ${falco} demands, not bothering to hide the ire in ${fhis} tone. "If you pulled us into some harebrained scheme based on a hunch and a dream, then Isha-on-high, I'll—"
        
        *label harestraight
        "It's not harebrained. Just…straightforward," Eli says, trying a smile which might have been intended to appear mollifying. It comes across as nervous instead—and you know ${falco} of all people would've picked that up. "You heard what Kalla said: access to the highcity has been barred because of the nobles' decree. So the solution is simple: we ask for them to reverse it."

        ${falco}'s stare on ${ehim} is incredulous. "And you think they'll just say yes?"
        
        "We need only to remove the possibility of their refusal. By any means necessary."
        
        The silence which follows ${ehis} words is so prominent that you can hear naught but the driving rain beyond ${yusuha}'s wind barrier. Eli of all people is suggesting [i]extortion[/i].
        
        You blink once, hard, meeting Eli's gaze with your own. Light dances in ${ehis} eyes, which crinkle at the corners behind ${ehis} mask's eye sockets. You realize then that the @{evar man|woman} is [i]grinning[/i].
    #"History a hobby of yours, Plague?"
        The question is tongue-in-cheek, a nudge to the way ${ehe}'s been rambling about Aulain the whole way up. But the words leave an odd weight in the air as soon as you say them. It occurs to you that you truly know precious little about Eli—or at least, the version of ${ehim} which currently stands before you. The span of a lifetime rests between you now, and in that time Eli must have picked up a hundred different interests, made a thousand different connections. Developed hobbies you know nothing about, made friends and buried them, too.
        
        Given the circumstances of your childhoods, you had always taken it for granted that you and Eli would grow up together, remain a big part of each other's lives. To know that there were shades of ${ehim} which are now forever lost to you—those awkward, brilliant, embarrassing, beautiful years of ${ehim} coming into ${ehis} own—strikes a melancholy into your heart in a way you can't quite articulate.
        
        You wonder if ${ehe} shares the sentiment.
        
        "You know I was never great with books. That part of me hasn't changed," Eli answers, after a beat of silence. You wonder if you're reading too much into it, but it feels rather like ${ehe};'s reassuring you. That underneath it all, ${ehe}'s still the same person. That the closeness you once shared would endure, if you'd permit it. You wish you could see ${ehis} expression under the mask.
        
        "Then I hope you telling us all that was pertinent to the plan," ${falco} grouses. Roughly, as always. Blissful in ${fhis} ignorance. "You [i]do[/i] have one, I'm assuming."
        
        Eli's answer, worryingly, comes with great lethargy. "'Plan' may be a generous term," ${ehe} finally says.
        
        ${falco} immediately rounds on ${ehim}, ${fhis} stare incredulous. "What do you mean by that?" ${fhe} demands, not bothering to hide ${fhis} ire. "If you pulled us into some harebrained scheme based on a hunch and a dream, then Isha-on-high, I'll—"
        
        *goto harestraight
    #"I should have liked to see this place during its heyday."
        It is the birthright of all kingdoms and empires to one day die, and Aulain is hardly unique in being the husk of some bygone glory. Countless cities like it mar the face of the Three Continents, once wealthy and resplendent, now thick with the stench of unfounded pride and lost dreams. And yet despite its ongoing necrosis, Aulain has yet to die its second death, meet its final fate: that of obscurity. Such is the consequence of the heights to which it rose. Even when the city lies broken and condemned, Aulain's name ever remains synonymous with progress and ingenuity. And so it will remain should the greatfloods lay it down to its final rest.
        
        It takes a truly monumental city to have inspired such enduring reverence. Looking up at the city's worn, shadowed spires, you imagine them bathed in lantern light and crowded with people, going about their business in one of the world's greatest cities. Colorful awnings over the wide open plaza, set to a gentle sway by the whistling winds, commerce flowing as freely as the rainwater in Aulain's gutters.
        
        Aulain's star is fading now, and one day even its memory will surrender to the passage of time. The thought fills you with an odd sense of melancholy—that everything you have come to know will one day be lost, survived only by footnotes in the margins of history books.
        
        "It must have been beautiful, no doubt," Eli agrees, ${ehis} tone similarly contemplative. "There are countless paintings out there theorizing what the highcity looked like at its peak, but no two artists can agree on the finer points of their aesthetics."
        
        "Because they had to fill in the gaps themselves," ${yusuha} says. "Much was lost since those days, and so they've been forced to rely on a lot of guesswork. It's a shame." ${yusuha} shakes ${yhis} head. "I guess we Arcadians should count ourselves lucky. We found our footing quickly enough that plenty could still be salvaged, despite how…thorough Param and Salantira were."
        
        "We have to make sure it never comes to this for Arcadia," ${falco} adds, resolute.
        
        "A lofty goal, in truth. But I imagine our success here will go a long way towards achieving that," ${yusuha} adds thoughtfully, before turning towards Eli. "You promised a great deal to the lady knight down there. I assume you have a plan?"
        
        Eli's answer, worryingly, comes with great lethargy. "Something like that."
        
        "What do you mean, 'something like that'?" ${falco} demands, not bothering to hide the ire in ${fhis} tone. "If you pulled us into some harebrained scheme based on a hunch and a dream, then Isha-on-high, I'll—"
        
*choice
    #I smirk underneath my mask. Now we're talking.
        *set noble %- 15
        You're surprised by how heartened you are by the prospect. The White Fangs always ran a clean operation, obstinately dancing around the most clear-cut paths so that they could preserve their honor, their chivalry. And that same attitude extended to the rebellion's war table, though Leon's more impractical tendencies were steadily tempered out by the endless procession of generals and spies, the people willing to match Sister's ruthlessness with their own. Still there had been a lethargy there, an unwillingness to commit to what's necessary, both in Leon himself as well as his painfully honorable knights. No one wanted to dirty their hands any more than they absolutely had to.
        
        And so unwittingly, the task fell to you.
        
        Not so with the Saber, as it turns out. They wear their cloaks and daggers like badges of honor, sparing no mercy for the undeserving. And few would classify nobles who choose petty conflicts over saving their own people as anything else.
        
        "This is acceptable," you say. "Then we'll find the highest of these nobles, make them see the error of their ways."
        
        "Make an example of them, if necessary. Their allies might need some convincing to get on board," ${falco} adds, before turning towards Eli. "It's good to know you grew a backbone."
        
        "This city's been my home for many months now," Eli says simply. "I have complaints about how the city has been run. I'd like the opportunity to lodge them."
        
        "Inelegant, but I have no complaints," ${yusuha} says. $!{yhe} is the only person you suspected might take issue with the approach, given how ardently ${yhe} defended Arrival's assailants. You are glad to find ${yhis} mercy a judicious one. Reserved for the misled and exploited, rather than the willfully malicious. "Who exactly are we after?"
        
        ${falco} turns sharply on Eli. "You would know that much, surely."
        
        "I do," Eli says. "Aulain isn't ruled by a formal lord, but rather by a council of nobles. Exalted Beris is the foremost among them, and she's rich and influential enough to have many of the others at her beck and call. It will be a small matter to have the gates opened, if we can secure her cooperation."
        
        You trek another step up to the highcity. Despite the coat of mud pressing against your boots, your steps feel lighter than ever. "Then let's have a little chat with her, shall we?"
    #I'm worried about collateral damage. Things sound chaotic enough without us fueling the flames.
        *set noble %+ 15
        It's not as if you feel particular pity for a noble class who would leave their own people to die, but based on what Kalla told you, the highcity may already be seeing its fair share of bloodshed. There will be soldiers and mercenaries just making a living embroiled in that conflict, bleeding out in the streets as nameless pawns for a cruel game. Servants of noble households too convenient to leave behind, merchants who exhausted every coin they had for a chance to survive.
        
        These are the people you risk thrusting to the crossfire. Already their fates are left to the whims of their betters, and you wonder if your foreign influence wouldn't change their fortunes for the worse.
        
        "Is there no other way?" you ask, resigned. "It's not just nobles up there, but also the people who are at their beck and call. Civilians. We'd be pulling them into something they didn't sign up for."
        
        Eli looks thoughtful. "It's a valid concern," ${ehe} agrees. "But we're only a small force, all things considered. We'll try to be careful, surgical. Make sure our influence is no larger than necessary."
        
        You feel nails digging into the palm of your hands. "And if that's not enough?"
        
        "Then we accept it as a necessary cost," ${falco} says cuttingly. "Saving an entire city is ambitious enough as is. If we're particular in how we go about it, then we'll still be standing here debating finer points until the greatflood hits."
        
        "I'm inclined to agree," ${yusuha} adds, after a while, though you don't miss the unease in ${yhis} tone. "We'll do what we can for them, but we can't lose sight of the bigger picture."
        
        The three seem immovable on the point, and so you let the matter pass. Eli shoots you a concerned look, which you dismiss with a wave of your hand. "Very well, then," Eli says, after a while. "Then our target will be the foremost of Aulain's noble council, a highborn lady who goes by Exalted Beris. She is functionally the council's leader, and is rich and influential enough to have many of the other councilors in her pocket. It will be a small matter to have the gates opened, if we can secure her cooperation."
        
        "We'll pay her a visit, then," ${falco} says, and you note the eagerness in ${fhis} tone with discomfort.
        
        "I hope she will be agreeable," ${yusuha} says with a sigh, watching as ${falco} strides forward. Resolute and swift, despite the mud caked onto ${fhis} boots. "For her sake, rather than ours."
    #I haven't gotten over my surprise. Eli truly has changed a great deal.
        The Eli of your childhood had always been a little timid—unwilling to rock the boat ${ehim}self, and mostly content with letting Sister take the lead. $!{ehe} had grown to become a steady, grounding presence, offering support but always urging discretion. When Sister set the stage to seize your freedom, penning her missives while Thaubal drank himself stupid, Eli had grown so skittish and nervous that ${ehe} drew Thaubal's notice, and nearly set the whole house of cards to collapsing.
        
        It had earned ${ehim} a week in the experimentation chamber, ${ehis} screams echoing through the halls, insisting that ${ehe} knew nothing. $!{ehe} kept ${ehis} silence to the end, and eventually even Thaubal grew to reluctantly believe ${ehim}. Until the Grand Duke's forces came for his head.
        
        You sigh privately, feeling your breath misting in the mask's confines. You had thought his cautiousness an irremovable part of ${ehim}, borne as it was from ${ehis} first escape attempt—the one which had costed ${ehis} brother his life. Perhaps you ought to be glad that ${ehe}'s changed since, grown bolder and steadier, no longer ruled by the trauma of ${ehis} past. And yet it also places emphasis on how different Eli has become, the distance created when you fell out of each other's orbits.
        
        Then again, it was ${ehe} who had suggested you steal away in the night, when Sister's wicked designs first came to light. It was ${ehe} who stared her down when she caught up. When he made the ultimate sacrifice, laying down ${ehis} life for your sake.
        
        What can that be, if not bravery? Perhaps you've never had the full measure of ${ehim} to begin with.
        
        "…acceptable," ${falco} is saying, and you blink hard, snapping out of your reverie. "But how do you intend to strike? We haven't the numbers to take on the whole lot, nor the time for a more surgical approach."
        
        "We need only to go after the noble council's leader," Eli says. "Exalted Beris is her name, and she's rich and influential enough to have many of the others at her beck and call. It will be a small matter to have the gates opened, if we can secure her cooperation."
        
        "Inelegant, but I have no complaints," ${yusuha} says. "${callsign}?"
        *choice
            #"None. Let's pay this Exalted Beris a visit."
                "We're in agreement, then," Eli says, nodding slowly.
                
                "I do hope she'll be agreeable," ${yusuha} adds quietly as Eli and ${falco} stride onwards with resolve. "For her sake, rather than ours."
            #"Let's try to keep the chaos to a minimum. There are still innocents up there."
                "Of course," Eli says without hesitation. "We'll try to be careful, surgical. Limit our influence to be no larger than is absolutely necessary."
                
                "That's always been the Saber's way, anyhow," ${yusuha} says. "I doubt this time will be any different."
                
                "Then we're in agreement. Let's be on our way," ${falco} says, striding up towards the highcity with resolve.
                
                "Looking a little eager there, Zealot," ${yusuha} calls out after ${yhim}. The latter doesn't even turn around, opting instead to raise a finger in response. ${yusuha} lets out a sigh, and mutters under ${yhis} breath, "I do hope she'll be agreeable. For her sake, rather than ours."
                
                And then ${yhe} too falls into step, cresting up the hill to the highcity's yawning gate.

*page_break

The highcity's pandemonium is a quiet one.

You imagine that it is forced to be so by circumstance. This high up, the whipping winds and ceaseless downpour take on a new, ferocious sheen, battering the landscape with such force so as to slowly wear it away. Rainwater collects in a hundred small reservoirs, grey-brown with silt and chipped stone, before it is fed in rushing channels to the gaping maw of Aulain's waterways. You watch the channels with distaste, noting the ferocity with which the water rushes downward. Eager to become someone else's problem.

Still, for all that the highcity's rot is drowned out by the sound and scent of the driving rain, its signs pervade the cityscape all the same. Broken swords and pauldrons litter the streets, discarded now that they have served their purpose. Broken glass cling onto the frames of smashed windows, the wooden floor beyond slick with still-wet blood. And in those areas where the city's architecture bends into long arches and roofed walkways, you find bodies scattered like stars, lightning reflecting in their lifeless eyes.

No one wants to fight under the fury of a storm. And so it was that every shelter in the city has become a battlefield. The irony is not lost on you.

You feel the enchantment in your mask hum to life again. It's hard at work, diverting the gazes of soldiers tired and battered, but nevertheless forced to be vigilant by their circumstance. Eli, striding at the head of your party, considers them all. Watches for someone isolated enough to be threatened, or corrupt enough to be bought.

$!{ehe} instead comes upon something better.

*page_break

"Meviel," Eli says, doffing ${ehis} mask once more, quickly approaching a knight with silver hair and a long, drooping mustache. A quick glance around reveals ${ehis} decision is not unwise. It's a narrow alley you find yourself in, littered with bodies and splashed with blood. A chokepoint so strategic that the skirmish has moved elsewhere. "You got into the highcity, after all."

The knight known as Meviel draws his blade and drops into a stance—one he relaxes once his mind catches up to his vision. "My word, is that you, Eli?" he says, plainly astonished. His voice is hoarse, and the gait with which he approaches is slightly hobbled. It's clear the night has begun to take its toll on him. "Reports held that you were captured, possibly lost to us. I am full glad that you proved them wrong."

Eli appears to debate the wisdom in retelling ${ehis} tale yet again, but eventually decides against it. "I met with Kalla in the lower city. She updated me on the state of Aulain, but she was blind on the goings-on of the highcity," ${ehe} says. "Word is that you're trying to arrange for evacuation. Have you made any progress with that?"

"Not enough," Meviel says, grinding his teeth. "We've managed to secure a couple of caravans, and I have people preparing to send them down as we speak. We haven't the clearance—unlikely that they'd have given it to us, they're certainly not hurting for mouths to feed as is—but you must have seen that the city gate was unmanned. With any luck, the chaos will keep them busy enough that we can sneak some poor souls in here." He pauses and looks at the state of the city then, grimly shaking his head. "For all the good it'll do them. Like as not they'll be mistaken as hirelings and find a spear in their chest. And then there's the matter of liberating food from the nobles' stores…Jove preserve us, this is a foul night indeed."

*choice
    #Too foul. Memories of the war return in bursts, and I struggle not to retch.
        *set emotional %+ 15
        Broken bodies, glassy eyes. Blood flowing like rivers, stench rising from the rot, the moans of pain drowned out by war drums and rallying cries—
        
        Stop. You aren't on the front lines anymore, fighting a war for some lofty king with lofty ambitions. You are a viper, watching in the dark, striking only when necessary. One body at a time. And only if they deserve it.
        
        You are grateful for the mask, the way it hides your weakness from the world. Eli presses on in ${ehis} conversation, unknowing of your turmoil.
    #Such is human nature. Even in abundance, we quarrel for more.
        *set optimistic %- 15
        It is not enough that the nobles seized the only safe haven in all of Aulain for themselves, barring all access to the commonfolk. Now they contest one another to become king of the hill, streaking blood across storm-sheltered grounds. Where the greatflood cannot reach, squalor and death breeds all the same. The grim irony of it is almost humorous.
        
        Eli has made plain that ${ehe} feels the same way, but ${ehe} is compelled by ${ehis} duty, the promise ${ehe} made to see the evacuation through. And so ${ehe} keeps what comments ${ehe} may have to ${ehim}self. Goes straight to business, as is ${ehis} lot. To gather information, piece together the big picture, find the cracks where ${ehis} influence may be lodged.
        
    #We will resolve the violence before the evacuation is carried out.
        *set optimistic %+ 15
        Easier said than done, and you know that better than most. Your task is ambitious as is, amounting to political upheaval on the precipice of natural disaster. To make no mention of the chaos already ruling the highcity's streets.
        
        But there would be little point in arranging an evacuation if you're only sending them to another firepit. Who would thank you for saving them from a greatflood and thrusting them into a battlefield?
        
        You don't yet know how everything will be resolved. Only that you will commit the whole of your abilities to the task, and that it begins with the gathering of information. Piece together the big picture, find the cracks where your influence may be lodged. In this regard, Eli is ahead of you, gaze sharp as ${ehe} asks Meviel the necessary questions.
        
"What exactly is going on? How did things come to this?"

"Ask ten different men, and you'll get ten different answers." Meviel shakes his head. "What I can be sure of is that the council has splintered in two. Exalted Beris leads one faction, and Exalted Iril the other. As you might imagine given their respective standings, the rest of the nobility has been pulled into their struggle, and so the whole highcity devolved into open warfare."

Eli's jaw tightens at the words. "And you have absolutely no idea what could have triggered this brutality?"

"None that I can be sure of. Loyalty and coin are the orders of the day. Not reason," Meviel sighs. "But there are theories, alright. The most prevailing one is the most obvious: that this is a power struggle. That Iril seeks to seize power when Beris is least fortified."

"Hard to believe, considering there might not even be a city to rule after this," Eli says. "Anything else?"

Meviel appears contemplative for a moment, before eventually deciding to speak. "Aye. A strange lead—one with the sheen of hearsay. But all the more compelling for it, given how often it comes up." Meviel scratches at his mustache. He looks uncertain—possibly thinks that this rumor of his may not be worth mentioning. "Word is that Exalted Gars was cut down at the gate of Holysong Heights. By a pair of fighters dressed in strange, foreign gear."

Eli's gaze on Meviel turns sharp. "Were they twins, by any chance?"

"Aye, some that saw the pair suspected as much. Said they shared their coloring, at least," Meviel says at length, sounding a little stunned. "You've heard the rumor, then?"

"No, but I'm starting to think it has more truth to it than you suspect," Eli says. "Go on."

"Well, they're saying that the pair retreated into the Heights, and soon Beris's people were all over the place, forbidding all entry. Gars was one of Iril's closest political allies, as you know, and she didn't take kindly to Beris shielding his killers."

"And so the unrest."

Meviel nods grimly. "The tale sounded so far-fetched. I figured it was spun by Iril's faction. A cause to rally around," he says. "But it's true that Beris is digging her heels in the Heights. That'll be where the conflict is worst, I imagine—you ought to steer well clear of it, Eli."

"I will," Eli lies. You know as well as ${ehe} does that only the Heights can be your destination. It almost feels like divine providence, the way your diverging goals have been made to align. Assuming, of course, you'll able to dispatch whatever threat lies in the temple. "Thank you, Meviel. You've been very helpful."

Meviel nods, satisfied. "I'm happy for it." The man catches himself, then, and tilts his head at Eli in confusion. "Wait…what are you doing here, anyway? Looking into the evacuation?"

"Something like that. I have a lead I'm pursuing. No, I don't need any help—I have it handled," Eli says, interrupting Meviel before he could offer. "You keep working things on your end. With any luck, between both our efforts we'll be able to save the city."

"A lofty dream. But somehow it's reassuring, coming from you," Meviel says, grinning. "Jove watch over you, Eli. Them and Father Gerian both."

*page_break

From the very first step you take inside the Holysong Heights, you encounter a problem. The enchantment in your mask becomes fully spent, rendering you at last visible to the soldiers and guards you pass along your way.

${falco} is upon the two guards playing lookout before they can so much as realize what they're looking at. Twin fists upon their windpipes strangle their surprised yelps, and then ${falco}'s hands swiftly slide forward to meet the back of their necks. The two guards crumple like puppets with strings cut. Unconscious, but breathing.

"A foul start," ${yusuha} mourns, looking distastefully down onto the guards' forms. "Let us hope it doesn't reflect on the rest of our mission."

*choice
    #"The masks picked a fine time to die out. This place is crawling with hostiles."
        *set optimistic %- 15
        "It's an esoteric enchantment, and fickle by nature. We ought to be grateful it worked for as long as it did," ${yusuha} says, sighing. "But it's not like we're powerless without it. Reglaire should be proof enough, given how outnumbered we were."
        
        "It was a closer shave than you make it appear," you point out. "And we're down three fighters, besides."
        
        "But now we have a healer with us. One of the best," ${yusuha} replies, jerking a thumb towards Eli. "We can afford to take a few risks."
        
        "Specter would resent you for that," ${falco} grouses.
        
        "Please. As if he doesn't remind his patients daily of his theurgy's limits," ${yusuha} counters. "In any case, we have the means to preserve ourselves should complications arise."
        
        "And the resolve to see it through, hopefully," ${falco} says, ${fhis} gaze especially harsh towards ${yusuha}.
        
        "We'll be careful to not go overboard," Eli says, so firmly that ${ehe} inspires no rebuttals from ${falco}. The younger mage casts ${fhis} gaze away and mutters something inaudible under ${fhis} breath. If Eli notices, ${ehe} does not show it. "But we must go. And quickly."
    #"Plenty of assassins prowl Arvanand without them. We'll just have to rely on our skills."
        *set optimistic %+ 15
        "We're no stranger to infiltration work," ${yusuha} agrees. "And though we lack traditional training, there is magic enough between us to fill in the gaps."
        
        "We have magic enough to level this whole place," ${falco} corrects. "We did as much to Reglaire."
        
        "Only because we had no other choice," ${yusuha} rebuts. "That won't be the case here. Not with how many bodies are already littering the streets."
        
        "Perhaps. But should it become necessary…"
        
        "We'll cross that bridge when we come to it," ${yusuha} says, crossing ${yhis} arms.
        
        ${falco} returns ${yusuha}'s ire with ${fhis} own. "The mission takes priority. If we have to shed some blood to get there, pity, but that's the way things must be. These peole should've picked a different career if they were so scared of violence."
        
        ${yusuha} sighs, swinging ${yhis} gaze away. "Just…moderation, please."
        
        "We'll be careful not to go overboard," Eli interrupts, placing ${ehim}self between the pair. "But we must go. And quickly."
    #"If it comes down to it, we can cut down anyone standing in our path."
        *set noble %- 15
        *set rfalco %+ 5
        ${yusuha} groans at your words. "Wonderful. Now we have two @{fvar Falcos|Flysses} to deal with."
        
        "It's not like we'd be torching the place, or killing everyone we pass on our way," ${falco} says, scowling up at ${yusuha}. "It would be messy. Sprout more complications than it resolves."
        
        "Not to mention reprehensible," ${yusuha} says, crossing ${yhis} arms. "That [i]is[/i] a concern, yes?"
        
        "The mission takes priority. If we have to shed some blood to get there, pity, but I won't lose sleep over it. They should've picked a different career if they were so scared of violence."
        
        ${yusuha} sighs, swinging ${yhis} gaze away. "Just…moderation, please."
        
        "We'll be careful not to go overboard," Eli interrupts, placing ${ehim}self between the pair. "But we must go. And quickly."

*page_break

*comment housekeeping: maybe write this scene out? dialogue and all

Despite ${falco}'s apparent eagerness for carnage, ${fhe} proved willing to submit to a relatively bloodless method. You spot an isolated pocket of soldiers patrolling the Heights' outer halls, grizzled and vigilant, but nevertheless outmatched by your overwhelming talents. Having knocked most of them out with a flashier show of force than is strictly necessary, you corner the lone remaining knight, threatening him with every trick in the book. He crumples quickly—Eli's excellent eye for people serves you well, as does ${falco}'s talent for intimidation—and he becomes all too willing to divulge the information you seek.

Importantly, he is privy to the location of both Exalted Beris and her guests of honor. The Lady Beris, he says, is engaged in a meeting with some noble or other on the other side of the highcity, taking only a few of her most trusted knights with her. The specifics of her affairs were never disclosed to the rank and file, and so he could provide you with nothing more by way of information. He reacts with such terror to ${falco}'s fury at the news that you're inclined to believe him.

Despite the lady's absence, however, her guests yet remain in Holysong Heights. They've been granted the run of the Holy Mausoleum, a sprawling collection of tombs, where Jovian saints of centuries past have been buried. The mages among Beris's forces have complained of a potent and malicious energy pervading the surrounding areas. It seems your foes are actively engaged in something, and you're willing to bet it'd be in your interest to put a stop to it.

And so, the mausoleum.

You navigate through the Heights' halls towards the back of the building, sticking to shadows and employing Glyphs of Invisibility to escape the broader troops' notice. With ${falco}'s speartip pressed against his neck, your informant proved to be most cooperative. He suggested routes rich with shadows and free of patrols, allowing you to reach the mausoleum's entrance without further event. His purpose fulfilled, ${falco} knocks him out with a swift hand to the back of his neck, depositing his unconscious body just in front of the mausoleum entrance.

You descend into its depths.
*page_break
*goto_scene Checkpoint_8-2