;tsp slip out
@TSP_SLIP_OUT(ARG)
IF MAXBASE:MASTER:TSP >= 500 && BASE:MASTER:TSP >= 500
	PRINTFORML Use TSP to slip out?
	CALL ASK_YN
	IF !RESULT
		PRINTFORML %PARSE("You use your")% power to accelerate time for %CALLNAME:ARG%, exhausting them.
		BASE:MASTER:TSP -= 500
		BASE:ARG:気力 = 200
		RETURN 1
	ENDIF
ENDIF

;allow for the purchase of 4 additional fields (original code ny11)
@ADD_BuyMoreFields
PRINTFORML With this, %PARSE("you")% can plant an additional field in a garden.
PRINTFORML It will cost \\{3000 * (1 + FLAG:畑拡張)}.
CALL ASK_YN("Purchase","Nevermind")
IF !RESULT
	IF MONEY >= (3000 * (1 + FLAG:畑拡張))
		MONEY -= (3000 * (1 + FLAG:畑拡張))
		FLAG:畑拡張 ++
		PRINTFORMW %PARSE("You")% can now plant an additional field for a total of {1 + FLAG:畑拡張}.
	ELSE
		PRINTFORMW %PARSE("You don't")% have enough money.
	ENDIF
ENDIF

;Custom code, lets you avoid your food from getting _found_ in the first place, thus staying compatible with KOJO (original code Zergrush)
@Add_PreventFoodTheft
IF ABL:TARGET:戦闘能力 <= ABL:MASTER:戦闘能力
	PRINTFORMW \@THIRD_PERSON?%CALLNAME:MASTER%#You\@ suddenly feel%THIRD_PERSON?"s"#""% like \@THIRD_PERSON?%HIS_HER(MASTER)%#your\@ %TOLOWER(EX_DISH_NAME)% is in danger...
	LOCAL:50 = ABL:TARGET:戦闘能力 >= ABL:MASTER:戦闘能力 ? 100 # 50
	IF BASE:MASTER:TSP > LOCAL:50
		PRINTFORMW Stop time and hide it?
		CALL ASK_YN()
		IF RESULT == 0
			PRINTFORMW \@THIRD_PERSON?%CALLNAME:MASTER%#You\@ stop%THIRD_PERSON?"s"#""% time, hide%THIRD_PERSON?"s"#""% \@THIRD_PERSON?%HIS_HER(MASTER)%#your\@ %TOLOWER(EX_DISH_NAME)%, wait%THIRD_PERSON?"s"#""% until the danger has passed and then retrieve%THIRD_PERSON?"s"#""% it.
			LOCAL:51 = 3
			CALL RECOVER(MASTER,-LOCAL:50,"TSP")
			RETURN 1
		ENDIF
	ELSE
		PRINTFORMW But \@THIRD_PERSON?%HE_SHE(MASTER)% doesn't#you don't\@ have enough time to hide it!
	ENDIF
ENDIF

;Custom code, each time the theft is blocked because you stopped time earlier, the check is reduced
;unused?
	; ELSEIF LOCAL:51 != 0
		; LOCAL:51--
		
@Add_ShootingStar ;restored from older versions
#DIM 地底
地底 = 0
IF CFLAG:MASTER:デート中 == 9
	地底 = 1
ELSEIF CFLAG:MASTER:現在位置 == OMANEKIBEYA() && GROUPMATCH(CFLAG:MASTER:お招き, 36, 37, 38, 49, 60, 64, 83, 84)
	地底 = 1
ENDIF

;流れ星判定
IF TIME:2 >= 6 ;timezone between 20～4
	;晴れ系時のみ発生
	IF GROUPMATCH(TIME:5, 0, 1)
		;初期確率10%
		LOCAL = 10
		;冬は空気が澄むので確率上昇
		SIF DAY:2 == 4
			LOCAL -= 3
		;晴天時は確率上昇
		SIF TIME:5 == 1
			LOCAL -= 1
		;補正後確率にて流れ星発生
		SIF RAND:LOCAL == 0
			TIME:7 = 3
		;更に冬の流れ星時、10%で流星群に派生
		SIF TIME:7 == 3 && RAND:10 && DAY:2 == 4
			TIME:7 = 4
	ENDIF
ELSE
	SIF TIME:7 > 2
		TIME:7 = 0 
ENDIF
IF !CFLAG:MASTER:うふふ && !地底
	IF TIME:7 >= 3
		CALL COLORMESSAGE("A shooting star has appeared! Quick, make a wish!",C_YELLOW,2,1)
		SIF TIME:7 == 4
			CALL COLORMESSAGE("What the... all of the stars are falling down, one after another!",C_YELLOW,2,1)
	ENDIF
ENDIF

;-------------------------------------------------
;Mystia food cart, added sparrow sake
;-------------------------------------------------
@ADD_MystiaFoodCart
#DIM 同行人数カウント
#DIM 飲酒可能人数
#DIM ATSUKAN
#DIM OOMORI
#DIM KAIKEI
#DIM KAKAKU,3
#DIM PREV_DAY

同行人数カウント = 1
飲酒可能人数 = 0
ATSUKAN = 0
KAIKEI = 0
OOMORI = 0
VARSET KAKAKU
SIF CAN_DRINK(MASTER)
	飲酒可能人数 = 1
FOR LOCAL,1,CHARANUM
	SIF !CFLAG:LOCAL:同行
		CONTINUE
	 SIF !TIME_PROGRESS(TCVAR:LOCAL:空腹時刻)
	 	CONTINUE
	同行人数カウント ++
	SIF CAN_DRINK(LOCAL)
		飲酒可能人数 ++
NEXT
CALL SPTALK, [[ミスティア]], "笑顔", 0, @"「Welcome! {同行人数カウント} \@同行人数カウント>1?people#person\@?」", 1
KAKAKU:0 = 3 * 同行人数カウント
KAKAKU:1 = 5 * 同行人数カウント
PRINTFORML Charisma: %DIGIT_GROUP(MONEY:2)%
CALL ASK_M("Assorted Skewers　(One portion 3CM)",MONEY:2 >= KAKAKU:0 && TIME_PROGRESS(TCVAR:MASTER:空腹時刻),"Assorted Skewers, Big　(One portion 5CM)", MONEY:2 >= KAKAKU:1 && TIME_PROGRESS(TCVAR:MASTER:空腹時刻),"Take-out　(5CM)",MONEY:2 >= 5 && !ITEM:ヤツメ串, "Sake", CAN_DRINK(MASTER), "Return",1)
IF RESULT == 4
	CALL SPTALK, [[ミスティア]], "笑顔", 0, @"「Come again!」", 1
	RETURN -1
ENDIF
IF RESULT == 2
	ITEM:ヤツメ串 ++
	MONEY:2 -= 5
	CALL SPTALK, [[ミスティア]], "笑顔", 0, @"「Please eat it before it gets cold!」", 1
	SOURCE:歓楽 += 200
	TFLAG:98 = 1
	TIME += 5
	RETURN 1
ENDIF
IF RESULT == 3
	IF PREV_DAY == DAY
		CALL SPTALK, [[ミスティア]], "通常", 0, @"「Unfortunately, I'm all out of special sake for today. Come see me next time if you want more!」", 1
		RETURN -1
	ENDIF
	
	CALL SPTALK, [[ミスティア]], "笑顔", 0, @"「Fufu～n, you want some sake? ...Right now, I've got some really good one.」/「This here is called sparrow sake, the legendary sake made by sparrows～」/「It's a homage to our sparrow ancestors～ Do you want some?」", 1
	
	KAKAKU:2 = 100 * 同行人数カウント
	CALL ASK_M("Have it　(100CM per person)",MONEY:2 >= KAKAKU:2, "Too expensive...", 1)
	IF RESULT == 0
		PREV_DAY = DAY
		RESULT = 2
		ATSUKAN = 2
		PRINTFORMDL You spend a while drinking this special sake...
		PRINTFORMDL You feel rejuvenated and uplifted, to the point you can hardly contain the urge to start dancing wildly!
	ELSE
		CALL SPTALK, [[ミスティア]], "通常", 0, @"「Well, it takes time and effort to make one after all...」", 1
		WAIT
		CALL SPTALK, [[ミスティア]], "笑顔", 0, @"「But please make sure to enjoy our normal assortment of goods, I always keep them affordable～!」", 1
		RETURN -1
	ENDIF
ENDIF

MONEY:2 -= KAKAKU:RESULT
KAIKEI = KAKAKU:RESULT

SIF RESULT == 1
	OOMORI = 1

IF MONEY:2 >= 2 * 飲酒可能人数 && RESULT != 2
	CALL SPTALK, [[ミスティア]], "通常", 0, @"「Would you also like some warm sake at 2 Charisma per person?」", 1
	PRINTFORML (Increases ENE and DRUNK)
	CALL ASK_YN
	IF !RESULT
		ATSUKAN = 1
		KAIKEI += 2 * 飲酒可能人数
		MONEY:2 -= 2 * 飲酒可能人数
	ENDIF
ENDIF
;信頼
TFLAG:98 += 3
;同行中全員で回す

FOR LOCAL,0,CHARANUM
	SIF !CFLAG:LOCAL:同行 && LOCAL
		CONTINUE
	 SIF !TIME_PROGRESS(TCVAR:LOCAL:空腹時刻)
	 	CONTINUE
	CALL ADD_EAT_YATSUME(LOCAL,OOMORI,ATSUKAN)
NEXT

SOURCE:歓楽 += KAIKEI * 100
IF ATSUKAN == 2
	PRINTFORMDL You realize you spent a total of {KAIKEI} Charisma... This better be worth it.
	CALL SPTALK, [[ミスティア]], "笑顔", 0, @"「Hehe～, come again!」", 1
ELSE
	CALL SPTALK, [[ミスティア]], "笑顔", 0, @"「That will be a total of {KAIKEI} Charisma.」/「Please come again!」", 1
ENDIF
;time passage is already set in EAT_YATSUME 
;TIME += 30

@ADD_EAT_YATSUME(対象,ARG,ARG:1)
#DIM 回復前体力
#DIM 回復前気力
#DIM 回復前精力
#DIM 回復後体力
#DIM 回復後気力
#DIM 回復後精力
#DIM 対象

回復前体力 = BASE:対象:体力
回復前気力 = BASE:対象:気力
回復前精力 = BASE:対象:精力

;sparrow sake skip
IF ARG:1 == 2
;大盛りの場合
ELSEIF ARG == 1
	CALL 満腹度上昇(対象,"主食")
	CALL RECOVER_PERMIL(対象,100,"体力", 0, " ")
	CALL RECOVER_PERMIL(対象,200,"気力", 0, " ")
	CALL RECOVER_PERMIL(対象,100,"精力", 0, " ")
ELSE
	CALL 満腹度上昇(対象,"軽食")
	CALL RECOVER_PERMIL(対象,50,"体力", 0, " ")
	CALL RECOVER_PERMIL(対象,100,"気力", 0, " ")
	CALL RECOVER_PERMIL(対象,50,"精力", 0, " ")
ENDIF
IF 対象
;固定で獲得するソース
SOURCE:対象:歓楽 = 1000
SOURCE:対象:情愛 = 300

;ABL:欲望をみる
IF ABL:対象:欲望 <= 1
	SOURCE:対象:歓楽 += (ABL:対象:欲望 * 60)
ELSEIF ABL:対象:欲望 <= 3
	SOURCE:対象:歓楽 += 400 + (ABL:対象:欲望 * 60)
ELSEIF ABL:対象:欲望 <= 5
	SOURCE:対象:歓楽 += 800 + (ABL:対象:欲望 * 60)
ELSEIF ABL:対象:欲望 <= 8
	SOURCE:対象:歓楽 += 1000 + (ABL:対象:欲望 * 75)
ELSEIF ABL:対象:欲望 <= 11
	SOURCE:対象:歓楽 += 1700 + (ABL:対象:欲望 * 75)
ELSE
	SOURCE:対象:歓楽 += 2500 + (ABL:対象:欲望 * 35)
ENDIF

;ABL:対象:奉仕精神をみる
IF ABL:対象:奉仕精神 <= 1
	SOURCE:対象:情愛 += (ABL:対象:奉仕精神 * 30)
ELSEIF ABL:対象:奉仕精神 <= 3
	SOURCE:対象:情愛 += 200 + (ABL:対象:奉仕精神 * 30)
ELSEIF ABL:対象:奉仕精神 <= 5
	SOURCE:対象:情愛 += 500 + (ABL:対象:奉仕精神 * 30)
ELSEIF ABL:対象:奉仕精神 <= 8
	SOURCE:対象:情愛 += 700 + (ABL:対象:奉仕精神 * 45)
ELSEIF ABL:対象:奉仕精神 <= 11
	SOURCE:対象:情愛 += 1200 + (ABL:対象:奉仕精神 * 45)
ELSE
	SOURCE:対象:情愛 += 1800 + (ABL:対象:奉仕精神 * 20)
ENDIF

;好感度をみる
IF CFLAG:対象:2 <= 500
	SOURCE:対象:歓楽 += CFLAG:対象:2
ELSEIF CFLAG:対象:2 <= 5000
	SOURCE:対象:歓楽 += 750 + (CFLAG:対象:2 - 500) / 3
ELSE
	SOURCE:対象:歓楽 += 2000 + (CFLAG:対象:2 - 5000) / 4
ENDIF
SIF SOURCE:対象:歓楽 < 0
	SOURCE:対象:歓楽 = 0
SOURCE:対象:受動 = 200 + 110 * ABL:対象:従順
SOURCE:対象:征服 = 200 + 110 * ABL:対象:サドっ気

SIF TALENT:健啖
	TIMES SOURCE:対象:歓楽 , 1.50
ENDIF
;sparrow sake
IF ARG:1 == 2 && CAN_DRINK(対象)
	TIMES SOURCE:対象:歓楽 , 2.00
	CALL RECOVER_PERMIL(対象,50, "体力", 0, " ")
	CALL RECOVER_PERMIL(対象,250,"気力", 0, " ")
	CALL RECOVER_PERMIL(対象,150,"精力", 0, " ")
	SIF 対象 != MASTER
		CALL KIGEN_CHANGE(対象,100,1)
	CALL DRUNKEN(対象,53)
	CALL BUFF_BASE(対象, BASE_体力, 250, 1)
	CALL BUFF_BASE(対象, BASE_気力, 500, 1)
	CALL BUFF_BASE(対象, BASE_精力, 300, 1)
;熱燗頼んだ場合
ELSEIF ARG:1 && CAN_DRINK(対象)
	TIMES SOURCE:対象:歓楽 , 1.10
	CALL RECOVER_PERMIL(対象,50,"気力", 0, " ")
	SIF 対象 != MASTER
		CALL KIGEN_CHANGE(対象,50,1)
	CALL DRUNKEN(対象,52)
ENDIF

回復後体力 = BASE:対象:体力
回復後気力 = BASE:対象:気力
回復後精力 = BASE:対象:精力
PRINTFORMW 
TIME += 20
SIF ARG == 1
	TIME += 10
	
;decide if you want to move together with the 2hu when they go to work
@Add_Move_Job(ARG)
IF CAN_HELP_JOB(ARG)
	PRINTFORML %CALLNAME:ARG% asks whether you would like to tag along.
	CALL KOJO_MESSAGE_SEND("EVENT",13,ARG,97,0)
	CALL ASK_YN
	IF !RESULT
		;remove all "stragglers"
		FOR LOCAL, 1, GET_TARGETNUM() + 1
			SIF CFLAG:(TARGET:LOCAL):同行 
				CFLAG:(TARGET:LOCAL):同行 = 0
			;相合い傘もなくなる
			TEQUIP:(TARGET:LOCAL):201 = 0
		NEXT
		CFLAG:MASTER:同行 = 0
	
		CALL KOJO_MESSAGE_SEND("EVENT",13,ARG,98,0)
		PRINTFORMW Before you know it, you get transported together with %CALLNAME:ARG% to a new location!
		CFLAG:MASTER:現在位置 = CFLAG:ARG:職場
		CFLAG:MASTER:デート中 = GET_MAPID(CFLAG:ARG:職場)
	ELSE
		CALL KOJO_MESSAGE_SEND("EVENT",13,ARG,99,0)
	ENDIF
ENDIF
nMoveAsked = 1
	
;based on Follow command + some Date checks
@CAN_HELP_JOB(CHARA)
#FUNCTION
#DIM CHARA
SIF nMoveAsked
	RETURNF 0
SIF CHARA == MASTER
	RETURNF 0
SIF CFLAG:MASTER:イタズラ || CFLAG:MASTER:うふふ ;during sex
	RETURNF 0
SIF FLAG:70 ;tsp
	RETURNF 0
SIF BASE:MASTER:気力 < 500 ;tired
	RETURNF 0
SIF NEMUKE() >= 720 ;sleepy
	RETURNF 0
SIF TCVAR:CHARA:手伝えない == 1 ;must be able to help
	RETURNF 0
SIF CFLAG:CHARA:ブチギレ ;no pissed off characters
	RETURNF 0
SIF FLAG:デート相手 != CHARA && FLAG:デート相手 != 0 ;no dating at the moment
	RETURNF 0
SIF CFLAG:CHARA:負け犬 ;for generics?
	RETURNF 0
SIF !SHIRAHU(CHARA) ;any abnormal status
	RETURNF 0
SIF CFLAG:CHARA:態度 > 0 && CFLAG:CHARA:睡眠 == 0 ;accompany-able
	RETURNF 1
SIF (TALENT:CHARA:思慕 + TALENT:CHARA:恋慕 + TALENT:CHARA:愛欲) ;accompany-able
	RETURNF 1
	
@Add_Move_Follow(ARG)
IF CAN_MOVE_FOLLOW(ARG) == 2
	PRINTFORML %CALLNAME:ARG% asks whether you would like to tag along.
	CALL KOJO_MESSAGE_SEND("EVENT",1,ARG,97,0)
	CALL ASK_YN
	IF !RESULT
		;remove all "stragglers"
		FOR LOCAL, 1, GET_TARGETNUM() + 1
			SIF CFLAG:(TARGET:LOCAL):同行 
				CFLAG:(TARGET:LOCAL):同行 = 0
			;相合い傘もなくなる
			TEQUIP:(TARGET:LOCAL):201 = 0
		NEXT
		CFLAG:MASTER:同行 = 0
	
		CALL KOJO_MESSAGE_SEND("EVENT",1,ARG,98,0)
		PRINTFORMW Before you know it, you get transported together with %CALLNAME:ARG% to a new location!
		CFLAG:MASTER:現在位置 = CFLAG:ARG:現在位置
		CFLAG:MASTER:デート中 = GET_MAPID(CFLAG:ARG:現在位置)
	ELSE
		CALL KOJO_MESSAGE_SEND("EVENT",1,ARG,99,0)
	ENDIF
ELSEIF CAN_MOVE_FOLLOW(ARG) == 1
	PRINTFORML Would you like to follow after %HIM_HER(ARG)%?
	CALL ASK_YN
	IF !RESULT
		;remove all "stragglers"
		FOR LOCAL, 1, GET_TARGETNUM() + 1
			SIF CFLAG:(TARGET:LOCAL):同行 
				CFLAG:(TARGET:LOCAL):同行 = 0
			;相合い傘もなくなる
			TEQUIP:(TARGET:LOCAL):201 = 0
		NEXT
		CFLAG:MASTER:同行 = 0
		
		PRINTFORML You follow shortly after %CALLNAME:ARG%, who is going towards %GET_MAPNAME(GET_MAPID(CFLAG:ARG:現在位置))%.
		PRINTFORML You keep your distance somewhat, hoping %HE_SHE(ARG)% won't notice you.
		PRINTFORMW Somehow you end up arriving there without any time passing at all.
		CFLAG:MASTER:現在位置 = CFLAG:ARG:現在位置
		CFLAG:MASTER:デート中 = GET_MAPID(CFLAG:ARG:現在位置)
	ENDIF
ENDIF
nMoveAsked = 1

@CAN_MOVE_FOLLOW(CHARA)
#FUNCTION
#DIM CHARA
SIF nMoveAsked
	RETURNF 0
SIF CHARA == MASTER
	RETURNF 0
SIF CFLAG:MASTER:イタズラ || CFLAG:MASTER:うふふ ;during sex
	RETURNF 0
SIF FLAG:70 ;tsp
	RETURNF 0
SIF BASE:MASTER:気力 < 500 ;tired
	RETURNF 0
SIF NEMUKE() >= 720 ;sleepy
	RETURNF 0
SIF CFLAG:CHARA:現在位置 == SUKIMA() ;end location must exist
	RETURNF 0
SIF CFLAG:CHARA:ブチギレ ;no pissed off characters
	RETURNF 0
SIF FLAG:デート相手 != CHARA && FLAG:デート相手 != 0 ;no dating at the moment
	RETURNF 0
SIF !SHIRAHU(CHARA) ;any abnormal status
	RETURNF 0
SIF CFLAG:CHARA:態度 > 0 && CFLAG:CHARA:睡眠 == 0 ;accompany-able
	RETURNF 2
SIF (TALENT:CHARA:思慕 + TALENT:CHARA:恋慕 + TALENT:CHARA:愛欲) ;accompany-able
	RETURNF 2
RETURNF 1
	
;based on old feature for book reading, added back
@Add_SexED()
IF TFLAG:194 == 2
	PRINTFORML Seems like %CALLNAME:TARGET% is paying attention. Would you like to educate her on sexual matters?
	CALL ASK_YN
	IF RESULT
		TFLAG:194 = 0
		RETURN 0
	ENDIF
	PRINTFORML %BREAKENG(@"Up until now, the book that showed how men and women join their bodies together only made %CALLNAME:TARGET% tilt %HIS_HER(TARGET)% head in marvel.")%
	;性的経験ありの場合（めんどくさいから、自慰も無自覚も睡姦も全部含めちゃる（そもそも、教養2以上かつMASTERの教養3以上の時点でそれなりに時間経ってる筈（てか教養Lv1で無知取れても良いんじゃね？　とは思わないでもないけど、学習経験5で取れる時点で、（性的）無知は取れなくても仕方ないよねと思ったりも
	FOR LOCAL,0,66
		SIF CSVEXP(TARGET,LOCAL) != EXP:TARGET:LOCAL
			LOCAL:1 ++
	NEXT
	IF LOCAL:1
		PRINTFORML %BREAKENG(@"It certainly feels good to do that %HIMSELF_HERSELF(TARGET)%, but %HE_SHE(TARGET)%'s starting to raise questions about the purpose of such acts.")%
	ELSE
		PRINTFORML %HE_SHE(TARGET,1)%'s wondering what the fun is in doing this, asking with natural curiosity.
	ENDIF
	IF LOCAL:1 && (EXP:調教自慰経験 || EXP:自慰経験 < (EXP:Ｃ経験 + EXP:Ｖ経験 + EXP:Ａ経験 + EXP:Ｂ経験 + EXP:Ｍ経験))
		PRINTFORML %BREAKENG(@"You properly instill in %HIM_HER(TARGET)% the meaning and purpose of sexual acts, despite some twinge of guilt considering that you've done to %HIM_HER(TARGET)%.")%
		IF !TALENT:思慕 && !TALENT:恋慕 && !TALENT:恋人 && !TALENT:セフレ && !TALENT:愛欲
			PRINTFORML %CALLNAME:TARGET% glares at you with a look full of shock and contempt.
			CALL CHANGE_CFLAG(2, TARGET, -100)
			CALL CHANGE_CFLAG(4, TARGET, -100)
		ELSE
			PRINTFORML %BREAKENG(@"%HE_SHE(TARGET,1)% sighs in exasperation, but then smiles, thinking it was okay because if it feels good then it must be a great thing after all.")%
		ENDIF
	ELSEIF LOCAL:1
		PRINTFORML Trying to be as accurate as possible, you properly instill in %HIM_HER(TARGET)% the meaning and purpose of sexual acts.
		IF !TALENT:思慕 && !TALENT:恋慕 && !TALENT:恋人 && !TALENT:セフレ && !TALENT:愛欲
			PRINTFORML For some reason, %CALLNAME:TARGET% is turning deep red in the face.
		ELSE
			PRINTFORML %BREAKENG(@"While blushing, %CALLNAME:TARGET% lets out a sight, realizing that masturbation alone won't give %HIM_HER(TARGET)% any babies.")%
		ENDIF
	ELSE
		PRINTFORML You properly instill in %HIM_HER(TARGET)% the meaning and purpose of sexual acts in great detail.
		PRINTFORML %CALLNAME:TARGET% listens very carefully with a look of admiration for your superior knowledge.
	ENDIF
	PRINTFORML 
	PRINTFORML 
	PRINTFORML 
	CALL COLORMESSAGE(@"%CALLNAME:TARGET% is no longer [Ignorant]!",C_ORANGE,2,1)
	TALENT:無知 = 0
	TIME += 60 ;takes another hour
ENDIF

@Add_SexED_Hint()
IF TALENT:無知 && TFLAG:194 != 2
	IF !INRANGE(TFLAG:193, 6, 8) ;if reading a wrong book
		PRINTFORML ...You have a feeling you would be able to educate %CALLNAME:TARGET% on sexual matters if you used raunchier selection of books.
	ELSEIF ABL:教養 < 2 ;not educated enough
		PRINTFORML ...On the second thought, perhaps %CALLNAME:TARGET% is a little underprepared in terms of knowledge at the moment to grasp such concepts.
	ELSEIF ABL:教養 >= ABL:MASTER:教養 ;too smart, won't listen
		PRINTFORML ...You doubt %CALLNAME:TARGET% will be willing to listen to someone undereducated than %HIM_HER(TARGET)%.
	ELSE ;random
		PRINTFORML ...Perhaps the opportunity to educate %CALLNAME:TARGET% will present itself if you try a little bit more.
	ENDIF
ENDIF

;custom kojo call for specified com
@COM_KOJO_CALL(ARG, ARG:1, ARGS = "COM")
SIF FLAG:6 <= 0 || cBannedDialogue:(ARG):0
	RETURN 0
RESULT = 0
RESULTS =
;口上の存在判定 and RESULTSに文字列代入
IF CFLAG:ARG:口上セレクタ
	TRYCALLFORM M_KOJO_K{NO:ARG}_{CFLAG:ARG:口上セレクタ}
ELSE
	TRYCALLFORM M_KOJO_K{NO:ARG}
ENDIF
SIF !RESULT
	RETURN 0
SIF FLAG:口上色
	CALL SET_KOJO_COLOR() ;custom tweak, set color here because not all actions show TRAIN_MESSAGE from dialogue
TRYCCALLFORM M_KOJO%RESULTS%_MESSAGE_%ARGS%_K{NO:ARG}_{ARG:1}
CATCH
	;埋めていないところは汎用的な処理が可能
	RESULT = 0
	TRYCALLFORM M_KOJO%RESULTS%_MESSAGE_COM_K{NO:ARG}_00
	IF !RESULT
		RESETCOLOR
		RETURN 0
	ENDIF
ENDCATCH
RESETCOLOR
RETURN 1

@Add_TiredBitchesGotoSleep
FOR LOCAL, 1, CHARANUM
	SIF TARGET == LOCAL ;skip the current target, already processed by the main function
		CONTINUE
		
	;if meetable + exhausted + not already asleep
	IF CAN_MEET(LOCAL) && BASE:LOCAL:体力 < 500 && !TCVAR:LOCAL:休憩中 && !FLAG:70 ;tsp method not needed?
		IF CFLAG:MASTER:現在位置 != OMANEKIBEYA()
			SIF !CFLAG:LOCAL:衰弱
				CFLAG:LOCAL:衰弱 = 360
			IF CAN_SEE(LOCAL) || CFLAG:LOCAL:デート中 == MAIN_MAP ;show message only when nearby
				PRINTFORMW (It appears that %CALLNAME:LOCAL%'s strength neared its limit)
			ELSE ;debug
				;#; PRINTFORMW %CALLNAME:LOCAL% is tired and goes back to spawn area (STA - {BASE:LOCAL:体力})
			ENDIF
			
			;CALL CHARA_SLEEP, LOCAL, 1
			CALL 拠点から帰る(LOCAL) ;skip sleep function mumbo jumbo and just send them straight to bed
			;FOR LOCAL,0,CHARANUM
				CALL ENDUFUFU(LOCAL)
				CALL SET_PRANK(0,LOCAL,1)
				;SIF LOCAL
					CFLAG:LOCAL:デート中 = MAIN_MAP
				CFLAG:LOCAL:同行 = 0
				TCVAR:LOCAL:休憩中 = 1
				SIF CAN_SEE(LOCAL)
					CALL KOJO_MESSAGE_SEND("EVENT", 3, LOCAL, 1, 0)
			;NEXT
			;FLAG:デート相手 = 0
			;TFLAG:デート前好感度 = 0
			;TFLAG:106 = 0
		ENDIF
	ENDIF
NEXT

@Add_Vig_Check
#DIM 変動値
;code by AK_Spectre
IF SUMARRAY(BONUS_4_ABLE, 2, 13) + BONUS_4_ABLE:14 >= 10
	CALL COLORMESSAGE("Maximum STA and ENE have temporarily increased, with a small permanent increase as a bonus for impregnating 10 races!",C_YELLOW,2,1)
	MAXBASE:MASTER:体力 += MAXBASE:MASTER:体力/200
	MAXBASE:MASTER:気力 += MAXBASE:MASTER:気力/200
ELSE
	CALL COLORMESSAGE("Maximum TSP and ENE have temporarily increased!",C_YELLOW,2,1)
ENDIF

IF nVigIncrease < 5000
	IF FLAG:獲得パンツ種数 >= 2000
		CALL COLORMESSAGE("Maximum VIG has also increased by a small potion permanently!",C_YELLOW,2,1)
		LOCAL = MAXBASE:MASTER:精力/50
	ELSE
		CALL COLORMESSAGE("Maximum VIG has also increased by a tiny bit permanently!",C_YELLOW,2,1)
		LOCAL = MAXBASE:MASTER:精力/1000
	ENDIF
	nVigIncrease += LOCAL
	MAXBASE:MASTER:精力 += LOCAL
ENDIF

変動値 = MIN(MAXBASE:MASTER:気力 / 10, 300)
CALL BUFF_BASE(MASTER,BASE_気力,変動値)
変動値 = MIN(MAXBASE:MASTER:TSP / 2, 500)
CALL BUFF_BASE(MASTER,BASE_TSP,変動値)

@EVENTTRAIN ;when starting the day
nSexDone = 0
nVigCheck = 0

;from LIG
@Add_VigRecovery(ARG)
;絶倫
SIF TALENT:ARG:絶倫 && HAS_PENIS(ARG) && MAXBASE:ARG:精力 != 0 && BASE:ARG:精力 > 0
	BASE:ARG:精力 += RAND:(MAXBASE:ARG:精力 / 300) + 1

;精力回復
IF ARG != MASTER && BASE:MASTER:気力 > MAXBASE:MASTER:気力 / 2 && CFLAG:MASTER:現在位置 == CFLAG:ARG:現在位置
	SIF RAND:15 == 0
		BASE:MASTER:精力 ++
	SIF TALENT:ARG:謎の魅力 && RAND:20 == 0
		BASE:MASTER:精力 += 1
	SIF TALENT:ARG:人気 && RAND:20 == 0
		BASE:MASTER:精力 += 1
	SIF TALENT:ARG:恋慕 && RAND:20 == 0
		BASE:MASTER:精力 += 1
	SIF TALENT:ARG:恋人 && RAND:15 == 0
		BASE:MASTER:精力 += 1
	SIF TALENT:ARG:容姿 && RAND:10 == 0
		BASE:MASTER:精力 += 1
	;SIF TALENT:ARG:妻 && RAND:10 == 0
	;	BASE:MASTER:精力 += 1
	;SIF TALENT:ARG:幼馴染 && RAND:10 == 0
	;	BASE:MASTER:精力 += 1
	;SIF TALENT:ARG:運命の人 && RAND:5 == 0
	;	BASE:MASTER:精力 += 1
	; IF TCVAR:MASTER:精力剤ハイパー == 1
		; IF CFLAG:ARG:うふふ
			; BASE:MASTER:精力 += 5
		; ELSE
			; BASE:MASTER:精力 += 3
		; ENDIF
	; ENDIF
ENDIF

;龍印香炉の回復
; IF FLAG:龍印香炉購入済み == 1 && NOWPLACE(CFLAG:ARG:現在位置) == 99
	; BASE:ARG:体力 += RAND:(MAXBASE:ARG:体力 / 80) + 1
	; BASE:ARG:気力 += RAND:(MAXBASE:ARG:気力 / 120) + 1
; ENDIF

@Add_ExtraBonus(ARG)
FONTBOLD
SETCOLOR COLOR("PASTEL-GREEN")
;Giving an unmatched talent after ejaculating a lot
IF TALENT:ARG:絶倫 == 0 && EXP:ARG:射精経験 >= 1000 && HAS_PENIS(ARG)
	PRINTFORML After ejaculating so much, %HIS_HER(ARG)% body had to adapt...
	PRINTFORMW %CALLNAME:ARG% became【Unmatched】!
	TALENT:ARG:絶倫 = 1
	PRINTFORMW VIG has increased by 300!
	MAXBASE:ARG:精力 += 300
	
	;Increasing maximum erection for those who has 絶倫 talent to maintain erection longer
	MAXBASE:ARG:勃起 *= 2
	PRINTFORMW %CALLNAME:ARG% is now able to maintain %HIS_HER(ARG)% erection longer!
ENDIF

;Recovery speed
IF TALENT:ARG:回復速度 < 1 && MAXBASE:ARG:体力 >= 4000 && MAXBASE:ARG:気力 >= 3000
	PRINTFORML Such a massive amount of stamina and energy causes %HIS_HER(ARG)% body to adapt and learn how to recover more quickly.
	PRINTFORMW %NAME:ARG% obtained【Fast Recovery】!
	TALENT:ARG:回復速度 = 1
ENDIF
RESETCOLOR
FONTREGULAR

@Add_PantySense
#DIM P_ID
PRINTFORML You stick out your nose and begin sensing the area...
CALL SINGLE_EMPTY_LINE()
LOCAL:9 = LINECOUNT
FOR LOCAL, 1, CHARANUM
	IF GET_MAPID(CFLAG:LOCAL:現在位置) == GET_MAPID(CFLAG:MASTER:現在位置) && CFLAG:LOCAL:現在位置 != SUKIMA() && CAN_MEET(LOCAL)
		P_ID = CFLAG:LOCAL:睡眠 ? CFLAG:LOCAL:パジャマパンツ # CFLAG:LOCAL:きょうのぱんつ
		SIF P_ID > 0 && CFLAG:LOCAL:(P_ID + パンツ管理) == 0
			CALL COLORMESSAGE(@"%CALLNAME:LOCAL% is wearing %PANTSNAME(P_ID, LOCAL, 1)% today!",C_YELLOW, 1, 1)
	ENDIF
NEXT
SIF LOCAL:9 == LINECOUNT
	PRINTFORML ...No dice.
WAIT

@Add_GodPrayer(ARG)
SELECTCASE ARG
	CASE 22 ;from KR version
		PRINTL Who?
		DRAWLINE
		FOR LOCAL, 1, CHARANUM
			SIF TALENT:LOCAL:恋人 && !CFLAG:LOCAL:出禁
				PRINTFORMLC [{LOCAL}] %CALLNAME:LOCAL, 15, LEFT%
		NEXT
		PRINTL 
		DRAWLINE
		PRINTL [999] - Never mind
		INPUT
		IF RESULT >= 1 && RESULT <= CHARANUM && TALENT:RESULT:恋人
			LOCAL = RESULT
			LOCAL:9 = LINECOUNT
			$INPUT_LOOP2
			SIF LINECOUNT - LOCAL:9 > 0
				CLEARLINE LINECOUNT - LOCAL:9
			PRINTFORML [1] - C Sense \@TALENT:LOCAL:Ｃ感度?  - [%GET_TALENTNAME_TR(101, TALENT:LOCAL:Ｃ感度)%]  # \@   
			PRINTFORML [2] - V Sense \@TALENT:LOCAL:Ｖ感度?  - [%GET_TALENTNAME_TR(102, TALENT:LOCAL:Ｖ感度)%]  # \@   	
			PRINTFORML [3] - A Sense \@TALENT:LOCAL:Ａ感度?  - [%GET_TALENTNAME_TR(103, TALENT:LOCAL:Ａ感度)%]  # \@   
			PRINTFORML [4] - B Sense \@TALENT:LOCAL:Ｂ感度?  - [%GET_TALENTNAME_TR(104, TALENT:LOCAL:Ｂ感度)%]  # \@   
			PRINTFORML [5] - M Sense \@TALENT:LOCAL:Ｍ感度?  - [%GET_TALENTNAME_TR(106, TALENT:LOCAL:Ｍ感度)%]  # \@ 
			PRINTL [999] - Never mind
			INPUT
			SELECTCASE RESULT
				CASE 1,2,3,4
					IF TALENT:LOCAL:(100+RESULT)>=1
						PRINTW It's already sensitive enough.
						GOTO INPUT_LOOP2
					ELSE
						CALL IKENIE(LOCAL, 8+RESULT)
					ENDIF
				CASE 5
					IF TALENT:LOCAL:Ｍ感度>=1
						PRINTW It's already sensitive enough.
						GOTO INPUT_LOOP2
					ELSE
						CALL IKENIE(LOCAL, 13)
					ENDIF
				CASE 999
					RETURN -1
			ENDSELECT
		ELSE
			RETURN -1
		ENDIF	
	CASE 31 ;from KR version
		PRINTL Who?
		DRAWLINE
		FOR LOCAL, 1, CHARANUM
			SIF CFLAG:LOCAL:弱み握り && !CFLAG:LOCAL:出禁; && !TALENT:LOCAL:사망 (dead lmao)
				PRINTFORMLC [{LOCAL}] %CALLNAME:LOCAL, 15, LEFT%
		NEXT
		PRINTL 
		DRAWLINE
		PRINTL [999] - Never mind
		INPUT
		IF RESULT >= 1 && RESULT <= CHARANUM && CFLAG:RESULT:弱み握り
			CALL IKENIE(RESULT, 14)
		ELSE
			RETURN -1
		ENDIF	
ENDSELECT

@Add_GodPrayerEffect(ARG, ARG:1)
SELECTCASE ARG:1
	CASE 9,10,11,12
		TALENT:ARG:((ARG:1)-8+100)++
	CASE 13
		TALENT:ARG:Ｍ感度++
	CASE 14
		CFLAG:ARG:弱み握り = 0
ENDSELECT

@Add_Mob_Oni_Message
SELECTCASE RAND:4
CASE 0
	PRINTFORML Most oni are preoccupied with drinking rather than paying attention to what you're doing right now...
CASE 1
	PRINTFORML Looks like no one is objecting. Perhaps this is the norm among the oni...?
CASE 2
	PRINTFORML Some oni leer and cheer, seeing you and your partner getting intimate with each other...
CASE 3
	PRINTFORML Most oni seem to be either too drunk, or just don't care enough to get in the way...
ENDSELECT

@Add_Ban_Dialogue
#DIM nLineCnt_Head
#DIM nBannedCount

nLineCnt_Head = LINECOUNT
REDRAW 0
DO
	SIF LINECOUNT - nLineCnt_Head > 0
		CLEARLINE LINECOUNT - nLineCnt_Head
		
	nBannedCount = 0
	FOR LOCAL, 1, CHARANUM
		SIF cBannedDialogue:LOCAL:0
			nBannedCount ++
	NEXT

	PRINTL 　Characters with disabled dialogue will stay mute no matter what dialogue was chosen for them, automatic moans still apply. (Characters with a * have dialog)
	DRAWLINE
	SIF FLAG:並び替え
		CALL CHARASORT_EX
	FOR LOCAL:1, 1, EX_CHARANUM
		IF FLAG:並び替え
			LOCAL = RESULT:(LOCAL:1)
			SIF LOCAL < 0
				CONTINUE
		ELSE
			LOCAL = LOCAL:1
			SIF LOCAL >= CHARANUM
				BREAK
		ENDIF
		SIF cBannedDialogue:LOCAL:0
			SETCOLOR C_D_RED
		RESULT = 0
		TRYCALLFORM M_KOJO_K{NO:LOCAL}
		PRINTFORMLC [{LOCAL, 3}] \@ RESULT ? * # \@%CALLNAME:LOCAL%
		RESETCOLOR
	NEXT
	PRINTL 　
	DRAWLINE
	PRINTFORML [999] Finish (Disabled: %PRINT_PLUR("Character", nBannedCount)%)　[998] Reset
	$LOOP
	INPUT
	IF RESULT >= 1 && RESULT <= CHARANUM
		cBannedDialogue:RESULT:0 = !cBannedDialogue:RESULT:0
	ELSEIF RESULT == 999
		PRINTW Configuration has been completed.
		BREAK
	ELSEIF RESULT == 998
		FOR LOCAL,1,CHARANUM
			cBannedDialogue:LOCAL:0 = 0
		NEXT
	ENDIF
LOOP 1

@Add_PhysImprov(ARG, BAD_WEATHER)
#DIM BAD_WEATHER
SELECTCASE BAD_WEATHER
	CASE 0
		MAXBASE:ARG:体力 += RAND:6 + RAND:6
		MAXBASE:MASTER:体力 += RAND:4 + RAND:4
	CASE 1 ;bad weather
		MAXBASE:ARG:体力  += RAND:6 + RAND:6 + RAND:6
		MAXBASE:ARG:気力  += RAND:6 + RAND:6 + RAND:6
		MAXBASE:MASTER:体力 += RAND:4 + RAND:4 + RAND:4
		MAXBASE:MASTER:気力 += RAND:4 + RAND:4 + RAND:4
	CASE 2, 3 ;harsh weather
		MAXBASE:ARG:体力 += RAND:11 + RAND:11 + RAND:11
		MAXBASE:ARG:気力 += RAND:11 + RAND:11 + RAND:11
		MAXBASE:MASTER:体力 += RAND:5 + RAND:5 + RAND:3
		MAXBASE:MASTER:気力 += RAND:5 + RAND:5 + RAND:3
ENDSELECT

@Add_Casino_Escape(ARG)
LOCAL:9 = LINECOUNT
LOCAL = RAND(1000000) + 1000
PRINTFORML
PRINTFORML .........
PRINTFORML ......
PRINTFORML ...
WHILE RESULT != LOCAL
	PRINTFORML 「Well, have you calmed down yet?」
	PRINTFORMD [{LOCAL}] I'm calm
	INPUT
	SIF RESULT != LOCAL
		CLEARLINE 3
WEND
LOCAL = RAND(1000000) + 1000
WHILE RESULT != LOCAL
	PRINTFORML 「Very good! Is there anything I can help you with?」
	PRINTFORMD [{LOCAL}] Puh-Pleaaaaseee... Let me go! Let me go let me go let me go!!!
	INPUT
	SIF RESULT != LOCAL
		CLEARLINE 3
WEND
PRINTFORMW 「Very well. We aren't so cruel as to let you rot here for all eternity.」
PRINTFORMW 「Let's see... You may persuade me into telling you the code if you relinquish half of your Charisma earnings.」
PRINTFORMW 「It is chiefly your fault that you got yourself stuck like this, dear customer.」
PRINTFORMW 「Your only other choice is to stay here and lose everything. Well, what will it be?」
LOCAL = MULTIPLY(MONEY:2, 50)
PRINTFORML
CALL ASK_YN(@"Relinquish {LOCAL} Charisma", "I refuse!!!")
IF RESULT
	PRINTFORMW 「That's very unfortunate, dear customer.」
	PRINTFORMW 「Well, by all means, make yourself comfortable because this shall be your new home. Or grave, whichever you prefer.」
	CALL COLORMESSAGE("「Fufufu...」", C_RED, 2, 1)
ELSE
	CALL LOST_MONEY_CM(LOCAL, 2)
	IF LOCAL <= 10
		PRINTFORMW 「Eeh? Dear customer, you didn't have anything to begin with!」
		PRINTFORMW 「Fu... fufufu! Now I feel bad for bullying you so much!」
		PRINTFORMW 「Please, take this as a consolation prize. Better luck next time!」
		CALL GET_MONEY_CM(100, 2)
		PRINTFORML
	ENDIF
	PRINTFORMW 「All right... Now, listen very carefully, okay?」
	PRINTFORMW 「I will not repeat it again, so make sure you memorize it.」
	PRINTFORMW 「The code is...」
	CALL COLORMESSAGE(@"{ARG}", C_YELLOW, 2, 1)
	CLEARLINE 1
	PRINTFORMW 「And there we have it, dear customer. You are free to leave once you tell me the code.」
	PRINTFORMW 「Now please, say it!」
ENDIF
CLEARLINE LINECOUNT - LOCAL:9

@EVENTTRAIN
#PRI
FLAG:自室施錠 = 0 ;from KR version, reset locked door status

;-------------------------------
;Custom config section
;-------------------------------
@CUSTOM_OPTION_5
PRINTFORML [  5] - Show [Facial] images for the current target only：\@ nCloseAndPersonal ? Yes # No \@

@CUSTOM_OPTION_RESULT_5
nCloseAndPersonal = !nCloseAndPersonal